git.squeep.com Git - akkoma/blob - lib/pleroma/user.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.User do
   6   use Ecto.Schema
   7
   8   import Ecto.{Changeset, Query}
   9   alias Pleroma.{Repo, User, Object, Web, Activity, Notification}
  10   alias Comeonin.Pbkdf2
  11   alias Pleroma.Formatter
  12   alias Pleroma.Web.CommonAPI.Utils, as: CommonUtils
  13   alias Pleroma.Web.{OStatus, Websub, OAuth}
  14   alias Pleroma.Web.ActivityPub.{Utils, ActivityPub}
  15
  16   require Logger
  17
  18   @type t :: %__MODULE__{}
  19
  20   @email_regex ~r/^[a-zA-Z0-9.!#$%&'*+\/=?^_`{|}~-]+@[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?(?:\.[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?)*$/
  21
  22   @strict_local_nickname_regex ~r/^[a-zA-Z\d]+$/
  23   @extended_local_nickname_regex ~r/^[a-zA-Z\d_-]+$/
  24
  25   schema "users" do
  26     field(:bio, :string)
  27     field(:email, :string)
  28     field(:name, :string)
  29     field(:nickname, :string)
  30     field(:password_hash, :string)
  31     field(:password, :string, virtual: true)
  32     field(:password_confirmation, :string, virtual: true)
  33     field(:following, {:array, :string}, default: [])
  34     field(:ap_id, :string)
  35     field(:avatar, :map)
  36     field(:local, :boolean, default: true)
  37     field(:follower_address, :string)
  38     field(:search_rank, :float, virtual: true)
  39     field(:tags, {:array, :string}, default: [])
  40     field(:last_refreshed_at, :naive_datetime)
  41     has_many(:notifications, Notification)
  42     embeds_one(:info, Pleroma.User.Info)
  43
  44     timestamps()
  45   end
  46
  47   def auth_active?(%User{local: false}), do: true
  48
  49   def auth_active?(%User{info: %User.Info{confirmation_pending: false}}), do: true
  50
  51   def auth_active?(%User{info: %User.Info{confirmation_pending: true}}),
  52     do: !Pleroma.Config.get([:instance, :account_activation_required])
  53
  54   def auth_active?(_), do: false
  55
  56   def visible_for?(user, for_user \\ nil)
  57
  58   def visible_for?(%User{id: user_id}, %User{id: for_id}) when user_id == for_id, do: true
  59
  60   def visible_for?(%User{} = user, for_user) do
  61     auth_active?(user) || superuser?(for_user)
  62   end
  63
  64   def visible_for?(_, _), do: false
  65
  66   def superuser?(%User{local: true, info: %User.Info{is_admin: true}}), do: true
  67   def superuser?(%User{local: true, info: %User.Info{is_moderator: true}}), do: true
  68   def superuser?(_), do: false
  69
  70   def avatar_url(user) do
  71     case user.avatar do
  72       %{"url" => [%{"href" => href} | _]} -> href
  73       _ -> "#{Web.base_url()}/images/avi.png"
  74     end
  75   end
  76
  77   def banner_url(user) do
  78     case user.info.banner do
  79       %{"url" => [%{"href" => href} | _]} -> href
  80       _ -> "#{Web.base_url()}/images/banner.png"
  81     end
  82   end
  83
  84   def profile_url(%User{info: %{source_data: %{"url" => url}}}), do: url
  85   def profile_url(%User{ap_id: ap_id}), do: ap_id
  86   def profile_url(_), do: nil
  87
  88   def ap_id(%User{nickname: nickname}) do
  89     "#{Web.base_url()}/users/#{nickname}"
  90   end
  91
  92   def ap_followers(%User{} = user) do
  93     "#{ap_id(user)}/followers"
  94   end
  95
  96   def follow_changeset(struct, params \\ %{}) do
  97     struct
  98     |> cast(params, [:following])
  99     |> validate_required([:following])
 100   end
 101
 102   def user_info(%User{} = user) do
 103     oneself = if user.local, do: 1, else: 0
 104
 105     %{
 106       following_count: length(user.following) - oneself,
 107       note_count: user.info.note_count,
 108       follower_count: user.info.follower_count,
 109       locked: user.info.locked,
 110       confirmation_pending: user.info.confirmation_pending,
 111       default_scope: user.info.default_scope
 112     }
 113   end
 114
 115   def remote_user_creation(params) do
 116     params =
 117       params
 118       |> Map.put(:info, params[:info] || %{})
 119
 120     info_cng = User.Info.remote_user_creation(%User.Info{}, params[:info])
 121
 122     changes =
 123       %User{}
 124       |> cast(params, [:bio, :name, :ap_id, :nickname, :avatar])
 125       |> validate_required([:name, :ap_id])
 126       |> unique_constraint(:nickname)
 127       |> validate_format(:nickname, @email_regex)
 128       |> validate_length(:bio, max: 5000)
 129       |> validate_length(:name, max: 100)
 130       |> put_change(:local, false)
 131       |> put_embed(:info, info_cng)
 132
 133     if changes.valid? do
 134       case info_cng.changes[:source_data] do
 135         %{"followers" => followers} ->
 136           changes
 137           |> put_change(:follower_address, followers)
 138
 139         _ ->
 140           followers = User.ap_followers(%User{nickname: changes.changes[:nickname]})
 141
 142           changes
 143           |> put_change(:follower_address, followers)
 144       end
 145     else
 146       changes
 147     end
 148   end
 149
 150   def update_changeset(struct, params \\ %{}) do
 151     struct
 152     |> cast(params, [:bio, :name, :avatar])
 153     |> unique_constraint(:nickname)
 154     |> validate_format(:nickname, local_nickname_regex())
 155     |> validate_length(:bio, max: 5000)
 156     |> validate_length(:name, min: 1, max: 100)
 157   end
 158
 159   def upgrade_changeset(struct, params \\ %{}) do
 160     params =
 161       params
 162       |> Map.put(:last_refreshed_at, NaiveDateTime.utc_now())
 163
 164     info_cng =
 165       struct.info
 166       |> User.Info.user_upgrade(params[:info])
 167
 168     struct
 169     |> cast(params, [:bio, :name, :follower_address, :avatar, :last_refreshed_at])
 170     |> unique_constraint(:nickname)
 171     |> validate_format(:nickname, local_nickname_regex())
 172     |> validate_length(:bio, max: 5000)
 173     |> validate_length(:name, max: 100)
 174     |> put_embed(:info, info_cng)
 175   end
 176
 177   def password_update_changeset(struct, params) do
 178     changeset =
 179       struct
 180       |> cast(params, [:password, :password_confirmation])
 181       |> validate_required([:password, :password_confirmation])
 182       |> validate_confirmation(:password)
 183
 184     OAuth.Token.delete_user_tokens(struct)
 185     OAuth.Authorization.delete_user_authorizations(struct)
 186
 187     if changeset.valid? do
 188       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 189
 190       changeset
 191       |> put_change(:password_hash, hashed)
 192     else
 193       changeset
 194     end
 195   end
 196
 197   def reset_password(user, data) do
 198     update_and_set_cache(password_update_changeset(user, data))
 199   end
 200
 201   def register_changeset(struct, params \\ %{}, opts \\ []) do
 202     confirmation_status =
 203       if opts[:confirmed] || !Pleroma.Config.get([:instance, :account_activation_required]) do
 204         :confirmed
 205       else
 206         :unconfirmed
 207       end
 208
 209     info_change = User.Info.confirmation_changeset(%User.Info{}, confirmation_status)
 210
 211     changeset =
 212       struct
 213       |> cast(params, [:bio, :email, :name, :nickname, :password, :password_confirmation])
 214       |> validate_required([:email, :name, :nickname, :password, :password_confirmation])
 215       |> validate_confirmation(:password)
 216       |> unique_constraint(:email)
 217       |> unique_constraint(:nickname)
 218       |> validate_exclusion(:nickname, Pleroma.Config.get([Pleroma.User, :restricted_nicknames]))
 219       |> validate_format(:nickname, local_nickname_regex())
 220       |> validate_format(:email, @email_regex)
 221       |> validate_length(:bio, max: 1000)
 222       |> validate_length(:name, min: 1, max: 100)
 223       |> put_change(:info, info_change)
 224
 225     if changeset.valid? do
 226       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 227       ap_id = User.ap_id(%User{nickname: changeset.changes[:nickname]})
 228       followers = User.ap_followers(%User{nickname: changeset.changes[:nickname]})
 229
 230       changeset
 231       |> put_change(:password_hash, hashed)
 232       |> put_change(:ap_id, ap_id)
 233       |> put_change(:following, [followers])
 234       |> put_change(:follower_address, followers)
 235     else
 236       changeset
 237     end
 238   end
 239
 240   defp autofollow_users(user) do
 241     candidates = Pleroma.Config.get([:instance, :autofollowed_nicknames])
 242
 243     autofollowed_users =
 244       from(u in User,
 245         where: u.local == true,
 246         where: u.nickname in ^candidates
 247       )
 248       |> Repo.all()
 249
 250     follow_all(user, autofollowed_users)
 251   end
 252
 253   @doc "Inserts provided changeset, performs post-registration actions (confirmation email sending etc.)"
 254   def register(%Ecto.Changeset{} = changeset) do
 255     with {:ok, user} <- Repo.insert(changeset),
 256          {:ok, _} <- try_send_confirmation_email(user),
 257          {:ok, user} <- autofollow_users(user) do
 258       {:ok, user}
 259     end
 260   end
 261
 262   def try_send_confirmation_email(%User{} = user) do
 263     if user.info.confirmation_pending &&
 264          Pleroma.Config.get([:instance, :account_activation_required]) do
 265       user
 266       |> Pleroma.UserEmail.account_confirmation_email()
 267       |> Pleroma.Mailer.deliver()
 268     else
 269       {:ok, :noop}
 270     end
 271   end
 272
 273   def needs_update?(%User{local: true}), do: false
 274
 275   def needs_update?(%User{local: false, last_refreshed_at: nil}), do: true
 276
 277   def needs_update?(%User{local: false} = user) do
 278     NaiveDateTime.diff(NaiveDateTime.utc_now(), user.last_refreshed_at) >= 86400
 279   end
 280
 281   def needs_update?(_), do: true
 282
 283   def maybe_direct_follow(%User{} = follower, %User{local: true, info: %{locked: true}}) do
 284     {:ok, follower}
 285   end
 286
 287   def maybe_direct_follow(%User{} = follower, %User{local: true} = followed) do
 288     follow(follower, followed)
 289   end
 290
 291   def maybe_direct_follow(%User{} = follower, %User{} = followed) do
 292     if not User.ap_enabled?(followed) do
 293       follow(follower, followed)
 294     else
 295       {:ok, follower}
 296     end
 297   end
 298
 299   def maybe_follow(%User{} = follower, %User{info: _info} = followed) do
 300     if not following?(follower, followed) do
 301       follow(follower, followed)
 302     else
 303       {:ok, follower}
 304     end
 305   end
 306
 307   @doc "A mass follow for local users. Ignores blocks and has no side effects"
 308   @spec follow_all(User.t(), list(User.t())) :: {atom(), User.t()}
 309   def follow_all(follower, followeds) do
 310     following =
 311       (follower.following ++ Enum.map(followeds, fn %{follower_address: fa} -> fa end))
 312       |> Enum.uniq()
 313
 314     {:ok, follower} =
 315       follower
 316       |> follow_changeset(%{following: following})
 317       |> update_and_set_cache
 318
 319     Enum.each(followeds, fn followed ->
 320       update_follower_count(followed)
 321     end)
 322
 323     {:ok, follower}
 324   end
 325
 326   def follow(%User{} = follower, %User{info: info} = followed) do
 327     user_config = Application.get_env(:pleroma, :user)
 328     deny_follow_blocked = Keyword.get(user_config, :deny_follow_blocked)
 329
 330     ap_followers = followed.follower_address
 331
 332     cond do
 333       following?(follower, followed) or info.deactivated ->
 334         {:error, "Could not follow user: #{followed.nickname} is already on your list."}
 335
 336       deny_follow_blocked and blocks?(followed, follower) ->
 337         {:error, "Could not follow user: #{followed.nickname} blocked you."}
 338
 339       true ->
 340         if !followed.local && follower.local && !ap_enabled?(followed) do
 341           Websub.subscribe(follower, followed)
 342         end
 343
 344         following =
 345           [ap_followers | follower.following]
 346           |> Enum.uniq()
 347
 348         follower =
 349           follower
 350           |> follow_changeset(%{following: following})
 351           |> update_and_set_cache
 352
 353         {:ok, _} = update_follower_count(followed)
 354
 355         follower
 356     end
 357   end
 358
 359   def unfollow(%User{} = follower, %User{} = followed) do
 360     ap_followers = followed.follower_address
 361
 362     if following?(follower, followed) and follower.ap_id != followed.ap_id do
 363       following =
 364         follower.following
 365         |> List.delete(ap_followers)
 366
 367       {:ok, follower} =
 368         follower
 369         |> follow_changeset(%{following: following})
 370         |> update_and_set_cache
 371
 372       {:ok, followed} = update_follower_count(followed)
 373
 374       {:ok, follower, Utils.fetch_latest_follow(follower, followed)}
 375     else
 376       {:error, "Not subscribed!"}
 377     end
 378   end
 379
 380   @spec following?(User.t(), User.t()) :: boolean
 381   def following?(%User{} = follower, %User{} = followed) do
 382     Enum.member?(follower.following, followed.follower_address)
 383   end
 384
 385   def follow_import(%User{} = follower, followed_identifiers)
 386       when is_list(followed_identifiers) do
 387     Enum.map(
 388       followed_identifiers,
 389       fn followed_identifier ->
 390         with %User{} = followed <- get_or_fetch(followed_identifier),
 391              {:ok, follower} <- maybe_direct_follow(follower, followed),
 392              {:ok, _} <- ActivityPub.follow(follower, followed) do
 393           followed
 394         else
 395           err ->
 396             Logger.debug("follow_import failed for #{followed_identifier} with: #{inspect(err)}")
 397             err
 398         end
 399       end
 400     )
 401   end
 402
 403   def locked?(%User{} = user) do
 404     user.info.locked || false
 405   end
 406
 407   def get_by_ap_id(ap_id) do
 408     Repo.get_by(User, ap_id: ap_id)
 409   end
 410
 411   # This is mostly an SPC migration fix. This guesses the user nickname (by taking the last part of the ap_id and the domain) and tries to get that user
 412   def get_by_guessed_nickname(ap_id) do
 413     domain = URI.parse(ap_id).host
 414     name = List.last(String.split(ap_id, "/"))
 415     nickname = "#{name}@#{domain}"
 416
 417     get_by_nickname(nickname)
 418   end
 419
 420   def update_and_set_cache(changeset) do
 421     with {:ok, user} <- Repo.update(changeset) do
 422       Cachex.put(:user_cache, "ap_id:#{user.ap_id}", user)
 423       Cachex.put(:user_cache, "nickname:#{user.nickname}", user)
 424       Cachex.put(:user_cache, "user_info:#{user.id}", user_info(user))
 425       {:ok, user}
 426     else
 427       e -> e
 428     end
 429   end
 430
 431   def invalidate_cache(user) do
 432     Cachex.del(:user_cache, "ap_id:#{user.ap_id}")
 433     Cachex.del(:user_cache, "nickname:#{user.nickname}")
 434     Cachex.del(:user_cache, "user_info:#{user.id}")
 435   end
 436
 437   def get_cached_by_ap_id(ap_id) do
 438     key = "ap_id:#{ap_id}"
 439     Cachex.fetch!(:user_cache, key, fn _ -> get_by_ap_id(ap_id) end)
 440   end
 441
 442   def get_cached_by_nickname(nickname) do
 443     key = "nickname:#{nickname}"
 444     Cachex.fetch!(:user_cache, key, fn _ -> get_or_fetch_by_nickname(nickname) end)
 445   end
 446
 447   def get_by_nickname(nickname) do
 448     Repo.get_by(User, nickname: nickname) ||
 449       if Regex.match?(~r(@#{Pleroma.Web.Endpoint.host()})i, nickname) do
 450         [local_nickname, _] = String.split(nickname, "@")
 451         Repo.get_by(User, nickname: local_nickname)
 452       end
 453   end
 454
 455   def get_by_nickname_or_email(nickname_or_email) do
 456     case user = Repo.get_by(User, nickname: nickname_or_email) do
 457       %User{} -> user
 458       nil -> Repo.get_by(User, email: nickname_or_email)
 459     end
 460   end
 461
 462   def get_cached_user_info(user) do
 463     key = "user_info:#{user.id}"
 464     Cachex.fetch!(:user_cache, key, fn _ -> user_info(user) end)
 465   end
 466
 467   def fetch_by_nickname(nickname) do
 468     ap_try = ActivityPub.make_user_from_nickname(nickname)
 469
 470     case ap_try do
 471       {:ok, user} -> {:ok, user}
 472       _ -> OStatus.make_user(nickname)
 473     end
 474   end
 475
 476   def get_or_fetch_by_nickname(nickname) do
 477     with %User{} = user <- get_by_nickname(nickname) do
 478       user
 479     else
 480       _e ->
 481         with [_nick, _domain] <- String.split(nickname, "@"),
 482              {:ok, user} <- fetch_by_nickname(nickname) do
 483           user
 484         else
 485           _e -> nil
 486         end
 487     end
 488   end
 489
 490   def get_followers_query(%User{id: id, follower_address: follower_address}, nil) do
 491     from(
 492       u in User,
 493       where: fragment("? <@ ?", ^[follower_address], u.following),
 494       where: u.id != ^id
 495     )
 496   end
 497
 498   def get_followers_query(user, page) do
 499     from(
 500       u in get_followers_query(user, nil),
 501       limit: 20,
 502       offset: ^((page - 1) * 20)
 503     )
 504   end
 505
 506   def get_followers_query(user), do: get_followers_query(user, nil)
 507
 508   def get_followers(user, page \\ nil) do
 509     q = get_followers_query(user, page)
 510
 511     {:ok, Repo.all(q)}
 512   end
 513
 514   def get_followers_ids(user, page \\ nil) do
 515     q = get_followers_query(user, page)
 516
 517     Repo.all(from(u in q, select: u.id))
 518   end
 519
 520   def get_friends_query(%User{id: id, following: following}, nil) do
 521     from(
 522       u in User,
 523       where: u.follower_address in ^following,
 524       where: u.id != ^id
 525     )
 526   end
 527
 528   def get_friends_query(user, page) do
 529     from(
 530       u in get_friends_query(user, nil),
 531       limit: 20,
 532       offset: ^((page - 1) * 20)
 533     )
 534   end
 535
 536   def get_friends_query(user), do: get_friends_query(user, nil)
 537
 538   def get_friends(user, page \\ nil) do
 539     q = get_friends_query(user, page)
 540
 541     {:ok, Repo.all(q)}
 542   end
 543
 544   def get_friends_ids(user, page \\ nil) do
 545     q = get_friends_query(user, page)
 546
 547     Repo.all(from(u in q, select: u.id))
 548   end
 549
 550   def get_follow_requests_query(%User{} = user) do
 551     from(
 552       a in Activity,
 553       where:
 554         fragment(
 555           "? ->> 'type' = 'Follow'",
 556           a.data
 557         ),
 558       where:
 559         fragment(
 560           "? ->> 'state' = 'pending'",
 561           a.data
 562         ),
 563       where:
 564         fragment(
 565           "? @> ?",
 566           a.data,
 567           ^%{"object" => user.ap_id}
 568         )
 569     )
 570   end
 571
 572   def get_follow_requests(%User{} = user) do
 573     q = get_follow_requests_query(user)
 574     reqs = Repo.all(q)
 575
 576     users =
 577       Enum.map(reqs, fn req -> req.actor end)
 578       |> Enum.uniq()
 579       |> Enum.map(fn ap_id -> get_by_ap_id(ap_id) end)
 580       |> Enum.filter(fn u -> !is_nil(u) end)
 581       |> Enum.filter(fn u -> !following?(u, user) end)
 582
 583     {:ok, users}
 584   end
 585
 586   def increase_note_count(%User{} = user) do
 587     info_cng = User.Info.add_to_note_count(user.info, 1)
 588
 589     cng =
 590       change(user)
 591       |> put_embed(:info, info_cng)
 592
 593     update_and_set_cache(cng)
 594   end
 595
 596   def decrease_note_count(%User{} = user) do
 597     info_cng = User.Info.add_to_note_count(user.info, -1)
 598
 599     cng =
 600       change(user)
 601       |> put_embed(:info, info_cng)
 602
 603     update_and_set_cache(cng)
 604   end
 605
 606   def update_note_count(%User{} = user) do
 607     note_count_query =
 608       from(
 609         a in Object,
 610         where: fragment("?->>'actor' = ? and ?->>'type' = 'Note'", a.data, ^user.ap_id, a.data),
 611         select: count(a.id)
 612       )
 613
 614     note_count = Repo.one(note_count_query)
 615
 616     info_cng = User.Info.set_note_count(user.info, note_count)
 617
 618     cng =
 619       change(user)
 620       |> put_embed(:info, info_cng)
 621
 622     update_and_set_cache(cng)
 623   end
 624
 625   def update_follower_count(%User{} = user) do
 626     follower_count_query =
 627       from(
 628         u in User,
 629         where: ^user.follower_address in u.following,
 630         where: u.id != ^user.id,
 631         select: count(u.id)
 632       )
 633
 634     follower_count = Repo.one(follower_count_query)
 635
 636     info_cng =
 637       user.info
 638       |> User.Info.set_follower_count(follower_count)
 639
 640     cng =
 641       change(user)
 642       |> put_embed(:info, info_cng)
 643
 644     update_and_set_cache(cng)
 645   end
 646
 647   def get_users_from_set_query(ap_ids, false) do
 648     from(
 649       u in User,
 650       where: u.ap_id in ^ap_ids
 651     )
 652   end
 653
 654   def get_users_from_set_query(ap_ids, true) do
 655     query = get_users_from_set_query(ap_ids, false)
 656
 657     from(
 658       u in query,
 659       where: u.local == true
 660     )
 661   end
 662
 663   def get_users_from_set(ap_ids, local_only \\ true) do
 664     get_users_from_set_query(ap_ids, local_only)
 665     |> Repo.all()
 666   end
 667
 668   def get_recipients_from_activity(%Activity{recipients: to}) do
 669     query =
 670       from(
 671         u in User,
 672         where: u.ap_id in ^to,
 673         or_where: fragment("? && ?", u.following, ^to)
 674       )
 675
 676     query = from(u in query, where: u.local == true)
 677
 678     Repo.all(query)
 679   end
 680
 681   def search(query, resolve \\ false, for_user \\ nil) do
 682     # Strip the beginning @ off if there is a query
 683     query = String.trim_leading(query, "@")
 684
 685     if resolve, do: User.get_or_fetch_by_nickname(query)
 686
 687     fts_results = do_search(fts_search_subquery(query), for_user)
 688
 689     trigram_results = do_search(trigram_search_subquery(query), for_user)
 690
 691     Enum.uniq_by(fts_results ++ trigram_results, & &1.id)
 692   end
 693
 694   defp do_search(subquery, for_user, options \\ []) do
 695     q =
 696       from(
 697         s in subquery(subquery),
 698         order_by: [desc: s.search_rank],
 699         limit: ^(options[:limit] || 20)
 700       )
 701
 702     results =
 703       q
 704       |> Repo.all()
 705       |> Enum.filter(&(&1.search_rank > 0))
 706
 707     boost_search_results(results, for_user)
 708   end
 709
 710   defp fts_search_subquery(query) do
 711     processed_query =
 712       query
 713       |> String.replace(~r/\W+/, " ")
 714       |> String.trim()
 715       |> String.split()
 716       |> Enum.map(&(&1 <> ":*"))
 717       |> Enum.join(" | ")
 718
 719     from(
 720       u in User,
 721       select_merge: %{
 722         search_rank:
 723           fragment(
 724             """
 725             ts_rank_cd(
 726               setweight(to_tsvector('simple', regexp_replace(?, '\\W', ' ', 'g')), 'A') ||
 727               setweight(to_tsvector('simple', regexp_replace(coalesce(?, ''), '\\W', ' ', 'g')), 'B'),
 728               to_tsquery('simple', ?),
 729               32
 730             )
 731             """,
 732             u.nickname,
 733             u.name,
 734             ^processed_query
 735           )
 736       },
 737       where:
 738         fragment(
 739           """
 740             (setweight(to_tsvector('simple', regexp_replace(?, '\\W', ' ', 'g')), 'A') ||
 741             setweight(to_tsvector('simple', regexp_replace(coalesce(?, ''), '\\W', ' ', 'g')), 'B')) @@ to_tsquery('simple', ?)
 742           """,
 743           u.nickname,
 744           u.name,
 745           ^processed_query
 746         )
 747     )
 748   end
 749
 750   defp trigram_search_subquery(query) do
 751     from(
 752       u in User,
 753       select_merge: %{
 754         search_rank:
 755           fragment(
 756             "similarity(?, trim(? || ' ' || coalesce(?, '')))",
 757             ^query,
 758             u.nickname,
 759             u.name
 760           )
 761       },
 762       where: fragment("trim(? || ' ' || coalesce(?, '')) % ?", u.nickname, u.name, ^query)
 763     )
 764   end
 765
 766   defp boost_search_results(results, nil), do: results
 767
 768   defp boost_search_results(results, for_user) do
 769     friends_ids = get_friends_ids(for_user)
 770     followers_ids = get_followers_ids(for_user)
 771
 772     Enum.map(
 773       results,
 774       fn u ->
 775         search_rank_coef =
 776           cond do
 777             u.id in friends_ids ->
 778               1.2
 779
 780             u.id in followers_ids ->
 781               1.1
 782
 783             true ->
 784               1
 785           end
 786
 787         Map.put(u, :search_rank, u.search_rank * search_rank_coef)
 788       end
 789     )
 790     |> Enum.sort_by(&(-&1.search_rank))
 791   end
 792
 793   def blocks_import(%User{} = blocker, blocked_identifiers) when is_list(blocked_identifiers) do
 794     Enum.map(
 795       blocked_identifiers,
 796       fn blocked_identifier ->
 797         with %User{} = blocked <- get_or_fetch(blocked_identifier),
 798              {:ok, blocker} <- block(blocker, blocked),
 799              {:ok, _} <- ActivityPub.block(blocker, blocked) do
 800           blocked
 801         else
 802           err ->
 803             Logger.debug("blocks_import failed for #{blocked_identifier} with: #{inspect(err)}")
 804             err
 805         end
 806       end
 807     )
 808   end
 809
 810   def block(blocker, %User{ap_id: ap_id} = blocked) do
 811     # sever any follow relationships to prevent leaks per activitypub (Pleroma issue #213)
 812     blocker =
 813       if following?(blocker, blocked) do
 814         {:ok, blocker, _} = unfollow(blocker, blocked)
 815         blocker
 816       else
 817         blocker
 818       end
 819
 820     if following?(blocked, blocker) do
 821       unfollow(blocked, blocker)
 822     end
 823
 824     info_cng =
 825       blocker.info
 826       |> User.Info.add_to_block(ap_id)
 827
 828     cng =
 829       change(blocker)
 830       |> put_embed(:info, info_cng)
 831
 832     update_and_set_cache(cng)
 833   end
 834
 835   # helper to handle the block given only an actor's AP id
 836   def block(blocker, %{ap_id: ap_id}) do
 837     block(blocker, User.get_by_ap_id(ap_id))
 838   end
 839
 840   def unblock(blocker, %{ap_id: ap_id}) do
 841     info_cng =
 842       blocker.info
 843       |> User.Info.remove_from_block(ap_id)
 844
 845     cng =
 846       change(blocker)
 847       |> put_embed(:info, info_cng)
 848
 849     update_and_set_cache(cng)
 850   end
 851
 852   def blocks?(user, %{ap_id: ap_id}) do
 853     blocks = user.info.blocks
 854     domain_blocks = user.info.domain_blocks
 855     %{host: host} = URI.parse(ap_id)
 856
 857     Enum.member?(blocks, ap_id) ||
 858       Enum.any?(domain_blocks, fn domain ->
 859         host == domain
 860       end)
 861   end
 862
 863   def blocked_users(user),
 864     do: Repo.all(from(u in User, where: u.ap_id in ^user.info.blocks))
 865
 866   def block_domain(user, domain) do
 867     info_cng =
 868       user.info
 869       |> User.Info.add_to_domain_block(domain)
 870
 871     cng =
 872       change(user)
 873       |> put_embed(:info, info_cng)
 874
 875     update_and_set_cache(cng)
 876   end
 877
 878   def unblock_domain(user, domain) do
 879     info_cng =
 880       user.info
 881       |> User.Info.remove_from_domain_block(domain)
 882
 883     cng =
 884       change(user)
 885       |> put_embed(:info, info_cng)
 886
 887     update_and_set_cache(cng)
 888   end
 889
 890   def local_user_query() do
 891     from(
 892       u in User,
 893       where: u.local == true,
 894       where: not is_nil(u.nickname)
 895     )
 896   end
 897
 898   def moderator_user_query() do
 899     from(
 900       u in User,
 901       where: u.local == true,
 902       where: fragment("?->'is_moderator' @> 'true'", u.info)
 903     )
 904   end
 905
 906   def deactivate(%User{} = user, status \\ true) do
 907     info_cng = User.Info.set_activation_status(user.info, status)
 908
 909     cng =
 910       change(user)
 911       |> put_embed(:info, info_cng)
 912
 913     update_and_set_cache(cng)
 914   end
 915
 916   def delete(%User{} = user) do
 917     {:ok, user} = User.deactivate(user)
 918
 919     # Remove all relationships
 920     {:ok, followers} = User.get_followers(user)
 921
 922     followers
 923     |> Enum.each(fn follower -> User.unfollow(follower, user) end)
 924
 925     {:ok, friends} = User.get_friends(user)
 926
 927     friends
 928     |> Enum.each(fn followed -> User.unfollow(user, followed) end)
 929
 930     query = from(a in Activity, where: a.actor == ^user.ap_id)
 931
 932     Repo.all(query)
 933     |> Enum.each(fn activity ->
 934       case activity.data["type"] do
 935         "Create" ->
 936           ActivityPub.delete(Object.normalize(activity.data["object"]))
 937
 938         # TODO: Do something with likes, follows, repeats.
 939         _ ->
 940           "Doing nothing"
 941       end
 942     end)
 943
 944     {:ok, user}
 945   end
 946
 947   def html_filter_policy(%User{info: %{no_rich_text: true}}) do
 948     Pleroma.HTML.Scrubber.TwitterText
 949   end
 950
 951   @default_scrubbers Pleroma.Config.get([:markup, :scrub_policy])
 952
 953   def html_filter_policy(_), do: @default_scrubbers
 954
 955   def get_or_fetch_by_ap_id(ap_id) do
 956     user = get_by_ap_id(ap_id)
 957
 958     if !is_nil(user) and !User.needs_update?(user) do
 959       user
 960     else
 961       ap_try = ActivityPub.make_user_from_ap_id(ap_id)
 962
 963       case ap_try do
 964         {:ok, user} ->
 965           user
 966
 967         _ ->
 968           case OStatus.make_user(ap_id) do
 969             {:ok, user} -> user
 970             _ -> {:error, "Could not fetch by AP id"}
 971           end
 972       end
 973     end
 974   end
 975
 976   def get_or_create_instance_user do
 977     relay_uri = "#{Pleroma.Web.Endpoint.url()}/relay"
 978
 979     if user = get_by_ap_id(relay_uri) do
 980       user
 981     else
 982       changes =
 983         %User{info: %User.Info{}}
 984         |> cast(%{}, [:ap_id, :nickname, :local])
 985         |> put_change(:ap_id, relay_uri)
 986         |> put_change(:nickname, nil)
 987         |> put_change(:local, true)
 988         |> put_change(:follower_address, relay_uri <> "/followers")
 989
 990       {:ok, user} = Repo.insert(changes)
 991       user
 992     end
 993   end
 994
 995   # AP style
 996   def public_key_from_info(%{
 997         source_data: %{"publicKey" => %{"publicKeyPem" => public_key_pem}}
 998       }) do
 999     key =
1000       public_key_pem
1001       |> :public_key.pem_decode()
1002       |> hd()
1003       |> :public_key.pem_entry_decode()
1004
1005     {:ok, key}
1006   end
1007
1008   # OStatus Magic Key
1009   def public_key_from_info(%{magic_key: magic_key}) do
1010     {:ok, Pleroma.Web.Salmon.decode_key(magic_key)}
1011   end
1012
1013   def get_public_key_for_ap_id(ap_id) do
1014     with %User{} = user <- get_or_fetch_by_ap_id(ap_id),
1015          {:ok, public_key} <- public_key_from_info(user.info) do
1016       {:ok, public_key}
1017     else
1018       _ -> :error
1019     end
1020   end
1021
1022   defp blank?(""), do: nil
1023   defp blank?(n), do: n
1024
1025   def insert_or_update_user(data) do
1026     data =
1027       data
1028       |> Map.put(:name, blank?(data[:name]) || data[:nickname])
1029
1030     cs = User.remote_user_creation(data)
1031
1032     Repo.insert(cs, on_conflict: :replace_all, conflict_target: :nickname)
1033   end
1034
1035   def ap_enabled?(%User{local: true}), do: true
1036   def ap_enabled?(%User{info: info}), do: info.ap_enabled
1037   def ap_enabled?(_), do: false
1038
1039   @doc "Gets or fetch a user by uri or nickname."
1040   @spec get_or_fetch(String.t()) :: User.t()
1041   def get_or_fetch("http" <> _host = uri), do: get_or_fetch_by_ap_id(uri)
1042   def get_or_fetch(nickname), do: get_or_fetch_by_nickname(nickname)
1043
1044   # wait a period of time and return newest version of the User structs
1045   # this is because we have synchronous follow APIs and need to simulate them
1046   # with an async handshake
1047   def wait_and_refresh(_, %User{local: true} = a, %User{local: true} = b) do
1048     with %User{} = a <- Repo.get(User, a.id),
1049          %User{} = b <- Repo.get(User, b.id) do
1050       {:ok, a, b}
1051     else
1052       _e ->
1053         :error
1054     end
1055   end
1056
1057   def wait_and_refresh(timeout, %User{} = a, %User{} = b) do
1058     with :ok <- :timer.sleep(timeout),
1059          %User{} = a <- Repo.get(User, a.id),
1060          %User{} = b <- Repo.get(User, b.id) do
1061       {:ok, a, b}
1062     else
1063       _e ->
1064         :error
1065     end
1066   end
1067
1068   def parse_bio(bio, user \\ %User{info: %{source_data: %{}}})
1069   def parse_bio(nil, _user), do: ""
1070   def parse_bio(bio, _user) when bio == "", do: bio
1071
1072   def parse_bio(bio, user) do
1073     mentions = Formatter.parse_mentions(bio)
1074     tags = Formatter.parse_tags(bio)
1075
1076     emoji =
1077       (user.info.source_data["tag"] || [])
1078       |> Enum.filter(fn %{"type" => t} -> t == "Emoji" end)
1079       |> Enum.map(fn %{"icon" => %{"url" => url}, "name" => name} ->
1080         {String.trim(name, ":"), url}
1081       end)
1082
1083     bio
1084     |> CommonUtils.format_input(mentions, tags, "text/plain")
1085     |> Formatter.emojify(emoji)
1086   end
1087
1088   def tag(user_identifiers, tags) when is_list(user_identifiers) do
1089     Repo.transaction(fn ->
1090       for user_identifier <- user_identifiers, do: tag(user_identifier, tags)
1091     end)
1092   end
1093
1094   def tag(nickname, tags) when is_binary(nickname),
1095     do: tag(User.get_by_nickname(nickname), tags)
1096
1097   def tag(%User{} = user, tags),
1098     do: update_tags(user, Enum.uniq((user.tags || []) ++ normalize_tags(tags)))
1099
1100   def untag(user_identifiers, tags) when is_list(user_identifiers) do
1101     Repo.transaction(fn ->
1102       for user_identifier <- user_identifiers, do: untag(user_identifier, tags)
1103     end)
1104   end
1105
1106   def untag(nickname, tags) when is_binary(nickname),
1107     do: untag(User.get_by_nickname(nickname), tags)
1108
1109   def untag(%User{} = user, tags),
1110     do: update_tags(user, (user.tags || []) -- normalize_tags(tags))
1111
1112   defp update_tags(%User{} = user, new_tags) do
1113     {:ok, updated_user} =
1114       user
1115       |> change(%{tags: new_tags})
1116       |> Repo.update()
1117
1118     updated_user
1119   end
1120
1121   defp normalize_tags(tags) do
1122     [tags]
1123     |> List.flatten()
1124     |> Enum.map(&String.downcase(&1))
1125   end
1126
1127   defp local_nickname_regex() do
1128     if Pleroma.Config.get([:instance, :extended_nickname_format]) do
1129       @extended_local_nickname_regex
1130     else
1131       @strict_local_nickname_regex
1132     end
1133   end
1134 end