git.squeep.com Git - akkoma/blob - lib/pleroma/user.ex

   1 defmodule Pleroma.User do
   2   use Ecto.Schema
   3
   4   import Ecto.{Changeset, Query}
   5   alias Pleroma.{Repo, User, Object, Web, Activity, Notification}
   6   alias Comeonin.Pbkdf2
   7   alias Pleroma.Formatter
   8   alias Pleroma.Web.CommonAPI.Utils, as: CommonUtils
   9   alias Pleroma.Web.{OStatus, Websub, OAuth}
  10   alias Pleroma.Web.ActivityPub.{Utils, ActivityPub}
  11
  12   schema "users" do
  13     field(:bio, :string)
  14     field(:email, :string)
  15     field(:name, :string)
  16     field(:nickname, :string)
  17     field(:password_hash, :string)
  18     field(:password, :string, virtual: true)
  19     field(:password_confirmation, :string, virtual: true)
  20     field(:following, {:array, :string}, default: [])
  21     field(:ap_id, :string)
  22     field(:avatar, :map)
  23     field(:local, :boolean, default: true)
  24     field(:follower_address, :string)
  25     field(:search_distance, :float, virtual: true)
  26     field(:last_refreshed_at, :naive_datetime)
  27     has_many(:notifications, Notification)
  28     embeds_one(:info, Pleroma.User.Info)
  29
  30     timestamps()
  31   end
  32
  33   def avatar_url(user) do
  34     case user.avatar do
  35       %{"url" => [%{"href" => href} | _]} -> href
  36       _ -> "#{Web.base_url()}/images/avi.png"
  37     end
  38   end
  39
  40   def banner_url(user) do
  41     case user.info.banner do
  42       %{"url" => [%{"href" => href} | _]} -> href
  43       _ -> "#{Web.base_url()}/images/banner.png"
  44     end
  45   end
  46
  47   def profile_url(%User{info: %{source_data: %{"url" => url}}}), do: url
  48   def profile_url(%User{ap_id: ap_id}), do: ap_id
  49   def profile_url(_), do: nil
  50
  51   def ap_id(%User{nickname: nickname}) do
  52     "#{Web.base_url()}/users/#{nickname}"
  53   end
  54
  55   def ap_followers(%User{} = user) do
  56     "#{ap_id(user)}/followers"
  57   end
  58
  59   def follow_changeset(struct, params \\ %{}) do
  60     struct
  61     |> cast(params, [:following])
  62     |> validate_required([:following])
  63   end
  64
  65   def info_changeset(struct, params \\ %{}) do
  66     raise "NOT VALID ANYMORE"
  67   end
  68
  69   def user_info(%User{} = user) do
  70     oneself = if user.local, do: 1, else: 0
  71
  72     %{
  73       following_count: length(user.following) - oneself,
  74       note_count: user.info.note_count,
  75       follower_count: user.info.follower_count,
  76       locked: user.info.locked,
  77       default_scope: user.info.default_scope
  78     }
  79   end
  80
  81   @email_regex ~r/^[a-zA-Z0-9.!#$%&'*+\/=?^_`{|}~-]+@[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?(?:\.[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?)*$/
  82   def remote_user_creation(params) do
  83     params =
  84       params
  85       |> Map.put(:info, params[:info] || %{})
  86
  87     info_cng = User.Info.remote_user_creation(%User.Info{}, params[:info])
  88
  89     changes =
  90       %User{}
  91       |> cast(params, [:bio, :name, :ap_id, :nickname, :avatar])
  92       |> validate_required([:name, :ap_id])
  93       |> unique_constraint(:nickname)
  94       |> validate_format(:nickname, @email_regex)
  95       |> validate_length(:bio, max: 5000)
  96       |> validate_length(:name, max: 100)
  97       |> put_change(:local, false)
  98       |> put_embed(:info, info_cng)
  99
 100     if changes.valid? do
 101       case info_cng.changes[:source_data] do
 102         %{"followers" => followers} ->
 103           changes
 104           |> put_change(:follower_address, followers)
 105
 106         _ ->
 107           followers = User.ap_followers(%User{nickname: changes.changes[:nickname]})
 108
 109           changes
 110           |> put_change(:follower_address, followers)
 111       end
 112     else
 113       changes
 114     end
 115   end
 116
 117   def update_changeset(struct, params \\ %{}) do
 118     struct
 119     |> cast(params, [:bio, :name, :avatar])
 120     |> unique_constraint(:nickname)
 121     |> validate_format(:nickname, ~r/^[a-zA-Z\d]+$/)
 122     |> validate_length(:bio, max: 5000)
 123     |> validate_length(:name, min: 1, max: 100)
 124   end
 125
 126   def upgrade_changeset(struct, params \\ %{}) do
 127     params =
 128       params
 129       |> Map.put(:last_refreshed_at, NaiveDateTime.utc_now())
 130
 131     info_cng =
 132       struct.info
 133       |> User.Info.user_upgrade(params[:info])
 134
 135     struct
 136     |> cast(params, [:bio, :name, :follower_address, :avatar, :last_refreshed_at])
 137     |> unique_constraint(:nickname)
 138     |> validate_format(:nickname, ~r/^[a-zA-Z\d]+$/)
 139     |> validate_length(:bio, max: 5000)
 140     |> validate_length(:name, max: 100)
 141     |> put_embed(:info, info_cng)
 142   end
 143
 144   def password_update_changeset(struct, params) do
 145     changeset =
 146       struct
 147       |> cast(params, [:password, :password_confirmation])
 148       |> validate_required([:password, :password_confirmation])
 149       |> validate_confirmation(:password)
 150
 151     OAuth.Token.delete_user_tokens(struct)
 152     OAuth.Authorization.delete_user_authorizations(struct)
 153
 154     if changeset.valid? do
 155       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 156
 157       changeset
 158       |> put_change(:password_hash, hashed)
 159     else
 160       changeset
 161     end
 162   end
 163
 164   def reset_password(user, data) do
 165     update_and_set_cache(password_update_changeset(user, data))
 166   end
 167
 168   def register_changeset(struct, params \\ %{}) do
 169     changeset =
 170       struct
 171       |> cast(params, [:bio, :email, :name, :nickname, :password, :password_confirmation])
 172       |> validate_required([:email, :name, :nickname, :password, :password_confirmation])
 173       |> validate_confirmation(:password)
 174       |> unique_constraint(:email)
 175       |> unique_constraint(:nickname)
 176       |> validate_format(:nickname, ~r/^[a-zA-Z\d]+$/)
 177       |> validate_format(:email, @email_regex)
 178       |> validate_length(:bio, max: 1000)
 179       |> validate_length(:name, min: 1, max: 100)
 180
 181     if changeset.valid? do
 182       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 183       ap_id = User.ap_id(%User{nickname: changeset.changes[:nickname]})
 184       followers = User.ap_followers(%User{nickname: changeset.changes[:nickname]})
 185
 186       changeset
 187       |> put_change(:password_hash, hashed)
 188       |> put_change(:ap_id, ap_id)
 189       |> put_change(:following, [followers])
 190       |> put_change(:follower_address, followers)
 191     else
 192       changeset
 193     end
 194   end
 195
 196   def needs_update?(%User{local: true}), do: false
 197
 198   def needs_update?(%User{local: false, last_refreshed_at: nil}), do: true
 199
 200   def needs_update?(%User{local: false} = user) do
 201     NaiveDateTime.diff(NaiveDateTime.utc_now(), user.last_refreshed_at) >= 86400
 202   end
 203
 204   def needs_update?(_), do: true
 205
 206   def maybe_direct_follow(%User{} = follower, %User{local: true, info: %{locked: true}}) do
 207     {:ok, follower}
 208   end
 209
 210   def maybe_direct_follow(%User{} = follower, %User{local: true} = followed) do
 211     follow(follower, followed)
 212   end
 213
 214   def maybe_direct_follow(%User{} = follower, %User{} = followed) do
 215     if !User.ap_enabled?(followed) do
 216       follow(follower, followed)
 217     else
 218       {:ok, follower}
 219     end
 220   end
 221
 222   def maybe_follow(%User{} = follower, %User{info: info} = followed) do
 223     if not following?(follower, followed) do
 224       follow(follower, followed)
 225     else
 226       {:ok, follower}
 227     end
 228   end
 229
 230   def follow(%User{} = follower, %User{info: info} = followed) do
 231     user_config = Application.get_env(:pleroma, :user)
 232     deny_follow_blocked = Keyword.get(user_config, :deny_follow_blocked)
 233
 234     ap_followers = followed.follower_address
 235
 236     cond do
 237       following?(follower, followed) or info.deactivated ->
 238         {:error, "Could not follow user: #{followed.nickname} is already on your list."}
 239
 240       deny_follow_blocked and blocks?(followed, follower) ->
 241         {:error, "Could not follow user: #{followed.nickname} blocked you."}
 242
 243       true ->
 244         if !followed.local && follower.local && !ap_enabled?(followed) do
 245           Websub.subscribe(follower, followed)
 246         end
 247
 248         following =
 249           [ap_followers | follower.following]
 250           |> Enum.uniq()
 251
 252         follower =
 253           follower
 254           |> follow_changeset(%{following: following})
 255           |> update_and_set_cache
 256
 257         {:ok, _} = update_follower_count(followed)
 258
 259         follower
 260     end
 261   end
 262
 263   def unfollow(%User{} = follower, %User{} = followed) do
 264     ap_followers = followed.follower_address
 265
 266     if following?(follower, followed) and follower.ap_id != followed.ap_id do
 267       following =
 268         follower.following
 269         |> List.delete(ap_followers)
 270
 271       {:ok, follower} =
 272         follower
 273         |> follow_changeset(%{following: following})
 274         |> update_and_set_cache
 275
 276       {:ok, followed} = update_follower_count(followed)
 277
 278       {:ok, follower, Utils.fetch_latest_follow(follower, followed)}
 279     else
 280       {:error, "Not subscribed!"}
 281     end
 282   end
 283
 284   def following?(%User{} = follower, %User{} = followed) do
 285     Enum.member?(follower.following, followed.follower_address)
 286   end
 287
 288   def locked?(%User{} = user) do
 289     user.info.locked || false
 290   end
 291
 292   def get_by_ap_id(ap_id) do
 293     Repo.get_by(User, ap_id: ap_id)
 294   end
 295
 296   def update_and_set_cache(changeset) do
 297     with {:ok, user} <- Repo.update(changeset) do
 298       Cachex.put(:user_cache, "ap_id:#{user.ap_id}", user)
 299       Cachex.put(:user_cache, "nickname:#{user.nickname}", user)
 300       Cachex.put(:user_cache, "user_info:#{user.id}", user_info(user))
 301       {:ok, user}
 302     else
 303       e -> e
 304     end
 305   end
 306
 307   def invalidate_cache(user) do
 308     Cachex.del(:user_cache, "ap_id:#{user.ap_id}")
 309     Cachex.del(:user_cache, "nickname:#{user.nickname}")
 310     Cachex.del(:user_cache, "user_info:#{user.id}")
 311   end
 312
 313   def get_cached_by_ap_id(ap_id) do
 314     key = "ap_id:#{ap_id}"
 315     Cachex.fetch!(:user_cache, key, fn _ -> get_by_ap_id(ap_id) end)
 316   end
 317
 318   def get_cached_by_nickname(nickname) do
 319     key = "nickname:#{nickname}"
 320     Cachex.fetch!(:user_cache, key, fn _ -> get_or_fetch_by_nickname(nickname) end)
 321   end
 322
 323   def get_by_nickname(nickname) do
 324     Repo.get_by(User, nickname: nickname)
 325   end
 326
 327   def get_by_nickname_or_email(nickname_or_email) do
 328     case user = Repo.get_by(User, nickname: nickname_or_email) do
 329       %User{} -> user
 330       nil -> Repo.get_by(User, email: nickname_or_email)
 331     end
 332   end
 333
 334   def get_cached_user_info(user) do
 335     key = "user_info:#{user.id}"
 336     Cachex.fetch!(:user_cache, key, fn _ -> user_info(user) end)
 337   end
 338
 339   def fetch_by_nickname(nickname) do
 340     ap_try = ActivityPub.make_user_from_nickname(nickname)
 341
 342     case ap_try do
 343       {:ok, user} -> {:ok, user}
 344       _ -> OStatus.make_user(nickname)
 345     end
 346   end
 347
 348   def get_or_fetch_by_nickname(nickname) do
 349     with %User{} = user <- get_by_nickname(nickname) do
 350       user
 351     else
 352       _e ->
 353         with [_nick, _domain] <- String.split(nickname, "@"),
 354              {:ok, user} <- fetch_by_nickname(nickname) do
 355           user
 356         else
 357           _e -> nil
 358         end
 359     end
 360   end
 361
 362   def get_followers_query(%User{id: id, follower_address: follower_address}) do
 363     from(
 364       u in User,
 365       where: fragment("? <@ ?", ^[follower_address], u.following),
 366       where: u.id != ^id
 367     )
 368   end
 369
 370   def get_followers(user) do
 371     q = get_followers_query(user)
 372
 373     {:ok, Repo.all(q)}
 374   end
 375
 376   def get_friends_query(%User{id: id, following: following}) do
 377     from(
 378       u in User,
 379       where: u.follower_address in ^following,
 380       where: u.id != ^id
 381     )
 382   end
 383
 384   def get_friends(user) do
 385     q = get_friends_query(user)
 386
 387     {:ok, Repo.all(q)}
 388   end
 389
 390   def get_follow_requests_query(%User{} = user) do
 391     from(
 392       a in Activity,
 393       where:
 394         fragment(
 395           "? ->> 'type' = 'Follow'",
 396           a.data
 397         ),
 398       where:
 399         fragment(
 400           "? ->> 'state' = 'pending'",
 401           a.data
 402         ),
 403       where:
 404         fragment(
 405           "? @> ?",
 406           a.data,
 407           ^%{"object" => user.ap_id}
 408         )
 409     )
 410   end
 411
 412   def get_follow_requests(%User{} = user) do
 413     q = get_follow_requests_query(user)
 414     reqs = Repo.all(q)
 415
 416     users =
 417       Enum.map(reqs, fn req -> req.actor end)
 418       |> Enum.uniq()
 419       |> Enum.map(fn ap_id -> get_by_ap_id(ap_id) end)
 420       |> Enum.filter(fn u -> !following?(u, user) end)
 421
 422     {:ok, users}
 423   end
 424
 425   def increase_note_count(%User{} = user) do
 426     info_cng = User.Info.add_to_note_count(user.info, 1)
 427
 428     cng =
 429       change(user)
 430       |> put_embed(:info, info_cng)
 431
 432     update_and_set_cache(cng)
 433   end
 434
 435   def decrease_note_count(%User{} = user) do
 436     info_cng = User.Info.add_to_note_count(user.info, -1)
 437
 438     cng =
 439       change(user)
 440       |> put_embed(:info, info_cng)
 441
 442     update_and_set_cache(cng)
 443   end
 444
 445   def update_note_count(%User{} = user) do
 446     note_count_query =
 447       from(
 448         a in Object,
 449         where: fragment("?->>'actor' = ? and ?->>'type' = 'Note'", a.data, ^user.ap_id, a.data),
 450         select: count(a.id)
 451       )
 452
 453     note_count = Repo.one(note_count_query)
 454
 455     info_cng = User.Info.set_note_count(user.info, note_count)
 456
 457     cng =
 458       change(user)
 459       |> put_embed(:info, info_cng)
 460
 461     update_and_set_cache(cng)
 462   end
 463
 464   def update_follower_count(%User{} = user) do
 465     follower_count_query =
 466       from(
 467         u in User,
 468         where: ^user.follower_address in u.following,
 469         where: u.id != ^user.id,
 470         select: count(u.id)
 471       )
 472
 473     follower_count = Repo.one(follower_count_query)
 474
 475     info_cng =
 476       user.info
 477       |> User.Info.set_follower_count(follower_count)
 478
 479     cng =
 480       change(user)
 481       |> put_embed(:info, info_cng)
 482
 483     update_and_set_cache(cng)
 484   end
 485
 486   def get_users_from_set_query(ap_ids, false) do
 487     from(
 488       u in User,
 489       where: u.ap_id in ^ap_ids
 490     )
 491   end
 492
 493   def get_users_from_set_query(ap_ids, true) do
 494     query = get_users_from_set_query(ap_ids, false)
 495
 496     from(
 497       u in query,
 498       where: u.local == true
 499     )
 500   end
 501
 502   def get_users_from_set(ap_ids, local_only \\ true) do
 503     get_users_from_set_query(ap_ids, local_only)
 504     |> Repo.all()
 505   end
 506
 507   def get_recipients_from_activity(%Activity{recipients: to}) do
 508     query =
 509       from(
 510         u in User,
 511         where: u.ap_id in ^to,
 512         or_where: fragment("? && ?", u.following, ^to)
 513       )
 514
 515     query = from(u in query, where: u.local == true)
 516
 517     Repo.all(query)
 518   end
 519
 520   def search(query, resolve \\ false) do
 521     # strip the beginning @ off if there is a query
 522     query = String.trim_leading(query, "@")
 523
 524     if resolve do
 525       User.get_or_fetch_by_nickname(query)
 526     end
 527
 528     inner =
 529       from(
 530         u in User,
 531         select_merge: %{
 532           search_distance:
 533             fragment(
 534               "? <-> (? || ?)",
 535               ^query,
 536               u.nickname,
 537               u.name
 538             )
 539         },
 540         where: not is_nil(u.nickname)
 541       )
 542
 543     q =
 544       from(
 545         s in subquery(inner),
 546         order_by: s.search_distance,
 547         limit: 20
 548       )
 549
 550     Repo.all(q)
 551   end
 552
 553   def block(blocker, %User{ap_id: ap_id} = blocked) do
 554     # sever any follow relationships to prevent leaks per activitypub (Pleroma issue #213)
 555     blocker =
 556       if following?(blocker, blocked) do
 557         {:ok, blocker, _} = unfollow(blocker, blocked)
 558         blocker
 559       else
 560         blocker
 561       end
 562
 563     if following?(blocked, blocker) do
 564       unfollow(blocked, blocker)
 565     end
 566
 567     info_cng =
 568       blocker.info
 569       |> User.Info.add_to_block(ap_id)
 570
 571     cng =
 572       change(blocker)
 573       |> put_embed(:info, info_cng)
 574
 575     update_and_set_cache(cng)
 576   end
 577
 578   # helper to handle the block given only an actor's AP id
 579   def block(blocker, %{ap_id: ap_id}) do
 580     block(blocker, User.get_by_ap_id(ap_id))
 581   end
 582
 583   def unblock(blocker, %{ap_id: ap_id}) do
 584     info_cng =
 585       blocker.info
 586       |> User.Info.remove_from_block(ap_id)
 587
 588     cng =
 589       change(blocker)
 590       |> put_embed(:info, info_cng)
 591
 592     update_and_set_cache(cng)
 593   end
 594
 595   def blocks?(user, %{ap_id: ap_id}) do
 596     blocks = user.info.blocks
 597     domain_blocks = user.info.domain_blocks
 598     %{host: host} = URI.parse(ap_id)
 599
 600     Enum.member?(blocks, ap_id) ||
 601       Enum.any?(domain_blocks, fn domain ->
 602         host == domain
 603       end)
 604   end
 605
 606   def block_domain(user, domain) do
 607     info_cng =
 608       user.info
 609       |> User.Info.add_to_domain_block(domain)
 610
 611     cng =
 612       change(user)
 613       |> put_embed(:info, info_cng)
 614
 615     update_and_set_cache(cng)
 616   end
 617
 618   def unblock_domain(user, domain) do
 619     info_cng =
 620       user.info
 621       |> User.Info.remove_from_domain_block(domain)
 622
 623     cng =
 624       change(user)
 625       |> put_embed(:info, info_cng)
 626
 627     update_and_set_cache(cng)
 628   end
 629
 630   def local_user_query() do
 631     from(
 632       u in User,
 633       where: u.local == true,
 634       where: not is_nil(u.nickname)
 635     )
 636   end
 637
 638   def moderator_user_query() do
 639     from(
 640       u in User,
 641       where: u.local == true,
 642       where: fragment("?->'is_moderator' @> 'true'", u.info)
 643     )
 644   end
 645
 646   def deactivate(%User{} = user, status \\ true) do
 647     info_cng = User.Info.set_activation_status(user.info, status)
 648
 649     cng =
 650       change(user)
 651       |> put_embed(:info, info_cng)
 652
 653     update_and_set_cache(cng)
 654   end
 655
 656   def delete(%User{} = user) do
 657     {:ok, user} = User.deactivate(user)
 658
 659     # Remove all relationships
 660     {:ok, followers} = User.get_followers(user)
 661
 662     followers
 663     |> Enum.each(fn follower -> User.unfollow(follower, user) end)
 664
 665     {:ok, friends} = User.get_friends(user)
 666
 667     friends
 668     |> Enum.each(fn followed -> User.unfollow(user, followed) end)
 669
 670     query = from(a in Activity, where: a.actor == ^user.ap_id)
 671
 672     Repo.all(query)
 673     |> Enum.each(fn activity ->
 674       case activity.data["type"] do
 675         "Create" ->
 676           ActivityPub.delete(Object.normalize(activity.data["object"]))
 677
 678         # TODO: Do something with likes, follows, repeats.
 679         _ ->
 680           "Doing nothing"
 681       end
 682     end)
 683
 684     {:ok, user}
 685   end
 686
 687   def html_filter_policy(%User{info: %{no_rich_text: true}}) do
 688     Pleroma.HTML.Scrubber.TwitterText
 689   end
 690
 691   def html_filter_policy(_), do: nil
 692
 693   def get_or_fetch_by_ap_id(ap_id) do
 694     user = get_by_ap_id(ap_id)
 695
 696     if !is_nil(user) and !User.needs_update?(user) do
 697       user
 698     else
 699       ap_try = ActivityPub.make_user_from_ap_id(ap_id)
 700
 701       case ap_try do
 702         {:ok, user} ->
 703           user
 704
 705         _ ->
 706           case OStatus.make_user(ap_id) do
 707             {:ok, user} -> user
 708             _ -> {:error, "Could not fetch by AP id"}
 709           end
 710       end
 711     end
 712   end
 713
 714   def get_or_create_instance_user do
 715     relay_uri = "#{Pleroma.Web.Endpoint.url()}/relay"
 716
 717     if user = get_by_ap_id(relay_uri) do
 718       user
 719     else
 720       changes =
 721         %User{info: %User.Info{}}
 722         |> cast(%{}, [:ap_id, :nickname, :local])
 723         |> put_change(:ap_id, relay_uri)
 724         |> put_change(:nickname, nil)
 725         |> put_change(:local, true)
 726         |> put_change(:follower_address, relay_uri <> "/followers")
 727
 728       {:ok, user} = Repo.insert(changes)
 729       user
 730     end
 731   end
 732
 733   # AP style
 734   def public_key_from_info(%{
 735         source_data: %{"publicKey" => %{"publicKeyPem" => public_key_pem}}
 736       }) do
 737     key =
 738       :public_key.pem_decode(public_key_pem)
 739       |> hd()
 740       |> :public_key.pem_entry_decode()
 741
 742     {:ok, key}
 743   end
 744
 745   # OStatus Magic Key
 746   def public_key_from_info(%{magic_key: magic_key}) do
 747     {:ok, Pleroma.Web.Salmon.decode_key(magic_key)}
 748   end
 749
 750   def get_public_key_for_ap_id(ap_id) do
 751     with %User{} = user <- get_or_fetch_by_ap_id(ap_id),
 752          {:ok, public_key} <- public_key_from_info(user.info) do
 753       {:ok, public_key}
 754     else
 755       _ -> :error
 756     end
 757   end
 758
 759   defp blank?(""), do: nil
 760   defp blank?(n), do: n
 761
 762   def insert_or_update_user(data) do
 763     data =
 764       data
 765       |> Map.put(:name, blank?(data[:name]) || data[:nickname])
 766
 767     cs = User.remote_user_creation(data)
 768
 769     Repo.insert(cs, on_conflict: :replace_all, conflict_target: :nickname)
 770   end
 771
 772   def ap_enabled?(%User{local: true}), do: true
 773   def ap_enabled?(%User{info: info}), do: info.ap_enabled
 774   def ap_enabled?(_), do: false
 775
 776   def get_or_fetch(uri_or_nickname) do
 777     if String.starts_with?(uri_or_nickname, "http") do
 778       get_or_fetch_by_ap_id(uri_or_nickname)
 779     else
 780       get_or_fetch_by_nickname(uri_or_nickname)
 781     end
 782   end
 783
 784   # wait a period of time and return newest version of the User structs
 785   # this is because we have synchronous follow APIs and need to simulate them
 786   # with an async handshake
 787   def wait_and_refresh(_, %User{local: true} = a, %User{local: true} = b) do
 788     with %User{} = a <- Repo.get(User, a.id),
 789          %User{} = b <- Repo.get(User, b.id) do
 790       {:ok, a, b}
 791     else
 792       _e ->
 793         :error
 794     end
 795   end
 796
 797   def wait_and_refresh(timeout, %User{} = a, %User{} = b) do
 798     with :ok <- :timer.sleep(timeout),
 799          %User{} = a <- Repo.get(User, a.id),
 800          %User{} = b <- Repo.get(User, b.id) do
 801       {:ok, a, b}
 802     else
 803       _e ->
 804         :error
 805     end
 806   end
 807
 808   def parse_bio(bio, user \\ %User{info: %{source_data: %{}}}) do
 809     mentions = Formatter.parse_mentions(bio)
 810     tags = Formatter.parse_tags(bio)
 811
 812     emoji =
 813       (user.info.source_data["tag"] || [])
 814       |> Enum.filter(fn %{"type" => t} -> t == "Emoji" end)
 815       |> Enum.map(fn %{"icon" => %{"url" => url}, "name" => name} ->
 816         {String.trim(name, ":"), url}
 817       end)
 818
 819     CommonUtils.format_input(bio, mentions, tags, "text/plain") |> Formatter.emojify(emoji)
 820   end
 821 end