git.squeep.com Git - akkoma/blob - lib/pleroma/user.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.User do
   6   use Ecto.Schema
   7
   8   import Ecto.{Changeset, Query}
   9   alias Pleroma.{Repo, User, Object, Web, Activity, Notification}
  10   alias Comeonin.Pbkdf2
  11   alias Pleroma.Formatter
  12   alias Pleroma.Web.CommonAPI.Utils, as: CommonUtils
  13   alias Pleroma.Web.{OStatus, Websub, OAuth}
  14   alias Pleroma.Web.ActivityPub.{Utils, ActivityPub}
  15
  16   require Logger
  17
  18   @type t :: %__MODULE__{}
  19
  20   @email_regex ~r/^[a-zA-Z0-9.!#$%&'*+\/=?^_`{|}~-]+@[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?(?:\.[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?)*$/
  21
  22   @strict_local_nickname_regex ~r/^[a-zA-Z\d]+$/
  23   @extended_local_nickname_regex ~r/^[a-zA-Z\d_-]+$/
  24
  25   schema "users" do
  26     field(:bio, :string)
  27     field(:email, :string)
  28     field(:name, :string)
  29     field(:nickname, :string)
  30     field(:password_hash, :string)
  31     field(:password, :string, virtual: true)
  32     field(:password_confirmation, :string, virtual: true)
  33     field(:following, {:array, :string}, default: [])
  34     field(:ap_id, :string)
  35     field(:avatar, :map)
  36     field(:local, :boolean, default: true)
  37     field(:follower_address, :string)
  38     field(:search_distance, :float, virtual: true)
  39     field(:tags, {:array, :string}, default: [])
  40     field(:last_refreshed_at, :naive_datetime)
  41     has_many(:notifications, Notification)
  42     embeds_one(:info, Pleroma.User.Info)
  43
  44     timestamps()
  45   end
  46
  47   def auth_active?(%User{local: false}), do: true
  48
  49   def auth_active?(%User{info: %User.Info{confirmation_pending: false}}), do: true
  50
  51   def auth_active?(%User{info: %User.Info{confirmation_pending: true}}),
  52     do: !Pleroma.Config.get([:instance, :account_activation_required])
  53
  54   def auth_active?(_), do: false
  55
  56   def visible_for?(user, for_user \\ nil)
  57
  58   def visible_for?(%User{id: user_id}, %User{id: for_id}) when user_id == for_id, do: true
  59
  60   def visible_for?(%User{} = user, for_user) do
  61     auth_active?(user) || superuser?(for_user)
  62   end
  63
  64   def visible_for?(_, _), do: false
  65
  66   def superuser?(%User{local: true, info: %User.Info{is_admin: true}}), do: true
  67   def superuser?(%User{local: true, info: %User.Info{is_moderator: true}}), do: true
  68   def superuser?(_), do: false
  69
  70   def avatar_url(user) do
  71     case user.avatar do
  72       %{"url" => [%{"href" => href} | _]} -> href
  73       _ -> "#{Web.base_url()}/images/avi.png"
  74     end
  75   end
  76
  77   def banner_url(user) do
  78     case user.info.banner do
  79       %{"url" => [%{"href" => href} | _]} -> href
  80       _ -> "#{Web.base_url()}/images/banner.png"
  81     end
  82   end
  83
  84   def profile_url(%User{info: %{source_data: %{"url" => url}}}), do: url
  85   def profile_url(%User{ap_id: ap_id}), do: ap_id
  86   def profile_url(_), do: nil
  87
  88   def ap_id(%User{nickname: nickname}) do
  89     "#{Web.base_url()}/users/#{nickname}"
  90   end
  91
  92   def ap_followers(%User{} = user) do
  93     "#{ap_id(user)}/followers"
  94   end
  95
  96   def follow_changeset(struct, params \\ %{}) do
  97     struct
  98     |> cast(params, [:following])
  99     |> validate_required([:following])
 100   end
 101
 102   def user_info(%User{} = user) do
 103     oneself = if user.local, do: 1, else: 0
 104
 105     %{
 106       following_count: length(user.following) - oneself,
 107       note_count: user.info.note_count,
 108       follower_count: user.info.follower_count,
 109       locked: user.info.locked,
 110       confirmation_pending: user.info.confirmation_pending,
 111       default_scope: user.info.default_scope
 112     }
 113   end
 114
 115   def remote_user_creation(params) do
 116     params =
 117       params
 118       |> Map.put(:info, params[:info] || %{})
 119
 120     info_cng = User.Info.remote_user_creation(%User.Info{}, params[:info])
 121
 122     changes =
 123       %User{}
 124       |> cast(params, [:bio, :name, :ap_id, :nickname, :avatar])
 125       |> validate_required([:name, :ap_id])
 126       |> unique_constraint(:nickname)
 127       |> validate_format(:nickname, @email_regex)
 128       |> validate_length(:bio, max: 5000)
 129       |> validate_length(:name, max: 100)
 130       |> put_change(:local, false)
 131       |> put_embed(:info, info_cng)
 132
 133     if changes.valid? do
 134       case info_cng.changes[:source_data] do
 135         %{"followers" => followers} ->
 136           changes
 137           |> put_change(:follower_address, followers)
 138
 139         _ ->
 140           followers = User.ap_followers(%User{nickname: changes.changes[:nickname]})
 141
 142           changes
 143           |> put_change(:follower_address, followers)
 144       end
 145     else
 146       changes
 147     end
 148   end
 149
 150   def update_changeset(struct, params \\ %{}) do
 151     struct
 152     |> cast(params, [:bio, :name, :avatar])
 153     |> unique_constraint(:nickname)
 154     |> validate_format(:nickname, local_nickname_regex())
 155     |> validate_length(:bio, max: 5000)
 156     |> validate_length(:name, min: 1, max: 100)
 157   end
 158
 159   def upgrade_changeset(struct, params \\ %{}) do
 160     params =
 161       params
 162       |> Map.put(:last_refreshed_at, NaiveDateTime.utc_now())
 163
 164     info_cng =
 165       struct.info
 166       |> User.Info.user_upgrade(params[:info])
 167
 168     struct
 169     |> cast(params, [:bio, :name, :follower_address, :avatar, :last_refreshed_at])
 170     |> unique_constraint(:nickname)
 171     |> validate_format(:nickname, local_nickname_regex())
 172     |> validate_length(:bio, max: 5000)
 173     |> validate_length(:name, max: 100)
 174     |> put_embed(:info, info_cng)
 175   end
 176
 177   def password_update_changeset(struct, params) do
 178     changeset =
 179       struct
 180       |> cast(params, [:password, :password_confirmation])
 181       |> validate_required([:password, :password_confirmation])
 182       |> validate_confirmation(:password)
 183
 184     OAuth.Token.delete_user_tokens(struct)
 185     OAuth.Authorization.delete_user_authorizations(struct)
 186
 187     if changeset.valid? do
 188       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 189
 190       changeset
 191       |> put_change(:password_hash, hashed)
 192     else
 193       changeset
 194     end
 195   end
 196
 197   def reset_password(user, data) do
 198     update_and_set_cache(password_update_changeset(user, data))
 199   end
 200
 201   def register_changeset(struct, params \\ %{}, opts \\ []) do
 202     confirmation_status =
 203       if opts[:confirmed] || !Pleroma.Config.get([:instance, :account_activation_required]) do
 204         :confirmed
 205       else
 206         :unconfirmed
 207       end
 208
 209     info_change = User.Info.confirmation_changeset(%User.Info{}, confirmation_status)
 210
 211     changeset =
 212       struct
 213       |> cast(params, [:bio, :email, :name, :nickname, :password, :password_confirmation])
 214       |> validate_required([:email, :name, :nickname, :password, :password_confirmation])
 215       |> validate_confirmation(:password)
 216       |> unique_constraint(:email)
 217       |> unique_constraint(:nickname)
 218       |> validate_exclusion(:nickname, Pleroma.Config.get([Pleroma.User, :restricted_nicknames]))
 219       |> validate_format(:nickname, local_nickname_regex())
 220       |> validate_format(:email, @email_regex)
 221       |> validate_length(:bio, max: 1000)
 222       |> validate_length(:name, min: 1, max: 100)
 223       |> put_change(:info, info_change)
 224
 225     if changeset.valid? do
 226       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 227       ap_id = User.ap_id(%User{nickname: changeset.changes[:nickname]})
 228       followers = User.ap_followers(%User{nickname: changeset.changes[:nickname]})
 229
 230       changeset
 231       |> put_change(:password_hash, hashed)
 232       |> put_change(:ap_id, ap_id)
 233       |> put_change(:following, [followers])
 234       |> put_change(:follower_address, followers)
 235     else
 236       changeset
 237     end
 238   end
 239
 240   defp autofollow_users(user) do
 241     candidates = Pleroma.Config.get([:instance, :autofollowed_nicknames])
 242
 243     autofollowed_users =
 244       from(u in User,
 245         where: u.local == true,
 246         where: u.nickname in ^candidates
 247       )
 248       |> Repo.all()
 249
 250     follow_all(user, autofollowed_users)
 251   end
 252
 253   @doc "Inserts provided changeset, performs post-registration actions (confirmation email sending etc.)"
 254   def register(%Ecto.Changeset{} = changeset) do
 255     with {:ok, user} <- Repo.insert(changeset),
 256          {:ok, _} <- try_send_confirmation_email(user),
 257          {:ok, user} <- autofollow_users(user) do
 258       {:ok, user}
 259     end
 260   end
 261
 262   def try_send_confirmation_email(%User{} = user) do
 263     if user.info.confirmation_pending &&
 264          Pleroma.Config.get([:instance, :account_activation_required]) do
 265       user
 266       |> Pleroma.UserEmail.account_confirmation_email()
 267       |> Pleroma.Mailer.deliver()
 268     else
 269       {:ok, :noop}
 270     end
 271   end
 272
 273   def needs_update?(%User{local: true}), do: false
 274
 275   def needs_update?(%User{local: false, last_refreshed_at: nil}), do: true
 276
 277   def needs_update?(%User{local: false} = user) do
 278     NaiveDateTime.diff(NaiveDateTime.utc_now(), user.last_refreshed_at) >= 86400
 279   end
 280
 281   def needs_update?(_), do: true
 282
 283   def maybe_direct_follow(%User{} = follower, %User{local: true, info: %{locked: true}}) do
 284     {:ok, follower}
 285   end
 286
 287   def maybe_direct_follow(%User{} = follower, %User{local: true} = followed) do
 288     follow(follower, followed)
 289   end
 290
 291   def maybe_direct_follow(%User{} = follower, %User{} = followed) do
 292     if not User.ap_enabled?(followed) do
 293       follow(follower, followed)
 294     else
 295       {:ok, follower}
 296     end
 297   end
 298
 299   def maybe_follow(%User{} = follower, %User{info: _info} = followed) do
 300     if not following?(follower, followed) do
 301       follow(follower, followed)
 302     else
 303       {:ok, follower}
 304     end
 305   end
 306
 307   @doc "A mass follow for local users. Ignores blocks and has no side effects"
 308   @spec follow_all(User.t(), list(User.t())) :: {atom(), User.t()}
 309   def follow_all(follower, followeds) do
 310     following =
 311       (follower.following ++ Enum.map(followeds, fn %{follower_address: fa} -> fa end))
 312       |> Enum.uniq()
 313
 314     {:ok, follower} =
 315       follower
 316       |> follow_changeset(%{following: following})
 317       |> update_and_set_cache
 318
 319     Enum.each(followeds, fn followed ->
 320       update_follower_count(followed)
 321     end)
 322
 323     {:ok, follower}
 324   end
 325
 326   def follow(%User{} = follower, %User{info: info} = followed) do
 327     user_config = Application.get_env(:pleroma, :user)
 328     deny_follow_blocked = Keyword.get(user_config, :deny_follow_blocked)
 329
 330     ap_followers = followed.follower_address
 331
 332     cond do
 333       following?(follower, followed) or info.deactivated ->
 334         {:error, "Could not follow user: #{followed.nickname} is already on your list."}
 335
 336       deny_follow_blocked and blocks?(followed, follower) ->
 337         {:error, "Could not follow user: #{followed.nickname} blocked you."}
 338
 339       true ->
 340         if !followed.local && follower.local && !ap_enabled?(followed) do
 341           Websub.subscribe(follower, followed)
 342         end
 343
 344         following =
 345           [ap_followers | follower.following]
 346           |> Enum.uniq()
 347
 348         follower =
 349           follower
 350           |> follow_changeset(%{following: following})
 351           |> update_and_set_cache
 352
 353         {:ok, _} = update_follower_count(followed)
 354
 355         follower
 356     end
 357   end
 358
 359   def unfollow(%User{} = follower, %User{} = followed) do
 360     ap_followers = followed.follower_address
 361
 362     if following?(follower, followed) and follower.ap_id != followed.ap_id do
 363       following =
 364         follower.following
 365         |> List.delete(ap_followers)
 366
 367       {:ok, follower} =
 368         follower
 369         |> follow_changeset(%{following: following})
 370         |> update_and_set_cache
 371
 372       {:ok, followed} = update_follower_count(followed)
 373
 374       {:ok, follower, Utils.fetch_latest_follow(follower, followed)}
 375     else
 376       {:error, "Not subscribed!"}
 377     end
 378   end
 379
 380   @spec following?(User.t(), User.t()) :: boolean
 381   def following?(%User{} = follower, %User{} = followed) do
 382     Enum.member?(follower.following, followed.follower_address)
 383   end
 384
 385   def follow_import(%User{} = follower, followed_identifiers)
 386       when is_list(followed_identifiers) do
 387     Enum.map(
 388       followed_identifiers,
 389       fn followed_identifier ->
 390         with %User{} = followed <- get_or_fetch(followed_identifier),
 391              {:ok, follower} <- maybe_direct_follow(follower, followed),
 392              {:ok, _} <- ActivityPub.follow(follower, followed) do
 393           followed
 394         else
 395           err ->
 396             Logger.debug("follow_import failed for #{followed_identifier} with: #{inspect(err)}")
 397             err
 398         end
 399       end
 400     )
 401   end
 402
 403   def locked?(%User{} = user) do
 404     user.info.locked || false
 405   end
 406
 407   def get_by_id(id) do
 408     Repo.get_by(User, id: id)
 409   end
 410
 411   def get_by_ap_id(ap_id) do
 412     Repo.get_by(User, ap_id: ap_id)
 413   end
 414
 415   # This is mostly an SPC migration fix. This guesses the user nickname (by taking the last part of the ap_id and the domain) and tries to get that user
 416   def get_by_guessed_nickname(ap_id) do
 417     domain = URI.parse(ap_id).host
 418     name = List.last(String.split(ap_id, "/"))
 419     nickname = "#{name}@#{domain}"
 420
 421     get_by_nickname(nickname)
 422   end
 423
 424   def update_and_set_cache(changeset) do
 425     with {:ok, user} <- Repo.update(changeset) do
 426       Cachex.put(:user_cache, "ap_id:#{user.ap_id}", user)
 427       Cachex.put(:user_cache, "nickname:#{user.nickname}", user)
 428       Cachex.put(:user_cache, "user_info:#{user.id}", user_info(user))
 429       {:ok, user}
 430     else
 431       e -> e
 432     end
 433   end
 434
 435   def invalidate_cache(user) do
 436     Cachex.del(:user_cache, "ap_id:#{user.ap_id}")
 437     Cachex.del(:user_cache, "nickname:#{user.nickname}")
 438     Cachex.del(:user_cache, "user_info:#{user.id}")
 439   end
 440
 441   def get_cached_by_ap_id(ap_id) do
 442     key = "ap_id:#{ap_id}"
 443     Cachex.fetch!(:user_cache, key, fn _ -> get_by_ap_id(ap_id) end)
 444   end
 445
 446   def get_cached_by_id(id) do
 447     key = "id:#{id}"
 448     Cachex.fetch!(:user_cache, key, fn _ -> get_by_id(id) end)
 449   end
 450
 451   def get_cached_by_nickname(nickname) do
 452     key = "nickname:#{nickname}"
 453     Cachex.fetch!(:user_cache, key, fn _ -> get_or_fetch_by_nickname(nickname) end)
 454   end
 455
 456   def get_cached_by_nickname_or_id(nickname_or_id) do
 457     get_cached_by_nickname(nickname_or_id) || get_cached_by_id(nickname_or_id)
 458   end
 459
 460   def get_by_nickname(nickname) do
 461     Repo.get_by(User, nickname: nickname) ||
 462       if Regex.match?(~r(@#{Pleroma.Web.Endpoint.host()})i, nickname) do
 463         [local_nickname, _] = String.split(nickname, "@")
 464         Repo.get_by(User, nickname: local_nickname)
 465       end
 466   end
 467
 468   def get_by_nickname_or_email(nickname_or_email) do
 469     case user = Repo.get_by(User, nickname: nickname_or_email) do
 470       %User{} -> user
 471       nil -> Repo.get_by(User, email: nickname_or_email)
 472     end
 473   end
 474
 475   def get_cached_user_info(user) do
 476     key = "user_info:#{user.id}"
 477     Cachex.fetch!(:user_cache, key, fn _ -> user_info(user) end)
 478   end
 479
 480   def fetch_by_nickname(nickname) do
 481     ap_try = ActivityPub.make_user_from_nickname(nickname)
 482
 483     case ap_try do
 484       {:ok, user} -> {:ok, user}
 485       _ -> OStatus.make_user(nickname)
 486     end
 487   end
 488
 489   def get_or_fetch_by_nickname(nickname) do
 490     with %User{} = user <- get_by_nickname(nickname) do
 491       user
 492     else
 493       _e ->
 494         with [_nick, _domain] <- String.split(nickname, "@"),
 495              {:ok, user} <- fetch_by_nickname(nickname) do
 496           user
 497         else
 498           _e -> nil
 499         end
 500     end
 501   end
 502
 503   def get_followers_query(%User{id: id, follower_address: follower_address}, nil) do
 504     from(
 505       u in User,
 506       where: fragment("? <@ ?", ^[follower_address], u.following),
 507       where: u.id != ^id
 508     )
 509   end
 510
 511   def get_followers_query(user, page) do
 512     from(
 513       u in get_followers_query(user, nil),
 514       limit: 20,
 515       offset: ^((page - 1) * 20)
 516     )
 517   end
 518
 519   def get_followers_query(user), do: get_followers_query(user, nil)
 520
 521   def get_followers(user, page \\ nil) do
 522     q = get_followers_query(user, page)
 523
 524     {:ok, Repo.all(q)}
 525   end
 526
 527   def get_friends_query(%User{id: id, following: following}, nil) do
 528     from(
 529       u in User,
 530       where: u.follower_address in ^following,
 531       where: u.id != ^id
 532     )
 533   end
 534
 535   def get_friends_query(user, page) do
 536     from(
 537       u in get_friends_query(user, nil),
 538       limit: 20,
 539       offset: ^((page - 1) * 20)
 540     )
 541   end
 542
 543   def get_friends_query(user), do: get_friends_query(user, nil)
 544
 545   def get_friends(user, page \\ nil) do
 546     q = get_friends_query(user, page)
 547
 548     {:ok, Repo.all(q)}
 549   end
 550
 551   def get_follow_requests_query(%User{} = user) do
 552     from(
 553       a in Activity,
 554       where:
 555         fragment(
 556           "? ->> 'type' = 'Follow'",
 557           a.data
 558         ),
 559       where:
 560         fragment(
 561           "? ->> 'state' = 'pending'",
 562           a.data
 563         ),
 564       where:
 565         fragment(
 566           "? @> ?",
 567           a.data,
 568           ^%{"object" => user.ap_id}
 569         )
 570     )
 571   end
 572
 573   def get_follow_requests(%User{} = user) do
 574     q = get_follow_requests_query(user)
 575     reqs = Repo.all(q)
 576
 577     users =
 578       Enum.map(reqs, fn req -> req.actor end)
 579       |> Enum.uniq()
 580       |> Enum.map(fn ap_id -> get_by_ap_id(ap_id) end)
 581       |> Enum.filter(fn u -> !is_nil(u) end)
 582       |> Enum.filter(fn u -> !following?(u, user) end)
 583
 584     {:ok, users}
 585   end
 586
 587   def increase_note_count(%User{} = user) do
 588     info_cng = User.Info.add_to_note_count(user.info, 1)
 589
 590     cng =
 591       change(user)
 592       |> put_embed(:info, info_cng)
 593
 594     update_and_set_cache(cng)
 595   end
 596
 597   def decrease_note_count(%User{} = user) do
 598     info_cng = User.Info.add_to_note_count(user.info, -1)
 599
 600     cng =
 601       change(user)
 602       |> put_embed(:info, info_cng)
 603
 604     update_and_set_cache(cng)
 605   end
 606
 607   def update_note_count(%User{} = user) do
 608     note_count_query =
 609       from(
 610         a in Object,
 611         where: fragment("?->>'actor' = ? and ?->>'type' = 'Note'", a.data, ^user.ap_id, a.data),
 612         select: count(a.id)
 613       )
 614
 615     note_count = Repo.one(note_count_query)
 616
 617     info_cng = User.Info.set_note_count(user.info, note_count)
 618
 619     cng =
 620       change(user)
 621       |> put_embed(:info, info_cng)
 622
 623     update_and_set_cache(cng)
 624   end
 625
 626   def update_follower_count(%User{} = user) do
 627     follower_count_query =
 628       from(
 629         u in User,
 630         where: ^user.follower_address in u.following,
 631         where: u.id != ^user.id,
 632         select: count(u.id)
 633       )
 634
 635     follower_count = Repo.one(follower_count_query)
 636
 637     info_cng =
 638       user.info
 639       |> User.Info.set_follower_count(follower_count)
 640
 641     cng =
 642       change(user)
 643       |> put_embed(:info, info_cng)
 644
 645     update_and_set_cache(cng)
 646   end
 647
 648   def get_users_from_set_query(ap_ids, false) do
 649     from(
 650       u in User,
 651       where: u.ap_id in ^ap_ids
 652     )
 653   end
 654
 655   def get_users_from_set_query(ap_ids, true) do
 656     query = get_users_from_set_query(ap_ids, false)
 657
 658     from(
 659       u in query,
 660       where: u.local == true
 661     )
 662   end
 663
 664   def get_users_from_set(ap_ids, local_only \\ true) do
 665     get_users_from_set_query(ap_ids, local_only)
 666     |> Repo.all()
 667   end
 668
 669   def get_recipients_from_activity(%Activity{recipients: to}) do
 670     query =
 671       from(
 672         u in User,
 673         where: u.ap_id in ^to,
 674         or_where: fragment("? && ?", u.following, ^to)
 675       )
 676
 677     query = from(u in query, where: u.local == true)
 678
 679     Repo.all(query)
 680   end
 681
 682   def search(query, resolve \\ false) do
 683     # strip the beginning @ off if there is a query
 684     query = String.trim_leading(query, "@")
 685
 686     if resolve do
 687       User.get_or_fetch_by_nickname(query)
 688     end
 689
 690     inner =
 691       from(
 692         u in User,
 693         select_merge: %{
 694           search_distance:
 695             fragment(
 696               "? <-> (? || coalesce(?, ''))",
 697               ^query,
 698               u.nickname,
 699               u.name
 700             )
 701         },
 702         where: not is_nil(u.nickname)
 703       )
 704
 705     q =
 706       from(
 707         s in subquery(inner),
 708         order_by: s.search_distance,
 709         limit: 20
 710       )
 711
 712     Repo.all(q)
 713   end
 714
 715   def blocks_import(%User{} = blocker, blocked_identifiers) when is_list(blocked_identifiers) do
 716     Enum.map(
 717       blocked_identifiers,
 718       fn blocked_identifier ->
 719         with %User{} = blocked <- get_or_fetch(blocked_identifier),
 720              {:ok, blocker} <- block(blocker, blocked),
 721              {:ok, _} <- ActivityPub.block(blocker, blocked) do
 722           blocked
 723         else
 724           err ->
 725             Logger.debug("blocks_import failed for #{blocked_identifier} with: #{inspect(err)}")
 726             err
 727         end
 728       end
 729     )
 730   end
 731
 732   def block(blocker, %User{ap_id: ap_id} = blocked) do
 733     # sever any follow relationships to prevent leaks per activitypub (Pleroma issue #213)
 734     blocker =
 735       if following?(blocker, blocked) do
 736         {:ok, blocker, _} = unfollow(blocker, blocked)
 737         blocker
 738       else
 739         blocker
 740       end
 741
 742     if following?(blocked, blocker) do
 743       unfollow(blocked, blocker)
 744     end
 745
 746     info_cng =
 747       blocker.info
 748       |> User.Info.add_to_block(ap_id)
 749
 750     cng =
 751       change(blocker)
 752       |> put_embed(:info, info_cng)
 753
 754     update_and_set_cache(cng)
 755   end
 756
 757   # helper to handle the block given only an actor's AP id
 758   def block(blocker, %{ap_id: ap_id}) do
 759     block(blocker, User.get_by_ap_id(ap_id))
 760   end
 761
 762   def unblock(blocker, %{ap_id: ap_id}) do
 763     info_cng =
 764       blocker.info
 765       |> User.Info.remove_from_block(ap_id)
 766
 767     cng =
 768       change(blocker)
 769       |> put_embed(:info, info_cng)
 770
 771     update_and_set_cache(cng)
 772   end
 773
 774   def blocks?(user, %{ap_id: ap_id}) do
 775     blocks = user.info.blocks
 776     domain_blocks = user.info.domain_blocks
 777     %{host: host} = URI.parse(ap_id)
 778
 779     Enum.member?(blocks, ap_id) ||
 780       Enum.any?(domain_blocks, fn domain ->
 781         host == domain
 782       end)
 783   end
 784
 785   def blocked_users(user),
 786     do: Repo.all(from(u in User, where: u.ap_id in ^user.info.blocks))
 787
 788   def block_domain(user, domain) do
 789     info_cng =
 790       user.info
 791       |> User.Info.add_to_domain_block(domain)
 792
 793     cng =
 794       change(user)
 795       |> put_embed(:info, info_cng)
 796
 797     update_and_set_cache(cng)
 798   end
 799
 800   def unblock_domain(user, domain) do
 801     info_cng =
 802       user.info
 803       |> User.Info.remove_from_domain_block(domain)
 804
 805     cng =
 806       change(user)
 807       |> put_embed(:info, info_cng)
 808
 809     update_and_set_cache(cng)
 810   end
 811
 812   def local_user_query() do
 813     from(
 814       u in User,
 815       where: u.local == true,
 816       where: not is_nil(u.nickname)
 817     )
 818   end
 819
 820   def moderator_user_query() do
 821     from(
 822       u in User,
 823       where: u.local == true,
 824       where: fragment("?->'is_moderator' @> 'true'", u.info)
 825     )
 826   end
 827
 828   def deactivate(%User{} = user, status \\ true) do
 829     info_cng = User.Info.set_activation_status(user.info, status)
 830
 831     cng =
 832       change(user)
 833       |> put_embed(:info, info_cng)
 834
 835     update_and_set_cache(cng)
 836   end
 837
 838   def delete(%User{} = user) do
 839     {:ok, user} = User.deactivate(user)
 840
 841     # Remove all relationships
 842     {:ok, followers} = User.get_followers(user)
 843
 844     followers
 845     |> Enum.each(fn follower -> User.unfollow(follower, user) end)
 846
 847     {:ok, friends} = User.get_friends(user)
 848
 849     friends
 850     |> Enum.each(fn followed -> User.unfollow(user, followed) end)
 851
 852     query = from(a in Activity, where: a.actor == ^user.ap_id)
 853
 854     Repo.all(query)
 855     |> Enum.each(fn activity ->
 856       case activity.data["type"] do
 857         "Create" ->
 858           ActivityPub.delete(Object.normalize(activity.data["object"]))
 859
 860         # TODO: Do something with likes, follows, repeats.
 861         _ ->
 862           "Doing nothing"
 863       end
 864     end)
 865
 866     {:ok, user}
 867   end
 868
 869   def html_filter_policy(%User{info: %{no_rich_text: true}}) do
 870     Pleroma.HTML.Scrubber.TwitterText
 871   end
 872
 873   @default_scrubbers Pleroma.Config.get([:markup, :scrub_policy])
 874
 875   def html_filter_policy(_), do: @default_scrubbers
 876
 877   def get_or_fetch_by_ap_id(ap_id) do
 878     user = get_by_ap_id(ap_id)
 879
 880     if !is_nil(user) and !User.needs_update?(user) do
 881       user
 882     else
 883       ap_try = ActivityPub.make_user_from_ap_id(ap_id)
 884
 885       case ap_try do
 886         {:ok, user} ->
 887           user
 888
 889         _ ->
 890           case OStatus.make_user(ap_id) do
 891             {:ok, user} -> user
 892             _ -> {:error, "Could not fetch by AP id"}
 893           end
 894       end
 895     end
 896   end
 897
 898   def get_or_create_instance_user do
 899     relay_uri = "#{Pleroma.Web.Endpoint.url()}/relay"
 900
 901     if user = get_by_ap_id(relay_uri) do
 902       user
 903     else
 904       changes =
 905         %User{info: %User.Info{}}
 906         |> cast(%{}, [:ap_id, :nickname, :local])
 907         |> put_change(:ap_id, relay_uri)
 908         |> put_change(:nickname, nil)
 909         |> put_change(:local, true)
 910         |> put_change(:follower_address, relay_uri <> "/followers")
 911
 912       {:ok, user} = Repo.insert(changes)
 913       user
 914     end
 915   end
 916
 917   # AP style
 918   def public_key_from_info(%{
 919         source_data: %{"publicKey" => %{"publicKeyPem" => public_key_pem}}
 920       }) do
 921     key =
 922       public_key_pem
 923       |> :public_key.pem_decode()
 924       |> hd()
 925       |> :public_key.pem_entry_decode()
 926
 927     {:ok, key}
 928   end
 929
 930   # OStatus Magic Key
 931   def public_key_from_info(%{magic_key: magic_key}) do
 932     {:ok, Pleroma.Web.Salmon.decode_key(magic_key)}
 933   end
 934
 935   def get_public_key_for_ap_id(ap_id) do
 936     with %User{} = user <- get_or_fetch_by_ap_id(ap_id),
 937          {:ok, public_key} <- public_key_from_info(user.info) do
 938       {:ok, public_key}
 939     else
 940       _ -> :error
 941     end
 942   end
 943
 944   defp blank?(""), do: nil
 945   defp blank?(n), do: n
 946
 947   def insert_or_update_user(data) do
 948     data =
 949       data
 950       |> Map.put(:name, blank?(data[:name]) || data[:nickname])
 951
 952     cs = User.remote_user_creation(data)
 953
 954     Repo.insert(cs, on_conflict: :replace_all, conflict_target: :nickname)
 955   end
 956
 957   def ap_enabled?(%User{local: true}), do: true
 958   def ap_enabled?(%User{info: info}), do: info.ap_enabled
 959   def ap_enabled?(_), do: false
 960
 961   @doc "Gets or fetch a user by uri or nickname."
 962   @spec get_or_fetch(String.t()) :: User.t()
 963   def get_or_fetch("http" <> _host = uri), do: get_or_fetch_by_ap_id(uri)
 964   def get_or_fetch(nickname), do: get_or_fetch_by_nickname(nickname)
 965
 966   # wait a period of time and return newest version of the User structs
 967   # this is because we have synchronous follow APIs and need to simulate them
 968   # with an async handshake
 969   def wait_and_refresh(_, %User{local: true} = a, %User{local: true} = b) do
 970     with %User{} = a <- Repo.get(User, a.id),
 971          %User{} = b <- Repo.get(User, b.id) do
 972       {:ok, a, b}
 973     else
 974       _e ->
 975         :error
 976     end
 977   end
 978
 979   def wait_and_refresh(timeout, %User{} = a, %User{} = b) do
 980     with :ok <- :timer.sleep(timeout),
 981          %User{} = a <- Repo.get(User, a.id),
 982          %User{} = b <- Repo.get(User, b.id) do
 983       {:ok, a, b}
 984     else
 985       _e ->
 986         :error
 987     end
 988   end
 989
 990   def parse_bio(bio, user \\ %User{info: %{source_data: %{}}})
 991   def parse_bio(nil, _user), do: ""
 992   def parse_bio(bio, _user) when bio == "", do: bio
 993
 994   def parse_bio(bio, user) do
 995     mentions = Formatter.parse_mentions(bio)
 996     tags = Formatter.parse_tags(bio)
 997
 998     emoji =
 999       (user.info.source_data["tag"] || [])
1000       |> Enum.filter(fn %{"type" => t} -> t == "Emoji" end)
1001       |> Enum.map(fn %{"icon" => %{"url" => url}, "name" => name} ->
1002         {String.trim(name, ":"), url}
1003       end)
1004
1005     bio
1006     |> CommonUtils.format_input(mentions, tags, "text/plain")
1007     |> Formatter.emojify(emoji)
1008   end
1009
1010   def tag(user_identifiers, tags) when is_list(user_identifiers) do
1011     Repo.transaction(fn ->
1012       for user_identifier <- user_identifiers, do: tag(user_identifier, tags)
1013     end)
1014   end
1015
1016   def tag(nickname, tags) when is_binary(nickname),
1017     do: tag(User.get_by_nickname(nickname), tags)
1018
1019   def tag(%User{} = user, tags),
1020     do: update_tags(user, Enum.uniq((user.tags || []) ++ normalize_tags(tags)))
1021
1022   def untag(user_identifiers, tags) when is_list(user_identifiers) do
1023     Repo.transaction(fn ->
1024       for user_identifier <- user_identifiers, do: untag(user_identifier, tags)
1025     end)
1026   end
1027
1028   def untag(nickname, tags) when is_binary(nickname),
1029     do: untag(User.get_by_nickname(nickname), tags)
1030
1031   def untag(%User{} = user, tags),
1032     do: update_tags(user, (user.tags || []) -- normalize_tags(tags))
1033
1034   defp update_tags(%User{} = user, new_tags) do
1035     {:ok, updated_user} =
1036       user
1037       |> change(%{tags: new_tags})
1038       |> Repo.update()
1039
1040     updated_user
1041   end
1042
1043   defp normalize_tags(tags) do
1044     [tags]
1045     |> List.flatten()
1046     |> Enum.map(&String.downcase(&1))
1047   end
1048
1049   defp local_nickname_regex() do
1050     if Pleroma.Config.get([:instance, :extended_nickname_format]) do
1051       @extended_local_nickname_regex
1052     else
1053       @strict_local_nickname_regex
1054     end
1055   end
1056 end