git.squeep.com Git - akkoma/blob - lib/pleroma/user.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.User do
   6   use Ecto.Schema
   7
   8   import Ecto.Changeset
   9   import Ecto.Query
  10   import Ecto, only: [assoc: 2]
  11
  12   alias Ecto.Multi
  13   alias Pleroma.Activity
  14   alias Pleroma.Config
  15   alias Pleroma.Conversation.Participation
  16   alias Pleroma.Delivery
  17   alias Pleroma.Emoji
  18   alias Pleroma.FollowingRelationship
  19   alias Pleroma.Formatter
  20   alias Pleroma.HTML
  21   alias Pleroma.Keys
  22   alias Pleroma.MFA
  23   alias Pleroma.Notification
  24   alias Pleroma.Object
  25   alias Pleroma.Registration
  26   alias Pleroma.Repo
  27   alias Pleroma.RepoStreamer
  28   alias Pleroma.User
  29   alias Pleroma.UserRelationship
  30   alias Pleroma.Web
  31   alias Pleroma.Web.ActivityPub.ActivityPub
  32   alias Pleroma.Web.ActivityPub.Builder
  33   alias Pleroma.Web.ActivityPub.ObjectValidators.Types
  34   alias Pleroma.Web.ActivityPub.Pipeline
  35   alias Pleroma.Web.ActivityPub.Utils
  36   alias Pleroma.Web.CommonAPI
  37   alias Pleroma.Web.CommonAPI.Utils, as: CommonUtils
  38   alias Pleroma.Web.OAuth
  39   alias Pleroma.Web.RelMe
  40   alias Pleroma.Workers.BackgroundWorker
  41
  42   require Logger
  43
  44   @type t :: %__MODULE__{}
  45   @type account_status :: :active | :deactivated | :password_reset_pending | :confirmation_pending
  46   @primary_key {:id, FlakeId.Ecto.CompatType, autogenerate: true}
  47
  48   # credo:disable-for-next-line Credo.Check.Readability.MaxLineLength
  49   @email_regex ~r/^[a-zA-Z0-9.!#$%&'*+\/=?^_`{|}~-]+@[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?(?:\.[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?)*$/
  50
  51   @strict_local_nickname_regex ~r/^[a-zA-Z\d]+$/
  52   @extended_local_nickname_regex ~r/^[a-zA-Z\d_-]+$/
  53
  54   # AP ID user relationships (blocks, mutes etc.)
  55   # Format: [rel_type: [outgoing_rel: :outgoing_rel_target, incoming_rel: :incoming_rel_source]]
  56   @user_relationships_config [
  57     block: [
  58       blocker_blocks: :blocked_users,
  59       blockee_blocks: :blocker_users
  60     ],
  61     mute: [
  62       muter_mutes: :muted_users,
  63       mutee_mutes: :muter_users
  64     ],
  65     reblog_mute: [
  66       reblog_muter_mutes: :reblog_muted_users,
  67       reblog_mutee_mutes: :reblog_muter_users
  68     ],
  69     notification_mute: [
  70       notification_muter_mutes: :notification_muted_users,
  71       notification_mutee_mutes: :notification_muter_users
  72     ],
  73     # Note: `inverse_subscription` relationship is inverse: subscriber acts as relationship target
  74     inverse_subscription: [
  75       subscribee_subscriptions: :subscriber_users,
  76       subscriber_subscriptions: :subscribee_users
  77     ]
  78   ]
  79
  80   schema "users" do
  81     field(:bio, :string)
  82     field(:email, :string)
  83     field(:name, :string)
  84     field(:nickname, :string)
  85     field(:password_hash, :string)
  86     field(:password, :string, virtual: true)
  87     field(:password_confirmation, :string, virtual: true)
  88     field(:keys, :string)
  89     field(:public_key, :string)
  90     field(:ap_id, :string)
  91     field(:avatar, :map)
  92     field(:local, :boolean, default: true)
  93     field(:follower_address, :string)
  94     field(:following_address, :string)
  95     field(:search_rank, :float, virtual: true)
  96     field(:search_type, :integer, virtual: true)
  97     field(:tags, {:array, :string}, default: [])
  98     field(:last_refreshed_at, :naive_datetime_usec)
  99     field(:last_digest_emailed_at, :naive_datetime)
 100     field(:banner, :map, default: %{})
 101     field(:background, :map, default: %{})
 102     field(:note_count, :integer, default: 0)
 103     field(:follower_count, :integer, default: 0)
 104     field(:following_count, :integer, default: 0)
 105     field(:locked, :boolean, default: false)
 106     field(:confirmation_pending, :boolean, default: false)
 107     field(:password_reset_pending, :boolean, default: false)
 108     field(:confirmation_token, :string, default: nil)
 109     field(:default_scope, :string, default: "public")
 110     field(:domain_blocks, {:array, :string}, default: [])
 111     field(:deactivated, :boolean, default: false)
 112     field(:no_rich_text, :boolean, default: false)
 113     field(:ap_enabled, :boolean, default: false)
 114     field(:is_moderator, :boolean, default: false)
 115     field(:is_admin, :boolean, default: false)
 116     field(:show_role, :boolean, default: true)
 117     field(:settings, :map, default: nil)
 118     field(:uri, Types.Uri, default: nil)
 119     field(:hide_followers_count, :boolean, default: false)
 120     field(:hide_follows_count, :boolean, default: false)
 121     field(:hide_followers, :boolean, default: false)
 122     field(:hide_follows, :boolean, default: false)
 123     field(:hide_favorites, :boolean, default: true)
 124     field(:unread_conversation_count, :integer, default: 0)
 125     field(:pinned_activities, {:array, :string}, default: [])
 126     field(:email_notifications, :map, default: %{"digest" => false})
 127     field(:mascot, :map, default: nil)
 128     field(:emoji, :map, default: %{})
 129     field(:pleroma_settings_store, :map, default: %{})
 130     field(:fields, {:array, :map}, default: [])
 131     field(:raw_fields, {:array, :map}, default: [])
 132     field(:discoverable, :boolean, default: false)
 133     field(:invisible, :boolean, default: false)
 134     field(:allow_following_move, :boolean, default: true)
 135     field(:skip_thread_containment, :boolean, default: false)
 136     field(:actor_type, :string, default: "Person")
 137     field(:also_known_as, {:array, :string}, default: [])
 138     field(:inbox, :string)
 139     field(:shared_inbox, :string)
 140
 141     embeds_one(
 142       :notification_settings,
 143       Pleroma.User.NotificationSetting,
 144       on_replace: :update
 145     )
 146
 147     has_many(:notifications, Notification)
 148     has_many(:registrations, Registration)
 149     has_many(:deliveries, Delivery)
 150
 151     has_many(:outgoing_relationships, UserRelationship, foreign_key: :source_id)
 152     has_many(:incoming_relationships, UserRelationship, foreign_key: :target_id)
 153
 154     for {relationship_type,
 155          [
 156            {outgoing_relation, outgoing_relation_target},
 157            {incoming_relation, incoming_relation_source}
 158          ]} <- @user_relationships_config do
 159       # Definitions of `has_many` relations: :blocker_blocks, :muter_mutes, :reblog_muter_mutes,
 160       #   :notification_muter_mutes, :subscribee_subscriptions
 161       has_many(outgoing_relation, UserRelationship,
 162         foreign_key: :source_id,
 163         where: [relationship_type: relationship_type]
 164       )
 165
 166       # Definitions of `has_many` relations: :blockee_blocks, :mutee_mutes, :reblog_mutee_mutes,
 167       #   :notification_mutee_mutes, :subscriber_subscriptions
 168       has_many(incoming_relation, UserRelationship,
 169         foreign_key: :target_id,
 170         where: [relationship_type: relationship_type]
 171       )
 172
 173       # Definitions of `has_many` relations: :blocked_users, :muted_users, :reblog_muted_users,
 174       #   :notification_muted_users, :subscriber_users
 175       has_many(outgoing_relation_target, through: [outgoing_relation, :target])
 176
 177       # Definitions of `has_many` relations: :blocker_users, :muter_users, :reblog_muter_users,
 178       #   :notification_muter_users, :subscribee_users
 179       has_many(incoming_relation_source, through: [incoming_relation, :source])
 180     end
 181
 182     # `:blocks` is deprecated (replaced with `blocked_users` relation)
 183     field(:blocks, {:array, :string}, default: [])
 184     # `:mutes` is deprecated (replaced with `muted_users` relation)
 185     field(:mutes, {:array, :string}, default: [])
 186     # `:muted_reblogs` is deprecated (replaced with `reblog_muted_users` relation)
 187     field(:muted_reblogs, {:array, :string}, default: [])
 188     # `:muted_notifications` is deprecated (replaced with `notification_muted_users` relation)
 189     field(:muted_notifications, {:array, :string}, default: [])
 190     # `:subscribers` is deprecated (replaced with `subscriber_users` relation)
 191     field(:subscribers, {:array, :string}, default: [])
 192
 193     embeds_one(
 194       :multi_factor_authentication_settings,
 195       MFA.Settings,
 196       on_replace: :delete
 197     )
 198
 199     timestamps()
 200   end
 201
 202   for {_relationship_type, [{_outgoing_relation, outgoing_relation_target}, _]} <-
 203         @user_relationships_config do
 204     # `def blocked_users_relation/2`, `def muted_users_relation/2`,
 205     #   `def reblog_muted_users_relation/2`, `def notification_muted_users/2`,
 206     #   `def subscriber_users/2`
 207     def unquote(:"#{outgoing_relation_target}_relation")(user, restrict_deactivated? \\ false) do
 208       target_users_query = assoc(user, unquote(outgoing_relation_target))
 209
 210       if restrict_deactivated? do
 211         restrict_deactivated(target_users_query)
 212       else
 213         target_users_query
 214       end
 215     end
 216
 217     # `def blocked_users/2`, `def muted_users/2`, `def reblog_muted_users/2`,
 218     #   `def notification_muted_users/2`, `def subscriber_users/2`
 219     def unquote(outgoing_relation_target)(user, restrict_deactivated? \\ false) do
 220       __MODULE__
 221       |> apply(unquote(:"#{outgoing_relation_target}_relation"), [
 222         user,
 223         restrict_deactivated?
 224       ])
 225       |> Repo.all()
 226     end
 227
 228     # `def blocked_users_ap_ids/2`, `def muted_users_ap_ids/2`, `def reblog_muted_users_ap_ids/2`,
 229     #   `def notification_muted_users_ap_ids/2`, `def subscriber_users_ap_ids/2`
 230     def unquote(:"#{outgoing_relation_target}_ap_ids")(user, restrict_deactivated? \\ false) do
 231       __MODULE__
 232       |> apply(unquote(:"#{outgoing_relation_target}_relation"), [
 233         user,
 234         restrict_deactivated?
 235       ])
 236       |> select([u], u.ap_id)
 237       |> Repo.all()
 238     end
 239   end
 240
 241   @doc """
 242   Dumps Flake Id to SQL-compatible format (16-byte UUID).
 243   E.g. "9pQtDGXuq4p3VlcJEm" -> <<0, 0, 1, 110, 179, 218, 42, 92, 213, 41, 44, 227, 95, 213, 0, 0>>
 244   """
 245   def binary_id(source_id) when is_binary(source_id) do
 246     with {:ok, dumped_id} <- FlakeId.Ecto.CompatType.dump(source_id) do
 247       dumped_id
 248     else
 249       _ -> source_id
 250     end
 251   end
 252
 253   def binary_id(source_ids) when is_list(source_ids) do
 254     Enum.map(source_ids, &binary_id/1)
 255   end
 256
 257   def binary_id(%User{} = user), do: binary_id(user.id)
 258
 259   @doc "Returns status account"
 260   @spec account_status(User.t()) :: account_status()
 261   def account_status(%User{deactivated: true}), do: :deactivated
 262   def account_status(%User{password_reset_pending: true}), do: :password_reset_pending
 263
 264   def account_status(%User{confirmation_pending: true}) do
 265     case Config.get([:instance, :account_activation_required]) do
 266       true -> :confirmation_pending
 267       _ -> :active
 268     end
 269   end
 270
 271   def account_status(%User{}), do: :active
 272
 273   @spec visible_for?(User.t(), User.t() | nil) :: boolean()
 274   def visible_for?(user, for_user \\ nil)
 275
 276   def visible_for?(%User{invisible: true}, _), do: false
 277
 278   def visible_for?(%User{id: user_id}, %User{id: user_id}), do: true
 279
 280   def visible_for?(%User{local: local} = user, nil) do
 281     cfg_key =
 282       if local,
 283         do: :local,
 284         else: :remote
 285
 286     if Config.get([:restrict_unauthenticated, :profiles, cfg_key]),
 287       do: false,
 288       else: account_status(user) == :active
 289   end
 290
 291   def visible_for?(%User{} = user, for_user) do
 292     account_status(user) == :active || superuser?(for_user)
 293   end
 294
 295   def visible_for?(_, _), do: false
 296
 297   @spec superuser?(User.t()) :: boolean()
 298   def superuser?(%User{local: true, is_admin: true}), do: true
 299   def superuser?(%User{local: true, is_moderator: true}), do: true
 300   def superuser?(_), do: false
 301
 302   @spec invisible?(User.t()) :: boolean()
 303   def invisible?(%User{invisible: true}), do: true
 304   def invisible?(_), do: false
 305
 306   def avatar_url(user, options \\ []) do
 307     case user.avatar do
 308       %{"url" => [%{"href" => href} | _]} ->
 309         href
 310
 311       _ ->
 312         unless options[:no_default] do
 313           Config.get([:assets, :default_user_avatar], "#{Web.base_url()}/images/avi.png")
 314         end
 315     end
 316   end
 317
 318   def banner_url(user, options \\ []) do
 319     case user.banner do
 320       %{"url" => [%{"href" => href} | _]} -> href
 321       _ -> !options[:no_default] && "#{Web.base_url()}/images/banner.png"
 322     end
 323   end
 324
 325   # Should probably be renamed or removed
 326   def ap_id(%User{nickname: nickname}), do: "#{Web.base_url()}/users/#{nickname}"
 327
 328   def ap_followers(%User{follower_address: fa}) when is_binary(fa), do: fa
 329   def ap_followers(%User{} = user), do: "#{ap_id(user)}/followers"
 330
 331   @spec ap_following(User.t()) :: String.t()
 332   def ap_following(%User{following_address: fa}) when is_binary(fa), do: fa
 333   def ap_following(%User{} = user), do: "#{ap_id(user)}/following"
 334
 335   @spec restrict_deactivated(Ecto.Query.t()) :: Ecto.Query.t()
 336   def restrict_deactivated(query) do
 337     from(u in query, where: u.deactivated != ^true)
 338   end
 339
 340   defdelegate following_count(user), to: FollowingRelationship
 341
 342   defp truncate_fields_param(params) do
 343     if Map.has_key?(params, :fields) do
 344       Map.put(params, :fields, Enum.map(params[:fields], &truncate_field/1))
 345     else
 346       params
 347     end
 348   end
 349
 350   defp truncate_if_exists(params, key, max_length) do
 351     if Map.has_key?(params, key) and is_binary(params[key]) do
 352       {value, _chopped} = String.split_at(params[key], max_length)
 353       Map.put(params, key, value)
 354     else
 355       params
 356     end
 357   end
 358
 359   defp fix_follower_address(%{follower_address: _, following_address: _} = params), do: params
 360
 361   defp fix_follower_address(%{nickname: nickname} = params),
 362     do: Map.put(params, :follower_address, ap_followers(%User{nickname: nickname}))
 363
 364   defp fix_follower_address(params), do: params
 365
 366   def remote_user_changeset(struct \\ %User{local: false}, params) do
 367     bio_limit = Pleroma.Config.get([:instance, :user_bio_length], 5000)
 368     name_limit = Pleroma.Config.get([:instance, :user_name_length], 100)
 369
 370     name =
 371       case params[:name] do
 372         name when is_binary(name) and byte_size(name) > 0 -> name
 373         _ -> params[:nickname]
 374       end
 375
 376     params =
 377       params
 378       |> Map.put(:name, name)
 379       |> Map.put_new(:last_refreshed_at, NaiveDateTime.utc_now())
 380       |> truncate_if_exists(:name, name_limit)
 381       |> truncate_if_exists(:bio, bio_limit)
 382       |> truncate_fields_param()
 383       |> fix_follower_address()
 384
 385     struct
 386     |> cast(
 387       params,
 388       [
 389         :bio,
 390         :name,
 391         :emoji,
 392         :ap_id,
 393         :inbox,
 394         :shared_inbox,
 395         :nickname,
 396         :public_key,
 397         :avatar,
 398         :ap_enabled,
 399         :banner,
 400         :locked,
 401         :last_refreshed_at,
 402         :uri,
 403         :follower_address,
 404         :following_address,
 405         :hide_followers,
 406         :hide_follows,
 407         :hide_followers_count,
 408         :hide_follows_count,
 409         :follower_count,
 410         :fields,
 411         :following_count,
 412         :discoverable,
 413         :invisible,
 414         :actor_type,
 415         :also_known_as
 416       ]
 417     )
 418     |> validate_required([:name, :ap_id])
 419     |> unique_constraint(:nickname)
 420     |> validate_format(:nickname, @email_regex)
 421     |> validate_length(:bio, max: bio_limit)
 422     |> validate_length(:name, max: name_limit)
 423     |> validate_fields(true)
 424   end
 425
 426   def update_changeset(struct, params \\ %{}) do
 427     bio_limit = Pleroma.Config.get([:instance, :user_bio_length], 5000)
 428     name_limit = Pleroma.Config.get([:instance, :user_name_length], 100)
 429
 430     struct
 431     |> cast(
 432       params,
 433       [
 434         :bio,
 435         :name,
 436         :emoji,
 437         :avatar,
 438         :public_key,
 439         :inbox,
 440         :shared_inbox,
 441         :locked,
 442         :no_rich_text,
 443         :default_scope,
 444         :banner,
 445         :hide_follows,
 446         :hide_followers,
 447         :hide_followers_count,
 448         :hide_follows_count,
 449         :hide_favorites,
 450         :allow_following_move,
 451         :background,
 452         :show_role,
 453         :skip_thread_containment,
 454         :fields,
 455         :raw_fields,
 456         :pleroma_settings_store,
 457         :discoverable,
 458         :actor_type,
 459         :also_known_as
 460       ]
 461     )
 462     |> unique_constraint(:nickname)
 463     |> validate_format(:nickname, local_nickname_regex())
 464     |> validate_length(:bio, max: bio_limit)
 465     |> validate_length(:name, min: 1, max: name_limit)
 466     |> put_fields()
 467     |> put_emoji()
 468     |> put_change_if_present(:bio, &{:ok, parse_bio(&1, struct)})
 469     |> put_change_if_present(:avatar, &put_upload(&1, :avatar))
 470     |> put_change_if_present(:banner, &put_upload(&1, :banner))
 471     |> put_change_if_present(:background, &put_upload(&1, :background))
 472     |> put_change_if_present(
 473       :pleroma_settings_store,
 474       &{:ok, Map.merge(struct.pleroma_settings_store, &1)}
 475     )
 476     |> validate_fields(false)
 477   end
 478
 479   defp put_fields(changeset) do
 480     if raw_fields = get_change(changeset, :raw_fields) do
 481       raw_fields =
 482         raw_fields
 483         |> Enum.filter(fn %{"name" => n} -> n != "" end)
 484
 485       fields =
 486         raw_fields
 487         |> Enum.map(fn f -> Map.update!(f, "value", &parse_fields(&1)) end)
 488
 489       changeset
 490       |> put_change(:raw_fields, raw_fields)
 491       |> put_change(:fields, fields)
 492     else
 493       changeset
 494     end
 495   end
 496
 497   defp parse_fields(value) do
 498     value
 499     |> Formatter.linkify(mentions_format: :full)
 500     |> elem(0)
 501   end
 502
 503   defp put_emoji(changeset) do
 504     bio = get_change(changeset, :bio)
 505     name = get_change(changeset, :name)
 506
 507     if bio || name do
 508       emoji = Map.merge(Emoji.Formatter.get_emoji_map(bio), Emoji.Formatter.get_emoji_map(name))
 509       put_change(changeset, :emoji, emoji)
 510     else
 511       changeset
 512     end
 513   end
 514
 515   defp put_change_if_present(changeset, map_field, value_function) do
 516     if value = get_change(changeset, map_field) do
 517       with {:ok, new_value} <- value_function.(value) do
 518         put_change(changeset, map_field, new_value)
 519       else
 520         _ -> changeset
 521       end
 522     else
 523       changeset
 524     end
 525   end
 526
 527   defp put_upload(value, type) do
 528     with %Plug.Upload{} <- value,
 529          {:ok, object} <- ActivityPub.upload(value, type: type) do
 530       {:ok, object.data}
 531     end
 532   end
 533
 534   def update_as_admin_changeset(struct, params) do
 535     struct
 536     |> update_changeset(params)
 537     |> cast(params, [:email])
 538     |> delete_change(:also_known_as)
 539     |> unique_constraint(:email)
 540     |> validate_format(:email, @email_regex)
 541   end
 542
 543   @spec update_as_admin(%User{}, map) :: {:ok, User.t()} | {:error, Ecto.Changeset.t()}
 544   def update_as_admin(user, params) do
 545     params = Map.put(params, "password_confirmation", params["password"])
 546     changeset = update_as_admin_changeset(user, params)
 547
 548     if params["password"] do
 549       reset_password(user, changeset, params)
 550     else
 551       User.update_and_set_cache(changeset)
 552     end
 553   end
 554
 555   def password_update_changeset(struct, params) do
 556     struct
 557     |> cast(params, [:password, :password_confirmation])
 558     |> validate_required([:password, :password_confirmation])
 559     |> validate_confirmation(:password)
 560     |> put_password_hash()
 561     |> put_change(:password_reset_pending, false)
 562   end
 563
 564   @spec reset_password(User.t(), map) :: {:ok, User.t()} | {:error, Ecto.Changeset.t()}
 565   def reset_password(%User{} = user, params) do
 566     reset_password(user, user, params)
 567   end
 568
 569   def reset_password(%User{id: user_id} = user, struct, params) do
 570     multi =
 571       Multi.new()
 572       |> Multi.update(:user, password_update_changeset(struct, params))
 573       |> Multi.delete_all(:tokens, OAuth.Token.Query.get_by_user(user_id))
 574       |> Multi.delete_all(:auth, OAuth.Authorization.delete_by_user_query(user))
 575
 576     case Repo.transaction(multi) do
 577       {:ok, %{user: user} = _} -> set_cache(user)
 578       {:error, _, changeset, _} -> {:error, changeset}
 579     end
 580   end
 581
 582   def update_password_reset_pending(user, value) do
 583     user
 584     |> change()
 585     |> put_change(:password_reset_pending, value)
 586     |> update_and_set_cache()
 587   end
 588
 589   def force_password_reset_async(user) do
 590     BackgroundWorker.enqueue("force_password_reset", %{"user_id" => user.id})
 591   end
 592
 593   @spec force_password_reset(User.t()) :: {:ok, User.t()} | {:error, Ecto.Changeset.t()}
 594   def force_password_reset(user), do: update_password_reset_pending(user, true)
 595
 596   def register_changeset(struct, params \\ %{}, opts \\ []) do
 597     bio_limit = Pleroma.Config.get([:instance, :user_bio_length], 5000)
 598     name_limit = Pleroma.Config.get([:instance, :user_name_length], 100)
 599
 600     need_confirmation? =
 601       if is_nil(opts[:need_confirmation]) do
 602         Pleroma.Config.get([:instance, :account_activation_required])
 603       else
 604         opts[:need_confirmation]
 605       end
 606
 607     struct
 608     |> confirmation_changeset(need_confirmation: need_confirmation?)
 609     |> cast(params, [:bio, :email, :name, :nickname, :password, :password_confirmation, :emoji])
 610     |> validate_required([:name, :nickname, :password, :password_confirmation])
 611     |> validate_confirmation(:password)
 612     |> unique_constraint(:email)
 613     |> unique_constraint(:nickname)
 614     |> validate_exclusion(:nickname, Pleroma.Config.get([User, :restricted_nicknames]))
 615     |> validate_format(:nickname, local_nickname_regex())
 616     |> validate_format(:email, @email_regex)
 617     |> validate_length(:bio, max: bio_limit)
 618     |> validate_length(:name, min: 1, max: name_limit)
 619     |> maybe_validate_required_email(opts[:external])
 620     |> put_password_hash
 621     |> put_ap_id()
 622     |> unique_constraint(:ap_id)
 623     |> put_following_and_follower_address()
 624   end
 625
 626   def maybe_validate_required_email(changeset, true), do: changeset
 627
 628   def maybe_validate_required_email(changeset, _) do
 629     if Pleroma.Config.get([:instance, :account_activation_required]) do
 630       validate_required(changeset, [:email])
 631     else
 632       changeset
 633     end
 634   end
 635
 636   defp put_ap_id(changeset) do
 637     ap_id = ap_id(%User{nickname: get_field(changeset, :nickname)})
 638     put_change(changeset, :ap_id, ap_id)
 639   end
 640
 641   defp put_following_and_follower_address(changeset) do
 642     followers = ap_followers(%User{nickname: get_field(changeset, :nickname)})
 643
 644     changeset
 645     |> put_change(:follower_address, followers)
 646   end
 647
 648   defp autofollow_users(user) do
 649     candidates = Pleroma.Config.get([:instance, :autofollowed_nicknames])
 650
 651     autofollowed_users =
 652       User.Query.build(%{nickname: candidates, local: true, deactivated: false})
 653       |> Repo.all()
 654
 655     follow_all(user, autofollowed_users)
 656   end
 657
 658   @doc "Inserts provided changeset, performs post-registration actions (confirmation email sending etc.)"
 659   def register(%Ecto.Changeset{} = changeset) do
 660     with {:ok, user} <- Repo.insert(changeset) do
 661       post_register_action(user)
 662     end
 663   end
 664
 665   def post_register_action(%User{} = user) do
 666     with {:ok, user} <- autofollow_users(user),
 667          {:ok, user} <- set_cache(user),
 668          {:ok, _} <- User.WelcomeMessage.post_welcome_message_to_user(user),
 669          {:ok, _} <- try_send_confirmation_email(user) do
 670       {:ok, user}
 671     end
 672   end
 673
 674   def try_send_confirmation_email(%User{} = user) do
 675     if user.confirmation_pending &&
 676          Pleroma.Config.get([:instance, :account_activation_required]) do
 677       user
 678       |> Pleroma.Emails.UserEmail.account_confirmation_email()
 679       |> Pleroma.Emails.Mailer.deliver_async()
 680
 681       {:ok, :enqueued}
 682     else
 683       {:ok, :noop}
 684     end
 685   end
 686
 687   def try_send_confirmation_email(users) do
 688     Enum.each(users, &try_send_confirmation_email/1)
 689   end
 690
 691   def needs_update?(%User{local: true}), do: false
 692
 693   def needs_update?(%User{local: false, last_refreshed_at: nil}), do: true
 694
 695   def needs_update?(%User{local: false} = user) do
 696     NaiveDateTime.diff(NaiveDateTime.utc_now(), user.last_refreshed_at) >= 86_400
 697   end
 698
 699   def needs_update?(_), do: true
 700
 701   @spec maybe_direct_follow(User.t(), User.t()) :: {:ok, User.t()} | {:error, String.t()}
 702
 703   # "Locked" (self-locked) users demand explicit authorization of follow requests
 704   def maybe_direct_follow(%User{} = follower, %User{local: true, locked: true} = followed) do
 705     follow(follower, followed, :follow_pending)
 706   end
 707
 708   def maybe_direct_follow(%User{} = follower, %User{local: true} = followed) do
 709     follow(follower, followed)
 710   end
 711
 712   def maybe_direct_follow(%User{} = follower, %User{} = followed) do
 713     if not ap_enabled?(followed) do
 714       follow(follower, followed)
 715     else
 716       {:ok, follower}
 717     end
 718   end
 719
 720   @doc "A mass follow for local users. Respects blocks in both directions but does not create activities."
 721   @spec follow_all(User.t(), list(User.t())) :: {atom(), User.t()}
 722   def follow_all(follower, followeds) do
 723     followeds
 724     |> Enum.reject(fn followed -> blocks?(follower, followed) || blocks?(followed, follower) end)
 725     |> Enum.each(&follow(follower, &1, :follow_accept))
 726
 727     set_cache(follower)
 728   end
 729
 730   defdelegate following(user), to: FollowingRelationship
 731
 732   def follow(%User{} = follower, %User{} = followed, state \\ :follow_accept) do
 733     deny_follow_blocked = Pleroma.Config.get([:user, :deny_follow_blocked])
 734
 735     cond do
 736       followed.deactivated ->
 737         {:error, "Could not follow user: #{followed.nickname} is deactivated."}
 738
 739       deny_follow_blocked and blocks?(followed, follower) ->
 740         {:error, "Could not follow user: #{followed.nickname} blocked you."}
 741
 742       true ->
 743         FollowingRelationship.follow(follower, followed, state)
 744
 745         {:ok, _} = update_follower_count(followed)
 746
 747         follower
 748         |> update_following_count()
 749         |> set_cache()
 750     end
 751   end
 752
 753   def unfollow(%User{ap_id: ap_id}, %User{ap_id: ap_id}) do
 754     {:error, "Not subscribed!"}
 755   end
 756
 757   @spec unfollow(User.t(), User.t()) :: {:ok, User.t(), Activity.t()} | {:error, String.t()}
 758   def unfollow(%User{} = follower, %User{} = followed) do
 759     case do_unfollow(follower, followed) do
 760       {:ok, follower, followed} ->
 761         {:ok, follower, Utils.fetch_latest_follow(follower, followed)}
 762
 763       error ->
 764         error
 765     end
 766   end
 767
 768   @spec do_unfollow(User.t(), User.t()) :: {:ok, User.t(), User.t()} | {:error, String.t()}
 769   defp do_unfollow(%User{} = follower, %User{} = followed) do
 770     case get_follow_state(follower, followed) do
 771       state when state in [:follow_pending, :follow_accept] ->
 772         FollowingRelationship.unfollow(follower, followed)
 773         {:ok, followed} = update_follower_count(followed)
 774
 775         {:ok, follower} =
 776           follower
 777           |> update_following_count()
 778           |> set_cache()
 779
 780         {:ok, follower, followed}
 781
 782       nil ->
 783         {:error, "Not subscribed!"}
 784     end
 785   end
 786
 787   defdelegate following?(follower, followed), to: FollowingRelationship
 788
 789   @doc "Returns follow state as Pleroma.FollowingRelationship.State value"
 790   def get_follow_state(%User{} = follower, %User{} = following) do
 791     following_relationship = FollowingRelationship.get(follower, following)
 792     get_follow_state(follower, following, following_relationship)
 793   end
 794
 795   def get_follow_state(
 796         %User{} = follower,
 797         %User{} = following,
 798         following_relationship
 799       ) do
 800     case {following_relationship, following.local} do
 801       {nil, false} ->
 802         case Utils.fetch_latest_follow(follower, following) do
 803           %Activity{data: %{"state" => state}} when state in ["pending", "accept"] ->
 804             FollowingRelationship.state_to_enum(state)
 805
 806           _ ->
 807             nil
 808         end
 809
 810       {%{state: state}, _} ->
 811         state
 812
 813       {nil, _} ->
 814         nil
 815     end
 816   end
 817
 818   def locked?(%User{} = user) do
 819     user.locked || false
 820   end
 821
 822   def get_by_id(id) do
 823     Repo.get_by(User, id: id)
 824   end
 825
 826   def get_by_ap_id(ap_id) do
 827     Repo.get_by(User, ap_id: ap_id)
 828   end
 829
 830   def get_all_by_ap_id(ap_ids) do
 831     from(u in __MODULE__,
 832       where: u.ap_id in ^ap_ids
 833     )
 834     |> Repo.all()
 835   end
 836
 837   def get_all_by_ids(ids) do
 838     from(u in __MODULE__, where: u.id in ^ids)
 839     |> Repo.all()
 840   end
 841
 842   # This is mostly an SPC migration fix. This guesses the user nickname by taking the last part
 843   # of the ap_id and the domain and tries to get that user
 844   def get_by_guessed_nickname(ap_id) do
 845     domain = URI.parse(ap_id).host
 846     name = List.last(String.split(ap_id, "/"))
 847     nickname = "#{name}@#{domain}"
 848
 849     get_cached_by_nickname(nickname)
 850   end
 851
 852   def set_cache({:ok, user}), do: set_cache(user)
 853   def set_cache({:error, err}), do: {:error, err}
 854
 855   def set_cache(%User{} = user) do
 856     Cachex.put(:user_cache, "ap_id:#{user.ap_id}", user)
 857     Cachex.put(:user_cache, "nickname:#{user.nickname}", user)
 858     Cachex.put(:user_cache, "friends_ap_ids:#{user.nickname}", get_user_friends_ap_ids(user))
 859     {:ok, user}
 860   end
 861
 862   def update_and_set_cache(struct, params) do
 863     struct
 864     |> update_changeset(params)
 865     |> update_and_set_cache()
 866   end
 867
 868   def update_and_set_cache(changeset) do
 869     with {:ok, user} <- Repo.update(changeset, stale_error_field: :id) do
 870       set_cache(user)
 871     end
 872   end
 873
 874   def get_user_friends_ap_ids(user) do
 875     from(u in User.get_friends_query(user), select: u.ap_id)
 876     |> Repo.all()
 877   end
 878
 879   @spec get_cached_user_friends_ap_ids(User.t()) :: [String.t()]
 880   def get_cached_user_friends_ap_ids(user) do
 881     Cachex.fetch!(:user_cache, "friends_ap_ids:#{user.ap_id}", fn _ ->
 882       get_user_friends_ap_ids(user)
 883     end)
 884   end
 885
 886   def invalidate_cache(user) do
 887     Cachex.del(:user_cache, "ap_id:#{user.ap_id}")
 888     Cachex.del(:user_cache, "nickname:#{user.nickname}")
 889     Cachex.del(:user_cache, "friends_ap_ids:#{user.ap_id}")
 890   end
 891
 892   @spec get_cached_by_ap_id(String.t()) :: User.t() | nil
 893   def get_cached_by_ap_id(ap_id) do
 894     key = "ap_id:#{ap_id}"
 895
 896     with {:ok, nil} <- Cachex.get(:user_cache, key),
 897          user when not is_nil(user) <- get_by_ap_id(ap_id),
 898          {:ok, true} <- Cachex.put(:user_cache, key, user) do
 899       user
 900     else
 901       {:ok, user} -> user
 902       nil -> nil
 903     end
 904   end
 905
 906   def get_cached_by_id(id) do
 907     key = "id:#{id}"
 908
 909     ap_id =
 910       Cachex.fetch!(:user_cache, key, fn _ ->
 911         user = get_by_id(id)
 912
 913         if user do
 914           Cachex.put(:user_cache, "ap_id:#{user.ap_id}", user)
 915           {:commit, user.ap_id}
 916         else
 917           {:ignore, ""}
 918         end
 919       end)
 920
 921     get_cached_by_ap_id(ap_id)
 922   end
 923
 924   def get_cached_by_nickname(nickname) do
 925     key = "nickname:#{nickname}"
 926
 927     Cachex.fetch!(:user_cache, key, fn ->
 928       case get_or_fetch_by_nickname(nickname) do
 929         {:ok, user} -> {:commit, user}
 930         {:error, _error} -> {:ignore, nil}
 931       end
 932     end)
 933   end
 934
 935   def get_cached_by_nickname_or_id(nickname_or_id, opts \\ []) do
 936     restrict_to_local = Pleroma.Config.get([:instance, :limit_to_local_content])
 937
 938     cond do
 939       is_integer(nickname_or_id) or FlakeId.flake_id?(nickname_or_id) ->
 940         get_cached_by_id(nickname_or_id) || get_cached_by_nickname(nickname_or_id)
 941
 942       restrict_to_local == false or not String.contains?(nickname_or_id, "@") ->
 943         get_cached_by_nickname(nickname_or_id)
 944
 945       restrict_to_local == :unauthenticated and match?(%User{}, opts[:for]) ->
 946         get_cached_by_nickname(nickname_or_id)
 947
 948       true ->
 949         nil
 950     end
 951   end
 952
 953   @spec get_by_nickname(String.t()) :: User.t() | nil
 954   def get_by_nickname(nickname) do
 955     Repo.get_by(User, nickname: nickname) ||
 956       if Regex.match?(~r(@#{Pleroma.Web.Endpoint.host()})i, nickname) do
 957         Repo.get_by(User, nickname: local_nickname(nickname))
 958       end
 959   end
 960
 961   def get_by_email(email), do: Repo.get_by(User, email: email)
 962
 963   def get_by_nickname_or_email(nickname_or_email) do
 964     get_by_nickname(nickname_or_email) || get_by_email(nickname_or_email)
 965   end
 966
 967   def fetch_by_nickname(nickname), do: ActivityPub.make_user_from_nickname(nickname)
 968
 969   def get_or_fetch_by_nickname(nickname) do
 970     with %User{} = user <- get_by_nickname(nickname) do
 971       {:ok, user}
 972     else
 973       _e ->
 974         with [_nick, _domain] <- String.split(nickname, "@"),
 975              {:ok, user} <- fetch_by_nickname(nickname) do
 976           {:ok, user}
 977         else
 978           _e -> {:error, "not found " <> nickname}
 979         end
 980     end
 981   end
 982
 983   @spec get_followers_query(User.t(), pos_integer() | nil) :: Ecto.Query.t()
 984   def get_followers_query(%User{} = user, nil) do
 985     User.Query.build(%{followers: user, deactivated: false})
 986   end
 987
 988   def get_followers_query(user, page) do
 989     user
 990     |> get_followers_query(nil)
 991     |> User.Query.paginate(page, 20)
 992   end
 993
 994   @spec get_followers_query(User.t()) :: Ecto.Query.t()
 995   def get_followers_query(user), do: get_followers_query(user, nil)
 996
 997   @spec get_followers(User.t(), pos_integer() | nil) :: {:ok, list(User.t())}
 998   def get_followers(user, page \\ nil) do
 999     user
1000     |> get_followers_query(page)
1001     |> Repo.all()
1002   end
1003
1004   @spec get_external_followers(User.t(), pos_integer() | nil) :: {:ok, list(User.t())}
1005   def get_external_followers(user, page \\ nil) do
1006     user
1007     |> get_followers_query(page)
1008     |> User.Query.build(%{external: true})
1009     |> Repo.all()
1010   end
1011
1012   def get_followers_ids(user, page \\ nil) do
1013     user
1014     |> get_followers_query(page)
1015     |> select([u], u.id)
1016     |> Repo.all()
1017   end
1018
1019   @spec get_friends_query(User.t(), pos_integer() | nil) :: Ecto.Query.t()
1020   def get_friends_query(%User{} = user, nil) do
1021     User.Query.build(%{friends: user, deactivated: false})
1022   end
1023
1024   def get_friends_query(user, page) do
1025     user
1026     |> get_friends_query(nil)
1027     |> User.Query.paginate(page, 20)
1028   end
1029
1030   @spec get_friends_query(User.t()) :: Ecto.Query.t()
1031   def get_friends_query(user), do: get_friends_query(user, nil)
1032
1033   def get_friends(user, page \\ nil) do
1034     user
1035     |> get_friends_query(page)
1036     |> Repo.all()
1037   end
1038
1039   def get_friends_ap_ids(user) do
1040     user
1041     |> get_friends_query(nil)
1042     |> select([u], u.ap_id)
1043     |> Repo.all()
1044   end
1045
1046   def get_friends_ids(user, page \\ nil) do
1047     user
1048     |> get_friends_query(page)
1049     |> select([u], u.id)
1050     |> Repo.all()
1051   end
1052
1053   defdelegate get_follow_requests(user), to: FollowingRelationship
1054
1055   def increase_note_count(%User{} = user) do
1056     User
1057     |> where(id: ^user.id)
1058     |> update([u], inc: [note_count: 1])
1059     |> select([u], u)
1060     |> Repo.update_all([])
1061     |> case do
1062       {1, [user]} -> set_cache(user)
1063       _ -> {:error, user}
1064     end
1065   end
1066
1067   def decrease_note_count(%User{} = user) do
1068     User
1069     |> where(id: ^user.id)
1070     |> update([u],
1071       set: [
1072         note_count: fragment("greatest(0, note_count - 1)")
1073       ]
1074     )
1075     |> select([u], u)
1076     |> Repo.update_all([])
1077     |> case do
1078       {1, [user]} -> set_cache(user)
1079       _ -> {:error, user}
1080     end
1081   end
1082
1083   def update_note_count(%User{} = user, note_count \\ nil) do
1084     note_count =
1085       note_count ||
1086         from(
1087           a in Object,
1088           where: fragment("?->>'actor' = ? and ?->>'type' = 'Note'", a.data, ^user.ap_id, a.data),
1089           select: count(a.id)
1090         )
1091         |> Repo.one()
1092
1093     user
1094     |> cast(%{note_count: note_count}, [:note_count])
1095     |> update_and_set_cache()
1096   end
1097
1098   @spec maybe_fetch_follow_information(User.t()) :: User.t()
1099   def maybe_fetch_follow_information(user) do
1100     with {:ok, user} <- fetch_follow_information(user) do
1101       user
1102     else
1103       e ->
1104         Logger.error("Follower/Following counter update for #{user.ap_id} failed.\n#{inspect(e)}")
1105
1106         user
1107     end
1108   end
1109
1110   def fetch_follow_information(user) do
1111     with {:ok, info} <- ActivityPub.fetch_follow_information_for_user(user) do
1112       user
1113       |> follow_information_changeset(info)
1114       |> update_and_set_cache()
1115     end
1116   end
1117
1118   defp follow_information_changeset(user, params) do
1119     user
1120     |> cast(params, [
1121       :hide_followers,
1122       :hide_follows,
1123       :follower_count,
1124       :following_count,
1125       :hide_followers_count,
1126       :hide_follows_count
1127     ])
1128   end
1129
1130   def update_follower_count(%User{} = user) do
1131     if user.local or !Pleroma.Config.get([:instance, :external_user_synchronization]) do
1132       follower_count_query =
1133         User.Query.build(%{followers: user, deactivated: false})
1134         |> select([u], %{count: count(u.id)})
1135
1136       User
1137       |> where(id: ^user.id)
1138       |> join(:inner, [u], s in subquery(follower_count_query))
1139       |> update([u, s],
1140         set: [follower_count: s.count]
1141       )
1142       |> select([u], u)
1143       |> Repo.update_all([])
1144       |> case do
1145         {1, [user]} -> set_cache(user)
1146         _ -> {:error, user}
1147       end
1148     else
1149       {:ok, maybe_fetch_follow_information(user)}
1150     end
1151   end
1152
1153   @spec update_following_count(User.t()) :: User.t()
1154   def update_following_count(%User{local: false} = user) do
1155     if Pleroma.Config.get([:instance, :external_user_synchronization]) do
1156       maybe_fetch_follow_information(user)
1157     else
1158       user
1159     end
1160   end
1161
1162   def update_following_count(%User{local: true} = user) do
1163     following_count = FollowingRelationship.following_count(user)
1164
1165     user
1166     |> follow_information_changeset(%{following_count: following_count})
1167     |> Repo.update!()
1168   end
1169
1170   def set_unread_conversation_count(%User{local: true} = user) do
1171     unread_query = Participation.unread_conversation_count_for_user(user)
1172
1173     User
1174     |> join(:inner, [u], p in subquery(unread_query))
1175     |> update([u, p],
1176       set: [unread_conversation_count: p.count]
1177     )
1178     |> where([u], u.id == ^user.id)
1179     |> select([u], u)
1180     |> Repo.update_all([])
1181     |> case do
1182       {1, [user]} -> set_cache(user)
1183       _ -> {:error, user}
1184     end
1185   end
1186
1187   def set_unread_conversation_count(user), do: {:ok, user}
1188
1189   def increment_unread_conversation_count(conversation, %User{local: true} = user) do
1190     unread_query =
1191       Participation.unread_conversation_count_for_user(user)
1192       |> where([p], p.conversation_id == ^conversation.id)
1193
1194     User
1195     |> join(:inner, [u], p in subquery(unread_query))
1196     |> update([u, p],
1197       inc: [unread_conversation_count: 1]
1198     )
1199     |> where([u], u.id == ^user.id)
1200     |> where([u, p], p.count == 0)
1201     |> select([u], u)
1202     |> Repo.update_all([])
1203     |> case do
1204       {1, [user]} -> set_cache(user)
1205       _ -> {:error, user}
1206     end
1207   end
1208
1209   def increment_unread_conversation_count(_, user), do: {:ok, user}
1210
1211   @spec get_users_from_set([String.t()], keyword()) :: [User.t()]
1212   def get_users_from_set(ap_ids, opts \\ []) do
1213     local_only = Keyword.get(opts, :local_only, true)
1214     criteria = %{ap_id: ap_ids, deactivated: false}
1215     criteria = if local_only, do: Map.put(criteria, :local, true), else: criteria
1216
1217     User.Query.build(criteria)
1218     |> Repo.all()
1219   end
1220
1221   @spec get_recipients_from_activity(Activity.t()) :: [User.t()]
1222   def get_recipients_from_activity(%Activity{recipients: to, actor: actor}) do
1223     to = [actor | to]
1224
1225     query = User.Query.build(%{recipients_from_activity: to, local: true, deactivated: false})
1226
1227     query
1228     |> Repo.all()
1229   end
1230
1231   @spec mute(User.t(), User.t(), boolean()) ::
1232           {:ok, list(UserRelationship.t())} | {:error, String.t()}
1233   def mute(%User{} = muter, %User{} = mutee, notifications? \\ true) do
1234     add_to_mutes(muter, mutee, notifications?)
1235   end
1236
1237   def unmute(%User{} = muter, %User{} = mutee) do
1238     remove_from_mutes(muter, mutee)
1239   end
1240
1241   def subscribe(%User{} = subscriber, %User{} = target) do
1242     deny_follow_blocked = Pleroma.Config.get([:user, :deny_follow_blocked])
1243
1244     if blocks?(target, subscriber) and deny_follow_blocked do
1245       {:error, "Could not subscribe: #{target.nickname} is blocking you"}
1246     else
1247       # Note: the relationship is inverse: subscriber acts as relationship target
1248       UserRelationship.create_inverse_subscription(target, subscriber)
1249     end
1250   end
1251
1252   def subscribe(%User{} = subscriber, %{ap_id: ap_id}) do
1253     with %User{} = subscribee <- get_cached_by_ap_id(ap_id) do
1254       subscribe(subscriber, subscribee)
1255     end
1256   end
1257
1258   def unsubscribe(%User{} = unsubscriber, %User{} = target) do
1259     # Note: the relationship is inverse: subscriber acts as relationship target
1260     UserRelationship.delete_inverse_subscription(target, unsubscriber)
1261   end
1262
1263   def unsubscribe(%User{} = unsubscriber, %{ap_id: ap_id}) do
1264     with %User{} = user <- get_cached_by_ap_id(ap_id) do
1265       unsubscribe(unsubscriber, user)
1266     end
1267   end
1268
1269   def block(%User{} = blocker, %User{} = blocked) do
1270     # sever any follow relationships to prevent leaks per activitypub (Pleroma issue #213)
1271     blocker =
1272       if following?(blocker, blocked) do
1273         {:ok, blocker, _} = unfollow(blocker, blocked)
1274         blocker
1275       else
1276         blocker
1277       end
1278
1279     # clear any requested follows as well
1280     blocked =
1281       case CommonAPI.reject_follow_request(blocked, blocker) do
1282         {:ok, %User{} = updated_blocked} -> updated_blocked
1283         nil -> blocked
1284       end
1285
1286     unsubscribe(blocked, blocker)
1287
1288     if following?(blocked, blocker), do: unfollow(blocked, blocker)
1289
1290     {:ok, blocker} = update_follower_count(blocker)
1291     {:ok, blocker, _} = Participation.mark_all_as_read(blocker, blocked)
1292     add_to_block(blocker, blocked)
1293   end
1294
1295   # helper to handle the block given only an actor's AP id
1296   def block(%User{} = blocker, %{ap_id: ap_id}) do
1297     block(blocker, get_cached_by_ap_id(ap_id))
1298   end
1299
1300   def unblock(%User{} = blocker, %User{} = blocked) do
1301     remove_from_block(blocker, blocked)
1302   end
1303
1304   # helper to handle the block given only an actor's AP id
1305   def unblock(%User{} = blocker, %{ap_id: ap_id}) do
1306     unblock(blocker, get_cached_by_ap_id(ap_id))
1307   end
1308
1309   def mutes?(nil, _), do: false
1310   def mutes?(%User{} = user, %User{} = target), do: mutes_user?(user, target)
1311
1312   def mutes_user?(%User{} = user, %User{} = target) do
1313     UserRelationship.mute_exists?(user, target)
1314   end
1315
1316   @spec muted_notifications?(User.t() | nil, User.t() | map()) :: boolean()
1317   def muted_notifications?(nil, _), do: false
1318
1319   def muted_notifications?(%User{} = user, %User{} = target),
1320     do: UserRelationship.notification_mute_exists?(user, target)
1321
1322   def blocks?(nil, _), do: false
1323
1324   def blocks?(%User{} = user, %User{} = target) do
1325     blocks_user?(user, target) ||
1326       (blocks_domain?(user, target) and not User.following?(user, target))
1327   end
1328
1329   def blocks_user?(%User{} = user, %User{} = target) do
1330     UserRelationship.block_exists?(user, target)
1331   end
1332
1333   def blocks_user?(_, _), do: false
1334
1335   def blocks_domain?(%User{} = user, %User{} = target) do
1336     domain_blocks = Pleroma.Web.ActivityPub.MRF.subdomains_regex(user.domain_blocks)
1337     %{host: host} = URI.parse(target.ap_id)
1338     Pleroma.Web.ActivityPub.MRF.subdomain_match?(domain_blocks, host)
1339   end
1340
1341   def blocks_domain?(_, _), do: false
1342
1343   def subscribed_to?(%User{} = user, %User{} = target) do
1344     # Note: the relationship is inverse: subscriber acts as relationship target
1345     UserRelationship.inverse_subscription_exists?(target, user)
1346   end
1347
1348   def subscribed_to?(%User{} = user, %{ap_id: ap_id}) do
1349     with %User{} = target <- get_cached_by_ap_id(ap_id) do
1350       subscribed_to?(user, target)
1351     end
1352   end
1353
1354   @doc """
1355   Returns map of outgoing (blocked, muted etc.) relationships' user AP IDs by relation type.
1356   E.g. `outgoing_relationships_ap_ids(user, [:block])` -> `%{block: ["https://some.site/users/userapid"]}`
1357   """
1358   @spec outgoing_relationships_ap_ids(User.t(), list(atom())) :: %{atom() => list(String.t())}
1359   def outgoing_relationships_ap_ids(_user, []), do: %{}
1360
1361   def outgoing_relationships_ap_ids(nil, _relationship_types), do: %{}
1362
1363   def outgoing_relationships_ap_ids(%User{} = user, relationship_types)
1364       when is_list(relationship_types) do
1365     db_result =
1366       user
1367       |> assoc(:outgoing_relationships)
1368       |> join(:inner, [user_rel], u in assoc(user_rel, :target))
1369       |> where([user_rel, u], user_rel.relationship_type in ^relationship_types)
1370       |> select([user_rel, u], [user_rel.relationship_type, fragment("array_agg(?)", u.ap_id)])
1371       |> group_by([user_rel, u], user_rel.relationship_type)
1372       |> Repo.all()
1373       |> Enum.into(%{}, fn [k, v] -> {k, v} end)
1374
1375     Enum.into(
1376       relationship_types,
1377       %{},
1378       fn rel_type -> {rel_type, db_result[rel_type] || []} end
1379     )
1380   end
1381
1382   def incoming_relationships_ungrouped_ap_ids(user, relationship_types, ap_ids \\ nil)
1383
1384   def incoming_relationships_ungrouped_ap_ids(_user, [], _ap_ids), do: []
1385
1386   def incoming_relationships_ungrouped_ap_ids(nil, _relationship_types, _ap_ids), do: []
1387
1388   def incoming_relationships_ungrouped_ap_ids(%User{} = user, relationship_types, ap_ids)
1389       when is_list(relationship_types) do
1390     user
1391     |> assoc(:incoming_relationships)
1392     |> join(:inner, [user_rel], u in assoc(user_rel, :source))
1393     |> where([user_rel, u], user_rel.relationship_type in ^relationship_types)
1394     |> maybe_filter_on_ap_id(ap_ids)
1395     |> select([user_rel, u], u.ap_id)
1396     |> distinct(true)
1397     |> Repo.all()
1398   end
1399
1400   defp maybe_filter_on_ap_id(query, ap_ids) when is_list(ap_ids) do
1401     where(query, [user_rel, u], u.ap_id in ^ap_ids)
1402   end
1403
1404   defp maybe_filter_on_ap_id(query, _ap_ids), do: query
1405
1406   def deactivate_async(user, status \\ true) do
1407     BackgroundWorker.enqueue("deactivate_user", %{"user_id" => user.id, "status" => status})
1408   end
1409
1410   def deactivate(user, status \\ true)
1411
1412   def deactivate(users, status) when is_list(users) do
1413     Repo.transaction(fn ->
1414       for user <- users, do: deactivate(user, status)
1415     end)
1416   end
1417
1418   def deactivate(%User{} = user, status) do
1419     with {:ok, user} <- set_activation_status(user, status) do
1420       user
1421       |> get_followers()
1422       |> Enum.filter(& &1.local)
1423       |> Enum.each(&set_cache(update_following_count(&1)))
1424
1425       # Only update local user counts, remote will be update during the next pull.
1426       user
1427       |> get_friends()
1428       |> Enum.filter(& &1.local)
1429       |> Enum.each(&do_unfollow(user, &1))
1430
1431       {:ok, user}
1432     end
1433   end
1434
1435   def update_notification_settings(%User{} = user, settings) do
1436     user
1437     |> cast(%{notification_settings: settings}, [])
1438     |> cast_embed(:notification_settings)
1439     |> validate_required([:notification_settings])
1440     |> update_and_set_cache()
1441   end
1442
1443   def delete(users) when is_list(users) do
1444     for user <- users, do: delete(user)
1445   end
1446
1447   def delete(%User{} = user) do
1448     BackgroundWorker.enqueue("delete_user", %{"user_id" => user.id})
1449   end
1450
1451   defp delete_and_invalidate_cache(%User{} = user) do
1452     invalidate_cache(user)
1453     Repo.delete(user)
1454   end
1455
1456   defp delete_or_deactivate(%User{local: false} = user), do: delete_and_invalidate_cache(user)
1457
1458   defp delete_or_deactivate(%User{local: true} = user) do
1459     status = account_status(user)
1460
1461     if status == :confirmation_pending do
1462       delete_and_invalidate_cache(user)
1463     else
1464       user
1465       |> change(%{deactivated: true, email: nil})
1466       |> update_and_set_cache()
1467     end
1468   end
1469
1470   def perform(:force_password_reset, user), do: force_password_reset(user)
1471
1472   @spec perform(atom(), User.t()) :: {:ok, User.t()}
1473   def perform(:delete, %User{} = user) do
1474     # Remove all relationships
1475     user
1476     |> get_followers()
1477     |> Enum.each(fn follower ->
1478       ActivityPub.unfollow(follower, user)
1479       unfollow(follower, user)
1480     end)
1481
1482     user
1483     |> get_friends()
1484     |> Enum.each(fn followed ->
1485       ActivityPub.unfollow(user, followed)
1486       unfollow(user, followed)
1487     end)
1488
1489     delete_user_activities(user)
1490
1491     delete_or_deactivate(user)
1492   end
1493
1494   def perform(:deactivate_async, user, status), do: deactivate(user, status)
1495
1496   @spec perform(atom(), User.t(), list()) :: list() | {:error, any()}
1497   def perform(:blocks_import, %User{} = blocker, blocked_identifiers)
1498       when is_list(blocked_identifiers) do
1499     Enum.map(
1500       blocked_identifiers,
1501       fn blocked_identifier ->
1502         with {:ok, %User{} = blocked} <- get_or_fetch(blocked_identifier),
1503              {:ok, _user_block} <- block(blocker, blocked),
1504              {:ok, _} <- ActivityPub.block(blocker, blocked) do
1505           blocked
1506         else
1507           err ->
1508             Logger.debug("blocks_import failed for #{blocked_identifier} with: #{inspect(err)}")
1509             err
1510         end
1511       end
1512     )
1513   end
1514
1515   def perform(:follow_import, %User{} = follower, followed_identifiers)
1516       when is_list(followed_identifiers) do
1517     Enum.map(
1518       followed_identifiers,
1519       fn followed_identifier ->
1520         with {:ok, %User{} = followed} <- get_or_fetch(followed_identifier),
1521              {:ok, follower} <- maybe_direct_follow(follower, followed),
1522              {:ok, _} <- ActivityPub.follow(follower, followed) do
1523           followed
1524         else
1525           err ->
1526             Logger.debug("follow_import failed for #{followed_identifier} with: #{inspect(err)}")
1527             err
1528         end
1529       end
1530     )
1531   end
1532
1533   @spec external_users_query() :: Ecto.Query.t()
1534   def external_users_query do
1535     User.Query.build(%{
1536       external: true,
1537       active: true,
1538       order_by: :id
1539     })
1540   end
1541
1542   @spec external_users(keyword()) :: [User.t()]
1543   def external_users(opts \\ []) do
1544     query =
1545       external_users_query()
1546       |> select([u], struct(u, [:id, :ap_id]))
1547
1548     query =
1549       if opts[:max_id],
1550         do: where(query, [u], u.id > ^opts[:max_id]),
1551         else: query
1552
1553     query =
1554       if opts[:limit],
1555         do: limit(query, ^opts[:limit]),
1556         else: query
1557
1558     Repo.all(query)
1559   end
1560
1561   def blocks_import(%User{} = blocker, blocked_identifiers) when is_list(blocked_identifiers) do
1562     BackgroundWorker.enqueue("blocks_import", %{
1563       "blocker_id" => blocker.id,
1564       "blocked_identifiers" => blocked_identifiers
1565     })
1566   end
1567
1568   def follow_import(%User{} = follower, followed_identifiers)
1569       when is_list(followed_identifiers) do
1570     BackgroundWorker.enqueue("follow_import", %{
1571       "follower_id" => follower.id,
1572       "followed_identifiers" => followed_identifiers
1573     })
1574   end
1575
1576   def delete_user_activities(%User{ap_id: ap_id} = user) do
1577     ap_id
1578     |> Activity.Queries.by_actor()
1579     |> RepoStreamer.chunk_stream(50)
1580     |> Stream.each(fn activities ->
1581       Enum.each(activities, fn activity -> delete_activity(activity, user) end)
1582     end)
1583     |> Stream.run()
1584   end
1585
1586   defp delete_activity(%{data: %{"type" => "Create", "object" => object}} = activity, user) do
1587     with {_, %Object{}} <- {:find_object, Object.get_by_ap_id(object)},
1588          {:ok, delete_data, _} <- Builder.delete(user, object) do
1589       Pipeline.common_pipeline(delete_data, local: user.local)
1590     else
1591       {:find_object, nil} ->
1592         # We have the create activity, but not the object, it was probably pruned.
1593         # Insert a tombstone and try again
1594         with {:ok, tombstone_data, _} <- Builder.tombstone(user.ap_id, object),
1595              {:ok, _tombstone} <- Object.create(tombstone_data) do
1596           delete_activity(activity, user)
1597         end
1598
1599       e ->
1600         Logger.error("Could not delete #{object} created by #{activity.data["ap_id"]}")
1601         Logger.error("Error: #{inspect(e)}")
1602     end
1603   end
1604
1605   defp delete_activity(%{data: %{"type" => type}} = activity, user)
1606        when type in ["Like", "Announce"] do
1607     {:ok, undo, _} = Builder.undo(user, activity)
1608     Pipeline.common_pipeline(undo, local: user.local)
1609   end
1610
1611   defp delete_activity(_activity, _user), do: "Doing nothing"
1612
1613   def html_filter_policy(%User{no_rich_text: true}) do
1614     Pleroma.HTML.Scrubber.TwitterText
1615   end
1616
1617   def html_filter_policy(_), do: Pleroma.Config.get([:markup, :scrub_policy])
1618
1619   def fetch_by_ap_id(ap_id), do: ActivityPub.make_user_from_ap_id(ap_id)
1620
1621   def get_or_fetch_by_ap_id(ap_id) do
1622     user = get_cached_by_ap_id(ap_id)
1623
1624     if !is_nil(user) and !needs_update?(user) do
1625       {:ok, user}
1626     else
1627       fetch_by_ap_id(ap_id)
1628     end
1629   end
1630
1631   @doc """
1632   Creates an internal service actor by URI if missing.
1633   Optionally takes nickname for addressing.
1634   """
1635   @spec get_or_create_service_actor_by_ap_id(String.t(), String.t()) :: User.t() | nil
1636   def get_or_create_service_actor_by_ap_id(uri, nickname) do
1637     {_, user} =
1638       case get_cached_by_ap_id(uri) do
1639         nil ->
1640           with {:error, %{errors: errors}} <- create_service_actor(uri, nickname) do
1641             Logger.error("Cannot create service actor: #{uri}/.\n#{inspect(errors)}")
1642             {:error, nil}
1643           end
1644
1645         %User{invisible: false} = user ->
1646           set_invisible(user)
1647
1648         user ->
1649           {:ok, user}
1650       end
1651
1652     user
1653   end
1654
1655   @spec set_invisible(User.t()) :: {:ok, User.t()}
1656   defp set_invisible(user) do
1657     user
1658     |> change(%{invisible: true})
1659     |> update_and_set_cache()
1660   end
1661
1662   @spec create_service_actor(String.t(), String.t()) ::
1663           {:ok, User.t()} | {:error, Ecto.Changeset.t()}
1664   defp create_service_actor(uri, nickname) do
1665     %User{
1666       invisible: true,
1667       local: true,
1668       ap_id: uri,
1669       nickname: nickname,
1670       follower_address: uri <> "/followers"
1671     }
1672     |> change
1673     |> unique_constraint(:nickname)
1674     |> Repo.insert()
1675     |> set_cache()
1676   end
1677
1678   def public_key(%{public_key: public_key_pem}) when is_binary(public_key_pem) do
1679     key =
1680       public_key_pem
1681       |> :public_key.pem_decode()
1682       |> hd()
1683       |> :public_key.pem_entry_decode()
1684
1685     {:ok, key}
1686   end
1687
1688   def public_key(_), do: {:error, "key not found"}
1689
1690   def get_public_key_for_ap_id(ap_id) do
1691     with {:ok, %User{} = user} <- get_or_fetch_by_ap_id(ap_id),
1692          {:ok, public_key} <- public_key(user) do
1693       {:ok, public_key}
1694     else
1695       _ -> :error
1696     end
1697   end
1698
1699   def ap_enabled?(%User{local: true}), do: true
1700   def ap_enabled?(%User{ap_enabled: ap_enabled}), do: ap_enabled
1701   def ap_enabled?(_), do: false
1702
1703   @doc "Gets or fetch a user by uri or nickname."
1704   @spec get_or_fetch(String.t()) :: {:ok, User.t()} | {:error, String.t()}
1705   def get_or_fetch("http" <> _host = uri), do: get_or_fetch_by_ap_id(uri)
1706   def get_or_fetch(nickname), do: get_or_fetch_by_nickname(nickname)
1707
1708   # wait a period of time and return newest version of the User structs
1709   # this is because we have synchronous follow APIs and need to simulate them
1710   # with an async handshake
1711   def wait_and_refresh(_, %User{local: true} = a, %User{local: true} = b) do
1712     with %User{} = a <- get_cached_by_id(a.id),
1713          %User{} = b <- get_cached_by_id(b.id) do
1714       {:ok, a, b}
1715     else
1716       nil -> :error
1717     end
1718   end
1719
1720   def wait_and_refresh(timeout, %User{} = a, %User{} = b) do
1721     with :ok <- :timer.sleep(timeout),
1722          %User{} = a <- get_cached_by_id(a.id),
1723          %User{} = b <- get_cached_by_id(b.id) do
1724       {:ok, a, b}
1725     else
1726       nil -> :error
1727     end
1728   end
1729
1730   def parse_bio(bio) when is_binary(bio) and bio != "" do
1731     bio
1732     |> CommonUtils.format_input("text/plain", mentions_format: :full)
1733     |> elem(0)
1734   end
1735
1736   def parse_bio(_), do: ""
1737
1738   def parse_bio(bio, user) when is_binary(bio) and bio != "" do
1739     # TODO: get profile URLs other than user.ap_id
1740     profile_urls = [user.ap_id]
1741
1742     bio
1743     |> CommonUtils.format_input("text/plain",
1744       mentions_format: :full,
1745       rel: &RelMe.maybe_put_rel_me(&1, profile_urls)
1746     )
1747     |> elem(0)
1748   end
1749
1750   def parse_bio(_, _), do: ""
1751
1752   def tag(user_identifiers, tags) when is_list(user_identifiers) do
1753     Repo.transaction(fn ->
1754       for user_identifier <- user_identifiers, do: tag(user_identifier, tags)
1755     end)
1756   end
1757
1758   def tag(nickname, tags) when is_binary(nickname),
1759     do: tag(get_by_nickname(nickname), tags)
1760
1761   def tag(%User{} = user, tags),
1762     do: update_tags(user, Enum.uniq((user.tags || []) ++ normalize_tags(tags)))
1763
1764   def untag(user_identifiers, tags) when is_list(user_identifiers) do
1765     Repo.transaction(fn ->
1766       for user_identifier <- user_identifiers, do: untag(user_identifier, tags)
1767     end)
1768   end
1769
1770   def untag(nickname, tags) when is_binary(nickname),
1771     do: untag(get_by_nickname(nickname), tags)
1772
1773   def untag(%User{} = user, tags),
1774     do: update_tags(user, (user.tags || []) -- normalize_tags(tags))
1775
1776   defp update_tags(%User{} = user, new_tags) do
1777     {:ok, updated_user} =
1778       user
1779       |> change(%{tags: new_tags})
1780       |> update_and_set_cache()
1781
1782     updated_user
1783   end
1784
1785   defp normalize_tags(tags) do
1786     [tags]
1787     |> List.flatten()
1788     |> Enum.map(&String.downcase/1)
1789   end
1790
1791   defp local_nickname_regex do
1792     if Pleroma.Config.get([:instance, :extended_nickname_format]) do
1793       @extended_local_nickname_regex
1794     else
1795       @strict_local_nickname_regex
1796     end
1797   end
1798
1799   def local_nickname(nickname_or_mention) do
1800     nickname_or_mention
1801     |> full_nickname()
1802     |> String.split("@")
1803     |> hd()
1804   end
1805
1806   def full_nickname(nickname_or_mention),
1807     do: String.trim_leading(nickname_or_mention, "@")
1808
1809   def error_user(ap_id) do
1810     %User{
1811       name: ap_id,
1812       ap_id: ap_id,
1813       nickname: "erroruser@example.com",
1814       inserted_at: NaiveDateTime.utc_now()
1815     }
1816   end
1817
1818   @spec all_superusers() :: [User.t()]
1819   def all_superusers do
1820     User.Query.build(%{super_users: true, local: true, deactivated: false})
1821     |> Repo.all()
1822   end
1823
1824   def muting_reblogs?(%User{} = user, %User{} = target) do
1825     UserRelationship.reblog_mute_exists?(user, target)
1826   end
1827
1828   def showing_reblogs?(%User{} = user, %User{} = target) do
1829     not muting_reblogs?(user, target)
1830   end
1831
1832   @doc """
1833   The function returns a query to get users with no activity for given interval of days.
1834   Inactive users are those who didn't read any notification, or had any activity where
1835   the user is the activity's actor, during `inactivity_threshold` days.
1836   Deactivated users will not appear in this list.
1837
1838   ## Examples
1839
1840       iex> Pleroma.User.list_inactive_users()
1841       %Ecto.Query{}
1842   """
1843   @spec list_inactive_users_query(integer()) :: Ecto.Query.t()
1844   def list_inactive_users_query(inactivity_threshold \\ 7) do
1845     negative_inactivity_threshold = -inactivity_threshold
1846     now = NaiveDateTime.truncate(NaiveDateTime.utc_now(), :second)
1847     # Subqueries are not supported in `where` clauses, join gets too complicated.
1848     has_read_notifications =
1849       from(n in Pleroma.Notification,
1850         where: n.seen == true,
1851         group_by: n.id,
1852         having: max(n.updated_at) > datetime_add(^now, ^negative_inactivity_threshold, "day"),
1853         select: n.user_id
1854       )
1855       |> Pleroma.Repo.all()
1856
1857     from(u in Pleroma.User,
1858       left_join: a in Pleroma.Activity,
1859       on: u.ap_id == a.actor,
1860       where: not is_nil(u.nickname),
1861       where: u.deactivated != ^true,
1862       where: u.id not in ^has_read_notifications,
1863       group_by: u.id,
1864       having:
1865         max(a.inserted_at) < datetime_add(^now, ^negative_inactivity_threshold, "day") or
1866           is_nil(max(a.inserted_at))
1867     )
1868   end
1869
1870   @doc """
1871   Enable or disable email notifications for user
1872
1873   ## Examples
1874
1875       iex> Pleroma.User.switch_email_notifications(Pleroma.User{email_notifications: %{"digest" => false}}, "digest", true)
1876       Pleroma.User{email_notifications: %{"digest" => true}}
1877
1878       iex> Pleroma.User.switch_email_notifications(Pleroma.User{email_notifications: %{"digest" => true}}, "digest", false)
1879       Pleroma.User{email_notifications: %{"digest" => false}}
1880   """
1881   @spec switch_email_notifications(t(), String.t(), boolean()) ::
1882           {:ok, t()} | {:error, Ecto.Changeset.t()}
1883   def switch_email_notifications(user, type, status) do
1884     User.update_email_notifications(user, %{type => status})
1885   end
1886
1887   @doc """
1888   Set `last_digest_emailed_at` value for the user to current time
1889   """
1890   @spec touch_last_digest_emailed_at(t()) :: t()
1891   def touch_last_digest_emailed_at(user) do
1892     now = NaiveDateTime.truncate(NaiveDateTime.utc_now(), :second)
1893
1894     {:ok, updated_user} =
1895       user
1896       |> change(%{last_digest_emailed_at: now})
1897       |> update_and_set_cache()
1898
1899     updated_user
1900   end
1901
1902   @spec toggle_confirmation(User.t()) :: {:ok, User.t()} | {:error, Changeset.t()}
1903   def toggle_confirmation(%User{} = user) do
1904     user
1905     |> confirmation_changeset(need_confirmation: !user.confirmation_pending)
1906     |> update_and_set_cache()
1907   end
1908
1909   @spec toggle_confirmation([User.t()]) :: [{:ok, User.t()} | {:error, Changeset.t()}]
1910   def toggle_confirmation(users) do
1911     Enum.map(users, &toggle_confirmation/1)
1912   end
1913
1914   def get_mascot(%{mascot: %{} = mascot}) when not is_nil(mascot) do
1915     mascot
1916   end
1917
1918   def get_mascot(%{mascot: mascot}) when is_nil(mascot) do
1919     # use instance-default
1920     config = Pleroma.Config.get([:assets, :mascots])
1921     default_mascot = Pleroma.Config.get([:assets, :default_mascot])
1922     mascot = Keyword.get(config, default_mascot)
1923
1924     %{
1925       "id" => "default-mascot",
1926       "url" => mascot[:url],
1927       "preview_url" => mascot[:url],
1928       "pleroma" => %{
1929         "mime_type" => mascot[:mime_type]
1930       }
1931     }
1932   end
1933
1934   def ensure_keys_present(%{keys: keys} = user) when not is_nil(keys), do: {:ok, user}
1935
1936   def ensure_keys_present(%User{} = user) do
1937     with {:ok, pem} <- Keys.generate_rsa_pem() do
1938       user
1939       |> cast(%{keys: pem}, [:keys])
1940       |> validate_required([:keys])
1941       |> update_and_set_cache()
1942     end
1943   end
1944
1945   def get_ap_ids_by_nicknames(nicknames) do
1946     from(u in User,
1947       where: u.nickname in ^nicknames,
1948       select: u.ap_id
1949     )
1950     |> Repo.all()
1951   end
1952
1953   defdelegate search(query, opts \\ []), to: User.Search
1954
1955   defp put_password_hash(
1956          %Ecto.Changeset{valid?: true, changes: %{password: password}} = changeset
1957        ) do
1958     change(changeset, password_hash: Pbkdf2.hash_pwd_salt(password))
1959   end
1960
1961   defp put_password_hash(changeset), do: changeset
1962
1963   def is_internal_user?(%User{nickname: nil}), do: true
1964   def is_internal_user?(%User{local: true, nickname: "internal." <> _}), do: true
1965   def is_internal_user?(_), do: false
1966
1967   # A hack because user delete activities have a fake id for whatever reason
1968   # TODO: Get rid of this
1969   def get_delivered_users_by_object_id("pleroma:fake_object_id"), do: []
1970
1971   def get_delivered_users_by_object_id(object_id) do
1972     from(u in User,
1973       inner_join: delivery in assoc(u, :deliveries),
1974       where: delivery.object_id == ^object_id
1975     )
1976     |> Repo.all()
1977   end
1978
1979   def change_email(user, email) do
1980     user
1981     |> cast(%{email: email}, [:email])
1982     |> validate_required([:email])
1983     |> unique_constraint(:email)
1984     |> validate_format(:email, @email_regex)
1985     |> update_and_set_cache()
1986   end
1987
1988   # Internal function; public one is `deactivate/2`
1989   defp set_activation_status(user, deactivated) do
1990     user
1991     |> cast(%{deactivated: deactivated}, [:deactivated])
1992     |> update_and_set_cache()
1993   end
1994
1995   def update_banner(user, banner) do
1996     user
1997     |> cast(%{banner: banner}, [:banner])
1998     |> update_and_set_cache()
1999   end
2000
2001   def update_background(user, background) do
2002     user
2003     |> cast(%{background: background}, [:background])
2004     |> update_and_set_cache()
2005   end
2006
2007   def roles(%{is_moderator: is_moderator, is_admin: is_admin}) do
2008     %{
2009       admin: is_admin,
2010       moderator: is_moderator
2011     }
2012   end
2013
2014   def validate_fields(changeset, remote? \\ false) do
2015     limit_name = if remote?, do: :max_remote_account_fields, else: :max_account_fields
2016     limit = Pleroma.Config.get([:instance, limit_name], 0)
2017
2018     changeset
2019     |> validate_length(:fields, max: limit)
2020     |> validate_change(:fields, fn :fields, fields ->
2021       if Enum.all?(fields, &valid_field?/1) do
2022         []
2023       else
2024         [fields: "invalid"]
2025       end
2026     end)
2027   end
2028
2029   defp valid_field?(%{"name" => name, "value" => value}) do
2030     name_limit = Pleroma.Config.get([:instance, :account_field_name_length], 255)
2031     value_limit = Pleroma.Config.get([:instance, :account_field_value_length], 255)
2032
2033     is_binary(name) && is_binary(value) && String.length(name) <= name_limit &&
2034       String.length(value) <= value_limit
2035   end
2036
2037   defp valid_field?(_), do: false
2038
2039   defp truncate_field(%{"name" => name, "value" => value}) do
2040     {name, _chopped} =
2041       String.split_at(name, Pleroma.Config.get([:instance, :account_field_name_length], 255))
2042
2043     {value, _chopped} =
2044       String.split_at(value, Pleroma.Config.get([:instance, :account_field_value_length], 255))
2045
2046     %{"name" => name, "value" => value}
2047   end
2048
2049   def admin_api_update(user, params) do
2050     user
2051     |> cast(params, [
2052       :is_moderator,
2053       :is_admin,
2054       :show_role
2055     ])
2056     |> update_and_set_cache()
2057   end
2058
2059   @doc "Signs user out of all applications"
2060   def global_sign_out(user) do
2061     OAuth.Authorization.delete_user_authorizations(user)
2062     OAuth.Token.delete_user_tokens(user)
2063   end
2064
2065   def mascot_update(user, url) do
2066     user
2067     |> cast(%{mascot: url}, [:mascot])
2068     |> validate_required([:mascot])
2069     |> update_and_set_cache()
2070   end
2071
2072   def mastodon_settings_update(user, settings) do
2073     user
2074     |> cast(%{settings: settings}, [:settings])
2075     |> validate_required([:settings])
2076     |> update_and_set_cache()
2077   end
2078
2079   @spec confirmation_changeset(User.t(), keyword()) :: Changeset.t()
2080   def confirmation_changeset(user, need_confirmation: need_confirmation?) do
2081     params =
2082       if need_confirmation? do
2083         %{
2084           confirmation_pending: true,
2085           confirmation_token: :crypto.strong_rand_bytes(32) |> Base.url_encode64()
2086         }
2087       else
2088         %{
2089           confirmation_pending: false,
2090           confirmation_token: nil
2091         }
2092       end
2093
2094     cast(user, params, [:confirmation_pending, :confirmation_token])
2095   end
2096
2097   def add_pinnned_activity(user, %Pleroma.Activity{id: id}) do
2098     if id not in user.pinned_activities do
2099       max_pinned_statuses = Pleroma.Config.get([:instance, :max_pinned_statuses], 0)
2100       params = %{pinned_activities: user.pinned_activities ++ [id]}
2101
2102       user
2103       |> cast(params, [:pinned_activities])
2104       |> validate_length(:pinned_activities,
2105         max: max_pinned_statuses,
2106         message: "You have already pinned the maximum number of statuses"
2107       )
2108     else
2109       change(user)
2110     end
2111     |> update_and_set_cache()
2112   end
2113
2114   def remove_pinnned_activity(user, %Pleroma.Activity{id: id}) do
2115     params = %{pinned_activities: List.delete(user.pinned_activities, id)}
2116
2117     user
2118     |> cast(params, [:pinned_activities])
2119     |> update_and_set_cache()
2120   end
2121
2122   def update_email_notifications(user, settings) do
2123     email_notifications =
2124       user.email_notifications
2125       |> Map.merge(settings)
2126       |> Map.take(["digest"])
2127
2128     params = %{email_notifications: email_notifications}
2129     fields = [:email_notifications]
2130
2131     user
2132     |> cast(params, fields)
2133     |> validate_required(fields)
2134     |> update_and_set_cache()
2135   end
2136
2137   defp set_domain_blocks(user, domain_blocks) do
2138     params = %{domain_blocks: domain_blocks}
2139
2140     user
2141     |> cast(params, [:domain_blocks])
2142     |> validate_required([:domain_blocks])
2143     |> update_and_set_cache()
2144   end
2145
2146   def block_domain(user, domain_blocked) do
2147     set_domain_blocks(user, Enum.uniq([domain_blocked | user.domain_blocks]))
2148   end
2149
2150   def unblock_domain(user, domain_blocked) do
2151     set_domain_blocks(user, List.delete(user.domain_blocks, domain_blocked))
2152   end
2153
2154   @spec add_to_block(User.t(), User.t()) ::
2155           {:ok, UserRelationship.t()} | {:error, Ecto.Changeset.t()}
2156   defp add_to_block(%User{} = user, %User{} = blocked) do
2157     UserRelationship.create_block(user, blocked)
2158   end
2159
2160   @spec add_to_block(User.t(), User.t()) ::
2161           {:ok, UserRelationship.t()} | {:ok, nil} | {:error, Ecto.Changeset.t()}
2162   defp remove_from_block(%User{} = user, %User{} = blocked) do
2163     UserRelationship.delete_block(user, blocked)
2164   end
2165
2166   defp add_to_mutes(%User{} = user, %User{} = muted_user, notifications?) do
2167     with {:ok, user_mute} <- UserRelationship.create_mute(user, muted_user),
2168          {:ok, user_notification_mute} <-
2169            (notifications? && UserRelationship.create_notification_mute(user, muted_user)) ||
2170              {:ok, nil} do
2171       {:ok, Enum.filter([user_mute, user_notification_mute], & &1)}
2172     end
2173   end
2174
2175   defp remove_from_mutes(user, %User{} = muted_user) do
2176     with {:ok, user_mute} <- UserRelationship.delete_mute(user, muted_user),
2177          {:ok, user_notification_mute} <-
2178            UserRelationship.delete_notification_mute(user, muted_user) do
2179       {:ok, [user_mute, user_notification_mute]}
2180     end
2181   end
2182
2183   def set_invisible(user, invisible) do
2184     params = %{invisible: invisible}
2185
2186     user
2187     |> cast(params, [:invisible])
2188     |> validate_required([:invisible])
2189     |> update_and_set_cache()
2190   end
2191
2192   def sanitize_html(%User{} = user) do
2193     sanitize_html(user, nil)
2194   end
2195
2196   # User data that mastodon isn't filtering (treated as plaintext):
2197   # - field name
2198   # - display name
2199   def sanitize_html(%User{} = user, filter) do
2200     fields =
2201       Enum.map(user.fields, fn %{"name" => name, "value" => value} ->
2202         %{
2203           "name" => name,
2204           "value" => HTML.filter_tags(value, Pleroma.HTML.Scrubber.LinksOnly)
2205         }
2206       end)
2207
2208     user
2209     |> Map.put(:bio, HTML.filter_tags(user.bio, filter))
2210     |> Map.put(:fields, fields)
2211   end
2212 end