git.squeep.com Git - akkoma/blob - lib/pleroma/user.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.User do
   6   use Ecto.Schema
   7
   8   import Ecto.{Changeset, Query}
   9   alias Pleroma.{Repo, User, Object, Web, Activity, Notification}
  10   alias Comeonin.Pbkdf2
  11   alias Pleroma.Formatter
  12   alias Pleroma.Web.CommonAPI.Utils, as: CommonUtils
  13   alias Pleroma.Web.{OStatus, Websub, OAuth}
  14   alias Pleroma.Web.ActivityPub.{Utils, ActivityPub}
  15
  16   require Logger
  17
  18   @type t :: %__MODULE__{}
  19
  20   @email_regex ~r/^[a-zA-Z0-9.!#$%&'*+\/=?^_`{|}~-]+@[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?(?:\.[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?)*$/
  21
  22   @strict_local_nickname_regex ~r/^[a-zA-Z\d]+$/
  23   @extended_local_nickname_regex ~r/^[a-zA-Z\d_-]+$/
  24
  25   schema "users" do
  26     field(:bio, :string)
  27     field(:email, :string)
  28     field(:name, :string)
  29     field(:nickname, :string)
  30     field(:password_hash, :string)
  31     field(:password, :string, virtual: true)
  32     field(:password_confirmation, :string, virtual: true)
  33     field(:following, {:array, :string}, default: [])
  34     field(:ap_id, :string)
  35     field(:avatar, :map)
  36     field(:local, :boolean, default: true)
  37     field(:follower_address, :string)
  38     field(:search_distance, :float, virtual: true)
  39     field(:tags, {:array, :string}, default: [])
  40     field(:last_refreshed_at, :naive_datetime)
  41     has_many(:notifications, Notification)
  42     embeds_one(:info, Pleroma.User.Info)
  43
  44     timestamps()
  45   end
  46
  47   def auth_active?(%User{} = user) do
  48     (user.info && !user.info.confirmation_pending) ||
  49       !Pleroma.Config.get([:instance, :account_activation_required])
  50   end
  51
  52   def remote_or_auth_active?(%User{} = user), do: !user.local || auth_active?(user)
  53
  54   def visible_for?(%User{} = user, for_user \\ nil) do
  55     User.remote_or_auth_active?(user) || (for_user && for_user.id == user.id) ||
  56       User.superuser?(for_user)
  57   end
  58
  59   def superuser?(nil), do: false
  60   def superuser?(%User{} = user), do: user.info && User.Info.superuser?(user.info)
  61
  62   def avatar_url(user) do
  63     case user.avatar do
  64       %{"url" => [%{"href" => href} | _]} -> href
  65       _ -> "#{Web.base_url()}/images/avi.png"
  66     end
  67   end
  68
  69   def banner_url(user) do
  70     case user.info.banner do
  71       %{"url" => [%{"href" => href} | _]} -> href
  72       _ -> "#{Web.base_url()}/images/banner.png"
  73     end
  74   end
  75
  76   def profile_url(%User{info: %{source_data: %{"url" => url}}}), do: url
  77   def profile_url(%User{ap_id: ap_id}), do: ap_id
  78   def profile_url(_), do: nil
  79
  80   def ap_id(%User{nickname: nickname}) do
  81     "#{Web.base_url()}/users/#{nickname}"
  82   end
  83
  84   def ap_followers(%User{} = user) do
  85     "#{ap_id(user)}/followers"
  86   end
  87
  88   def follow_changeset(struct, params \\ %{}) do
  89     struct
  90     |> cast(params, [:following])
  91     |> validate_required([:following])
  92   end
  93
  94   def user_info(%User{} = user) do
  95     oneself = if user.local, do: 1, else: 0
  96
  97     %{
  98       following_count: length(user.following) - oneself,
  99       note_count: user.info.note_count,
 100       follower_count: user.info.follower_count,
 101       locked: user.info.locked,
 102       confirmation_pending: user.info.confirmation_pending,
 103       default_scope: user.info.default_scope
 104     }
 105   end
 106
 107   def remote_user_creation(params) do
 108     params =
 109       params
 110       |> Map.put(:info, params[:info] || %{})
 111
 112     info_cng = User.Info.remote_user_creation(%User.Info{}, params[:info])
 113
 114     changes =
 115       %User{}
 116       |> cast(params, [:bio, :name, :ap_id, :nickname, :avatar])
 117       |> validate_required([:name, :ap_id])
 118       |> unique_constraint(:nickname)
 119       |> validate_format(:nickname, @email_regex)
 120       |> validate_length(:bio, max: 5000)
 121       |> validate_length(:name, max: 100)
 122       |> put_change(:local, false)
 123       |> put_embed(:info, info_cng)
 124
 125     if changes.valid? do
 126       case info_cng.changes[:source_data] do
 127         %{"followers" => followers} ->
 128           changes
 129           |> put_change(:follower_address, followers)
 130
 131         _ ->
 132           followers = User.ap_followers(%User{nickname: changes.changes[:nickname]})
 133
 134           changes
 135           |> put_change(:follower_address, followers)
 136       end
 137     else
 138       changes
 139     end
 140   end
 141
 142   def update_changeset(struct, params \\ %{}) do
 143     struct
 144     |> cast(params, [:bio, :name, :avatar])
 145     |> unique_constraint(:nickname)
 146     |> validate_format(:nickname, local_nickname_regex())
 147     |> validate_length(:bio, max: 5000)
 148     |> validate_length(:name, min: 1, max: 100)
 149   end
 150
 151   def upgrade_changeset(struct, params \\ %{}) do
 152     params =
 153       params
 154       |> Map.put(:last_refreshed_at, NaiveDateTime.utc_now())
 155
 156     info_cng =
 157       struct.info
 158       |> User.Info.user_upgrade(params[:info])
 159
 160     struct
 161     |> cast(params, [:bio, :name, :follower_address, :avatar, :last_refreshed_at])
 162     |> unique_constraint(:nickname)
 163     |> validate_format(:nickname, local_nickname_regex())
 164     |> validate_length(:bio, max: 5000)
 165     |> validate_length(:name, max: 100)
 166     |> put_embed(:info, info_cng)
 167   end
 168
 169   def password_update_changeset(struct, params) do
 170     changeset =
 171       struct
 172       |> cast(params, [:password, :password_confirmation])
 173       |> validate_required([:password, :password_confirmation])
 174       |> validate_confirmation(:password)
 175
 176     OAuth.Token.delete_user_tokens(struct)
 177     OAuth.Authorization.delete_user_authorizations(struct)
 178
 179     if changeset.valid? do
 180       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 181
 182       changeset
 183       |> put_change(:password_hash, hashed)
 184     else
 185       changeset
 186     end
 187   end
 188
 189   def reset_password(user, data) do
 190     update_and_set_cache(password_update_changeset(user, data))
 191   end
 192
 193   def register_changeset(struct, params \\ %{}, opts \\ []) do
 194     confirmation_status =
 195       if opts[:confirmed] || !Pleroma.Config.get([:instance, :account_activation_required]) do
 196         :confirmed
 197       else
 198         :unconfirmed
 199       end
 200
 201     info_change = User.Info.confirmation_changeset(%User.Info{}, confirmation_status)
 202
 203     changeset =
 204       struct
 205       |> cast(params, [:bio, :email, :name, :nickname, :password, :password_confirmation])
 206       |> validate_required([:email, :name, :nickname, :password, :password_confirmation])
 207       |> validate_confirmation(:password)
 208       |> unique_constraint(:email)
 209       |> unique_constraint(:nickname)
 210       |> validate_exclusion(:nickname, Pleroma.Config.get([Pleroma.User, :restricted_nicknames]))
 211       |> validate_format(:nickname, local_nickname_regex())
 212       |> validate_format(:email, @email_regex)
 213       |> validate_length(:bio, max: 1000)
 214       |> validate_length(:name, min: 1, max: 100)
 215       |> put_change(:info, info_change)
 216
 217     if changeset.valid? do
 218       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 219       ap_id = User.ap_id(%User{nickname: changeset.changes[:nickname]})
 220       followers = User.ap_followers(%User{nickname: changeset.changes[:nickname]})
 221
 222       changeset
 223       |> put_change(:password_hash, hashed)
 224       |> put_change(:ap_id, ap_id)
 225       |> put_change(:following, [followers])
 226       |> put_change(:follower_address, followers)
 227     else
 228       changeset
 229     end
 230   end
 231
 232   @doc "Inserts provided changeset, performs post-registration actions (confirmation email sending etc.)"
 233   def register(%Ecto.Changeset{} = changeset) do
 234     with {:ok, user} <- Repo.insert(changeset),
 235          {:ok, _} = try_send_confirmation_email(user) do
 236       {:ok, user}
 237     end
 238   end
 239
 240   def try_send_confirmation_email(%User{} = user) do
 241     if user.info.confirmation_pending &&
 242          Pleroma.Config.get([:instance, :account_activation_required]) do
 243       user
 244       |> Pleroma.UserEmail.account_confirmation_email()
 245       |> Pleroma.Mailer.deliver()
 246     else
 247       {:ok, :noop}
 248     end
 249   end
 250
 251   def needs_update?(%User{local: true}), do: false
 252
 253   def needs_update?(%User{local: false, last_refreshed_at: nil}), do: true
 254
 255   def needs_update?(%User{local: false} = user) do
 256     NaiveDateTime.diff(NaiveDateTime.utc_now(), user.last_refreshed_at) >= 86400
 257   end
 258
 259   def needs_update?(_), do: true
 260
 261   def maybe_direct_follow(%User{} = follower, %User{local: true, info: %{locked: true}}) do
 262     {:ok, follower}
 263   end
 264
 265   def maybe_direct_follow(%User{} = follower, %User{local: true} = followed) do
 266     follow(follower, followed)
 267   end
 268
 269   def maybe_direct_follow(%User{} = follower, %User{} = followed) do
 270     if not User.ap_enabled?(followed) do
 271       follow(follower, followed)
 272     else
 273       {:ok, follower}
 274     end
 275   end
 276
 277   def maybe_follow(%User{} = follower, %User{info: _info} = followed) do
 278     if not following?(follower, followed) do
 279       follow(follower, followed)
 280     else
 281       {:ok, follower}
 282     end
 283   end
 284
 285   def follow(%User{} = follower, %User{info: info} = followed) do
 286     user_config = Application.get_env(:pleroma, :user)
 287     deny_follow_blocked = Keyword.get(user_config, :deny_follow_blocked)
 288
 289     ap_followers = followed.follower_address
 290
 291     cond do
 292       following?(follower, followed) or info.deactivated ->
 293         {:error, "Could not follow user: #{followed.nickname} is already on your list."}
 294
 295       deny_follow_blocked and blocks?(followed, follower) ->
 296         {:error, "Could not follow user: #{followed.nickname} blocked you."}
 297
 298       true ->
 299         if !followed.local && follower.local && !ap_enabled?(followed) do
 300           Websub.subscribe(follower, followed)
 301         end
 302
 303         following =
 304           [ap_followers | follower.following]
 305           |> Enum.uniq()
 306
 307         follower =
 308           follower
 309           |> follow_changeset(%{following: following})
 310           |> update_and_set_cache
 311
 312         {:ok, _} = update_follower_count(followed)
 313
 314         follower
 315     end
 316   end
 317
 318   def unfollow(%User{} = follower, %User{} = followed) do
 319     ap_followers = followed.follower_address
 320
 321     if following?(follower, followed) and follower.ap_id != followed.ap_id do
 322       following =
 323         follower.following
 324         |> List.delete(ap_followers)
 325
 326       {:ok, follower} =
 327         follower
 328         |> follow_changeset(%{following: following})
 329         |> update_and_set_cache
 330
 331       {:ok, followed} = update_follower_count(followed)
 332
 333       {:ok, follower, Utils.fetch_latest_follow(follower, followed)}
 334     else
 335       {:error, "Not subscribed!"}
 336     end
 337   end
 338
 339   @spec following?(User.t(), User.t()) :: boolean
 340   def following?(%User{} = follower, %User{} = followed) do
 341     Enum.member?(follower.following, followed.follower_address)
 342   end
 343
 344   def follow_import(%User{} = follower, followed_identifiers)
 345       when is_list(followed_identifiers) do
 346     Enum.map(
 347       followed_identifiers,
 348       fn followed_identifier ->
 349         with %User{} = followed <- get_or_fetch(followed_identifier),
 350              {:ok, follower} <- maybe_direct_follow(follower, followed),
 351              {:ok, _} <- ActivityPub.follow(follower, followed) do
 352           followed
 353         else
 354           err ->
 355             Logger.debug("follow_import failed for #{followed_identifier} with: #{inspect(err)}")
 356             err
 357         end
 358       end
 359     )
 360   end
 361
 362   def locked?(%User{} = user) do
 363     user.info.locked || false
 364   end
 365
 366   def get_by_ap_id(ap_id) do
 367     Repo.get_by(User, ap_id: ap_id)
 368   end
 369
 370   def update_and_set_cache(changeset) do
 371     with {:ok, user} <- Repo.update(changeset) do
 372       Cachex.put(:user_cache, "ap_id:#{user.ap_id}", user)
 373       Cachex.put(:user_cache, "nickname:#{user.nickname}", user)
 374       Cachex.put(:user_cache, "user_info:#{user.id}", user_info(user))
 375       {:ok, user}
 376     else
 377       e -> e
 378     end
 379   end
 380
 381   def invalidate_cache(user) do
 382     Cachex.del(:user_cache, "ap_id:#{user.ap_id}")
 383     Cachex.del(:user_cache, "nickname:#{user.nickname}")
 384     Cachex.del(:user_cache, "user_info:#{user.id}")
 385   end
 386
 387   def get_cached_by_ap_id(ap_id) do
 388     key = "ap_id:#{ap_id}"
 389     Cachex.fetch!(:user_cache, key, fn _ -> get_by_ap_id(ap_id) end)
 390   end
 391
 392   def get_cached_by_nickname(nickname) do
 393     key = "nickname:#{nickname}"
 394     Cachex.fetch!(:user_cache, key, fn _ -> get_or_fetch_by_nickname(nickname) end)
 395   end
 396
 397   def get_by_nickname(nickname) do
 398     Repo.get_by(User, nickname: nickname) ||
 399       if Regex.match?(~r(@#{Pleroma.Web.Endpoint.host()})i, nickname) do
 400         [local_nickname, _] = String.split(nickname, "@")
 401         Repo.get_by(User, nickname: local_nickname)
 402       end
 403   end
 404
 405   def get_by_nickname_or_email(nickname_or_email) do
 406     case user = Repo.get_by(User, nickname: nickname_or_email) do
 407       %User{} -> user
 408       nil -> Repo.get_by(User, email: nickname_or_email)
 409     end
 410   end
 411
 412   def get_cached_user_info(user) do
 413     key = "user_info:#{user.id}"
 414     Cachex.fetch!(:user_cache, key, fn _ -> user_info(user) end)
 415   end
 416
 417   def fetch_by_nickname(nickname) do
 418     ap_try = ActivityPub.make_user_from_nickname(nickname)
 419
 420     case ap_try do
 421       {:ok, user} -> {:ok, user}
 422       _ -> OStatus.make_user(nickname)
 423     end
 424   end
 425
 426   def get_or_fetch_by_nickname(nickname) do
 427     with %User{} = user <- get_by_nickname(nickname) do
 428       user
 429     else
 430       _e ->
 431         with [_nick, _domain] <- String.split(nickname, "@"),
 432              {:ok, user} <- fetch_by_nickname(nickname) do
 433           user
 434         else
 435           _e -> nil
 436         end
 437     end
 438   end
 439
 440   def get_followers_query(%User{id: id, follower_address: follower_address}) do
 441     from(
 442       u in User,
 443       where: fragment("? <@ ?", ^[follower_address], u.following),
 444       where: u.id != ^id
 445     )
 446   end
 447
 448   def get_followers(user) do
 449     q = get_followers_query(user)
 450
 451     {:ok, Repo.all(q)}
 452   end
 453
 454   def get_friends_query(%User{id: id, following: following}) do
 455     from(
 456       u in User,
 457       where: u.follower_address in ^following,
 458       where: u.id != ^id
 459     )
 460   end
 461
 462   def get_friends(user) do
 463     q = get_friends_query(user)
 464
 465     {:ok, Repo.all(q)}
 466   end
 467
 468   def get_follow_requests_query(%User{} = user) do
 469     from(
 470       a in Activity,
 471       where:
 472         fragment(
 473           "? ->> 'type' = 'Follow'",
 474           a.data
 475         ),
 476       where:
 477         fragment(
 478           "? ->> 'state' = 'pending'",
 479           a.data
 480         ),
 481       where:
 482         fragment(
 483           "? @> ?",
 484           a.data,
 485           ^%{"object" => user.ap_id}
 486         )
 487     )
 488   end
 489
 490   def get_follow_requests(%User{} = user) do
 491     q = get_follow_requests_query(user)
 492     reqs = Repo.all(q)
 493
 494     users =
 495       Enum.map(reqs, fn req -> req.actor end)
 496       |> Enum.uniq()
 497       |> Enum.map(fn ap_id -> get_by_ap_id(ap_id) end)
 498       |> Enum.filter(fn u -> !following?(u, user) end)
 499
 500     {:ok, users}
 501   end
 502
 503   def increase_note_count(%User{} = user) do
 504     info_cng = User.Info.add_to_note_count(user.info, 1)
 505
 506     cng =
 507       change(user)
 508       |> put_embed(:info, info_cng)
 509
 510     update_and_set_cache(cng)
 511   end
 512
 513   def decrease_note_count(%User{} = user) do
 514     info_cng = User.Info.add_to_note_count(user.info, -1)
 515
 516     cng =
 517       change(user)
 518       |> put_embed(:info, info_cng)
 519
 520     update_and_set_cache(cng)
 521   end
 522
 523   def update_note_count(%User{} = user) do
 524     note_count_query =
 525       from(
 526         a in Object,
 527         where: fragment("?->>'actor' = ? and ?->>'type' = 'Note'", a.data, ^user.ap_id, a.data),
 528         select: count(a.id)
 529       )
 530
 531     note_count = Repo.one(note_count_query)
 532
 533     info_cng = User.Info.set_note_count(user.info, note_count)
 534
 535     cng =
 536       change(user)
 537       |> put_embed(:info, info_cng)
 538
 539     update_and_set_cache(cng)
 540   end
 541
 542   def update_follower_count(%User{} = user) do
 543     follower_count_query =
 544       from(
 545         u in User,
 546         where: ^user.follower_address in u.following,
 547         where: u.id != ^user.id,
 548         select: count(u.id)
 549       )
 550
 551     follower_count = Repo.one(follower_count_query)
 552
 553     info_cng =
 554       user.info
 555       |> User.Info.set_follower_count(follower_count)
 556
 557     cng =
 558       change(user)
 559       |> put_embed(:info, info_cng)
 560
 561     update_and_set_cache(cng)
 562   end
 563
 564   def get_users_from_set_query(ap_ids, false) do
 565     from(
 566       u in User,
 567       where: u.ap_id in ^ap_ids
 568     )
 569   end
 570
 571   def get_users_from_set_query(ap_ids, true) do
 572     query = get_users_from_set_query(ap_ids, false)
 573
 574     from(
 575       u in query,
 576       where: u.local == true
 577     )
 578   end
 579
 580   def get_users_from_set(ap_ids, local_only \\ true) do
 581     get_users_from_set_query(ap_ids, local_only)
 582     |> Repo.all()
 583   end
 584
 585   def get_recipients_from_activity(%Activity{recipients: to}) do
 586     query =
 587       from(
 588         u in User,
 589         where: u.ap_id in ^to,
 590         or_where: fragment("? && ?", u.following, ^to)
 591       )
 592
 593     query = from(u in query, where: u.local == true)
 594
 595     Repo.all(query)
 596   end
 597
 598   def search(query, resolve \\ false) do
 599     # strip the beginning @ off if there is a query
 600     query = String.trim_leading(query, "@")
 601
 602     if resolve do
 603       User.get_or_fetch_by_nickname(query)
 604     end
 605
 606     inner =
 607       from(
 608         u in User,
 609         select_merge: %{
 610           search_distance:
 611             fragment(
 612               "? <-> (? || ?)",
 613               ^query,
 614               u.nickname,
 615               u.name
 616             )
 617         },
 618         where: not is_nil(u.nickname)
 619       )
 620
 621     q =
 622       from(
 623         s in subquery(inner),
 624         order_by: s.search_distance,
 625         limit: 20
 626       )
 627
 628     Repo.all(q)
 629   end
 630
 631   def blocks_import(%User{} = blocker, blocked_identifiers) when is_list(blocked_identifiers) do
 632     Enum.map(
 633       blocked_identifiers,
 634       fn blocked_identifier ->
 635         with %User{} = blocked <- get_or_fetch(blocked_identifier),
 636              {:ok, blocker} <- block(blocker, blocked),
 637              {:ok, _} <- ActivityPub.block(blocker, blocked) do
 638           blocked
 639         else
 640           err ->
 641             Logger.debug("blocks_import failed for #{blocked_identifier} with: #{inspect(err)}")
 642             err
 643         end
 644       end
 645     )
 646   end
 647
 648   def block(blocker, %User{ap_id: ap_id} = blocked) do
 649     # sever any follow relationships to prevent leaks per activitypub (Pleroma issue #213)
 650     blocker =
 651       if following?(blocker, blocked) do
 652         {:ok, blocker, _} = unfollow(blocker, blocked)
 653         blocker
 654       else
 655         blocker
 656       end
 657
 658     if following?(blocked, blocker) do
 659       unfollow(blocked, blocker)
 660     end
 661
 662     info_cng =
 663       blocker.info
 664       |> User.Info.add_to_block(ap_id)
 665
 666     cng =
 667       change(blocker)
 668       |> put_embed(:info, info_cng)
 669
 670     update_and_set_cache(cng)
 671   end
 672
 673   # helper to handle the block given only an actor's AP id
 674   def block(blocker, %{ap_id: ap_id}) do
 675     block(blocker, User.get_by_ap_id(ap_id))
 676   end
 677
 678   def unblock(blocker, %{ap_id: ap_id}) do
 679     info_cng =
 680       blocker.info
 681       |> User.Info.remove_from_block(ap_id)
 682
 683     cng =
 684       change(blocker)
 685       |> put_embed(:info, info_cng)
 686
 687     update_and_set_cache(cng)
 688   end
 689
 690   def blocks?(user, %{ap_id: ap_id}) do
 691     blocks = user.info.blocks
 692     domain_blocks = user.info.domain_blocks
 693     %{host: host} = URI.parse(ap_id)
 694
 695     Enum.member?(blocks, ap_id) ||
 696       Enum.any?(domain_blocks, fn domain ->
 697         host == domain
 698       end)
 699   end
 700
 701   def blocked_users(user),
 702     do: Repo.all(from(u in User, where: u.ap_id in ^user.info.blocks))
 703
 704   def block_domain(user, domain) do
 705     info_cng =
 706       user.info
 707       |> User.Info.add_to_domain_block(domain)
 708
 709     cng =
 710       change(user)
 711       |> put_embed(:info, info_cng)
 712
 713     update_and_set_cache(cng)
 714   end
 715
 716   def unblock_domain(user, domain) do
 717     info_cng =
 718       user.info
 719       |> User.Info.remove_from_domain_block(domain)
 720
 721     cng =
 722       change(user)
 723       |> put_embed(:info, info_cng)
 724
 725     update_and_set_cache(cng)
 726   end
 727
 728   def local_user_query() do
 729     from(
 730       u in User,
 731       where: u.local == true,
 732       where: not is_nil(u.nickname)
 733     )
 734   end
 735
 736   def moderator_user_query() do
 737     from(
 738       u in User,
 739       where: u.local == true,
 740       where: fragment("?->'is_moderator' @> 'true'", u.info)
 741     )
 742   end
 743
 744   def deactivate(%User{} = user, status \\ true) do
 745     info_cng = User.Info.set_activation_status(user.info, status)
 746
 747     cng =
 748       change(user)
 749       |> put_embed(:info, info_cng)
 750
 751     update_and_set_cache(cng)
 752   end
 753
 754   def delete(%User{} = user) do
 755     {:ok, user} = User.deactivate(user)
 756
 757     # Remove all relationships
 758     {:ok, followers} = User.get_followers(user)
 759
 760     followers
 761     |> Enum.each(fn follower -> User.unfollow(follower, user) end)
 762
 763     {:ok, friends} = User.get_friends(user)
 764
 765     friends
 766     |> Enum.each(fn followed -> User.unfollow(user, followed) end)
 767
 768     query = from(a in Activity, where: a.actor == ^user.ap_id)
 769
 770     Repo.all(query)
 771     |> Enum.each(fn activity ->
 772       case activity.data["type"] do
 773         "Create" ->
 774           ActivityPub.delete(Object.normalize(activity.data["object"]))
 775
 776         # TODO: Do something with likes, follows, repeats.
 777         _ ->
 778           "Doing nothing"
 779       end
 780     end)
 781
 782     {:ok, user}
 783   end
 784
 785   def html_filter_policy(%User{info: %{no_rich_text: true}}) do
 786     Pleroma.HTML.Scrubber.TwitterText
 787   end
 788
 789   @default_scrubbers Pleroma.Config.get([:markup, :scrub_policy])
 790
 791   def html_filter_policy(_), do: @default_scrubbers
 792
 793   def get_or_fetch_by_ap_id(ap_id) do
 794     user = get_by_ap_id(ap_id)
 795
 796     if !is_nil(user) and !User.needs_update?(user) do
 797       user
 798     else
 799       ap_try = ActivityPub.make_user_from_ap_id(ap_id)
 800
 801       case ap_try do
 802         {:ok, user} ->
 803           user
 804
 805         _ ->
 806           case OStatus.make_user(ap_id) do
 807             {:ok, user} -> user
 808             _ -> {:error, "Could not fetch by AP id"}
 809           end
 810       end
 811     end
 812   end
 813
 814   def get_or_create_instance_user do
 815     relay_uri = "#{Pleroma.Web.Endpoint.url()}/relay"
 816
 817     if user = get_by_ap_id(relay_uri) do
 818       user
 819     else
 820       changes =
 821         %User{info: %User.Info{}}
 822         |> cast(%{}, [:ap_id, :nickname, :local])
 823         |> put_change(:ap_id, relay_uri)
 824         |> put_change(:nickname, nil)
 825         |> put_change(:local, true)
 826         |> put_change(:follower_address, relay_uri <> "/followers")
 827
 828       {:ok, user} = Repo.insert(changes)
 829       user
 830     end
 831   end
 832
 833   # AP style
 834   def public_key_from_info(%{
 835         source_data: %{"publicKey" => %{"publicKeyPem" => public_key_pem}}
 836       }) do
 837     key =
 838       public_key_pem
 839       |> :public_key.pem_decode()
 840       |> hd()
 841       |> :public_key.pem_entry_decode()
 842
 843     {:ok, key}
 844   end
 845
 846   # OStatus Magic Key
 847   def public_key_from_info(%{magic_key: magic_key}) do
 848     {:ok, Pleroma.Web.Salmon.decode_key(magic_key)}
 849   end
 850
 851   def get_public_key_for_ap_id(ap_id) do
 852     with %User{} = user <- get_or_fetch_by_ap_id(ap_id),
 853          {:ok, public_key} <- public_key_from_info(user.info) do
 854       {:ok, public_key}
 855     else
 856       _ -> :error
 857     end
 858   end
 859
 860   defp blank?(""), do: nil
 861   defp blank?(n), do: n
 862
 863   def insert_or_update_user(data) do
 864     data =
 865       data
 866       |> Map.put(:name, blank?(data[:name]) || data[:nickname])
 867
 868     cs = User.remote_user_creation(data)
 869
 870     Repo.insert(cs, on_conflict: :replace_all, conflict_target: :nickname)
 871   end
 872
 873   def ap_enabled?(%User{local: true}), do: true
 874   def ap_enabled?(%User{info: info}), do: info.ap_enabled
 875   def ap_enabled?(_), do: false
 876
 877   @doc "Gets or fetch a user by uri or nickname."
 878   @spec get_or_fetch(String.t()) :: User.t()
 879   def get_or_fetch("http" <> _host = uri), do: get_or_fetch_by_ap_id(uri)
 880   def get_or_fetch(nickname), do: get_or_fetch_by_nickname(nickname)
 881
 882   # wait a period of time and return newest version of the User structs
 883   # this is because we have synchronous follow APIs and need to simulate them
 884   # with an async handshake
 885   def wait_and_refresh(_, %User{local: true} = a, %User{local: true} = b) do
 886     with %User{} = a <- Repo.get(User, a.id),
 887          %User{} = b <- Repo.get(User, b.id) do
 888       {:ok, a, b}
 889     else
 890       _e ->
 891         :error
 892     end
 893   end
 894
 895   def wait_and_refresh(timeout, %User{} = a, %User{} = b) do
 896     with :ok <- :timer.sleep(timeout),
 897          %User{} = a <- Repo.get(User, a.id),
 898          %User{} = b <- Repo.get(User, b.id) do
 899       {:ok, a, b}
 900     else
 901       _e ->
 902         :error
 903     end
 904   end
 905
 906   def parse_bio(bio, user \\ %User{info: %{source_data: %{}}})
 907   def parse_bio(nil, _user), do: ""
 908   def parse_bio(bio, _user) when bio == "", do: bio
 909
 910   def parse_bio(bio, user) do
 911     mentions = Formatter.parse_mentions(bio)
 912     tags = Formatter.parse_tags(bio)
 913
 914     emoji =
 915       (user.info.source_data["tag"] || [])
 916       |> Enum.filter(fn %{"type" => t} -> t == "Emoji" end)
 917       |> Enum.map(fn %{"icon" => %{"url" => url}, "name" => name} ->
 918         {String.trim(name, ":"), url}
 919       end)
 920
 921     bio
 922     |> CommonUtils.format_input(mentions, tags, "text/plain")
 923     |> Formatter.emojify(emoji)
 924   end
 925
 926   def tag(user_identifiers, tags) when is_list(user_identifiers) do
 927     Repo.transaction(fn ->
 928       for user_identifier <- user_identifiers, do: tag(user_identifier, tags)
 929     end)
 930   end
 931
 932   def tag(nickname, tags) when is_binary(nickname),
 933     do: tag(User.get_by_nickname(nickname), tags)
 934
 935   def tag(%User{} = user, tags),
 936     do: update_tags(user, Enum.uniq((user.tags || []) ++ normalize_tags(tags)))
 937
 938   def untag(user_identifiers, tags) when is_list(user_identifiers) do
 939     Repo.transaction(fn ->
 940       for user_identifier <- user_identifiers, do: untag(user_identifier, tags)
 941     end)
 942   end
 943
 944   def untag(nickname, tags) when is_binary(nickname),
 945     do: untag(User.get_by_nickname(nickname), tags)
 946
 947   def untag(%User{} = user, tags),
 948     do: update_tags(user, (user.tags || []) -- normalize_tags(tags))
 949
 950   defp update_tags(%User{} = user, new_tags) do
 951     {:ok, updated_user} =
 952       user
 953       |> change(%{tags: new_tags})
 954       |> Repo.update()
 955
 956     updated_user
 957   end
 958
 959   defp normalize_tags(tags) do
 960     [tags]
 961     |> List.flatten()
 962     |> Enum.map(&String.downcase(&1))
 963   end
 964
 965   defp local_nickname_regex() do
 966     if Pleroma.Config.get([:instance, :extended_nickname_format]) do
 967       @extended_local_nickname_regex
 968     else
 969       @strict_local_nickname_regex
 970     end
 971   end
 972 end