git.squeep.com Git - akkoma/blob - lib/pleroma/user.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.User do
   6   use Ecto.Schema
   7
   8   import Ecto.{Changeset, Query}
   9   alias Pleroma.{Repo, User, Object, Web, Activity, Notification}
  10   alias Comeonin.Pbkdf2
  11   alias Pleroma.Formatter
  12   alias Pleroma.Web.CommonAPI.Utils, as: CommonUtils
  13   alias Pleroma.Web.{OStatus, Websub, OAuth}
  14   alias Pleroma.Web.ActivityPub.{Utils, ActivityPub}
  15
  16   require Logger
  17
  18   @type t :: %__MODULE__{}
  19
  20   @email_regex ~r/^[a-zA-Z0-9.!#$%&'*+\/=?^_`{|}~-]+@[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?(?:\.[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?)*$/
  21
  22   @strict_local_nickname_regex ~r/^[a-zA-Z\d]+$/
  23   @extended_local_nickname_regex ~r/^[a-zA-Z\d_-]+$/
  24
  25   schema "users" do
  26     field(:bio, :string)
  27     field(:email, :string)
  28     field(:name, :string)
  29     field(:nickname, :string)
  30     field(:password_hash, :string)
  31     field(:password, :string, virtual: true)
  32     field(:password_confirmation, :string, virtual: true)
  33     field(:following, {:array, :string}, default: [])
  34     field(:ap_id, :string)
  35     field(:avatar, :map)
  36     field(:local, :boolean, default: true)
  37     field(:follower_address, :string)
  38     field(:search_distance, :float, virtual: true)
  39     field(:tags, {:array, :string}, default: [])
  40     field(:last_refreshed_at, :naive_datetime)
  41     has_many(:notifications, Notification)
  42     embeds_one(:info, Pleroma.User.Info)
  43
  44     timestamps()
  45   end
  46
  47   def auth_active?(%User{} = user) do
  48     (user.info && !user.info.confirmation_pending) ||
  49       !Pleroma.Config.get([:instance, :account_activation_required])
  50   end
  51
  52   def remote_or_auth_active?(%User{} = user), do: !user.local || auth_active?(user)
  53
  54   def visible_for?(%User{} = user, for_user \\ nil) do
  55     User.remote_or_auth_active?(user) || (for_user && for_user.id == user.id) ||
  56       User.superuser?(for_user)
  57   end
  58
  59   def superuser?(nil), do: false
  60   def superuser?(%User{} = user), do: user.info && User.Info.superuser?(user.info)
  61
  62   def avatar_url(user) do
  63     case user.avatar do
  64       %{"url" => [%{"href" => href} | _]} -> href
  65       _ -> "#{Web.base_url()}/images/avi.png"
  66     end
  67   end
  68
  69   def banner_url(user) do
  70     case user.info.banner do
  71       %{"url" => [%{"href" => href} | _]} -> href
  72       _ -> "#{Web.base_url()}/images/banner.png"
  73     end
  74   end
  75
  76   def profile_url(%User{info: %{source_data: %{"url" => url}}}), do: url
  77   def profile_url(%User{ap_id: ap_id}), do: ap_id
  78   def profile_url(_), do: nil
  79
  80   def ap_id(%User{nickname: nickname}) do
  81     "#{Web.base_url()}/users/#{nickname}"
  82   end
  83
  84   def ap_followers(%User{} = user) do
  85     "#{ap_id(user)}/followers"
  86   end
  87
  88   def follow_changeset(struct, params \\ %{}) do
  89     struct
  90     |> cast(params, [:following])
  91     |> validate_required([:following])
  92   end
  93
  94   def user_info(%User{} = user) do
  95     oneself = if user.local, do: 1, else: 0
  96
  97     %{
  98       following_count: length(user.following) - oneself,
  99       note_count: user.info.note_count,
 100       follower_count: user.info.follower_count,
 101       locked: user.info.locked,
 102       confirmation_pending: user.info.confirmation_pending,
 103       default_scope: user.info.default_scope
 104     }
 105   end
 106
 107   def remote_user_creation(params) do
 108     params =
 109       params
 110       |> Map.put(:info, params[:info] || %{})
 111
 112     info_cng = User.Info.remote_user_creation(%User.Info{}, params[:info])
 113
 114     changes =
 115       %User{}
 116       |> cast(params, [:bio, :name, :ap_id, :nickname, :avatar])
 117       |> validate_required([:name, :ap_id])
 118       |> unique_constraint(:nickname)
 119       |> validate_format(:nickname, @email_regex)
 120       |> validate_length(:bio, max: 5000)
 121       |> validate_length(:name, max: 100)
 122       |> put_change(:local, false)
 123       |> put_embed(:info, info_cng)
 124
 125     if changes.valid? do
 126       case info_cng.changes[:source_data] do
 127         %{"followers" => followers} ->
 128           changes
 129           |> put_change(:follower_address, followers)
 130
 131         _ ->
 132           followers = User.ap_followers(%User{nickname: changes.changes[:nickname]})
 133
 134           changes
 135           |> put_change(:follower_address, followers)
 136       end
 137     else
 138       changes
 139     end
 140   end
 141
 142   def update_changeset(struct, params \\ %{}) do
 143     struct
 144     |> cast(params, [:bio, :name, :avatar])
 145     |> unique_constraint(:nickname)
 146     |> validate_format(:nickname, local_nickname_regex())
 147     |> validate_length(:bio, max: 5000)
 148     |> validate_length(:name, min: 1, max: 100)
 149   end
 150
 151   def upgrade_changeset(struct, params \\ %{}) do
 152     params =
 153       params
 154       |> Map.put(:last_refreshed_at, NaiveDateTime.utc_now())
 155
 156     info_cng =
 157       struct.info
 158       |> User.Info.user_upgrade(params[:info])
 159
 160     struct
 161     |> cast(params, [:bio, :name, :follower_address, :avatar, :last_refreshed_at])
 162     |> unique_constraint(:nickname)
 163     |> validate_format(:nickname, local_nickname_regex())
 164     |> validate_length(:bio, max: 5000)
 165     |> validate_length(:name, max: 100)
 166     |> put_embed(:info, info_cng)
 167   end
 168
 169   def password_update_changeset(struct, params) do
 170     changeset =
 171       struct
 172       |> cast(params, [:password, :password_confirmation])
 173       |> validate_required([:password, :password_confirmation])
 174       |> validate_confirmation(:password)
 175
 176     OAuth.Token.delete_user_tokens(struct)
 177     OAuth.Authorization.delete_user_authorizations(struct)
 178
 179     if changeset.valid? do
 180       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 181
 182       changeset
 183       |> put_change(:password_hash, hashed)
 184     else
 185       changeset
 186     end
 187   end
 188
 189   def reset_password(user, data) do
 190     update_and_set_cache(password_update_changeset(user, data))
 191   end
 192
 193   def register_changeset(struct, params \\ %{}, opts \\ []) do
 194     confirmation_status =
 195       if opts[:confirmed] || !Pleroma.Config.get([:instance, :account_activation_required]) do
 196         :confirmed
 197       else
 198         :unconfirmed
 199       end
 200
 201     info_change = User.Info.confirmation_changeset(%User.Info{}, confirmation_status)
 202
 203     changeset =
 204       struct
 205       |> cast(params, [:bio, :email, :name, :nickname, :password, :password_confirmation])
 206       |> validate_required([:email, :name, :nickname, :password, :password_confirmation])
 207       |> validate_confirmation(:password)
 208       |> unique_constraint(:email)
 209       |> unique_constraint(:nickname)
 210       |> validate_exclusion(:nickname, Pleroma.Config.get([Pleroma.User, :restricted_nicknames]))
 211       |> validate_format(:nickname, local_nickname_regex())
 212       |> validate_format(:email, @email_regex)
 213       |> validate_length(:bio, max: 1000)
 214       |> validate_length(:name, min: 1, max: 100)
 215       |> put_change(:info, info_change)
 216
 217     if changeset.valid? do
 218       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 219       ap_id = User.ap_id(%User{nickname: changeset.changes[:nickname]})
 220       followers = User.ap_followers(%User{nickname: changeset.changes[:nickname]})
 221
 222       changeset
 223       |> put_change(:password_hash, hashed)
 224       |> put_change(:ap_id, ap_id)
 225       |> put_change(:following, [followers])
 226       |> put_change(:follower_address, followers)
 227     else
 228       changeset
 229     end
 230   end
 231
 232   @doc "Inserts provided changeset, performs post-registration actions (confirmation email sending etc.)"
 233   def register(%Ecto.Changeset{} = changeset) do
 234     with {:ok, user} <- Repo.insert(changeset),
 235          {:ok, _} = try_send_confirmation_email(user) do
 236       {:ok, user}
 237     end
 238   end
 239
 240   def try_send_confirmation_email(%User{} = user) do
 241     if user.info.confirmation_pending &&
 242          Pleroma.Config.get([:instance, :account_activation_required]) do
 243       user
 244       |> Pleroma.UserEmail.account_confirmation_email()
 245       |> Pleroma.Mailer.deliver()
 246     else
 247       {:ok, :noop}
 248     end
 249   end
 250
 251   def needs_update?(%User{local: true}), do: false
 252
 253   def needs_update?(%User{local: false, last_refreshed_at: nil}), do: true
 254
 255   def needs_update?(%User{local: false} = user) do
 256     NaiveDateTime.diff(NaiveDateTime.utc_now(), user.last_refreshed_at) >= 86400
 257   end
 258
 259   def needs_update?(_), do: true
 260
 261   def maybe_direct_follow(%User{} = follower, %User{local: true, info: %{locked: true}}) do
 262     {:ok, follower}
 263   end
 264
 265   def maybe_direct_follow(%User{} = follower, %User{local: true} = followed) do
 266     follow(follower, followed)
 267   end
 268
 269   def maybe_direct_follow(%User{} = follower, %User{} = followed) do
 270     if not User.ap_enabled?(followed) do
 271       follow(follower, followed)
 272     else
 273       {:ok, follower}
 274     end
 275   end
 276
 277   def maybe_follow(%User{} = follower, %User{info: _info} = followed) do
 278     if not following?(follower, followed) do
 279       follow(follower, followed)
 280     else
 281       {:ok, follower}
 282     end
 283   end
 284
 285   def follow(%User{} = follower, %User{info: info} = followed) do
 286     user_config = Application.get_env(:pleroma, :user)
 287     deny_follow_blocked = Keyword.get(user_config, :deny_follow_blocked)
 288
 289     ap_followers = followed.follower_address
 290
 291     cond do
 292       following?(follower, followed) or info.deactivated ->
 293         {:error, "Could not follow user: #{followed.nickname} is already on your list."}
 294
 295       deny_follow_blocked and blocks?(followed, follower) ->
 296         {:error, "Could not follow user: #{followed.nickname} blocked you."}
 297
 298       true ->
 299         if !followed.local && follower.local && !ap_enabled?(followed) do
 300           Websub.subscribe(follower, followed)
 301         end
 302
 303         following =
 304           [ap_followers | follower.following]
 305           |> Enum.uniq()
 306
 307         follower =
 308           follower
 309           |> follow_changeset(%{following: following})
 310           |> update_and_set_cache
 311
 312         {:ok, _} = update_follower_count(followed)
 313
 314         follower
 315     end
 316   end
 317
 318   def unfollow(%User{} = follower, %User{} = followed) do
 319     ap_followers = followed.follower_address
 320
 321     if following?(follower, followed) and follower.ap_id != followed.ap_id do
 322       following =
 323         follower.following
 324         |> List.delete(ap_followers)
 325
 326       {:ok, follower} =
 327         follower
 328         |> follow_changeset(%{following: following})
 329         |> update_and_set_cache
 330
 331       {:ok, followed} = update_follower_count(followed)
 332
 333       {:ok, follower, Utils.fetch_latest_follow(follower, followed)}
 334     else
 335       {:error, "Not subscribed!"}
 336     end
 337   end
 338
 339   @spec following?(User.t(), User.t()) :: boolean
 340   def following?(%User{} = follower, %User{} = followed) do
 341     Enum.member?(follower.following, followed.follower_address)
 342   end
 343
 344   def follow_import(%User{} = follower, followed_identifiers)
 345       when is_list(followed_identifiers) do
 346     Enum.map(
 347       followed_identifiers,
 348       fn followed_identifier ->
 349         with %User{} = followed <- get_or_fetch(followed_identifier),
 350              {:ok, follower} <- maybe_direct_follow(follower, followed),
 351              {:ok, _} <- ActivityPub.follow(follower, followed) do
 352           followed
 353         else
 354           err ->
 355             Logger.debug("follow_import failed for #{followed_identifier} with: #{inspect(err)}")
 356             err
 357         end
 358       end
 359     )
 360   end
 361
 362   def locked?(%User{} = user) do
 363     user.info.locked || false
 364   end
 365
 366   def get_by_ap_id(ap_id) do
 367     Repo.get_by(User, ap_id: ap_id)
 368   end
 369
 370   # This is mostly an SPC migration fix. This guesses the user nickname (by taking the last part of the ap_id and the domain) and tries to get that user
 371   def get_by_guessed_nickname(ap_id) do
 372     domain = URI.parse(ap_id).host
 373     name = List.last(String.split(ap_id, "/"))
 374     nickname = "#{name}@#{domain}"
 375
 376     get_by_nickname(nickname)
 377   end
 378
 379   def update_and_set_cache(changeset) do
 380     with {:ok, user} <- Repo.update(changeset) do
 381       Cachex.put(:user_cache, "ap_id:#{user.ap_id}", user)
 382       Cachex.put(:user_cache, "nickname:#{user.nickname}", user)
 383       Cachex.put(:user_cache, "user_info:#{user.id}", user_info(user))
 384       {:ok, user}
 385     else
 386       e -> e
 387     end
 388   end
 389
 390   def invalidate_cache(user) do
 391     Cachex.del(:user_cache, "ap_id:#{user.ap_id}")
 392     Cachex.del(:user_cache, "nickname:#{user.nickname}")
 393     Cachex.del(:user_cache, "user_info:#{user.id}")
 394   end
 395
 396   def get_cached_by_ap_id(ap_id) do
 397     key = "ap_id:#{ap_id}"
 398     Cachex.fetch!(:user_cache, key, fn _ -> get_by_ap_id(ap_id) end)
 399   end
 400
 401   def get_cached_by_nickname(nickname) do
 402     key = "nickname:#{nickname}"
 403     Cachex.fetch!(:user_cache, key, fn _ -> get_or_fetch_by_nickname(nickname) end)
 404   end
 405
 406   def get_by_nickname(nickname) do
 407     Repo.get_by(User, nickname: nickname) ||
 408       if Regex.match?(~r(@#{Pleroma.Web.Endpoint.host()})i, nickname) do
 409         [local_nickname, _] = String.split(nickname, "@")
 410         Repo.get_by(User, nickname: local_nickname)
 411       end
 412   end
 413
 414   def get_by_nickname_or_email(nickname_or_email) do
 415     case user = Repo.get_by(User, nickname: nickname_or_email) do
 416       %User{} -> user
 417       nil -> Repo.get_by(User, email: nickname_or_email)
 418     end
 419   end
 420
 421   def get_cached_user_info(user) do
 422     key = "user_info:#{user.id}"
 423     Cachex.fetch!(:user_cache, key, fn _ -> user_info(user) end)
 424   end
 425
 426   def fetch_by_nickname(nickname) do
 427     ap_try = ActivityPub.make_user_from_nickname(nickname)
 428
 429     case ap_try do
 430       {:ok, user} -> {:ok, user}
 431       _ -> OStatus.make_user(nickname)
 432     end
 433   end
 434
 435   def get_or_fetch_by_nickname(nickname) do
 436     with %User{} = user <- get_by_nickname(nickname) do
 437       user
 438     else
 439       _e ->
 440         with [_nick, _domain] <- String.split(nickname, "@"),
 441              {:ok, user} <- fetch_by_nickname(nickname) do
 442           user
 443         else
 444           _e -> nil
 445         end
 446     end
 447   end
 448
 449   def get_followers_query(%User{id: id, follower_address: follower_address}) do
 450     from(
 451       u in User,
 452       where: fragment("? <@ ?", ^[follower_address], u.following),
 453       where: u.id != ^id
 454     )
 455   end
 456
 457   def get_followers(user) do
 458     q = get_followers_query(user)
 459
 460     {:ok, Repo.all(q)}
 461   end
 462
 463   def get_friends_query(%User{id: id, following: following}) do
 464     from(
 465       u in User,
 466       where: u.follower_address in ^following,
 467       where: u.id != ^id
 468     )
 469   end
 470
 471   def get_friends(user) do
 472     q = get_friends_query(user)
 473
 474     {:ok, Repo.all(q)}
 475   end
 476
 477   def get_follow_requests_query(%User{} = user) do
 478     from(
 479       a in Activity,
 480       where:
 481         fragment(
 482           "? ->> 'type' = 'Follow'",
 483           a.data
 484         ),
 485       where:
 486         fragment(
 487           "? ->> 'state' = 'pending'",
 488           a.data
 489         ),
 490       where:
 491         fragment(
 492           "? @> ?",
 493           a.data,
 494           ^%{"object" => user.ap_id}
 495         )
 496     )
 497   end
 498
 499   def get_follow_requests(%User{} = user) do
 500     q = get_follow_requests_query(user)
 501     reqs = Repo.all(q)
 502
 503     users =
 504       Enum.map(reqs, fn req -> req.actor end)
 505       |> Enum.uniq()
 506       |> Enum.map(fn ap_id -> get_by_ap_id(ap_id) end)
 507       |> Enum.filter(fn u -> !is_nil(u) end)
 508       |> Enum.filter(fn u -> !following?(u, user) end)
 509
 510     {:ok, users}
 511   end
 512
 513   def increase_note_count(%User{} = user) do
 514     info_cng = User.Info.add_to_note_count(user.info, 1)
 515
 516     cng =
 517       change(user)
 518       |> put_embed(:info, info_cng)
 519
 520     update_and_set_cache(cng)
 521   end
 522
 523   def decrease_note_count(%User{} = user) do
 524     info_cng = User.Info.add_to_note_count(user.info, -1)
 525
 526     cng =
 527       change(user)
 528       |> put_embed(:info, info_cng)
 529
 530     update_and_set_cache(cng)
 531   end
 532
 533   def update_note_count(%User{} = user) do
 534     note_count_query =
 535       from(
 536         a in Object,
 537         where: fragment("?->>'actor' = ? and ?->>'type' = 'Note'", a.data, ^user.ap_id, a.data),
 538         select: count(a.id)
 539       )
 540
 541     note_count = Repo.one(note_count_query)
 542
 543     info_cng = User.Info.set_note_count(user.info, note_count)
 544
 545     cng =
 546       change(user)
 547       |> put_embed(:info, info_cng)
 548
 549     update_and_set_cache(cng)
 550   end
 551
 552   def update_follower_count(%User{} = user) do
 553     follower_count_query =
 554       from(
 555         u in User,
 556         where: ^user.follower_address in u.following,
 557         where: u.id != ^user.id,
 558         select: count(u.id)
 559       )
 560
 561     follower_count = Repo.one(follower_count_query)
 562
 563     info_cng =
 564       user.info
 565       |> User.Info.set_follower_count(follower_count)
 566
 567     cng =
 568       change(user)
 569       |> put_embed(:info, info_cng)
 570
 571     update_and_set_cache(cng)
 572   end
 573
 574   def get_users_from_set_query(ap_ids, false) do
 575     from(
 576       u in User,
 577       where: u.ap_id in ^ap_ids
 578     )
 579   end
 580
 581   def get_users_from_set_query(ap_ids, true) do
 582     query = get_users_from_set_query(ap_ids, false)
 583
 584     from(
 585       u in query,
 586       where: u.local == true
 587     )
 588   end
 589
 590   def get_users_from_set(ap_ids, local_only \\ true) do
 591     get_users_from_set_query(ap_ids, local_only)
 592     |> Repo.all()
 593   end
 594
 595   def get_recipients_from_activity(%Activity{recipients: to}) do
 596     query =
 597       from(
 598         u in User,
 599         where: u.ap_id in ^to,
 600         or_where: fragment("? && ?", u.following, ^to)
 601       )
 602
 603     query = from(u in query, where: u.local == true)
 604
 605     Repo.all(query)
 606   end
 607
 608   def search(query, resolve \\ false) do
 609     # strip the beginning @ off if there is a query
 610     query = String.trim_leading(query, "@")
 611
 612     if resolve do
 613       User.get_or_fetch_by_nickname(query)
 614     end
 615
 616     inner =
 617       from(
 618         u in User,
 619         select_merge: %{
 620           search_distance:
 621             fragment(
 622               "? <-> (? || coalesce(?, ''))",
 623               ^query,
 624               u.nickname,
 625               u.name
 626             )
 627         },
 628         where: not is_nil(u.nickname)
 629       )
 630
 631     q =
 632       from(
 633         s in subquery(inner),
 634         order_by: s.search_distance,
 635         limit: 20
 636       )
 637
 638     Repo.all(q)
 639   end
 640
 641   def blocks_import(%User{} = blocker, blocked_identifiers) when is_list(blocked_identifiers) do
 642     Enum.map(
 643       blocked_identifiers,
 644       fn blocked_identifier ->
 645         with %User{} = blocked <- get_or_fetch(blocked_identifier),
 646              {:ok, blocker} <- block(blocker, blocked),
 647              {:ok, _} <- ActivityPub.block(blocker, blocked) do
 648           blocked
 649         else
 650           err ->
 651             Logger.debug("blocks_import failed for #{blocked_identifier} with: #{inspect(err)}")
 652             err
 653         end
 654       end
 655     )
 656   end
 657
 658   def block(blocker, %User{ap_id: ap_id} = blocked) do
 659     # sever any follow relationships to prevent leaks per activitypub (Pleroma issue #213)
 660     blocker =
 661       if following?(blocker, blocked) do
 662         {:ok, blocker, _} = unfollow(blocker, blocked)
 663         blocker
 664       else
 665         blocker
 666       end
 667
 668     if following?(blocked, blocker) do
 669       unfollow(blocked, blocker)
 670     end
 671
 672     info_cng =
 673       blocker.info
 674       |> User.Info.add_to_block(ap_id)
 675
 676     cng =
 677       change(blocker)
 678       |> put_embed(:info, info_cng)
 679
 680     update_and_set_cache(cng)
 681   end
 682
 683   # helper to handle the block given only an actor's AP id
 684   def block(blocker, %{ap_id: ap_id}) do
 685     block(blocker, User.get_by_ap_id(ap_id))
 686   end
 687
 688   def unblock(blocker, %{ap_id: ap_id}) do
 689     info_cng =
 690       blocker.info
 691       |> User.Info.remove_from_block(ap_id)
 692
 693     cng =
 694       change(blocker)
 695       |> put_embed(:info, info_cng)
 696
 697     update_and_set_cache(cng)
 698   end
 699
 700   def blocks?(user, %{ap_id: ap_id}) do
 701     blocks = user.info.blocks
 702     domain_blocks = user.info.domain_blocks
 703     %{host: host} = URI.parse(ap_id)
 704
 705     Enum.member?(blocks, ap_id) ||
 706       Enum.any?(domain_blocks, fn domain ->
 707         host == domain
 708       end)
 709   end
 710
 711   def blocked_users(user),
 712     do: Repo.all(from(u in User, where: u.ap_id in ^user.info.blocks))
 713
 714   def block_domain(user, domain) do
 715     info_cng =
 716       user.info
 717       |> User.Info.add_to_domain_block(domain)
 718
 719     cng =
 720       change(user)
 721       |> put_embed(:info, info_cng)
 722
 723     update_and_set_cache(cng)
 724   end
 725
 726   def unblock_domain(user, domain) do
 727     info_cng =
 728       user.info
 729       |> User.Info.remove_from_domain_block(domain)
 730
 731     cng =
 732       change(user)
 733       |> put_embed(:info, info_cng)
 734
 735     update_and_set_cache(cng)
 736   end
 737
 738   def local_user_query() do
 739     from(
 740       u in User,
 741       where: u.local == true,
 742       where: not is_nil(u.nickname)
 743     )
 744   end
 745
 746   def moderator_user_query() do
 747     from(
 748       u in User,
 749       where: u.local == true,
 750       where: fragment("?->'is_moderator' @> 'true'", u.info)
 751     )
 752   end
 753
 754   def deactivate(%User{} = user, status \\ true) do
 755     info_cng = User.Info.set_activation_status(user.info, status)
 756
 757     cng =
 758       change(user)
 759       |> put_embed(:info, info_cng)
 760
 761     update_and_set_cache(cng)
 762   end
 763
 764   def delete(%User{} = user) do
 765     {:ok, user} = User.deactivate(user)
 766
 767     # Remove all relationships
 768     {:ok, followers} = User.get_followers(user)
 769
 770     followers
 771     |> Enum.each(fn follower -> User.unfollow(follower, user) end)
 772
 773     {:ok, friends} = User.get_friends(user)
 774
 775     friends
 776     |> Enum.each(fn followed -> User.unfollow(user, followed) end)
 777
 778     query = from(a in Activity, where: a.actor == ^user.ap_id)
 779
 780     Repo.all(query)
 781     |> Enum.each(fn activity ->
 782       case activity.data["type"] do
 783         "Create" ->
 784           ActivityPub.delete(Object.normalize(activity.data["object"]))
 785
 786         # TODO: Do something with likes, follows, repeats.
 787         _ ->
 788           "Doing nothing"
 789       end
 790     end)
 791
 792     {:ok, user}
 793   end
 794
 795   def html_filter_policy(%User{info: %{no_rich_text: true}}) do
 796     Pleroma.HTML.Scrubber.TwitterText
 797   end
 798
 799   @default_scrubbers Pleroma.Config.get([:markup, :scrub_policy])
 800
 801   def html_filter_policy(_), do: @default_scrubbers
 802
 803   def get_or_fetch_by_ap_id(ap_id) do
 804     user = get_by_ap_id(ap_id)
 805
 806     if !is_nil(user) and !User.needs_update?(user) do
 807       user
 808     else
 809       ap_try = ActivityPub.make_user_from_ap_id(ap_id)
 810
 811       case ap_try do
 812         {:ok, user} ->
 813           user
 814
 815         _ ->
 816           case OStatus.make_user(ap_id) do
 817             {:ok, user} -> user
 818             _ -> {:error, "Could not fetch by AP id"}
 819           end
 820       end
 821     end
 822   end
 823
 824   def get_or_create_instance_user do
 825     relay_uri = "#{Pleroma.Web.Endpoint.url()}/relay"
 826
 827     if user = get_by_ap_id(relay_uri) do
 828       user
 829     else
 830       changes =
 831         %User{info: %User.Info{}}
 832         |> cast(%{}, [:ap_id, :nickname, :local])
 833         |> put_change(:ap_id, relay_uri)
 834         |> put_change(:nickname, nil)
 835         |> put_change(:local, true)
 836         |> put_change(:follower_address, relay_uri <> "/followers")
 837
 838       {:ok, user} = Repo.insert(changes)
 839       user
 840     end
 841   end
 842
 843   # AP style
 844   def public_key_from_info(%{
 845         source_data: %{"publicKey" => %{"publicKeyPem" => public_key_pem}}
 846       }) do
 847     key =
 848       public_key_pem
 849       |> :public_key.pem_decode()
 850       |> hd()
 851       |> :public_key.pem_entry_decode()
 852
 853     {:ok, key}
 854   end
 855
 856   # OStatus Magic Key
 857   def public_key_from_info(%{magic_key: magic_key}) do
 858     {:ok, Pleroma.Web.Salmon.decode_key(magic_key)}
 859   end
 860
 861   def get_public_key_for_ap_id(ap_id) do
 862     with %User{} = user <- get_or_fetch_by_ap_id(ap_id),
 863          {:ok, public_key} <- public_key_from_info(user.info) do
 864       {:ok, public_key}
 865     else
 866       _ -> :error
 867     end
 868   end
 869
 870   defp blank?(""), do: nil
 871   defp blank?(n), do: n
 872
 873   def insert_or_update_user(data) do
 874     data =
 875       data
 876       |> Map.put(:name, blank?(data[:name]) || data[:nickname])
 877
 878     cs = User.remote_user_creation(data)
 879
 880     Repo.insert(cs, on_conflict: :replace_all, conflict_target: :nickname)
 881   end
 882
 883   def ap_enabled?(%User{local: true}), do: true
 884   def ap_enabled?(%User{info: info}), do: info.ap_enabled
 885   def ap_enabled?(_), do: false
 886
 887   @doc "Gets or fetch a user by uri or nickname."
 888   @spec get_or_fetch(String.t()) :: User.t()
 889   def get_or_fetch("http" <> _host = uri), do: get_or_fetch_by_ap_id(uri)
 890   def get_or_fetch(nickname), do: get_or_fetch_by_nickname(nickname)
 891
 892   # wait a period of time and return newest version of the User structs
 893   # this is because we have synchronous follow APIs and need to simulate them
 894   # with an async handshake
 895   def wait_and_refresh(_, %User{local: true} = a, %User{local: true} = b) do
 896     with %User{} = a <- Repo.get(User, a.id),
 897          %User{} = b <- Repo.get(User, b.id) do
 898       {:ok, a, b}
 899     else
 900       _e ->
 901         :error
 902     end
 903   end
 904
 905   def wait_and_refresh(timeout, %User{} = a, %User{} = b) do
 906     with :ok <- :timer.sleep(timeout),
 907          %User{} = a <- Repo.get(User, a.id),
 908          %User{} = b <- Repo.get(User, b.id) do
 909       {:ok, a, b}
 910     else
 911       _e ->
 912         :error
 913     end
 914   end
 915
 916   def parse_bio(bio, user \\ %User{info: %{source_data: %{}}})
 917   def parse_bio(nil, _user), do: ""
 918   def parse_bio(bio, _user) when bio == "", do: bio
 919
 920   def parse_bio(bio, user) do
 921     mentions = Formatter.parse_mentions(bio)
 922     tags = Formatter.parse_tags(bio)
 923
 924     emoji =
 925       (user.info.source_data["tag"] || [])
 926       |> Enum.filter(fn %{"type" => t} -> t == "Emoji" end)
 927       |> Enum.map(fn %{"icon" => %{"url" => url}, "name" => name} ->
 928         {String.trim(name, ":"), url}
 929       end)
 930
 931     bio
 932     |> CommonUtils.format_input(mentions, tags, "text/plain")
 933     |> Formatter.emojify(emoji)
 934   end
 935
 936   def tag(user_identifiers, tags) when is_list(user_identifiers) do
 937     Repo.transaction(fn ->
 938       for user_identifier <- user_identifiers, do: tag(user_identifier, tags)
 939     end)
 940   end
 941
 942   def tag(nickname, tags) when is_binary(nickname),
 943     do: tag(User.get_by_nickname(nickname), tags)
 944
 945   def tag(%User{} = user, tags),
 946     do: update_tags(user, Enum.uniq((user.tags || []) ++ normalize_tags(tags)))
 947
 948   def untag(user_identifiers, tags) when is_list(user_identifiers) do
 949     Repo.transaction(fn ->
 950       for user_identifier <- user_identifiers, do: untag(user_identifier, tags)
 951     end)
 952   end
 953
 954   def untag(nickname, tags) when is_binary(nickname),
 955     do: untag(User.get_by_nickname(nickname), tags)
 956
 957   def untag(%User{} = user, tags),
 958     do: update_tags(user, (user.tags || []) -- normalize_tags(tags))
 959
 960   defp update_tags(%User{} = user, new_tags) do
 961     {:ok, updated_user} =
 962       user
 963       |> change(%{tags: new_tags})
 964       |> Repo.update()
 965
 966     updated_user
 967   end
 968
 969   defp normalize_tags(tags) do
 970     [tags]
 971     |> List.flatten()
 972     |> Enum.map(&String.downcase(&1))
 973   end
 974
 975   defp local_nickname_regex() do
 976     if Pleroma.Config.get([:instance, :extended_nickname_format]) do
 977       @extended_local_nickname_regex
 978     else
 979       @strict_local_nickname_regex
 980     end
 981   end
 982 end