git.squeep.com Git - akkoma/blob - lib/pleroma/user.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.User do
   6   use Ecto.Schema
   7
   8   import Ecto.{Changeset, Query}
   9   alias Pleroma.{Repo, User, Object, Web, Activity, Notification}
  10   alias Comeonin.Pbkdf2
  11   alias Pleroma.Formatter
  12   alias Pleroma.Web.CommonAPI.Utils, as: CommonUtils
  13   alias Pleroma.Web.{OStatus, Websub, OAuth}
  14   alias Pleroma.Web.ActivityPub.{Utils, ActivityPub}
  15
  16   require Logger
  17
  18   @type t :: %__MODULE__{}
  19
  20   @email_regex ~r/^[a-zA-Z0-9.!#$%&'*+\/=?^_`{|}~-]+@[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?(?:\.[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?)*$/
  21
  22   @strict_local_nickname_regex ~r/^[a-zA-Z\d]+$/
  23   @extended_local_nickname_regex ~r/^[a-zA-Z\d_-]+$/
  24
  25   schema "users" do
  26     field(:bio, :string)
  27     field(:email, :string)
  28     field(:name, :string)
  29     field(:nickname, :string)
  30     field(:password_hash, :string)
  31     field(:password, :string, virtual: true)
  32     field(:password_confirmation, :string, virtual: true)
  33     field(:following, {:array, :string}, default: [])
  34     field(:ap_id, :string)
  35     field(:avatar, :map)
  36     field(:local, :boolean, default: true)
  37     field(:follower_address, :string)
  38     field(:search_distance, :float, virtual: true)
  39     field(:tags, {:array, :string}, default: [])
  40     field(:last_refreshed_at, :naive_datetime)
  41     has_many(:notifications, Notification)
  42     embeds_one(:info, Pleroma.User.Info)
  43
  44     timestamps()
  45   end
  46
  47   def auth_active?(%User{local: false}), do: true
  48
  49   def auth_active?(%User{info: %User.Info{confirmation_pending: false}}), do: true
  50
  51   def auth_active?(%User{info: %User.Info{confirmation_pending: true}}),
  52     do: !Pleroma.Config.get([:instance, :account_activation_required])
  53
  54   def auth_active?(_), do: false
  55
  56   def visible_for?(user, for_user \\ nil)
  57
  58   def visible_for?(%User{id: user_id}, %User{id: for_id}) when user_id == for_id, do: true
  59
  60   def visible_for?(%User{} = user, for_user) do
  61     auth_active?(user) || superuser?(for_user)
  62   end
  63
  64   def visible_for?(_, _), do: false
  65
  66   def superuser?(%User{local: true, info: %User.Info{is_admin: true}}), do: true
  67   def superuser?(%User{local: true, info: %User.Info{is_moderator: true}}), do: true
  68   def superuser?(_), do: false
  69
  70   def avatar_url(user) do
  71     case user.avatar do
  72       %{"url" => [%{"href" => href} | _]} -> href
  73       _ -> "#{Web.base_url()}/images/avi.png"
  74     end
  75   end
  76
  77   def banner_url(user) do
  78     case user.info.banner do
  79       %{"url" => [%{"href" => href} | _]} -> href
  80       _ -> "#{Web.base_url()}/images/banner.png"
  81     end
  82   end
  83
  84   def profile_url(%User{info: %{source_data: %{"url" => url}}}), do: url
  85   def profile_url(%User{ap_id: ap_id}), do: ap_id
  86   def profile_url(_), do: nil
  87
  88   def ap_id(%User{nickname: nickname}) do
  89     "#{Web.base_url()}/users/#{nickname}"
  90   end
  91
  92   def ap_followers(%User{} = user) do
  93     "#{ap_id(user)}/followers"
  94   end
  95
  96   def follow_changeset(struct, params \\ %{}) do
  97     struct
  98     |> cast(params, [:following])
  99     |> validate_required([:following])
 100   end
 101
 102   def user_info(%User{} = user) do
 103     oneself = if user.local, do: 1, else: 0
 104
 105     %{
 106       following_count: length(user.following) - oneself,
 107       note_count: user.info.note_count,
 108       follower_count: user.info.follower_count,
 109       locked: user.info.locked,
 110       confirmation_pending: user.info.confirmation_pending,
 111       default_scope: user.info.default_scope
 112     }
 113   end
 114
 115   def remote_user_creation(params) do
 116     params =
 117       params
 118       |> Map.put(:info, params[:info] || %{})
 119
 120     info_cng = User.Info.remote_user_creation(%User.Info{}, params[:info])
 121
 122     changes =
 123       %User{}
 124       |> cast(params, [:bio, :name, :ap_id, :nickname, :avatar])
 125       |> validate_required([:name, :ap_id])
 126       |> unique_constraint(:nickname)
 127       |> validate_format(:nickname, @email_regex)
 128       |> validate_length(:bio, max: 5000)
 129       |> validate_length(:name, max: 100)
 130       |> put_change(:local, false)
 131       |> put_embed(:info, info_cng)
 132
 133     if changes.valid? do
 134       case info_cng.changes[:source_data] do
 135         %{"followers" => followers} ->
 136           changes
 137           |> put_change(:follower_address, followers)
 138
 139         _ ->
 140           followers = User.ap_followers(%User{nickname: changes.changes[:nickname]})
 141
 142           changes
 143           |> put_change(:follower_address, followers)
 144       end
 145     else
 146       changes
 147     end
 148   end
 149
 150   def update_changeset(struct, params \\ %{}) do
 151     struct
 152     |> cast(params, [:bio, :name, :avatar])
 153     |> unique_constraint(:nickname)
 154     |> validate_format(:nickname, local_nickname_regex())
 155     |> validate_length(:bio, max: 5000)
 156     |> validate_length(:name, min: 1, max: 100)
 157   end
 158
 159   def upgrade_changeset(struct, params \\ %{}) do
 160     params =
 161       params
 162       |> Map.put(:last_refreshed_at, NaiveDateTime.utc_now())
 163
 164     info_cng =
 165       struct.info
 166       |> User.Info.user_upgrade(params[:info])
 167
 168     struct
 169     |> cast(params, [:bio, :name, :follower_address, :avatar, :last_refreshed_at])
 170     |> unique_constraint(:nickname)
 171     |> validate_format(:nickname, local_nickname_regex())
 172     |> validate_length(:bio, max: 5000)
 173     |> validate_length(:name, max: 100)
 174     |> put_embed(:info, info_cng)
 175   end
 176
 177   def password_update_changeset(struct, params) do
 178     changeset =
 179       struct
 180       |> cast(params, [:password, :password_confirmation])
 181       |> validate_required([:password, :password_confirmation])
 182       |> validate_confirmation(:password)
 183
 184     OAuth.Token.delete_user_tokens(struct)
 185     OAuth.Authorization.delete_user_authorizations(struct)
 186
 187     if changeset.valid? do
 188       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 189
 190       changeset
 191       |> put_change(:password_hash, hashed)
 192     else
 193       changeset
 194     end
 195   end
 196
 197   def reset_password(user, data) do
 198     update_and_set_cache(password_update_changeset(user, data))
 199   end
 200
 201   def register_changeset(struct, params \\ %{}, opts \\ []) do
 202     confirmation_status =
 203       if opts[:confirmed] || !Pleroma.Config.get([:instance, :account_activation_required]) do
 204         :confirmed
 205       else
 206         :unconfirmed
 207       end
 208
 209     info_change = User.Info.confirmation_changeset(%User.Info{}, confirmation_status)
 210
 211     changeset =
 212       struct
 213       |> cast(params, [:bio, :email, :name, :nickname, :password, :password_confirmation])
 214       |> validate_required([:email, :name, :nickname, :password, :password_confirmation])
 215       |> validate_confirmation(:password)
 216       |> unique_constraint(:email)
 217       |> unique_constraint(:nickname)
 218       |> validate_exclusion(:nickname, Pleroma.Config.get([Pleroma.User, :restricted_nicknames]))
 219       |> validate_format(:nickname, local_nickname_regex())
 220       |> validate_format(:email, @email_regex)
 221       |> validate_length(:bio, max: 1000)
 222       |> validate_length(:name, min: 1, max: 100)
 223       |> put_change(:info, info_change)
 224
 225     if changeset.valid? do
 226       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 227       ap_id = User.ap_id(%User{nickname: changeset.changes[:nickname]})
 228       followers = User.ap_followers(%User{nickname: changeset.changes[:nickname]})
 229
 230       changeset
 231       |> put_change(:password_hash, hashed)
 232       |> put_change(:ap_id, ap_id)
 233       |> put_change(:following, [followers])
 234       |> put_change(:follower_address, followers)
 235     else
 236       changeset
 237     end
 238   end
 239
 240   defp autofollow_users(user) do
 241     candidates = Pleroma.Config.get([:instance, :autofollowed_nicknames])
 242
 243     autofollowed_users =
 244       from(u in User,
 245         where: u.local == true,
 246         where: u.nickname in ^candidates
 247       )
 248       |> Repo.all()
 249
 250     follow_all(user, autofollowed_users)
 251   end
 252
 253   @doc "Inserts provided changeset, performs post-registration actions (confirmation email sending etc.)"
 254   def register(%Ecto.Changeset{} = changeset) do
 255     with {:ok, user} <- Repo.insert(changeset),
 256          {:ok, _} <- try_send_confirmation_email(user),
 257          {:ok, user} <- autofollow_users(user) do
 258       {:ok, user}
 259     end
 260   end
 261
 262   def try_send_confirmation_email(%User{} = user) do
 263     if user.info.confirmation_pending &&
 264          Pleroma.Config.get([:instance, :account_activation_required]) do
 265       user
 266       |> Pleroma.UserEmail.account_confirmation_email()
 267       |> Pleroma.Mailer.deliver()
 268     else
 269       {:ok, :noop}
 270     end
 271   end
 272
 273   def needs_update?(%User{local: true}), do: false
 274
 275   def needs_update?(%User{local: false, last_refreshed_at: nil}), do: true
 276
 277   def needs_update?(%User{local: false} = user) do
 278     NaiveDateTime.diff(NaiveDateTime.utc_now(), user.last_refreshed_at) >= 86400
 279   end
 280
 281   def needs_update?(_), do: true
 282
 283   def maybe_direct_follow(%User{} = follower, %User{local: true, info: %{locked: true}}) do
 284     {:ok, follower}
 285   end
 286
 287   def maybe_direct_follow(%User{} = follower, %User{local: true} = followed) do
 288     follow(follower, followed)
 289   end
 290
 291   def maybe_direct_follow(%User{} = follower, %User{} = followed) do
 292     if not User.ap_enabled?(followed) do
 293       follow(follower, followed)
 294     else
 295       {:ok, follower}
 296     end
 297   end
 298
 299   def maybe_follow(%User{} = follower, %User{info: _info} = followed) do
 300     if not following?(follower, followed) do
 301       follow(follower, followed)
 302     else
 303       {:ok, follower}
 304     end
 305   end
 306
 307   @doc "A mass follow for local users. Ignores blocks and has no side effects"
 308   @spec follow_all(User.t(), list(User.t())) :: {atom(), User.t()}
 309   def follow_all(follower, followeds) do
 310     following =
 311       (follower.following ++ Enum.map(followeds, fn %{follower_address: fa} -> fa end))
 312       |> Enum.uniq()
 313
 314     {:ok, follower} =
 315       follower
 316       |> follow_changeset(%{following: following})
 317       |> update_and_set_cache
 318
 319     Enum.each(followeds, fn followed ->
 320       update_follower_count(followed)
 321     end)
 322
 323     {:ok, follower}
 324   end
 325
 326   def follow(%User{} = follower, %User{info: info} = followed) do
 327     user_config = Application.get_env(:pleroma, :user)
 328     deny_follow_blocked = Keyword.get(user_config, :deny_follow_blocked)
 329
 330     ap_followers = followed.follower_address
 331
 332     cond do
 333       following?(follower, followed) or info.deactivated ->
 334         {:error, "Could not follow user: #{followed.nickname} is already on your list."}
 335
 336       deny_follow_blocked and blocks?(followed, follower) ->
 337         {:error, "Could not follow user: #{followed.nickname} blocked you."}
 338
 339       true ->
 340         if !followed.local && follower.local && !ap_enabled?(followed) do
 341           Websub.subscribe(follower, followed)
 342         end
 343
 344         following =
 345           [ap_followers | follower.following]
 346           |> Enum.uniq()
 347
 348         follower =
 349           follower
 350           |> follow_changeset(%{following: following})
 351           |> update_and_set_cache
 352
 353         {:ok, _} = update_follower_count(followed)
 354
 355         follower
 356     end
 357   end
 358
 359   def unfollow(%User{} = follower, %User{} = followed) do
 360     ap_followers = followed.follower_address
 361
 362     if following?(follower, followed) and follower.ap_id != followed.ap_id do
 363       following =
 364         follower.following
 365         |> List.delete(ap_followers)
 366
 367       {:ok, follower} =
 368         follower
 369         |> follow_changeset(%{following: following})
 370         |> update_and_set_cache
 371
 372       {:ok, followed} = update_follower_count(followed)
 373
 374       {:ok, follower, Utils.fetch_latest_follow(follower, followed)}
 375     else
 376       {:error, "Not subscribed!"}
 377     end
 378   end
 379
 380   @spec following?(User.t(), User.t()) :: boolean
 381   def following?(%User{} = follower, %User{} = followed) do
 382     Enum.member?(follower.following, followed.follower_address)
 383   end
 384
 385   def follow_import(%User{} = follower, followed_identifiers)
 386       when is_list(followed_identifiers) do
 387     Enum.map(
 388       followed_identifiers,
 389       fn followed_identifier ->
 390         with %User{} = followed <- get_or_fetch(followed_identifier),
 391              {:ok, follower} <- maybe_direct_follow(follower, followed),
 392              {:ok, _} <- ActivityPub.follow(follower, followed) do
 393           followed
 394         else
 395           err ->
 396             Logger.debug("follow_import failed for #{followed_identifier} with: #{inspect(err)}")
 397             err
 398         end
 399       end
 400     )
 401   end
 402
 403   def locked?(%User{} = user) do
 404     user.info.locked || false
 405   end
 406
 407   def get_by_ap_id(ap_id) do
 408     Repo.get_by(User, ap_id: ap_id)
 409   end
 410
 411   # This is mostly an SPC migration fix. This guesses the user nickname (by taking the last part of the ap_id and the domain) and tries to get that user
 412   def get_by_guessed_nickname(ap_id) do
 413     domain = URI.parse(ap_id).host
 414     name = List.last(String.split(ap_id, "/"))
 415     nickname = "#{name}@#{domain}"
 416
 417     get_by_nickname(nickname)
 418   end
 419
 420   def update_and_set_cache(changeset) do
 421     with {:ok, user} <- Repo.update(changeset) do
 422       Cachex.put(:user_cache, "ap_id:#{user.ap_id}", user)
 423       Cachex.put(:user_cache, "nickname:#{user.nickname}", user)
 424       Cachex.put(:user_cache, "user_info:#{user.id}", user_info(user))
 425       {:ok, user}
 426     else
 427       e -> e
 428     end
 429   end
 430
 431   def invalidate_cache(user) do
 432     Cachex.del(:user_cache, "ap_id:#{user.ap_id}")
 433     Cachex.del(:user_cache, "nickname:#{user.nickname}")
 434     Cachex.del(:user_cache, "user_info:#{user.id}")
 435   end
 436
 437   def get_cached_by_ap_id(ap_id) do
 438     key = "ap_id:#{ap_id}"
 439     Cachex.fetch!(:user_cache, key, fn _ -> get_by_ap_id(ap_id) end)
 440   end
 441
 442   def get_cached_by_nickname(nickname) do
 443     key = "nickname:#{nickname}"
 444     Cachex.fetch!(:user_cache, key, fn _ -> get_or_fetch_by_nickname(nickname) end)
 445   end
 446
 447   def get_by_nickname(nickname) do
 448     Repo.get_by(User, nickname: nickname) ||
 449       if Regex.match?(~r(@#{Pleroma.Web.Endpoint.host()})i, nickname) do
 450         Repo.get_by(User, nickname: local_nickname(nickname))
 451       end
 452   end
 453
 454   def get_by_nickname_or_email(nickname_or_email) do
 455     case user = Repo.get_by(User, nickname: nickname_or_email) do
 456       %User{} -> user
 457       nil -> Repo.get_by(User, email: nickname_or_email)
 458     end
 459   end
 460
 461   def get_cached_user_info(user) do
 462     key = "user_info:#{user.id}"
 463     Cachex.fetch!(:user_cache, key, fn _ -> user_info(user) end)
 464   end
 465
 466   def fetch_by_nickname(nickname) do
 467     ap_try = ActivityPub.make_user_from_nickname(nickname)
 468
 469     case ap_try do
 470       {:ok, user} -> {:ok, user}
 471       _ -> OStatus.make_user(nickname)
 472     end
 473   end
 474
 475   def get_or_fetch_by_nickname(nickname) do
 476     with %User{} = user <- get_by_nickname(nickname) do
 477       user
 478     else
 479       _e ->
 480         with [_nick, _domain] <- String.split(nickname, "@"),
 481              {:ok, user} <- fetch_by_nickname(nickname) do
 482           user
 483         else
 484           _e -> nil
 485         end
 486     end
 487   end
 488
 489   def get_followers_query(%User{id: id, follower_address: follower_address}, nil) do
 490     from(
 491       u in User,
 492       where: fragment("? <@ ?", ^[follower_address], u.following),
 493       where: u.id != ^id
 494     )
 495   end
 496
 497   def get_followers_query(user, page) do
 498     from(
 499       u in get_followers_query(user, nil),
 500       limit: 20,
 501       offset: ^((page - 1) * 20)
 502     )
 503   end
 504
 505   def get_followers_query(user), do: get_followers_query(user, nil)
 506
 507   def get_followers(user, page \\ nil) do
 508     q = get_followers_query(user, page)
 509
 510     {:ok, Repo.all(q)}
 511   end
 512
 513   def get_friends_query(%User{id: id, following: following}, nil) do
 514     from(
 515       u in User,
 516       where: u.follower_address in ^following,
 517       where: u.id != ^id
 518     )
 519   end
 520
 521   def get_friends_query(user, page) do
 522     from(
 523       u in get_friends_query(user, nil),
 524       limit: 20,
 525       offset: ^((page - 1) * 20)
 526     )
 527   end
 528
 529   def get_friends_query(user), do: get_friends_query(user, nil)
 530
 531   def get_friends(user, page \\ nil) do
 532     q = get_friends_query(user, page)
 533
 534     {:ok, Repo.all(q)}
 535   end
 536
 537   def get_follow_requests_query(%User{} = user) do
 538     from(
 539       a in Activity,
 540       where:
 541         fragment(
 542           "? ->> 'type' = 'Follow'",
 543           a.data
 544         ),
 545       where:
 546         fragment(
 547           "? ->> 'state' = 'pending'",
 548           a.data
 549         ),
 550       where:
 551         fragment(
 552           "? @> ?",
 553           a.data,
 554           ^%{"object" => user.ap_id}
 555         )
 556     )
 557   end
 558
 559   def get_follow_requests(%User{} = user) do
 560     q = get_follow_requests_query(user)
 561     reqs = Repo.all(q)
 562
 563     users =
 564       Enum.map(reqs, fn req -> req.actor end)
 565       |> Enum.uniq()
 566       |> Enum.map(fn ap_id -> get_by_ap_id(ap_id) end)
 567       |> Enum.filter(fn u -> !is_nil(u) end)
 568       |> Enum.filter(fn u -> !following?(u, user) end)
 569
 570     {:ok, users}
 571   end
 572
 573   def increase_note_count(%User{} = user) do
 574     info_cng = User.Info.add_to_note_count(user.info, 1)
 575
 576     cng =
 577       change(user)
 578       |> put_embed(:info, info_cng)
 579
 580     update_and_set_cache(cng)
 581   end
 582
 583   def decrease_note_count(%User{} = user) do
 584     info_cng = User.Info.add_to_note_count(user.info, -1)
 585
 586     cng =
 587       change(user)
 588       |> put_embed(:info, info_cng)
 589
 590     update_and_set_cache(cng)
 591   end
 592
 593   def update_note_count(%User{} = user) do
 594     note_count_query =
 595       from(
 596         a in Object,
 597         where: fragment("?->>'actor' = ? and ?->>'type' = 'Note'", a.data, ^user.ap_id, a.data),
 598         select: count(a.id)
 599       )
 600
 601     note_count = Repo.one(note_count_query)
 602
 603     info_cng = User.Info.set_note_count(user.info, note_count)
 604
 605     cng =
 606       change(user)
 607       |> put_embed(:info, info_cng)
 608
 609     update_and_set_cache(cng)
 610   end
 611
 612   def update_follower_count(%User{} = user) do
 613     follower_count_query =
 614       from(
 615         u in User,
 616         where: ^user.follower_address in u.following,
 617         where: u.id != ^user.id,
 618         select: count(u.id)
 619       )
 620
 621     follower_count = Repo.one(follower_count_query)
 622
 623     info_cng =
 624       user.info
 625       |> User.Info.set_follower_count(follower_count)
 626
 627     cng =
 628       change(user)
 629       |> put_embed(:info, info_cng)
 630
 631     update_and_set_cache(cng)
 632   end
 633
 634   def get_users_from_set_query(ap_ids, false) do
 635     from(
 636       u in User,
 637       where: u.ap_id in ^ap_ids
 638     )
 639   end
 640
 641   def get_users_from_set_query(ap_ids, true) do
 642     query = get_users_from_set_query(ap_ids, false)
 643
 644     from(
 645       u in query,
 646       where: u.local == true
 647     )
 648   end
 649
 650   def get_users_from_set(ap_ids, local_only \\ true) do
 651     get_users_from_set_query(ap_ids, local_only)
 652     |> Repo.all()
 653   end
 654
 655   def get_recipients_from_activity(%Activity{recipients: to}) do
 656     query =
 657       from(
 658         u in User,
 659         where: u.ap_id in ^to,
 660         or_where: fragment("? && ?", u.following, ^to)
 661       )
 662
 663     query = from(u in query, where: u.local == true)
 664
 665     Repo.all(query)
 666   end
 667
 668   def search(query, resolve \\ false) do
 669     # strip the beginning @ off if there is a query
 670     query = String.trim_leading(query, "@")
 671
 672     if resolve do
 673       User.get_or_fetch_by_nickname(query)
 674     end
 675
 676     inner =
 677       from(
 678         u in User,
 679         select_merge: %{
 680           search_distance:
 681             fragment(
 682               "? <-> (? || coalesce(?, ''))",
 683               ^query,
 684               u.nickname,
 685               u.name
 686             )
 687         },
 688         where: not is_nil(u.nickname)
 689       )
 690
 691     q =
 692       from(
 693         s in subquery(inner),
 694         order_by: s.search_distance,
 695         limit: 20
 696       )
 697
 698     Repo.all(q)
 699   end
 700
 701   def blocks_import(%User{} = blocker, blocked_identifiers) when is_list(blocked_identifiers) do
 702     Enum.map(
 703       blocked_identifiers,
 704       fn blocked_identifier ->
 705         with %User{} = blocked <- get_or_fetch(blocked_identifier),
 706              {:ok, blocker} <- block(blocker, blocked),
 707              {:ok, _} <- ActivityPub.block(blocker, blocked) do
 708           blocked
 709         else
 710           err ->
 711             Logger.debug("blocks_import failed for #{blocked_identifier} with: #{inspect(err)}")
 712             err
 713         end
 714       end
 715     )
 716   end
 717
 718   def block(blocker, %User{ap_id: ap_id} = blocked) do
 719     # sever any follow relationships to prevent leaks per activitypub (Pleroma issue #213)
 720     blocker =
 721       if following?(blocker, blocked) do
 722         {:ok, blocker, _} = unfollow(blocker, blocked)
 723         blocker
 724       else
 725         blocker
 726       end
 727
 728     if following?(blocked, blocker) do
 729       unfollow(blocked, blocker)
 730     end
 731
 732     info_cng =
 733       blocker.info
 734       |> User.Info.add_to_block(ap_id)
 735
 736     cng =
 737       change(blocker)
 738       |> put_embed(:info, info_cng)
 739
 740     update_and_set_cache(cng)
 741   end
 742
 743   # helper to handle the block given only an actor's AP id
 744   def block(blocker, %{ap_id: ap_id}) do
 745     block(blocker, User.get_by_ap_id(ap_id))
 746   end
 747
 748   def unblock(blocker, %{ap_id: ap_id}) do
 749     info_cng =
 750       blocker.info
 751       |> User.Info.remove_from_block(ap_id)
 752
 753     cng =
 754       change(blocker)
 755       |> put_embed(:info, info_cng)
 756
 757     update_and_set_cache(cng)
 758   end
 759
 760   def blocks?(user, %{ap_id: ap_id}) do
 761     blocks = user.info.blocks
 762     domain_blocks = user.info.domain_blocks
 763     %{host: host} = URI.parse(ap_id)
 764
 765     Enum.member?(blocks, ap_id) ||
 766       Enum.any?(domain_blocks, fn domain ->
 767         host == domain
 768       end)
 769   end
 770
 771   def blocked_users(user),
 772     do: Repo.all(from(u in User, where: u.ap_id in ^user.info.blocks))
 773
 774   def block_domain(user, domain) do
 775     info_cng =
 776       user.info
 777       |> User.Info.add_to_domain_block(domain)
 778
 779     cng =
 780       change(user)
 781       |> put_embed(:info, info_cng)
 782
 783     update_and_set_cache(cng)
 784   end
 785
 786   def unblock_domain(user, domain) do
 787     info_cng =
 788       user.info
 789       |> User.Info.remove_from_domain_block(domain)
 790
 791     cng =
 792       change(user)
 793       |> put_embed(:info, info_cng)
 794
 795     update_and_set_cache(cng)
 796   end
 797
 798   def local_user_query do
 799     from(
 800       u in User,
 801       where: u.local == true,
 802       where: not is_nil(u.nickname)
 803     )
 804   end
 805
 806   def active_local_user_query do
 807     from(
 808       u in local_user_query(),
 809       where: fragment("?->'deactivated' @> 'false'", u.info)
 810     )
 811   end
 812
 813   def moderator_user_query do
 814     from(
 815       u in User,
 816       where: u.local == true,
 817       where: fragment("?->'is_moderator' @> 'true'", u.info)
 818     )
 819   end
 820
 821   def deactivate(%User{} = user, status \\ true) do
 822     info_cng = User.Info.set_activation_status(user.info, status)
 823
 824     cng =
 825       change(user)
 826       |> put_embed(:info, info_cng)
 827
 828     update_and_set_cache(cng)
 829   end
 830
 831   def delete(%User{} = user) do
 832     {:ok, user} = User.deactivate(user)
 833
 834     # Remove all relationships
 835     {:ok, followers} = User.get_followers(user)
 836
 837     followers
 838     |> Enum.each(fn follower -> User.unfollow(follower, user) end)
 839
 840     {:ok, friends} = User.get_friends(user)
 841
 842     friends
 843     |> Enum.each(fn followed -> User.unfollow(user, followed) end)
 844
 845     query = from(a in Activity, where: a.actor == ^user.ap_id)
 846
 847     Repo.all(query)
 848     |> Enum.each(fn activity ->
 849       case activity.data["type"] do
 850         "Create" ->
 851           ActivityPub.delete(Object.normalize(activity.data["object"]))
 852
 853         # TODO: Do something with likes, follows, repeats.
 854         _ ->
 855           "Doing nothing"
 856       end
 857     end)
 858
 859     {:ok, user}
 860   end
 861
 862   def html_filter_policy(%User{info: %{no_rich_text: true}}) do
 863     Pleroma.HTML.Scrubber.TwitterText
 864   end
 865
 866   @default_scrubbers Pleroma.Config.get([:markup, :scrub_policy])
 867
 868   def html_filter_policy(_), do: @default_scrubbers
 869
 870   def get_or_fetch_by_ap_id(ap_id) do
 871     user = get_by_ap_id(ap_id)
 872
 873     if !is_nil(user) and !User.needs_update?(user) do
 874       user
 875     else
 876       ap_try = ActivityPub.make_user_from_ap_id(ap_id)
 877
 878       case ap_try do
 879         {:ok, user} ->
 880           user
 881
 882         _ ->
 883           case OStatus.make_user(ap_id) do
 884             {:ok, user} -> user
 885             _ -> {:error, "Could not fetch by AP id"}
 886           end
 887       end
 888     end
 889   end
 890
 891   def get_or_create_instance_user do
 892     relay_uri = "#{Pleroma.Web.Endpoint.url()}/relay"
 893
 894     if user = get_by_ap_id(relay_uri) do
 895       user
 896     else
 897       changes =
 898         %User{info: %User.Info{}}
 899         |> cast(%{}, [:ap_id, :nickname, :local])
 900         |> put_change(:ap_id, relay_uri)
 901         |> put_change(:nickname, nil)
 902         |> put_change(:local, true)
 903         |> put_change(:follower_address, relay_uri <> "/followers")
 904
 905       {:ok, user} = Repo.insert(changes)
 906       user
 907     end
 908   end
 909
 910   # AP style
 911   def public_key_from_info(%{
 912         source_data: %{"publicKey" => %{"publicKeyPem" => public_key_pem}}
 913       }) do
 914     key =
 915       public_key_pem
 916       |> :public_key.pem_decode()
 917       |> hd()
 918       |> :public_key.pem_entry_decode()
 919
 920     {:ok, key}
 921   end
 922
 923   # OStatus Magic Key
 924   def public_key_from_info(%{magic_key: magic_key}) do
 925     {:ok, Pleroma.Web.Salmon.decode_key(magic_key)}
 926   end
 927
 928   def get_public_key_for_ap_id(ap_id) do
 929     with %User{} = user <- get_or_fetch_by_ap_id(ap_id),
 930          {:ok, public_key} <- public_key_from_info(user.info) do
 931       {:ok, public_key}
 932     else
 933       _ -> :error
 934     end
 935   end
 936
 937   defp blank?(""), do: nil
 938   defp blank?(n), do: n
 939
 940   def insert_or_update_user(data) do
 941     data =
 942       data
 943       |> Map.put(:name, blank?(data[:name]) || data[:nickname])
 944
 945     cs = User.remote_user_creation(data)
 946
 947     Repo.insert(cs, on_conflict: :replace_all, conflict_target: :nickname)
 948   end
 949
 950   def ap_enabled?(%User{local: true}), do: true
 951   def ap_enabled?(%User{info: info}), do: info.ap_enabled
 952   def ap_enabled?(_), do: false
 953
 954   @doc "Gets or fetch a user by uri or nickname."
 955   @spec get_or_fetch(String.t()) :: User.t()
 956   def get_or_fetch("http" <> _host = uri), do: get_or_fetch_by_ap_id(uri)
 957   def get_or_fetch(nickname), do: get_or_fetch_by_nickname(nickname)
 958
 959   # wait a period of time and return newest version of the User structs
 960   # this is because we have synchronous follow APIs and need to simulate them
 961   # with an async handshake
 962   def wait_and_refresh(_, %User{local: true} = a, %User{local: true} = b) do
 963     with %User{} = a <- Repo.get(User, a.id),
 964          %User{} = b <- Repo.get(User, b.id) do
 965       {:ok, a, b}
 966     else
 967       _e ->
 968         :error
 969     end
 970   end
 971
 972   def wait_and_refresh(timeout, %User{} = a, %User{} = b) do
 973     with :ok <- :timer.sleep(timeout),
 974          %User{} = a <- Repo.get(User, a.id),
 975          %User{} = b <- Repo.get(User, b.id) do
 976       {:ok, a, b}
 977     else
 978       _e ->
 979         :error
 980     end
 981   end
 982
 983   def parse_bio(bio, user \\ %User{info: %{source_data: %{}}})
 984   def parse_bio(nil, _user), do: ""
 985   def parse_bio(bio, _user) when bio == "", do: bio
 986
 987   def parse_bio(bio, user) do
 988     mentions = Formatter.parse_mentions(bio)
 989     tags = Formatter.parse_tags(bio)
 990
 991     emoji =
 992       (user.info.source_data["tag"] || [])
 993       |> Enum.filter(fn %{"type" => t} -> t == "Emoji" end)
 994       |> Enum.map(fn %{"icon" => %{"url" => url}, "name" => name} ->
 995         {String.trim(name, ":"), url}
 996       end)
 997
 998     bio
 999     |> CommonUtils.format_input(mentions, tags, "text/plain", user_links: [format: :full])
1000     |> Formatter.emojify(emoji)
1001   end
1002
1003   def tag(user_identifiers, tags) when is_list(user_identifiers) do
1004     Repo.transaction(fn ->
1005       for user_identifier <- user_identifiers, do: tag(user_identifier, tags)
1006     end)
1007   end
1008
1009   def tag(nickname, tags) when is_binary(nickname),
1010     do: tag(User.get_by_nickname(nickname), tags)
1011
1012   def tag(%User{} = user, tags),
1013     do: update_tags(user, Enum.uniq((user.tags || []) ++ normalize_tags(tags)))
1014
1015   def untag(user_identifiers, tags) when is_list(user_identifiers) do
1016     Repo.transaction(fn ->
1017       for user_identifier <- user_identifiers, do: untag(user_identifier, tags)
1018     end)
1019   end
1020
1021   def untag(nickname, tags) when is_binary(nickname),
1022     do: untag(User.get_by_nickname(nickname), tags)
1023
1024   def untag(%User{} = user, tags),
1025     do: update_tags(user, (user.tags || []) -- normalize_tags(tags))
1026
1027   defp update_tags(%User{} = user, new_tags) do
1028     {:ok, updated_user} =
1029       user
1030       |> change(%{tags: new_tags})
1031       |> Repo.update()
1032
1033     updated_user
1034   end
1035
1036   defp normalize_tags(tags) do
1037     [tags]
1038     |> List.flatten()
1039     |> Enum.map(&String.downcase(&1))
1040   end
1041
1042   defp local_nickname_regex() do
1043     if Pleroma.Config.get([:instance, :extended_nickname_format]) do
1044       @extended_local_nickname_regex
1045     else
1046       @strict_local_nickname_regex
1047     end
1048   end
1049
1050   def local_nickname(nickname_or_mention) do
1051     nickname_or_mention
1052     |> full_nickname()
1053     |> String.split("@")
1054     |> hd()
1055   end
1056
1057   def full_nickname(nickname_or_mention),
1058     do: String.trim_leading(nickname_or_mention, "@")
1059
1060   def error_user(ap_id) do
1061     %User{
1062       name: ap_id,
1063       ap_id: ap_id,
1064       info: %User.Info{},
1065       nickname: "erroruser@example.com",
1066       inserted_at: NaiveDateTime.utc_now()
1067     }
1068   end
1069 end