git.squeep.com Git - akkoma/blob - lib/pleroma/user.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.User do
   6   use Ecto.Schema
   7
   8   import Ecto.{Changeset, Query}
   9   alias Pleroma.{Repo, User, Object, Web, Activity, Notification}
  10   alias Comeonin.Pbkdf2
  11   alias Pleroma.Formatter
  12   alias Pleroma.Web.CommonAPI.Utils, as: CommonUtils
  13   alias Pleroma.Web.{OStatus, Websub, OAuth}
  14   alias Pleroma.Web.ActivityPub.{Utils, ActivityPub}
  15
  16   require Logger
  17
  18   @type t :: %__MODULE__{}
  19
  20   @email_regex ~r/^[a-zA-Z0-9.!#$%&'*+\/=?^_`{|}~-]+@[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?(?:\.[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?)*$/
  21
  22   @strict_local_nickname_regex ~r/^[a-zA-Z\d]+$/
  23   @extended_local_nickname_regex ~r/^[a-zA-Z\d_-]+$/
  24
  25   schema "users" do
  26     field(:bio, :string)
  27     field(:email, :string)
  28     field(:name, :string)
  29     field(:nickname, :string)
  30     field(:password_hash, :string)
  31     field(:password, :string, virtual: true)
  32     field(:password_confirmation, :string, virtual: true)
  33     field(:following, {:array, :string}, default: [])
  34     field(:ap_id, :string)
  35     field(:avatar, :map)
  36     field(:local, :boolean, default: true)
  37     field(:follower_address, :string)
  38     field(:search_distance, :float, virtual: true)
  39     field(:tags, {:array, :string}, default: [])
  40     field(:last_refreshed_at, :naive_datetime)
  41     has_many(:notifications, Notification)
  42     embeds_one(:info, Pleroma.User.Info)
  43
  44     timestamps()
  45   end
  46
  47   def auth_active?(%User{local: false}), do: false
  48
  49   def auth_active?(%User{info: %User.Info{confirmation_pending: false}}), do: true
  50
  51   def auth_active?(%User{info: %User.Info{confirmation_pending: true}}),
  52     do: !Pleroma.Config.get([:instance, :account_activation_required])
  53
  54   def auth_active?(_), do: false
  55
  56   def visible_for?(user, for_user \\ nil)
  57
  58   def visible_for?(%User{id: user_id}, %User{id: for_id}) when user_id == for_id, do: true
  59
  60   def visible_for?(%User{} = user, for_user) do
  61     auth_active?(user) || superuser?(for_user)
  62   end
  63
  64   def visible_for?(_, _), do: false
  65
  66   def superuser?(%User{info: %User.Info{} = info}), do: User.Info.superuser?(info)
  67   def superuser?(_), do: false
  68
  69   def avatar_url(user) do
  70     case user.avatar do
  71       %{"url" => [%{"href" => href} | _]} -> href
  72       _ -> "#{Web.base_url()}/images/avi.png"
  73     end
  74   end
  75
  76   def banner_url(user) do
  77     case user.info.banner do
  78       %{"url" => [%{"href" => href} | _]} -> href
  79       _ -> "#{Web.base_url()}/images/banner.png"
  80     end
  81   end
  82
  83   def profile_url(%User{info: %{source_data: %{"url" => url}}}), do: url
  84   def profile_url(%User{ap_id: ap_id}), do: ap_id
  85   def profile_url(_), do: nil
  86
  87   def ap_id(%User{nickname: nickname}) do
  88     "#{Web.base_url()}/users/#{nickname}"
  89   end
  90
  91   def ap_followers(%User{} = user) do
  92     "#{ap_id(user)}/followers"
  93   end
  94
  95   def follow_changeset(struct, params \\ %{}) do
  96     struct
  97     |> cast(params, [:following])
  98     |> validate_required([:following])
  99   end
 100
 101   def user_info(%User{} = user) do
 102     oneself = if user.local, do: 1, else: 0
 103
 104     %{
 105       following_count: length(user.following) - oneself,
 106       note_count: user.info.note_count,
 107       follower_count: user.info.follower_count,
 108       locked: user.info.locked,
 109       confirmation_pending: user.info.confirmation_pending,
 110       default_scope: user.info.default_scope
 111     }
 112   end
 113
 114   def remote_user_creation(params) do
 115     params =
 116       params
 117       |> Map.put(:info, params[:info] || %{})
 118
 119     info_cng = User.Info.remote_user_creation(%User.Info{}, params[:info])
 120
 121     changes =
 122       %User{}
 123       |> cast(params, [:bio, :name, :ap_id, :nickname, :avatar])
 124       |> validate_required([:name, :ap_id])
 125       |> unique_constraint(:nickname)
 126       |> validate_format(:nickname, @email_regex)
 127       |> validate_length(:bio, max: 5000)
 128       |> validate_length(:name, max: 100)
 129       |> put_change(:local, false)
 130       |> put_embed(:info, info_cng)
 131
 132     if changes.valid? do
 133       case info_cng.changes[:source_data] do
 134         %{"followers" => followers} ->
 135           changes
 136           |> put_change(:follower_address, followers)
 137
 138         _ ->
 139           followers = User.ap_followers(%User{nickname: changes.changes[:nickname]})
 140
 141           changes
 142           |> put_change(:follower_address, followers)
 143       end
 144     else
 145       changes
 146     end
 147   end
 148
 149   def update_changeset(struct, params \\ %{}) do
 150     struct
 151     |> cast(params, [:bio, :name, :avatar])
 152     |> unique_constraint(:nickname)
 153     |> validate_format(:nickname, local_nickname_regex())
 154     |> validate_length(:bio, max: 5000)
 155     |> validate_length(:name, min: 1, max: 100)
 156   end
 157
 158   def upgrade_changeset(struct, params \\ %{}) do
 159     params =
 160       params
 161       |> Map.put(:last_refreshed_at, NaiveDateTime.utc_now())
 162
 163     info_cng =
 164       struct.info
 165       |> User.Info.user_upgrade(params[:info])
 166
 167     struct
 168     |> cast(params, [:bio, :name, :follower_address, :avatar, :last_refreshed_at])
 169     |> unique_constraint(:nickname)
 170     |> validate_format(:nickname, local_nickname_regex())
 171     |> validate_length(:bio, max: 5000)
 172     |> validate_length(:name, max: 100)
 173     |> put_embed(:info, info_cng)
 174   end
 175
 176   def password_update_changeset(struct, params) do
 177     changeset =
 178       struct
 179       |> cast(params, [:password, :password_confirmation])
 180       |> validate_required([:password, :password_confirmation])
 181       |> validate_confirmation(:password)
 182
 183     OAuth.Token.delete_user_tokens(struct)
 184     OAuth.Authorization.delete_user_authorizations(struct)
 185
 186     if changeset.valid? do
 187       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 188
 189       changeset
 190       |> put_change(:password_hash, hashed)
 191     else
 192       changeset
 193     end
 194   end
 195
 196   def reset_password(user, data) do
 197     update_and_set_cache(password_update_changeset(user, data))
 198   end
 199
 200   def register_changeset(struct, params \\ %{}, opts \\ []) do
 201     confirmation_status =
 202       if opts[:confirmed] || !Pleroma.Config.get([:instance, :account_activation_required]) do
 203         :confirmed
 204       else
 205         :unconfirmed
 206       end
 207
 208     info_change = User.Info.confirmation_changeset(%User.Info{}, confirmation_status)
 209
 210     changeset =
 211       struct
 212       |> cast(params, [:bio, :email, :name, :nickname, :password, :password_confirmation])
 213       |> validate_required([:email, :name, :nickname, :password, :password_confirmation])
 214       |> validate_confirmation(:password)
 215       |> unique_constraint(:email)
 216       |> unique_constraint(:nickname)
 217       |> validate_exclusion(:nickname, Pleroma.Config.get([Pleroma.User, :restricted_nicknames]))
 218       |> validate_format(:nickname, local_nickname_regex())
 219       |> validate_format(:email, @email_regex)
 220       |> validate_length(:bio, max: 1000)
 221       |> validate_length(:name, min: 1, max: 100)
 222       |> put_change(:info, info_change)
 223
 224     if changeset.valid? do
 225       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 226       ap_id = User.ap_id(%User{nickname: changeset.changes[:nickname]})
 227       followers = User.ap_followers(%User{nickname: changeset.changes[:nickname]})
 228
 229       changeset
 230       |> put_change(:password_hash, hashed)
 231       |> put_change(:ap_id, ap_id)
 232       |> put_change(:following, [followers])
 233       |> put_change(:follower_address, followers)
 234     else
 235       changeset
 236     end
 237   end
 238
 239   @doc "Inserts provided changeset, performs post-registration actions (confirmation email sending etc.)"
 240   def register(%Ecto.Changeset{} = changeset) do
 241     with {:ok, user} <- Repo.insert(changeset),
 242          {:ok, _} = try_send_confirmation_email(user) do
 243       {:ok, user}
 244     end
 245   end
 246
 247   def try_send_confirmation_email(%User{} = user) do
 248     if user.info.confirmation_pending &&
 249          Pleroma.Config.get([:instance, :account_activation_required]) do
 250       user
 251       |> Pleroma.UserEmail.account_confirmation_email()
 252       |> Pleroma.Mailer.deliver()
 253     else
 254       {:ok, :noop}
 255     end
 256   end
 257
 258   def needs_update?(%User{local: true}), do: false
 259
 260   def needs_update?(%User{local: false, last_refreshed_at: nil}), do: true
 261
 262   def needs_update?(%User{local: false} = user) do
 263     NaiveDateTime.diff(NaiveDateTime.utc_now(), user.last_refreshed_at) >= 86400
 264   end
 265
 266   def needs_update?(_), do: true
 267
 268   def maybe_direct_follow(%User{} = follower, %User{local: true, info: %{locked: true}}) do
 269     {:ok, follower}
 270   end
 271
 272   def maybe_direct_follow(%User{} = follower, %User{local: true} = followed) do
 273     follow(follower, followed)
 274   end
 275
 276   def maybe_direct_follow(%User{} = follower, %User{} = followed) do
 277     if not User.ap_enabled?(followed) do
 278       follow(follower, followed)
 279     else
 280       {:ok, follower}
 281     end
 282   end
 283
 284   def maybe_follow(%User{} = follower, %User{info: _info} = followed) do
 285     if not following?(follower, followed) do
 286       follow(follower, followed)
 287     else
 288       {:ok, follower}
 289     end
 290   end
 291
 292   def follow(%User{} = follower, %User{info: info} = followed) do
 293     user_config = Application.get_env(:pleroma, :user)
 294     deny_follow_blocked = Keyword.get(user_config, :deny_follow_blocked)
 295
 296     ap_followers = followed.follower_address
 297
 298     cond do
 299       following?(follower, followed) or info.deactivated ->
 300         {:error, "Could not follow user: #{followed.nickname} is already on your list."}
 301
 302       deny_follow_blocked and blocks?(followed, follower) ->
 303         {:error, "Could not follow user: #{followed.nickname} blocked you."}
 304
 305       true ->
 306         if !followed.local && follower.local && !ap_enabled?(followed) do
 307           Websub.subscribe(follower, followed)
 308         end
 309
 310         following =
 311           [ap_followers | follower.following]
 312           |> Enum.uniq()
 313
 314         follower =
 315           follower
 316           |> follow_changeset(%{following: following})
 317           |> update_and_set_cache
 318
 319         {:ok, _} = update_follower_count(followed)
 320
 321         follower
 322     end
 323   end
 324
 325   def unfollow(%User{} = follower, %User{} = followed) do
 326     ap_followers = followed.follower_address
 327
 328     if following?(follower, followed) and follower.ap_id != followed.ap_id do
 329       following =
 330         follower.following
 331         |> List.delete(ap_followers)
 332
 333       {:ok, follower} =
 334         follower
 335         |> follow_changeset(%{following: following})
 336         |> update_and_set_cache
 337
 338       {:ok, followed} = update_follower_count(followed)
 339
 340       {:ok, follower, Utils.fetch_latest_follow(follower, followed)}
 341     else
 342       {:error, "Not subscribed!"}
 343     end
 344   end
 345
 346   @spec following?(User.t(), User.t()) :: boolean
 347   def following?(%User{} = follower, %User{} = followed) do
 348     Enum.member?(follower.following, followed.follower_address)
 349   end
 350
 351   def follow_import(%User{} = follower, followed_identifiers)
 352       when is_list(followed_identifiers) do
 353     Enum.map(
 354       followed_identifiers,
 355       fn followed_identifier ->
 356         with %User{} = followed <- get_or_fetch(followed_identifier),
 357              {:ok, follower} <- maybe_direct_follow(follower, followed),
 358              {:ok, _} <- ActivityPub.follow(follower, followed) do
 359           followed
 360         else
 361           err ->
 362             Logger.debug("follow_import failed for #{followed_identifier} with: #{inspect(err)}")
 363             err
 364         end
 365       end
 366     )
 367   end
 368
 369   def locked?(%User{} = user) do
 370     user.info.locked || false
 371   end
 372
 373   def get_by_ap_id(ap_id) do
 374     Repo.get_by(User, ap_id: ap_id)
 375   end
 376
 377   # This is mostly an SPC migration fix. This guesses the user nickname (by taking the last part of the ap_id and the domain) and tries to get that user
 378   def get_by_guessed_nickname(ap_id) do
 379     domain = URI.parse(ap_id).host
 380     name = List.last(String.split(ap_id, "/"))
 381     nickname = "#{name}@#{domain}"
 382
 383     get_by_nickname(nickname)
 384   end
 385
 386   def update_and_set_cache(changeset) do
 387     with {:ok, user} <- Repo.update(changeset) do
 388       Cachex.put(:user_cache, "ap_id:#{user.ap_id}", user)
 389       Cachex.put(:user_cache, "nickname:#{user.nickname}", user)
 390       Cachex.put(:user_cache, "user_info:#{user.id}", user_info(user))
 391       {:ok, user}
 392     else
 393       e -> e
 394     end
 395   end
 396
 397   def invalidate_cache(user) do
 398     Cachex.del(:user_cache, "ap_id:#{user.ap_id}")
 399     Cachex.del(:user_cache, "nickname:#{user.nickname}")
 400     Cachex.del(:user_cache, "user_info:#{user.id}")
 401   end
 402
 403   def get_cached_by_ap_id(ap_id) do
 404     key = "ap_id:#{ap_id}"
 405     Cachex.fetch!(:user_cache, key, fn _ -> get_by_ap_id(ap_id) end)
 406   end
 407
 408   def get_cached_by_nickname(nickname) do
 409     key = "nickname:#{nickname}"
 410     Cachex.fetch!(:user_cache, key, fn _ -> get_or_fetch_by_nickname(nickname) end)
 411   end
 412
 413   def get_by_nickname(nickname) do
 414     Repo.get_by(User, nickname: nickname) ||
 415       if Regex.match?(~r(@#{Pleroma.Web.Endpoint.host()})i, nickname) do
 416         [local_nickname, _] = String.split(nickname, "@")
 417         Repo.get_by(User, nickname: local_nickname)
 418       end
 419   end
 420
 421   def get_by_nickname_or_email(nickname_or_email) do
 422     case user = Repo.get_by(User, nickname: nickname_or_email) do
 423       %User{} -> user
 424       nil -> Repo.get_by(User, email: nickname_or_email)
 425     end
 426   end
 427
 428   def get_cached_user_info(user) do
 429     key = "user_info:#{user.id}"
 430     Cachex.fetch!(:user_cache, key, fn _ -> user_info(user) end)
 431   end
 432
 433   def fetch_by_nickname(nickname) do
 434     ap_try = ActivityPub.make_user_from_nickname(nickname)
 435
 436     case ap_try do
 437       {:ok, user} -> {:ok, user}
 438       _ -> OStatus.make_user(nickname)
 439     end
 440   end
 441
 442   def get_or_fetch_by_nickname(nickname) do
 443     with %User{} = user <- get_by_nickname(nickname) do
 444       user
 445     else
 446       _e ->
 447         with [_nick, _domain] <- String.split(nickname, "@"),
 448              {:ok, user} <- fetch_by_nickname(nickname) do
 449           user
 450         else
 451           _e -> nil
 452         end
 453     end
 454   end
 455
 456   def get_followers_query(%User{id: id, follower_address: follower_address}) do
 457     from(
 458       u in User,
 459       where: fragment("? <@ ?", ^[follower_address], u.following),
 460       where: u.id != ^id
 461     )
 462   end
 463
 464   def get_followers(user) do
 465     q = get_followers_query(user)
 466
 467     {:ok, Repo.all(q)}
 468   end
 469
 470   def get_friends_query(%User{id: id, following: following}) do
 471     from(
 472       u in User,
 473       where: u.follower_address in ^following,
 474       where: u.id != ^id
 475     )
 476   end
 477
 478   def get_friends(user) do
 479     q = get_friends_query(user)
 480
 481     {:ok, Repo.all(q)}
 482   end
 483
 484   def get_follow_requests_query(%User{} = user) do
 485     from(
 486       a in Activity,
 487       where:
 488         fragment(
 489           "? ->> 'type' = 'Follow'",
 490           a.data
 491         ),
 492       where:
 493         fragment(
 494           "? ->> 'state' = 'pending'",
 495           a.data
 496         ),
 497       where:
 498         fragment(
 499           "? @> ?",
 500           a.data,
 501           ^%{"object" => user.ap_id}
 502         )
 503     )
 504   end
 505
 506   def get_follow_requests(%User{} = user) do
 507     q = get_follow_requests_query(user)
 508     reqs = Repo.all(q)
 509
 510     users =
 511       Enum.map(reqs, fn req -> req.actor end)
 512       |> Enum.uniq()
 513       |> Enum.map(fn ap_id -> get_by_ap_id(ap_id) end)
 514       |> Enum.filter(fn u -> !is_nil(u) end)
 515       |> Enum.filter(fn u -> !following?(u, user) end)
 516
 517     {:ok, users}
 518   end
 519
 520   def increase_note_count(%User{} = user) do
 521     info_cng = User.Info.add_to_note_count(user.info, 1)
 522
 523     cng =
 524       change(user)
 525       |> put_embed(:info, info_cng)
 526
 527     update_and_set_cache(cng)
 528   end
 529
 530   def decrease_note_count(%User{} = user) do
 531     info_cng = User.Info.add_to_note_count(user.info, -1)
 532
 533     cng =
 534       change(user)
 535       |> put_embed(:info, info_cng)
 536
 537     update_and_set_cache(cng)
 538   end
 539
 540   def update_note_count(%User{} = user) do
 541     note_count_query =
 542       from(
 543         a in Object,
 544         where: fragment("?->>'actor' = ? and ?->>'type' = 'Note'", a.data, ^user.ap_id, a.data),
 545         select: count(a.id)
 546       )
 547
 548     note_count = Repo.one(note_count_query)
 549
 550     info_cng = User.Info.set_note_count(user.info, note_count)
 551
 552     cng =
 553       change(user)
 554       |> put_embed(:info, info_cng)
 555
 556     update_and_set_cache(cng)
 557   end
 558
 559   def update_follower_count(%User{} = user) do
 560     follower_count_query =
 561       from(
 562         u in User,
 563         where: ^user.follower_address in u.following,
 564         where: u.id != ^user.id,
 565         select: count(u.id)
 566       )
 567
 568     follower_count = Repo.one(follower_count_query)
 569
 570     info_cng =
 571       user.info
 572       |> User.Info.set_follower_count(follower_count)
 573
 574     cng =
 575       change(user)
 576       |> put_embed(:info, info_cng)
 577
 578     update_and_set_cache(cng)
 579   end
 580
 581   def get_users_from_set_query(ap_ids, false) do
 582     from(
 583       u in User,
 584       where: u.ap_id in ^ap_ids
 585     )
 586   end
 587
 588   def get_users_from_set_query(ap_ids, true) do
 589     query = get_users_from_set_query(ap_ids, false)
 590
 591     from(
 592       u in query,
 593       where: u.local == true
 594     )
 595   end
 596
 597   def get_users_from_set(ap_ids, local_only \\ true) do
 598     get_users_from_set_query(ap_ids, local_only)
 599     |> Repo.all()
 600   end
 601
 602   def get_recipients_from_activity(%Activity{recipients: to}) do
 603     query =
 604       from(
 605         u in User,
 606         where: u.ap_id in ^to,
 607         or_where: fragment("? && ?", u.following, ^to)
 608       )
 609
 610     query = from(u in query, where: u.local == true)
 611
 612     Repo.all(query)
 613   end
 614
 615   def search(query, resolve \\ false) do
 616     # strip the beginning @ off if there is a query
 617     query = String.trim_leading(query, "@")
 618
 619     if resolve do
 620       User.get_or_fetch_by_nickname(query)
 621     end
 622
 623     inner =
 624       from(
 625         u in User,
 626         select_merge: %{
 627           search_distance:
 628             fragment(
 629               "? <-> (? || coalesce(?, ''))",
 630               ^query,
 631               u.nickname,
 632               u.name
 633             )
 634         },
 635         where: not is_nil(u.nickname)
 636       )
 637
 638     q =
 639       from(
 640         s in subquery(inner),
 641         order_by: s.search_distance,
 642         limit: 20
 643       )
 644
 645     Repo.all(q)
 646   end
 647
 648   def blocks_import(%User{} = blocker, blocked_identifiers) when is_list(blocked_identifiers) do
 649     Enum.map(
 650       blocked_identifiers,
 651       fn blocked_identifier ->
 652         with %User{} = blocked <- get_or_fetch(blocked_identifier),
 653              {:ok, blocker} <- block(blocker, blocked),
 654              {:ok, _} <- ActivityPub.block(blocker, blocked) do
 655           blocked
 656         else
 657           err ->
 658             Logger.debug("blocks_import failed for #{blocked_identifier} with: #{inspect(err)}")
 659             err
 660         end
 661       end
 662     )
 663   end
 664
 665   def block(blocker, %User{ap_id: ap_id} = blocked) do
 666     # sever any follow relationships to prevent leaks per activitypub (Pleroma issue #213)
 667     blocker =
 668       if following?(blocker, blocked) do
 669         {:ok, blocker, _} = unfollow(blocker, blocked)
 670         blocker
 671       else
 672         blocker
 673       end
 674
 675     if following?(blocked, blocker) do
 676       unfollow(blocked, blocker)
 677     end
 678
 679     info_cng =
 680       blocker.info
 681       |> User.Info.add_to_block(ap_id)
 682
 683     cng =
 684       change(blocker)
 685       |> put_embed(:info, info_cng)
 686
 687     update_and_set_cache(cng)
 688   end
 689
 690   # helper to handle the block given only an actor's AP id
 691   def block(blocker, %{ap_id: ap_id}) do
 692     block(blocker, User.get_by_ap_id(ap_id))
 693   end
 694
 695   def unblock(blocker, %{ap_id: ap_id}) do
 696     info_cng =
 697       blocker.info
 698       |> User.Info.remove_from_block(ap_id)
 699
 700     cng =
 701       change(blocker)
 702       |> put_embed(:info, info_cng)
 703
 704     update_and_set_cache(cng)
 705   end
 706
 707   def blocks?(user, %{ap_id: ap_id}) do
 708     blocks = user.info.blocks
 709     domain_blocks = user.info.domain_blocks
 710     %{host: host} = URI.parse(ap_id)
 711
 712     Enum.member?(blocks, ap_id) ||
 713       Enum.any?(domain_blocks, fn domain ->
 714         host == domain
 715       end)
 716   end
 717
 718   def blocked_users(user),
 719     do: Repo.all(from(u in User, where: u.ap_id in ^user.info.blocks))
 720
 721   def block_domain(user, domain) do
 722     info_cng =
 723       user.info
 724       |> User.Info.add_to_domain_block(domain)
 725
 726     cng =
 727       change(user)
 728       |> put_embed(:info, info_cng)
 729
 730     update_and_set_cache(cng)
 731   end
 732
 733   def unblock_domain(user, domain) do
 734     info_cng =
 735       user.info
 736       |> User.Info.remove_from_domain_block(domain)
 737
 738     cng =
 739       change(user)
 740       |> put_embed(:info, info_cng)
 741
 742     update_and_set_cache(cng)
 743   end
 744
 745   def local_user_query() do
 746     from(
 747       u in User,
 748       where: u.local == true,
 749       where: not is_nil(u.nickname)
 750     )
 751   end
 752
 753   def moderator_user_query() do
 754     from(
 755       u in User,
 756       where: u.local == true,
 757       where: fragment("?->'is_moderator' @> 'true'", u.info)
 758     )
 759   end
 760
 761   def deactivate(%User{} = user, status \\ true) do
 762     info_cng = User.Info.set_activation_status(user.info, status)
 763
 764     cng =
 765       change(user)
 766       |> put_embed(:info, info_cng)
 767
 768     update_and_set_cache(cng)
 769   end
 770
 771   def delete(%User{} = user) do
 772     {:ok, user} = User.deactivate(user)
 773
 774     # Remove all relationships
 775     {:ok, followers} = User.get_followers(user)
 776
 777     followers
 778     |> Enum.each(fn follower -> User.unfollow(follower, user) end)
 779
 780     {:ok, friends} = User.get_friends(user)
 781
 782     friends
 783     |> Enum.each(fn followed -> User.unfollow(user, followed) end)
 784
 785     query = from(a in Activity, where: a.actor == ^user.ap_id)
 786
 787     Repo.all(query)
 788     |> Enum.each(fn activity ->
 789       case activity.data["type"] do
 790         "Create" ->
 791           ActivityPub.delete(Object.normalize(activity.data["object"]))
 792
 793         # TODO: Do something with likes, follows, repeats.
 794         _ ->
 795           "Doing nothing"
 796       end
 797     end)
 798
 799     {:ok, user}
 800   end
 801
 802   def html_filter_policy(%User{info: %{no_rich_text: true}}) do
 803     Pleroma.HTML.Scrubber.TwitterText
 804   end
 805
 806   @default_scrubbers Pleroma.Config.get([:markup, :scrub_policy])
 807
 808   def html_filter_policy(_), do: @default_scrubbers
 809
 810   def get_or_fetch_by_ap_id(ap_id) do
 811     user = get_by_ap_id(ap_id)
 812
 813     if !is_nil(user) and !User.needs_update?(user) do
 814       user
 815     else
 816       ap_try = ActivityPub.make_user_from_ap_id(ap_id)
 817
 818       case ap_try do
 819         {:ok, user} ->
 820           user
 821
 822         _ ->
 823           case OStatus.make_user(ap_id) do
 824             {:ok, user} -> user
 825             _ -> {:error, "Could not fetch by AP id"}
 826           end
 827       end
 828     end
 829   end
 830
 831   def get_or_create_instance_user do
 832     relay_uri = "#{Pleroma.Web.Endpoint.url()}/relay"
 833
 834     if user = get_by_ap_id(relay_uri) do
 835       user
 836     else
 837       changes =
 838         %User{info: %User.Info{}}
 839         |> cast(%{}, [:ap_id, :nickname, :local])
 840         |> put_change(:ap_id, relay_uri)
 841         |> put_change(:nickname, nil)
 842         |> put_change(:local, true)
 843         |> put_change(:follower_address, relay_uri <> "/followers")
 844
 845       {:ok, user} = Repo.insert(changes)
 846       user
 847     end
 848   end
 849
 850   # AP style
 851   def public_key_from_info(%{
 852         source_data: %{"publicKey" => %{"publicKeyPem" => public_key_pem}}
 853       }) do
 854     key =
 855       public_key_pem
 856       |> :public_key.pem_decode()
 857       |> hd()
 858       |> :public_key.pem_entry_decode()
 859
 860     {:ok, key}
 861   end
 862
 863   # OStatus Magic Key
 864   def public_key_from_info(%{magic_key: magic_key}) do
 865     {:ok, Pleroma.Web.Salmon.decode_key(magic_key)}
 866   end
 867
 868   def get_public_key_for_ap_id(ap_id) do
 869     with %User{} = user <- get_or_fetch_by_ap_id(ap_id),
 870          {:ok, public_key} <- public_key_from_info(user.info) do
 871       {:ok, public_key}
 872     else
 873       _ -> :error
 874     end
 875   end
 876
 877   defp blank?(""), do: nil
 878   defp blank?(n), do: n
 879
 880   def insert_or_update_user(data) do
 881     data =
 882       data
 883       |> Map.put(:name, blank?(data[:name]) || data[:nickname])
 884
 885     cs = User.remote_user_creation(data)
 886
 887     Repo.insert(cs, on_conflict: :replace_all, conflict_target: :nickname)
 888   end
 889
 890   def ap_enabled?(%User{local: true}), do: true
 891   def ap_enabled?(%User{info: info}), do: info.ap_enabled
 892   def ap_enabled?(_), do: false
 893
 894   @doc "Gets or fetch a user by uri or nickname."
 895   @spec get_or_fetch(String.t()) :: User.t()
 896   def get_or_fetch("http" <> _host = uri), do: get_or_fetch_by_ap_id(uri)
 897   def get_or_fetch(nickname), do: get_or_fetch_by_nickname(nickname)
 898
 899   # wait a period of time and return newest version of the User structs
 900   # this is because we have synchronous follow APIs and need to simulate them
 901   # with an async handshake
 902   def wait_and_refresh(_, %User{local: true} = a, %User{local: true} = b) do
 903     with %User{} = a <- Repo.get(User, a.id),
 904          %User{} = b <- Repo.get(User, b.id) do
 905       {:ok, a, b}
 906     else
 907       _e ->
 908         :error
 909     end
 910   end
 911
 912   def wait_and_refresh(timeout, %User{} = a, %User{} = b) do
 913     with :ok <- :timer.sleep(timeout),
 914          %User{} = a <- Repo.get(User, a.id),
 915          %User{} = b <- Repo.get(User, b.id) do
 916       {:ok, a, b}
 917     else
 918       _e ->
 919         :error
 920     end
 921   end
 922
 923   def parse_bio(bio, user \\ %User{info: %{source_data: %{}}})
 924   def parse_bio(nil, _user), do: ""
 925   def parse_bio(bio, _user) when bio == "", do: bio
 926
 927   def parse_bio(bio, user) do
 928     mentions = Formatter.parse_mentions(bio)
 929     tags = Formatter.parse_tags(bio)
 930
 931     emoji =
 932       (user.info.source_data["tag"] || [])
 933       |> Enum.filter(fn %{"type" => t} -> t == "Emoji" end)
 934       |> Enum.map(fn %{"icon" => %{"url" => url}, "name" => name} ->
 935         {String.trim(name, ":"), url}
 936       end)
 937
 938     bio
 939     |> CommonUtils.format_input(mentions, tags, "text/plain")
 940     |> Formatter.emojify(emoji)
 941   end
 942
 943   def tag(user_identifiers, tags) when is_list(user_identifiers) do
 944     Repo.transaction(fn ->
 945       for user_identifier <- user_identifiers, do: tag(user_identifier, tags)
 946     end)
 947   end
 948
 949   def tag(nickname, tags) when is_binary(nickname),
 950     do: tag(User.get_by_nickname(nickname), tags)
 951
 952   def tag(%User{} = user, tags),
 953     do: update_tags(user, Enum.uniq((user.tags || []) ++ normalize_tags(tags)))
 954
 955   def untag(user_identifiers, tags) when is_list(user_identifiers) do
 956     Repo.transaction(fn ->
 957       for user_identifier <- user_identifiers, do: untag(user_identifier, tags)
 958     end)
 959   end
 960
 961   def untag(nickname, tags) when is_binary(nickname),
 962     do: untag(User.get_by_nickname(nickname), tags)
 963
 964   def untag(%User{} = user, tags),
 965     do: update_tags(user, (user.tags || []) -- normalize_tags(tags))
 966
 967   defp update_tags(%User{} = user, new_tags) do
 968     {:ok, updated_user} =
 969       user
 970       |> change(%{tags: new_tags})
 971       |> Repo.update()
 972
 973     updated_user
 974   end
 975
 976   defp normalize_tags(tags) do
 977     [tags]
 978     |> List.flatten()
 979     |> Enum.map(&String.downcase(&1))
 980   end
 981
 982   defp local_nickname_regex() do
 983     if Pleroma.Config.get([:instance, :extended_nickname_format]) do
 984       @extended_local_nickname_regex
 985     else
 986       @strict_local_nickname_regex
 987     end
 988   end
 989 end