git.squeep.com Git - akkoma/blob - lib/pleroma/user.ex

   1 defmodule Pleroma.User do
   2   use Ecto.Schema
   3
   4   import Ecto.{Changeset, Query}
   5   alias Pleroma.{Repo, User, Object, Web, Activity, Notification}
   6   alias Comeonin.Pbkdf2
   7   alias Pleroma.Formatter
   8   alias Pleroma.Web.CommonAPI.Utils, as: CommonUtils
   9   alias Pleroma.Web.{OStatus, Websub, OAuth}
  10   alias Pleroma.Web.ActivityPub.{Utils, ActivityPub}
  11
  12   @type t :: %__MODULE__{}
  13
  14   schema "users" do
  15     field(:bio, :string)
  16     field(:email, :string)
  17     field(:name, :string)
  18     field(:nickname, :string)
  19     field(:password_hash, :string)
  20     field(:password, :string, virtual: true)
  21     field(:password_confirmation, :string, virtual: true)
  22     field(:following, {:array, :string}, default: [])
  23     field(:ap_id, :string)
  24     field(:avatar, :map)
  25     field(:local, :boolean, default: true)
  26     field(:follower_address, :string)
  27     field(:search_distance, :float, virtual: true)
  28     field(:tags, {:array, :string}, default: [])
  29     field(:last_refreshed_at, :naive_datetime)
  30     has_many(:notifications, Notification)
  31     embeds_one(:info, Pleroma.User.Info)
  32
  33     timestamps()
  34   end
  35
  36   def avatar_url(user) do
  37     case user.avatar do
  38       %{"url" => [%{"href" => href} | _]} -> href
  39       _ -> "#{Web.base_url()}/images/avi.png"
  40     end
  41   end
  42
  43   def banner_url(user) do
  44     case user.info.banner do
  45       %{"url" => [%{"href" => href} | _]} -> href
  46       _ -> "#{Web.base_url()}/images/banner.png"
  47     end
  48   end
  49
  50   def profile_url(%User{info: %{source_data: %{"url" => url}}}), do: url
  51   def profile_url(%User{ap_id: ap_id}), do: ap_id
  52   def profile_url(_), do: nil
  53
  54   def ap_id(%User{nickname: nickname}) do
  55     "#{Web.base_url()}/users/#{nickname}"
  56   end
  57
  58   def ap_followers(%User{} = user) do
  59     "#{ap_id(user)}/followers"
  60   end
  61
  62   def follow_changeset(struct, params \\ %{}) do
  63     struct
  64     |> cast(params, [:following])
  65     |> validate_required([:following])
  66   end
  67
  68   def user_info(%User{} = user) do
  69     oneself = if user.local, do: 1, else: 0
  70
  71     %{
  72       following_count: length(user.following) - oneself,
  73       note_count: user.info.note_count,
  74       follower_count: user.info.follower_count,
  75       locked: user.info.locked,
  76       default_scope: user.info.default_scope
  77     }
  78   end
  79
  80   @email_regex ~r/^[a-zA-Z0-9.!#$%&'*+\/=?^_`{|}~-]+@[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?(?:\.[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?)*$/
  81   def remote_user_creation(params) do
  82     params =
  83       params
  84       |> Map.put(:info, params[:info] || %{})
  85
  86     info_cng = User.Info.remote_user_creation(%User.Info{}, params[:info])
  87
  88     changes =
  89       %User{}
  90       |> cast(params, [:bio, :name, :ap_id, :nickname, :avatar])
  91       |> validate_required([:name, :ap_id])
  92       |> unique_constraint(:nickname)
  93       |> validate_format(:nickname, @email_regex)
  94       |> validate_length(:bio, max: 5000)
  95       |> validate_length(:name, max: 100)
  96       |> put_change(:local, false)
  97       |> put_embed(:info, info_cng)
  98
  99     if changes.valid? do
 100       case info_cng.changes[:source_data] do
 101         %{"followers" => followers} ->
 102           changes
 103           |> put_change(:follower_address, followers)
 104
 105         _ ->
 106           followers = User.ap_followers(%User{nickname: changes.changes[:nickname]})
 107
 108           changes
 109           |> put_change(:follower_address, followers)
 110       end
 111     else
 112       changes
 113     end
 114   end
 115
 116   def update_changeset(struct, params \\ %{}) do
 117     struct
 118     |> cast(params, [:bio, :name, :avatar])
 119     |> unique_constraint(:nickname)
 120     |> validate_format(:nickname, ~r/^[a-zA-Z\d]+$/)
 121     |> validate_length(:bio, max: 5000)
 122     |> validate_length(:name, min: 1, max: 100)
 123   end
 124
 125   def upgrade_changeset(struct, params \\ %{}) do
 126     params =
 127       params
 128       |> Map.put(:last_refreshed_at, NaiveDateTime.utc_now())
 129
 130     info_cng =
 131       struct.info
 132       |> User.Info.user_upgrade(params[:info])
 133
 134     struct
 135     |> cast(params, [:bio, :name, :follower_address, :avatar, :last_refreshed_at])
 136     |> unique_constraint(:nickname)
 137     |> validate_format(:nickname, ~r/^[a-zA-Z\d]+$/)
 138     |> validate_length(:bio, max: 5000)
 139     |> validate_length(:name, max: 100)
 140     |> put_embed(:info, info_cng)
 141   end
 142
 143   def password_update_changeset(struct, params) do
 144     changeset =
 145       struct
 146       |> cast(params, [:password, :password_confirmation])
 147       |> validate_required([:password, :password_confirmation])
 148       |> validate_confirmation(:password)
 149
 150     OAuth.Token.delete_user_tokens(struct)
 151     OAuth.Authorization.delete_user_authorizations(struct)
 152
 153     if changeset.valid? do
 154       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 155
 156       changeset
 157       |> put_change(:password_hash, hashed)
 158     else
 159       changeset
 160     end
 161   end
 162
 163   def reset_password(user, data) do
 164     update_and_set_cache(password_update_changeset(user, data))
 165   end
 166
 167   def register_changeset(struct, params \\ %{}) do
 168     changeset =
 169       struct
 170       |> cast(params, [:bio, :email, :name, :nickname, :password, :password_confirmation])
 171       |> validate_required([:email, :name, :nickname, :password, :password_confirmation])
 172       |> validate_confirmation(:password)
 173       |> unique_constraint(:email)
 174       |> unique_constraint(:nickname)
 175       |> validate_format(:nickname, ~r/^[a-zA-Z\d]+$/)
 176       |> validate_format(:email, @email_regex)
 177       |> validate_length(:bio, max: 1000)
 178       |> validate_length(:name, min: 1, max: 100)
 179       |> put_change(:info, %Pleroma.User.Info{})
 180
 181     if changeset.valid? do
 182       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 183       ap_id = User.ap_id(%User{nickname: changeset.changes[:nickname]})
 184       followers = User.ap_followers(%User{nickname: changeset.changes[:nickname]})
 185
 186       changeset
 187       |> put_change(:password_hash, hashed)
 188       |> put_change(:ap_id, ap_id)
 189       |> put_change(:following, [followers])
 190       |> put_change(:follower_address, followers)
 191     else
 192       changeset
 193     end
 194   end
 195
 196   def needs_update?(%User{local: true}), do: false
 197
 198   def needs_update?(%User{local: false, last_refreshed_at: nil}), do: true
 199
 200   def needs_update?(%User{local: false} = user) do
 201     NaiveDateTime.diff(NaiveDateTime.utc_now(), user.last_refreshed_at) >= 86400
 202   end
 203
 204   def needs_update?(_), do: true
 205
 206   def maybe_direct_follow(%User{} = follower, %User{local: true, info: %{locked: true}}) do
 207     {:ok, follower}
 208   end
 209
 210   def maybe_direct_follow(%User{} = follower, %User{local: true} = followed) do
 211     follow(follower, followed)
 212   end
 213
 214   def maybe_direct_follow(%User{} = follower, %User{} = followed) do
 215     if !User.ap_enabled?(followed) do
 216       follow(follower, followed)
 217     else
 218       {:ok, follower}
 219     end
 220   end
 221
 222   def maybe_follow(%User{} = follower, %User{info: _info} = followed) do
 223     if not following?(follower, followed) do
 224       follow(follower, followed)
 225     else
 226       {:ok, follower}
 227     end
 228   end
 229
 230   def follow(%User{} = follower, %User{info: info} = followed) do
 231     user_config = Application.get_env(:pleroma, :user)
 232     deny_follow_blocked = Keyword.get(user_config, :deny_follow_blocked)
 233
 234     ap_followers = followed.follower_address
 235
 236     cond do
 237       following?(follower, followed) or info.deactivated ->
 238         {:error, "Could not follow user: #{followed.nickname} is already on your list."}
 239
 240       deny_follow_blocked and blocks?(followed, follower) ->
 241         {:error, "Could not follow user: #{followed.nickname} blocked you."}
 242
 243       true ->
 244         if !followed.local && follower.local && !ap_enabled?(followed) do
 245           Websub.subscribe(follower, followed)
 246         end
 247
 248         following =
 249           [ap_followers | follower.following]
 250           |> Enum.uniq()
 251
 252         follower =
 253           follower
 254           |> follow_changeset(%{following: following})
 255           |> update_and_set_cache
 256
 257         {:ok, _} = update_follower_count(followed)
 258
 259         follower
 260     end
 261   end
 262
 263   def unfollow(%User{} = follower, %User{} = followed) do
 264     ap_followers = followed.follower_address
 265
 266     if following?(follower, followed) and follower.ap_id != followed.ap_id do
 267       following =
 268         follower.following
 269         |> List.delete(ap_followers)
 270
 271       {:ok, follower} =
 272         follower
 273         |> follow_changeset(%{following: following})
 274         |> update_and_set_cache
 275
 276       {:ok, followed} = update_follower_count(followed)
 277
 278       {:ok, follower, Utils.fetch_latest_follow(follower, followed)}
 279     else
 280       {:error, "Not subscribed!"}
 281     end
 282   end
 283
 284   @spec following?(User.t(), User.t()) :: boolean
 285   def following?(%User{} = follower, %User{} = followed) do
 286     Enum.member?(follower.following, followed.follower_address)
 287   end
 288
 289   def locked?(%User{} = user) do
 290     user.info.locked || false
 291   end
 292
 293   def get_by_ap_id(ap_id) do
 294     Repo.get_by(User, ap_id: ap_id)
 295   end
 296
 297   def update_and_set_cache(changeset) do
 298     with {:ok, user} <- Repo.update(changeset) do
 299       Cachex.put(:user_cache, "ap_id:#{user.ap_id}", user)
 300       Cachex.put(:user_cache, "nickname:#{user.nickname}", user)
 301       Cachex.put(:user_cache, "user_info:#{user.id}", user_info(user))
 302       {:ok, user}
 303     else
 304       e -> e
 305     end
 306   end
 307
 308   def invalidate_cache(user) do
 309     Cachex.del(:user_cache, "ap_id:#{user.ap_id}")
 310     Cachex.del(:user_cache, "nickname:#{user.nickname}")
 311     Cachex.del(:user_cache, "user_info:#{user.id}")
 312   end
 313
 314   def get_cached_by_ap_id(ap_id) do
 315     key = "ap_id:#{ap_id}"
 316     Cachex.fetch!(:user_cache, key, fn _ -> get_by_ap_id(ap_id) end)
 317   end
 318
 319   def get_cached_by_nickname(nickname) do
 320     key = "nickname:#{nickname}"
 321     Cachex.fetch!(:user_cache, key, fn _ -> get_or_fetch_by_nickname(nickname) end)
 322   end
 323
 324   def get_by_nickname(nickname) do
 325     Repo.get_by(User, nickname: nickname)
 326   end
 327
 328   def get_by_nickname_or_email(nickname_or_email) do
 329     case user = Repo.get_by(User, nickname: nickname_or_email) do
 330       %User{} -> user
 331       nil -> Repo.get_by(User, email: nickname_or_email)
 332     end
 333   end
 334
 335   def get_cached_user_info(user) do
 336     key = "user_info:#{user.id}"
 337     Cachex.fetch!(:user_cache, key, fn _ -> user_info(user) end)
 338   end
 339
 340   def fetch_by_nickname(nickname) do
 341     ap_try = ActivityPub.make_user_from_nickname(nickname)
 342
 343     case ap_try do
 344       {:ok, user} -> {:ok, user}
 345       _ -> OStatus.make_user(nickname)
 346     end
 347   end
 348
 349   def get_or_fetch_by_nickname(nickname) do
 350     with %User{} = user <- get_by_nickname(nickname) do
 351       user
 352     else
 353       _e ->
 354         with [_nick, _domain] <- String.split(nickname, "@"),
 355              {:ok, user} <- fetch_by_nickname(nickname) do
 356           user
 357         else
 358           _e -> nil
 359         end
 360     end
 361   end
 362
 363   def get_followers_query(%User{id: id, follower_address: follower_address}) do
 364     from(
 365       u in User,
 366       where: fragment("? <@ ?", ^[follower_address], u.following),
 367       where: u.id != ^id
 368     )
 369   end
 370
 371   def get_followers(user) do
 372     q = get_followers_query(user)
 373
 374     {:ok, Repo.all(q)}
 375   end
 376
 377   def get_friends_query(%User{id: id, following: following}) do
 378     from(
 379       u in User,
 380       where: u.follower_address in ^following,
 381       where: u.id != ^id
 382     )
 383   end
 384
 385   def get_friends(user) do
 386     q = get_friends_query(user)
 387
 388     {:ok, Repo.all(q)}
 389   end
 390
 391   def get_follow_requests_query(%User{} = user) do
 392     from(
 393       a in Activity,
 394       where:
 395         fragment(
 396           "? ->> 'type' = 'Follow'",
 397           a.data
 398         ),
 399       where:
 400         fragment(
 401           "? ->> 'state' = 'pending'",
 402           a.data
 403         ),
 404       where:
 405         fragment(
 406           "? @> ?",
 407           a.data,
 408           ^%{"object" => user.ap_id}
 409         )
 410     )
 411   end
 412
 413   def get_follow_requests(%User{} = user) do
 414     q = get_follow_requests_query(user)
 415     reqs = Repo.all(q)
 416
 417     users =
 418       Enum.map(reqs, fn req -> req.actor end)
 419       |> Enum.uniq()
 420       |> Enum.map(fn ap_id -> get_by_ap_id(ap_id) end)
 421       |> Enum.filter(fn u -> !following?(u, user) end)
 422
 423     {:ok, users}
 424   end
 425
 426   def increase_note_count(%User{} = user) do
 427     info_cng = User.Info.add_to_note_count(user.info, 1)
 428
 429     cng =
 430       change(user)
 431       |> put_embed(:info, info_cng)
 432
 433     update_and_set_cache(cng)
 434   end
 435
 436   def decrease_note_count(%User{} = user) do
 437     info_cng = User.Info.add_to_note_count(user.info, -1)
 438
 439     cng =
 440       change(user)
 441       |> put_embed(:info, info_cng)
 442
 443     update_and_set_cache(cng)
 444   end
 445
 446   def update_note_count(%User{} = user) do
 447     note_count_query =
 448       from(
 449         a in Object,
 450         where: fragment("?->>'actor' = ? and ?->>'type' = 'Note'", a.data, ^user.ap_id, a.data),
 451         select: count(a.id)
 452       )
 453
 454     note_count = Repo.one(note_count_query)
 455
 456     info_cng = User.Info.set_note_count(user.info, note_count)
 457
 458     cng =
 459       change(user)
 460       |> put_embed(:info, info_cng)
 461
 462     update_and_set_cache(cng)
 463   end
 464
 465   def update_follower_count(%User{} = user) do
 466     follower_count_query =
 467       from(
 468         u in User,
 469         where: ^user.follower_address in u.following,
 470         where: u.id != ^user.id,
 471         select: count(u.id)
 472       )
 473
 474     follower_count = Repo.one(follower_count_query)
 475
 476     info_cng =
 477       user.info
 478       |> User.Info.set_follower_count(follower_count)
 479
 480     cng =
 481       change(user)
 482       |> put_embed(:info, info_cng)
 483
 484     update_and_set_cache(cng)
 485   end
 486
 487   def get_users_from_set_query(ap_ids, false) do
 488     from(
 489       u in User,
 490       where: u.ap_id in ^ap_ids
 491     )
 492   end
 493
 494   def get_users_from_set_query(ap_ids, true) do
 495     query = get_users_from_set_query(ap_ids, false)
 496
 497     from(
 498       u in query,
 499       where: u.local == true
 500     )
 501   end
 502
 503   def get_users_from_set(ap_ids, local_only \\ true) do
 504     get_users_from_set_query(ap_ids, local_only)
 505     |> Repo.all()
 506   end
 507
 508   def get_recipients_from_activity(%Activity{recipients: to}) do
 509     query =
 510       from(
 511         u in User,
 512         where: u.ap_id in ^to,
 513         or_where: fragment("? && ?", u.following, ^to)
 514       )
 515
 516     query = from(u in query, where: u.local == true)
 517
 518     Repo.all(query)
 519   end
 520
 521   def search(query, resolve \\ false) do
 522     # strip the beginning @ off if there is a query
 523     query = String.trim_leading(query, "@")
 524
 525     if resolve do
 526       User.get_or_fetch_by_nickname(query)
 527     end
 528
 529     inner =
 530       from(
 531         u in User,
 532         select_merge: %{
 533           search_distance:
 534             fragment(
 535               "? <-> (? || ?)",
 536               ^query,
 537               u.nickname,
 538               u.name
 539             )
 540         },
 541         where: not is_nil(u.nickname)
 542       )
 543
 544     q =
 545       from(
 546         s in subquery(inner),
 547         order_by: s.search_distance,
 548         limit: 20
 549       )
 550
 551     Repo.all(q)
 552   end
 553
 554   def block(blocker, %User{ap_id: ap_id} = blocked) do
 555     # sever any follow relationships to prevent leaks per activitypub (Pleroma issue #213)
 556     blocker =
 557       if following?(blocker, blocked) do
 558         {:ok, blocker, _} = unfollow(blocker, blocked)
 559         blocker
 560       else
 561         blocker
 562       end
 563
 564     if following?(blocked, blocker) do
 565       unfollow(blocked, blocker)
 566     end
 567
 568     info_cng =
 569       blocker.info
 570       |> User.Info.add_to_block(ap_id)
 571
 572     cng =
 573       change(blocker)
 574       |> put_embed(:info, info_cng)
 575
 576     update_and_set_cache(cng)
 577   end
 578
 579   # helper to handle the block given only an actor's AP id
 580   def block(blocker, %{ap_id: ap_id}) do
 581     block(blocker, User.get_by_ap_id(ap_id))
 582   end
 583
 584   def unblock(blocker, %{ap_id: ap_id}) do
 585     info_cng =
 586       blocker.info
 587       |> User.Info.remove_from_block(ap_id)
 588
 589     cng =
 590       change(blocker)
 591       |> put_embed(:info, info_cng)
 592
 593     update_and_set_cache(cng)
 594   end
 595
 596   def blocks?(user, %{ap_id: ap_id}) do
 597     blocks = user.info.blocks
 598     domain_blocks = user.info.domain_blocks
 599     %{host: host} = URI.parse(ap_id)
 600
 601     Enum.member?(blocks, ap_id) ||
 602       Enum.any?(domain_blocks, fn domain ->
 603         host == domain
 604       end)
 605   end
 606
 607   def block_domain(user, domain) do
 608     info_cng =
 609       user.info
 610       |> User.Info.add_to_domain_block(domain)
 611
 612     cng =
 613       change(user)
 614       |> put_embed(:info, info_cng)
 615
 616     update_and_set_cache(cng)
 617   end
 618
 619   def unblock_domain(user, domain) do
 620     info_cng =
 621       user.info
 622       |> User.Info.remove_from_domain_block(domain)
 623
 624     cng =
 625       change(user)
 626       |> put_embed(:info, info_cng)
 627
 628     update_and_set_cache(cng)
 629   end
 630
 631   def local_user_query() do
 632     from(
 633       u in User,
 634       where: u.local == true,
 635       where: not is_nil(u.nickname)
 636     )
 637   end
 638
 639   def moderator_user_query() do
 640     from(
 641       u in User,
 642       where: u.local == true,
 643       where: fragment("?->'is_moderator' @> 'true'", u.info)
 644     )
 645   end
 646
 647   def deactivate(%User{} = user, status \\ true) do
 648     info_cng = User.Info.set_activation_status(user.info, status)
 649
 650     cng =
 651       change(user)
 652       |> put_embed(:info, info_cng)
 653
 654     update_and_set_cache(cng)
 655   end
 656
 657   def delete(%User{} = user) do
 658     {:ok, user} = User.deactivate(user)
 659
 660     # Remove all relationships
 661     {:ok, followers} = User.get_followers(user)
 662
 663     followers
 664     |> Enum.each(fn follower -> User.unfollow(follower, user) end)
 665
 666     {:ok, friends} = User.get_friends(user)
 667
 668     friends
 669     |> Enum.each(fn followed -> User.unfollow(user, followed) end)
 670
 671     query = from(a in Activity, where: a.actor == ^user.ap_id)
 672
 673     Repo.all(query)
 674     |> Enum.each(fn activity ->
 675       case activity.data["type"] do
 676         "Create" ->
 677           ActivityPub.delete(Object.normalize(activity.data["object"]))
 678
 679         # TODO: Do something with likes, follows, repeats.
 680         _ ->
 681           "Doing nothing"
 682       end
 683     end)
 684
 685     {:ok, user}
 686   end
 687
 688   def html_filter_policy(%User{info: %{no_rich_text: true}}) do
 689     Pleroma.HTML.Scrubber.TwitterText
 690   end
 691
 692   def html_filter_policy(_), do: nil
 693
 694   def get_or_fetch_by_ap_id(ap_id) do
 695     user = get_by_ap_id(ap_id)
 696
 697     if !is_nil(user) and !User.needs_update?(user) do
 698       user
 699     else
 700       ap_try = ActivityPub.make_user_from_ap_id(ap_id)
 701
 702       case ap_try do
 703         {:ok, user} ->
 704           user
 705
 706         _ ->
 707           case OStatus.make_user(ap_id) do
 708             {:ok, user} -> user
 709             _ -> {:error, "Could not fetch by AP id"}
 710           end
 711       end
 712     end
 713   end
 714
 715   def get_or_create_instance_user do
 716     relay_uri = "#{Pleroma.Web.Endpoint.url()}/relay"
 717
 718     if user = get_by_ap_id(relay_uri) do
 719       user
 720     else
 721       changes =
 722         %User{info: %User.Info{}}
 723         |> cast(%{}, [:ap_id, :nickname, :local])
 724         |> put_change(:ap_id, relay_uri)
 725         |> put_change(:nickname, nil)
 726         |> put_change(:local, true)
 727         |> put_change(:follower_address, relay_uri <> "/followers")
 728
 729       {:ok, user} = Repo.insert(changes)
 730       user
 731     end
 732   end
 733
 734   # AP style
 735   def public_key_from_info(%{
 736         source_data: %{"publicKey" => %{"publicKeyPem" => public_key_pem}}
 737       }) do
 738     key =
 739       :public_key.pem_decode(public_key_pem)
 740       |> hd()
 741       |> :public_key.pem_entry_decode()
 742
 743     {:ok, key}
 744   end
 745
 746   # OStatus Magic Key
 747   def public_key_from_info(%{magic_key: magic_key}) do
 748     {:ok, Pleroma.Web.Salmon.decode_key(magic_key)}
 749   end
 750
 751   def get_public_key_for_ap_id(ap_id) do
 752     with %User{} = user <- get_or_fetch_by_ap_id(ap_id),
 753          {:ok, public_key} <- public_key_from_info(user.info) do
 754       {:ok, public_key}
 755     else
 756       _ -> :error
 757     end
 758   end
 759
 760   defp blank?(""), do: nil
 761   defp blank?(n), do: n
 762
 763   def insert_or_update_user(data) do
 764     data =
 765       data
 766       |> Map.put(:name, blank?(data[:name]) || data[:nickname])
 767
 768     cs = User.remote_user_creation(data)
 769
 770     Repo.insert(cs, on_conflict: :replace_all, conflict_target: :nickname)
 771   end
 772
 773   def ap_enabled?(%User{local: true}), do: true
 774   def ap_enabled?(%User{info: info}), do: info.ap_enabled
 775   def ap_enabled?(_), do: false
 776
 777   def get_or_fetch(uri_or_nickname) do
 778     if String.starts_with?(uri_or_nickname, "http") do
 779       get_or_fetch_by_ap_id(uri_or_nickname)
 780     else
 781       get_or_fetch_by_nickname(uri_or_nickname)
 782     end
 783   end
 784
 785   # wait a period of time and return newest version of the User structs
 786   # this is because we have synchronous follow APIs and need to simulate them
 787   # with an async handshake
 788   def wait_and_refresh(_, %User{local: true} = a, %User{local: true} = b) do
 789     with %User{} = a <- Repo.get(User, a.id),
 790          %User{} = b <- Repo.get(User, b.id) do
 791       {:ok, a, b}
 792     else
 793       _e ->
 794         :error
 795     end
 796   end
 797
 798   def wait_and_refresh(timeout, %User{} = a, %User{} = b) do
 799     with :ok <- :timer.sleep(timeout),
 800          %User{} = a <- Repo.get(User, a.id),
 801          %User{} = b <- Repo.get(User, b.id) do
 802       {:ok, a, b}
 803     else
 804       _e ->
 805         :error
 806     end
 807   end
 808
 809   def parse_bio(bio, user \\ %User{info: %{source_data: %{}}}) do
 810     mentions = Formatter.parse_mentions(bio)
 811     tags = Formatter.parse_tags(bio)
 812
 813     emoji =
 814       (user.info.source_data["tag"] || [])
 815       |> Enum.filter(fn %{"type" => t} -> t == "Emoji" end)
 816       |> Enum.map(fn %{"icon" => %{"url" => url}, "name" => name} ->
 817         {String.trim(name, ":"), url}
 818       end)
 819
 820     CommonUtils.format_input(bio, mentions, tags, "text/plain") |> Formatter.emojify(emoji)
 821   end
 822
 823   def tag(user_identifiers, tags) when is_list(user_identifiers) do
 824     Repo.transaction(fn ->
 825       for user_identifier <- user_identifiers, do: tag(user_identifier, tags)
 826     end)
 827   end
 828
 829   def tag(nickname, tags) when is_binary(nickname),
 830     do: tag(User.get_by_nickname(nickname), tags)
 831
 832   def tag(%User{} = user, tags),
 833     do: update_tags(user, Enum.uniq(user.tags ++ normalize_tags(tags)))
 834
 835   def untag(user_identifiers, tags) when is_list(user_identifiers) do
 836     Repo.transaction(fn ->
 837       for user_identifier <- user_identifiers, do: untag(user_identifier, tags)
 838     end)
 839   end
 840
 841   def untag(nickname, tags) when is_binary(nickname),
 842     do: untag(User.get_by_nickname(nickname), tags)
 843
 844   def untag(%User{} = user, tags), do: update_tags(user, user.tags -- normalize_tags(tags))
 845
 846   defp update_tags(%User{} = user, new_tags) do
 847     {:ok, updated_user} =
 848       user
 849       |> change(%{tags: new_tags})
 850       |> Repo.update()
 851
 852     updated_user
 853   end
 854
 855   defp normalize_tags(tags) do
 856     [tags]
 857     |> List.flatten()
 858     |> Enum.map(&String.downcase(&1))
 859   end
 860 end