git.squeep.com Git - akkoma/blob - lib/pleroma/user.ex

   1 defmodule Pleroma.User do
   2   use Ecto.Schema
   3   import Ecto.Changeset
   4   alias Pleroma.{Repo, User}
   5
   6   schema "users" do
   7     field :bio, :string
   8     field :email, :string
   9     field :name, :string
  10     field :nickname, :string
  11     field :password_hash, :string
  12     field :password, :string, virtual: true
  13     field :password_confirmation, :string, virtual: true
  14     field :following, { :array, :string }, default: []
  15     field :ap_id, :string
  16
  17     timestamps()
  18   end
  19
  20   def ap_id(%User{nickname: nickname}) do
  21     "#{Pleroma.Web.base_url}/users/#{nickname}"
  22   end
  23
  24   def ap_followers(%User{} = user) do
  25     "#{ap_id(user)}/followers"
  26   end
  27
  28   def follow_changeset(struct, params \\ %{}) do
  29     struct
  30     |> cast(params, [:following])
  31     |> validate_required([:following])
  32   end
  33
  34   def register_changeset(struct, params \\ %{}) do
  35     changeset = struct
  36     |> cast(params, [:bio, :email, :name, :nickname, :password, :password_confirmation])
  37     |> validate_required([:bio, :email, :name, :nickname, :password, :password_confirmation])
  38     |> validate_confirmation(:password)
  39     |> unique_constraint(:email)
  40     |> unique_constraint(:nickname)
  41
  42     if changeset.valid? do
  43       hashed = Comeonin.Pbkdf2.hashpwsalt(changeset.changes[:password])
  44       ap_id = User.ap_id(%User{nickname: changeset.changes[:nickname]})
  45       followers = User.ap_followers(%User{nickname: changeset.changes[:nickname]})
  46       changeset
  47       |> put_change(:password_hash, hashed)
  48       |> put_change(:ap_id, ap_id)
  49       |> put_change(:following, [followers])
  50     else
  51       changeset
  52     end
  53   end
  54
  55   def follow(%User{} = follower, %User{} = followed) do
  56     ap_followers = User.ap_followers(followed)
  57     following = [ap_followers | follower.following]
  58     |> Enum.uniq
  59
  60     follower
  61     |> follow_changeset(%{following: following})
  62     |> Repo.update
  63   end
  64
  65   def unfollow(%User{} = follower, %User{} = followed) do
  66     ap_followers = User.ap_followers(followed)
  67     following = follower.following
  68     |> List.delete(ap_followers)
  69
  70     follower
  71     |> follow_changeset(%{following: following})
  72     |> Repo.update
  73   end
  74
  75   def following?(%User{} = follower, %User{} = followed) do
  76     Enum.member?(follower.following, User.ap_followers(followed))
  77   end
  78
  79   def get_cached_by_ap_id(ap_id) do
  80     ConCache.get_or_store(:users, "ap_id:#{ap_id}", fn() ->
  81       # Return false so the cache will store it.
  82       Repo.get_by(User, ap_id: ap_id) || false
  83     end)
  84   end
  85
  86   def get_cached_by_nickname(nickname) do
  87     ConCache.get_or_store(:users, "nickname:#{nickname}", fn() ->
  88       Repo.get_by(User, nickname: nickname) || false
  89     end)
  90   end
  91 end