git.squeep.com Git - akkoma/blob - lib/pleroma/user.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.User do
   6   use Ecto.Schema
   7
   8   import Ecto.{Changeset, Query}
   9   alias Pleroma.{Repo, User, Object, Web, Activity, Notification}
  10   alias Comeonin.Pbkdf2
  11   alias Pleroma.Formatter
  12   alias Pleroma.Web.CommonAPI.Utils, as: CommonUtils
  13   alias Pleroma.Web.{OStatus, Websub, OAuth}
  14   alias Pleroma.Web.ActivityPub.{Utils, ActivityPub}
  15
  16   require Logger
  17
  18   @type t :: %__MODULE__{}
  19
  20   @email_regex ~r/^[a-zA-Z0-9.!#$%&'*+\/=?^_`{|}~-]+@[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?(?:\.[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?)*$/
  21
  22   @strict_local_nickname_regex ~r/^[a-zA-Z\d]+$/
  23   @extended_local_nickname_regex ~r/^[a-zA-Z\d_-]+$/
  24
  25   schema "users" do
  26     field(:bio, :string)
  27     field(:email, :string)
  28     field(:name, :string)
  29     field(:nickname, :string)
  30     field(:password_hash, :string)
  31     field(:password, :string, virtual: true)
  32     field(:password_confirmation, :string, virtual: true)
  33     field(:following, {:array, :string}, default: [])
  34     field(:ap_id, :string)
  35     field(:avatar, :map)
  36     field(:local, :boolean, default: true)
  37     field(:follower_address, :string)
  38     field(:search_distance, :float, virtual: true)
  39     field(:tags, {:array, :string}, default: [])
  40     field(:last_refreshed_at, :naive_datetime)
  41     has_many(:notifications, Notification)
  42     embeds_one(:info, Pleroma.User.Info)
  43
  44     timestamps()
  45   end
  46
  47   def auth_active?(%User{local: false}), do: true
  48
  49   def auth_active?(%User{info: %User.Info{confirmation_pending: false}}), do: true
  50
  51   def auth_active?(%User{info: %User.Info{confirmation_pending: true}}),
  52     do: !Pleroma.Config.get([:instance, :account_activation_required])
  53
  54   def auth_active?(_), do: false
  55
  56   def visible_for?(user, for_user \\ nil)
  57
  58   def visible_for?(%User{id: user_id}, %User{id: for_id}) when user_id == for_id, do: true
  59
  60   def visible_for?(%User{} = user, for_user) do
  61     auth_active?(user) || superuser?(for_user)
  62   end
  63
  64   def visible_for?(_, _), do: false
  65
  66   def superuser?(%User{local: true, info: %User.Info{is_admin: true}}), do: true
  67   def superuser?(%User{local: true, info: %User.Info{is_moderator: true}}), do: true
  68   def superuser?(_), do: false
  69
  70   def avatar_url(user) do
  71     case user.avatar do
  72       %{"url" => [%{"href" => href} | _]} -> href
  73       _ -> "#{Web.base_url()}/images/avi.png"
  74     end
  75   end
  76
  77   def banner_url(user) do
  78     case user.info.banner do
  79       %{"url" => [%{"href" => href} | _]} -> href
  80       _ -> "#{Web.base_url()}/images/banner.png"
  81     end
  82   end
  83
  84   def profile_url(%User{info: %{source_data: %{"url" => url}}}), do: url
  85   def profile_url(%User{ap_id: ap_id}), do: ap_id
  86   def profile_url(_), do: nil
  87
  88   def ap_id(%User{nickname: nickname}) do
  89     "#{Web.base_url()}/users/#{nickname}"
  90   end
  91
  92   def ap_followers(%User{} = user) do
  93     "#{ap_id(user)}/followers"
  94   end
  95
  96   def follow_changeset(struct, params \\ %{}) do
  97     struct
  98     |> cast(params, [:following])
  99     |> validate_required([:following])
 100   end
 101
 102   def user_info(%User{} = user) do
 103     oneself = if user.local, do: 1, else: 0
 104
 105     %{
 106       following_count: length(user.following) - oneself,
 107       note_count: user.info.note_count,
 108       follower_count: user.info.follower_count,
 109       locked: user.info.locked,
 110       confirmation_pending: user.info.confirmation_pending,
 111       default_scope: user.info.default_scope
 112     }
 113   end
 114
 115   def remote_user_creation(params) do
 116     params =
 117       params
 118       |> Map.put(:info, params[:info] || %{})
 119
 120     info_cng = User.Info.remote_user_creation(%User.Info{}, params[:info])
 121
 122     changes =
 123       %User{}
 124       |> cast(params, [:bio, :name, :ap_id, :nickname, :avatar])
 125       |> validate_required([:name, :ap_id])
 126       |> unique_constraint(:nickname)
 127       |> validate_format(:nickname, @email_regex)
 128       |> validate_length(:bio, max: 5000)
 129       |> validate_length(:name, max: 100)
 130       |> put_change(:local, false)
 131       |> put_embed(:info, info_cng)
 132
 133     if changes.valid? do
 134       case info_cng.changes[:source_data] do
 135         %{"followers" => followers} ->
 136           changes
 137           |> put_change(:follower_address, followers)
 138
 139         _ ->
 140           followers = User.ap_followers(%User{nickname: changes.changes[:nickname]})
 141
 142           changes
 143           |> put_change(:follower_address, followers)
 144       end
 145     else
 146       changes
 147     end
 148   end
 149
 150   def update_changeset(struct, params \\ %{}) do
 151     struct
 152     |> cast(params, [:bio, :name, :avatar])
 153     |> unique_constraint(:nickname)
 154     |> validate_format(:nickname, local_nickname_regex())
 155     |> validate_length(:bio, max: 5000)
 156     |> validate_length(:name, min: 1, max: 100)
 157   end
 158
 159   def upgrade_changeset(struct, params \\ %{}) do
 160     params =
 161       params
 162       |> Map.put(:last_refreshed_at, NaiveDateTime.utc_now())
 163
 164     info_cng =
 165       struct.info
 166       |> User.Info.user_upgrade(params[:info])
 167
 168     struct
 169     |> cast(params, [:bio, :name, :follower_address, :avatar, :last_refreshed_at])
 170     |> unique_constraint(:nickname)
 171     |> validate_format(:nickname, local_nickname_regex())
 172     |> validate_length(:bio, max: 5000)
 173     |> validate_length(:name, max: 100)
 174     |> put_embed(:info, info_cng)
 175   end
 176
 177   def password_update_changeset(struct, params) do
 178     changeset =
 179       struct
 180       |> cast(params, [:password, :password_confirmation])
 181       |> validate_required([:password, :password_confirmation])
 182       |> validate_confirmation(:password)
 183
 184     OAuth.Token.delete_user_tokens(struct)
 185     OAuth.Authorization.delete_user_authorizations(struct)
 186
 187     if changeset.valid? do
 188       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 189
 190       changeset
 191       |> put_change(:password_hash, hashed)
 192     else
 193       changeset
 194     end
 195   end
 196
 197   def reset_password(user, data) do
 198     update_and_set_cache(password_update_changeset(user, data))
 199   end
 200
 201   def register_changeset(struct, params \\ %{}, opts \\ []) do
 202     confirmation_status =
 203       if opts[:confirmed] || !Pleroma.Config.get([:instance, :account_activation_required]) do
 204         :confirmed
 205       else
 206         :unconfirmed
 207       end
 208
 209     info_change = User.Info.confirmation_changeset(%User.Info{}, confirmation_status)
 210
 211     changeset =
 212       struct
 213       |> cast(params, [:bio, :email, :name, :nickname, :password, :password_confirmation])
 214       |> validate_required([:email, :name, :nickname, :password, :password_confirmation])
 215       |> validate_confirmation(:password)
 216       |> unique_constraint(:email)
 217       |> unique_constraint(:nickname)
 218       |> validate_exclusion(:nickname, Pleroma.Config.get([Pleroma.User, :restricted_nicknames]))
 219       |> validate_format(:nickname, local_nickname_regex())
 220       |> validate_format(:email, @email_regex)
 221       |> validate_length(:bio, max: 1000)
 222       |> validate_length(:name, min: 1, max: 100)
 223       |> put_change(:info, info_change)
 224
 225     if changeset.valid? do
 226       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 227       ap_id = User.ap_id(%User{nickname: changeset.changes[:nickname]})
 228       followers = User.ap_followers(%User{nickname: changeset.changes[:nickname]})
 229
 230       changeset
 231       |> put_change(:password_hash, hashed)
 232       |> put_change(:ap_id, ap_id)
 233       |> put_change(:following, [followers])
 234       |> put_change(:follower_address, followers)
 235     else
 236       changeset
 237     end
 238   end
 239
 240   defp autofollow_users(user) do
 241     candidates = Pleroma.Config.get([:instance, :autofollowed_nicknames])
 242
 243     autofollowed_users =
 244       from(u in User,
 245         where: u.local == true,
 246         where: u.nickname in ^candidates
 247       )
 248       |> Repo.all()
 249
 250     autofollowed_users
 251     |> Enum.reduce({:ok, user}, fn other_user, {:ok, user} ->
 252       follow(user, other_user)
 253     end)
 254   end
 255
 256   @doc "Inserts provided changeset, performs post-registration actions (confirmation email sending etc.)"
 257   def register(%Ecto.Changeset{} = changeset) do
 258     with {:ok, user} <- Repo.insert(changeset),
 259          {:ok, _} <- try_send_confirmation_email(user),
 260          {:ok, user} <- autofollow_users(user) do
 261       {:ok, user}
 262     end
 263   end
 264
 265   def try_send_confirmation_email(%User{} = user) do
 266     if user.info.confirmation_pending &&
 267          Pleroma.Config.get([:instance, :account_activation_required]) do
 268       user
 269       |> Pleroma.UserEmail.account_confirmation_email()
 270       |> Pleroma.Mailer.deliver()
 271     else
 272       {:ok, :noop}
 273     end
 274   end
 275
 276   def needs_update?(%User{local: true}), do: false
 277
 278   def needs_update?(%User{local: false, last_refreshed_at: nil}), do: true
 279
 280   def needs_update?(%User{local: false} = user) do
 281     NaiveDateTime.diff(NaiveDateTime.utc_now(), user.last_refreshed_at) >= 86400
 282   end
 283
 284   def needs_update?(_), do: true
 285
 286   def maybe_direct_follow(%User{} = follower, %User{local: true, info: %{locked: true}}) do
 287     {:ok, follower}
 288   end
 289
 290   def maybe_direct_follow(%User{} = follower, %User{local: true} = followed) do
 291     follow(follower, followed)
 292   end
 293
 294   def maybe_direct_follow(%User{} = follower, %User{} = followed) do
 295     if not User.ap_enabled?(followed) do
 296       follow(follower, followed)
 297     else
 298       {:ok, follower}
 299     end
 300   end
 301
 302   def maybe_follow(%User{} = follower, %User{info: _info} = followed) do
 303     if not following?(follower, followed) do
 304       follow(follower, followed)
 305     else
 306       {:ok, follower}
 307     end
 308   end
 309
 310   def follow(%User{} = follower, %User{info: info} = followed) do
 311     user_config = Application.get_env(:pleroma, :user)
 312     deny_follow_blocked = Keyword.get(user_config, :deny_follow_blocked)
 313
 314     ap_followers = followed.follower_address
 315
 316     cond do
 317       following?(follower, followed) or info.deactivated ->
 318         {:error, "Could not follow user: #{followed.nickname} is already on your list."}
 319
 320       deny_follow_blocked and blocks?(followed, follower) ->
 321         {:error, "Could not follow user: #{followed.nickname} blocked you."}
 322
 323       true ->
 324         if !followed.local && follower.local && !ap_enabled?(followed) do
 325           Websub.subscribe(follower, followed)
 326         end
 327
 328         following =
 329           [ap_followers | follower.following]
 330           |> Enum.uniq()
 331
 332         follower =
 333           follower
 334           |> follow_changeset(%{following: following})
 335           |> update_and_set_cache
 336
 337         {:ok, _} = update_follower_count(followed)
 338
 339         follower
 340     end
 341   end
 342
 343   def unfollow(%User{} = follower, %User{} = followed) do
 344     ap_followers = followed.follower_address
 345
 346     if following?(follower, followed) and follower.ap_id != followed.ap_id do
 347       following =
 348         follower.following
 349         |> List.delete(ap_followers)
 350
 351       {:ok, follower} =
 352         follower
 353         |> follow_changeset(%{following: following})
 354         |> update_and_set_cache
 355
 356       {:ok, followed} = update_follower_count(followed)
 357
 358       {:ok, follower, Utils.fetch_latest_follow(follower, followed)}
 359     else
 360       {:error, "Not subscribed!"}
 361     end
 362   end
 363
 364   @spec following?(User.t(), User.t()) :: boolean
 365   def following?(%User{} = follower, %User{} = followed) do
 366     Enum.member?(follower.following, followed.follower_address)
 367   end
 368
 369   def follow_import(%User{} = follower, followed_identifiers)
 370       when is_list(followed_identifiers) do
 371     Enum.map(
 372       followed_identifiers,
 373       fn followed_identifier ->
 374         with %User{} = followed <- get_or_fetch(followed_identifier),
 375              {:ok, follower} <- maybe_direct_follow(follower, followed),
 376              {:ok, _} <- ActivityPub.follow(follower, followed) do
 377           followed
 378         else
 379           err ->
 380             Logger.debug("follow_import failed for #{followed_identifier} with: #{inspect(err)}")
 381             err
 382         end
 383       end
 384     )
 385   end
 386
 387   def locked?(%User{} = user) do
 388     user.info.locked || false
 389   end
 390
 391   def get_by_ap_id(ap_id) do
 392     Repo.get_by(User, ap_id: ap_id)
 393   end
 394
 395   # This is mostly an SPC migration fix. This guesses the user nickname (by taking the last part of the ap_id and the domain) and tries to get that user
 396   def get_by_guessed_nickname(ap_id) do
 397     domain = URI.parse(ap_id).host
 398     name = List.last(String.split(ap_id, "/"))
 399     nickname = "#{name}@#{domain}"
 400
 401     get_by_nickname(nickname)
 402   end
 403
 404   def update_and_set_cache(changeset) do
 405     with {:ok, user} <- Repo.update(changeset) do
 406       Cachex.put(:user_cache, "ap_id:#{user.ap_id}", user)
 407       Cachex.put(:user_cache, "nickname:#{user.nickname}", user)
 408       Cachex.put(:user_cache, "user_info:#{user.id}", user_info(user))
 409       {:ok, user}
 410     else
 411       e -> e
 412     end
 413   end
 414
 415   def invalidate_cache(user) do
 416     Cachex.del(:user_cache, "ap_id:#{user.ap_id}")
 417     Cachex.del(:user_cache, "nickname:#{user.nickname}")
 418     Cachex.del(:user_cache, "user_info:#{user.id}")
 419   end
 420
 421   def get_cached_by_ap_id(ap_id) do
 422     key = "ap_id:#{ap_id}"
 423     Cachex.fetch!(:user_cache, key, fn _ -> get_by_ap_id(ap_id) end)
 424   end
 425
 426   def get_cached_by_nickname(nickname) do
 427     key = "nickname:#{nickname}"
 428     Cachex.fetch!(:user_cache, key, fn _ -> get_or_fetch_by_nickname(nickname) end)
 429   end
 430
 431   def get_by_nickname(nickname) do
 432     Repo.get_by(User, nickname: nickname) ||
 433       if Regex.match?(~r(@#{Pleroma.Web.Endpoint.host()})i, nickname) do
 434         [local_nickname, _] = String.split(nickname, "@")
 435         Repo.get_by(User, nickname: local_nickname)
 436       end
 437   end
 438
 439   def get_by_nickname_or_email(nickname_or_email) do
 440     case user = Repo.get_by(User, nickname: nickname_or_email) do
 441       %User{} -> user
 442       nil -> Repo.get_by(User, email: nickname_or_email)
 443     end
 444   end
 445
 446   def get_cached_user_info(user) do
 447     key = "user_info:#{user.id}"
 448     Cachex.fetch!(:user_cache, key, fn _ -> user_info(user) end)
 449   end
 450
 451   def fetch_by_nickname(nickname) do
 452     ap_try = ActivityPub.make_user_from_nickname(nickname)
 453
 454     case ap_try do
 455       {:ok, user} -> {:ok, user}
 456       _ -> OStatus.make_user(nickname)
 457     end
 458   end
 459
 460   def get_or_fetch_by_nickname(nickname) do
 461     with %User{} = user <- get_by_nickname(nickname) do
 462       user
 463     else
 464       _e ->
 465         with [_nick, _domain] <- String.split(nickname, "@"),
 466              {:ok, user} <- fetch_by_nickname(nickname) do
 467           user
 468         else
 469           _e -> nil
 470         end
 471     end
 472   end
 473
 474   def get_followers_query(%User{id: id, follower_address: follower_address}, nil) do
 475     from(
 476       u in User,
 477       where: fragment("? <@ ?", ^[follower_address], u.following),
 478       where: u.id != ^id
 479     )
 480   end
 481
 482   def get_followers_query(user, page) do
 483     from(
 484       u in get_followers_query(user, nil),
 485       limit: 20,
 486       offset: ^((page - 1) * 20)
 487     )
 488   end
 489
 490   def get_followers_query(user), do: get_followers_query(user, nil)
 491
 492   def get_followers(user, page \\ nil) do
 493     q = get_followers_query(user, page)
 494
 495     {:ok, Repo.all(q)}
 496   end
 497
 498   def get_friends_query(%User{id: id, following: following}, nil) do
 499     from(
 500       u in User,
 501       where: u.follower_address in ^following,
 502       where: u.id != ^id
 503     )
 504   end
 505
 506   def get_friends_query(user, page) do
 507     from(
 508       u in get_friends_query(user, nil),
 509       limit: 20,
 510       offset: ^((page - 1) * 20)
 511     )
 512   end
 513
 514   def get_friends_query(user), do: get_friends_query(user, nil)
 515
 516   def get_friends(user, page \\ nil) do
 517     q = get_friends_query(user, page)
 518
 519     {:ok, Repo.all(q)}
 520   end
 521
 522   def get_follow_requests_query(%User{} = user) do
 523     from(
 524       a in Activity,
 525       where:
 526         fragment(
 527           "? ->> 'type' = 'Follow'",
 528           a.data
 529         ),
 530       where:
 531         fragment(
 532           "? ->> 'state' = 'pending'",
 533           a.data
 534         ),
 535       where:
 536         fragment(
 537           "? @> ?",
 538           a.data,
 539           ^%{"object" => user.ap_id}
 540         )
 541     )
 542   end
 543
 544   def get_follow_requests(%User{} = user) do
 545     q = get_follow_requests_query(user)
 546     reqs = Repo.all(q)
 547
 548     users =
 549       Enum.map(reqs, fn req -> req.actor end)
 550       |> Enum.uniq()
 551       |> Enum.map(fn ap_id -> get_by_ap_id(ap_id) end)
 552       |> Enum.filter(fn u -> !is_nil(u) end)
 553       |> Enum.filter(fn u -> !following?(u, user) end)
 554
 555     {:ok, users}
 556   end
 557
 558   def increase_note_count(%User{} = user) do
 559     info_cng = User.Info.add_to_note_count(user.info, 1)
 560
 561     cng =
 562       change(user)
 563       |> put_embed(:info, info_cng)
 564
 565     update_and_set_cache(cng)
 566   end
 567
 568   def decrease_note_count(%User{} = user) do
 569     info_cng = User.Info.add_to_note_count(user.info, -1)
 570
 571     cng =
 572       change(user)
 573       |> put_embed(:info, info_cng)
 574
 575     update_and_set_cache(cng)
 576   end
 577
 578   def update_note_count(%User{} = user) do
 579     note_count_query =
 580       from(
 581         a in Object,
 582         where: fragment("?->>'actor' = ? and ?->>'type' = 'Note'", a.data, ^user.ap_id, a.data),
 583         select: count(a.id)
 584       )
 585
 586     note_count = Repo.one(note_count_query)
 587
 588     info_cng = User.Info.set_note_count(user.info, note_count)
 589
 590     cng =
 591       change(user)
 592       |> put_embed(:info, info_cng)
 593
 594     update_and_set_cache(cng)
 595   end
 596
 597   def update_follower_count(%User{} = user) do
 598     follower_count_query =
 599       from(
 600         u in User,
 601         where: ^user.follower_address in u.following,
 602         where: u.id != ^user.id,
 603         select: count(u.id)
 604       )
 605
 606     follower_count = Repo.one(follower_count_query)
 607
 608     info_cng =
 609       user.info
 610       |> User.Info.set_follower_count(follower_count)
 611
 612     cng =
 613       change(user)
 614       |> put_embed(:info, info_cng)
 615
 616     update_and_set_cache(cng)
 617   end
 618
 619   def get_users_from_set_query(ap_ids, false) do
 620     from(
 621       u in User,
 622       where: u.ap_id in ^ap_ids
 623     )
 624   end
 625
 626   def get_users_from_set_query(ap_ids, true) do
 627     query = get_users_from_set_query(ap_ids, false)
 628
 629     from(
 630       u in query,
 631       where: u.local == true
 632     )
 633   end
 634
 635   def get_users_from_set(ap_ids, local_only \\ true) do
 636     get_users_from_set_query(ap_ids, local_only)
 637     |> Repo.all()
 638   end
 639
 640   def get_recipients_from_activity(%Activity{recipients: to}) do
 641     query =
 642       from(
 643         u in User,
 644         where: u.ap_id in ^to,
 645         or_where: fragment("? && ?", u.following, ^to)
 646       )
 647
 648     query = from(u in query, where: u.local == true)
 649
 650     Repo.all(query)
 651   end
 652
 653   def search(query, resolve \\ false) do
 654     # strip the beginning @ off if there is a query
 655     query = String.trim_leading(query, "@")
 656
 657     if resolve do
 658       User.get_or_fetch_by_nickname(query)
 659     end
 660
 661     inner =
 662       from(
 663         u in User,
 664         select_merge: %{
 665           search_distance:
 666             fragment(
 667               "? <-> (? || coalesce(?, ''))",
 668               ^query,
 669               u.nickname,
 670               u.name
 671             )
 672         },
 673         where: not is_nil(u.nickname)
 674       )
 675
 676     q =
 677       from(
 678         s in subquery(inner),
 679         order_by: s.search_distance,
 680         limit: 20
 681       )
 682
 683     Repo.all(q)
 684   end
 685
 686   def blocks_import(%User{} = blocker, blocked_identifiers) when is_list(blocked_identifiers) do
 687     Enum.map(
 688       blocked_identifiers,
 689       fn blocked_identifier ->
 690         with %User{} = blocked <- get_or_fetch(blocked_identifier),
 691              {:ok, blocker} <- block(blocker, blocked),
 692              {:ok, _} <- ActivityPub.block(blocker, blocked) do
 693           blocked
 694         else
 695           err ->
 696             Logger.debug("blocks_import failed for #{blocked_identifier} with: #{inspect(err)}")
 697             err
 698         end
 699       end
 700     )
 701   end
 702
 703   def block(blocker, %User{ap_id: ap_id} = blocked) do
 704     # sever any follow relationships to prevent leaks per activitypub (Pleroma issue #213)
 705     blocker =
 706       if following?(blocker, blocked) do
 707         {:ok, blocker, _} = unfollow(blocker, blocked)
 708         blocker
 709       else
 710         blocker
 711       end
 712
 713     if following?(blocked, blocker) do
 714       unfollow(blocked, blocker)
 715     end
 716
 717     info_cng =
 718       blocker.info
 719       |> User.Info.add_to_block(ap_id)
 720
 721     cng =
 722       change(blocker)
 723       |> put_embed(:info, info_cng)
 724
 725     update_and_set_cache(cng)
 726   end
 727
 728   # helper to handle the block given only an actor's AP id
 729   def block(blocker, %{ap_id: ap_id}) do
 730     block(blocker, User.get_by_ap_id(ap_id))
 731   end
 732
 733   def unblock(blocker, %{ap_id: ap_id}) do
 734     info_cng =
 735       blocker.info
 736       |> User.Info.remove_from_block(ap_id)
 737
 738     cng =
 739       change(blocker)
 740       |> put_embed(:info, info_cng)
 741
 742     update_and_set_cache(cng)
 743   end
 744
 745   def blocks?(user, %{ap_id: ap_id}) do
 746     blocks = user.info.blocks
 747     domain_blocks = user.info.domain_blocks
 748     %{host: host} = URI.parse(ap_id)
 749
 750     Enum.member?(blocks, ap_id) ||
 751       Enum.any?(domain_blocks, fn domain ->
 752         host == domain
 753       end)
 754   end
 755
 756   def blocked_users(user),
 757     do: Repo.all(from(u in User, where: u.ap_id in ^user.info.blocks))
 758
 759   def block_domain(user, domain) do
 760     info_cng =
 761       user.info
 762       |> User.Info.add_to_domain_block(domain)
 763
 764     cng =
 765       change(user)
 766       |> put_embed(:info, info_cng)
 767
 768     update_and_set_cache(cng)
 769   end
 770
 771   def unblock_domain(user, domain) do
 772     info_cng =
 773       user.info
 774       |> User.Info.remove_from_domain_block(domain)
 775
 776     cng =
 777       change(user)
 778       |> put_embed(:info, info_cng)
 779
 780     update_and_set_cache(cng)
 781   end
 782
 783   def local_user_query() do
 784     from(
 785       u in User,
 786       where: u.local == true,
 787       where: not is_nil(u.nickname)
 788     )
 789   end
 790
 791   def moderator_user_query() do
 792     from(
 793       u in User,
 794       where: u.local == true,
 795       where: fragment("?->'is_moderator' @> 'true'", u.info)
 796     )
 797   end
 798
 799   def deactivate(%User{} = user, status \\ true) do
 800     info_cng = User.Info.set_activation_status(user.info, status)
 801
 802     cng =
 803       change(user)
 804       |> put_embed(:info, info_cng)
 805
 806     update_and_set_cache(cng)
 807   end
 808
 809   def delete(%User{} = user) do
 810     {:ok, user} = User.deactivate(user)
 811
 812     # Remove all relationships
 813     {:ok, followers} = User.get_followers(user)
 814
 815     followers
 816     |> Enum.each(fn follower -> User.unfollow(follower, user) end)
 817
 818     {:ok, friends} = User.get_friends(user)
 819
 820     friends
 821     |> Enum.each(fn followed -> User.unfollow(user, followed) end)
 822
 823     query = from(a in Activity, where: a.actor == ^user.ap_id)
 824
 825     Repo.all(query)
 826     |> Enum.each(fn activity ->
 827       case activity.data["type"] do
 828         "Create" ->
 829           ActivityPub.delete(Object.normalize(activity.data["object"]))
 830
 831         # TODO: Do something with likes, follows, repeats.
 832         _ ->
 833           "Doing nothing"
 834       end
 835     end)
 836
 837     {:ok, user}
 838   end
 839
 840   def html_filter_policy(%User{info: %{no_rich_text: true}}) do
 841     Pleroma.HTML.Scrubber.TwitterText
 842   end
 843
 844   @default_scrubbers Pleroma.Config.get([:markup, :scrub_policy])
 845
 846   def html_filter_policy(_), do: @default_scrubbers
 847
 848   def get_or_fetch_by_ap_id(ap_id) do
 849     user = get_by_ap_id(ap_id)
 850
 851     if !is_nil(user) and !User.needs_update?(user) do
 852       user
 853     else
 854       ap_try = ActivityPub.make_user_from_ap_id(ap_id)
 855
 856       case ap_try do
 857         {:ok, user} ->
 858           user
 859
 860         _ ->
 861           case OStatus.make_user(ap_id) do
 862             {:ok, user} -> user
 863             _ -> {:error, "Could not fetch by AP id"}
 864           end
 865       end
 866     end
 867   end
 868
 869   def get_or_create_instance_user do
 870     relay_uri = "#{Pleroma.Web.Endpoint.url()}/relay"
 871
 872     if user = get_by_ap_id(relay_uri) do
 873       user
 874     else
 875       changes =
 876         %User{info: %User.Info{}}
 877         |> cast(%{}, [:ap_id, :nickname, :local])
 878         |> put_change(:ap_id, relay_uri)
 879         |> put_change(:nickname, nil)
 880         |> put_change(:local, true)
 881         |> put_change(:follower_address, relay_uri <> "/followers")
 882
 883       {:ok, user} = Repo.insert(changes)
 884       user
 885     end
 886   end
 887
 888   # AP style
 889   def public_key_from_info(%{
 890         source_data: %{"publicKey" => %{"publicKeyPem" => public_key_pem}}
 891       }) do
 892     key =
 893       public_key_pem
 894       |> :public_key.pem_decode()
 895       |> hd()
 896       |> :public_key.pem_entry_decode()
 897
 898     {:ok, key}
 899   end
 900
 901   # OStatus Magic Key
 902   def public_key_from_info(%{magic_key: magic_key}) do
 903     {:ok, Pleroma.Web.Salmon.decode_key(magic_key)}
 904   end
 905
 906   def get_public_key_for_ap_id(ap_id) do
 907     with %User{} = user <- get_or_fetch_by_ap_id(ap_id),
 908          {:ok, public_key} <- public_key_from_info(user.info) do
 909       {:ok, public_key}
 910     else
 911       _ -> :error
 912     end
 913   end
 914
 915   defp blank?(""), do: nil
 916   defp blank?(n), do: n
 917
 918   def insert_or_update_user(data) do
 919     data =
 920       data
 921       |> Map.put(:name, blank?(data[:name]) || data[:nickname])
 922
 923     cs = User.remote_user_creation(data)
 924
 925     Repo.insert(cs, on_conflict: :replace_all, conflict_target: :nickname)
 926   end
 927
 928   def ap_enabled?(%User{local: true}), do: true
 929   def ap_enabled?(%User{info: info}), do: info.ap_enabled
 930   def ap_enabled?(_), do: false
 931
 932   @doc "Gets or fetch a user by uri or nickname."
 933   @spec get_or_fetch(String.t()) :: User.t()
 934   def get_or_fetch("http" <> _host = uri), do: get_or_fetch_by_ap_id(uri)
 935   def get_or_fetch(nickname), do: get_or_fetch_by_nickname(nickname)
 936
 937   # wait a period of time and return newest version of the User structs
 938   # this is because we have synchronous follow APIs and need to simulate them
 939   # with an async handshake
 940   def wait_and_refresh(_, %User{local: true} = a, %User{local: true} = b) do
 941     with %User{} = a <- Repo.get(User, a.id),
 942          %User{} = b <- Repo.get(User, b.id) do
 943       {:ok, a, b}
 944     else
 945       _e ->
 946         :error
 947     end
 948   end
 949
 950   def wait_and_refresh(timeout, %User{} = a, %User{} = b) do
 951     with :ok <- :timer.sleep(timeout),
 952          %User{} = a <- Repo.get(User, a.id),
 953          %User{} = b <- Repo.get(User, b.id) do
 954       {:ok, a, b}
 955     else
 956       _e ->
 957         :error
 958     end
 959   end
 960
 961   def parse_bio(bio, user \\ %User{info: %{source_data: %{}}})
 962   def parse_bio(nil, _user), do: ""
 963   def parse_bio(bio, _user) when bio == "", do: bio
 964
 965   def parse_bio(bio, user) do
 966     mentions = Formatter.parse_mentions(bio)
 967     tags = Formatter.parse_tags(bio)
 968
 969     emoji =
 970       (user.info.source_data["tag"] || [])
 971       |> Enum.filter(fn %{"type" => t} -> t == "Emoji" end)
 972       |> Enum.map(fn %{"icon" => %{"url" => url}, "name" => name} ->
 973         {String.trim(name, ":"), url}
 974       end)
 975
 976     bio
 977     |> CommonUtils.format_input(mentions, tags, "text/plain")
 978     |> Formatter.emojify(emoji)
 979   end
 980
 981   def tag(user_identifiers, tags) when is_list(user_identifiers) do
 982     Repo.transaction(fn ->
 983       for user_identifier <- user_identifiers, do: tag(user_identifier, tags)
 984     end)
 985   end
 986
 987   def tag(nickname, tags) when is_binary(nickname),
 988     do: tag(User.get_by_nickname(nickname), tags)
 989
 990   def tag(%User{} = user, tags),
 991     do: update_tags(user, Enum.uniq((user.tags || []) ++ normalize_tags(tags)))
 992
 993   def untag(user_identifiers, tags) when is_list(user_identifiers) do
 994     Repo.transaction(fn ->
 995       for user_identifier <- user_identifiers, do: untag(user_identifier, tags)
 996     end)
 997   end
 998
 999   def untag(nickname, tags) when is_binary(nickname),
1000     do: untag(User.get_by_nickname(nickname), tags)
1001
1002   def untag(%User{} = user, tags),
1003     do: update_tags(user, (user.tags || []) -- normalize_tags(tags))
1004
1005   defp update_tags(%User{} = user, new_tags) do
1006     {:ok, updated_user} =
1007       user
1008       |> change(%{tags: new_tags})
1009       |> Repo.update()
1010
1011     updated_user
1012   end
1013
1014   defp normalize_tags(tags) do
1015     [tags]
1016     |> List.flatten()
1017     |> Enum.map(&String.downcase(&1))
1018   end
1019
1020   defp local_nickname_regex() do
1021     if Pleroma.Config.get([:instance, :extended_nickname_format]) do
1022       @extended_local_nickname_regex
1023     else
1024       @strict_local_nickname_regex
1025     end
1026   end
1027 end