git.squeep.com Git - akkoma/blob - lib/pleroma/user.ex

   1 defmodule Pleroma.User do
   2   use Ecto.Schema
   3
   4   import Ecto.{Changeset, Query}
   5   alias Pleroma.{Repo, User, Object, Web, Activity, Notification}
   6   alias Comeonin.Pbkdf2
   7   alias Pleroma.Web.{OStatus, Websub}
   8   alias Pleroma.Web.ActivityPub.{Utils, ActivityPub}
   9
  10   schema "users" do
  11     field(:bio, :string)
  12     field(:email, :string)
  13     field(:name, :string)
  14     field(:nickname, :string)
  15     field(:password_hash, :string)
  16     field(:password, :string, virtual: true)
  17     field(:password_confirmation, :string, virtual: true)
  18     field(:following, {:array, :string}, default: [])
  19     field(:ap_id, :string)
  20     field(:avatar, :map)
  21     field(:local, :boolean, default: true)
  22     field(:info, :map, default: %{})
  23     field(:follower_address, :string)
  24     field(:search_distance, :float, virtual: true)
  25     has_many(:notifications, Notification)
  26
  27     timestamps()
  28   end
  29
  30   def avatar_url(user) do
  31     case user.avatar do
  32       %{"url" => [%{"href" => href} | _]} -> href
  33       _ -> "#{Web.base_url()}/images/avi.png"
  34     end
  35   end
  36
  37   def banner_url(user) do
  38     case user.info["banner"] do
  39       %{"url" => [%{"href" => href} | _]} -> href
  40       _ -> "#{Web.base_url()}/images/banner.png"
  41     end
  42   end
  43
  44   def ap_id(%User{nickname: nickname}) do
  45     "#{Web.base_url()}/users/#{nickname}"
  46   end
  47
  48   def ap_followers(%User{} = user) do
  49     "#{ap_id(user)}/followers"
  50   end
  51
  52   def follow_changeset(struct, params \\ %{}) do
  53     struct
  54     |> cast(params, [:following])
  55     |> validate_required([:following])
  56   end
  57
  58   def info_changeset(struct, params \\ %{}) do
  59     struct
  60     |> cast(params, [:info])
  61     |> validate_required([:info])
  62   end
  63
  64   def user_info(%User{} = user) do
  65     oneself = if user.local, do: 1, else: 0
  66
  67     %{
  68       following_count: length(user.following) - oneself,
  69       note_count: user.info["note_count"] || 0,
  70       follower_count: user.info["follower_count"] || 0,
  71       locked: user.info["locked"] || false
  72     }
  73   end
  74
  75   @email_regex ~r/^[a-zA-Z0-9.!#$%&'*+\/=?^_`{|}~-]+@[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?(?:\.[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?)*$/
  76   def remote_user_creation(params) do
  77     changes =
  78       %User{}
  79       |> cast(params, [:bio, :name, :ap_id, :nickname, :info, :avatar])
  80       |> validate_required([:name, :ap_id, :nickname])
  81       |> unique_constraint(:nickname)
  82       |> validate_format(:nickname, @email_regex)
  83       |> validate_length(:bio, max: 5000)
  84       |> validate_length(:name, max: 100)
  85       |> put_change(:local, false)
  86
  87     if changes.valid? do
  88       case changes.changes[:info]["source_data"] do
  89         %{"followers" => followers} ->
  90           changes
  91           |> put_change(:follower_address, followers)
  92
  93         _ ->
  94           followers = User.ap_followers(%User{nickname: changes.changes[:nickname]})
  95
  96           changes
  97           |> put_change(:follower_address, followers)
  98       end
  99     else
 100       changes
 101     end
 102   end
 103
 104   def update_changeset(struct, params \\ %{}) do
 105     struct
 106     |> cast(params, [:bio, :name])
 107     |> unique_constraint(:nickname)
 108     |> validate_format(:nickname, ~r/^[a-zA-Z\d]+$/)
 109     |> validate_length(:bio, max: 5000)
 110     |> validate_length(:name, min: 1, max: 100)
 111   end
 112
 113   def upgrade_changeset(struct, params \\ %{}) do
 114     struct
 115     |> cast(params, [:bio, :name, :info, :follower_address, :avatar])
 116     |> unique_constraint(:nickname)
 117     |> validate_format(:nickname, ~r/^[a-zA-Z\d]+$/)
 118     |> validate_length(:bio, max: 5000)
 119     |> validate_length(:name, max: 100)
 120   end
 121
 122   def password_update_changeset(struct, params) do
 123     changeset =
 124       struct
 125       |> cast(params, [:password, :password_confirmation])
 126       |> validate_required([:password, :password_confirmation])
 127       |> validate_confirmation(:password)
 128
 129     if changeset.valid? do
 130       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 131
 132       changeset
 133       |> put_change(:password_hash, hashed)
 134     else
 135       changeset
 136     end
 137   end
 138
 139   def reset_password(user, data) do
 140     update_and_set_cache(password_update_changeset(user, data))
 141   end
 142
 143   def register_changeset(struct, params \\ %{}) do
 144     changeset =
 145       struct
 146       |> cast(params, [:bio, :email, :name, :nickname, :password, :password_confirmation])
 147       |> validate_required([:email, :name, :nickname, :password, :password_confirmation])
 148       |> validate_confirmation(:password)
 149       |> unique_constraint(:email)
 150       |> unique_constraint(:nickname)
 151       |> validate_format(:nickname, ~r/^[a-zA-Z\d]+$/)
 152       |> validate_format(:email, @email_regex)
 153       |> validate_length(:bio, max: 1000)
 154       |> validate_length(:name, min: 1, max: 100)
 155
 156     if changeset.valid? do
 157       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 158       ap_id = User.ap_id(%User{nickname: changeset.changes[:nickname]})
 159       followers = User.ap_followers(%User{nickname: changeset.changes[:nickname]})
 160
 161       changeset
 162       |> put_change(:password_hash, hashed)
 163       |> put_change(:ap_id, ap_id)
 164       |> put_change(:following, [followers])
 165       |> put_change(:follower_address, followers)
 166     else
 167       changeset
 168     end
 169   end
 170
 171   def maybe_direct_follow(%User{} = follower, %User{info: info} = followed) do
 172     user_info = user_info(followed)
 173
 174     should_direct_follow =
 175       cond do
 176         # if the account is locked, don't pre-create the relationship
 177         user_info[:locked] == true ->
 178           false
 179
 180         # if the users are blocking each other, we shouldn't even be here, but check for it anyway
 181         User.blocks?(follower, followed) == true or User.blocks?(followed, follower) == true ->
 182           false
 183
 184         # if OStatus, then there is no three-way handshake to follow
 185         User.ap_enabled?(followed) != true ->
 186           true
 187
 188         # if there are no other reasons not to, just pre-create the relationship
 189         true ->
 190           true
 191       end
 192
 193     if should_direct_follow do
 194       follow(follower, followed)
 195     else
 196       {:ok, follower}
 197     end
 198   end
 199
 200   def follow(%User{} = follower, %User{info: info} = followed) do
 201     ap_followers = followed.follower_address
 202
 203     cond do
 204       following?(follower, followed) or info["deactivated"] ->
 205         {:error, "Could not follow user: #{followed.nickname} is already on your list."}
 206
 207       blocks?(followed, follower) ->
 208         {:error, "Could not follow user: #{followed.nickname} blocked you."}
 209
 210       true ->
 211         if !followed.local && follower.local && !ap_enabled?(followed) do
 212           Websub.subscribe(follower, followed)
 213         end
 214
 215         following =
 216           [ap_followers | follower.following]
 217           |> Enum.uniq()
 218
 219         follower =
 220           follower
 221           |> follow_changeset(%{following: following})
 222           |> update_and_set_cache
 223
 224         {:ok, _} = update_follower_count(followed)
 225
 226         follower
 227     end
 228   end
 229
 230   def unfollow(%User{} = follower, %User{} = followed) do
 231     ap_followers = followed.follower_address
 232
 233     if following?(follower, followed) and follower.ap_id != followed.ap_id do
 234       following =
 235         follower.following
 236         |> List.delete(ap_followers)
 237
 238       {:ok, follower} =
 239         follower
 240         |> follow_changeset(%{following: following})
 241         |> update_and_set_cache
 242
 243       {:ok, followed} = update_follower_count(followed)
 244
 245       {:ok, follower, Utils.fetch_latest_follow(follower, followed)}
 246     else
 247       {:error, "Not subscribed!"}
 248     end
 249   end
 250
 251   def following?(%User{} = follower, %User{} = followed) do
 252     Enum.member?(follower.following, followed.follower_address)
 253   end
 254
 255   def get_by_ap_id(ap_id) do
 256     Repo.get_by(User, ap_id: ap_id)
 257   end
 258
 259   def update_and_set_cache(changeset) do
 260     with {:ok, user} <- Repo.update(changeset) do
 261       Cachex.put(:user_cache, "ap_id:#{user.ap_id}", user)
 262       Cachex.put(:user_cache, "nickname:#{user.nickname}", user)
 263       Cachex.put(:user_cache, "user_info:#{user.id}", user_info(user))
 264       {:ok, user}
 265     else
 266       e -> e
 267     end
 268   end
 269
 270   def invalidate_cache(user) do
 271     Cachex.del(:user_cache, "ap_id:#{user.ap_id}")
 272     Cachex.del(:user_cache, "nickname:#{user.nickname}")
 273   end
 274
 275   def get_cached_by_ap_id(ap_id) do
 276     key = "ap_id:#{ap_id}"
 277     Cachex.fetch!(:user_cache, key, fn _ -> get_by_ap_id(ap_id) end)
 278   end
 279
 280   def get_cached_by_nickname(nickname) do
 281     key = "nickname:#{nickname}"
 282     Cachex.fetch!(:user_cache, key, fn _ -> get_or_fetch_by_nickname(nickname) end)
 283   end
 284
 285   def get_by_nickname(nickname) do
 286     Repo.get_by(User, nickname: nickname)
 287   end
 288
 289   def get_by_nickname_or_email(nickname_or_email) do
 290     case user = Repo.get_by(User, nickname: nickname_or_email) do
 291       %User{} -> user
 292       nil -> Repo.get_by(User, email: nickname_or_email)
 293     end
 294   end
 295
 296   def get_cached_user_info(user) do
 297     key = "user_info:#{user.id}"
 298     Cachex.fetch!(:user_cache, key, fn _ -> user_info(user) end)
 299   end
 300
 301   def fetch_by_nickname(nickname) do
 302     ap_try = ActivityPub.make_user_from_nickname(nickname)
 303
 304     case ap_try do
 305       {:ok, user} -> {:ok, user}
 306       _ -> OStatus.make_user(nickname)
 307     end
 308   end
 309
 310   def get_or_fetch_by_nickname(nickname) do
 311     with %User{} = user <- get_by_nickname(nickname) do
 312       user
 313     else
 314       _e ->
 315         with [_nick, _domain] <- String.split(nickname, "@"),
 316              {:ok, user} <- fetch_by_nickname(nickname) do
 317           user
 318         else
 319           _e -> nil
 320         end
 321     end
 322   end
 323
 324   def get_followers_query(%User{id: id, follower_address: follower_address}) do
 325     from(
 326       u in User,
 327       where: fragment("? <@ ?", ^[follower_address], u.following),
 328       where: u.id != ^id
 329     )
 330   end
 331
 332   def get_followers(user) do
 333     q = get_followers_query(user)
 334
 335     {:ok, Repo.all(q)}
 336   end
 337
 338   def get_friends_query(%User{id: id, following: following}) do
 339     from(
 340       u in User,
 341       where: u.follower_address in ^following,
 342       where: u.id != ^id
 343     )
 344   end
 345
 346   def get_friends(user) do
 347     q = get_friends_query(user)
 348
 349     {:ok, Repo.all(q)}
 350   end
 351
 352   def increase_note_count(%User{} = user) do
 353     note_count = (user.info["note_count"] || 0) + 1
 354     new_info = Map.put(user.info, "note_count", note_count)
 355
 356     cs = info_changeset(user, %{info: new_info})
 357
 358     update_and_set_cache(cs)
 359   end
 360
 361   def decrease_note_count(%User{} = user) do
 362     note_count = user.info["note_count"] || 0
 363     note_count = if note_count <= 0, do: 0, else: note_count - 1
 364     new_info = Map.put(user.info, "note_count", note_count)
 365
 366     cs = info_changeset(user, %{info: new_info})
 367
 368     update_and_set_cache(cs)
 369   end
 370
 371   def update_note_count(%User{} = user) do
 372     note_count_query =
 373       from(
 374         a in Object,
 375         where: fragment("?->>'actor' = ? and ?->>'type' = 'Note'", a.data, ^user.ap_id, a.data),
 376         select: count(a.id)
 377       )
 378
 379     note_count = Repo.one(note_count_query)
 380
 381     new_info = Map.put(user.info, "note_count", note_count)
 382
 383     cs = info_changeset(user, %{info: new_info})
 384
 385     update_and_set_cache(cs)
 386   end
 387
 388   def update_follower_count(%User{} = user) do
 389     follower_count_query =
 390       from(
 391         u in User,
 392         where: ^user.follower_address in u.following,
 393         where: u.id != ^user.id,
 394         select: count(u.id)
 395       )
 396
 397     follower_count = Repo.one(follower_count_query)
 398
 399     new_info = Map.put(user.info, "follower_count", follower_count)
 400
 401     cs = info_changeset(user, %{info: new_info})
 402
 403     update_and_set_cache(cs)
 404   end
 405
 406   def get_notified_from_activity(%Activity{recipients: to}) do
 407     query =
 408       from(
 409         u in User,
 410         where: u.ap_id in ^to,
 411         where: u.local == true
 412       )
 413
 414     Repo.all(query)
 415   end
 416
 417   def get_recipients_from_activity(%Activity{recipients: to}) do
 418     query =
 419       from(
 420         u in User,
 421         where: u.ap_id in ^to,
 422         or_where: fragment("? && ?", u.following, ^to)
 423       )
 424
 425     query = from(u in query, where: u.local == true)
 426
 427     Repo.all(query)
 428   end
 429
 430   def search(query, resolve) do
 431     # strip the beginning @ off if there is a query
 432     query = String.trim_leading(query, "@")
 433
 434     if resolve do
 435       User.get_or_fetch_by_nickname(query)
 436     end
 437
 438     inner =
 439       from(
 440         u in User,
 441         select_merge: %{
 442           search_distance:
 443             fragment(
 444               "? <-> (? || ?)",
 445               ^query,
 446               u.nickname,
 447               u.name
 448             )
 449         }
 450       )
 451
 452     q =
 453       from(
 454         s in subquery(inner),
 455         order_by: s.search_distance,
 456         limit: 20
 457       )
 458
 459     Repo.all(q)
 460   end
 461
 462   def block(user, %{ap_id: ap_id}) do
 463     blocks = user.info["blocks"] || []
 464     new_blocks = Enum.uniq([ap_id | blocks])
 465     new_info = Map.put(user.info, "blocks", new_blocks)
 466
 467     cs = User.info_changeset(user, %{info: new_info})
 468     update_and_set_cache(cs)
 469   end
 470
 471   def unblock(user, %{ap_id: ap_id}) do
 472     blocks = user.info["blocks"] || []
 473     new_blocks = List.delete(blocks, ap_id)
 474     new_info = Map.put(user.info, "blocks", new_blocks)
 475
 476     cs = User.info_changeset(user, %{info: new_info})
 477     update_and_set_cache(cs)
 478   end
 479
 480   def blocks?(user, %{ap_id: ap_id}) do
 481     blocks = user.info["blocks"] || []
 482     domain_blocks = user.info["domain_blocks"] || []
 483     %{host: host} = URI.parse(ap_id)
 484
 485     Enum.member?(blocks, ap_id) ||
 486       Enum.any?(domain_blocks, fn domain ->
 487         host == domain
 488       end)
 489   end
 490
 491   def block_domain(user, domain) do
 492     domain_blocks = user.info["domain_blocks"] || []
 493     new_blocks = Enum.uniq([domain | domain_blocks])
 494     new_info = Map.put(user.info, "domain_blocks", new_blocks)
 495
 496     cs = User.info_changeset(user, %{info: new_info})
 497     update_and_set_cache(cs)
 498   end
 499
 500   def unblock_domain(user, domain) do
 501     blocks = user.info["domain_blocks"] || []
 502     new_blocks = List.delete(blocks, domain)
 503     new_info = Map.put(user.info, "domain_blocks", new_blocks)
 504
 505     cs = User.info_changeset(user, %{info: new_info})
 506     update_and_set_cache(cs)
 507   end
 508
 509   def local_user_query() do
 510     from(u in User, where: u.local == true)
 511   end
 512
 513   def deactivate(%User{} = user) do
 514     new_info = Map.put(user.info, "deactivated", true)
 515     cs = User.info_changeset(user, %{info: new_info})
 516     update_and_set_cache(cs)
 517   end
 518
 519   def delete(%User{} = user) do
 520     {:ok, user} = User.deactivate(user)
 521
 522     # Remove all relationships
 523     {:ok, followers} = User.get_followers(user)
 524
 525     followers
 526     |> Enum.each(fn follower -> User.unfollow(follower, user) end)
 527
 528     {:ok, friends} = User.get_friends(user)
 529
 530     friends
 531     |> Enum.each(fn followed -> User.unfollow(user, followed) end)
 532
 533     query = from(a in Activity, where: a.actor == ^user.ap_id)
 534
 535     Repo.all(query)
 536     |> Enum.each(fn activity ->
 537       case activity.data["type"] do
 538         "Create" ->
 539           ActivityPub.delete(Object.get_by_ap_id(activity.data["object"]["id"]))
 540
 541         # TODO: Do something with likes, follows, repeats.
 542         _ ->
 543           "Doing nothing"
 544       end
 545     end)
 546
 547     :ok
 548   end
 549
 550   def get_or_fetch_by_ap_id(ap_id) do
 551     if user = get_by_ap_id(ap_id) do
 552       user
 553     else
 554       ap_try = ActivityPub.make_user_from_ap_id(ap_id)
 555
 556       case ap_try do
 557         {:ok, user} ->
 558           user
 559
 560         _ ->
 561           case OStatus.make_user(ap_id) do
 562             {:ok, user} -> user
 563             _ -> {:error, "Could not fetch by AP id"}
 564           end
 565       end
 566     end
 567   end
 568
 569   # AP style
 570   def public_key_from_info(%{
 571         "source_data" => %{"publicKey" => %{"publicKeyPem" => public_key_pem}}
 572       }) do
 573     key =
 574       :public_key.pem_decode(public_key_pem)
 575       |> hd()
 576       |> :public_key.pem_entry_decode()
 577
 578     {:ok, key}
 579   end
 580
 581   # OStatus Magic Key
 582   def public_key_from_info(%{"magic_key" => magic_key}) do
 583     {:ok, Pleroma.Web.Salmon.decode_key(magic_key)}
 584   end
 585
 586   def get_public_key_for_ap_id(ap_id) do
 587     with %User{} = user <- get_or_fetch_by_ap_id(ap_id),
 588          {:ok, public_key} <- public_key_from_info(user.info) do
 589       {:ok, public_key}
 590     else
 591       _ -> :error
 592     end
 593   end
 594
 595   defp blank?(""), do: nil
 596   defp blank?(n), do: n
 597
 598   def insert_or_update_user(data) do
 599     data =
 600       data
 601       |> Map.put(:name, blank?(data[:name]) || data[:nickname])
 602
 603     cs = User.remote_user_creation(data)
 604     Repo.insert(cs, on_conflict: :replace_all, conflict_target: :nickname)
 605   end
 606
 607   def ap_enabled?(%User{info: info}), do: info["ap_enabled"]
 608   def ap_enabled?(_), do: false
 609
 610   def get_or_fetch(uri_or_nickname) do
 611     if String.starts_with?(uri_or_nickname, "http") do
 612       get_or_fetch_by_ap_id(uri_or_nickname)
 613     else
 614       get_or_fetch_by_nickname(uri_or_nickname)
 615     end
 616   end
 617 end