git.squeep.com Git - akkoma/blob - lib/pleroma/user.ex

   1 defmodule Pleroma.User do
   2   use Ecto.Schema
   3
   4   import Ecto.{Changeset, Query}
   5   alias Pleroma.{Repo, User, Object, Web, Activity, Notification}
   6   alias Comeonin.Pbkdf2
   7   alias Pleroma.Web.{OStatus, Websub, OAuth}
   8   alias Pleroma.Web.ActivityPub.{Utils, ActivityPub}
   9
  10   schema "users" do
  11     field(:bio, :string)
  12     field(:email, :string)
  13     field(:name, :string)
  14     field(:nickname, :string)
  15     field(:password_hash, :string)
  16     field(:password, :string, virtual: true)
  17     field(:password_confirmation, :string, virtual: true)
  18     field(:following, {:array, :string}, default: [])
  19     field(:ap_id, :string)
  20     field(:avatar, :map)
  21     field(:local, :boolean, default: true)
  22     field(:info, :map, default: %{})
  23     field(:follower_address, :string)
  24     field(:search_distance, :float, virtual: true)
  25     field(:last_refreshed_at, :naive_datetime)
  26     has_many(:notifications, Notification)
  27
  28     timestamps()
  29   end
  30
  31   def avatar_url(user) do
  32     case user.avatar do
  33       %{"url" => [%{"href" => href} | _]} -> href
  34       _ -> "#{Web.base_url()}/images/avi.png"
  35     end
  36   end
  37
  38   def banner_url(user) do
  39     case user.info["banner"] do
  40       %{"url" => [%{"href" => href} | _]} -> href
  41       _ -> "#{Web.base_url()}/images/banner.png"
  42     end
  43   end
  44
  45   def profile_url(%User{info: %{"source_data" => %{"url" => url}}}), do: url
  46   def profile_url(%User{ap_id: ap_id}), do: ap_id
  47   def profile_url(_), do: nil
  48
  49   def ap_id(%User{nickname: nickname}) do
  50     "#{Web.base_url()}/users/#{nickname}"
  51   end
  52
  53   def ap_followers(%User{} = user) do
  54     "#{ap_id(user)}/followers"
  55   end
  56
  57   def follow_changeset(struct, params \\ %{}) do
  58     struct
  59     |> cast(params, [:following])
  60     |> validate_required([:following])
  61   end
  62
  63   def info_changeset(struct, params \\ %{}) do
  64     struct
  65     |> cast(params, [:info])
  66     |> validate_required([:info])
  67   end
  68
  69   def user_info(%User{} = user) do
  70     oneself = if user.local, do: 1, else: 0
  71
  72     %{
  73       following_count: length(user.following) - oneself,
  74       note_count: user.info["note_count"] || 0,
  75       follower_count: user.info["follower_count"] || 0,
  76       locked: user.info["locked"] || false,
  77       default_scope: user.info["default_scope"] || "public"
  78     }
  79   end
  80
  81   @email_regex ~r/^[a-zA-Z0-9.!#$%&'*+\/=?^_`{|}~-]+@[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?(?:\.[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?)*$/
  82   def remote_user_creation(params) do
  83     changes =
  84       %User{}
  85       |> cast(params, [:bio, :name, :ap_id, :nickname, :info, :avatar])
  86       |> validate_required([:name, :ap_id])
  87       |> unique_constraint(:nickname)
  88       |> validate_format(:nickname, @email_regex)
  89       |> validate_length(:bio, max: 5000)
  90       |> validate_length(:name, max: 100)
  91       |> put_change(:local, false)
  92
  93     if changes.valid? do
  94       case changes.changes[:info]["source_data"] do
  95         %{"followers" => followers} ->
  96           changes
  97           |> put_change(:follower_address, followers)
  98
  99         _ ->
 100           followers = User.ap_followers(%User{nickname: changes.changes[:nickname]})
 101
 102           changes
 103           |> put_change(:follower_address, followers)
 104       end
 105     else
 106       changes
 107     end
 108   end
 109
 110   def update_changeset(struct, params \\ %{}) do
 111     struct
 112     |> cast(params, [:bio, :name])
 113     |> unique_constraint(:nickname)
 114     |> validate_format(:nickname, ~r/^[a-zA-Z\d]+$/)
 115     |> validate_length(:bio, max: 5000)
 116     |> validate_length(:name, min: 1, max: 100)
 117   end
 118
 119   def upgrade_changeset(struct, params \\ %{}) do
 120     params =
 121       params
 122       |> Map.put(:last_refreshed_at, NaiveDateTime.utc_now())
 123
 124     struct
 125     |> cast(params, [:bio, :name, :info, :follower_address, :avatar, :last_refreshed_at])
 126     |> unique_constraint(:nickname)
 127     |> validate_format(:nickname, ~r/^[a-zA-Z\d]+$/)
 128     |> validate_length(:bio, max: 5000)
 129     |> validate_length(:name, max: 100)
 130   end
 131
 132   def password_update_changeset(struct, params) do
 133     changeset =
 134       struct
 135       |> cast(params, [:password, :password_confirmation])
 136       |> validate_required([:password, :password_confirmation])
 137       |> validate_confirmation(:password)
 138
 139     OAuth.Token.delete_user_tokens(struct)
 140     OAuth.Authorization.delete_user_authorizations(struct)
 141
 142     if changeset.valid? do
 143       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 144
 145       changeset
 146       |> put_change(:password_hash, hashed)
 147     else
 148       changeset
 149     end
 150   end
 151
 152   def reset_password(user, data) do
 153     update_and_set_cache(password_update_changeset(user, data))
 154   end
 155
 156   def register_changeset(struct, params \\ %{}) do
 157     changeset =
 158       struct
 159       |> cast(params, [:bio, :email, :name, :nickname, :password, :password_confirmation])
 160       |> validate_required([:email, :name, :nickname, :password, :password_confirmation])
 161       |> validate_confirmation(:password)
 162       |> unique_constraint(:email)
 163       |> unique_constraint(:nickname)
 164       |> validate_format(:nickname, ~r/^[a-zA-Z\d]+$/)
 165       |> validate_format(:email, @email_regex)
 166       |> validate_length(:bio, max: 1000)
 167       |> validate_length(:name, min: 1, max: 100)
 168
 169     if changeset.valid? do
 170       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 171       ap_id = User.ap_id(%User{nickname: changeset.changes[:nickname]})
 172       followers = User.ap_followers(%User{nickname: changeset.changes[:nickname]})
 173
 174       changeset
 175       |> put_change(:password_hash, hashed)
 176       |> put_change(:ap_id, ap_id)
 177       |> put_change(:following, [followers])
 178       |> put_change(:follower_address, followers)
 179     else
 180       changeset
 181     end
 182   end
 183
 184   def needs_update?(%User{local: true}), do: false
 185
 186   def needs_update?(%User{local: false, last_refreshed_at: nil}), do: true
 187
 188   def needs_update?(%User{local: false} = user) do
 189     NaiveDateTime.diff(NaiveDateTime.utc_now(), user.last_refreshed_at) >= 86400
 190   end
 191
 192   def needs_update?(_), do: true
 193
 194   def maybe_direct_follow(%User{} = follower, %User{local: true, info: %{"locked" => true}}) do
 195     {:ok, follower}
 196   end
 197
 198   def maybe_direct_follow(%User{} = follower, %User{local: true} = followed) do
 199     follow(follower, followed)
 200   end
 201
 202   def maybe_direct_follow(%User{} = follower, %User{} = followed) do
 203     if !User.ap_enabled?(followed) do
 204       follow(follower, followed)
 205     else
 206       {:ok, follower}
 207     end
 208   end
 209
 210   def maybe_follow(%User{} = follower, %User{info: info} = followed) do
 211     if not following?(follower, followed) do
 212       follow(follower, followed)
 213     else
 214       {:ok, follower}
 215     end
 216   end
 217
 218   def follow(%User{} = follower, %User{info: info} = followed) do
 219     user_config = Application.get_env(:pleroma, :user)
 220     deny_follow_blocked = Keyword.get(user_config, :deny_follow_blocked)
 221
 222     ap_followers = followed.follower_address
 223
 224     cond do
 225       following?(follower, followed) or info["deactivated"] ->
 226         {:error, "Could not follow user: #{followed.nickname} is already on your list."}
 227
 228       deny_follow_blocked and blocks?(followed, follower) ->
 229         {:error, "Could not follow user: #{followed.nickname} blocked you."}
 230
 231       true ->
 232         if !followed.local && follower.local && !ap_enabled?(followed) do
 233           Websub.subscribe(follower, followed)
 234         end
 235
 236         following =
 237           [ap_followers | follower.following]
 238           |> Enum.uniq()
 239
 240         follower =
 241           follower
 242           |> follow_changeset(%{following: following})
 243           |> update_and_set_cache
 244
 245         {:ok, _} = update_follower_count(followed)
 246
 247         follower
 248     end
 249   end
 250
 251   def unfollow(%User{} = follower, %User{} = followed) do
 252     ap_followers = followed.follower_address
 253
 254     if following?(follower, followed) and follower.ap_id != followed.ap_id do
 255       following =
 256         follower.following
 257         |> List.delete(ap_followers)
 258
 259       {:ok, follower} =
 260         follower
 261         |> follow_changeset(%{following: following})
 262         |> update_and_set_cache
 263
 264       {:ok, followed} = update_follower_count(followed)
 265
 266       {:ok, follower, Utils.fetch_latest_follow(follower, followed)}
 267     else
 268       {:error, "Not subscribed!"}
 269     end
 270   end
 271
 272   def following?(%User{} = follower, %User{} = followed) do
 273     Enum.member?(follower.following, followed.follower_address)
 274   end
 275
 276   def locked?(%User{} = user) do
 277     user.info["locked"] || false
 278   end
 279
 280   def get_by_ap_id(ap_id) do
 281     Repo.get_by(User, ap_id: ap_id)
 282   end
 283
 284   def update_and_set_cache(changeset) do
 285     with {:ok, user} <- Repo.update(changeset) do
 286       Cachex.put(:user_cache, "ap_id:#{user.ap_id}", user)
 287       Cachex.put(:user_cache, "nickname:#{user.nickname}", user)
 288       Cachex.put(:user_cache, "user_info:#{user.id}", user_info(user))
 289       {:ok, user}
 290     else
 291       e -> e
 292     end
 293   end
 294
 295   def invalidate_cache(user) do
 296     Cachex.del(:user_cache, "ap_id:#{user.ap_id}")
 297     Cachex.del(:user_cache, "nickname:#{user.nickname}")
 298     Cachex.del(:user_cache, "user_info:#{user.id}")
 299   end
 300
 301   def get_cached_by_ap_id(ap_id) do
 302     key = "ap_id:#{ap_id}"
 303     Cachex.fetch!(:user_cache, key, fn _ -> get_by_ap_id(ap_id) end)
 304   end
 305
 306   def get_cached_by_nickname(nickname) do
 307     key = "nickname:#{nickname}"
 308     Cachex.fetch!(:user_cache, key, fn _ -> get_or_fetch_by_nickname(nickname) end)
 309   end
 310
 311   def get_by_nickname(nickname) do
 312     Repo.get_by(User, nickname: nickname)
 313   end
 314
 315   def get_by_nickname_or_email(nickname_or_email) do
 316     case user = Repo.get_by(User, nickname: nickname_or_email) do
 317       %User{} -> user
 318       nil -> Repo.get_by(User, email: nickname_or_email)
 319     end
 320   end
 321
 322   def get_cached_user_info(user) do
 323     key = "user_info:#{user.id}"
 324     Cachex.fetch!(:user_cache, key, fn _ -> user_info(user) end)
 325   end
 326
 327   def fetch_by_nickname(nickname) do
 328     ap_try = ActivityPub.make_user_from_nickname(nickname)
 329
 330     case ap_try do
 331       {:ok, user} -> {:ok, user}
 332       _ -> OStatus.make_user(nickname)
 333     end
 334   end
 335
 336   def get_or_fetch_by_nickname(nickname) do
 337     with %User{} = user <- get_by_nickname(nickname) do
 338       user
 339     else
 340       _e ->
 341         with [_nick, _domain] <- String.split(nickname, "@"),
 342              {:ok, user} <- fetch_by_nickname(nickname) do
 343           user
 344         else
 345           _e -> nil
 346         end
 347     end
 348   end
 349
 350   def get_followers_query(%User{id: id, follower_address: follower_address}) do
 351     from(
 352       u in User,
 353       where: fragment("? <@ ?", ^[follower_address], u.following),
 354       where: u.id != ^id
 355     )
 356   end
 357
 358   def get_followers(user) do
 359     q = get_followers_query(user)
 360
 361     {:ok, Repo.all(q)}
 362   end
 363
 364   def get_friends_query(%User{id: id, following: following}) do
 365     from(
 366       u in User,
 367       where: u.follower_address in ^following,
 368       where: u.id != ^id
 369     )
 370   end
 371
 372   def get_friends(user) do
 373     q = get_friends_query(user)
 374
 375     {:ok, Repo.all(q)}
 376   end
 377
 378   def get_follow_requests_query(%User{} = user) do
 379     from(
 380       a in Activity,
 381       where:
 382         fragment(
 383           "? ->> 'type' = 'Follow'",
 384           a.data
 385         ),
 386       where:
 387         fragment(
 388           "? ->> 'state' = 'pending'",
 389           a.data
 390         ),
 391       where:
 392         fragment(
 393           "? @> ?",
 394           a.data,
 395           ^%{"object" => user.ap_id}
 396         )
 397     )
 398   end
 399
 400   def get_follow_requests(%User{} = user) do
 401     q = get_follow_requests_query(user)
 402     reqs = Repo.all(q)
 403
 404     users =
 405       Enum.map(reqs, fn req -> req.actor end)
 406       |> Enum.uniq()
 407       |> Enum.map(fn ap_id -> get_by_ap_id(ap_id) end)
 408       |> Enum.filter(fn u -> !following?(u, user) end)
 409
 410     {:ok, users}
 411   end
 412
 413   def increase_note_count(%User{} = user) do
 414     note_count = (user.info["note_count"] || 0) + 1
 415     new_info = Map.put(user.info, "note_count", note_count)
 416
 417     cs = info_changeset(user, %{info: new_info})
 418
 419     update_and_set_cache(cs)
 420   end
 421
 422   def decrease_note_count(%User{} = user) do
 423     note_count = user.info["note_count"] || 0
 424     note_count = if note_count <= 0, do: 0, else: note_count - 1
 425     new_info = Map.put(user.info, "note_count", note_count)
 426
 427     cs = info_changeset(user, %{info: new_info})
 428
 429     update_and_set_cache(cs)
 430   end
 431
 432   def update_note_count(%User{} = user) do
 433     note_count_query =
 434       from(
 435         a in Object,
 436         where: fragment("?->>'actor' = ? and ?->>'type' = 'Note'", a.data, ^user.ap_id, a.data),
 437         select: count(a.id)
 438       )
 439
 440     note_count = Repo.one(note_count_query)
 441
 442     new_info = Map.put(user.info, "note_count", note_count)
 443
 444     cs = info_changeset(user, %{info: new_info})
 445
 446     update_and_set_cache(cs)
 447   end
 448
 449   def update_follower_count(%User{} = user) do
 450     follower_count_query =
 451       from(
 452         u in User,
 453         where: ^user.follower_address in u.following,
 454         where: u.id != ^user.id,
 455         select: count(u.id)
 456       )
 457
 458     follower_count = Repo.one(follower_count_query)
 459
 460     new_info = Map.put(user.info, "follower_count", follower_count)
 461
 462     cs = info_changeset(user, %{info: new_info})
 463
 464     update_and_set_cache(cs)
 465   end
 466
 467   def get_notified_from_activity_query(to, false) do
 468     from(
 469       u in User,
 470       where: u.ap_id in ^to
 471     )
 472   end
 473
 474   def get_notified_from_activity_query(to, true) do
 475     query = get_notified_from_activity_query(to, false)
 476
 477     from(
 478       u in query,
 479       where: u.local == true
 480     )
 481   end
 482
 483   def get_notified_from_activity(activity, local_only \\ true)
 484
 485   def get_notified_from_activity(%Activity{data: %{"to" => to} = data}, local_only) do
 486     object = Object.normalize(data["object"])
 487
 488     # somehow, get an AS2 object, preferring the normalized object if we have one
 489     object_data =
 490       if object do
 491         object.data
 492       else
 493         if is_map(data["object"]) do
 494           data["object"]
 495         else
 496           %{}
 497         end
 498       end
 499
 500     # finally extract AS2 mentions from this object
 501     tagged_mentions =
 502       if object_data["tag"] do
 503         object_data["tag"]
 504         |> Enum.filter(fn x -> is_map(x) end)
 505         |> Enum.filter(fn x -> x["type"] == "Mention" end)
 506         |> Enum.map(fn x -> x["href"] end)
 507       else
 508         []
 509       end
 510
 511     # ensure all mentioned users are unique
 512     to =
 513       (to ++ tagged_mentions)
 514       |> Enum.uniq()
 515
 516     query = get_notified_from_activity_query(to, local_only)
 517
 518     Repo.all(query)
 519   end
 520
 521   def get_notified_from_activity(_, _), do: []
 522
 523   def get_recipients_from_activity(%Activity{recipients: to}) do
 524     query =
 525       from(
 526         u in User,
 527         where: u.ap_id in ^to,
 528         or_where: fragment("? && ?", u.following, ^to)
 529       )
 530
 531     query = from(u in query, where: u.local == true)
 532
 533     Repo.all(query)
 534   end
 535
 536   def search(query, resolve) do
 537     # strip the beginning @ off if there is a query
 538     query = String.trim_leading(query, "@")
 539
 540     if resolve do
 541       User.get_or_fetch_by_nickname(query)
 542     end
 543
 544     inner =
 545       from(
 546         u in User,
 547         select_merge: %{
 548           search_distance:
 549             fragment(
 550               "? <-> (? || ?)",
 551               ^query,
 552               u.nickname,
 553               u.name
 554             )
 555         },
 556         where: not is_nil(u.nickname)
 557       )
 558
 559     q =
 560       from(
 561         s in subquery(inner),
 562         order_by: s.search_distance,
 563         limit: 20
 564       )
 565
 566     Repo.all(q)
 567   end
 568
 569   def block(blocker, %User{ap_id: ap_id} = blocked) do
 570     # sever any follow relationships to prevent leaks per activitypub (Pleroma issue #213)
 571     blocker =
 572       if following?(blocker, blocked) do
 573         {:ok, blocker, _} = unfollow(blocker, blocked)
 574         blocker
 575       else
 576         blocker
 577       end
 578
 579     if following?(blocked, blocker) do
 580       unfollow(blocked, blocker)
 581     end
 582
 583     blocks = blocker.info["blocks"] || []
 584     new_blocks = Enum.uniq([ap_id | blocks])
 585     new_info = Map.put(blocker.info, "blocks", new_blocks)
 586
 587     cs = User.info_changeset(blocker, %{info: new_info})
 588     update_and_set_cache(cs)
 589   end
 590
 591   # helper to handle the block given only an actor's AP id
 592   def block(blocker, %{ap_id: ap_id}) do
 593     block(blocker, User.get_by_ap_id(ap_id))
 594   end
 595
 596   def unblock(user, %{ap_id: ap_id}) do
 597     blocks = user.info["blocks"] || []
 598     new_blocks = List.delete(blocks, ap_id)
 599     new_info = Map.put(user.info, "blocks", new_blocks)
 600
 601     cs = User.info_changeset(user, %{info: new_info})
 602     update_and_set_cache(cs)
 603   end
 604
 605   def blocks?(user, %{ap_id: ap_id}) do
 606     blocks = user.info["blocks"] || []
 607     domain_blocks = user.info["domain_blocks"] || []
 608     %{host: host} = URI.parse(ap_id)
 609
 610     Enum.member?(blocks, ap_id) ||
 611       Enum.any?(domain_blocks, fn domain ->
 612         host == domain
 613       end)
 614   end
 615
 616   def block_domain(user, domain) do
 617     domain_blocks = user.info["domain_blocks"] || []
 618     new_blocks = Enum.uniq([domain | domain_blocks])
 619     new_info = Map.put(user.info, "domain_blocks", new_blocks)
 620
 621     cs = User.info_changeset(user, %{info: new_info})
 622     update_and_set_cache(cs)
 623   end
 624
 625   def unblock_domain(user, domain) do
 626     blocks = user.info["domain_blocks"] || []
 627     new_blocks = List.delete(blocks, domain)
 628     new_info = Map.put(user.info, "domain_blocks", new_blocks)
 629
 630     cs = User.info_changeset(user, %{info: new_info})
 631     update_and_set_cache(cs)
 632   end
 633
 634   def local_user_query() do
 635     from(
 636       u in User,
 637       where: u.local == true,
 638       where: not is_nil(u.nickname)
 639     )
 640   end
 641
 642   def moderator_user_query() do
 643     from(
 644       u in User,
 645       where: u.local == true,
 646       where: fragment("?->'is_moderator' @> 'true'", u.info)
 647     )
 648   end
 649
 650   def deactivate(%User{} = user, status \\ true) do
 651     new_info = Map.put(user.info, "deactivated", status)
 652     cs = User.info_changeset(user, %{info: new_info})
 653     update_and_set_cache(cs)
 654   end
 655
 656   def delete(%User{} = user) do
 657     {:ok, user} = User.deactivate(user)
 658
 659     # Remove all relationships
 660     {:ok, followers} = User.get_followers(user)
 661
 662     followers
 663     |> Enum.each(fn follower -> User.unfollow(follower, user) end)
 664
 665     {:ok, friends} = User.get_friends(user)
 666
 667     friends
 668     |> Enum.each(fn followed -> User.unfollow(user, followed) end)
 669
 670     query = from(a in Activity, where: a.actor == ^user.ap_id)
 671
 672     Repo.all(query)
 673     |> Enum.each(fn activity ->
 674       case activity.data["type"] do
 675         "Create" ->
 676           ActivityPub.delete(Object.normalize(activity.data["object"]))
 677
 678         # TODO: Do something with likes, follows, repeats.
 679         _ ->
 680           "Doing nothing"
 681       end
 682     end)
 683
 684     {:ok, user}
 685   end
 686
 687   def html_filter_policy(%User{info: %{"no_rich_text" => true}}) do
 688     Pleroma.HTML.Scrubber.TwitterText
 689   end
 690
 691   def html_filter_policy(_), do: nil
 692
 693   def get_or_fetch_by_ap_id(ap_id) do
 694     user = get_by_ap_id(ap_id)
 695
 696     if !is_nil(user) and !User.needs_update?(user) do
 697       user
 698     else
 699       ap_try = ActivityPub.make_user_from_ap_id(ap_id)
 700
 701       case ap_try do
 702         {:ok, user} ->
 703           user
 704
 705         _ ->
 706           case OStatus.make_user(ap_id) do
 707             {:ok, user} -> user
 708             _ -> {:error, "Could not fetch by AP id"}
 709           end
 710       end
 711     end
 712   end
 713
 714   def get_or_create_instance_user do
 715     relay_uri = "#{Pleroma.Web.Endpoint.url()}/relay"
 716
 717     if user = get_by_ap_id(relay_uri) do
 718       user
 719     else
 720       changes =
 721         %User{}
 722         |> cast(%{}, [:ap_id, :nickname, :local])
 723         |> put_change(:ap_id, relay_uri)
 724         |> put_change(:nickname, nil)
 725         |> put_change(:local, true)
 726         |> put_change(:follower_address, relay_uri <> "/followers")
 727
 728       {:ok, user} = Repo.insert(changes)
 729       user
 730     end
 731   end
 732
 733   # AP style
 734   def public_key_from_info(%{
 735         "source_data" => %{"publicKey" => %{"publicKeyPem" => public_key_pem}}
 736       }) do
 737     key =
 738       :public_key.pem_decode(public_key_pem)
 739       |> hd()
 740       |> :public_key.pem_entry_decode()
 741
 742     {:ok, key}
 743   end
 744
 745   # OStatus Magic Key
 746   def public_key_from_info(%{"magic_key" => magic_key}) do
 747     {:ok, Pleroma.Web.Salmon.decode_key(magic_key)}
 748   end
 749
 750   def get_public_key_for_ap_id(ap_id) do
 751     with %User{} = user <- get_or_fetch_by_ap_id(ap_id),
 752          {:ok, public_key} <- public_key_from_info(user.info) do
 753       {:ok, public_key}
 754     else
 755       _ -> :error
 756     end
 757   end
 758
 759   defp blank?(""), do: nil
 760   defp blank?(n), do: n
 761
 762   def insert_or_update_user(data) do
 763     data =
 764       data
 765       |> Map.put(:name, blank?(data[:name]) || data[:nickname])
 766
 767     cs = User.remote_user_creation(data)
 768     Repo.insert(cs, on_conflict: :replace_all, conflict_target: :nickname)
 769   end
 770
 771   def ap_enabled?(%User{local: true}), do: true
 772   def ap_enabled?(%User{info: info}), do: info["ap_enabled"]
 773   def ap_enabled?(_), do: false
 774
 775   def get_or_fetch(uri_or_nickname) do
 776     if String.starts_with?(uri_or_nickname, "http") do
 777       get_or_fetch_by_ap_id(uri_or_nickname)
 778     else
 779       get_or_fetch_by_nickname(uri_or_nickname)
 780     end
 781   end
 782
 783   # wait a period of time and return newest version of the User structs
 784   # this is because we have synchronous follow APIs and need to simulate them
 785   # with an async handshake
 786   def wait_and_refresh(_, %User{local: true} = a, %User{local: true} = b) do
 787     with %User{} = a <- Repo.get(User, a.id),
 788          %User{} = b <- Repo.get(User, b.id) do
 789       {:ok, a, b}
 790     else
 791       _e ->
 792         :error
 793     end
 794   end
 795
 796   def wait_and_refresh(timeout, %User{} = a, %User{} = b) do
 797     with :ok <- :timer.sleep(timeout),
 798          %User{} = a <- Repo.get(User, a.id),
 799          %User{} = b <- Repo.get(User, b.id) do
 800       {:ok, a, b}
 801     else
 802       _e ->
 803         :error
 804     end
 805   end
 806 end