git.squeep.com Git - akkoma/blob - lib/pleroma/user.ex

   1 defmodule Pleroma.User do
   2   use Ecto.Schema
   3   import Ecto.Changeset
   4   alias Pleroma.{Repo, User}
   5
   6   schema "users" do
   7     field :bio, :string
   8     field :email, :string
   9     field :name, :string
  10     field :nickname, :string
  11     field :password_hash, :string
  12     field :password, :string, virtual: true
  13     field :password_confirmation, :string, virtual: true
  14     field :following, { :array, :string }, default: []
  15     field :ap_id, :string
  16     field :avatar, :map
  17
  18     timestamps()
  19   end
  20
  21   def ap_id(%User{nickname: nickname}) do
  22     "#{Pleroma.Web.base_url}/users/#{nickname}"
  23   end
  24
  25   def ap_followers(%User{} = user) do
  26     "#{ap_id(user)}/followers"
  27   end
  28
  29   def follow_changeset(struct, params \\ %{}) do
  30     struct
  31     |> cast(params, [:following])
  32     |> validate_required([:following])
  33   end
  34
  35   def register_changeset(struct, params \\ %{}) do
  36     changeset = struct
  37     |> cast(params, [:bio, :email, :name, :nickname, :password, :password_confirmation])
  38     |> validate_required([:bio, :email, :name, :nickname, :password, :password_confirmation])
  39     |> validate_confirmation(:password)
  40     |> unique_constraint(:email)
  41     |> unique_constraint(:nickname)
  42
  43     if changeset.valid? do
  44       hashed = Comeonin.Pbkdf2.hashpwsalt(changeset.changes[:password])
  45       ap_id = User.ap_id(%User{nickname: changeset.changes[:nickname]})
  46       followers = User.ap_followers(%User{nickname: changeset.changes[:nickname]})
  47       changeset
  48       |> put_change(:password_hash, hashed)
  49       |> put_change(:ap_id, ap_id)
  50       |> put_change(:following, [followers])
  51     else
  52       changeset
  53     end
  54   end
  55
  56   def follow(%User{} = follower, %User{} = followed) do
  57     ap_followers = User.ap_followers(followed)
  58     following = [ap_followers | follower.following]
  59     |> Enum.uniq
  60
  61     follower
  62     |> follow_changeset(%{following: following})
  63     |> Repo.update
  64   end
  65
  66   def unfollow(%User{} = follower, %User{} = followed) do
  67     ap_followers = User.ap_followers(followed)
  68     following = follower.following
  69     |> List.delete(ap_followers)
  70
  71     follower
  72     |> follow_changeset(%{following: following})
  73     |> Repo.update
  74   end
  75
  76   def following?(%User{} = follower, %User{} = followed) do
  77     Enum.member?(follower.following, User.ap_followers(followed))
  78   end
  79
  80   def get_cached_by_ap_id(ap_id) do
  81     key = "ap_id:#{ap_id}"
  82     Cachex.get!(:user_cache, key, fallback: fn(_) -> Repo.get_by(User, ap_id: ap_id) end)
  83   end
  84
  85   def get_cached_by_nickname(nickname) do
  86     key = "nickname:#{nickname}"
  87     Cachex.get!(:user_cache, key, fallback: fn(_) -> Repo.get_by(User, nickname: nickname) end)
  88   end
  89 end