git.squeep.com Git - akkoma/blob - lib/pleroma/user.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.User do
   6   use Ecto.Schema
   7
   8   import Ecto.{Changeset, Query}
   9   alias Pleroma.{Repo, User, Object, Web, Activity, Notification}
  10   alias Comeonin.Pbkdf2
  11   alias Pleroma.Formatter
  12   alias Pleroma.Web.CommonAPI.Utils, as: CommonUtils
  13   alias Pleroma.Web.{OStatus, Websub, OAuth}
  14   alias Pleroma.Web.ActivityPub.{Utils, ActivityPub}
  15
  16   require Logger
  17
  18   @type t :: %__MODULE__{}
  19
  20   @primary_key {:id, Pleroma.FlakeId, autogenerate: true}
  21
  22   @email_regex ~r/^[a-zA-Z0-9.!#$%&'*+\/=?^_`{|}~-]+@[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?(?:\.[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?)*$/
  23
  24   @strict_local_nickname_regex ~r/^[a-zA-Z\d]+$/
  25   @extended_local_nickname_regex ~r/^[a-zA-Z\d_-]+$/
  26
  27   schema "users" do
  28     field(:bio, :string)
  29     field(:email, :string)
  30     field(:name, :string)
  31     field(:nickname, :string)
  32     field(:password_hash, :string)
  33     field(:password, :string, virtual: true)
  34     field(:password_confirmation, :string, virtual: true)
  35     field(:following, {:array, :string}, default: [])
  36     field(:ap_id, :string)
  37     field(:avatar, :map)
  38     field(:local, :boolean, default: true)
  39     field(:follower_address, :string)
  40     field(:search_rank, :float, virtual: true)
  41     field(:tags, {:array, :string}, default: [])
  42     field(:last_refreshed_at, :naive_datetime)
  43     has_many(:notifications, Notification)
  44     embeds_one(:info, Pleroma.User.Info)
  45
  46     timestamps()
  47   end
  48
  49   def auth_active?(%User{local: false}), do: true
  50
  51   def auth_active?(%User{info: %User.Info{confirmation_pending: false}}), do: true
  52
  53   def auth_active?(%User{info: %User.Info{confirmation_pending: true}}),
  54     do: !Pleroma.Config.get([:instance, :account_activation_required])
  55
  56   def auth_active?(_), do: false
  57
  58   def visible_for?(user, for_user \\ nil)
  59
  60   def visible_for?(%User{id: user_id}, %User{id: for_id}) when user_id == for_id, do: true
  61
  62   def visible_for?(%User{} = user, for_user) do
  63     auth_active?(user) || superuser?(for_user)
  64   end
  65
  66   def visible_for?(_, _), do: false
  67
  68   def superuser?(%User{local: true, info: %User.Info{is_admin: true}}), do: true
  69   def superuser?(%User{local: true, info: %User.Info{is_moderator: true}}), do: true
  70   def superuser?(_), do: false
  71
  72   def avatar_url(user) do
  73     case user.avatar do
  74       %{"url" => [%{"href" => href} | _]} -> href
  75       _ -> "#{Web.base_url()}/images/avi.png"
  76     end
  77   end
  78
  79   def banner_url(user) do
  80     case user.info.banner do
  81       %{"url" => [%{"href" => href} | _]} -> href
  82       _ -> "#{Web.base_url()}/images/banner.png"
  83     end
  84   end
  85
  86   def profile_url(%User{info: %{source_data: %{"url" => url}}}), do: url
  87   def profile_url(%User{ap_id: ap_id}), do: ap_id
  88   def profile_url(_), do: nil
  89
  90   def ap_id(%User{nickname: nickname}) do
  91     "#{Web.base_url()}/users/#{nickname}"
  92   end
  93
  94   def ap_followers(%User{} = user) do
  95     "#{ap_id(user)}/followers"
  96   end
  97
  98   def follow_changeset(struct, params \\ %{}) do
  99     struct
 100     |> cast(params, [:following])
 101     |> validate_required([:following])
 102   end
 103
 104   def user_info(%User{} = user) do
 105     oneself = if user.local, do: 1, else: 0
 106
 107     %{
 108       following_count: length(user.following) - oneself,
 109       note_count: user.info.note_count,
 110       follower_count: user.info.follower_count,
 111       locked: user.info.locked,
 112       confirmation_pending: user.info.confirmation_pending,
 113       default_scope: user.info.default_scope
 114     }
 115   end
 116
 117   def remote_user_creation(params) do
 118     params =
 119       params
 120       |> Map.put(:info, params[:info] || %{})
 121
 122     info_cng = User.Info.remote_user_creation(%User.Info{}, params[:info])
 123
 124     changes =
 125       %User{}
 126       |> cast(params, [:bio, :name, :ap_id, :nickname, :avatar])
 127       |> validate_required([:name, :ap_id])
 128       |> unique_constraint(:nickname)
 129       |> validate_format(:nickname, @email_regex)
 130       |> validate_length(:bio, max: 5000)
 131       |> validate_length(:name, max: 100)
 132       |> put_change(:local, false)
 133       |> put_embed(:info, info_cng)
 134
 135     if changes.valid? do
 136       case info_cng.changes[:source_data] do
 137         %{"followers" => followers} ->
 138           changes
 139           |> put_change(:follower_address, followers)
 140
 141         _ ->
 142           followers = User.ap_followers(%User{nickname: changes.changes[:nickname]})
 143
 144           changes
 145           |> put_change(:follower_address, followers)
 146       end
 147     else
 148       changes
 149     end
 150   end
 151
 152   def update_changeset(struct, params \\ %{}) do
 153     struct
 154     |> cast(params, [:bio, :name, :avatar])
 155     |> unique_constraint(:nickname)
 156     |> validate_format(:nickname, local_nickname_regex())
 157     |> validate_length(:bio, max: 5000)
 158     |> validate_length(:name, min: 1, max: 100)
 159   end
 160
 161   def upgrade_changeset(struct, params \\ %{}) do
 162     params =
 163       params
 164       |> Map.put(:last_refreshed_at, NaiveDateTime.utc_now())
 165
 166     info_cng =
 167       struct.info
 168       |> User.Info.user_upgrade(params[:info])
 169
 170     struct
 171     |> cast(params, [:bio, :name, :follower_address, :avatar, :last_refreshed_at])
 172     |> unique_constraint(:nickname)
 173     |> validate_format(:nickname, local_nickname_regex())
 174     |> validate_length(:bio, max: 5000)
 175     |> validate_length(:name, max: 100)
 176     |> put_embed(:info, info_cng)
 177   end
 178
 179   def password_update_changeset(struct, params) do
 180     changeset =
 181       struct
 182       |> cast(params, [:password, :password_confirmation])
 183       |> validate_required([:password, :password_confirmation])
 184       |> validate_confirmation(:password)
 185
 186     OAuth.Token.delete_user_tokens(struct)
 187     OAuth.Authorization.delete_user_authorizations(struct)
 188
 189     if changeset.valid? do
 190       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 191
 192       changeset
 193       |> put_change(:password_hash, hashed)
 194     else
 195       changeset
 196     end
 197   end
 198
 199   def reset_password(user, data) do
 200     update_and_set_cache(password_update_changeset(user, data))
 201   end
 202
 203   def register_changeset(struct, params \\ %{}, opts \\ []) do
 204     confirmation_status =
 205       if opts[:confirmed] || !Pleroma.Config.get([:instance, :account_activation_required]) do
 206         :confirmed
 207       else
 208         :unconfirmed
 209       end
 210
 211     info_change = User.Info.confirmation_changeset(%User.Info{}, confirmation_status)
 212
 213     changeset =
 214       struct
 215       |> cast(params, [:bio, :email, :name, :nickname, :password, :password_confirmation])
 216       |> validate_required([:email, :name, :nickname, :password, :password_confirmation])
 217       |> validate_confirmation(:password)
 218       |> unique_constraint(:email)
 219       |> unique_constraint(:nickname)
 220       |> validate_exclusion(:nickname, Pleroma.Config.get([Pleroma.User, :restricted_nicknames]))
 221       |> validate_format(:nickname, local_nickname_regex())
 222       |> validate_format(:email, @email_regex)
 223       |> validate_length(:bio, max: 1000)
 224       |> validate_length(:name, min: 1, max: 100)
 225       |> put_change(:info, info_change)
 226
 227     if changeset.valid? do
 228       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 229       ap_id = User.ap_id(%User{nickname: changeset.changes[:nickname]})
 230       followers = User.ap_followers(%User{nickname: changeset.changes[:nickname]})
 231
 232       changeset
 233       |> put_change(:password_hash, hashed)
 234       |> put_change(:ap_id, ap_id)
 235       |> put_change(:following, [followers])
 236       |> put_change(:follower_address, followers)
 237     else
 238       changeset
 239     end
 240   end
 241
 242   defp autofollow_users(user) do
 243     candidates = Pleroma.Config.get([:instance, :autofollowed_nicknames])
 244
 245     autofollowed_users =
 246       from(u in User,
 247         where: u.local == true,
 248         where: u.nickname in ^candidates
 249       )
 250       |> Repo.all()
 251
 252     follow_all(user, autofollowed_users)
 253   end
 254
 255   @doc "Inserts provided changeset, performs post-registration actions (confirmation email sending etc.)"
 256   def register(%Ecto.Changeset{} = changeset) do
 257     with {:ok, user} <- Repo.insert(changeset),
 258          {:ok, _} <- try_send_confirmation_email(user),
 259          {:ok, user} <- autofollow_users(user) do
 260       {:ok, user}
 261     end
 262   end
 263
 264   def try_send_confirmation_email(%User{} = user) do
 265     if user.info.confirmation_pending &&
 266          Pleroma.Config.get([:instance, :account_activation_required]) do
 267       user
 268       |> Pleroma.UserEmail.account_confirmation_email()
 269       |> Pleroma.Mailer.deliver()
 270     else
 271       {:ok, :noop}
 272     end
 273   end
 274
 275   def needs_update?(%User{local: true}), do: false
 276
 277   def needs_update?(%User{local: false, last_refreshed_at: nil}), do: true
 278
 279   def needs_update?(%User{local: false} = user) do
 280     NaiveDateTime.diff(NaiveDateTime.utc_now(), user.last_refreshed_at) >= 86400
 281   end
 282
 283   def needs_update?(_), do: true
 284
 285   def maybe_direct_follow(%User{} = follower, %User{local: true, info: %{locked: true}}) do
 286     {:ok, follower}
 287   end
 288
 289   def maybe_direct_follow(%User{} = follower, %User{local: true} = followed) do
 290     follow(follower, followed)
 291   end
 292
 293   def maybe_direct_follow(%User{} = follower, %User{} = followed) do
 294     if not User.ap_enabled?(followed) do
 295       follow(follower, followed)
 296     else
 297       {:ok, follower}
 298     end
 299   end
 300
 301   def maybe_follow(%User{} = follower, %User{info: _info} = followed) do
 302     if not following?(follower, followed) do
 303       follow(follower, followed)
 304     else
 305       {:ok, follower}
 306     end
 307   end
 308
 309   @doc "A mass follow for local users. Ignores blocks and has no side effects"
 310   @spec follow_all(User.t(), list(User.t())) :: {atom(), User.t()}
 311   def follow_all(follower, followeds) do
 312     following =
 313       (follower.following ++ Enum.map(followeds, fn %{follower_address: fa} -> fa end))
 314       |> Enum.uniq()
 315
 316     {:ok, follower} =
 317       follower
 318       |> follow_changeset(%{following: following})
 319       |> update_and_set_cache
 320
 321     Enum.each(followeds, fn followed ->
 322       update_follower_count(followed)
 323     end)
 324
 325     {:ok, follower}
 326   end
 327
 328   def follow(%User{} = follower, %User{info: info} = followed) do
 329     user_config = Application.get_env(:pleroma, :user)
 330     deny_follow_blocked = Keyword.get(user_config, :deny_follow_blocked)
 331
 332     ap_followers = followed.follower_address
 333
 334     cond do
 335       following?(follower, followed) or info.deactivated ->
 336         {:error, "Could not follow user: #{followed.nickname} is already on your list."}
 337
 338       deny_follow_blocked and blocks?(followed, follower) ->
 339         {:error, "Could not follow user: #{followed.nickname} blocked you."}
 340
 341       true ->
 342         if !followed.local && follower.local && !ap_enabled?(followed) do
 343           Websub.subscribe(follower, followed)
 344         end
 345
 346         q =
 347           from(u in User,
 348             where: u.id == ^follower.id,
 349             update: [push: [following: ^ap_followers]]
 350           )
 351
 352         {1, [follower]} = Repo.update_all(q, [], returning: true)
 353
 354         {:ok, _} = update_follower_count(followed)
 355
 356         set_cache(follower)
 357     end
 358   end
 359
 360   def unfollow(%User{} = follower, %User{} = followed) do
 361     ap_followers = followed.follower_address
 362
 363     if following?(follower, followed) and follower.ap_id != followed.ap_id do
 364       q =
 365         from(u in User,
 366           where: u.id == ^follower.id,
 367           update: [pull: [following: ^ap_followers]]
 368         )
 369
 370       {1, [follower]} = Repo.update_all(q, [], returning: true)
 371
 372       {:ok, followed} = update_follower_count(followed)
 373
 374       set_cache(follower)
 375
 376       {:ok, follower, Utils.fetch_latest_follow(follower, followed)}
 377     else
 378       {:error, "Not subscribed!"}
 379     end
 380   end
 381
 382   @spec following?(User.t(), User.t()) :: boolean
 383   def following?(%User{} = follower, %User{} = followed) do
 384     Enum.member?(follower.following, followed.follower_address)
 385   end
 386
 387   def follow_import(%User{} = follower, followed_identifiers)
 388       when is_list(followed_identifiers) do
 389     Enum.map(
 390       followed_identifiers,
 391       fn followed_identifier ->
 392         with %User{} = followed <- get_or_fetch(followed_identifier),
 393              {:ok, follower} <- maybe_direct_follow(follower, followed),
 394              {:ok, _} <- ActivityPub.follow(follower, followed) do
 395           followed
 396         else
 397           err ->
 398             Logger.debug("follow_import failed for #{followed_identifier} with: #{inspect(err)}")
 399             err
 400         end
 401       end
 402     )
 403   end
 404
 405   def locked?(%User{} = user) do
 406     user.info.locked || false
 407   end
 408
 409   def get_by_id(id) do
 410     Repo.get_by(User, id: id)
 411   end
 412
 413   def get_by_ap_id(ap_id) do
 414     Repo.get_by(User, ap_id: ap_id)
 415   end
 416
 417   # This is mostly an SPC migration fix. This guesses the user nickname (by taking the last part of the ap_id and the domain) and tries to get that user
 418   def get_by_guessed_nickname(ap_id) do
 419     domain = URI.parse(ap_id).host
 420     name = List.last(String.split(ap_id, "/"))
 421     nickname = "#{name}@#{domain}"
 422
 423     get_by_nickname(nickname)
 424   end
 425
 426   def set_cache(user) do
 427     Cachex.put(:user_cache, "ap_id:#{user.ap_id}", user)
 428     Cachex.put(:user_cache, "nickname:#{user.nickname}", user)
 429     Cachex.put(:user_cache, "user_info:#{user.id}", user_info(user))
 430     {:ok, user}
 431   end
 432
 433   def update_and_set_cache(changeset) do
 434     with {:ok, user} <- Repo.update(changeset) do
 435       set_cache(user)
 436     else
 437       e -> e
 438     end
 439   end
 440
 441   def invalidate_cache(user) do
 442     Cachex.del(:user_cache, "ap_id:#{user.ap_id}")
 443     Cachex.del(:user_cache, "nickname:#{user.nickname}")
 444     Cachex.del(:user_cache, "user_info:#{user.id}")
 445   end
 446
 447   def get_cached_by_ap_id(ap_id) do
 448     key = "ap_id:#{ap_id}"
 449     Cachex.fetch!(:user_cache, key, fn _ -> get_by_ap_id(ap_id) end)
 450   end
 451
 452   def get_cached_by_id(id) do
 453     key = "id:#{id}"
 454
 455     ap_id =
 456       Cachex.fetch!(:user_cache, key, fn _ ->
 457         user = get_by_id(id)
 458
 459         if user do
 460           Cachex.put(:user_cache, "ap_id:#{user.ap_id}", user)
 461           {:commit, user.ap_id}
 462         else
 463           {:ignore, ""}
 464         end
 465       end)
 466
 467     get_cached_by_ap_id(ap_id)
 468   end
 469
 470   def get_cached_by_nickname(nickname) do
 471     key = "nickname:#{nickname}"
 472     Cachex.fetch!(:user_cache, key, fn _ -> get_or_fetch_by_nickname(nickname) end)
 473   end
 474
 475   def get_cached_by_nickname_or_id(nickname_or_id) do
 476     get_cached_by_id(nickname_or_id) || get_cached_by_nickname(nickname_or_id)
 477   end
 478
 479   def get_by_nickname(nickname) do
 480     Repo.get_by(User, nickname: nickname) ||
 481       if Regex.match?(~r(@#{Pleroma.Web.Endpoint.host()})i, nickname) do
 482         Repo.get_by(User, nickname: local_nickname(nickname))
 483       end
 484   end
 485
 486   def get_by_nickname_or_email(nickname_or_email) do
 487     case user = Repo.get_by(User, nickname: nickname_or_email) do
 488       %User{} -> user
 489       nil -> Repo.get_by(User, email: nickname_or_email)
 490     end
 491   end
 492
 493   def get_cached_user_info(user) do
 494     key = "user_info:#{user.id}"
 495     Cachex.fetch!(:user_cache, key, fn _ -> user_info(user) end)
 496   end
 497
 498   def fetch_by_nickname(nickname) do
 499     ap_try = ActivityPub.make_user_from_nickname(nickname)
 500
 501     case ap_try do
 502       {:ok, user} -> {:ok, user}
 503       _ -> OStatus.make_user(nickname)
 504     end
 505   end
 506
 507   def get_or_fetch_by_nickname(nickname) do
 508     with %User{} = user <- get_by_nickname(nickname) do
 509       user
 510     else
 511       _e ->
 512         with [_nick, _domain] <- String.split(nickname, "@"),
 513              {:ok, user} <- fetch_by_nickname(nickname) do
 514           user
 515         else
 516           _e -> nil
 517         end
 518     end
 519   end
 520
 521   def get_followers_query(%User{id: id, follower_address: follower_address}, nil) do
 522     from(
 523       u in User,
 524       where: fragment("? <@ ?", ^[follower_address], u.following),
 525       where: u.id != ^id
 526     )
 527   end
 528
 529   def get_followers_query(user, page) do
 530     from(
 531       u in get_followers_query(user, nil),
 532       limit: 20,
 533       offset: ^((page - 1) * 20)
 534     )
 535   end
 536
 537   def get_followers_query(user), do: get_followers_query(user, nil)
 538
 539   def get_followers(user, page \\ nil) do
 540     q = get_followers_query(user, page)
 541
 542     {:ok, Repo.all(q)}
 543   end
 544
 545   def get_followers_ids(user, page \\ nil) do
 546     q = get_followers_query(user, page)
 547
 548     Repo.all(from(u in q, select: u.id))
 549   end
 550
 551   def get_friends_query(%User{id: id, following: following}, nil) do
 552     from(
 553       u in User,
 554       where: u.follower_address in ^following,
 555       where: u.id != ^id
 556     )
 557   end
 558
 559   def get_friends_query(user, page) do
 560     from(
 561       u in get_friends_query(user, nil),
 562       limit: 20,
 563       offset: ^((page - 1) * 20)
 564     )
 565   end
 566
 567   def get_friends_query(user), do: get_friends_query(user, nil)
 568
 569   def get_friends(user, page \\ nil) do
 570     q = get_friends_query(user, page)
 571
 572     {:ok, Repo.all(q)}
 573   end
 574
 575   def get_friends_ids(user, page \\ nil) do
 576     q = get_friends_query(user, page)
 577
 578     Repo.all(from(u in q, select: u.id))
 579   end
 580
 581   def get_follow_requests_query(%User{} = user) do
 582     from(
 583       a in Activity,
 584       where:
 585         fragment(
 586           "? ->> 'type' = 'Follow'",
 587           a.data
 588         ),
 589       where:
 590         fragment(
 591           "? ->> 'state' = 'pending'",
 592           a.data
 593         ),
 594       where:
 595         fragment(
 596           "? @> ?",
 597           a.data,
 598           ^%{"object" => user.ap_id}
 599         )
 600     )
 601   end
 602
 603   def get_follow_requests(%User{} = user) do
 604     q = get_follow_requests_query(user)
 605     reqs = Repo.all(q)
 606
 607     users =
 608       Enum.map(reqs, fn req -> req.actor end)
 609       |> Enum.uniq()
 610       |> Enum.map(fn ap_id -> get_by_ap_id(ap_id) end)
 611       |> Enum.filter(fn u -> !is_nil(u) end)
 612       |> Enum.filter(fn u -> !following?(u, user) end)
 613
 614     {:ok, users}
 615   end
 616
 617   def increase_note_count(%User{} = user) do
 618     info_cng = User.Info.add_to_note_count(user.info, 1)
 619
 620     cng =
 621       change(user)
 622       |> put_embed(:info, info_cng)
 623
 624     update_and_set_cache(cng)
 625   end
 626
 627   def decrease_note_count(%User{} = user) do
 628     info_cng = User.Info.add_to_note_count(user.info, -1)
 629
 630     cng =
 631       change(user)
 632       |> put_embed(:info, info_cng)
 633
 634     update_and_set_cache(cng)
 635   end
 636
 637   def update_note_count(%User{} = user) do
 638     note_count_query =
 639       from(
 640         a in Object,
 641         where: fragment("?->>'actor' = ? and ?->>'type' = 'Note'", a.data, ^user.ap_id, a.data),
 642         select: count(a.id)
 643       )
 644
 645     note_count = Repo.one(note_count_query)
 646
 647     info_cng = User.Info.set_note_count(user.info, note_count)
 648
 649     cng =
 650       change(user)
 651       |> put_embed(:info, info_cng)
 652
 653     update_and_set_cache(cng)
 654   end
 655
 656   def update_follower_count(%User{} = user) do
 657     follower_count_query =
 658       from(
 659         u in User,
 660         where: ^user.follower_address in u.following,
 661         where: u.id != ^user.id,
 662         select: count(u.id)
 663       )
 664
 665     follower_count = Repo.one(follower_count_query)
 666
 667     info_cng =
 668       user.info
 669       |> User.Info.set_follower_count(follower_count)
 670
 671     cng =
 672       change(user)
 673       |> put_embed(:info, info_cng)
 674
 675     update_and_set_cache(cng)
 676   end
 677
 678   def get_users_from_set_query(ap_ids, false) do
 679     from(
 680       u in User,
 681       where: u.ap_id in ^ap_ids
 682     )
 683   end
 684
 685   def get_users_from_set_query(ap_ids, true) do
 686     query = get_users_from_set_query(ap_ids, false)
 687
 688     from(
 689       u in query,
 690       where: u.local == true
 691     )
 692   end
 693
 694   def get_users_from_set(ap_ids, local_only \\ true) do
 695     get_users_from_set_query(ap_ids, local_only)
 696     |> Repo.all()
 697   end
 698
 699   def get_recipients_from_activity(%Activity{recipients: to}) do
 700     query =
 701       from(
 702         u in User,
 703         where: u.ap_id in ^to,
 704         or_where: fragment("? && ?", u.following, ^to)
 705       )
 706
 707     query = from(u in query, where: u.local == true)
 708
 709     Repo.all(query)
 710   end
 711
 712   def search(query, resolve \\ false, for_user \\ nil) do
 713     # Strip the beginning @ off if there is a query
 714     query = String.trim_leading(query, "@")
 715
 716     if resolve, do: User.get_or_fetch_by_nickname(query)
 717
 718     fts_results = do_search(fts_search_subquery(query), for_user)
 719
 720     {:ok, trigram_results} =
 721       Repo.transaction(fn ->
 722         Ecto.Adapters.SQL.query(Repo, "select set_limit(0.25)", [])
 723         do_search(trigram_search_subquery(query), for_user)
 724       end)
 725
 726     Enum.uniq_by(fts_results ++ trigram_results, & &1.id)
 727   end
 728
 729   defp do_search(subquery, for_user, options \\ []) do
 730     q =
 731       from(
 732         s in subquery(subquery),
 733         order_by: [desc: s.search_rank],
 734         limit: ^(options[:limit] || 20)
 735       )
 736
 737     results =
 738       q
 739       |> Repo.all()
 740       |> Enum.filter(&(&1.search_rank > 0))
 741
 742     boost_search_results(results, for_user)
 743   end
 744
 745   defp fts_search_subquery(query) do
 746     processed_query =
 747       query
 748       |> String.replace(~r/\W+/, " ")
 749       |> String.trim()
 750       |> String.split()
 751       |> Enum.map(&(&1 <> ":*"))
 752       |> Enum.join(" | ")
 753
 754     from(
 755       u in User,
 756       select_merge: %{
 757         search_rank:
 758           fragment(
 759             """
 760             ts_rank_cd(
 761               setweight(to_tsvector('simple', regexp_replace(?, '\\W', ' ', 'g')), 'A') ||
 762               setweight(to_tsvector('simple', regexp_replace(coalesce(?, ''), '\\W', ' ', 'g')), 'B'),
 763               to_tsquery('simple', ?),
 764               32
 765             )
 766             """,
 767             u.nickname,
 768             u.name,
 769             ^processed_query
 770           )
 771       },
 772       where:
 773         fragment(
 774           """
 775             (setweight(to_tsvector('simple', regexp_replace(?, '\\W', ' ', 'g')), 'A') ||
 776             setweight(to_tsvector('simple', regexp_replace(coalesce(?, ''), '\\W', ' ', 'g')), 'B')) @@ to_tsquery('simple', ?)
 777           """,
 778           u.nickname,
 779           u.name,
 780           ^processed_query
 781         )
 782     )
 783   end
 784
 785   defp trigram_search_subquery(query) do
 786     from(
 787       u in User,
 788       select_merge: %{
 789         search_rank:
 790           fragment(
 791             "similarity(?, trim(? || ' ' || coalesce(?, '')))",
 792             ^query,
 793             u.nickname,
 794             u.name
 795           )
 796       },
 797       where: fragment("trim(? || ' ' || coalesce(?, '')) % ?", u.nickname, u.name, ^query)
 798     )
 799   end
 800
 801   defp boost_search_results(results, nil), do: results
 802
 803   defp boost_search_results(results, for_user) do
 804     friends_ids = get_friends_ids(for_user)
 805     followers_ids = get_followers_ids(for_user)
 806
 807     Enum.map(
 808       results,
 809       fn u ->
 810         search_rank_coef =
 811           cond do
 812             u.id in friends_ids ->
 813               1.2
 814
 815             u.id in followers_ids ->
 816               1.1
 817
 818             true ->
 819               1
 820           end
 821
 822         Map.put(u, :search_rank, u.search_rank * search_rank_coef)
 823       end
 824     )
 825     |> Enum.sort_by(&(-&1.search_rank))
 826   end
 827
 828   def blocks_import(%User{} = blocker, blocked_identifiers) when is_list(blocked_identifiers) do
 829     Enum.map(
 830       blocked_identifiers,
 831       fn blocked_identifier ->
 832         with %User{} = blocked <- get_or_fetch(blocked_identifier),
 833              {:ok, blocker} <- block(blocker, blocked),
 834              {:ok, _} <- ActivityPub.block(blocker, blocked) do
 835           blocked
 836         else
 837           err ->
 838             Logger.debug("blocks_import failed for #{blocked_identifier} with: #{inspect(err)}")
 839             err
 840         end
 841       end
 842     )
 843   end
 844
 845   def block(blocker, %User{ap_id: ap_id} = blocked) do
 846     # sever any follow relationships to prevent leaks per activitypub (Pleroma issue #213)
 847     blocker =
 848       if following?(blocker, blocked) do
 849         {:ok, blocker, _} = unfollow(blocker, blocked)
 850         blocker
 851       else
 852         blocker
 853       end
 854
 855     if following?(blocked, blocker) do
 856       unfollow(blocked, blocker)
 857     end
 858
 859     info_cng =
 860       blocker.info
 861       |> User.Info.add_to_block(ap_id)
 862
 863     cng =
 864       change(blocker)
 865       |> put_embed(:info, info_cng)
 866
 867     update_and_set_cache(cng)
 868   end
 869
 870   # helper to handle the block given only an actor's AP id
 871   def block(blocker, %{ap_id: ap_id}) do
 872     block(blocker, User.get_by_ap_id(ap_id))
 873   end
 874
 875   def unblock(blocker, %{ap_id: ap_id}) do
 876     info_cng =
 877       blocker.info
 878       |> User.Info.remove_from_block(ap_id)
 879
 880     cng =
 881       change(blocker)
 882       |> put_embed(:info, info_cng)
 883
 884     update_and_set_cache(cng)
 885   end
 886
 887   def blocks?(user, %{ap_id: ap_id}) do
 888     blocks = user.info.blocks
 889     domain_blocks = user.info.domain_blocks
 890     %{host: host} = URI.parse(ap_id)
 891
 892     Enum.member?(blocks, ap_id) ||
 893       Enum.any?(domain_blocks, fn domain ->
 894         host == domain
 895       end)
 896   end
 897
 898   def blocked_users(user),
 899     do: Repo.all(from(u in User, where: u.ap_id in ^user.info.blocks))
 900
 901   def block_domain(user, domain) do
 902     info_cng =
 903       user.info
 904       |> User.Info.add_to_domain_block(domain)
 905
 906     cng =
 907       change(user)
 908       |> put_embed(:info, info_cng)
 909
 910     update_and_set_cache(cng)
 911   end
 912
 913   def unblock_domain(user, domain) do
 914     info_cng =
 915       user.info
 916       |> User.Info.remove_from_domain_block(domain)
 917
 918     cng =
 919       change(user)
 920       |> put_embed(:info, info_cng)
 921
 922     update_and_set_cache(cng)
 923   end
 924
 925   def local_user_query do
 926     from(
 927       u in User,
 928       where: u.local == true,
 929       where: not is_nil(u.nickname)
 930     )
 931   end
 932
 933   def active_local_user_query do
 934     from(
 935       u in local_user_query(),
 936       where: fragment("not (?->'deactivated' @> 'true')", u.info)
 937     )
 938   end
 939
 940   def moderator_user_query do
 941     from(
 942       u in User,
 943       where: u.local == true,
 944       where: fragment("?->'is_moderator' @> 'true'", u.info)
 945     )
 946   end
 947
 948   def deactivate(%User{} = user, status \\ true) do
 949     info_cng = User.Info.set_activation_status(user.info, status)
 950
 951     cng =
 952       change(user)
 953       |> put_embed(:info, info_cng)
 954
 955     update_and_set_cache(cng)
 956   end
 957
 958   def delete(%User{} = user) do
 959     {:ok, user} = User.deactivate(user)
 960
 961     # Remove all relationships
 962     {:ok, followers} = User.get_followers(user)
 963
 964     followers
 965     |> Enum.each(fn follower -> User.unfollow(follower, user) end)
 966
 967     {:ok, friends} = User.get_friends(user)
 968
 969     friends
 970     |> Enum.each(fn followed -> User.unfollow(user, followed) end)
 971
 972     query = from(a in Activity, where: a.actor == ^user.ap_id)
 973
 974     Repo.all(query)
 975     |> Enum.each(fn activity ->
 976       case activity.data["type"] do
 977         "Create" ->
 978           ActivityPub.delete(Object.normalize(activity.data["object"]))
 979
 980         # TODO: Do something with likes, follows, repeats.
 981         _ ->
 982           "Doing nothing"
 983       end
 984     end)
 985
 986     {:ok, user}
 987   end
 988
 989   def html_filter_policy(%User{info: %{no_rich_text: true}}) do
 990     Pleroma.HTML.Scrubber.TwitterText
 991   end
 992
 993   @default_scrubbers Pleroma.Config.get([:markup, :scrub_policy])
 994
 995   def html_filter_policy(_), do: @default_scrubbers
 996
 997   def get_or_fetch_by_ap_id(ap_id) do
 998     user = get_by_ap_id(ap_id)
 999
1000     if !is_nil(user) and !User.needs_update?(user) do
1001       user
1002     else
1003       ap_try = ActivityPub.make_user_from_ap_id(ap_id)
1004
1005       case ap_try do
1006         {:ok, user} ->
1007           user
1008
1009         _ ->
1010           case OStatus.make_user(ap_id) do
1011             {:ok, user} -> user
1012             _ -> {:error, "Could not fetch by AP id"}
1013           end
1014       end
1015     end
1016   end
1017
1018   def get_or_create_instance_user do
1019     relay_uri = "#{Pleroma.Web.Endpoint.url()}/relay"
1020
1021     if user = get_by_ap_id(relay_uri) do
1022       user
1023     else
1024       changes =
1025         %User{info: %User.Info{}}
1026         |> cast(%{}, [:ap_id, :nickname, :local])
1027         |> put_change(:ap_id, relay_uri)
1028         |> put_change(:nickname, nil)
1029         |> put_change(:local, true)
1030         |> put_change(:follower_address, relay_uri <> "/followers")
1031
1032       {:ok, user} = Repo.insert(changes)
1033       user
1034     end
1035   end
1036
1037   # AP style
1038   def public_key_from_info(%{
1039         source_data: %{"publicKey" => %{"publicKeyPem" => public_key_pem}}
1040       }) do
1041     key =
1042       public_key_pem
1043       |> :public_key.pem_decode()
1044       |> hd()
1045       |> :public_key.pem_entry_decode()
1046
1047     {:ok, key}
1048   end
1049
1050   # OStatus Magic Key
1051   def public_key_from_info(%{magic_key: magic_key}) do
1052     {:ok, Pleroma.Web.Salmon.decode_key(magic_key)}
1053   end
1054
1055   def get_public_key_for_ap_id(ap_id) do
1056     with %User{} = user <- get_or_fetch_by_ap_id(ap_id),
1057          {:ok, public_key} <- public_key_from_info(user.info) do
1058       {:ok, public_key}
1059     else
1060       _ -> :error
1061     end
1062   end
1063
1064   defp blank?(""), do: nil
1065   defp blank?(n), do: n
1066
1067   def insert_or_update_user(data) do
1068     data =
1069       data
1070       |> Map.put(:name, blank?(data[:name]) || data[:nickname])
1071
1072     cs = User.remote_user_creation(data)
1073
1074     Repo.insert(cs, on_conflict: :replace_all, conflict_target: :nickname)
1075   end
1076
1077   def ap_enabled?(%User{local: true}), do: true
1078   def ap_enabled?(%User{info: info}), do: info.ap_enabled
1079   def ap_enabled?(_), do: false
1080
1081   @doc "Gets or fetch a user by uri or nickname."
1082   @spec get_or_fetch(String.t()) :: User.t()
1083   def get_or_fetch("http" <> _host = uri), do: get_or_fetch_by_ap_id(uri)
1084   def get_or_fetch(nickname), do: get_or_fetch_by_nickname(nickname)
1085
1086   # wait a period of time and return newest version of the User structs
1087   # this is because we have synchronous follow APIs and need to simulate them
1088   # with an async handshake
1089   def wait_and_refresh(_, %User{local: true} = a, %User{local: true} = b) do
1090     with %User{} = a <- Repo.get(User, a.id),
1091          %User{} = b <- Repo.get(User, b.id) do
1092       {:ok, a, b}
1093     else
1094       _e ->
1095         :error
1096     end
1097   end
1098
1099   def wait_and_refresh(timeout, %User{} = a, %User{} = b) do
1100     with :ok <- :timer.sleep(timeout),
1101          %User{} = a <- Repo.get(User, a.id),
1102          %User{} = b <- Repo.get(User, b.id) do
1103       {:ok, a, b}
1104     else
1105       _e ->
1106         :error
1107     end
1108   end
1109
1110   def parse_bio(bio, user \\ %User{info: %{source_data: %{}}})
1111   def parse_bio(nil, _user), do: ""
1112   def parse_bio(bio, _user) when bio == "", do: bio
1113
1114   def parse_bio(bio, user) do
1115     mentions = Formatter.parse_mentions(bio)
1116     tags = Formatter.parse_tags(bio)
1117
1118     emoji =
1119       (user.info.source_data["tag"] || [])
1120       |> Enum.filter(fn %{"type" => t} -> t == "Emoji" end)
1121       |> Enum.map(fn %{"icon" => %{"url" => url}, "name" => name} ->
1122         {String.trim(name, ":"), url}
1123       end)
1124
1125     bio
1126     |> CommonUtils.format_input(mentions, tags, "text/plain", user_links: [format: :full])
1127     |> Formatter.emojify(emoji)
1128   end
1129
1130   def tag(user_identifiers, tags) when is_list(user_identifiers) do
1131     Repo.transaction(fn ->
1132       for user_identifier <- user_identifiers, do: tag(user_identifier, tags)
1133     end)
1134   end
1135
1136   def tag(nickname, tags) when is_binary(nickname),
1137     do: tag(User.get_by_nickname(nickname), tags)
1138
1139   def tag(%User{} = user, tags),
1140     do: update_tags(user, Enum.uniq((user.tags || []) ++ normalize_tags(tags)))
1141
1142   def untag(user_identifiers, tags) when is_list(user_identifiers) do
1143     Repo.transaction(fn ->
1144       for user_identifier <- user_identifiers, do: untag(user_identifier, tags)
1145     end)
1146   end
1147
1148   def untag(nickname, tags) when is_binary(nickname),
1149     do: untag(User.get_by_nickname(nickname), tags)
1150
1151   def untag(%User{} = user, tags),
1152     do: update_tags(user, (user.tags || []) -- normalize_tags(tags))
1153
1154   defp update_tags(%User{} = user, new_tags) do
1155     {:ok, updated_user} =
1156       user
1157       |> change(%{tags: new_tags})
1158       |> Repo.update()
1159
1160     updated_user
1161   end
1162
1163   defp normalize_tags(tags) do
1164     [tags]
1165     |> List.flatten()
1166     |> Enum.map(&String.downcase(&1))
1167   end
1168
1169   defp local_nickname_regex() do
1170     if Pleroma.Config.get([:instance, :extended_nickname_format]) do
1171       @extended_local_nickname_regex
1172     else
1173       @strict_local_nickname_regex
1174     end
1175   end
1176
1177   def local_nickname(nickname_or_mention) do
1178     nickname_or_mention
1179     |> full_nickname()
1180     |> String.split("@")
1181     |> hd()
1182   end
1183
1184   def full_nickname(nickname_or_mention),
1185     do: String.trim_leading(nickname_or_mention, "@")
1186
1187   def error_user(ap_id) do
1188     %User{
1189       name: ap_id,
1190       ap_id: ap_id,
1191       info: %User.Info{},
1192       nickname: "erroruser@example.com",
1193       inserted_at: NaiveDateTime.utc_now()
1194     }
1195   end
1196 end