git.squeep.com Git - akkoma/blob - lib/pleroma/user.ex

   1 defmodule Pleroma.User do
   2   use Ecto.Schema
   3
   4   import Ecto.{Changeset, Query}
   5   alias Ecto.Multi
   6   alias Pleroma.{Repo, User, Object, Web, Activity, Notification}
   7   alias Comeonin.Pbkdf2
   8   alias Pleroma.Formatter
   9   alias Pleroma.Web.CommonAPI.Utils, as: CommonUtils
  10   alias Pleroma.Web.{OStatus, Websub, OAuth}
  11   alias Pleroma.Web.ActivityPub.{Utils, ActivityPub}
  12
  13   schema "users" do
  14     field(:bio, :string)
  15     field(:email, :string)
  16     field(:name, :string)
  17     field(:nickname, :string)
  18     field(:password_hash, :string)
  19     field(:password, :string, virtual: true)
  20     field(:password_confirmation, :string, virtual: true)
  21     field(:following, {:array, :string}, default: [])
  22     field(:ap_id, :string)
  23     field(:avatar, :map)
  24     field(:local, :boolean, default: true)
  25     field(:follower_address, :string)
  26     field(:search_distance, :float, virtual: true)
  27     field(:tags, {:array, :string}, default: [])
  28     field(:last_refreshed_at, :naive_datetime)
  29     has_many(:notifications, Notification)
  30     embeds_one(:info, Pleroma.User.Info)
  31
  32     timestamps()
  33   end
  34
  35   def avatar_url(user) do
  36     case user.avatar do
  37       %{"url" => [%{"href" => href} | _]} -> href
  38       _ -> "#{Web.base_url()}/images/avi.png"
  39     end
  40   end
  41
  42   def banner_url(user) do
  43     case user.info.banner do
  44       %{"url" => [%{"href" => href} | _]} -> href
  45       _ -> "#{Web.base_url()}/images/banner.png"
  46     end
  47   end
  48
  49   def profile_url(%User{info: %{source_data: %{"url" => url}}}), do: url
  50   def profile_url(%User{ap_id: ap_id}), do: ap_id
  51   def profile_url(_), do: nil
  52
  53   def ap_id(%User{nickname: nickname}) do
  54     "#{Web.base_url()}/users/#{nickname}"
  55   end
  56
  57   def ap_followers(%User{} = user) do
  58     "#{ap_id(user)}/followers"
  59   end
  60
  61   def follow_changeset(struct, params \\ %{}) do
  62     struct
  63     |> cast(params, [:following])
  64     |> validate_required([:following])
  65   end
  66
  67   def user_info(%User{} = user) do
  68     oneself = if user.local, do: 1, else: 0
  69
  70     %{
  71       following_count: length(user.following) - oneself,
  72       note_count: user.info.note_count,
  73       follower_count: user.info.follower_count,
  74       locked: user.info.locked,
  75       default_scope: user.info.default_scope
  76     }
  77   end
  78
  79   @email_regex ~r/^[a-zA-Z0-9.!#$%&'*+\/=?^_`{|}~-]+@[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?(?:\.[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?)*$/
  80   def remote_user_creation(params) do
  81     params =
  82       params
  83       |> Map.put(:info, params[:info] || %{})
  84
  85     info_cng = User.Info.remote_user_creation(%User.Info{}, params[:info])
  86
  87     changes =
  88       %User{}
  89       |> cast(params, [:bio, :name, :ap_id, :nickname, :avatar])
  90       |> validate_required([:name, :ap_id])
  91       |> unique_constraint(:nickname)
  92       |> validate_format(:nickname, @email_regex)
  93       |> validate_length(:bio, max: 5000)
  94       |> validate_length(:name, max: 100)
  95       |> put_change(:local, false)
  96       |> put_embed(:info, info_cng)
  97
  98     if changes.valid? do
  99       case info_cng.changes[:source_data] do
 100         %{"followers" => followers} ->
 101           changes
 102           |> put_change(:follower_address, followers)
 103
 104         _ ->
 105           followers = User.ap_followers(%User{nickname: changes.changes[:nickname]})
 106
 107           changes
 108           |> put_change(:follower_address, followers)
 109       end
 110     else
 111       changes
 112     end
 113   end
 114
 115   def update_changeset(struct, params \\ %{}) do
 116     struct
 117     |> cast(params, [:bio, :name, :avatar])
 118     |> unique_constraint(:nickname)
 119     |> validate_format(:nickname, ~r/^[a-zA-Z\d]+$/)
 120     |> validate_length(:bio, max: 5000)
 121     |> validate_length(:name, min: 1, max: 100)
 122   end
 123
 124   def upgrade_changeset(struct, params \\ %{}) do
 125     params =
 126       params
 127       |> Map.put(:last_refreshed_at, NaiveDateTime.utc_now())
 128
 129     info_cng =
 130       struct.info
 131       |> User.Info.user_upgrade(params[:info])
 132
 133     struct
 134     |> cast(params, [:bio, :name, :follower_address, :avatar, :last_refreshed_at])
 135     |> unique_constraint(:nickname)
 136     |> validate_format(:nickname, ~r/^[a-zA-Z\d]+$/)
 137     |> validate_length(:bio, max: 5000)
 138     |> validate_length(:name, max: 100)
 139     |> put_embed(:info, info_cng)
 140   end
 141
 142   def password_update_changeset(struct, params) do
 143     changeset =
 144       struct
 145       |> cast(params, [:password, :password_confirmation])
 146       |> validate_required([:password, :password_confirmation])
 147       |> validate_confirmation(:password)
 148
 149     OAuth.Token.delete_user_tokens(struct)
 150     OAuth.Authorization.delete_user_authorizations(struct)
 151
 152     if changeset.valid? do
 153       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 154
 155       changeset
 156       |> put_change(:password_hash, hashed)
 157     else
 158       changeset
 159     end
 160   end
 161
 162   def reset_password(user, data) do
 163     update_and_set_cache(password_update_changeset(user, data))
 164   end
 165
 166   def register_changeset(struct, params \\ %{}) do
 167     changeset =
 168       struct
 169       |> cast(params, [:bio, :email, :name, :nickname, :password, :password_confirmation])
 170       |> validate_required([:email, :name, :nickname, :password, :password_confirmation])
 171       |> validate_confirmation(:password)
 172       |> unique_constraint(:email)
 173       |> unique_constraint(:nickname)
 174       |> validate_format(:nickname, ~r/^[a-zA-Z\d]+$/)
 175       |> validate_format(:email, @email_regex)
 176       |> validate_length(:bio, max: 1000)
 177       |> validate_length(:name, min: 1, max: 100)
 178       |> put_change(:info, %Pleroma.User.Info{})
 179
 180     if changeset.valid? do
 181       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 182       ap_id = User.ap_id(%User{nickname: changeset.changes[:nickname]})
 183       followers = User.ap_followers(%User{nickname: changeset.changes[:nickname]})
 184
 185       changeset
 186       |> put_change(:password_hash, hashed)
 187       |> put_change(:ap_id, ap_id)
 188       |> put_change(:following, [followers])
 189       |> put_change(:follower_address, followers)
 190     else
 191       changeset
 192     end
 193   end
 194
 195   def needs_update?(%User{local: true}), do: false
 196
 197   def needs_update?(%User{local: false, last_refreshed_at: nil}), do: true
 198
 199   def needs_update?(%User{local: false} = user) do
 200     NaiveDateTime.diff(NaiveDateTime.utc_now(), user.last_refreshed_at) >= 86400
 201   end
 202
 203   def needs_update?(_), do: true
 204
 205   def maybe_direct_follow(%User{} = follower, %User{local: true, info: %{locked: true}}) do
 206     {:ok, follower}
 207   end
 208
 209   def maybe_direct_follow(%User{} = follower, %User{local: true} = followed) do
 210     follow(follower, followed)
 211   end
 212
 213   def maybe_direct_follow(%User{} = follower, %User{} = followed) do
 214     if !User.ap_enabled?(followed) do
 215       follow(follower, followed)
 216     else
 217       {:ok, follower}
 218     end
 219   end
 220
 221   def maybe_follow(%User{} = follower, %User{info: info} = followed) do
 222     if not following?(follower, followed) do
 223       follow(follower, followed)
 224     else
 225       {:ok, follower}
 226     end
 227   end
 228
 229   def follow(%User{} = follower, %User{info: info} = followed) do
 230     user_config = Application.get_env(:pleroma, :user)
 231     deny_follow_blocked = Keyword.get(user_config, :deny_follow_blocked)
 232
 233     ap_followers = followed.follower_address
 234
 235     cond do
 236       following?(follower, followed) or info.deactivated ->
 237         {:error, "Could not follow user: #{followed.nickname} is already on your list."}
 238
 239       deny_follow_blocked and blocks?(followed, follower) ->
 240         {:error, "Could not follow user: #{followed.nickname} blocked you."}
 241
 242       true ->
 243         if !followed.local && follower.local && !ap_enabled?(followed) do
 244           Websub.subscribe(follower, followed)
 245         end
 246
 247         following =
 248           [ap_followers | follower.following]
 249           |> Enum.uniq()
 250
 251         follower =
 252           follower
 253           |> follow_changeset(%{following: following})
 254           |> update_and_set_cache
 255
 256         {:ok, _} = update_follower_count(followed)
 257
 258         follower
 259     end
 260   end
 261
 262   def unfollow(%User{} = follower, %User{} = followed) do
 263     ap_followers = followed.follower_address
 264
 265     if following?(follower, followed) and follower.ap_id != followed.ap_id do
 266       following =
 267         follower.following
 268         |> List.delete(ap_followers)
 269
 270       {:ok, follower} =
 271         follower
 272         |> follow_changeset(%{following: following})
 273         |> update_and_set_cache
 274
 275       {:ok, followed} = update_follower_count(followed)
 276
 277       {:ok, follower, Utils.fetch_latest_follow(follower, followed)}
 278     else
 279       {:error, "Not subscribed!"}
 280     end
 281   end
 282
 283   def following?(%User{} = follower, %User{} = followed) do
 284     Enum.member?(follower.following, followed.follower_address)
 285   end
 286
 287   def locked?(%User{} = user) do
 288     user.info.locked || false
 289   end
 290
 291   def get_by_ap_id(ap_id) do
 292     Repo.get_by(User, ap_id: ap_id)
 293   end
 294
 295   def update_and_set_cache(changeset) do
 296     with {:ok, user} <- Repo.update(changeset) do
 297       Cachex.put(:user_cache, "ap_id:#{user.ap_id}", user)
 298       Cachex.put(:user_cache, "nickname:#{user.nickname}", user)
 299       Cachex.put(:user_cache, "user_info:#{user.id}", user_info(user))
 300       {:ok, user}
 301     else
 302       e -> e
 303     end
 304   end
 305
 306   def invalidate_cache(user) do
 307     Cachex.del(:user_cache, "ap_id:#{user.ap_id}")
 308     Cachex.del(:user_cache, "nickname:#{user.nickname}")
 309     Cachex.del(:user_cache, "user_info:#{user.id}")
 310   end
 311
 312   def get_cached_by_ap_id(ap_id) do
 313     key = "ap_id:#{ap_id}"
 314     Cachex.fetch!(:user_cache, key, fn _ -> get_by_ap_id(ap_id) end)
 315   end
 316
 317   def get_cached_by_nickname(nickname) do
 318     key = "nickname:#{nickname}"
 319     Cachex.fetch!(:user_cache, key, fn _ -> get_or_fetch_by_nickname(nickname) end)
 320   end
 321
 322   def get_by_nickname(nickname) do
 323     Repo.get_by(User, nickname: nickname)
 324   end
 325
 326   def get_by_nickname_or_email(nickname_or_email) do
 327     case user = Repo.get_by(User, nickname: nickname_or_email) do
 328       %User{} -> user
 329       nil -> Repo.get_by(User, email: nickname_or_email)
 330     end
 331   end
 332
 333   def get_cached_user_info(user) do
 334     key = "user_info:#{user.id}"
 335     Cachex.fetch!(:user_cache, key, fn _ -> user_info(user) end)
 336   end
 337
 338   def fetch_by_nickname(nickname) do
 339     ap_try = ActivityPub.make_user_from_nickname(nickname)
 340
 341     case ap_try do
 342       {:ok, user} -> {:ok, user}
 343       _ -> OStatus.make_user(nickname)
 344     end
 345   end
 346
 347   def get_or_fetch_by_nickname(nickname) do
 348     with %User{} = user <- get_by_nickname(nickname) do
 349       user
 350     else
 351       _e ->
 352         with [_nick, _domain] <- String.split(nickname, "@"),
 353              {:ok, user} <- fetch_by_nickname(nickname) do
 354           user
 355         else
 356           _e -> nil
 357         end
 358     end
 359   end
 360
 361   def get_followers_query(%User{id: id, follower_address: follower_address}) do
 362     from(
 363       u in User,
 364       where: fragment("? <@ ?", ^[follower_address], u.following),
 365       where: u.id != ^id
 366     )
 367   end
 368
 369   def get_followers(user) do
 370     q = get_followers_query(user)
 371
 372     {:ok, Repo.all(q)}
 373   end
 374
 375   def get_friends_query(%User{id: id, following: following}) do
 376     from(
 377       u in User,
 378       where: u.follower_address in ^following,
 379       where: u.id != ^id
 380     )
 381   end
 382
 383   def get_friends(user) do
 384     q = get_friends_query(user)
 385
 386     {:ok, Repo.all(q)}
 387   end
 388
 389   def get_follow_requests_query(%User{} = user) do
 390     from(
 391       a in Activity,
 392       where:
 393         fragment(
 394           "? ->> 'type' = 'Follow'",
 395           a.data
 396         ),
 397       where:
 398         fragment(
 399           "? ->> 'state' = 'pending'",
 400           a.data
 401         ),
 402       where:
 403         fragment(
 404           "? @> ?",
 405           a.data,
 406           ^%{"object" => user.ap_id}
 407         )
 408     )
 409   end
 410
 411   def get_follow_requests(%User{} = user) do
 412     q = get_follow_requests_query(user)
 413     reqs = Repo.all(q)
 414
 415     users =
 416       Enum.map(reqs, fn req -> req.actor end)
 417       |> Enum.uniq()
 418       |> Enum.map(fn ap_id -> get_by_ap_id(ap_id) end)
 419       |> Enum.filter(fn u -> !following?(u, user) end)
 420
 421     {:ok, users}
 422   end
 423
 424   def increase_note_count(%User{} = user) do
 425     info_cng = User.Info.add_to_note_count(user.info, 1)
 426
 427     cng =
 428       change(user)
 429       |> put_embed(:info, info_cng)
 430
 431     update_and_set_cache(cng)
 432   end
 433
 434   def decrease_note_count(%User{} = user) do
 435     info_cng = User.Info.add_to_note_count(user.info, -1)
 436
 437     cng =
 438       change(user)
 439       |> put_embed(:info, info_cng)
 440
 441     update_and_set_cache(cng)
 442   end
 443
 444   def update_note_count(%User{} = user) do
 445     note_count_query =
 446       from(
 447         a in Object,
 448         where: fragment("?->>'actor' = ? and ?->>'type' = 'Note'", a.data, ^user.ap_id, a.data),
 449         select: count(a.id)
 450       )
 451
 452     note_count = Repo.one(note_count_query)
 453
 454     info_cng = User.Info.set_note_count(user.info, note_count)
 455
 456     cng =
 457       change(user)
 458       |> put_embed(:info, info_cng)
 459
 460     update_and_set_cache(cng)
 461   end
 462
 463   def update_follower_count(%User{} = user) do
 464     follower_count_query =
 465       from(
 466         u in User,
 467         where: ^user.follower_address in u.following,
 468         where: u.id != ^user.id,
 469         select: count(u.id)
 470       )
 471
 472     follower_count = Repo.one(follower_count_query)
 473
 474     info_cng =
 475       user.info
 476       |> User.Info.set_follower_count(follower_count)
 477
 478     cng =
 479       change(user)
 480       |> put_embed(:info, info_cng)
 481
 482     update_and_set_cache(cng)
 483   end
 484
 485   def get_users_from_set_query(ap_ids, false) do
 486     from(
 487       u in User,
 488       where: u.ap_id in ^ap_ids
 489     )
 490   end
 491
 492   def get_users_from_set_query(ap_ids, true) do
 493     query = get_users_from_set_query(ap_ids, false)
 494
 495     from(
 496       u in query,
 497       where: u.local == true
 498     )
 499   end
 500
 501   def get_users_from_set(ap_ids, local_only \\ true) do
 502     get_users_from_set_query(ap_ids, local_only)
 503     |> Repo.all()
 504   end
 505
 506   def get_recipients_from_activity(%Activity{recipients: to}) do
 507     query =
 508       from(
 509         u in User,
 510         where: u.ap_id in ^to,
 511         or_where: fragment("? && ?", u.following, ^to)
 512       )
 513
 514     query = from(u in query, where: u.local == true)
 515
 516     Repo.all(query)
 517   end
 518
 519   def search(query, resolve \\ false) do
 520     # strip the beginning @ off if there is a query
 521     query = String.trim_leading(query, "@")
 522
 523     if resolve do
 524       User.get_or_fetch_by_nickname(query)
 525     end
 526
 527     inner =
 528       from(
 529         u in User,
 530         select_merge: %{
 531           search_distance:
 532             fragment(
 533               "? <-> (? || ?)",
 534               ^query,
 535               u.nickname,
 536               u.name
 537             )
 538         },
 539         where: not is_nil(u.nickname)
 540       )
 541
 542     q =
 543       from(
 544         s in subquery(inner),
 545         order_by: s.search_distance,
 546         limit: 20
 547       )
 548
 549     Repo.all(q)
 550   end
 551
 552   def block(blocker, %User{ap_id: ap_id} = blocked) do
 553     # sever any follow relationships to prevent leaks per activitypub (Pleroma issue #213)
 554     blocker =
 555       if following?(blocker, blocked) do
 556         {:ok, blocker, _} = unfollow(blocker, blocked)
 557         blocker
 558       else
 559         blocker
 560       end
 561
 562     if following?(blocked, blocker) do
 563       unfollow(blocked, blocker)
 564     end
 565
 566     info_cng =
 567       blocker.info
 568       |> User.Info.add_to_block(ap_id)
 569
 570     cng =
 571       change(blocker)
 572       |> put_embed(:info, info_cng)
 573
 574     update_and_set_cache(cng)
 575   end
 576
 577   # helper to handle the block given only an actor's AP id
 578   def block(blocker, %{ap_id: ap_id}) do
 579     block(blocker, User.get_by_ap_id(ap_id))
 580   end
 581
 582   def unblock(blocker, %{ap_id: ap_id}) do
 583     info_cng =
 584       blocker.info
 585       |> User.Info.remove_from_block(ap_id)
 586
 587     cng =
 588       change(blocker)
 589       |> put_embed(:info, info_cng)
 590
 591     update_and_set_cache(cng)
 592   end
 593
 594   def blocks?(user, %{ap_id: ap_id}) do
 595     blocks = user.info.blocks
 596     domain_blocks = user.info.domain_blocks
 597     %{host: host} = URI.parse(ap_id)
 598
 599     Enum.member?(blocks, ap_id) ||
 600       Enum.any?(domain_blocks, fn domain ->
 601         host == domain
 602       end)
 603   end
 604
 605   def block_domain(user, domain) do
 606     info_cng =
 607       user.info
 608       |> User.Info.add_to_domain_block(domain)
 609
 610     cng =
 611       change(user)
 612       |> put_embed(:info, info_cng)
 613
 614     update_and_set_cache(cng)
 615   end
 616
 617   def unblock_domain(user, domain) do
 618     info_cng =
 619       user.info
 620       |> User.Info.remove_from_domain_block(domain)
 621
 622     cng =
 623       change(user)
 624       |> put_embed(:info, info_cng)
 625
 626     update_and_set_cache(cng)
 627   end
 628
 629   def local_user_query() do
 630     from(
 631       u in User,
 632       where: u.local == true,
 633       where: not is_nil(u.nickname)
 634     )
 635   end
 636
 637   def moderator_user_query() do
 638     from(
 639       u in User,
 640       where: u.local == true,
 641       where: fragment("?->'is_moderator' @> 'true'", u.info)
 642     )
 643   end
 644
 645   def deactivate(%User{} = user, status \\ true) do
 646     info_cng = User.Info.set_activation_status(user.info, status)
 647
 648     cng =
 649       change(user)
 650       |> put_embed(:info, info_cng)
 651
 652     update_and_set_cache(cng)
 653   end
 654
 655   def delete(%User{} = user) do
 656     {:ok, user} = User.deactivate(user)
 657
 658     # Remove all relationships
 659     {:ok, followers} = User.get_followers(user)
 660
 661     followers
 662     |> Enum.each(fn follower -> User.unfollow(follower, user) end)
 663
 664     {:ok, friends} = User.get_friends(user)
 665
 666     friends
 667     |> Enum.each(fn followed -> User.unfollow(user, followed) end)
 668
 669     query = from(a in Activity, where: a.actor == ^user.ap_id)
 670
 671     Repo.all(query)
 672     |> Enum.each(fn activity ->
 673       case activity.data["type"] do
 674         "Create" ->
 675           ActivityPub.delete(Object.normalize(activity.data["object"]))
 676
 677         # TODO: Do something with likes, follows, repeats.
 678         _ ->
 679           "Doing nothing"
 680       end
 681     end)
 682
 683     {:ok, user}
 684   end
 685
 686   def html_filter_policy(%User{info: %{no_rich_text: true}}) do
 687     Pleroma.HTML.Scrubber.TwitterText
 688   end
 689
 690   def html_filter_policy(_), do: nil
 691
 692   def get_or_fetch_by_ap_id(ap_id) do
 693     user = get_by_ap_id(ap_id)
 694
 695     if !is_nil(user) and !User.needs_update?(user) do
 696       user
 697     else
 698       ap_try = ActivityPub.make_user_from_ap_id(ap_id)
 699
 700       case ap_try do
 701         {:ok, user} ->
 702           user
 703
 704         _ ->
 705           case OStatus.make_user(ap_id) do
 706             {:ok, user} -> user
 707             _ -> {:error, "Could not fetch by AP id"}
 708           end
 709       end
 710     end
 711   end
 712
 713   def get_or_create_instance_user do
 714     relay_uri = "#{Pleroma.Web.Endpoint.url()}/relay"
 715
 716     if user = get_by_ap_id(relay_uri) do
 717       user
 718     else
 719       changes =
 720         %User{info: %User.Info{}}
 721         |> cast(%{}, [:ap_id, :nickname, :local])
 722         |> put_change(:ap_id, relay_uri)
 723         |> put_change(:nickname, nil)
 724         |> put_change(:local, true)
 725         |> put_change(:follower_address, relay_uri <> "/followers")
 726
 727       {:ok, user} = Repo.insert(changes)
 728       user
 729     end
 730   end
 731
 732   # AP style
 733   def public_key_from_info(%{
 734         source_data: %{"publicKey" => %{"publicKeyPem" => public_key_pem}}
 735       }) do
 736     key =
 737       :public_key.pem_decode(public_key_pem)
 738       |> hd()
 739       |> :public_key.pem_entry_decode()
 740
 741     {:ok, key}
 742   end
 743
 744   # OStatus Magic Key
 745   def public_key_from_info(%{magic_key: magic_key}) do
 746     {:ok, Pleroma.Web.Salmon.decode_key(magic_key)}
 747   end
 748
 749   def get_public_key_for_ap_id(ap_id) do
 750     with %User{} = user <- get_or_fetch_by_ap_id(ap_id),
 751          {:ok, public_key} <- public_key_from_info(user.info) do
 752       {:ok, public_key}
 753     else
 754       _ -> :error
 755     end
 756   end
 757
 758   defp blank?(""), do: nil
 759   defp blank?(n), do: n
 760
 761   def insert_or_update_user(data) do
 762     data =
 763       data
 764       |> Map.put(:name, blank?(data[:name]) || data[:nickname])
 765
 766     cs = User.remote_user_creation(data)
 767
 768     Repo.insert(cs, on_conflict: :replace_all, conflict_target: :nickname)
 769   end
 770
 771   def ap_enabled?(%User{local: true}), do: true
 772   def ap_enabled?(%User{info: info}), do: info.ap_enabled
 773   def ap_enabled?(_), do: false
 774
 775   def get_or_fetch(uri_or_nickname) do
 776     if String.starts_with?(uri_or_nickname, "http") do
 777       get_or_fetch_by_ap_id(uri_or_nickname)
 778     else
 779       get_or_fetch_by_nickname(uri_or_nickname)
 780     end
 781   end
 782
 783   # wait a period of time and return newest version of the User structs
 784   # this is because we have synchronous follow APIs and need to simulate them
 785   # with an async handshake
 786   def wait_and_refresh(_, %User{local: true} = a, %User{local: true} = b) do
 787     with %User{} = a <- Repo.get(User, a.id),
 788          %User{} = b <- Repo.get(User, b.id) do
 789       {:ok, a, b}
 790     else
 791       _e ->
 792         :error
 793     end
 794   end
 795
 796   def wait_and_refresh(timeout, %User{} = a, %User{} = b) do
 797     with :ok <- :timer.sleep(timeout),
 798          %User{} = a <- Repo.get(User, a.id),
 799          %User{} = b <- Repo.get(User, b.id) do
 800       {:ok, a, b}
 801     else
 802       _e ->
 803         :error
 804     end
 805   end
 806
 807   def parse_bio(bio, user \\ %User{info: %{source_data: %{}}}) do
 808     mentions = Formatter.parse_mentions(bio)
 809     tags = Formatter.parse_tags(bio)
 810
 811     emoji =
 812       (user.info.source_data["tag"] || [])
 813       |> Enum.filter(fn %{"type" => t} -> t == "Emoji" end)
 814       |> Enum.map(fn %{"icon" => %{"url" => url}, "name" => name} ->
 815         {String.trim(name, ":"), url}
 816       end)
 817
 818     CommonUtils.format_input(bio, mentions, tags, "text/plain") |> Formatter.emojify(emoji)
 819   end
 820
 821   def tag(user_identifiers, tags) when is_list(user_identifiers) do
 822     Repo.transaction(fn ->
 823       for user_identifier <- user_identifiers, do: tag(user_identifier, tags)
 824     end)
 825   end
 826
 827   def untag(user_identifiers, tags) when is_list(user_identifiers) do
 828     Repo.transaction(fn ->
 829       for user_identifier <- user_identifiers, do: untag(user_identifier, tags)
 830     end)
 831   end
 832
 833   def tag(nickname, tags) when is_binary(nickname), do: tag(User.get_by_nickname(nickname), tags)
 834
 835   def untag(nickname, tags) when is_binary(nickname),
 836     do: untag(User.get_by_nickname(nickname), tags)
 837
 838   def tag(%User{} = user, tags),
 839     do: update_tags(user, Enum.uniq(user.tags ++ normalize_tags(tags)))
 840
 841   def untag(%User{} = user, tags), do: update_tags(user, user.tags -- normalize_tags(tags))
 842
 843   defp update_tags(%User{} = user, new_tags) do
 844     {:ok, updated_user} =
 845       user
 846       |> change(%{tags: new_tags})
 847       |> Repo.update()
 848
 849     updated_user
 850   end
 851
 852   defp normalize_tags(tags) do
 853     [tags]
 854     |> List.flatten()
 855     |> Enum.map(&String.downcase(&1))
 856   end
 857 end