git.squeep.com Git - akkoma/blob - lib/pleroma/user.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.User do
   6   use Ecto.Schema
   7
   8   import Ecto.{Changeset, Query}
   9   alias Pleroma.{Repo, User, Object, Web, Activity, Notification}
  10   alias Comeonin.Pbkdf2
  11   alias Pleroma.Formatter
  12   alias Pleroma.Web.CommonAPI.Utils, as: CommonUtils
  13   alias Pleroma.Web.{OStatus, Websub, OAuth}
  14   alias Pleroma.Web.ActivityPub.{Utils, ActivityPub}
  15
  16   require Logger
  17
  18   @type t :: %__MODULE__{}
  19
  20   @email_regex ~r/^[a-zA-Z0-9.!#$%&'*+\/=?^_`{|}~-]+@[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?(?:\.[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?)*$/
  21
  22   @strict_local_nickname_regex ~r/^[a-zA-Z\d]+$/
  23   @extended_local_nickname_regex ~r/^[a-zA-Z\d_-]+$/
  24
  25   schema "users" do
  26     field(:bio, :string)
  27     field(:email, :string)
  28     field(:name, :string)
  29     field(:nickname, :string)
  30     field(:password_hash, :string)
  31     field(:password, :string, virtual: true)
  32     field(:password_confirmation, :string, virtual: true)
  33     field(:following, {:array, :string}, default: [])
  34     field(:ap_id, :string)
  35     field(:avatar, :map)
  36     field(:local, :boolean, default: true)
  37     field(:follower_address, :string)
  38     field(:search_distance, :float, virtual: true)
  39     field(:tags, {:array, :string}, default: [])
  40     field(:last_refreshed_at, :naive_datetime)
  41     has_many(:notifications, Notification)
  42     embeds_one(:info, Pleroma.User.Info)
  43
  44     timestamps()
  45   end
  46
  47   def auth_active?(%User{local: false}), do: true
  48
  49   def auth_active?(%User{info: %User.Info{confirmation_pending: false}}), do: true
  50
  51   def auth_active?(%User{info: %User.Info{confirmation_pending: true}}),
  52     do: !Pleroma.Config.get([:instance, :account_activation_required])
  53
  54   def auth_active?(_), do: false
  55
  56   def visible_for?(user, for_user \\ nil)
  57
  58   def visible_for?(%User{id: user_id}, %User{id: for_id}) when user_id == for_id, do: true
  59
  60   def visible_for?(%User{} = user, for_user) do
  61     auth_active?(user) || superuser?(for_user)
  62   end
  63
  64   def visible_for?(_, _), do: false
  65
  66   def superuser?(%User{local: true, info: %User.Info{is_admin: true}}), do: true
  67   def superuser?(%User{local: true, info: %User.Info{is_moderator: true}}), do: true
  68   def superuser?(_), do: false
  69
  70   def avatar_url(user) do
  71     case user.avatar do
  72       %{"url" => [%{"href" => href} | _]} -> href
  73       _ -> "#{Web.base_url()}/images/avi.png"
  74     end
  75   end
  76
  77   def banner_url(user) do
  78     case user.info.banner do
  79       %{"url" => [%{"href" => href} | _]} -> href
  80       _ -> "#{Web.base_url()}/images/banner.png"
  81     end
  82   end
  83
  84   def profile_url(%User{info: %{source_data: %{"url" => url}}}), do: url
  85   def profile_url(%User{ap_id: ap_id}), do: ap_id
  86   def profile_url(_), do: nil
  87
  88   def ap_id(%User{nickname: nickname}) do
  89     "#{Web.base_url()}/users/#{nickname}"
  90   end
  91
  92   def ap_followers(%User{} = user) do
  93     "#{ap_id(user)}/followers"
  94   end
  95
  96   def follow_changeset(struct, params \\ %{}) do
  97     struct
  98     |> cast(params, [:following])
  99     |> validate_required([:following])
 100   end
 101
 102   def user_info(%User{} = user) do
 103     oneself = if user.local, do: 1, else: 0
 104
 105     %{
 106       following_count: length(user.following) - oneself,
 107       note_count: user.info.note_count,
 108       follower_count: user.info.follower_count,
 109       locked: user.info.locked,
 110       confirmation_pending: user.info.confirmation_pending,
 111       default_scope: user.info.default_scope
 112     }
 113   end
 114
 115   def remote_user_creation(params) do
 116     params =
 117       params
 118       |> Map.put(:info, params[:info] || %{})
 119
 120     info_cng = User.Info.remote_user_creation(%User.Info{}, params[:info])
 121
 122     changes =
 123       %User{}
 124       |> cast(params, [:bio, :name, :ap_id, :nickname, :avatar])
 125       |> validate_required([:name, :ap_id])
 126       |> unique_constraint(:nickname)
 127       |> validate_format(:nickname, @email_regex)
 128       |> validate_length(:bio, max: 5000)
 129       |> validate_length(:name, max: 100)
 130       |> put_change(:local, false)
 131       |> put_embed(:info, info_cng)
 132
 133     if changes.valid? do
 134       case info_cng.changes[:source_data] do
 135         %{"followers" => followers} ->
 136           changes
 137           |> put_change(:follower_address, followers)
 138
 139         _ ->
 140           followers = User.ap_followers(%User{nickname: changes.changes[:nickname]})
 141
 142           changes
 143           |> put_change(:follower_address, followers)
 144       end
 145     else
 146       changes
 147     end
 148   end
 149
 150   def update_changeset(struct, params \\ %{}) do
 151     struct
 152     |> cast(params, [:bio, :name, :avatar])
 153     |> unique_constraint(:nickname)
 154     |> validate_format(:nickname, local_nickname_regex())
 155     |> validate_length(:bio, max: 5000)
 156     |> validate_length(:name, min: 1, max: 100)
 157   end
 158
 159   def upgrade_changeset(struct, params \\ %{}) do
 160     params =
 161       params
 162       |> Map.put(:last_refreshed_at, NaiveDateTime.utc_now())
 163
 164     info_cng =
 165       struct.info
 166       |> User.Info.user_upgrade(params[:info])
 167
 168     struct
 169     |> cast(params, [:bio, :name, :follower_address, :avatar, :last_refreshed_at])
 170     |> unique_constraint(:nickname)
 171     |> validate_format(:nickname, local_nickname_regex())
 172     |> validate_length(:bio, max: 5000)
 173     |> validate_length(:name, max: 100)
 174     |> put_embed(:info, info_cng)
 175   end
 176
 177   def password_update_changeset(struct, params) do
 178     changeset =
 179       struct
 180       |> cast(params, [:password, :password_confirmation])
 181       |> validate_required([:password, :password_confirmation])
 182       |> validate_confirmation(:password)
 183
 184     OAuth.Token.delete_user_tokens(struct)
 185     OAuth.Authorization.delete_user_authorizations(struct)
 186
 187     if changeset.valid? do
 188       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 189
 190       changeset
 191       |> put_change(:password_hash, hashed)
 192     else
 193       changeset
 194     end
 195   end
 196
 197   def reset_password(user, data) do
 198     update_and_set_cache(password_update_changeset(user, data))
 199   end
 200
 201   def register_changeset(struct, params \\ %{}, opts \\ []) do
 202     confirmation_status =
 203       if opts[:confirmed] || !Pleroma.Config.get([:instance, :account_activation_required]) do
 204         :confirmed
 205       else
 206         :unconfirmed
 207       end
 208
 209     info_change = User.Info.confirmation_changeset(%User.Info{}, confirmation_status)
 210
 211     changeset =
 212       struct
 213       |> cast(params, [:bio, :email, :name, :nickname, :password, :password_confirmation])
 214       |> validate_required([:email, :name, :nickname, :password, :password_confirmation])
 215       |> validate_confirmation(:password)
 216       |> unique_constraint(:email)
 217       |> unique_constraint(:nickname)
 218       |> validate_exclusion(:nickname, Pleroma.Config.get([Pleroma.User, :restricted_nicknames]))
 219       |> validate_format(:nickname, local_nickname_regex())
 220       |> validate_format(:email, @email_regex)
 221       |> validate_length(:bio, max: 1000)
 222       |> validate_length(:name, min: 1, max: 100)
 223       |> put_change(:info, info_change)
 224
 225     if changeset.valid? do
 226       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 227       ap_id = User.ap_id(%User{nickname: changeset.changes[:nickname]})
 228       followers = User.ap_followers(%User{nickname: changeset.changes[:nickname]})
 229
 230       changeset
 231       |> put_change(:password_hash, hashed)
 232       |> put_change(:ap_id, ap_id)
 233       |> put_change(:following, [followers])
 234       |> put_change(:follower_address, followers)
 235     else
 236       changeset
 237     end
 238   end
 239
 240   defp autofollow_users(user) do
 241     candidates = Pleroma.Config.get([:instance, :autofollowed_nicknames])
 242
 243     autofollowed_users =
 244       from(u in User,
 245         where: u.local == true,
 246         where: u.nickname in ^candidates
 247       )
 248       |> Repo.all()
 249
 250     follow_all(user, autofollowed_users)
 251   end
 252
 253   @doc "Inserts provided changeset, performs post-registration actions (confirmation email sending etc.)"
 254   def register(%Ecto.Changeset{} = changeset) do
 255     with {:ok, user} <- Repo.insert(changeset),
 256          {:ok, _} <- try_send_confirmation_email(user),
 257          {:ok, user} <- autofollow_users(user) do
 258       {:ok, user}
 259     end
 260   end
 261
 262   def try_send_confirmation_email(%User{} = user) do
 263     if user.info.confirmation_pending &&
 264          Pleroma.Config.get([:instance, :account_activation_required]) do
 265       user
 266       |> Pleroma.UserEmail.account_confirmation_email()
 267       |> Pleroma.Mailer.deliver()
 268     else
 269       {:ok, :noop}
 270     end
 271   end
 272
 273   def needs_update?(%User{local: true}), do: false
 274
 275   def needs_update?(%User{local: false, last_refreshed_at: nil}), do: true
 276
 277   def needs_update?(%User{local: false} = user) do
 278     NaiveDateTime.diff(NaiveDateTime.utc_now(), user.last_refreshed_at) >= 86400
 279   end
 280
 281   def needs_update?(_), do: true
 282
 283   def maybe_direct_follow(%User{} = follower, %User{local: true, info: %{locked: true}}) do
 284     {:ok, follower}
 285   end
 286
 287   def maybe_direct_follow(%User{} = follower, %User{local: true} = followed) do
 288     follow(follower, followed)
 289   end
 290
 291   def maybe_direct_follow(%User{} = follower, %User{} = followed) do
 292     if not User.ap_enabled?(followed) do
 293       follow(follower, followed)
 294     else
 295       {:ok, follower}
 296     end
 297   end
 298
 299   def maybe_follow(%User{} = follower, %User{info: _info} = followed) do
 300     if not following?(follower, followed) do
 301       follow(follower, followed)
 302     else
 303       {:ok, follower}
 304     end
 305   end
 306
 307   @doc "A mass follow for local users. Ignores blocks and has no side effects"
 308   @spec follow_all(User.t(), list(User.t())) :: {atom(), User.t()}
 309   def follow_all(follower, followeds) do
 310     following =
 311       (follower.following ++ Enum.map(followeds, fn %{follower_address: fa} -> fa end))
 312       |> Enum.uniq()
 313
 314     {:ok, follower} =
 315       follower
 316       |> follow_changeset(%{following: following})
 317       |> update_and_set_cache
 318
 319     Enum.each(followeds, fn followed ->
 320       update_follower_count(followed)
 321     end)
 322
 323     {:ok, follower}
 324   end
 325
 326   def follow(%User{} = follower, %User{info: info} = followed) do
 327     user_config = Application.get_env(:pleroma, :user)
 328     deny_follow_blocked = Keyword.get(user_config, :deny_follow_blocked)
 329
 330     ap_followers = followed.follower_address
 331
 332     cond do
 333       following?(follower, followed) or info.deactivated ->
 334         {:error, "Could not follow user: #{followed.nickname} is already on your list."}
 335
 336       deny_follow_blocked and blocks?(followed, follower) ->
 337         {:error, "Could not follow user: #{followed.nickname} blocked you."}
 338
 339       true ->
 340         if !followed.local && follower.local && !ap_enabled?(followed) do
 341           Websub.subscribe(follower, followed)
 342         end
 343
 344         following =
 345           [ap_followers | follower.following]
 346           |> Enum.uniq()
 347
 348         follower =
 349           follower
 350           |> follow_changeset(%{following: following})
 351           |> update_and_set_cache
 352
 353         {:ok, _} = update_follower_count(followed)
 354
 355         follower
 356     end
 357   end
 358
 359   def unfollow(%User{} = follower, %User{} = followed) do
 360     ap_followers = followed.follower_address
 361
 362     if following?(follower, followed) and follower.ap_id != followed.ap_id do
 363       following =
 364         follower.following
 365         |> List.delete(ap_followers)
 366
 367       {:ok, follower} =
 368         follower
 369         |> follow_changeset(%{following: following})
 370         |> update_and_set_cache
 371
 372       {:ok, followed} = update_follower_count(followed)
 373
 374       {:ok, follower, Utils.fetch_latest_follow(follower, followed)}
 375     else
 376       {:error, "Not subscribed!"}
 377     end
 378   end
 379
 380   @spec following?(User.t(), User.t()) :: boolean
 381   def following?(%User{} = follower, %User{} = followed) do
 382     Enum.member?(follower.following, followed.follower_address)
 383   end
 384
 385   def follow_import(%User{} = follower, followed_identifiers)
 386       when is_list(followed_identifiers) do
 387     Enum.map(
 388       followed_identifiers,
 389       fn followed_identifier ->
 390         with %User{} = followed <- get_or_fetch(followed_identifier),
 391              {:ok, follower} <- maybe_direct_follow(follower, followed),
 392              {:ok, _} <- ActivityPub.follow(follower, followed) do
 393           followed
 394         else
 395           err ->
 396             Logger.debug("follow_import failed for #{followed_identifier} with: #{inspect(err)}")
 397             err
 398         end
 399       end
 400     )
 401   end
 402
 403   def locked?(%User{} = user) do
 404     user.info.locked || false
 405   end
 406
 407   def get_by_ap_id(ap_id) do
 408     Repo.get_by(User, ap_id: ap_id)
 409   end
 410
 411   # This is mostly an SPC migration fix. This guesses the user nickname (by taking the last part of the ap_id and the domain) and tries to get that user
 412   def get_by_guessed_nickname(ap_id) do
 413     domain = URI.parse(ap_id).host
 414     name = List.last(String.split(ap_id, "/"))
 415     nickname = "#{name}@#{domain}"
 416
 417     get_by_nickname(nickname)
 418   end
 419
 420   def update_and_set_cache(changeset) do
 421     with {:ok, user} <- Repo.update(changeset) do
 422       Cachex.put(:user_cache, "ap_id:#{user.ap_id}", user)
 423       Cachex.put(:user_cache, "nickname:#{user.nickname}", user)
 424       Cachex.put(:user_cache, "user_info:#{user.id}", user_info(user))
 425       {:ok, user}
 426     else
 427       e -> e
 428     end
 429   end
 430
 431   def invalidate_cache(user) do
 432     Cachex.del(:user_cache, "ap_id:#{user.ap_id}")
 433     Cachex.del(:user_cache, "nickname:#{user.nickname}")
 434     Cachex.del(:user_cache, "user_info:#{user.id}")
 435   end
 436
 437   def get_cached_by_ap_id(ap_id) do
 438     key = "ap_id:#{ap_id}"
 439     Cachex.fetch!(:user_cache, key, fn _ -> get_by_ap_id(ap_id) end)
 440   end
 441
 442   def get_cached_by_nickname(nickname) do
 443     key = "nickname:#{nickname}"
 444     Cachex.fetch!(:user_cache, key, fn _ -> get_or_fetch_by_nickname(nickname) end)
 445   end
 446
 447   def get_by_nickname(nickname) do
 448     Repo.get_by(User, nickname: nickname) ||
 449       if Regex.match?(~r(@#{Pleroma.Web.Endpoint.host()})i, nickname) do
 450         [local_nickname, _] = String.split(nickname, "@")
 451         Repo.get_by(User, nickname: local_nickname)
 452       end
 453   end
 454
 455   def get_by_nickname_or_email(nickname_or_email) do
 456     case user = Repo.get_by(User, nickname: nickname_or_email) do
 457       %User{} -> user
 458       nil -> Repo.get_by(User, email: nickname_or_email)
 459     end
 460   end
 461
 462   def get_cached_user_info(user) do
 463     key = "user_info:#{user.id}"
 464     Cachex.fetch!(:user_cache, key, fn _ -> user_info(user) end)
 465   end
 466
 467   def fetch_by_nickname(nickname) do
 468     ap_try = ActivityPub.make_user_from_nickname(nickname)
 469
 470     case ap_try do
 471       {:ok, user} -> {:ok, user}
 472       _ -> OStatus.make_user(nickname)
 473     end
 474   end
 475
 476   def get_or_fetch_by_nickname(nickname) do
 477     with %User{} = user <- get_by_nickname(nickname) do
 478       user
 479     else
 480       _e ->
 481         with [_nick, _domain] <- String.split(nickname, "@"),
 482              {:ok, user} <- fetch_by_nickname(nickname) do
 483           user
 484         else
 485           _e -> nil
 486         end
 487     end
 488   end
 489
 490   def get_followers_query(%User{id: id, follower_address: follower_address}) do
 491     from(
 492       u in User,
 493       where: fragment("? <@ ?", ^[follower_address], u.following),
 494       where: u.id != ^id
 495     )
 496   end
 497
 498   def get_followers(user) do
 499     q = get_followers_query(user)
 500
 501     {:ok, Repo.all(q)}
 502   end
 503
 504   def get_friends_query(%User{id: id, following: following}) do
 505     from(
 506       u in User,
 507       where: u.follower_address in ^following,
 508       where: u.id != ^id
 509     )
 510   end
 511
 512   def get_friends(user) do
 513     q = get_friends_query(user)
 514
 515     {:ok, Repo.all(q)}
 516   end
 517
 518   def get_follow_requests_query(%User{} = user) do
 519     from(
 520       a in Activity,
 521       where:
 522         fragment(
 523           "? ->> 'type' = 'Follow'",
 524           a.data
 525         ),
 526       where:
 527         fragment(
 528           "? ->> 'state' = 'pending'",
 529           a.data
 530         ),
 531       where:
 532         fragment(
 533           "? @> ?",
 534           a.data,
 535           ^%{"object" => user.ap_id}
 536         )
 537     )
 538   end
 539
 540   def get_follow_requests(%User{} = user) do
 541     q = get_follow_requests_query(user)
 542     reqs = Repo.all(q)
 543
 544     users =
 545       Enum.map(reqs, fn req -> req.actor end)
 546       |> Enum.uniq()
 547       |> Enum.map(fn ap_id -> get_by_ap_id(ap_id) end)
 548       |> Enum.filter(fn u -> !is_nil(u) end)
 549       |> Enum.filter(fn u -> !following?(u, user) end)
 550
 551     {:ok, users}
 552   end
 553
 554   def increase_note_count(%User{} = user) do
 555     info_cng = User.Info.add_to_note_count(user.info, 1)
 556
 557     cng =
 558       change(user)
 559       |> put_embed(:info, info_cng)
 560
 561     update_and_set_cache(cng)
 562   end
 563
 564   def decrease_note_count(%User{} = user) do
 565     info_cng = User.Info.add_to_note_count(user.info, -1)
 566
 567     cng =
 568       change(user)
 569       |> put_embed(:info, info_cng)
 570
 571     update_and_set_cache(cng)
 572   end
 573
 574   def update_note_count(%User{} = user) do
 575     note_count_query =
 576       from(
 577         a in Object,
 578         where: fragment("?->>'actor' = ? and ?->>'type' = 'Note'", a.data, ^user.ap_id, a.data),
 579         select: count(a.id)
 580       )
 581
 582     note_count = Repo.one(note_count_query)
 583
 584     info_cng = User.Info.set_note_count(user.info, note_count)
 585
 586     cng =
 587       change(user)
 588       |> put_embed(:info, info_cng)
 589
 590     update_and_set_cache(cng)
 591   end
 592
 593   def update_follower_count(%User{} = user) do
 594     follower_count_query =
 595       from(
 596         u in User,
 597         where: ^user.follower_address in u.following,
 598         where: u.id != ^user.id,
 599         select: count(u.id)
 600       )
 601
 602     follower_count = Repo.one(follower_count_query)
 603
 604     info_cng =
 605       user.info
 606       |> User.Info.set_follower_count(follower_count)
 607
 608     cng =
 609       change(user)
 610       |> put_embed(:info, info_cng)
 611
 612     update_and_set_cache(cng)
 613   end
 614
 615   def get_users_from_set_query(ap_ids, false) do
 616     from(
 617       u in User,
 618       where: u.ap_id in ^ap_ids
 619     )
 620   end
 621
 622   def get_users_from_set_query(ap_ids, true) do
 623     query = get_users_from_set_query(ap_ids, false)
 624
 625     from(
 626       u in query,
 627       where: u.local == true
 628     )
 629   end
 630
 631   def get_users_from_set(ap_ids, local_only \\ true) do
 632     get_users_from_set_query(ap_ids, local_only)
 633     |> Repo.all()
 634   end
 635
 636   def get_recipients_from_activity(%Activity{recipients: to}) do
 637     query =
 638       from(
 639         u in User,
 640         where: u.ap_id in ^to,
 641         or_where: fragment("? && ?", u.following, ^to)
 642       )
 643
 644     query = from(u in query, where: u.local == true)
 645
 646     Repo.all(query)
 647   end
 648
 649   def search(query, resolve \\ false) do
 650     # strip the beginning @ off if there is a query
 651     query = String.trim_leading(query, "@")
 652
 653     if resolve do
 654       User.get_or_fetch_by_nickname(query)
 655     end
 656
 657     inner =
 658       from(
 659         u in User,
 660         select_merge: %{
 661           search_distance:
 662             fragment(
 663               "? <-> (? || coalesce(?, ''))",
 664               ^query,
 665               u.nickname,
 666               u.name
 667             )
 668         },
 669         where: not is_nil(u.nickname)
 670       )
 671
 672     q =
 673       from(
 674         s in subquery(inner),
 675         order_by: s.search_distance,
 676         limit: 20
 677       )
 678
 679     Repo.all(q)
 680   end
 681
 682   def blocks_import(%User{} = blocker, blocked_identifiers) when is_list(blocked_identifiers) do
 683     Enum.map(
 684       blocked_identifiers,
 685       fn blocked_identifier ->
 686         with %User{} = blocked <- get_or_fetch(blocked_identifier),
 687              {:ok, blocker} <- block(blocker, blocked),
 688              {:ok, _} <- ActivityPub.block(blocker, blocked) do
 689           blocked
 690         else
 691           err ->
 692             Logger.debug("blocks_import failed for #{blocked_identifier} with: #{inspect(err)}")
 693             err
 694         end
 695       end
 696     )
 697   end
 698
 699   def block(blocker, %User{ap_id: ap_id} = blocked) do
 700     # sever any follow relationships to prevent leaks per activitypub (Pleroma issue #213)
 701     blocker =
 702       if following?(blocker, blocked) do
 703         {:ok, blocker, _} = unfollow(blocker, blocked)
 704         blocker
 705       else
 706         blocker
 707       end
 708
 709     if following?(blocked, blocker) do
 710       unfollow(blocked, blocker)
 711     end
 712
 713     info_cng =
 714       blocker.info
 715       |> User.Info.add_to_block(ap_id)
 716
 717     cng =
 718       change(blocker)
 719       |> put_embed(:info, info_cng)
 720
 721     update_and_set_cache(cng)
 722   end
 723
 724   # helper to handle the block given only an actor's AP id
 725   def block(blocker, %{ap_id: ap_id}) do
 726     block(blocker, User.get_by_ap_id(ap_id))
 727   end
 728
 729   def unblock(blocker, %{ap_id: ap_id}) do
 730     info_cng =
 731       blocker.info
 732       |> User.Info.remove_from_block(ap_id)
 733
 734     cng =
 735       change(blocker)
 736       |> put_embed(:info, info_cng)
 737
 738     update_and_set_cache(cng)
 739   end
 740
 741   def blocks?(user, %{ap_id: ap_id}) do
 742     blocks = user.info.blocks
 743     domain_blocks = user.info.domain_blocks
 744     %{host: host} = URI.parse(ap_id)
 745
 746     Enum.member?(blocks, ap_id) ||
 747       Enum.any?(domain_blocks, fn domain ->
 748         host == domain
 749       end)
 750   end
 751
 752   def blocked_users(user),
 753     do: Repo.all(from(u in User, where: u.ap_id in ^user.info.blocks))
 754
 755   def block_domain(user, domain) do
 756     info_cng =
 757       user.info
 758       |> User.Info.add_to_domain_block(domain)
 759
 760     cng =
 761       change(user)
 762       |> put_embed(:info, info_cng)
 763
 764     update_and_set_cache(cng)
 765   end
 766
 767   def unblock_domain(user, domain) do
 768     info_cng =
 769       user.info
 770       |> User.Info.remove_from_domain_block(domain)
 771
 772     cng =
 773       change(user)
 774       |> put_embed(:info, info_cng)
 775
 776     update_and_set_cache(cng)
 777   end
 778
 779   def local_user_query() do
 780     from(
 781       u in User,
 782       where: u.local == true,
 783       where: not is_nil(u.nickname)
 784     )
 785   end
 786
 787   def moderator_user_query() do
 788     from(
 789       u in User,
 790       where: u.local == true,
 791       where: fragment("?->'is_moderator' @> 'true'", u.info)
 792     )
 793   end
 794
 795   def deactivate(%User{} = user, status \\ true) do
 796     info_cng = User.Info.set_activation_status(user.info, status)
 797
 798     cng =
 799       change(user)
 800       |> put_embed(:info, info_cng)
 801
 802     update_and_set_cache(cng)
 803   end
 804
 805   def delete(%User{} = user) do
 806     {:ok, user} = User.deactivate(user)
 807
 808     # Remove all relationships
 809     {:ok, followers} = User.get_followers(user)
 810
 811     followers
 812     |> Enum.each(fn follower -> User.unfollow(follower, user) end)
 813
 814     {:ok, friends} = User.get_friends(user)
 815
 816     friends
 817     |> Enum.each(fn followed -> User.unfollow(user, followed) end)
 818
 819     query = from(a in Activity, where: a.actor == ^user.ap_id)
 820
 821     Repo.all(query)
 822     |> Enum.each(fn activity ->
 823       case activity.data["type"] do
 824         "Create" ->
 825           ActivityPub.delete(Object.normalize(activity.data["object"]))
 826
 827         # TODO: Do something with likes, follows, repeats.
 828         _ ->
 829           "Doing nothing"
 830       end
 831     end)
 832
 833     {:ok, user}
 834   end
 835
 836   def html_filter_policy(%User{info: %{no_rich_text: true}}) do
 837     Pleroma.HTML.Scrubber.TwitterText
 838   end
 839
 840   @default_scrubbers Pleroma.Config.get([:markup, :scrub_policy])
 841
 842   def html_filter_policy(_), do: @default_scrubbers
 843
 844   def get_or_fetch_by_ap_id(ap_id) do
 845     user = get_by_ap_id(ap_id)
 846
 847     if !is_nil(user) and !User.needs_update?(user) do
 848       user
 849     else
 850       ap_try = ActivityPub.make_user_from_ap_id(ap_id)
 851
 852       case ap_try do
 853         {:ok, user} ->
 854           user
 855
 856         _ ->
 857           case OStatus.make_user(ap_id) do
 858             {:ok, user} -> user
 859             _ -> {:error, "Could not fetch by AP id"}
 860           end
 861       end
 862     end
 863   end
 864
 865   def get_or_create_instance_user do
 866     relay_uri = "#{Pleroma.Web.Endpoint.url()}/relay"
 867
 868     if user = get_by_ap_id(relay_uri) do
 869       user
 870     else
 871       changes =
 872         %User{info: %User.Info{}}
 873         |> cast(%{}, [:ap_id, :nickname, :local])
 874         |> put_change(:ap_id, relay_uri)
 875         |> put_change(:nickname, nil)
 876         |> put_change(:local, true)
 877         |> put_change(:follower_address, relay_uri <> "/followers")
 878
 879       {:ok, user} = Repo.insert(changes)
 880       user
 881     end
 882   end
 883
 884   # AP style
 885   def public_key_from_info(%{
 886         source_data: %{"publicKey" => %{"publicKeyPem" => public_key_pem}}
 887       }) do
 888     key =
 889       public_key_pem
 890       |> :public_key.pem_decode()
 891       |> hd()
 892       |> :public_key.pem_entry_decode()
 893
 894     {:ok, key}
 895   end
 896
 897   # OStatus Magic Key
 898   def public_key_from_info(%{magic_key: magic_key}) do
 899     {:ok, Pleroma.Web.Salmon.decode_key(magic_key)}
 900   end
 901
 902   def get_public_key_for_ap_id(ap_id) do
 903     with %User{} = user <- get_or_fetch_by_ap_id(ap_id),
 904          {:ok, public_key} <- public_key_from_info(user.info) do
 905       {:ok, public_key}
 906     else
 907       _ -> :error
 908     end
 909   end
 910
 911   defp blank?(""), do: nil
 912   defp blank?(n), do: n
 913
 914   def insert_or_update_user(data) do
 915     data =
 916       data
 917       |> Map.put(:name, blank?(data[:name]) || data[:nickname])
 918
 919     cs = User.remote_user_creation(data)
 920
 921     Repo.insert(cs, on_conflict: :replace_all, conflict_target: :nickname)
 922   end
 923
 924   def ap_enabled?(%User{local: true}), do: true
 925   def ap_enabled?(%User{info: info}), do: info.ap_enabled
 926   def ap_enabled?(_), do: false
 927
 928   @doc "Gets or fetch a user by uri or nickname."
 929   @spec get_or_fetch(String.t()) :: User.t()
 930   def get_or_fetch("http" <> _host = uri), do: get_or_fetch_by_ap_id(uri)
 931   def get_or_fetch(nickname), do: get_or_fetch_by_nickname(nickname)
 932
 933   # wait a period of time and return newest version of the User structs
 934   # this is because we have synchronous follow APIs and need to simulate them
 935   # with an async handshake
 936   def wait_and_refresh(_, %User{local: true} = a, %User{local: true} = b) do
 937     with %User{} = a <- Repo.get(User, a.id),
 938          %User{} = b <- Repo.get(User, b.id) do
 939       {:ok, a, b}
 940     else
 941       _e ->
 942         :error
 943     end
 944   end
 945
 946   def wait_and_refresh(timeout, %User{} = a, %User{} = b) do
 947     with :ok <- :timer.sleep(timeout),
 948          %User{} = a <- Repo.get(User, a.id),
 949          %User{} = b <- Repo.get(User, b.id) do
 950       {:ok, a, b}
 951     else
 952       _e ->
 953         :error
 954     end
 955   end
 956
 957   def parse_bio(bio, user \\ %User{info: %{source_data: %{}}})
 958   def parse_bio(nil, _user), do: ""
 959   def parse_bio(bio, _user) when bio == "", do: bio
 960
 961   def parse_bio(bio, user) do
 962     mentions = Formatter.parse_mentions(bio)
 963     tags = Formatter.parse_tags(bio)
 964
 965     emoji =
 966       (user.info.source_data["tag"] || [])
 967       |> Enum.filter(fn %{"type" => t} -> t == "Emoji" end)
 968       |> Enum.map(fn %{"icon" => %{"url" => url}, "name" => name} ->
 969         {String.trim(name, ":"), url}
 970       end)
 971
 972     bio
 973     |> CommonUtils.format_input(mentions, tags, "text/plain")
 974     |> Formatter.emojify(emoji)
 975   end
 976
 977   def tag(user_identifiers, tags) when is_list(user_identifiers) do
 978     Repo.transaction(fn ->
 979       for user_identifier <- user_identifiers, do: tag(user_identifier, tags)
 980     end)
 981   end
 982
 983   def tag(nickname, tags) when is_binary(nickname),
 984     do: tag(User.get_by_nickname(nickname), tags)
 985
 986   def tag(%User{} = user, tags),
 987     do: update_tags(user, Enum.uniq((user.tags || []) ++ normalize_tags(tags)))
 988
 989   def untag(user_identifiers, tags) when is_list(user_identifiers) do
 990     Repo.transaction(fn ->
 991       for user_identifier <- user_identifiers, do: untag(user_identifier, tags)
 992     end)
 993   end
 994
 995   def untag(nickname, tags) when is_binary(nickname),
 996     do: untag(User.get_by_nickname(nickname), tags)
 997
 998   def untag(%User{} = user, tags),
 999     do: update_tags(user, (user.tags || []) -- normalize_tags(tags))
1000
1001   defp update_tags(%User{} = user, new_tags) do
1002     {:ok, updated_user} =
1003       user
1004       |> change(%{tags: new_tags})
1005       |> Repo.update()
1006
1007     updated_user
1008   end
1009
1010   defp normalize_tags(tags) do
1011     [tags]
1012     |> List.flatten()
1013     |> Enum.map(&String.downcase(&1))
1014   end
1015
1016   defp local_nickname_regex() do
1017     if Pleroma.Config.get([:instance, :extended_nickname_format]) do
1018       @extended_local_nickname_regex
1019     else
1020       @strict_local_nickname_regex
1021     end
1022   end
1023 end