git.squeep.com Git - akkoma/blob - lib/pleroma/user.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.User do
   6   use Ecto.Schema
   7
   8   import Ecto.{Changeset, Query}
   9   alias Pleroma.{Repo, User, Object, Web, Activity, Notification}
  10   alias Comeonin.Pbkdf2
  11   alias Pleroma.Formatter
  12   alias Pleroma.Web.CommonAPI.Utils, as: CommonUtils
  13   alias Pleroma.Web.{OStatus, Websub, OAuth}
  14   alias Pleroma.Web.ActivityPub.{Utils, ActivityPub}
  15
  16   require Logger
  17
  18   @type t :: %__MODULE__{}
  19
  20   @email_regex ~r/^[a-zA-Z0-9.!#$%&'*+\/=?^_`{|}~-]+@[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?(?:\.[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?)*$/
  21
  22   @strict_local_nickname_regex ~r/^[a-zA-Z\d]+$/
  23   @extended_local_nickname_regex ~r/^[a-zA-Z\d_-]+$/
  24
  25   schema "users" do
  26     field(:bio, :string)
  27     field(:email, :string)
  28     field(:name, :string)
  29     field(:nickname, :string)
  30     field(:password_hash, :string)
  31     field(:password, :string, virtual: true)
  32     field(:password_confirmation, :string, virtual: true)
  33     field(:following, {:array, :string}, default: [])
  34     field(:ap_id, :string)
  35     field(:avatar, :map)
  36     field(:local, :boolean, default: true)
  37     field(:follower_address, :string)
  38     field(:search_distance, :float, virtual: true)
  39     field(:tags, {:array, :string}, default: [])
  40     field(:last_refreshed_at, :naive_datetime)
  41     has_many(:notifications, Notification)
  42     embeds_one(:info, Pleroma.User.Info)
  43
  44     timestamps()
  45   end
  46
  47   def auth_active?(%User{local: false}), do: true
  48
  49   def auth_active?(%User{info: %User.Info{confirmation_pending: false}}), do: true
  50
  51   def auth_active?(%User{info: %User.Info{confirmation_pending: true}}),
  52     do: !Pleroma.Config.get([:instance, :account_activation_required])
  53
  54   def auth_active?(_), do: false
  55
  56   def visible_for?(user, for_user \\ nil)
  57
  58   def visible_for?(%User{id: user_id}, %User{id: for_id}) when user_id == for_id, do: true
  59
  60   def visible_for?(%User{} = user, for_user) do
  61     auth_active?(user) || superuser?(for_user)
  62   end
  63
  64   def visible_for?(_, _), do: false
  65
  66   def superuser?(%User{local: true, info: %User.Info{is_admin: true}}), do: true
  67   def superuser?(%User{local: true, info: %User.Info{is_moderator: true}}), do: true
  68   def superuser?(_), do: false
  69
  70   def avatar_url(user) do
  71     case user.avatar do
  72       %{"url" => [%{"href" => href} | _]} -> href
  73       _ -> "#{Web.base_url()}/images/avi.png"
  74     end
  75   end
  76
  77   def banner_url(user) do
  78     case user.info.banner do
  79       %{"url" => [%{"href" => href} | _]} -> href
  80       _ -> "#{Web.base_url()}/images/banner.png"
  81     end
  82   end
  83
  84   def profile_url(%User{info: %{source_data: %{"url" => url}}}), do: url
  85   def profile_url(%User{ap_id: ap_id}), do: ap_id
  86   def profile_url(_), do: nil
  87
  88   def ap_id(%User{nickname: nickname}) do
  89     "#{Web.base_url()}/users/#{nickname}"
  90   end
  91
  92   def ap_followers(%User{} = user) do
  93     "#{ap_id(user)}/followers"
  94   end
  95
  96   def follow_changeset(struct, params \\ %{}) do
  97     struct
  98     |> cast(params, [:following])
  99     |> validate_required([:following])
 100   end
 101
 102   def user_info(%User{} = user) do
 103     oneself = if user.local, do: 1, else: 0
 104
 105     %{
 106       following_count: length(user.following) - oneself,
 107       note_count: user.info.note_count,
 108       follower_count: user.info.follower_count,
 109       locked: user.info.locked,
 110       confirmation_pending: user.info.confirmation_pending,
 111       default_scope: user.info.default_scope
 112     }
 113   end
 114
 115   def remote_user_creation(params) do
 116     params =
 117       params
 118       |> Map.put(:info, params[:info] || %{})
 119
 120     info_cng = User.Info.remote_user_creation(%User.Info{}, params[:info])
 121
 122     changes =
 123       %User{}
 124       |> cast(params, [:bio, :name, :ap_id, :nickname, :avatar])
 125       |> validate_required([:name, :ap_id])
 126       |> unique_constraint(:nickname)
 127       |> validate_format(:nickname, @email_regex)
 128       |> validate_length(:bio, max: 5000)
 129       |> validate_length(:name, max: 100)
 130       |> put_change(:local, false)
 131       |> put_embed(:info, info_cng)
 132
 133     if changes.valid? do
 134       case info_cng.changes[:source_data] do
 135         %{"followers" => followers} ->
 136           changes
 137           |> put_change(:follower_address, followers)
 138
 139         _ ->
 140           followers = User.ap_followers(%User{nickname: changes.changes[:nickname]})
 141
 142           changes
 143           |> put_change(:follower_address, followers)
 144       end
 145     else
 146       changes
 147     end
 148   end
 149
 150   def update_changeset(struct, params \\ %{}) do
 151     struct
 152     |> cast(params, [:bio, :name, :avatar])
 153     |> unique_constraint(:nickname)
 154     |> validate_format(:nickname, local_nickname_regex())
 155     |> validate_length(:bio, max: 5000)
 156     |> validate_length(:name, min: 1, max: 100)
 157   end
 158
 159   def upgrade_changeset(struct, params \\ %{}) do
 160     params =
 161       params
 162       |> Map.put(:last_refreshed_at, NaiveDateTime.utc_now())
 163
 164     info_cng =
 165       struct.info
 166       |> User.Info.user_upgrade(params[:info])
 167
 168     struct
 169     |> cast(params, [:bio, :name, :follower_address, :avatar, :last_refreshed_at])
 170     |> unique_constraint(:nickname)
 171     |> validate_format(:nickname, local_nickname_regex())
 172     |> validate_length(:bio, max: 5000)
 173     |> validate_length(:name, max: 100)
 174     |> put_embed(:info, info_cng)
 175   end
 176
 177   def password_update_changeset(struct, params) do
 178     changeset =
 179       struct
 180       |> cast(params, [:password, :password_confirmation])
 181       |> validate_required([:password, :password_confirmation])
 182       |> validate_confirmation(:password)
 183
 184     OAuth.Token.delete_user_tokens(struct)
 185     OAuth.Authorization.delete_user_authorizations(struct)
 186
 187     if changeset.valid? do
 188       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 189
 190       changeset
 191       |> put_change(:password_hash, hashed)
 192     else
 193       changeset
 194     end
 195   end
 196
 197   def reset_password(user, data) do
 198     update_and_set_cache(password_update_changeset(user, data))
 199   end
 200
 201   def register_changeset(struct, params \\ %{}, opts \\ []) do
 202     confirmation_status =
 203       if opts[:confirmed] || !Pleroma.Config.get([:instance, :account_activation_required]) do
 204         :confirmed
 205       else
 206         :unconfirmed
 207       end
 208
 209     info_change = User.Info.confirmation_changeset(%User.Info{}, confirmation_status)
 210
 211     changeset =
 212       struct
 213       |> cast(params, [:bio, :email, :name, :nickname, :password, :password_confirmation])
 214       |> validate_required([:email, :name, :nickname, :password, :password_confirmation])
 215       |> validate_confirmation(:password)
 216       |> unique_constraint(:email)
 217       |> unique_constraint(:nickname)
 218       |> validate_exclusion(:nickname, Pleroma.Config.get([Pleroma.User, :restricted_nicknames]))
 219       |> validate_format(:nickname, local_nickname_regex())
 220       |> validate_format(:email, @email_regex)
 221       |> validate_length(:bio, max: 1000)
 222       |> validate_length(:name, min: 1, max: 100)
 223       |> put_change(:info, info_change)
 224
 225     if changeset.valid? do
 226       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 227       ap_id = User.ap_id(%User{nickname: changeset.changes[:nickname]})
 228       followers = User.ap_followers(%User{nickname: changeset.changes[:nickname]})
 229
 230       changeset
 231       |> put_change(:password_hash, hashed)
 232       |> put_change(:ap_id, ap_id)
 233       |> put_change(:following, [followers])
 234       |> put_change(:follower_address, followers)
 235     else
 236       changeset
 237     end
 238   end
 239
 240   defp autofollow_users(user) do
 241     candidates = Pleroma.Config.get([:instance, :autofollowed_nicknames])
 242
 243     autofollowed_users =
 244       from(u in User,
 245         where: u.local == true,
 246         where: u.nickname in ^candidates
 247       )
 248       |> Repo.all()
 249
 250     follow_all(user, autofollowed_users)
 251   end
 252
 253   @doc "Inserts provided changeset, performs post-registration actions (confirmation email sending etc.)"
 254   def register(%Ecto.Changeset{} = changeset) do
 255     with {:ok, user} <- Repo.insert(changeset),
 256          {:ok, _} <- try_send_confirmation_email(user),
 257          {:ok, user} <- autofollow_users(user) do
 258       {:ok, user}
 259     end
 260   end
 261
 262   def try_send_confirmation_email(%User{} = user) do
 263     if user.info.confirmation_pending &&
 264          Pleroma.Config.get([:instance, :account_activation_required]) do
 265       user
 266       |> Pleroma.UserEmail.account_confirmation_email()
 267       |> Pleroma.Mailer.deliver()
 268     else
 269       {:ok, :noop}
 270     end
 271   end
 272
 273   def needs_update?(%User{local: true}), do: false
 274
 275   def needs_update?(%User{local: false, last_refreshed_at: nil}), do: true
 276
 277   def needs_update?(%User{local: false} = user) do
 278     NaiveDateTime.diff(NaiveDateTime.utc_now(), user.last_refreshed_at) >= 86400
 279   end
 280
 281   def needs_update?(_), do: true
 282
 283   def maybe_direct_follow(%User{} = follower, %User{local: true, info: %{locked: true}}) do
 284     {:ok, follower}
 285   end
 286
 287   def maybe_direct_follow(%User{} = follower, %User{local: true} = followed) do
 288     follow(follower, followed)
 289   end
 290
 291   def maybe_direct_follow(%User{} = follower, %User{} = followed) do
 292     if not User.ap_enabled?(followed) do
 293       follow(follower, followed)
 294     else
 295       {:ok, follower}
 296     end
 297   end
 298
 299   def maybe_follow(%User{} = follower, %User{info: _info} = followed) do
 300     if not following?(follower, followed) do
 301       follow(follower, followed)
 302     else
 303       {:ok, follower}
 304     end
 305   end
 306
 307   @doc "A mass follow for local users. Ignores blocks and has no side effects"
 308   @spec follow_all(User.t(), list(User.t())) :: {atom(), User.t()}
 309   def follow_all(follower, followeds) do
 310     following =
 311       (follower.following ++ Enum.map(followeds, fn %{follower_address: fa} -> fa end))
 312       |> Enum.uniq()
 313
 314     {:ok, follower} =
 315       follower
 316       |> follow_changeset(%{following: following})
 317       |> update_and_set_cache
 318
 319     Enum.each(followeds, fn followed ->
 320       update_follower_count(followed)
 321     end)
 322
 323     {:ok, follower}
 324   end
 325
 326   def follow(%User{} = follower, %User{info: info} = followed) do
 327     user_config = Application.get_env(:pleroma, :user)
 328     deny_follow_blocked = Keyword.get(user_config, :deny_follow_blocked)
 329
 330     ap_followers = followed.follower_address
 331
 332     cond do
 333       following?(follower, followed) or info.deactivated ->
 334         {:error, "Could not follow user: #{followed.nickname} is already on your list."}
 335
 336       deny_follow_blocked and blocks?(followed, follower) ->
 337         {:error, "Could not follow user: #{followed.nickname} blocked you."}
 338
 339       true ->
 340         if !followed.local && follower.local && !ap_enabled?(followed) do
 341           Websub.subscribe(follower, followed)
 342         end
 343
 344         following =
 345           [ap_followers | follower.following]
 346           |> Enum.uniq()
 347
 348         follower =
 349           follower
 350           |> follow_changeset(%{following: following})
 351           |> update_and_set_cache
 352
 353         {:ok, _} = update_follower_count(followed)
 354
 355         follower
 356     end
 357   end
 358
 359   def unfollow(%User{} = follower, %User{} = followed) do
 360     ap_followers = followed.follower_address
 361
 362     if following?(follower, followed) and follower.ap_id != followed.ap_id do
 363       following =
 364         follower.following
 365         |> List.delete(ap_followers)
 366
 367       {:ok, follower} =
 368         follower
 369         |> follow_changeset(%{following: following})
 370         |> update_and_set_cache
 371
 372       {:ok, followed} = update_follower_count(followed)
 373
 374       {:ok, follower, Utils.fetch_latest_follow(follower, followed)}
 375     else
 376       {:error, "Not subscribed!"}
 377     end
 378   end
 379
 380   @spec following?(User.t(), User.t()) :: boolean
 381   def following?(%User{} = follower, %User{} = followed) do
 382     Enum.member?(follower.following, followed.follower_address)
 383   end
 384
 385   def follow_import(%User{} = follower, followed_identifiers)
 386       when is_list(followed_identifiers) do
 387     Enum.map(
 388       followed_identifiers,
 389       fn followed_identifier ->
 390         with %User{} = followed <- get_or_fetch(followed_identifier),
 391              {:ok, follower} <- maybe_direct_follow(follower, followed),
 392              {:ok, _} <- ActivityPub.follow(follower, followed) do
 393           followed
 394         else
 395           err ->
 396             Logger.debug("follow_import failed for #{followed_identifier} with: #{inspect(err)}")
 397             err
 398         end
 399       end
 400     )
 401   end
 402
 403   def locked?(%User{} = user) do
 404     user.info.locked || false
 405   end
 406
 407   def get_by_id(id) do
 408     Repo.get_by(User, id: id)
 409   end
 410
 411   def get_by_ap_id(ap_id) do
 412     Repo.get_by(User, ap_id: ap_id)
 413   end
 414
 415   # This is mostly an SPC migration fix. This guesses the user nickname (by taking the last part of the ap_id and the domain) and tries to get that user
 416   def get_by_guessed_nickname(ap_id) do
 417     domain = URI.parse(ap_id).host
 418     name = List.last(String.split(ap_id, "/"))
 419     nickname = "#{name}@#{domain}"
 420
 421     get_by_nickname(nickname)
 422   end
 423
 424   def update_and_set_cache(changeset) do
 425     with {:ok, user} <- Repo.update(changeset) do
 426       Cachex.put(:user_cache, "ap_id:#{user.ap_id}", user)
 427       Cachex.put(:user_cache, "nickname:#{user.nickname}", user)
 428       Cachex.put(:user_cache, "user_info:#{user.id}", user_info(user))
 429       {:ok, user}
 430     else
 431       e -> e
 432     end
 433   end
 434
 435   def invalidate_cache(user) do
 436     Cachex.del(:user_cache, "ap_id:#{user.ap_id}")
 437     Cachex.del(:user_cache, "nickname:#{user.nickname}")
 438     Cachex.del(:user_cache, "user_info:#{user.id}")
 439   end
 440
 441   def get_cached_by_ap_id(ap_id) do
 442     key = "ap_id:#{ap_id}"
 443     Cachex.fetch!(:user_cache, key, fn _ -> get_by_ap_id(ap_id) end)
 444   end
 445
 446   def get_cached_by_id(id) do
 447     key = "id:#{id}"
 448
 449     ap_id =
 450       Cachex.fetch!(:user_cache, key, fn _ ->
 451         user = get_by_id(id)
 452         Cachex.put(:user_cache, "ap_id:#{user.ap_id}", user)
 453         {:commit, user.ap_id}
 454       end)
 455
 456     get_cached_by_ap_id(ap_id)
 457   end
 458
 459   def get_cached_by_nickname(nickname) do
 460     key = "nickname:#{nickname}"
 461     Cachex.fetch!(:user_cache, key, fn _ -> get_or_fetch_by_nickname(nickname) end)
 462   end
 463
 464   def get_cached_by_nickname_or_id(nickname_or_id) do
 465       get_cached_by_id(maybe_id) || get_cached_by_nickname(nickname_or_id)
 466   end
 467
 468   def get_by_nickname(nickname) do
 469     Repo.get_by(User, nickname: nickname) ||
 470       if Regex.match?(~r(@#{Pleroma.Web.Endpoint.host()})i, nickname) do
 471         [local_nickname, _] = String.split(nickname, "@")
 472         Repo.get_by(User, nickname: local_nickname)
 473       end
 474   end
 475
 476   def get_by_nickname_or_email(nickname_or_email) do
 477     case user = Repo.get_by(User, nickname: nickname_or_email) do
 478       %User{} -> user
 479       nil -> Repo.get_by(User, email: nickname_or_email)
 480     end
 481   end
 482
 483   def get_cached_user_info(user) do
 484     key = "user_info:#{user.id}"
 485     Cachex.fetch!(:user_cache, key, fn _ -> user_info(user) end)
 486   end
 487
 488   def fetch_by_nickname(nickname) do
 489     ap_try = ActivityPub.make_user_from_nickname(nickname)
 490
 491     case ap_try do
 492       {:ok, user} -> {:ok, user}
 493       _ -> OStatus.make_user(nickname)
 494     end
 495   end
 496
 497   def get_or_fetch_by_nickname(nickname) do
 498     with %User{} = user <- get_by_nickname(nickname) do
 499       user
 500     else
 501       _e ->
 502         with [_nick, _domain] <- String.split(nickname, "@"),
 503              {:ok, user} <- fetch_by_nickname(nickname) do
 504           user
 505         else
 506           _e -> nil
 507         end
 508     end
 509   end
 510
 511   def get_followers_query(%User{id: id, follower_address: follower_address}, nil) do
 512     from(
 513       u in User,
 514       where: fragment("? <@ ?", ^[follower_address], u.following),
 515       where: u.id != ^id
 516     )
 517   end
 518
 519   def get_followers_query(user, page) do
 520     from(
 521       u in get_followers_query(user, nil),
 522       limit: 20,
 523       offset: ^((page - 1) * 20)
 524     )
 525   end
 526
 527   def get_followers_query(user), do: get_followers_query(user, nil)
 528
 529   def get_followers(user, page \\ nil) do
 530     q = get_followers_query(user, page)
 531
 532     {:ok, Repo.all(q)}
 533   end
 534
 535   def get_friends_query(%User{id: id, following: following}, nil) do
 536     from(
 537       u in User,
 538       where: u.follower_address in ^following,
 539       where: u.id != ^id
 540     )
 541   end
 542
 543   def get_friends_query(user, page) do
 544     from(
 545       u in get_friends_query(user, nil),
 546       limit: 20,
 547       offset: ^((page - 1) * 20)
 548     )
 549   end
 550
 551   def get_friends_query(user), do: get_friends_query(user, nil)
 552
 553   def get_friends(user, page \\ nil) do
 554     q = get_friends_query(user, page)
 555
 556     {:ok, Repo.all(q)}
 557   end
 558
 559   def get_follow_requests_query(%User{} = user) do
 560     from(
 561       a in Activity,
 562       where:
 563         fragment(
 564           "? ->> 'type' = 'Follow'",
 565           a.data
 566         ),
 567       where:
 568         fragment(
 569           "? ->> 'state' = 'pending'",
 570           a.data
 571         ),
 572       where:
 573         fragment(
 574           "? @> ?",
 575           a.data,
 576           ^%{"object" => user.ap_id}
 577         )
 578     )
 579   end
 580
 581   def get_follow_requests(%User{} = user) do
 582     q = get_follow_requests_query(user)
 583     reqs = Repo.all(q)
 584
 585     users =
 586       Enum.map(reqs, fn req -> req.actor end)
 587       |> Enum.uniq()
 588       |> Enum.map(fn ap_id -> get_by_ap_id(ap_id) end)
 589       |> Enum.filter(fn u -> !is_nil(u) end)
 590       |> Enum.filter(fn u -> !following?(u, user) end)
 591
 592     {:ok, users}
 593   end
 594
 595   def increase_note_count(%User{} = user) do
 596     info_cng = User.Info.add_to_note_count(user.info, 1)
 597
 598     cng =
 599       change(user)
 600       |> put_embed(:info, info_cng)
 601
 602     update_and_set_cache(cng)
 603   end
 604
 605   def decrease_note_count(%User{} = user) do
 606     info_cng = User.Info.add_to_note_count(user.info, -1)
 607
 608     cng =
 609       change(user)
 610       |> put_embed(:info, info_cng)
 611
 612     update_and_set_cache(cng)
 613   end
 614
 615   def update_note_count(%User{} = user) do
 616     note_count_query =
 617       from(
 618         a in Object,
 619         where: fragment("?->>'actor' = ? and ?->>'type' = 'Note'", a.data, ^user.ap_id, a.data),
 620         select: count(a.id)
 621       )
 622
 623     note_count = Repo.one(note_count_query)
 624
 625     info_cng = User.Info.set_note_count(user.info, note_count)
 626
 627     cng =
 628       change(user)
 629       |> put_embed(:info, info_cng)
 630
 631     update_and_set_cache(cng)
 632   end
 633
 634   def update_follower_count(%User{} = user) do
 635     follower_count_query =
 636       from(
 637         u in User,
 638         where: ^user.follower_address in u.following,
 639         where: u.id != ^user.id,
 640         select: count(u.id)
 641       )
 642
 643     follower_count = Repo.one(follower_count_query)
 644
 645     info_cng =
 646       user.info
 647       |> User.Info.set_follower_count(follower_count)
 648
 649     cng =
 650       change(user)
 651       |> put_embed(:info, info_cng)
 652
 653     update_and_set_cache(cng)
 654   end
 655
 656   def get_users_from_set_query(ap_ids, false) do
 657     from(
 658       u in User,
 659       where: u.ap_id in ^ap_ids
 660     )
 661   end
 662
 663   def get_users_from_set_query(ap_ids, true) do
 664     query = get_users_from_set_query(ap_ids, false)
 665
 666     from(
 667       u in query,
 668       where: u.local == true
 669     )
 670   end
 671
 672   def get_users_from_set(ap_ids, local_only \\ true) do
 673     get_users_from_set_query(ap_ids, local_only)
 674     |> Repo.all()
 675   end
 676
 677   def get_recipients_from_activity(%Activity{recipients: to}) do
 678     query =
 679       from(
 680         u in User,
 681         where: u.ap_id in ^to,
 682         or_where: fragment("? && ?", u.following, ^to)
 683       )
 684
 685     query = from(u in query, where: u.local == true)
 686
 687     Repo.all(query)
 688   end
 689
 690   def search(query, resolve \\ false) do
 691     # strip the beginning @ off if there is a query
 692     query = String.trim_leading(query, "@")
 693
 694     if resolve do
 695       User.get_or_fetch_by_nickname(query)
 696     end
 697
 698     inner =
 699       from(
 700         u in User,
 701         select_merge: %{
 702           search_distance:
 703             fragment(
 704               "? <-> (? || coalesce(?, ''))",
 705               ^query,
 706               u.nickname,
 707               u.name
 708             )
 709         },
 710         where: not is_nil(u.nickname)
 711       )
 712
 713     q =
 714       from(
 715         s in subquery(inner),
 716         order_by: s.search_distance,
 717         limit: 20
 718       )
 719
 720     Repo.all(q)
 721   end
 722
 723   def blocks_import(%User{} = blocker, blocked_identifiers) when is_list(blocked_identifiers) do
 724     Enum.map(
 725       blocked_identifiers,
 726       fn blocked_identifier ->
 727         with %User{} = blocked <- get_or_fetch(blocked_identifier),
 728              {:ok, blocker} <- block(blocker, blocked),
 729              {:ok, _} <- ActivityPub.block(blocker, blocked) do
 730           blocked
 731         else
 732           err ->
 733             Logger.debug("blocks_import failed for #{blocked_identifier} with: #{inspect(err)}")
 734             err
 735         end
 736       end
 737     )
 738   end
 739
 740   def block(blocker, %User{ap_id: ap_id} = blocked) do
 741     # sever any follow relationships to prevent leaks per activitypub (Pleroma issue #213)
 742     blocker =
 743       if following?(blocker, blocked) do
 744         {:ok, blocker, _} = unfollow(blocker, blocked)
 745         blocker
 746       else
 747         blocker
 748       end
 749
 750     if following?(blocked, blocker) do
 751       unfollow(blocked, blocker)
 752     end
 753
 754     info_cng =
 755       blocker.info
 756       |> User.Info.add_to_block(ap_id)
 757
 758     cng =
 759       change(blocker)
 760       |> put_embed(:info, info_cng)
 761
 762     update_and_set_cache(cng)
 763   end
 764
 765   # helper to handle the block given only an actor's AP id
 766   def block(blocker, %{ap_id: ap_id}) do
 767     block(blocker, User.get_by_ap_id(ap_id))
 768   end
 769
 770   def unblock(blocker, %{ap_id: ap_id}) do
 771     info_cng =
 772       blocker.info
 773       |> User.Info.remove_from_block(ap_id)
 774
 775     cng =
 776       change(blocker)
 777       |> put_embed(:info, info_cng)
 778
 779     update_and_set_cache(cng)
 780   end
 781
 782   def blocks?(user, %{ap_id: ap_id}) do
 783     blocks = user.info.blocks
 784     domain_blocks = user.info.domain_blocks
 785     %{host: host} = URI.parse(ap_id)
 786
 787     Enum.member?(blocks, ap_id) ||
 788       Enum.any?(domain_blocks, fn domain ->
 789         host == domain
 790       end)
 791   end
 792
 793   def blocked_users(user),
 794     do: Repo.all(from(u in User, where: u.ap_id in ^user.info.blocks))
 795
 796   def block_domain(user, domain) do
 797     info_cng =
 798       user.info
 799       |> User.Info.add_to_domain_block(domain)
 800
 801     cng =
 802       change(user)
 803       |> put_embed(:info, info_cng)
 804
 805     update_and_set_cache(cng)
 806   end
 807
 808   def unblock_domain(user, domain) do
 809     info_cng =
 810       user.info
 811       |> User.Info.remove_from_domain_block(domain)
 812
 813     cng =
 814       change(user)
 815       |> put_embed(:info, info_cng)
 816
 817     update_and_set_cache(cng)
 818   end
 819
 820   def local_user_query() do
 821     from(
 822       u in User,
 823       where: u.local == true,
 824       where: not is_nil(u.nickname)
 825     )
 826   end
 827
 828   def moderator_user_query() do
 829     from(
 830       u in User,
 831       where: u.local == true,
 832       where: fragment("?->'is_moderator' @> 'true'", u.info)
 833     )
 834   end
 835
 836   def deactivate(%User{} = user, status \\ true) do
 837     info_cng = User.Info.set_activation_status(user.info, status)
 838
 839     cng =
 840       change(user)
 841       |> put_embed(:info, info_cng)
 842
 843     update_and_set_cache(cng)
 844   end
 845
 846   def delete(%User{} = user) do
 847     {:ok, user} = User.deactivate(user)
 848
 849     # Remove all relationships
 850     {:ok, followers} = User.get_followers(user)
 851
 852     followers
 853     |> Enum.each(fn follower -> User.unfollow(follower, user) end)
 854
 855     {:ok, friends} = User.get_friends(user)
 856
 857     friends
 858     |> Enum.each(fn followed -> User.unfollow(user, followed) end)
 859
 860     query = from(a in Activity, where: a.actor == ^user.ap_id)
 861
 862     Repo.all(query)
 863     |> Enum.each(fn activity ->
 864       case activity.data["type"] do
 865         "Create" ->
 866           ActivityPub.delete(Object.normalize(activity.data["object"]))
 867
 868         # TODO: Do something with likes, follows, repeats.
 869         _ ->
 870           "Doing nothing"
 871       end
 872     end)
 873
 874     {:ok, user}
 875   end
 876
 877   def html_filter_policy(%User{info: %{no_rich_text: true}}) do
 878     Pleroma.HTML.Scrubber.TwitterText
 879   end
 880
 881   @default_scrubbers Pleroma.Config.get([:markup, :scrub_policy])
 882
 883   def html_filter_policy(_), do: @default_scrubbers
 884
 885   def get_or_fetch_by_ap_id(ap_id) do
 886     user = get_by_ap_id(ap_id)
 887
 888     if !is_nil(user) and !User.needs_update?(user) do
 889       user
 890     else
 891       ap_try = ActivityPub.make_user_from_ap_id(ap_id)
 892
 893       case ap_try do
 894         {:ok, user} ->
 895           user
 896
 897         _ ->
 898           case OStatus.make_user(ap_id) do
 899             {:ok, user} -> user
 900             _ -> {:error, "Could not fetch by AP id"}
 901           end
 902       end
 903     end
 904   end
 905
 906   def get_or_create_instance_user do
 907     relay_uri = "#{Pleroma.Web.Endpoint.url()}/relay"
 908
 909     if user = get_by_ap_id(relay_uri) do
 910       user
 911     else
 912       changes =
 913         %User{info: %User.Info{}}
 914         |> cast(%{}, [:ap_id, :nickname, :local])
 915         |> put_change(:ap_id, relay_uri)
 916         |> put_change(:nickname, nil)
 917         |> put_change(:local, true)
 918         |> put_change(:follower_address, relay_uri <> "/followers")
 919
 920       {:ok, user} = Repo.insert(changes)
 921       user
 922     end
 923   end
 924
 925   # AP style
 926   def public_key_from_info(%{
 927         source_data: %{"publicKey" => %{"publicKeyPem" => public_key_pem}}
 928       }) do
 929     key =
 930       public_key_pem
 931       |> :public_key.pem_decode()
 932       |> hd()
 933       |> :public_key.pem_entry_decode()
 934
 935     {:ok, key}
 936   end
 937
 938   # OStatus Magic Key
 939   def public_key_from_info(%{magic_key: magic_key}) do
 940     {:ok, Pleroma.Web.Salmon.decode_key(magic_key)}
 941   end
 942
 943   def get_public_key_for_ap_id(ap_id) do
 944     with %User{} = user <- get_or_fetch_by_ap_id(ap_id),
 945          {:ok, public_key} <- public_key_from_info(user.info) do
 946       {:ok, public_key}
 947     else
 948       _ -> :error
 949     end
 950   end
 951
 952   defp blank?(""), do: nil
 953   defp blank?(n), do: n
 954
 955   def insert_or_update_user(data) do
 956     data =
 957       data
 958       |> Map.put(:name, blank?(data[:name]) || data[:nickname])
 959
 960     cs = User.remote_user_creation(data)
 961
 962     Repo.insert(cs, on_conflict: :replace_all, conflict_target: :nickname)
 963   end
 964
 965   def ap_enabled?(%User{local: true}), do: true
 966   def ap_enabled?(%User{info: info}), do: info.ap_enabled
 967   def ap_enabled?(_), do: false
 968
 969   @doc "Gets or fetch a user by uri or nickname."
 970   @spec get_or_fetch(String.t()) :: User.t()
 971   def get_or_fetch("http" <> _host = uri), do: get_or_fetch_by_ap_id(uri)
 972   def get_or_fetch(nickname), do: get_or_fetch_by_nickname(nickname)
 973
 974   # wait a period of time and return newest version of the User structs
 975   # this is because we have synchronous follow APIs and need to simulate them
 976   # with an async handshake
 977   def wait_and_refresh(_, %User{local: true} = a, %User{local: true} = b) do
 978     with %User{} = a <- Repo.get(User, a.id),
 979          %User{} = b <- Repo.get(User, b.id) do
 980       {:ok, a, b}
 981     else
 982       _e ->
 983         :error
 984     end
 985   end
 986
 987   def wait_and_refresh(timeout, %User{} = a, %User{} = b) do
 988     with :ok <- :timer.sleep(timeout),
 989          %User{} = a <- Repo.get(User, a.id),
 990          %User{} = b <- Repo.get(User, b.id) do
 991       {:ok, a, b}
 992     else
 993       _e ->
 994         :error
 995     end
 996   end
 997
 998   def parse_bio(bio, user \\ %User{info: %{source_data: %{}}})
 999   def parse_bio(nil, _user), do: ""
1000   def parse_bio(bio, _user) when bio == "", do: bio
1001
1002   def parse_bio(bio, user) do
1003     mentions = Formatter.parse_mentions(bio)
1004     tags = Formatter.parse_tags(bio)
1005
1006     emoji =
1007       (user.info.source_data["tag"] || [])
1008       |> Enum.filter(fn %{"type" => t} -> t == "Emoji" end)
1009       |> Enum.map(fn %{"icon" => %{"url" => url}, "name" => name} ->
1010         {String.trim(name, ":"), url}
1011       end)
1012
1013     bio
1014     |> CommonUtils.format_input(mentions, tags, "text/plain")
1015     |> Formatter.emojify(emoji)
1016   end
1017
1018   def tag(user_identifiers, tags) when is_list(user_identifiers) do
1019     Repo.transaction(fn ->
1020       for user_identifier <- user_identifiers, do: tag(user_identifier, tags)
1021     end)
1022   end
1023
1024   def tag(nickname, tags) when is_binary(nickname),
1025     do: tag(User.get_by_nickname(nickname), tags)
1026
1027   def tag(%User{} = user, tags),
1028     do: update_tags(user, Enum.uniq((user.tags || []) ++ normalize_tags(tags)))
1029
1030   def untag(user_identifiers, tags) when is_list(user_identifiers) do
1031     Repo.transaction(fn ->
1032       for user_identifier <- user_identifiers, do: untag(user_identifier, tags)
1033     end)
1034   end
1035
1036   def untag(nickname, tags) when is_binary(nickname),
1037     do: untag(User.get_by_nickname(nickname), tags)
1038
1039   def untag(%User{} = user, tags),
1040     do: update_tags(user, (user.tags || []) -- normalize_tags(tags))
1041
1042   defp update_tags(%User{} = user, new_tags) do
1043     {:ok, updated_user} =
1044       user
1045       |> change(%{tags: new_tags})
1046       |> Repo.update()
1047
1048     updated_user
1049   end
1050
1051   defp normalize_tags(tags) do
1052     [tags]
1053     |> List.flatten()
1054     |> Enum.map(&String.downcase(&1))
1055   end
1056
1057   defp local_nickname_regex() do
1058     if Pleroma.Config.get([:instance, :extended_nickname_format]) do
1059       @extended_local_nickname_regex
1060     else
1061       @strict_local_nickname_regex
1062     end
1063   end
1064 end