git.squeep.com Git - akkoma/blob - lib/pleroma/user.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.User do
   6   use Ecto.Schema
   7
   8   import Ecto.{Changeset, Query}
   9   alias Pleroma.{Repo, User, Object, Web, Activity, Notification}
  10   alias Comeonin.Pbkdf2
  11   alias Pleroma.Formatter
  12   alias Pleroma.Web.CommonAPI.Utils, as: CommonUtils
  13   alias Pleroma.Web.{OStatus, Websub, OAuth}
  14   alias Pleroma.Web.ActivityPub.{Utils, ActivityPub}
  15
  16   require Logger
  17
  18   @type t :: %__MODULE__{}
  19
  20   @email_regex ~r/^[a-zA-Z0-9.!#$%&'*+\/=?^_`{|}~-]+@[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?(?:\.[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?)*$/
  21
  22   @strict_local_nickname_regex ~r/^[a-zA-Z\d]+$/
  23   @extended_local_nickname_regex ~r/^[a-zA-Z\d_-]+$/
  24
  25   schema "users" do
  26     field(:bio, :string)
  27     field(:email, :string)
  28     field(:name, :string)
  29     field(:nickname, :string)
  30     field(:password_hash, :string)
  31     field(:password, :string, virtual: true)
  32     field(:password_confirmation, :string, virtual: true)
  33     field(:following, {:array, :string}, default: [])
  34     field(:ap_id, :string)
  35     field(:avatar, :map)
  36     field(:local, :boolean, default: true)
  37     field(:follower_address, :string)
  38     field(:search_distance, :float, virtual: true)
  39     field(:tags, {:array, :string}, default: [])
  40     field(:last_refreshed_at, :naive_datetime)
  41     has_many(:notifications, Notification)
  42     embeds_one(:info, Pleroma.User.Info)
  43
  44     timestamps()
  45   end
  46
  47   def auth_active?(%User{local: false}), do: true
  48
  49   def auth_active?(%User{info: %User.Info{confirmation_pending: false}}), do: true
  50
  51   def auth_active?(%User{info: %User.Info{confirmation_pending: true}}),
  52     do: !Pleroma.Config.get([:instance, :account_activation_required])
  53
  54   def auth_active?(_), do: false
  55
  56   def visible_for?(user, for_user \\ nil)
  57
  58   def visible_for?(%User{id: user_id}, %User{id: for_id}) when user_id == for_id, do: true
  59
  60   def visible_for?(%User{} = user, for_user) do
  61     auth_active?(user) || superuser?(for_user)
  62   end
  63
  64   def visible_for?(_, _), do: false
  65
  66   def superuser?(%User{local: true, info: %User.Info{is_admin: true}}), do: true
  67   def superuser?(%User{local: true, info: %User.Info{is_moderator: true}}), do: true
  68   def superuser?(_), do: false
  69
  70   def avatar_url(user) do
  71     case user.avatar do
  72       %{"url" => [%{"href" => href} | _]} -> href
  73       _ -> "#{Web.base_url()}/images/avi.png"
  74     end
  75   end
  76
  77   def banner_url(user) do
  78     case user.info.banner do
  79       %{"url" => [%{"href" => href} | _]} -> href
  80       _ -> "#{Web.base_url()}/images/banner.png"
  81     end
  82   end
  83
  84   def profile_url(%User{info: %{source_data: %{"url" => url}}}), do: url
  85   def profile_url(%User{ap_id: ap_id}), do: ap_id
  86   def profile_url(_), do: nil
  87
  88   def ap_id(%User{nickname: nickname}) do
  89     "#{Web.base_url()}/users/#{nickname}"
  90   end
  91
  92   def ap_followers(%User{} = user) do
  93     "#{ap_id(user)}/followers"
  94   end
  95
  96   def follow_changeset(struct, params \\ %{}) do
  97     struct
  98     |> cast(params, [:following])
  99     |> validate_required([:following])
 100   end
 101
 102   def user_info(%User{} = user) do
 103     oneself = if user.local, do: 1, else: 0
 104
 105     %{
 106       following_count: length(user.following) - oneself,
 107       note_count: user.info.note_count,
 108       follower_count: user.info.follower_count,
 109       locked: user.info.locked,
 110       confirmation_pending: user.info.confirmation_pending,
 111       default_scope: user.info.default_scope
 112     }
 113   end
 114
 115   def remote_user_creation(params) do
 116     params =
 117       params
 118       |> Map.put(:info, params[:info] || %{})
 119
 120     info_cng = User.Info.remote_user_creation(%User.Info{}, params[:info])
 121
 122     changes =
 123       %User{}
 124       |> cast(params, [:bio, :name, :ap_id, :nickname, :avatar])
 125       |> validate_required([:name, :ap_id])
 126       |> unique_constraint(:nickname)
 127       |> validate_format(:nickname, @email_regex)
 128       |> validate_length(:bio, max: 5000)
 129       |> validate_length(:name, max: 100)
 130       |> put_change(:local, false)
 131       |> put_embed(:info, info_cng)
 132
 133     if changes.valid? do
 134       case info_cng.changes[:source_data] do
 135         %{"followers" => followers} ->
 136           changes
 137           |> put_change(:follower_address, followers)
 138
 139         _ ->
 140           followers = User.ap_followers(%User{nickname: changes.changes[:nickname]})
 141
 142           changes
 143           |> put_change(:follower_address, followers)
 144       end
 145     else
 146       changes
 147     end
 148   end
 149
 150   def update_changeset(struct, params \\ %{}) do
 151     struct
 152     |> cast(params, [:bio, :name, :avatar])
 153     |> unique_constraint(:nickname)
 154     |> validate_format(:nickname, local_nickname_regex())
 155     |> validate_length(:bio, max: 5000)
 156     |> validate_length(:name, min: 1, max: 100)
 157   end
 158
 159   def upgrade_changeset(struct, params \\ %{}) do
 160     params =
 161       params
 162       |> Map.put(:last_refreshed_at, NaiveDateTime.utc_now())
 163
 164     info_cng =
 165       struct.info
 166       |> User.Info.user_upgrade(params[:info])
 167
 168     struct
 169     |> cast(params, [:bio, :name, :follower_address, :avatar, :last_refreshed_at])
 170     |> unique_constraint(:nickname)
 171     |> validate_format(:nickname, local_nickname_regex())
 172     |> validate_length(:bio, max: 5000)
 173     |> validate_length(:name, max: 100)
 174     |> put_embed(:info, info_cng)
 175   end
 176
 177   def password_update_changeset(struct, params) do
 178     changeset =
 179       struct
 180       |> cast(params, [:password, :password_confirmation])
 181       |> validate_required([:password, :password_confirmation])
 182       |> validate_confirmation(:password)
 183
 184     OAuth.Token.delete_user_tokens(struct)
 185     OAuth.Authorization.delete_user_authorizations(struct)
 186
 187     if changeset.valid? do
 188       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 189
 190       changeset
 191       |> put_change(:password_hash, hashed)
 192     else
 193       changeset
 194     end
 195   end
 196
 197   def reset_password(user, data) do
 198     update_and_set_cache(password_update_changeset(user, data))
 199   end
 200
 201   def register_changeset(struct, params \\ %{}, opts \\ []) do
 202     confirmation_status =
 203       if opts[:confirmed] || !Pleroma.Config.get([:instance, :account_activation_required]) do
 204         :confirmed
 205       else
 206         :unconfirmed
 207       end
 208
 209     info_change = User.Info.confirmation_changeset(%User.Info{}, confirmation_status)
 210
 211     changeset =
 212       struct
 213       |> cast(params, [:bio, :email, :name, :nickname, :password, :password_confirmation])
 214       |> validate_required([:email, :name, :nickname, :password, :password_confirmation])
 215       |> validate_confirmation(:password)
 216       |> unique_constraint(:email)
 217       |> unique_constraint(:nickname)
 218       |> validate_exclusion(:nickname, Pleroma.Config.get([Pleroma.User, :restricted_nicknames]))
 219       |> validate_format(:nickname, local_nickname_regex())
 220       |> validate_format(:email, @email_regex)
 221       |> validate_length(:bio, max: 1000)
 222       |> validate_length(:name, min: 1, max: 100)
 223       |> put_change(:info, info_change)
 224
 225     if changeset.valid? do
 226       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 227       ap_id = User.ap_id(%User{nickname: changeset.changes[:nickname]})
 228       followers = User.ap_followers(%User{nickname: changeset.changes[:nickname]})
 229
 230       changeset
 231       |> put_change(:password_hash, hashed)
 232       |> put_change(:ap_id, ap_id)
 233       |> put_change(:following, [followers])
 234       |> put_change(:follower_address, followers)
 235     else
 236       changeset
 237     end
 238   end
 239
 240   defp autofollow_users(user) do
 241     candidates = Pleroma.Config.get([:instance, :autofollowed_nicknames])
 242
 243     autofollowed_users =
 244       from(u in User,
 245         where: u.local == true,
 246         where: u.nickname in ^candidates
 247       )
 248       |> Repo.all()
 249
 250     follow_all(user, autofollowed_users)
 251   end
 252
 253   @doc "Inserts provided changeset, performs post-registration actions (confirmation email sending etc.)"
 254   def register(%Ecto.Changeset{} = changeset) do
 255     with {:ok, user} <- Repo.insert(changeset),
 256          {:ok, _} <- try_send_confirmation_email(user),
 257          {:ok, user} <- autofollow_users(user) do
 258       {:ok, user}
 259     end
 260   end
 261
 262   def try_send_confirmation_email(%User{} = user) do
 263     if user.info.confirmation_pending &&
 264          Pleroma.Config.get([:instance, :account_activation_required]) do
 265       user
 266       |> Pleroma.UserEmail.account_confirmation_email()
 267       |> Pleroma.Mailer.deliver()
 268     else
 269       {:ok, :noop}
 270     end
 271   end
 272
 273   def needs_update?(%User{local: true}), do: false
 274
 275   def needs_update?(%User{local: false, last_refreshed_at: nil}), do: true
 276
 277   def needs_update?(%User{local: false} = user) do
 278     NaiveDateTime.diff(NaiveDateTime.utc_now(), user.last_refreshed_at) >= 86400
 279   end
 280
 281   def needs_update?(_), do: true
 282
 283   def maybe_direct_follow(%User{} = follower, %User{local: true, info: %{locked: true}}) do
 284     {:ok, follower}
 285   end
 286
 287   def maybe_direct_follow(%User{} = follower, %User{local: true} = followed) do
 288     follow(follower, followed)
 289   end
 290
 291   def maybe_direct_follow(%User{} = follower, %User{} = followed) do
 292     if not User.ap_enabled?(followed) do
 293       follow(follower, followed)
 294     else
 295       {:ok, follower}
 296     end
 297   end
 298
 299   def maybe_follow(%User{} = follower, %User{info: _info} = followed) do
 300     if not following?(follower, followed) do
 301       follow(follower, followed)
 302     else
 303       {:ok, follower}
 304     end
 305   end
 306
 307   @doc "A mass follow for local users. Ignores blocks and has no side effects"
 308   @spec follow_all(User.t(), list(User.t())) :: {atom(), User.t()}
 309   def follow_all(follower, followeds) do
 310     following =
 311       (follower.following ++ Enum.map(followeds, fn %{follower_address: fa} -> fa end))
 312       |> Enum.uniq()
 313
 314     {:ok, follower} =
 315       follower
 316       |> follow_changeset(%{following: following})
 317       |> update_and_set_cache
 318
 319     Enum.each(followeds, fn followed ->
 320       update_follower_count(followed)
 321     end)
 322
 323     {:ok, follower}
 324   end
 325
 326   def follow(%User{} = follower, %User{info: info} = followed) do
 327     user_config = Application.get_env(:pleroma, :user)
 328     deny_follow_blocked = Keyword.get(user_config, :deny_follow_blocked)
 329
 330     ap_followers = followed.follower_address
 331
 332     cond do
 333       following?(follower, followed) or info.deactivated ->
 334         {:error, "Could not follow user: #{followed.nickname} is already on your list."}
 335
 336       deny_follow_blocked and blocks?(followed, follower) ->
 337         {:error, "Could not follow user: #{followed.nickname} blocked you."}
 338
 339       true ->
 340         if !followed.local && follower.local && !ap_enabled?(followed) do
 341           Websub.subscribe(follower, followed)
 342         end
 343
 344         following =
 345           [ap_followers | follower.following]
 346           |> Enum.uniq()
 347
 348         follower =
 349           follower
 350           |> follow_changeset(%{following: following})
 351           |> update_and_set_cache
 352
 353         {:ok, _} = update_follower_count(followed)
 354
 355         follower
 356     end
 357   end
 358
 359   def unfollow(%User{} = follower, %User{} = followed) do
 360     ap_followers = followed.follower_address
 361
 362     if following?(follower, followed) and follower.ap_id != followed.ap_id do
 363       following =
 364         follower.following
 365         |> List.delete(ap_followers)
 366
 367       {:ok, follower} =
 368         follower
 369         |> follow_changeset(%{following: following})
 370         |> update_and_set_cache
 371
 372       {:ok, followed} = update_follower_count(followed)
 373
 374       {:ok, follower, Utils.fetch_latest_follow(follower, followed)}
 375     else
 376       {:error, "Not subscribed!"}
 377     end
 378   end
 379
 380   @spec following?(User.t(), User.t()) :: boolean
 381   def following?(%User{} = follower, %User{} = followed) do
 382     Enum.member?(follower.following, followed.follower_address)
 383   end
 384
 385   def follow_import(%User{} = follower, followed_identifiers)
 386       when is_list(followed_identifiers) do
 387     Enum.map(
 388       followed_identifiers,
 389       fn followed_identifier ->
 390         with %User{} = followed <- get_or_fetch(followed_identifier),
 391              {:ok, follower} <- maybe_direct_follow(follower, followed),
 392              {:ok, _} <- ActivityPub.follow(follower, followed) do
 393           followed
 394         else
 395           err ->
 396             Logger.debug("follow_import failed for #{followed_identifier} with: #{inspect(err)}")
 397             err
 398         end
 399       end
 400     )
 401   end
 402
 403   def locked?(%User{} = user) do
 404     user.info.locked || false
 405   end
 406
 407   def get_by_ap_id(ap_id) do
 408     Repo.get_by(User, ap_id: ap_id)
 409   end
 410
 411   # This is mostly an SPC migration fix. This guesses the user nickname (by taking the last part of the ap_id and the domain) and tries to get that user
 412   def get_by_guessed_nickname(ap_id) do
 413     domain = URI.parse(ap_id).host
 414     name = List.last(String.split(ap_id, "/"))
 415     nickname = "#{name}@#{domain}"
 416
 417     get_by_nickname(nickname)
 418   end
 419
 420   def update_and_set_cache(changeset) do
 421     with {:ok, user} <- Repo.update(changeset) do
 422       Cachex.put(:user_cache, "ap_id:#{user.ap_id}", user)
 423       Cachex.put(:user_cache, "nickname:#{user.nickname}", user)
 424       Cachex.put(:user_cache, "user_info:#{user.id}", user_info(user))
 425       {:ok, user}
 426     else
 427       e -> e
 428     end
 429   end
 430
 431   def invalidate_cache(user) do
 432     Cachex.del(:user_cache, "ap_id:#{user.ap_id}")
 433     Cachex.del(:user_cache, "nickname:#{user.nickname}")
 434     Cachex.del(:user_cache, "user_info:#{user.id}")
 435   end
 436
 437   def get_cached_by_ap_id(ap_id) do
 438     key = "ap_id:#{ap_id}"
 439     Cachex.fetch!(:user_cache, key, fn _ -> get_by_ap_id(ap_id) end)
 440   end
 441
 442   def get_cached_by_nickname(nickname) do
 443     key = "nickname:#{nickname}"
 444     Cachex.fetch!(:user_cache, key, fn _ -> get_or_fetch_by_nickname(nickname) end)
 445   end
 446
 447   def get_by_nickname(nickname) do
 448     Repo.get_by(User, nickname: nickname) ||
 449       if Regex.match?(~r(@#{Pleroma.Web.Endpoint.host()})i, nickname) do
 450         [local_nickname, _] = String.split(nickname, "@")
 451         Repo.get_by(User, nickname: local_nickname)
 452       end
 453   end
 454
 455   def get_by_nickname_or_email(nickname_or_email) do
 456     case user = Repo.get_by(User, nickname: nickname_or_email) do
 457       %User{} -> user
 458       nil -> Repo.get_by(User, email: nickname_or_email)
 459     end
 460   end
 461
 462   def get_cached_user_info(user) do
 463     key = "user_info:#{user.id}"
 464     Cachex.fetch!(:user_cache, key, fn _ -> user_info(user) end)
 465   end
 466
 467   def fetch_by_nickname(nickname) do
 468     ap_try = ActivityPub.make_user_from_nickname(nickname)
 469
 470     case ap_try do
 471       {:ok, user} -> {:ok, user}
 472       _ -> OStatus.make_user(nickname)
 473     end
 474   end
 475
 476   def get_or_fetch_by_nickname(nickname) do
 477     with %User{} = user <- get_by_nickname(nickname) do
 478       user
 479     else
 480       _e ->
 481         with [_nick, _domain] <- String.split(nickname, "@"),
 482              {:ok, user} <- fetch_by_nickname(nickname) do
 483           user
 484         else
 485           _e -> nil
 486         end
 487     end
 488   end
 489
 490   def get_followers_query(%User{id: id, follower_address: follower_address}, nil) do
 491     from(
 492       u in User,
 493       where: fragment("? <@ ?", ^[follower_address], u.following),
 494       where: u.id != ^id
 495     )
 496   end
 497
 498   def get_followers_query(user, page) do
 499     from(
 500       u in get_followers_query(user, nil),
 501       limit: 20,
 502       offset: ^((page - 1) * 20)
 503     )
 504   end
 505
 506   def get_followers_query(user), do: get_followers_query(user, nil)
 507
 508   def get_followers(user, page \\ nil) do
 509     q = get_followers_query(user, page)
 510
 511     {:ok, Repo.all(q)}
 512   end
 513
 514   def get_friends_query(%User{id: id, following: following}, nil) do
 515     from(
 516       u in User,
 517       where: u.follower_address in ^following,
 518       where: u.id != ^id
 519     )
 520   end
 521
 522   def get_friends_query(user, page) do
 523     from(
 524       u in get_friends_query(user, nil),
 525       limit: 20,
 526       offset: ^((page - 1) * 20)
 527     )
 528   end
 529
 530   def get_friends_query(user), do: get_friends_query(user, nil)
 531
 532   def get_friends(user, page \\ nil) do
 533     q = get_friends_query(user, page)
 534
 535     {:ok, Repo.all(q)}
 536   end
 537
 538   def get_follow_requests_query(%User{} = user) do
 539     from(
 540       a in Activity,
 541       where:
 542         fragment(
 543           "? ->> 'type' = 'Follow'",
 544           a.data
 545         ),
 546       where:
 547         fragment(
 548           "? ->> 'state' = 'pending'",
 549           a.data
 550         ),
 551       where:
 552         fragment(
 553           "? @> ?",
 554           a.data,
 555           ^%{"object" => user.ap_id}
 556         )
 557     )
 558   end
 559
 560   def get_follow_requests(%User{} = user) do
 561     q = get_follow_requests_query(user)
 562     reqs = Repo.all(q)
 563
 564     users =
 565       Enum.map(reqs, fn req -> req.actor end)
 566       |> Enum.uniq()
 567       |> Enum.map(fn ap_id -> get_by_ap_id(ap_id) end)
 568       |> Enum.filter(fn u -> !is_nil(u) end)
 569       |> Enum.filter(fn u -> !following?(u, user) end)
 570
 571     {:ok, users}
 572   end
 573
 574   def increase_note_count(%User{} = user) do
 575     info_cng = User.Info.add_to_note_count(user.info, 1)
 576
 577     cng =
 578       change(user)
 579       |> put_embed(:info, info_cng)
 580
 581     update_and_set_cache(cng)
 582   end
 583
 584   def decrease_note_count(%User{} = user) do
 585     info_cng = User.Info.add_to_note_count(user.info, -1)
 586
 587     cng =
 588       change(user)
 589       |> put_embed(:info, info_cng)
 590
 591     update_and_set_cache(cng)
 592   end
 593
 594   def update_note_count(%User{} = user) do
 595     note_count_query =
 596       from(
 597         a in Object,
 598         where: fragment("?->>'actor' = ? and ?->>'type' = 'Note'", a.data, ^user.ap_id, a.data),
 599         select: count(a.id)
 600       )
 601
 602     note_count = Repo.one(note_count_query)
 603
 604     info_cng = User.Info.set_note_count(user.info, note_count)
 605
 606     cng =
 607       change(user)
 608       |> put_embed(:info, info_cng)
 609
 610     update_and_set_cache(cng)
 611   end
 612
 613   def update_follower_count(%User{} = user) do
 614     follower_count_query =
 615       from(
 616         u in User,
 617         where: ^user.follower_address in u.following,
 618         where: u.id != ^user.id,
 619         select: count(u.id)
 620       )
 621
 622     follower_count = Repo.one(follower_count_query)
 623
 624     info_cng =
 625       user.info
 626       |> User.Info.set_follower_count(follower_count)
 627
 628     cng =
 629       change(user)
 630       |> put_embed(:info, info_cng)
 631
 632     update_and_set_cache(cng)
 633   end
 634
 635   def get_users_from_set_query(ap_ids, false) do
 636     from(
 637       u in User,
 638       where: u.ap_id in ^ap_ids
 639     )
 640   end
 641
 642   def get_users_from_set_query(ap_ids, true) do
 643     query = get_users_from_set_query(ap_ids, false)
 644
 645     from(
 646       u in query,
 647       where: u.local == true
 648     )
 649   end
 650
 651   def get_users_from_set(ap_ids, local_only \\ true) do
 652     get_users_from_set_query(ap_ids, local_only)
 653     |> Repo.all()
 654   end
 655
 656   def get_recipients_from_activity(%Activity{recipients: to}) do
 657     query =
 658       from(
 659         u in User,
 660         where: u.ap_id in ^to,
 661         or_where: fragment("? && ?", u.following, ^to)
 662       )
 663
 664     query = from(u in query, where: u.local == true)
 665
 666     Repo.all(query)
 667   end
 668
 669   def search(query, resolve \\ false) do
 670     # strip the beginning @ off if there is a query
 671     query = String.trim_leading(query, "@")
 672
 673     if resolve do
 674       User.get_or_fetch_by_nickname(query)
 675     end
 676
 677     inner =
 678       from(
 679         u in User,
 680         select_merge: %{
 681           search_distance:
 682             fragment(
 683               "? <-> (? || coalesce(?, ''))",
 684               ^query,
 685               u.nickname,
 686               u.name
 687             )
 688         },
 689         where: not is_nil(u.nickname)
 690       )
 691
 692     q =
 693       from(
 694         s in subquery(inner),
 695         order_by: s.search_distance,
 696         limit: 20
 697       )
 698
 699     Repo.all(q)
 700   end
 701
 702   def blocks_import(%User{} = blocker, blocked_identifiers) when is_list(blocked_identifiers) do
 703     Enum.map(
 704       blocked_identifiers,
 705       fn blocked_identifier ->
 706         with %User{} = blocked <- get_or_fetch(blocked_identifier),
 707              {:ok, blocker} <- block(blocker, blocked),
 708              {:ok, _} <- ActivityPub.block(blocker, blocked) do
 709           blocked
 710         else
 711           err ->
 712             Logger.debug("blocks_import failed for #{blocked_identifier} with: #{inspect(err)}")
 713             err
 714         end
 715       end
 716     )
 717   end
 718
 719   def block(blocker, %User{ap_id: ap_id} = blocked) do
 720     # sever any follow relationships to prevent leaks per activitypub (Pleroma issue #213)
 721     blocker =
 722       if following?(blocker, blocked) do
 723         {:ok, blocker, _} = unfollow(blocker, blocked)
 724         blocker
 725       else
 726         blocker
 727       end
 728
 729     if following?(blocked, blocker) do
 730       unfollow(blocked, blocker)
 731     end
 732
 733     info_cng =
 734       blocker.info
 735       |> User.Info.add_to_block(ap_id)
 736
 737     cng =
 738       change(blocker)
 739       |> put_embed(:info, info_cng)
 740
 741     update_and_set_cache(cng)
 742   end
 743
 744   # helper to handle the block given only an actor's AP id
 745   def block(blocker, %{ap_id: ap_id}) do
 746     block(blocker, User.get_by_ap_id(ap_id))
 747   end
 748
 749   def unblock(blocker, %{ap_id: ap_id}) do
 750     info_cng =
 751       blocker.info
 752       |> User.Info.remove_from_block(ap_id)
 753
 754     cng =
 755       change(blocker)
 756       |> put_embed(:info, info_cng)
 757
 758     update_and_set_cache(cng)
 759   end
 760
 761   def blocks?(user, %{ap_id: ap_id}) do
 762     blocks = user.info.blocks
 763     domain_blocks = user.info.domain_blocks
 764     %{host: host} = URI.parse(ap_id)
 765
 766     Enum.member?(blocks, ap_id) ||
 767       Enum.any?(domain_blocks, fn domain ->
 768         host == domain
 769       end)
 770   end
 771
 772   def blocked_users(user),
 773     do: Repo.all(from(u in User, where: u.ap_id in ^user.info.blocks))
 774
 775   def block_domain(user, domain) do
 776     info_cng =
 777       user.info
 778       |> User.Info.add_to_domain_block(domain)
 779
 780     cng =
 781       change(user)
 782       |> put_embed(:info, info_cng)
 783
 784     update_and_set_cache(cng)
 785   end
 786
 787   def unblock_domain(user, domain) do
 788     info_cng =
 789       user.info
 790       |> User.Info.remove_from_domain_block(domain)
 791
 792     cng =
 793       change(user)
 794       |> put_embed(:info, info_cng)
 795
 796     update_and_set_cache(cng)
 797   end
 798
 799   def local_user_query do
 800     from(
 801       u in User,
 802       where: u.local == true,
 803       where: not is_nil(u.nickname)
 804     )
 805   end
 806
 807   def active_local_user_query do
 808     from(
 809       u in local_user_query(),
 810       where: fragment("?->'deactivated' @> 'false'", u.info)
 811     )
 812   end
 813
 814   def moderator_user_query do
 815     from(
 816       u in User,
 817       where: u.local == true,
 818       where: fragment("?->'is_moderator' @> 'true'", u.info)
 819     )
 820   end
 821
 822   def deactivate(%User{} = user, status \\ true) do
 823     info_cng = User.Info.set_activation_status(user.info, status)
 824
 825     cng =
 826       change(user)
 827       |> put_embed(:info, info_cng)
 828
 829     update_and_set_cache(cng)
 830   end
 831
 832   def delete(%User{} = user) do
 833     {:ok, user} = User.deactivate(user)
 834
 835     # Remove all relationships
 836     {:ok, followers} = User.get_followers(user)
 837
 838     followers
 839     |> Enum.each(fn follower -> User.unfollow(follower, user) end)
 840
 841     {:ok, friends} = User.get_friends(user)
 842
 843     friends
 844     |> Enum.each(fn followed -> User.unfollow(user, followed) end)
 845
 846     query = from(a in Activity, where: a.actor == ^user.ap_id)
 847
 848     Repo.all(query)
 849     |> Enum.each(fn activity ->
 850       case activity.data["type"] do
 851         "Create" ->
 852           ActivityPub.delete(Object.normalize(activity.data["object"]))
 853
 854         # TODO: Do something with likes, follows, repeats.
 855         _ ->
 856           "Doing nothing"
 857       end
 858     end)
 859
 860     {:ok, user}
 861   end
 862
 863   def html_filter_policy(%User{info: %{no_rich_text: true}}) do
 864     Pleroma.HTML.Scrubber.TwitterText
 865   end
 866
 867   @default_scrubbers Pleroma.Config.get([:markup, :scrub_policy])
 868
 869   def html_filter_policy(_), do: @default_scrubbers
 870
 871   def get_or_fetch_by_ap_id(ap_id) do
 872     user = get_by_ap_id(ap_id)
 873
 874     if !is_nil(user) and !User.needs_update?(user) do
 875       user
 876     else
 877       ap_try = ActivityPub.make_user_from_ap_id(ap_id)
 878
 879       case ap_try do
 880         {:ok, user} ->
 881           user
 882
 883         _ ->
 884           case OStatus.make_user(ap_id) do
 885             {:ok, user} -> user
 886             _ -> {:error, "Could not fetch by AP id"}
 887           end
 888       end
 889     end
 890   end
 891
 892   def get_or_create_instance_user do
 893     relay_uri = "#{Pleroma.Web.Endpoint.url()}/relay"
 894
 895     if user = get_by_ap_id(relay_uri) do
 896       user
 897     else
 898       changes =
 899         %User{info: %User.Info{}}
 900         |> cast(%{}, [:ap_id, :nickname, :local])
 901         |> put_change(:ap_id, relay_uri)
 902         |> put_change(:nickname, nil)
 903         |> put_change(:local, true)
 904         |> put_change(:follower_address, relay_uri <> "/followers")
 905
 906       {:ok, user} = Repo.insert(changes)
 907       user
 908     end
 909   end
 910
 911   # AP style
 912   def public_key_from_info(%{
 913         source_data: %{"publicKey" => %{"publicKeyPem" => public_key_pem}}
 914       }) do
 915     key =
 916       public_key_pem
 917       |> :public_key.pem_decode()
 918       |> hd()
 919       |> :public_key.pem_entry_decode()
 920
 921     {:ok, key}
 922   end
 923
 924   # OStatus Magic Key
 925   def public_key_from_info(%{magic_key: magic_key}) do
 926     {:ok, Pleroma.Web.Salmon.decode_key(magic_key)}
 927   end
 928
 929   def get_public_key_for_ap_id(ap_id) do
 930     with %User{} = user <- get_or_fetch_by_ap_id(ap_id),
 931          {:ok, public_key} <- public_key_from_info(user.info) do
 932       {:ok, public_key}
 933     else
 934       _ -> :error
 935     end
 936   end
 937
 938   defp blank?(""), do: nil
 939   defp blank?(n), do: n
 940
 941   def insert_or_update_user(data) do
 942     data =
 943       data
 944       |> Map.put(:name, blank?(data[:name]) || data[:nickname])
 945
 946     cs = User.remote_user_creation(data)
 947
 948     Repo.insert(cs, on_conflict: :replace_all, conflict_target: :nickname)
 949   end
 950
 951   def ap_enabled?(%User{local: true}), do: true
 952   def ap_enabled?(%User{info: info}), do: info.ap_enabled
 953   def ap_enabled?(_), do: false
 954
 955   @doc "Gets or fetch a user by uri or nickname."
 956   @spec get_or_fetch(String.t()) :: User.t()
 957   def get_or_fetch("http" <> _host = uri), do: get_or_fetch_by_ap_id(uri)
 958   def get_or_fetch(nickname), do: get_or_fetch_by_nickname(nickname)
 959
 960   # wait a period of time and return newest version of the User structs
 961   # this is because we have synchronous follow APIs and need to simulate them
 962   # with an async handshake
 963   def wait_and_refresh(_, %User{local: true} = a, %User{local: true} = b) do
 964     with %User{} = a <- Repo.get(User, a.id),
 965          %User{} = b <- Repo.get(User, b.id) do
 966       {:ok, a, b}
 967     else
 968       _e ->
 969         :error
 970     end
 971   end
 972
 973   def wait_and_refresh(timeout, %User{} = a, %User{} = b) do
 974     with :ok <- :timer.sleep(timeout),
 975          %User{} = a <- Repo.get(User, a.id),
 976          %User{} = b <- Repo.get(User, b.id) do
 977       {:ok, a, b}
 978     else
 979       _e ->
 980         :error
 981     end
 982   end
 983
 984   def parse_bio(bio, user \\ %User{info: %{source_data: %{}}})
 985   def parse_bio(nil, _user), do: ""
 986   def parse_bio(bio, _user) when bio == "", do: bio
 987
 988   def parse_bio(bio, user) do
 989     mentions = Formatter.parse_mentions(bio)
 990     tags = Formatter.parse_tags(bio)
 991
 992     emoji =
 993       (user.info.source_data["tag"] || [])
 994       |> Enum.filter(fn %{"type" => t} -> t == "Emoji" end)
 995       |> Enum.map(fn %{"icon" => %{"url" => url}, "name" => name} ->
 996         {String.trim(name, ":"), url}
 997       end)
 998
 999     bio
1000     |> CommonUtils.format_input(mentions, tags, "text/plain")
1001     |> Formatter.emojify(emoji)
1002   end
1003
1004   def tag(user_identifiers, tags) when is_list(user_identifiers) do
1005     Repo.transaction(fn ->
1006       for user_identifier <- user_identifiers, do: tag(user_identifier, tags)
1007     end)
1008   end
1009
1010   def tag(nickname, tags) when is_binary(nickname),
1011     do: tag(User.get_by_nickname(nickname), tags)
1012
1013   def tag(%User{} = user, tags),
1014     do: update_tags(user, Enum.uniq((user.tags || []) ++ normalize_tags(tags)))
1015
1016   def untag(user_identifiers, tags) when is_list(user_identifiers) do
1017     Repo.transaction(fn ->
1018       for user_identifier <- user_identifiers, do: untag(user_identifier, tags)
1019     end)
1020   end
1021
1022   def untag(nickname, tags) when is_binary(nickname),
1023     do: untag(User.get_by_nickname(nickname), tags)
1024
1025   def untag(%User{} = user, tags),
1026     do: update_tags(user, (user.tags || []) -- normalize_tags(tags))
1027
1028   defp update_tags(%User{} = user, new_tags) do
1029     {:ok, updated_user} =
1030       user
1031       |> change(%{tags: new_tags})
1032       |> Repo.update()
1033
1034     updated_user
1035   end
1036
1037   defp normalize_tags(tags) do
1038     [tags]
1039     |> List.flatten()
1040     |> Enum.map(&String.downcase(&1))
1041   end
1042
1043   defp local_nickname_regex() do
1044     if Pleroma.Config.get([:instance, :extended_nickname_format]) do
1045       @extended_local_nickname_regex
1046     else
1047       @strict_local_nickname_regex
1048     end
1049   end
1050
1051   def error_user(ap_id) do
1052     %User{
1053       name: ap_id,
1054       ap_id: ap_id,
1055       info: %User.Info{},
1056       nickname: "erroruser@example.com",
1057       inserted_at: NaiveDateTime.utc_now()
1058     }
1059   end
1060 end