git.squeep.com Git - akkoma/blob - lib/pleroma/user.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.User do
   6   use Ecto.Schema
   7
   8   import Ecto.{Changeset, Query}
   9   alias Pleroma.{Repo, User, Object, Web, Activity, Notification}
  10   alias Comeonin.Pbkdf2
  11   alias Pleroma.Formatter
  12   alias Pleroma.Web.CommonAPI.Utils, as: CommonUtils
  13   alias Pleroma.Web.{OStatus, Websub, OAuth}
  14   alias Pleroma.Web.ActivityPub.{Utils, ActivityPub}
  15
  16   require Logger
  17
  18   @type t :: %__MODULE__{}
  19
  20   @primary_key {:id, Pleroma.FlakeId, autogenerate: true}
  21
  22   @email_regex ~r/^[a-zA-Z0-9.!#$%&'*+\/=?^_`{|}~-]+@[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?(?:\.[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?)*$/
  23
  24   @strict_local_nickname_regex ~r/^[a-zA-Z\d]+$/
  25   @extended_local_nickname_regex ~r/^[a-zA-Z\d_-]+$/
  26
  27   schema "users" do
  28     field(:bio, :string)
  29     field(:email, :string)
  30     field(:name, :string)
  31     field(:nickname, :string)
  32     field(:password_hash, :string)
  33     field(:password, :string, virtual: true)
  34     field(:password_confirmation, :string, virtual: true)
  35     field(:following, {:array, :string}, default: [])
  36     field(:ap_id, :string)
  37     field(:avatar, :map)
  38     field(:local, :boolean, default: true)
  39     field(:follower_address, :string)
  40     field(:search_rank, :float, virtual: true)
  41     field(:tags, {:array, :string}, default: [])
  42     field(:last_refreshed_at, :naive_datetime)
  43     has_many(:notifications, Notification)
  44     embeds_one(:info, Pleroma.User.Info)
  45
  46     timestamps()
  47   end
  48
  49   def auth_active?(%User{local: false}), do: true
  50
  51   def auth_active?(%User{info: %User.Info{confirmation_pending: false}}), do: true
  52
  53   def auth_active?(%User{info: %User.Info{confirmation_pending: true}}),
  54     do: !Pleroma.Config.get([:instance, :account_activation_required])
  55
  56   def auth_active?(_), do: false
  57
  58   def visible_for?(user, for_user \\ nil)
  59
  60   def visible_for?(%User{id: user_id}, %User{id: for_id}) when user_id == for_id, do: true
  61
  62   def visible_for?(%User{} = user, for_user) do
  63     auth_active?(user) || superuser?(for_user)
  64   end
  65
  66   def visible_for?(_, _), do: false
  67
  68   def superuser?(%User{local: true, info: %User.Info{is_admin: true}}), do: true
  69   def superuser?(%User{local: true, info: %User.Info{is_moderator: true}}), do: true
  70   def superuser?(_), do: false
  71
  72   def avatar_url(user) do
  73     case user.avatar do
  74       %{"url" => [%{"href" => href} | _]} -> href
  75       _ -> "#{Web.base_url()}/images/avi.png"
  76     end
  77   end
  78
  79   def banner_url(user) do
  80     case user.info.banner do
  81       %{"url" => [%{"href" => href} | _]} -> href
  82       _ -> "#{Web.base_url()}/images/banner.png"
  83     end
  84   end
  85
  86   def profile_url(%User{info: %{source_data: %{"url" => url}}}), do: url
  87   def profile_url(%User{ap_id: ap_id}), do: ap_id
  88   def profile_url(_), do: nil
  89
  90   def ap_id(%User{nickname: nickname}) do
  91     "#{Web.base_url()}/users/#{nickname}"
  92   end
  93
  94   def ap_followers(%User{} = user) do
  95     "#{ap_id(user)}/followers"
  96   end
  97
  98   def follow_changeset(struct, params \\ %{}) do
  99     struct
 100     |> cast(params, [:following])
 101     |> validate_required([:following])
 102   end
 103
 104   def user_info(%User{} = user) do
 105     oneself = if user.local, do: 1, else: 0
 106
 107     %{
 108       following_count: length(user.following) - oneself,
 109       note_count: user.info.note_count,
 110       follower_count: user.info.follower_count,
 111       locked: user.info.locked,
 112       confirmation_pending: user.info.confirmation_pending,
 113       default_scope: user.info.default_scope
 114     }
 115   end
 116
 117   def remote_user_creation(params) do
 118     params =
 119       params
 120       |> Map.put(:info, params[:info] || %{})
 121
 122     info_cng = User.Info.remote_user_creation(%User.Info{}, params[:info])
 123
 124     changes =
 125       %User{}
 126       |> cast(params, [:bio, :name, :ap_id, :nickname, :avatar])
 127       |> validate_required([:name, :ap_id])
 128       |> unique_constraint(:nickname)
 129       |> validate_format(:nickname, @email_regex)
 130       |> validate_length(:bio, max: 5000)
 131       |> validate_length(:name, max: 100)
 132       |> put_change(:local, false)
 133       |> put_embed(:info, info_cng)
 134
 135     if changes.valid? do
 136       case info_cng.changes[:source_data] do
 137         %{"followers" => followers} ->
 138           changes
 139           |> put_change(:follower_address, followers)
 140
 141         _ ->
 142           followers = User.ap_followers(%User{nickname: changes.changes[:nickname]})
 143
 144           changes
 145           |> put_change(:follower_address, followers)
 146       end
 147     else
 148       changes
 149     end
 150   end
 151
 152   def update_changeset(struct, params \\ %{}) do
 153     struct
 154     |> cast(params, [:bio, :name, :avatar])
 155     |> unique_constraint(:nickname)
 156     |> validate_format(:nickname, local_nickname_regex())
 157     |> validate_length(:bio, max: 5000)
 158     |> validate_length(:name, min: 1, max: 100)
 159   end
 160
 161   def upgrade_changeset(struct, params \\ %{}) do
 162     params =
 163       params
 164       |> Map.put(:last_refreshed_at, NaiveDateTime.utc_now())
 165
 166     info_cng =
 167       struct.info
 168       |> User.Info.user_upgrade(params[:info])
 169
 170     struct
 171     |> cast(params, [:bio, :name, :follower_address, :avatar, :last_refreshed_at])
 172     |> unique_constraint(:nickname)
 173     |> validate_format(:nickname, local_nickname_regex())
 174     |> validate_length(:bio, max: 5000)
 175     |> validate_length(:name, max: 100)
 176     |> put_embed(:info, info_cng)
 177   end
 178
 179   def password_update_changeset(struct, params) do
 180     changeset =
 181       struct
 182       |> cast(params, [:password, :password_confirmation])
 183       |> validate_required([:password, :password_confirmation])
 184       |> validate_confirmation(:password)
 185
 186     OAuth.Token.delete_user_tokens(struct)
 187     OAuth.Authorization.delete_user_authorizations(struct)
 188
 189     if changeset.valid? do
 190       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 191
 192       changeset
 193       |> put_change(:password_hash, hashed)
 194     else
 195       changeset
 196     end
 197   end
 198
 199   def reset_password(user, data) do
 200     update_and_set_cache(password_update_changeset(user, data))
 201   end
 202
 203   def register_changeset(struct, params \\ %{}, opts \\ []) do
 204     confirmation_status =
 205       if opts[:confirmed] || !Pleroma.Config.get([:instance, :account_activation_required]) do
 206         :confirmed
 207       else
 208         :unconfirmed
 209       end
 210
 211     info_change = User.Info.confirmation_changeset(%User.Info{}, confirmation_status)
 212
 213     changeset =
 214       struct
 215       |> cast(params, [:bio, :email, :name, :nickname, :password, :password_confirmation])
 216       |> validate_required([:email, :name, :nickname, :password, :password_confirmation])
 217       |> validate_confirmation(:password)
 218       |> unique_constraint(:email)
 219       |> unique_constraint(:nickname)
 220       |> validate_exclusion(:nickname, Pleroma.Config.get([Pleroma.User, :restricted_nicknames]))
 221       |> validate_format(:nickname, local_nickname_regex())
 222       |> validate_format(:email, @email_regex)
 223       |> validate_length(:bio, max: 1000)
 224       |> validate_length(:name, min: 1, max: 100)
 225       |> put_change(:info, info_change)
 226
 227     if changeset.valid? do
 228       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 229       ap_id = User.ap_id(%User{nickname: changeset.changes[:nickname]})
 230       followers = User.ap_followers(%User{nickname: changeset.changes[:nickname]})
 231
 232       changeset
 233       |> put_change(:password_hash, hashed)
 234       |> put_change(:ap_id, ap_id)
 235       |> put_change(:following, [followers])
 236       |> put_change(:follower_address, followers)
 237     else
 238       changeset
 239     end
 240   end
 241
 242   defp autofollow_users(user) do
 243     candidates = Pleroma.Config.get([:instance, :autofollowed_nicknames])
 244
 245     autofollowed_users =
 246       from(u in User,
 247         where: u.local == true,
 248         where: u.nickname in ^candidates
 249       )
 250       |> Repo.all()
 251
 252     follow_all(user, autofollowed_users)
 253   end
 254
 255   @doc "Inserts provided changeset, performs post-registration actions (confirmation email sending etc.)"
 256   def register(%Ecto.Changeset{} = changeset) do
 257     with {:ok, user} <- Repo.insert(changeset),
 258          {:ok, _} <- try_send_confirmation_email(user),
 259          {:ok, user} <- autofollow_users(user) do
 260       {:ok, user}
 261     end
 262   end
 263
 264   def try_send_confirmation_email(%User{} = user) do
 265     if user.info.confirmation_pending &&
 266          Pleroma.Config.get([:instance, :account_activation_required]) do
 267       user
 268       |> Pleroma.UserEmail.account_confirmation_email()
 269       |> Pleroma.Mailer.deliver()
 270     else
 271       {:ok, :noop}
 272     end
 273   end
 274
 275   def needs_update?(%User{local: true}), do: false
 276
 277   def needs_update?(%User{local: false, last_refreshed_at: nil}), do: true
 278
 279   def needs_update?(%User{local: false} = user) do
 280     NaiveDateTime.diff(NaiveDateTime.utc_now(), user.last_refreshed_at) >= 86400
 281   end
 282
 283   def needs_update?(_), do: true
 284
 285   def maybe_direct_follow(%User{} = follower, %User{local: true, info: %{locked: true}}) do
 286     {:ok, follower}
 287   end
 288
 289   def maybe_direct_follow(%User{} = follower, %User{local: true} = followed) do
 290     follow(follower, followed)
 291   end
 292
 293   def maybe_direct_follow(%User{} = follower, %User{} = followed) do
 294     if not User.ap_enabled?(followed) do
 295       follow(follower, followed)
 296     else
 297       {:ok, follower}
 298     end
 299   end
 300
 301   def maybe_follow(%User{} = follower, %User{info: _info} = followed) do
 302     if not following?(follower, followed) do
 303       follow(follower, followed)
 304     else
 305       {:ok, follower}
 306     end
 307   end
 308
 309   @doc "A mass follow for local users. Ignores blocks and has no side effects"
 310   @spec follow_all(User.t(), list(User.t())) :: {atom(), User.t()}
 311   def follow_all(follower, followeds) do
 312     followed_addresses = Enum.map(followeds, fn %{follower_address: fa} -> fa end)
 313
 314     q =
 315       from(u in User,
 316         where: u.id == ^follower.id,
 317         update: [set: [following: fragment("array_cat(?, ?)", u.following, ^followed_addresses)]]
 318       )
 319
 320     {1, [follower]} = Repo.update_all(q, [], returning: true)
 321
 322     Enum.each(followeds, fn followed ->
 323       update_follower_count(followed)
 324     end)
 325
 326     set_cache(follower)
 327   end
 328
 329   def follow(%User{} = follower, %User{info: info} = followed) do
 330     user_config = Application.get_env(:pleroma, :user)
 331     deny_follow_blocked = Keyword.get(user_config, :deny_follow_blocked)
 332
 333     ap_followers = followed.follower_address
 334
 335     cond do
 336       following?(follower, followed) or info.deactivated ->
 337         {:error, "Could not follow user: #{followed.nickname} is already on your list."}
 338
 339       deny_follow_blocked and blocks?(followed, follower) ->
 340         {:error, "Could not follow user: #{followed.nickname} blocked you."}
 341
 342       true ->
 343         if !followed.local && follower.local && !ap_enabled?(followed) do
 344           Websub.subscribe(follower, followed)
 345         end
 346
 347         q =
 348           from(u in User,
 349             where: u.id == ^follower.id,
 350             update: [push: [following: ^ap_followers]]
 351           )
 352
 353         {1, [follower]} = Repo.update_all(q, [], returning: true)
 354
 355         {:ok, _} = update_follower_count(followed)
 356
 357         set_cache(follower)
 358     end
 359   end
 360
 361   def unfollow(%User{} = follower, %User{} = followed) do
 362     ap_followers = followed.follower_address
 363
 364     if following?(follower, followed) and follower.ap_id != followed.ap_id do
 365       q =
 366         from(u in User,
 367           where: u.id == ^follower.id,
 368           update: [pull: [following: ^ap_followers]]
 369         )
 370
 371       {1, [follower]} = Repo.update_all(q, [], returning: true)
 372
 373       {:ok, followed} = update_follower_count(followed)
 374
 375       set_cache(follower)
 376
 377       {:ok, follower, Utils.fetch_latest_follow(follower, followed)}
 378     else
 379       {:error, "Not subscribed!"}
 380     end
 381   end
 382
 383   @spec following?(User.t(), User.t()) :: boolean
 384   def following?(%User{} = follower, %User{} = followed) do
 385     Enum.member?(follower.following, followed.follower_address)
 386   end
 387
 388   def follow_import(%User{} = follower, followed_identifiers)
 389       when is_list(followed_identifiers) do
 390     Enum.map(
 391       followed_identifiers,
 392       fn followed_identifier ->
 393         with %User{} = followed <- get_or_fetch(followed_identifier),
 394              {:ok, follower} <- maybe_direct_follow(follower, followed),
 395              {:ok, _} <- ActivityPub.follow(follower, followed) do
 396           followed
 397         else
 398           err ->
 399             Logger.debug("follow_import failed for #{followed_identifier} with: #{inspect(err)}")
 400             err
 401         end
 402       end
 403     )
 404   end
 405
 406   def locked?(%User{} = user) do
 407     user.info.locked || false
 408   end
 409
 410   def get_by_id(id) do
 411     Repo.get_by(User, id: id)
 412   end
 413
 414   def get_by_ap_id(ap_id) do
 415     Repo.get_by(User, ap_id: ap_id)
 416   end
 417
 418   # This is mostly an SPC migration fix. This guesses the user nickname (by taking the last part of the ap_id and the domain) and tries to get that user
 419   def get_by_guessed_nickname(ap_id) do
 420     domain = URI.parse(ap_id).host
 421     name = List.last(String.split(ap_id, "/"))
 422     nickname = "#{name}@#{domain}"
 423
 424     get_by_nickname(nickname)
 425   end
 426
 427   def set_cache(user) do
 428     Cachex.put(:user_cache, "ap_id:#{user.ap_id}", user)
 429     Cachex.put(:user_cache, "nickname:#{user.nickname}", user)
 430     Cachex.put(:user_cache, "user_info:#{user.id}", user_info(user))
 431     {:ok, user}
 432   end
 433
 434   def update_and_set_cache(changeset) do
 435     with {:ok, user} <- Repo.update(changeset) do
 436       set_cache(user)
 437     else
 438       e -> e
 439     end
 440   end
 441
 442   def invalidate_cache(user) do
 443     Cachex.del(:user_cache, "ap_id:#{user.ap_id}")
 444     Cachex.del(:user_cache, "nickname:#{user.nickname}")
 445     Cachex.del(:user_cache, "user_info:#{user.id}")
 446   end
 447
 448   def get_cached_by_ap_id(ap_id) do
 449     key = "ap_id:#{ap_id}"
 450     Cachex.fetch!(:user_cache, key, fn _ -> get_by_ap_id(ap_id) end)
 451   end
 452
 453   def get_cached_by_id(id) do
 454     key = "id:#{id}"
 455
 456     ap_id =
 457       Cachex.fetch!(:user_cache, key, fn _ ->
 458         user = get_by_id(id)
 459
 460         if user do
 461           Cachex.put(:user_cache, "ap_id:#{user.ap_id}", user)
 462           {:commit, user.ap_id}
 463         else
 464           {:ignore, ""}
 465         end
 466       end)
 467
 468     get_cached_by_ap_id(ap_id)
 469   end
 470
 471   def get_cached_by_nickname(nickname) do
 472     key = "nickname:#{nickname}"
 473     Cachex.fetch!(:user_cache, key, fn _ -> get_or_fetch_by_nickname(nickname) end)
 474   end
 475
 476   def get_cached_by_nickname_or_id(nickname_or_id) do
 477     get_cached_by_id(nickname_or_id) || get_cached_by_nickname(nickname_or_id)
 478   end
 479
 480   def get_by_nickname(nickname) do
 481     Repo.get_by(User, nickname: nickname) ||
 482       if Regex.match?(~r(@#{Pleroma.Web.Endpoint.host()})i, nickname) do
 483         Repo.get_by(User, nickname: local_nickname(nickname))
 484       end
 485   end
 486
 487   def get_by_nickname_or_email(nickname_or_email) do
 488     case user = Repo.get_by(User, nickname: nickname_or_email) do
 489       %User{} -> user
 490       nil -> Repo.get_by(User, email: nickname_or_email)
 491     end
 492   end
 493
 494   def get_cached_user_info(user) do
 495     key = "user_info:#{user.id}"
 496     Cachex.fetch!(:user_cache, key, fn _ -> user_info(user) end)
 497   end
 498
 499   def fetch_by_nickname(nickname) do
 500     ap_try = ActivityPub.make_user_from_nickname(nickname)
 501
 502     case ap_try do
 503       {:ok, user} -> {:ok, user}
 504       _ -> OStatus.make_user(nickname)
 505     end
 506   end
 507
 508   def get_or_fetch_by_nickname(nickname) do
 509     with %User{} = user <- get_by_nickname(nickname) do
 510       user
 511     else
 512       _e ->
 513         with [_nick, _domain] <- String.split(nickname, "@"),
 514              {:ok, user} <- fetch_by_nickname(nickname) do
 515           user
 516         else
 517           _e -> nil
 518         end
 519     end
 520   end
 521
 522   def get_followers_query(%User{id: id, follower_address: follower_address}, nil) do
 523     from(
 524       u in User,
 525       where: fragment("? <@ ?", ^[follower_address], u.following),
 526       where: u.id != ^id
 527     )
 528   end
 529
 530   def get_followers_query(user, page) do
 531     from(
 532       u in get_followers_query(user, nil),
 533       limit: 20,
 534       offset: ^((page - 1) * 20)
 535     )
 536   end
 537
 538   def get_followers_query(user), do: get_followers_query(user, nil)
 539
 540   def get_followers(user, page \\ nil) do
 541     q = get_followers_query(user, page)
 542
 543     {:ok, Repo.all(q)}
 544   end
 545
 546   def get_followers_ids(user, page \\ nil) do
 547     q = get_followers_query(user, page)
 548
 549     Repo.all(from(u in q, select: u.id))
 550   end
 551
 552   def get_friends_query(%User{id: id, following: following}, nil) do
 553     from(
 554       u in User,
 555       where: u.follower_address in ^following,
 556       where: u.id != ^id
 557     )
 558   end
 559
 560   def get_friends_query(user, page) do
 561     from(
 562       u in get_friends_query(user, nil),
 563       limit: 20,
 564       offset: ^((page - 1) * 20)
 565     )
 566   end
 567
 568   def get_friends_query(user), do: get_friends_query(user, nil)
 569
 570   def get_friends(user, page \\ nil) do
 571     q = get_friends_query(user, page)
 572
 573     {:ok, Repo.all(q)}
 574   end
 575
 576   def get_friends_ids(user, page \\ nil) do
 577     q = get_friends_query(user, page)
 578
 579     Repo.all(from(u in q, select: u.id))
 580   end
 581
 582   def get_follow_requests_query(%User{} = user) do
 583     from(
 584       a in Activity,
 585       where:
 586         fragment(
 587           "? ->> 'type' = 'Follow'",
 588           a.data
 589         ),
 590       where:
 591         fragment(
 592           "? ->> 'state' = 'pending'",
 593           a.data
 594         ),
 595       where:
 596         fragment(
 597           "? @> ?",
 598           a.data,
 599           ^%{"object" => user.ap_id}
 600         )
 601     )
 602   end
 603
 604   def get_follow_requests(%User{} = user) do
 605     q = get_follow_requests_query(user)
 606     reqs = Repo.all(q)
 607
 608     users =
 609       Enum.map(reqs, fn req -> req.actor end)
 610       |> Enum.uniq()
 611       |> Enum.map(fn ap_id -> get_by_ap_id(ap_id) end)
 612       |> Enum.filter(fn u -> !is_nil(u) end)
 613       |> Enum.filter(fn u -> !following?(u, user) end)
 614
 615     {:ok, users}
 616   end
 617
 618   def increase_note_count(%User{} = user) do
 619     info_cng = User.Info.add_to_note_count(user.info, 1)
 620
 621     cng =
 622       change(user)
 623       |> put_embed(:info, info_cng)
 624
 625     update_and_set_cache(cng)
 626   end
 627
 628   def decrease_note_count(%User{} = user) do
 629     info_cng = User.Info.add_to_note_count(user.info, -1)
 630
 631     cng =
 632       change(user)
 633       |> put_embed(:info, info_cng)
 634
 635     update_and_set_cache(cng)
 636   end
 637
 638   def update_note_count(%User{} = user) do
 639     note_count_query =
 640       from(
 641         a in Object,
 642         where: fragment("?->>'actor' = ? and ?->>'type' = 'Note'", a.data, ^user.ap_id, a.data),
 643         select: count(a.id)
 644       )
 645
 646     note_count = Repo.one(note_count_query)
 647
 648     info_cng = User.Info.set_note_count(user.info, note_count)
 649
 650     cng =
 651       change(user)
 652       |> put_embed(:info, info_cng)
 653
 654     update_and_set_cache(cng)
 655   end
 656
 657   def update_follower_count(%User{} = user) do
 658     follower_count_query =
 659       from(
 660         u in User,
 661         where: ^user.follower_address in u.following,
 662         where: u.id != ^user.id,
 663         select: count(u.id)
 664       )
 665
 666     follower_count = Repo.one(follower_count_query)
 667
 668     info_cng =
 669       user.info
 670       |> User.Info.set_follower_count(follower_count)
 671
 672     cng =
 673       change(user)
 674       |> put_embed(:info, info_cng)
 675
 676     update_and_set_cache(cng)
 677   end
 678
 679   def get_users_from_set_query(ap_ids, false) do
 680     from(
 681       u in User,
 682       where: u.ap_id in ^ap_ids
 683     )
 684   end
 685
 686   def get_users_from_set_query(ap_ids, true) do
 687     query = get_users_from_set_query(ap_ids, false)
 688
 689     from(
 690       u in query,
 691       where: u.local == true
 692     )
 693   end
 694
 695   def get_users_from_set(ap_ids, local_only \\ true) do
 696     get_users_from_set_query(ap_ids, local_only)
 697     |> Repo.all()
 698   end
 699
 700   def get_recipients_from_activity(%Activity{recipients: to}) do
 701     query =
 702       from(
 703         u in User,
 704         where: u.ap_id in ^to,
 705         or_where: fragment("? && ?", u.following, ^to)
 706       )
 707
 708     query = from(u in query, where: u.local == true)
 709
 710     Repo.all(query)
 711   end
 712
 713   def search(query, resolve \\ false, for_user \\ nil) do
 714     # Strip the beginning @ off if there is a query
 715     query = String.trim_leading(query, "@")
 716
 717     if resolve, do: User.get_or_fetch_by_nickname(query)
 718
 719     fts_results = do_search(fts_search_subquery(query), for_user)
 720
 721     {:ok, trigram_results} =
 722       Repo.transaction(fn ->
 723         Ecto.Adapters.SQL.query(Repo, "select set_limit(0.25)", [])
 724         do_search(trigram_search_subquery(query), for_user)
 725       end)
 726
 727     Enum.uniq_by(fts_results ++ trigram_results, & &1.id)
 728   end
 729
 730   defp do_search(subquery, for_user, options \\ []) do
 731     q =
 732       from(
 733         s in subquery(subquery),
 734         order_by: [desc: s.search_rank],
 735         limit: ^(options[:limit] || 20)
 736       )
 737
 738     results =
 739       q
 740       |> Repo.all()
 741       |> Enum.filter(&(&1.search_rank > 0))
 742
 743     boost_search_results(results, for_user)
 744   end
 745
 746   defp fts_search_subquery(query) do
 747     processed_query =
 748       query
 749       |> String.replace(~r/\W+/, " ")
 750       |> String.trim()
 751       |> String.split()
 752       |> Enum.map(&(&1 <> ":*"))
 753       |> Enum.join(" | ")
 754
 755     from(
 756       u in User,
 757       select_merge: %{
 758         search_rank:
 759           fragment(
 760             """
 761             ts_rank_cd(
 762               setweight(to_tsvector('simple', regexp_replace(?, '\\W', ' ', 'g')), 'A') ||
 763               setweight(to_tsvector('simple', regexp_replace(coalesce(?, ''), '\\W', ' ', 'g')), 'B'),
 764               to_tsquery('simple', ?),
 765               32
 766             )
 767             """,
 768             u.nickname,
 769             u.name,
 770             ^processed_query
 771           )
 772       },
 773       where:
 774         fragment(
 775           """
 776             (setweight(to_tsvector('simple', regexp_replace(?, '\\W', ' ', 'g')), 'A') ||
 777             setweight(to_tsvector('simple', regexp_replace(coalesce(?, ''), '\\W', ' ', 'g')), 'B')) @@ to_tsquery('simple', ?)
 778           """,
 779           u.nickname,
 780           u.name,
 781           ^processed_query
 782         )
 783     )
 784   end
 785
 786   defp trigram_search_subquery(query) do
 787     from(
 788       u in User,
 789       select_merge: %{
 790         search_rank:
 791           fragment(
 792             "similarity(?, trim(? || ' ' || coalesce(?, '')))",
 793             ^query,
 794             u.nickname,
 795             u.name
 796           )
 797       },
 798       where: fragment("trim(? || ' ' || coalesce(?, '')) % ?", u.nickname, u.name, ^query)
 799     )
 800   end
 801
 802   defp boost_search_results(results, nil), do: results
 803
 804   defp boost_search_results(results, for_user) do
 805     friends_ids = get_friends_ids(for_user)
 806     followers_ids = get_followers_ids(for_user)
 807
 808     Enum.map(
 809       results,
 810       fn u ->
 811         search_rank_coef =
 812           cond do
 813             u.id in friends_ids ->
 814               1.2
 815
 816             u.id in followers_ids ->
 817               1.1
 818
 819             true ->
 820               1
 821           end
 822
 823         Map.put(u, :search_rank, u.search_rank * search_rank_coef)
 824       end
 825     )
 826     |> Enum.sort_by(&(-&1.search_rank))
 827   end
 828
 829   def blocks_import(%User{} = blocker, blocked_identifiers) when is_list(blocked_identifiers) do
 830     Enum.map(
 831       blocked_identifiers,
 832       fn blocked_identifier ->
 833         with %User{} = blocked <- get_or_fetch(blocked_identifier),
 834              {:ok, blocker} <- block(blocker, blocked),
 835              {:ok, _} <- ActivityPub.block(blocker, blocked) do
 836           blocked
 837         else
 838           err ->
 839             Logger.debug("blocks_import failed for #{blocked_identifier} with: #{inspect(err)}")
 840             err
 841         end
 842       end
 843     )
 844   end
 845
 846   def block(blocker, %User{ap_id: ap_id} = blocked) do
 847     # sever any follow relationships to prevent leaks per activitypub (Pleroma issue #213)
 848     blocker =
 849       if following?(blocker, blocked) do
 850         {:ok, blocker, _} = unfollow(blocker, blocked)
 851         blocker
 852       else
 853         blocker
 854       end
 855
 856     if following?(blocked, blocker) do
 857       unfollow(blocked, blocker)
 858     end
 859
 860     info_cng =
 861       blocker.info
 862       |> User.Info.add_to_block(ap_id)
 863
 864     cng =
 865       change(blocker)
 866       |> put_embed(:info, info_cng)
 867
 868     update_and_set_cache(cng)
 869   end
 870
 871   # helper to handle the block given only an actor's AP id
 872   def block(blocker, %{ap_id: ap_id}) do
 873     block(blocker, User.get_by_ap_id(ap_id))
 874   end
 875
 876   def unblock(blocker, %{ap_id: ap_id}) do
 877     info_cng =
 878       blocker.info
 879       |> User.Info.remove_from_block(ap_id)
 880
 881     cng =
 882       change(blocker)
 883       |> put_embed(:info, info_cng)
 884
 885     update_and_set_cache(cng)
 886   end
 887
 888   def blocks?(user, %{ap_id: ap_id}) do
 889     blocks = user.info.blocks
 890     domain_blocks = user.info.domain_blocks
 891     %{host: host} = URI.parse(ap_id)
 892
 893     Enum.member?(blocks, ap_id) ||
 894       Enum.any?(domain_blocks, fn domain ->
 895         host == domain
 896       end)
 897   end
 898
 899   def blocked_users(user),
 900     do: Repo.all(from(u in User, where: u.ap_id in ^user.info.blocks))
 901
 902   def block_domain(user, domain) do
 903     info_cng =
 904       user.info
 905       |> User.Info.add_to_domain_block(domain)
 906
 907     cng =
 908       change(user)
 909       |> put_embed(:info, info_cng)
 910
 911     update_and_set_cache(cng)
 912   end
 913
 914   def unblock_domain(user, domain) do
 915     info_cng =
 916       user.info
 917       |> User.Info.remove_from_domain_block(domain)
 918
 919     cng =
 920       change(user)
 921       |> put_embed(:info, info_cng)
 922
 923     update_and_set_cache(cng)
 924   end
 925
 926   def local_user_query do
 927     from(
 928       u in User,
 929       where: u.local == true,
 930       where: not is_nil(u.nickname)
 931     )
 932   end
 933
 934   def active_local_user_query do
 935     from(
 936       u in local_user_query(),
 937       where: fragment("not (?->'deactivated' @> 'true')", u.info)
 938     )
 939   end
 940
 941   def moderator_user_query do
 942     from(
 943       u in User,
 944       where: u.local == true,
 945       where: fragment("?->'is_moderator' @> 'true'", u.info)
 946     )
 947   end
 948
 949   def deactivate(%User{} = user, status \\ true) do
 950     info_cng = User.Info.set_activation_status(user.info, status)
 951
 952     cng =
 953       change(user)
 954       |> put_embed(:info, info_cng)
 955
 956     update_and_set_cache(cng)
 957   end
 958
 959   def delete(%User{} = user) do
 960     {:ok, user} = User.deactivate(user)
 961
 962     # Remove all relationships
 963     {:ok, followers} = User.get_followers(user)
 964
 965     followers
 966     |> Enum.each(fn follower -> User.unfollow(follower, user) end)
 967
 968     {:ok, friends} = User.get_friends(user)
 969
 970     friends
 971     |> Enum.each(fn followed -> User.unfollow(user, followed) end)
 972
 973     query = from(a in Activity, where: a.actor == ^user.ap_id)
 974
 975     Repo.all(query)
 976     |> Enum.each(fn activity ->
 977       case activity.data["type"] do
 978         "Create" ->
 979           ActivityPub.delete(Object.normalize(activity.data["object"]))
 980
 981         # TODO: Do something with likes, follows, repeats.
 982         _ ->
 983           "Doing nothing"
 984       end
 985     end)
 986
 987     {:ok, user}
 988   end
 989
 990   def html_filter_policy(%User{info: %{no_rich_text: true}}) do
 991     Pleroma.HTML.Scrubber.TwitterText
 992   end
 993
 994   @default_scrubbers Pleroma.Config.get([:markup, :scrub_policy])
 995
 996   def html_filter_policy(_), do: @default_scrubbers
 997
 998   def get_or_fetch_by_ap_id(ap_id) do
 999     user = get_by_ap_id(ap_id)
1000
1001     if !is_nil(user) and !User.needs_update?(user) do
1002       user
1003     else
1004       ap_try = ActivityPub.make_user_from_ap_id(ap_id)
1005
1006       case ap_try do
1007         {:ok, user} ->
1008           user
1009
1010         _ ->
1011           case OStatus.make_user(ap_id) do
1012             {:ok, user} -> user
1013             _ -> {:error, "Could not fetch by AP id"}
1014           end
1015       end
1016     end
1017   end
1018
1019   def get_or_create_instance_user do
1020     relay_uri = "#{Pleroma.Web.Endpoint.url()}/relay"
1021
1022     if user = get_by_ap_id(relay_uri) do
1023       user
1024     else
1025       changes =
1026         %User{info: %User.Info{}}
1027         |> cast(%{}, [:ap_id, :nickname, :local])
1028         |> put_change(:ap_id, relay_uri)
1029         |> put_change(:nickname, nil)
1030         |> put_change(:local, true)
1031         |> put_change(:follower_address, relay_uri <> "/followers")
1032
1033       {:ok, user} = Repo.insert(changes)
1034       user
1035     end
1036   end
1037
1038   # AP style
1039   def public_key_from_info(%{
1040         source_data: %{"publicKey" => %{"publicKeyPem" => public_key_pem}}
1041       }) do
1042     key =
1043       public_key_pem
1044       |> :public_key.pem_decode()
1045       |> hd()
1046       |> :public_key.pem_entry_decode()
1047
1048     {:ok, key}
1049   end
1050
1051   # OStatus Magic Key
1052   def public_key_from_info(%{magic_key: magic_key}) do
1053     {:ok, Pleroma.Web.Salmon.decode_key(magic_key)}
1054   end
1055
1056   def get_public_key_for_ap_id(ap_id) do
1057     with %User{} = user <- get_or_fetch_by_ap_id(ap_id),
1058          {:ok, public_key} <- public_key_from_info(user.info) do
1059       {:ok, public_key}
1060     else
1061       _ -> :error
1062     end
1063   end
1064
1065   defp blank?(""), do: nil
1066   defp blank?(n), do: n
1067
1068   def insert_or_update_user(data) do
1069     data =
1070       data
1071       |> Map.put(:name, blank?(data[:name]) || data[:nickname])
1072
1073     cs = User.remote_user_creation(data)
1074
1075     Repo.insert(cs, on_conflict: :replace_all, conflict_target: :nickname)
1076   end
1077
1078   def ap_enabled?(%User{local: true}), do: true
1079   def ap_enabled?(%User{info: info}), do: info.ap_enabled
1080   def ap_enabled?(_), do: false
1081
1082   @doc "Gets or fetch a user by uri or nickname."
1083   @spec get_or_fetch(String.t()) :: User.t()
1084   def get_or_fetch("http" <> _host = uri), do: get_or_fetch_by_ap_id(uri)
1085   def get_or_fetch(nickname), do: get_or_fetch_by_nickname(nickname)
1086
1087   # wait a period of time and return newest version of the User structs
1088   # this is because we have synchronous follow APIs and need to simulate them
1089   # with an async handshake
1090   def wait_and_refresh(_, %User{local: true} = a, %User{local: true} = b) do
1091     with %User{} = a <- Repo.get(User, a.id),
1092          %User{} = b <- Repo.get(User, b.id) do
1093       {:ok, a, b}
1094     else
1095       _e ->
1096         :error
1097     end
1098   end
1099
1100   def wait_and_refresh(timeout, %User{} = a, %User{} = b) do
1101     with :ok <- :timer.sleep(timeout),
1102          %User{} = a <- Repo.get(User, a.id),
1103          %User{} = b <- Repo.get(User, b.id) do
1104       {:ok, a, b}
1105     else
1106       _e ->
1107         :error
1108     end
1109   end
1110
1111   def parse_bio(bio, user \\ %User{info: %{source_data: %{}}})
1112   def parse_bio(nil, _user), do: ""
1113   def parse_bio(bio, _user) when bio == "", do: bio
1114
1115   def parse_bio(bio, user) do
1116     mentions = Formatter.parse_mentions(bio)
1117     tags = Formatter.parse_tags(bio)
1118
1119     emoji =
1120       (user.info.source_data["tag"] || [])
1121       |> Enum.filter(fn %{"type" => t} -> t == "Emoji" end)
1122       |> Enum.map(fn %{"icon" => %{"url" => url}, "name" => name} ->
1123         {String.trim(name, ":"), url}
1124       end)
1125
1126     bio
1127     |> CommonUtils.format_input(mentions, tags, "text/plain", user_links: [format: :full])
1128     |> Formatter.emojify(emoji)
1129   end
1130
1131   def tag(user_identifiers, tags) when is_list(user_identifiers) do
1132     Repo.transaction(fn ->
1133       for user_identifier <- user_identifiers, do: tag(user_identifier, tags)
1134     end)
1135   end
1136
1137   def tag(nickname, tags) when is_binary(nickname),
1138     do: tag(User.get_by_nickname(nickname), tags)
1139
1140   def tag(%User{} = user, tags),
1141     do: update_tags(user, Enum.uniq((user.tags || []) ++ normalize_tags(tags)))
1142
1143   def untag(user_identifiers, tags) when is_list(user_identifiers) do
1144     Repo.transaction(fn ->
1145       for user_identifier <- user_identifiers, do: untag(user_identifier, tags)
1146     end)
1147   end
1148
1149   def untag(nickname, tags) when is_binary(nickname),
1150     do: untag(User.get_by_nickname(nickname), tags)
1151
1152   def untag(%User{} = user, tags),
1153     do: update_tags(user, (user.tags || []) -- normalize_tags(tags))
1154
1155   defp update_tags(%User{} = user, new_tags) do
1156     {:ok, updated_user} =
1157       user
1158       |> change(%{tags: new_tags})
1159       |> Repo.update()
1160
1161     updated_user
1162   end
1163
1164   defp normalize_tags(tags) do
1165     [tags]
1166     |> List.flatten()
1167     |> Enum.map(&String.downcase(&1))
1168   end
1169
1170   defp local_nickname_regex() do
1171     if Pleroma.Config.get([:instance, :extended_nickname_format]) do
1172       @extended_local_nickname_regex
1173     else
1174       @strict_local_nickname_regex
1175     end
1176   end
1177
1178   def local_nickname(nickname_or_mention) do
1179     nickname_or_mention
1180     |> full_nickname()
1181     |> String.split("@")
1182     |> hd()
1183   end
1184
1185   def full_nickname(nickname_or_mention),
1186     do: String.trim_leading(nickname_or_mention, "@")
1187
1188   def error_user(ap_id) do
1189     %User{
1190       name: ap_id,
1191       ap_id: ap_id,
1192       info: %User.Info{},
1193       nickname: "erroruser@example.com",
1194       inserted_at: NaiveDateTime.utc_now()
1195     }
1196   end
1197 end