git.squeep.com Git - akkoma/blob - lib/pleroma/user.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.User do
   6   use Ecto.Schema
   7
   8   import Ecto.{Changeset, Query}
   9   alias Pleroma.{Repo, User, Object, Web, Activity, Notification}
  10   alias Comeonin.Pbkdf2
  11   alias Pleroma.Formatter
  12   alias Pleroma.Web.CommonAPI.Utils, as: CommonUtils
  13   alias Pleroma.Web.{OStatus, Websub, OAuth}
  14   alias Pleroma.Web.ActivityPub.{Utils, ActivityPub}
  15
  16   require Logger
  17
  18   @type t :: %__MODULE__{}
  19
  20   @email_regex ~r/^[a-zA-Z0-9.!#$%&'*+\/=?^_`{|}~-]+@[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?(?:\.[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?)*$/
  21
  22   @strict_local_nickname_regex ~r/^[a-zA-Z\d]+$/
  23   @extended_local_nickname_regex ~r/^[a-zA-Z\d_-]+$/
  24
  25   schema "users" do
  26     field(:bio, :string)
  27     field(:email, :string)
  28     field(:name, :string)
  29     field(:nickname, :string)
  30     field(:password_hash, :string)
  31     field(:password, :string, virtual: true)
  32     field(:password_confirmation, :string, virtual: true)
  33     field(:following, {:array, :string}, default: [])
  34     field(:ap_id, :string)
  35     field(:avatar, :map)
  36     field(:local, :boolean, default: true)
  37     field(:follower_address, :string)
  38     field(:search_distance, :float, virtual: true)
  39     field(:tags, {:array, :string}, default: [])
  40     field(:last_refreshed_at, :naive_datetime)
  41     has_many(:notifications, Notification)
  42     embeds_one(:info, Pleroma.User.Info)
  43
  44     timestamps()
  45   end
  46
  47   def auth_active?(%User{local: false}), do: true
  48
  49   def auth_active?(%User{info: %User.Info{confirmation_pending: false}}), do: true
  50
  51   def auth_active?(%User{info: %User.Info{confirmation_pending: true}}),
  52     do: !Pleroma.Config.get([:instance, :account_activation_required])
  53
  54   def auth_active?(_), do: false
  55
  56   def visible_for?(user, for_user \\ nil)
  57
  58   def visible_for?(%User{id: user_id}, %User{id: for_id}) when user_id == for_id, do: true
  59
  60   def visible_for?(%User{} = user, for_user) do
  61     auth_active?(user) || superuser?(for_user)
  62   end
  63
  64   def visible_for?(_, _), do: false
  65
  66   def superuser?(%User{local: true, info: %User.Info{is_admin: true}}), do: true
  67   def superuser?(%User{local: true, info: %User.Info{is_moderator: true}}), do: true
  68   def superuser?(_), do: false
  69
  70   def avatar_url(user) do
  71     case user.avatar do
  72       %{"url" => [%{"href" => href} | _]} -> href
  73       _ -> "#{Web.base_url()}/images/avi.png"
  74     end
  75   end
  76
  77   def banner_url(user) do
  78     case user.info.banner do
  79       %{"url" => [%{"href" => href} | _]} -> href
  80       _ -> "#{Web.base_url()}/images/banner.png"
  81     end
  82   end
  83
  84   def profile_url(%User{info: %{source_data: %{"url" => url}}}), do: url
  85   def profile_url(%User{ap_id: ap_id}), do: ap_id
  86   def profile_url(_), do: nil
  87
  88   def ap_id(%User{nickname: nickname}) do
  89     "#{Web.base_url()}/users/#{nickname}"
  90   end
  91
  92   def ap_followers(%User{} = user) do
  93     "#{ap_id(user)}/followers"
  94   end
  95
  96   def follow_changeset(struct, params \\ %{}) do
  97     struct
  98     |> cast(params, [:following])
  99     |> validate_required([:following])
 100   end
 101
 102   def user_info(%User{} = user) do
 103     oneself = if user.local, do: 1, else: 0
 104
 105     %{
 106       following_count: length(user.following) - oneself,
 107       note_count: user.info.note_count,
 108       follower_count: user.info.follower_count,
 109       locked: user.info.locked,
 110       confirmation_pending: user.info.confirmation_pending,
 111       default_scope: user.info.default_scope
 112     }
 113   end
 114
 115   def remote_user_creation(params) do
 116     params =
 117       params
 118       |> Map.put(:info, params[:info] || %{})
 119
 120     info_cng = User.Info.remote_user_creation(%User.Info{}, params[:info])
 121
 122     changes =
 123       %User{}
 124       |> cast(params, [:bio, :name, :ap_id, :nickname, :avatar])
 125       |> validate_required([:name, :ap_id])
 126       |> unique_constraint(:nickname)
 127       |> validate_format(:nickname, @email_regex)
 128       |> validate_length(:bio, max: 5000)
 129       |> validate_length(:name, max: 100)
 130       |> put_change(:local, false)
 131       |> put_embed(:info, info_cng)
 132
 133     if changes.valid? do
 134       case info_cng.changes[:source_data] do
 135         %{"followers" => followers} ->
 136           changes
 137           |> put_change(:follower_address, followers)
 138
 139         _ ->
 140           followers = User.ap_followers(%User{nickname: changes.changes[:nickname]})
 141
 142           changes
 143           |> put_change(:follower_address, followers)
 144       end
 145     else
 146       changes
 147     end
 148   end
 149
 150   def update_changeset(struct, params \\ %{}) do
 151     struct
 152     |> cast(params, [:bio, :name, :avatar])
 153     |> unique_constraint(:nickname)
 154     |> validate_format(:nickname, local_nickname_regex())
 155     |> validate_length(:bio, max: 5000)
 156     |> validate_length(:name, min: 1, max: 100)
 157   end
 158
 159   def upgrade_changeset(struct, params \\ %{}) do
 160     params =
 161       params
 162       |> Map.put(:last_refreshed_at, NaiveDateTime.utc_now())
 163
 164     info_cng =
 165       struct.info
 166       |> User.Info.user_upgrade(params[:info])
 167
 168     struct
 169     |> cast(params, [:bio, :name, :follower_address, :avatar, :last_refreshed_at])
 170     |> unique_constraint(:nickname)
 171     |> validate_format(:nickname, local_nickname_regex())
 172     |> validate_length(:bio, max: 5000)
 173     |> validate_length(:name, max: 100)
 174     |> put_embed(:info, info_cng)
 175   end
 176
 177   def password_update_changeset(struct, params) do
 178     changeset =
 179       struct
 180       |> cast(params, [:password, :password_confirmation])
 181       |> validate_required([:password, :password_confirmation])
 182       |> validate_confirmation(:password)
 183
 184     OAuth.Token.delete_user_tokens(struct)
 185     OAuth.Authorization.delete_user_authorizations(struct)
 186
 187     if changeset.valid? do
 188       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 189
 190       changeset
 191       |> put_change(:password_hash, hashed)
 192     else
 193       changeset
 194     end
 195   end
 196
 197   def reset_password(user, data) do
 198     update_and_set_cache(password_update_changeset(user, data))
 199   end
 200
 201   def register_changeset(struct, params \\ %{}, opts \\ []) do
 202     confirmation_status =
 203       if opts[:confirmed] || !Pleroma.Config.get([:instance, :account_activation_required]) do
 204         :confirmed
 205       else
 206         :unconfirmed
 207       end
 208
 209     info_change = User.Info.confirmation_changeset(%User.Info{}, confirmation_status)
 210
 211     changeset =
 212       struct
 213       |> cast(params, [:bio, :email, :name, :nickname, :password, :password_confirmation])
 214       |> validate_required([:email, :name, :nickname, :password, :password_confirmation])
 215       |> validate_confirmation(:password)
 216       |> unique_constraint(:email)
 217       |> unique_constraint(:nickname)
 218       |> validate_exclusion(:nickname, Pleroma.Config.get([Pleroma.User, :restricted_nicknames]))
 219       |> validate_format(:nickname, local_nickname_regex())
 220       |> validate_format(:email, @email_regex)
 221       |> validate_length(:bio, max: 1000)
 222       |> validate_length(:name, min: 1, max: 100)
 223       |> put_change(:info, info_change)
 224
 225     if changeset.valid? do
 226       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 227       ap_id = User.ap_id(%User{nickname: changeset.changes[:nickname]})
 228       followers = User.ap_followers(%User{nickname: changeset.changes[:nickname]})
 229
 230       changeset
 231       |> put_change(:password_hash, hashed)
 232       |> put_change(:ap_id, ap_id)
 233       |> put_change(:following, [followers])
 234       |> put_change(:follower_address, followers)
 235     else
 236       changeset
 237     end
 238   end
 239
 240   defp autofollow_users(user) do
 241     candidates = Pleroma.Config.get([:instance, :autofollowed_nicknames])
 242
 243     autofollowed_users =
 244       from(u in User,
 245         where: u.local == true,
 246         where: u.nickname in ^candidates
 247       )
 248       |> Repo.all()
 249
 250     follow_all(user, autofollowed_users)
 251   end
 252
 253   @doc "Inserts provided changeset, performs post-registration actions (confirmation email sending etc.)"
 254   def register(%Ecto.Changeset{} = changeset) do
 255     with {:ok, user} <- Repo.insert(changeset),
 256          {:ok, _} <- try_send_confirmation_email(user),
 257          {:ok, user} <- autofollow_users(user) do
 258       {:ok, user}
 259     end
 260   end
 261
 262   def try_send_confirmation_email(%User{} = user) do
 263     if user.info.confirmation_pending &&
 264          Pleroma.Config.get([:instance, :account_activation_required]) do
 265       user
 266       |> Pleroma.UserEmail.account_confirmation_email()
 267       |> Pleroma.Mailer.deliver()
 268     else
 269       {:ok, :noop}
 270     end
 271   end
 272
 273   def needs_update?(%User{local: true}), do: false
 274
 275   def needs_update?(%User{local: false, last_refreshed_at: nil}), do: true
 276
 277   def needs_update?(%User{local: false} = user) do
 278     NaiveDateTime.diff(NaiveDateTime.utc_now(), user.last_refreshed_at) >= 86400
 279   end
 280
 281   def needs_update?(_), do: true
 282
 283   def maybe_direct_follow(%User{} = follower, %User{local: true, info: %{locked: true}}) do
 284     {:ok, follower}
 285   end
 286
 287   def maybe_direct_follow(%User{} = follower, %User{local: true} = followed) do
 288     follow(follower, followed)
 289   end
 290
 291   def maybe_direct_follow(%User{} = follower, %User{} = followed) do
 292     if not User.ap_enabled?(followed) do
 293       follow(follower, followed)
 294     else
 295       {:ok, follower}
 296     end
 297   end
 298
 299   def maybe_follow(%User{} = follower, %User{info: _info} = followed) do
 300     if not following?(follower, followed) do
 301       follow(follower, followed)
 302     else
 303       {:ok, follower}
 304     end
 305   end
 306
 307   @doc "A mass follow for local users. Ignores blocks and has no side effects"
 308   @spec follow_all(User.t(), list(User.t())) :: {atom(), User.t()}
 309   def follow_all(follower, followeds) do
 310     following =
 311       (follower.following ++ Enum.map(followeds, fn %{follower_address: fa} -> fa end))
 312       |> Enum.uniq()
 313
 314     {:ok, follower} =
 315       follower
 316       |> follow_changeset(%{following: following})
 317       |> update_and_set_cache
 318
 319     Enum.each(followeds, fn followed ->
 320       update_follower_count(followed)
 321     end)
 322
 323     {:ok, follower}
 324   end
 325
 326   def follow(%User{} = follower, %User{info: info} = followed) do
 327     user_config = Application.get_env(:pleroma, :user)
 328     deny_follow_blocked = Keyword.get(user_config, :deny_follow_blocked)
 329
 330     ap_followers = followed.follower_address
 331
 332     cond do
 333       following?(follower, followed) or info.deactivated ->
 334         {:error, "Could not follow user: #{followed.nickname} is already on your list."}
 335
 336       deny_follow_blocked and blocks?(followed, follower) ->
 337         {:error, "Could not follow user: #{followed.nickname} blocked you."}
 338
 339       true ->
 340         if !followed.local && follower.local && !ap_enabled?(followed) do
 341           Websub.subscribe(follower, followed)
 342         end
 343
 344         following =
 345           [ap_followers | follower.following]
 346           |> Enum.uniq()
 347
 348         follower =
 349           follower
 350           |> follow_changeset(%{following: following})
 351           |> update_and_set_cache
 352
 353         {:ok, _} = update_follower_count(followed)
 354
 355         follower
 356     end
 357   end
 358
 359   def unfollow(%User{} = follower, %User{} = followed) do
 360     ap_followers = followed.follower_address
 361
 362     if following?(follower, followed) and follower.ap_id != followed.ap_id do
 363       following =
 364         follower.following
 365         |> List.delete(ap_followers)
 366
 367       {:ok, follower} =
 368         follower
 369         |> follow_changeset(%{following: following})
 370         |> update_and_set_cache
 371
 372       {:ok, followed} = update_follower_count(followed)
 373
 374       {:ok, follower, Utils.fetch_latest_follow(follower, followed)}
 375     else
 376       {:error, "Not subscribed!"}
 377     end
 378   end
 379
 380   @spec following?(User.t(), User.t()) :: boolean
 381   def following?(%User{} = follower, %User{} = followed) do
 382     Enum.member?(follower.following, followed.follower_address)
 383   end
 384
 385   def follow_import(%User{} = follower, followed_identifiers)
 386       when is_list(followed_identifiers) do
 387     Enum.map(
 388       followed_identifiers,
 389       fn followed_identifier ->
 390         with %User{} = followed <- get_or_fetch(followed_identifier),
 391              {:ok, follower} <- maybe_direct_follow(follower, followed),
 392              {:ok, _} <- ActivityPub.follow(follower, followed) do
 393           followed
 394         else
 395           err ->
 396             Logger.debug("follow_import failed for #{followed_identifier} with: #{inspect(err)}")
 397             err
 398         end
 399       end
 400     )
 401   end
 402
 403   def locked?(%User{} = user) do
 404     user.info.locked || false
 405   end
 406
 407   def get_by_id(id) do
 408     Repo.get_by(User, id: id)
 409   end
 410
 411   def get_by_ap_id(ap_id) do
 412     Repo.get_by(User, ap_id: ap_id)
 413   end
 414
 415   # This is mostly an SPC migration fix. This guesses the user nickname (by taking the last part of the ap_id and the domain) and tries to get that user
 416   def get_by_guessed_nickname(ap_id) do
 417     domain = URI.parse(ap_id).host
 418     name = List.last(String.split(ap_id, "/"))
 419     nickname = "#{name}@#{domain}"
 420
 421     get_by_nickname(nickname)
 422   end
 423
 424   def update_and_set_cache(changeset) do
 425     with {:ok, user} <- Repo.update(changeset) do
 426       Cachex.put(:user_cache, "ap_id:#{user.ap_id}", user)
 427       Cachex.put(:user_cache, "nickname:#{user.nickname}", user)
 428       Cachex.put(:user_cache, "user_info:#{user.id}", user_info(user))
 429       {:ok, user}
 430     else
 431       e -> e
 432     end
 433   end
 434
 435   def invalidate_cache(user) do
 436     Cachex.del(:user_cache, "ap_id:#{user.ap_id}")
 437     Cachex.del(:user_cache, "nickname:#{user.nickname}")
 438     Cachex.del(:user_cache, "user_info:#{user.id}")
 439   end
 440
 441   def get_cached_by_ap_id(ap_id) do
 442     key = "ap_id:#{ap_id}"
 443     Cachex.fetch!(:user_cache, key, fn _ -> get_by_ap_id(ap_id) end)
 444   end
 445
 446   def get_cached_by_id(id) do
 447     key = "id:#{id}"
 448
 449     ap_id =
 450       Cachex.fetch!(:user_cache, key, fn _ ->
 451         user = get_by_id(id)
 452         Cachex.put(:user_cache, "ap_id:#{user.ap_id}", user)
 453         {:commit, user.ap_id}
 454       end)
 455
 456     get_cached_by_ap_id(ap_id)
 457   end
 458
 459   def get_cached_by_nickname(nickname) do
 460     key = "nickname:#{nickname}"
 461     Cachex.fetch!(:user_cache, key, fn _ -> get_or_fetch_by_nickname(nickname) end)
 462   end
 463
 464   def get_cached_by_nickname_or_id(nickname_or_id) do
 465       get_cached_by_id(maybe_id) || get_cached_by_nickname(nickname_or_id)
 466     end
 467   end
 468
 469   def get_by_nickname(nickname) do
 470     Repo.get_by(User, nickname: nickname) ||
 471       if Regex.match?(~r(@#{Pleroma.Web.Endpoint.host()})i, nickname) do
 472         [local_nickname, _] = String.split(nickname, "@")
 473         Repo.get_by(User, nickname: local_nickname)
 474       end
 475   end
 476
 477   def get_by_nickname_or_email(nickname_or_email) do
 478     case user = Repo.get_by(User, nickname: nickname_or_email) do
 479       %User{} -> user
 480       nil -> Repo.get_by(User, email: nickname_or_email)
 481     end
 482   end
 483
 484   def get_cached_user_info(user) do
 485     key = "user_info:#{user.id}"
 486     Cachex.fetch!(:user_cache, key, fn _ -> user_info(user) end)
 487   end
 488
 489   def fetch_by_nickname(nickname) do
 490     ap_try = ActivityPub.make_user_from_nickname(nickname)
 491
 492     case ap_try do
 493       {:ok, user} -> {:ok, user}
 494       _ -> OStatus.make_user(nickname)
 495     end
 496   end
 497
 498   def get_or_fetch_by_nickname(nickname) do
 499     with %User{} = user <- get_by_nickname(nickname) do
 500       user
 501     else
 502       _e ->
 503         with [_nick, _domain] <- String.split(nickname, "@"),
 504              {:ok, user} <- fetch_by_nickname(nickname) do
 505           user
 506         else
 507           _e -> nil
 508         end
 509     end
 510   end
 511
 512   def get_followers_query(%User{id: id, follower_address: follower_address}, nil) do
 513     from(
 514       u in User,
 515       where: fragment("? <@ ?", ^[follower_address], u.following),
 516       where: u.id != ^id
 517     )
 518   end
 519
 520   def get_followers_query(user, page) do
 521     from(
 522       u in get_followers_query(user, nil),
 523       limit: 20,
 524       offset: ^((page - 1) * 20)
 525     )
 526   end
 527
 528   def get_followers_query(user), do: get_followers_query(user, nil)
 529
 530   def get_followers(user, page \\ nil) do
 531     q = get_followers_query(user, page)
 532
 533     {:ok, Repo.all(q)}
 534   end
 535
 536   def get_friends_query(%User{id: id, following: following}, nil) do
 537     from(
 538       u in User,
 539       where: u.follower_address in ^following,
 540       where: u.id != ^id
 541     )
 542   end
 543
 544   def get_friends_query(user, page) do
 545     from(
 546       u in get_friends_query(user, nil),
 547       limit: 20,
 548       offset: ^((page - 1) * 20)
 549     )
 550   end
 551
 552   def get_friends_query(user), do: get_friends_query(user, nil)
 553
 554   def get_friends(user, page \\ nil) do
 555     q = get_friends_query(user, page)
 556
 557     {:ok, Repo.all(q)}
 558   end
 559
 560   def get_follow_requests_query(%User{} = user) do
 561     from(
 562       a in Activity,
 563       where:
 564         fragment(
 565           "? ->> 'type' = 'Follow'",
 566           a.data
 567         ),
 568       where:
 569         fragment(
 570           "? ->> 'state' = 'pending'",
 571           a.data
 572         ),
 573       where:
 574         fragment(
 575           "? @> ?",
 576           a.data,
 577           ^%{"object" => user.ap_id}
 578         )
 579     )
 580   end
 581
 582   def get_follow_requests(%User{} = user) do
 583     q = get_follow_requests_query(user)
 584     reqs = Repo.all(q)
 585
 586     users =
 587       Enum.map(reqs, fn req -> req.actor end)
 588       |> Enum.uniq()
 589       |> Enum.map(fn ap_id -> get_by_ap_id(ap_id) end)
 590       |> Enum.filter(fn u -> !is_nil(u) end)
 591       |> Enum.filter(fn u -> !following?(u, user) end)
 592
 593     {:ok, users}
 594   end
 595
 596   def increase_note_count(%User{} = user) do
 597     info_cng = User.Info.add_to_note_count(user.info, 1)
 598
 599     cng =
 600       change(user)
 601       |> put_embed(:info, info_cng)
 602
 603     update_and_set_cache(cng)
 604   end
 605
 606   def decrease_note_count(%User{} = user) do
 607     info_cng = User.Info.add_to_note_count(user.info, -1)
 608
 609     cng =
 610       change(user)
 611       |> put_embed(:info, info_cng)
 612
 613     update_and_set_cache(cng)
 614   end
 615
 616   def update_note_count(%User{} = user) do
 617     note_count_query =
 618       from(
 619         a in Object,
 620         where: fragment("?->>'actor' = ? and ?->>'type' = 'Note'", a.data, ^user.ap_id, a.data),
 621         select: count(a.id)
 622       )
 623
 624     note_count = Repo.one(note_count_query)
 625
 626     info_cng = User.Info.set_note_count(user.info, note_count)
 627
 628     cng =
 629       change(user)
 630       |> put_embed(:info, info_cng)
 631
 632     update_and_set_cache(cng)
 633   end
 634
 635   def update_follower_count(%User{} = user) do
 636     follower_count_query =
 637       from(
 638         u in User,
 639         where: ^user.follower_address in u.following,
 640         where: u.id != ^user.id,
 641         select: count(u.id)
 642       )
 643
 644     follower_count = Repo.one(follower_count_query)
 645
 646     info_cng =
 647       user.info
 648       |> User.Info.set_follower_count(follower_count)
 649
 650     cng =
 651       change(user)
 652       |> put_embed(:info, info_cng)
 653
 654     update_and_set_cache(cng)
 655   end
 656
 657   def get_users_from_set_query(ap_ids, false) do
 658     from(
 659       u in User,
 660       where: u.ap_id in ^ap_ids
 661     )
 662   end
 663
 664   def get_users_from_set_query(ap_ids, true) do
 665     query = get_users_from_set_query(ap_ids, false)
 666
 667     from(
 668       u in query,
 669       where: u.local == true
 670     )
 671   end
 672
 673   def get_users_from_set(ap_ids, local_only \\ true) do
 674     get_users_from_set_query(ap_ids, local_only)
 675     |> Repo.all()
 676   end
 677
 678   def get_recipients_from_activity(%Activity{recipients: to}) do
 679     query =
 680       from(
 681         u in User,
 682         where: u.ap_id in ^to,
 683         or_where: fragment("? && ?", u.following, ^to)
 684       )
 685
 686     query = from(u in query, where: u.local == true)
 687
 688     Repo.all(query)
 689   end
 690
 691   def search(query, resolve \\ false) do
 692     # strip the beginning @ off if there is a query
 693     query = String.trim_leading(query, "@")
 694
 695     if resolve do
 696       User.get_or_fetch_by_nickname(query)
 697     end
 698
 699     inner =
 700       from(
 701         u in User,
 702         select_merge: %{
 703           search_distance:
 704             fragment(
 705               "? <-> (? || coalesce(?, ''))",
 706               ^query,
 707               u.nickname,
 708               u.name
 709             )
 710         },
 711         where: not is_nil(u.nickname)
 712       )
 713
 714     q =
 715       from(
 716         s in subquery(inner),
 717         order_by: s.search_distance,
 718         limit: 20
 719       )
 720
 721     Repo.all(q)
 722   end
 723
 724   def blocks_import(%User{} = blocker, blocked_identifiers) when is_list(blocked_identifiers) do
 725     Enum.map(
 726       blocked_identifiers,
 727       fn blocked_identifier ->
 728         with %User{} = blocked <- get_or_fetch(blocked_identifier),
 729              {:ok, blocker} <- block(blocker, blocked),
 730              {:ok, _} <- ActivityPub.block(blocker, blocked) do
 731           blocked
 732         else
 733           err ->
 734             Logger.debug("blocks_import failed for #{blocked_identifier} with: #{inspect(err)}")
 735             err
 736         end
 737       end
 738     )
 739   end
 740
 741   def block(blocker, %User{ap_id: ap_id} = blocked) do
 742     # sever any follow relationships to prevent leaks per activitypub (Pleroma issue #213)
 743     blocker =
 744       if following?(blocker, blocked) do
 745         {:ok, blocker, _} = unfollow(blocker, blocked)
 746         blocker
 747       else
 748         blocker
 749       end
 750
 751     if following?(blocked, blocker) do
 752       unfollow(blocked, blocker)
 753     end
 754
 755     info_cng =
 756       blocker.info
 757       |> User.Info.add_to_block(ap_id)
 758
 759     cng =
 760       change(blocker)
 761       |> put_embed(:info, info_cng)
 762
 763     update_and_set_cache(cng)
 764   end
 765
 766   # helper to handle the block given only an actor's AP id
 767   def block(blocker, %{ap_id: ap_id}) do
 768     block(blocker, User.get_by_ap_id(ap_id))
 769   end
 770
 771   def unblock(blocker, %{ap_id: ap_id}) do
 772     info_cng =
 773       blocker.info
 774       |> User.Info.remove_from_block(ap_id)
 775
 776     cng =
 777       change(blocker)
 778       |> put_embed(:info, info_cng)
 779
 780     update_and_set_cache(cng)
 781   end
 782
 783   def blocks?(user, %{ap_id: ap_id}) do
 784     blocks = user.info.blocks
 785     domain_blocks = user.info.domain_blocks
 786     %{host: host} = URI.parse(ap_id)
 787
 788     Enum.member?(blocks, ap_id) ||
 789       Enum.any?(domain_blocks, fn domain ->
 790         host == domain
 791       end)
 792   end
 793
 794   def blocked_users(user),
 795     do: Repo.all(from(u in User, where: u.ap_id in ^user.info.blocks))
 796
 797   def block_domain(user, domain) do
 798     info_cng =
 799       user.info
 800       |> User.Info.add_to_domain_block(domain)
 801
 802     cng =
 803       change(user)
 804       |> put_embed(:info, info_cng)
 805
 806     update_and_set_cache(cng)
 807   end
 808
 809   def unblock_domain(user, domain) do
 810     info_cng =
 811       user.info
 812       |> User.Info.remove_from_domain_block(domain)
 813
 814     cng =
 815       change(user)
 816       |> put_embed(:info, info_cng)
 817
 818     update_and_set_cache(cng)
 819   end
 820
 821   def local_user_query() do
 822     from(
 823       u in User,
 824       where: u.local == true,
 825       where: not is_nil(u.nickname)
 826     )
 827   end
 828
 829   def moderator_user_query() do
 830     from(
 831       u in User,
 832       where: u.local == true,
 833       where: fragment("?->'is_moderator' @> 'true'", u.info)
 834     )
 835   end
 836
 837   def deactivate(%User{} = user, status \\ true) do
 838     info_cng = User.Info.set_activation_status(user.info, status)
 839
 840     cng =
 841       change(user)
 842       |> put_embed(:info, info_cng)
 843
 844     update_and_set_cache(cng)
 845   end
 846
 847   def delete(%User{} = user) do
 848     {:ok, user} = User.deactivate(user)
 849
 850     # Remove all relationships
 851     {:ok, followers} = User.get_followers(user)
 852
 853     followers
 854     |> Enum.each(fn follower -> User.unfollow(follower, user) end)
 855
 856     {:ok, friends} = User.get_friends(user)
 857
 858     friends
 859     |> Enum.each(fn followed -> User.unfollow(user, followed) end)
 860
 861     query = from(a in Activity, where: a.actor == ^user.ap_id)
 862
 863     Repo.all(query)
 864     |> Enum.each(fn activity ->
 865       case activity.data["type"] do
 866         "Create" ->
 867           ActivityPub.delete(Object.normalize(activity.data["object"]))
 868
 869         # TODO: Do something with likes, follows, repeats.
 870         _ ->
 871           "Doing nothing"
 872       end
 873     end)
 874
 875     {:ok, user}
 876   end
 877
 878   def html_filter_policy(%User{info: %{no_rich_text: true}}) do
 879     Pleroma.HTML.Scrubber.TwitterText
 880   end
 881
 882   @default_scrubbers Pleroma.Config.get([:markup, :scrub_policy])
 883
 884   def html_filter_policy(_), do: @default_scrubbers
 885
 886   def get_or_fetch_by_ap_id(ap_id) do
 887     user = get_by_ap_id(ap_id)
 888
 889     if !is_nil(user) and !User.needs_update?(user) do
 890       user
 891     else
 892       ap_try = ActivityPub.make_user_from_ap_id(ap_id)
 893
 894       case ap_try do
 895         {:ok, user} ->
 896           user
 897
 898         _ ->
 899           case OStatus.make_user(ap_id) do
 900             {:ok, user} -> user
 901             _ -> {:error, "Could not fetch by AP id"}
 902           end
 903       end
 904     end
 905   end
 906
 907   def get_or_create_instance_user do
 908     relay_uri = "#{Pleroma.Web.Endpoint.url()}/relay"
 909
 910     if user = get_by_ap_id(relay_uri) do
 911       user
 912     else
 913       changes =
 914         %User{info: %User.Info{}}
 915         |> cast(%{}, [:ap_id, :nickname, :local])
 916         |> put_change(:ap_id, relay_uri)
 917         |> put_change(:nickname, nil)
 918         |> put_change(:local, true)
 919         |> put_change(:follower_address, relay_uri <> "/followers")
 920
 921       {:ok, user} = Repo.insert(changes)
 922       user
 923     end
 924   end
 925
 926   # AP style
 927   def public_key_from_info(%{
 928         source_data: %{"publicKey" => %{"publicKeyPem" => public_key_pem}}
 929       }) do
 930     key =
 931       public_key_pem
 932       |> :public_key.pem_decode()
 933       |> hd()
 934       |> :public_key.pem_entry_decode()
 935
 936     {:ok, key}
 937   end
 938
 939   # OStatus Magic Key
 940   def public_key_from_info(%{magic_key: magic_key}) do
 941     {:ok, Pleroma.Web.Salmon.decode_key(magic_key)}
 942   end
 943
 944   def get_public_key_for_ap_id(ap_id) do
 945     with %User{} = user <- get_or_fetch_by_ap_id(ap_id),
 946          {:ok, public_key} <- public_key_from_info(user.info) do
 947       {:ok, public_key}
 948     else
 949       _ -> :error
 950     end
 951   end
 952
 953   defp blank?(""), do: nil
 954   defp blank?(n), do: n
 955
 956   def insert_or_update_user(data) do
 957     data =
 958       data
 959       |> Map.put(:name, blank?(data[:name]) || data[:nickname])
 960
 961     cs = User.remote_user_creation(data)
 962
 963     Repo.insert(cs, on_conflict: :replace_all, conflict_target: :nickname)
 964   end
 965
 966   def ap_enabled?(%User{local: true}), do: true
 967   def ap_enabled?(%User{info: info}), do: info.ap_enabled
 968   def ap_enabled?(_), do: false
 969
 970   @doc "Gets or fetch a user by uri or nickname."
 971   @spec get_or_fetch(String.t()) :: User.t()
 972   def get_or_fetch("http" <> _host = uri), do: get_or_fetch_by_ap_id(uri)
 973   def get_or_fetch(nickname), do: get_or_fetch_by_nickname(nickname)
 974
 975   # wait a period of time and return newest version of the User structs
 976   # this is because we have synchronous follow APIs and need to simulate them
 977   # with an async handshake
 978   def wait_and_refresh(_, %User{local: true} = a, %User{local: true} = b) do
 979     with %User{} = a <- Repo.get(User, a.id),
 980          %User{} = b <- Repo.get(User, b.id) do
 981       {:ok, a, b}
 982     else
 983       _e ->
 984         :error
 985     end
 986   end
 987
 988   def wait_and_refresh(timeout, %User{} = a, %User{} = b) do
 989     with :ok <- :timer.sleep(timeout),
 990          %User{} = a <- Repo.get(User, a.id),
 991          %User{} = b <- Repo.get(User, b.id) do
 992       {:ok, a, b}
 993     else
 994       _e ->
 995         :error
 996     end
 997   end
 998
 999   def parse_bio(bio, user \\ %User{info: %{source_data: %{}}})
1000   def parse_bio(nil, _user), do: ""
1001   def parse_bio(bio, _user) when bio == "", do: bio
1002
1003   def parse_bio(bio, user) do
1004     mentions = Formatter.parse_mentions(bio)
1005     tags = Formatter.parse_tags(bio)
1006
1007     emoji =
1008       (user.info.source_data["tag"] || [])
1009       |> Enum.filter(fn %{"type" => t} -> t == "Emoji" end)
1010       |> Enum.map(fn %{"icon" => %{"url" => url}, "name" => name} ->
1011         {String.trim(name, ":"), url}
1012       end)
1013
1014     bio
1015     |> CommonUtils.format_input(mentions, tags, "text/plain")
1016     |> Formatter.emojify(emoji)
1017   end
1018
1019   def tag(user_identifiers, tags) when is_list(user_identifiers) do
1020     Repo.transaction(fn ->
1021       for user_identifier <- user_identifiers, do: tag(user_identifier, tags)
1022     end)
1023   end
1024
1025   def tag(nickname, tags) when is_binary(nickname),
1026     do: tag(User.get_by_nickname(nickname), tags)
1027
1028   def tag(%User{} = user, tags),
1029     do: update_tags(user, Enum.uniq((user.tags || []) ++ normalize_tags(tags)))
1030
1031   def untag(user_identifiers, tags) when is_list(user_identifiers) do
1032     Repo.transaction(fn ->
1033       for user_identifier <- user_identifiers, do: untag(user_identifier, tags)
1034     end)
1035   end
1036
1037   def untag(nickname, tags) when is_binary(nickname),
1038     do: untag(User.get_by_nickname(nickname), tags)
1039
1040   def untag(%User{} = user, tags),
1041     do: update_tags(user, (user.tags || []) -- normalize_tags(tags))
1042
1043   defp update_tags(%User{} = user, new_tags) do
1044     {:ok, updated_user} =
1045       user
1046       |> change(%{tags: new_tags})
1047       |> Repo.update()
1048
1049     updated_user
1050   end
1051
1052   defp normalize_tags(tags) do
1053     [tags]
1054     |> List.flatten()
1055     |> Enum.map(&String.downcase(&1))
1056   end
1057
1058   defp local_nickname_regex() do
1059     if Pleroma.Config.get([:instance, :extended_nickname_format]) do
1060       @extended_local_nickname_regex
1061     else
1062       @strict_local_nickname_regex
1063     end
1064   end
1065 end