git.squeep.com Git - akkoma/blob - lib/pleroma/user.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.User do
   6   use Ecto.Schema
   7
   8   import Ecto.{Changeset, Query}
   9   alias Pleroma.{Repo, User, Object, Web, Activity, Notification}
  10   alias Comeonin.Pbkdf2
  11   alias Pleroma.Formatter
  12   alias Pleroma.Web.CommonAPI.Utils, as: CommonUtils
  13   alias Pleroma.Web.{OStatus, Websub, OAuth}
  14   alias Pleroma.Web.ActivityPub.{Utils, ActivityPub}
  15
  16   require Logger
  17
  18   @type t :: %__MODULE__{}
  19
  20   @email_regex ~r/^[a-zA-Z0-9.!#$%&'*+\/=?^_`{|}~-]+@[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?(?:\.[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?)*$/
  21
  22   @strict_local_nickname_regex ~r/^[a-zA-Z\d]+$/
  23   @extended_local_nickname_regex ~r/^[a-zA-Z\d_-]+$/
  24
  25   schema "users" do
  26     field(:bio, :string)
  27     field(:email, :string)
  28     field(:name, :string)
  29     field(:nickname, :string)
  30     field(:password_hash, :string)
  31     field(:password, :string, virtual: true)
  32     field(:password_confirmation, :string, virtual: true)
  33     field(:following, {:array, :string}, default: [])
  34     field(:ap_id, :string)
  35     field(:avatar, :map)
  36     field(:local, :boolean, default: true)
  37     field(:follower_address, :string)
  38     field(:search_rank, :float, virtual: true)
  39     field(:tags, {:array, :string}, default: [])
  40     field(:last_refreshed_at, :naive_datetime)
  41     has_many(:notifications, Notification)
  42     embeds_one(:info, Pleroma.User.Info)
  43
  44     timestamps()
  45   end
  46
  47   def auth_active?(%User{local: false}), do: true
  48
  49   def auth_active?(%User{info: %User.Info{confirmation_pending: false}}), do: true
  50
  51   def auth_active?(%User{info: %User.Info{confirmation_pending: true}}),
  52     do: !Pleroma.Config.get([:instance, :account_activation_required])
  53
  54   def auth_active?(_), do: false
  55
  56   def visible_for?(user, for_user \\ nil)
  57
  58   def visible_for?(%User{id: user_id}, %User{id: for_id}) when user_id == for_id, do: true
  59
  60   def visible_for?(%User{} = user, for_user) do
  61     auth_active?(user) || superuser?(for_user)
  62   end
  63
  64   def visible_for?(_, _), do: false
  65
  66   def superuser?(%User{local: true, info: %User.Info{is_admin: true}}), do: true
  67   def superuser?(%User{local: true, info: %User.Info{is_moderator: true}}), do: true
  68   def superuser?(_), do: false
  69
  70   def avatar_url(user) do
  71     case user.avatar do
  72       %{"url" => [%{"href" => href} | _]} -> href
  73       _ -> "#{Web.base_url()}/images/avi.png"
  74     end
  75   end
  76
  77   def banner_url(user) do
  78     case user.info.banner do
  79       %{"url" => [%{"href" => href} | _]} -> href
  80       _ -> "#{Web.base_url()}/images/banner.png"
  81     end
  82   end
  83
  84   def profile_url(%User{info: %{source_data: %{"url" => url}}}), do: url
  85   def profile_url(%User{ap_id: ap_id}), do: ap_id
  86   def profile_url(_), do: nil
  87
  88   def ap_id(%User{nickname: nickname}) do
  89     "#{Web.base_url()}/users/#{nickname}"
  90   end
  91
  92   def ap_followers(%User{} = user) do
  93     "#{ap_id(user)}/followers"
  94   end
  95
  96   def follow_changeset(struct, params \\ %{}) do
  97     struct
  98     |> cast(params, [:following])
  99     |> validate_required([:following])
 100   end
 101
 102   def user_info(%User{} = user) do
 103     oneself = if user.local, do: 1, else: 0
 104
 105     %{
 106       following_count: length(user.following) - oneself,
 107       note_count: user.info.note_count,
 108       follower_count: user.info.follower_count,
 109       locked: user.info.locked,
 110       confirmation_pending: user.info.confirmation_pending,
 111       default_scope: user.info.default_scope
 112     }
 113   end
 114
 115   def remote_user_creation(params) do
 116     params =
 117       params
 118       |> Map.put(:info, params[:info] || %{})
 119
 120     info_cng = User.Info.remote_user_creation(%User.Info{}, params[:info])
 121
 122     changes =
 123       %User{}
 124       |> cast(params, [:bio, :name, :ap_id, :nickname, :avatar])
 125       |> validate_required([:name, :ap_id])
 126       |> unique_constraint(:nickname)
 127       |> validate_format(:nickname, @email_regex)
 128       |> validate_length(:bio, max: 5000)
 129       |> validate_length(:name, max: 100)
 130       |> put_change(:local, false)
 131       |> put_embed(:info, info_cng)
 132
 133     if changes.valid? do
 134       case info_cng.changes[:source_data] do
 135         %{"followers" => followers} ->
 136           changes
 137           |> put_change(:follower_address, followers)
 138
 139         _ ->
 140           followers = User.ap_followers(%User{nickname: changes.changes[:nickname]})
 141
 142           changes
 143           |> put_change(:follower_address, followers)
 144       end
 145     else
 146       changes
 147     end
 148   end
 149
 150   def update_changeset(struct, params \\ %{}) do
 151     struct
 152     |> cast(params, [:bio, :name, :avatar])
 153     |> unique_constraint(:nickname)
 154     |> validate_format(:nickname, local_nickname_regex())
 155     |> validate_length(:bio, max: 5000)
 156     |> validate_length(:name, min: 1, max: 100)
 157   end
 158
 159   def upgrade_changeset(struct, params \\ %{}) do
 160     params =
 161       params
 162       |> Map.put(:last_refreshed_at, NaiveDateTime.utc_now())
 163
 164     info_cng =
 165       struct.info
 166       |> User.Info.user_upgrade(params[:info])
 167
 168     struct
 169     |> cast(params, [:bio, :name, :follower_address, :avatar, :last_refreshed_at])
 170     |> unique_constraint(:nickname)
 171     |> validate_format(:nickname, local_nickname_regex())
 172     |> validate_length(:bio, max: 5000)
 173     |> validate_length(:name, max: 100)
 174     |> put_embed(:info, info_cng)
 175   end
 176
 177   def password_update_changeset(struct, params) do
 178     changeset =
 179       struct
 180       |> cast(params, [:password, :password_confirmation])
 181       |> validate_required([:password, :password_confirmation])
 182       |> validate_confirmation(:password)
 183
 184     OAuth.Token.delete_user_tokens(struct)
 185     OAuth.Authorization.delete_user_authorizations(struct)
 186
 187     if changeset.valid? do
 188       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 189
 190       changeset
 191       |> put_change(:password_hash, hashed)
 192     else
 193       changeset
 194     end
 195   end
 196
 197   def reset_password(user, data) do
 198     update_and_set_cache(password_update_changeset(user, data))
 199   end
 200
 201   def register_changeset(struct, params \\ %{}, opts \\ []) do
 202     confirmation_status =
 203       if opts[:confirmed] || !Pleroma.Config.get([:instance, :account_activation_required]) do
 204         :confirmed
 205       else
 206         :unconfirmed
 207       end
 208
 209     info_change = User.Info.confirmation_changeset(%User.Info{}, confirmation_status)
 210
 211     changeset =
 212       struct
 213       |> cast(params, [:bio, :email, :name, :nickname, :password, :password_confirmation])
 214       |> validate_required([:email, :name, :nickname, :password, :password_confirmation])
 215       |> validate_confirmation(:password)
 216       |> unique_constraint(:email)
 217       |> unique_constraint(:nickname)
 218       |> validate_exclusion(:nickname, Pleroma.Config.get([Pleroma.User, :restricted_nicknames]))
 219       |> validate_format(:nickname, local_nickname_regex())
 220       |> validate_format(:email, @email_regex)
 221       |> validate_length(:bio, max: 1000)
 222       |> validate_length(:name, min: 1, max: 100)
 223       |> put_change(:info, info_change)
 224
 225     if changeset.valid? do
 226       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 227       ap_id = User.ap_id(%User{nickname: changeset.changes[:nickname]})
 228       followers = User.ap_followers(%User{nickname: changeset.changes[:nickname]})
 229
 230       changeset
 231       |> put_change(:password_hash, hashed)
 232       |> put_change(:ap_id, ap_id)
 233       |> put_change(:following, [followers])
 234       |> put_change(:follower_address, followers)
 235     else
 236       changeset
 237     end
 238   end
 239
 240   defp autofollow_users(user) do
 241     candidates = Pleroma.Config.get([:instance, :autofollowed_nicknames])
 242
 243     autofollowed_users =
 244       from(u in User,
 245         where: u.local == true,
 246         where: u.nickname in ^candidates
 247       )
 248       |> Repo.all()
 249
 250     follow_all(user, autofollowed_users)
 251   end
 252
 253   @doc "Inserts provided changeset, performs post-registration actions (confirmation email sending etc.)"
 254   def register(%Ecto.Changeset{} = changeset) do
 255     with {:ok, user} <- Repo.insert(changeset),
 256          {:ok, _} <- try_send_confirmation_email(user),
 257          {:ok, user} <- autofollow_users(user) do
 258       {:ok, user}
 259     end
 260   end
 261
 262   def try_send_confirmation_email(%User{} = user) do
 263     if user.info.confirmation_pending &&
 264          Pleroma.Config.get([:instance, :account_activation_required]) do
 265       user
 266       |> Pleroma.UserEmail.account_confirmation_email()
 267       |> Pleroma.Mailer.deliver()
 268     else
 269       {:ok, :noop}
 270     end
 271   end
 272
 273   def needs_update?(%User{local: true}), do: false
 274
 275   def needs_update?(%User{local: false, last_refreshed_at: nil}), do: true
 276
 277   def needs_update?(%User{local: false} = user) do
 278     NaiveDateTime.diff(NaiveDateTime.utc_now(), user.last_refreshed_at) >= 86400
 279   end
 280
 281   def needs_update?(_), do: true
 282
 283   def maybe_direct_follow(%User{} = follower, %User{local: true, info: %{locked: true}}) do
 284     {:ok, follower}
 285   end
 286
 287   def maybe_direct_follow(%User{} = follower, %User{local: true} = followed) do
 288     follow(follower, followed)
 289   end
 290
 291   def maybe_direct_follow(%User{} = follower, %User{} = followed) do
 292     if not User.ap_enabled?(followed) do
 293       follow(follower, followed)
 294     else
 295       {:ok, follower}
 296     end
 297   end
 298
 299   def maybe_follow(%User{} = follower, %User{info: _info} = followed) do
 300     if not following?(follower, followed) do
 301       follow(follower, followed)
 302     else
 303       {:ok, follower}
 304     end
 305   end
 306
 307   @doc "A mass follow for local users. Ignores blocks and has no side effects"
 308   @spec follow_all(User.t(), list(User.t())) :: {atom(), User.t()}
 309   def follow_all(follower, followeds) do
 310     following =
 311       (follower.following ++ Enum.map(followeds, fn %{follower_address: fa} -> fa end))
 312       |> Enum.uniq()
 313
 314     {:ok, follower} =
 315       follower
 316       |> follow_changeset(%{following: following})
 317       |> update_and_set_cache
 318
 319     Enum.each(followeds, fn followed ->
 320       update_follower_count(followed)
 321     end)
 322
 323     {:ok, follower}
 324   end
 325
 326   def follow(%User{} = follower, %User{info: info} = followed) do
 327     user_config = Application.get_env(:pleroma, :user)
 328     deny_follow_blocked = Keyword.get(user_config, :deny_follow_blocked)
 329
 330     ap_followers = followed.follower_address
 331
 332     cond do
 333       following?(follower, followed) or info.deactivated ->
 334         {:error, "Could not follow user: #{followed.nickname} is already on your list."}
 335
 336       deny_follow_blocked and blocks?(followed, follower) ->
 337         {:error, "Could not follow user: #{followed.nickname} blocked you."}
 338
 339       true ->
 340         if !followed.local && follower.local && !ap_enabled?(followed) do
 341           Websub.subscribe(follower, followed)
 342         end
 343
 344         following =
 345           [ap_followers | follower.following]
 346           |> Enum.uniq()
 347
 348         follower =
 349           follower
 350           |> follow_changeset(%{following: following})
 351           |> update_and_set_cache
 352
 353         {:ok, _} = update_follower_count(followed)
 354
 355         follower
 356     end
 357   end
 358
 359   def unfollow(%User{} = follower, %User{} = followed) do
 360     ap_followers = followed.follower_address
 361
 362     if following?(follower, followed) and follower.ap_id != followed.ap_id do
 363       following =
 364         follower.following
 365         |> List.delete(ap_followers)
 366
 367       {:ok, follower} =
 368         follower
 369         |> follow_changeset(%{following: following})
 370         |> update_and_set_cache
 371
 372       {:ok, followed} = update_follower_count(followed)
 373
 374       {:ok, follower, Utils.fetch_latest_follow(follower, followed)}
 375     else
 376       {:error, "Not subscribed!"}
 377     end
 378   end
 379
 380   @spec following?(User.t(), User.t()) :: boolean
 381   def following?(%User{} = follower, %User{} = followed) do
 382     Enum.member?(follower.following, followed.follower_address)
 383   end
 384
 385   def follow_import(%User{} = follower, followed_identifiers)
 386       when is_list(followed_identifiers) do
 387     Enum.map(
 388       followed_identifiers,
 389       fn followed_identifier ->
 390         with %User{} = followed <- get_or_fetch(followed_identifier),
 391              {:ok, follower} <- maybe_direct_follow(follower, followed),
 392              {:ok, _} <- ActivityPub.follow(follower, followed) do
 393           followed
 394         else
 395           err ->
 396             Logger.debug("follow_import failed for #{followed_identifier} with: #{inspect(err)}")
 397             err
 398         end
 399       end
 400     )
 401   end
 402
 403   def locked?(%User{} = user) do
 404     user.info.locked || false
 405   end
 406
 407   def get_by_ap_id(ap_id) do
 408     Repo.get_by(User, ap_id: ap_id)
 409   end
 410
 411   # This is mostly an SPC migration fix. This guesses the user nickname (by taking the last part of the ap_id and the domain) and tries to get that user
 412   def get_by_guessed_nickname(ap_id) do
 413     domain = URI.parse(ap_id).host
 414     name = List.last(String.split(ap_id, "/"))
 415     nickname = "#{name}@#{domain}"
 416
 417     get_by_nickname(nickname)
 418   end
 419
 420   def update_and_set_cache(changeset) do
 421     with {:ok, user} <- Repo.update(changeset) do
 422       Cachex.put(:user_cache, "ap_id:#{user.ap_id}", user)
 423       Cachex.put(:user_cache, "nickname:#{user.nickname}", user)
 424       Cachex.put(:user_cache, "user_info:#{user.id}", user_info(user))
 425       {:ok, user}
 426     else
 427       e -> e
 428     end
 429   end
 430
 431   def invalidate_cache(user) do
 432     Cachex.del(:user_cache, "ap_id:#{user.ap_id}")
 433     Cachex.del(:user_cache, "nickname:#{user.nickname}")
 434     Cachex.del(:user_cache, "user_info:#{user.id}")
 435   end
 436
 437   def get_cached_by_ap_id(ap_id) do
 438     key = "ap_id:#{ap_id}"
 439     Cachex.fetch!(:user_cache, key, fn _ -> get_by_ap_id(ap_id) end)
 440   end
 441
 442   def get_cached_by_nickname(nickname) do
 443     key = "nickname:#{nickname}"
 444     Cachex.fetch!(:user_cache, key, fn _ -> get_or_fetch_by_nickname(nickname) end)
 445   end
 446
 447   def get_by_nickname(nickname) do
 448     Repo.get_by(User, nickname: nickname) ||
 449       if Regex.match?(~r(@#{Pleroma.Web.Endpoint.host()})i, nickname) do
 450         [local_nickname, _] = String.split(nickname, "@")
 451         Repo.get_by(User, nickname: local_nickname)
 452       end
 453   end
 454
 455   def get_by_nickname_or_email(nickname_or_email) do
 456     case user = Repo.get_by(User, nickname: nickname_or_email) do
 457       %User{} -> user
 458       nil -> Repo.get_by(User, email: nickname_or_email)
 459     end
 460   end
 461
 462   def get_cached_user_info(user) do
 463     key = "user_info:#{user.id}"
 464     Cachex.fetch!(:user_cache, key, fn _ -> user_info(user) end)
 465   end
 466
 467   def fetch_by_nickname(nickname) do
 468     ap_try = ActivityPub.make_user_from_nickname(nickname)
 469
 470     case ap_try do
 471       {:ok, user} -> {:ok, user}
 472       _ -> OStatus.make_user(nickname)
 473     end
 474   end
 475
 476   def get_or_fetch_by_nickname(nickname) do
 477     with %User{} = user <- get_by_nickname(nickname) do
 478       user
 479     else
 480       _e ->
 481         with [_nick, _domain] <- String.split(nickname, "@"),
 482              {:ok, user} <- fetch_by_nickname(nickname) do
 483           user
 484         else
 485           _e -> nil
 486         end
 487     end
 488   end
 489
 490   def get_followers_query(%User{id: id, follower_address: follower_address}, nil) do
 491     from(
 492       u in User,
 493       where: fragment("? <@ ?", ^[follower_address], u.following),
 494       where: u.id != ^id
 495     )
 496   end
 497
 498   def get_followers_query(user, page) do
 499     from(
 500       u in get_followers_query(user, nil),
 501       limit: 20,
 502       offset: ^((page - 1) * 20)
 503     )
 504   end
 505
 506   def get_followers_query(user), do: get_followers_query(user, nil)
 507
 508   def get_followers(user, page \\ nil) do
 509     q = get_followers_query(user, page)
 510
 511     {:ok, Repo.all(q)}
 512   end
 513
 514   def get_followers_ids(user, page \\ nil) do
 515     q = get_followers_query(user, page)
 516
 517     Repo.all(from(u in q, select: u.id))
 518   end
 519
 520   def get_friends_query(%User{id: id, following: following}, nil) do
 521     from(
 522       u in User,
 523       where: u.follower_address in ^following,
 524       where: u.id != ^id
 525     )
 526   end
 527
 528   def get_friends_query(user, page) do
 529     from(
 530       u in get_friends_query(user, nil),
 531       limit: 20,
 532       offset: ^((page - 1) * 20)
 533     )
 534   end
 535
 536   def get_friends_query(user), do: get_friends_query(user, nil)
 537
 538   def get_friends(user, page \\ nil) do
 539     q = get_friends_query(user, page)
 540
 541     {:ok, Repo.all(q)}
 542   end
 543
 544   def get_friends_ids(user, page \\ nil) do
 545     q = get_friends_query(user, page)
 546
 547     Repo.all(from(u in q, select: u.id))
 548   end
 549
 550   def get_follow_requests_query(%User{} = user) do
 551     from(
 552       a in Activity,
 553       where:
 554         fragment(
 555           "? ->> 'type' = 'Follow'",
 556           a.data
 557         ),
 558       where:
 559         fragment(
 560           "? ->> 'state' = 'pending'",
 561           a.data
 562         ),
 563       where:
 564         fragment(
 565           "? @> ?",
 566           a.data,
 567           ^%{"object" => user.ap_id}
 568         )
 569     )
 570   end
 571
 572   def get_follow_requests(%User{} = user) do
 573     q = get_follow_requests_query(user)
 574     reqs = Repo.all(q)
 575
 576     users =
 577       Enum.map(reqs, fn req -> req.actor end)
 578       |> Enum.uniq()
 579       |> Enum.map(fn ap_id -> get_by_ap_id(ap_id) end)
 580       |> Enum.filter(fn u -> !is_nil(u) end)
 581       |> Enum.filter(fn u -> !following?(u, user) end)
 582
 583     {:ok, users}
 584   end
 585
 586   def increase_note_count(%User{} = user) do
 587     info_cng = User.Info.add_to_note_count(user.info, 1)
 588
 589     cng =
 590       change(user)
 591       |> put_embed(:info, info_cng)
 592
 593     update_and_set_cache(cng)
 594   end
 595
 596   def decrease_note_count(%User{} = user) do
 597     info_cng = User.Info.add_to_note_count(user.info, -1)
 598
 599     cng =
 600       change(user)
 601       |> put_embed(:info, info_cng)
 602
 603     update_and_set_cache(cng)
 604   end
 605
 606   def update_note_count(%User{} = user) do
 607     note_count_query =
 608       from(
 609         a in Object,
 610         where: fragment("?->>'actor' = ? and ?->>'type' = 'Note'", a.data, ^user.ap_id, a.data),
 611         select: count(a.id)
 612       )
 613
 614     note_count = Repo.one(note_count_query)
 615
 616     info_cng = User.Info.set_note_count(user.info, note_count)
 617
 618     cng =
 619       change(user)
 620       |> put_embed(:info, info_cng)
 621
 622     update_and_set_cache(cng)
 623   end
 624
 625   def update_follower_count(%User{} = user) do
 626     follower_count_query =
 627       from(
 628         u in User,
 629         where: ^user.follower_address in u.following,
 630         where: u.id != ^user.id,
 631         select: count(u.id)
 632       )
 633
 634     follower_count = Repo.one(follower_count_query)
 635
 636     info_cng =
 637       user.info
 638       |> User.Info.set_follower_count(follower_count)
 639
 640     cng =
 641       change(user)
 642       |> put_embed(:info, info_cng)
 643
 644     update_and_set_cache(cng)
 645   end
 646
 647   def get_users_from_set_query(ap_ids, false) do
 648     from(
 649       u in User,
 650       where: u.ap_id in ^ap_ids
 651     )
 652   end
 653
 654   def get_users_from_set_query(ap_ids, true) do
 655     query = get_users_from_set_query(ap_ids, false)
 656
 657     from(
 658       u in query,
 659       where: u.local == true
 660     )
 661   end
 662
 663   def get_users_from_set(ap_ids, local_only \\ true) do
 664     get_users_from_set_query(ap_ids, local_only)
 665     |> Repo.all()
 666   end
 667
 668   def get_recipients_from_activity(%Activity{recipients: to}) do
 669     query =
 670       from(
 671         u in User,
 672         where: u.ap_id in ^to,
 673         or_where: fragment("? && ?", u.following, ^to)
 674       )
 675
 676     query = from(u in query, where: u.local == true)
 677
 678     Repo.all(query)
 679   end
 680
 681   def search(query, resolve \\ false, for_user \\ nil) do
 682     # strip the beginning @ off if there is a query
 683     query = String.trim_leading(query, "@")
 684
 685     if resolve do
 686       User.get_or_fetch_by_nickname(query)
 687     end
 688
 689     processed_query =
 690       query
 691       |> String.replace(~r/\W+/, " ")
 692       |> String.trim()
 693       |> String.split()
 694       |> Enum.map(&(&1 <> ":*"))
 695       |> Enum.join(" | ")
 696
 697     inner =
 698       from(
 699         u in User,
 700         select_merge: %{
 701           search_rank:
 702             fragment(
 703               """
 704               ts_rank_cd(
 705                 setweight(to_tsvector('simple', regexp_replace(nickname, '\\W', ' ', 'g')), 'A') ||
 706                 setweight(to_tsvector('simple', regexp_replace(coalesce(name, ''), '\\W', ' ', 'g')), 'B'),
 707                 to_tsquery('simple', ?),
 708                 32
 709               )
 710               """,
 711               ^processed_query
 712             )
 713         },
 714         where: not is_nil(u.nickname)
 715       )
 716
 717     q =
 718       from(
 719         s in subquery(inner),
 720         order_by: [desc: s.search_rank],
 721         limit: 20
 722       )
 723
 724     results =
 725       q
 726       |> Repo.all()
 727       |> Enum.filter(&(&1.search_rank > 0))
 728
 729     weighted_results =
 730       if for_user do
 731         friends_ids = get_friends_ids(for_user)
 732         followers_ids = get_followers_ids(for_user)
 733
 734         Enum.map(
 735           results,
 736           fn u ->
 737             search_rank_coef =
 738               cond do
 739                 u.id in friends_ids ->
 740                   1.2
 741
 742                 u.id in followers_ids ->
 743                   1.1
 744
 745                 true ->
 746                   1
 747               end
 748
 749             Map.put(u, :search_rank, u.search_rank * search_rank_coef)
 750           end
 751         )
 752         |> Enum.sort_by(&(-&1.search_rank))
 753       else
 754         results
 755       end
 756
 757     weighted_results
 758   end
 759
 760   def blocks_import(%User{} = blocker, blocked_identifiers) when is_list(blocked_identifiers) do
 761     Enum.map(
 762       blocked_identifiers,
 763       fn blocked_identifier ->
 764         with %User{} = blocked <- get_or_fetch(blocked_identifier),
 765              {:ok, blocker} <- block(blocker, blocked),
 766              {:ok, _} <- ActivityPub.block(blocker, blocked) do
 767           blocked
 768         else
 769           err ->
 770             Logger.debug("blocks_import failed for #{blocked_identifier} with: #{inspect(err)}")
 771             err
 772         end
 773       end
 774     )
 775   end
 776
 777   def block(blocker, %User{ap_id: ap_id} = blocked) do
 778     # sever any follow relationships to prevent leaks per activitypub (Pleroma issue #213)
 779     blocker =
 780       if following?(blocker, blocked) do
 781         {:ok, blocker, _} = unfollow(blocker, blocked)
 782         blocker
 783       else
 784         blocker
 785       end
 786
 787     if following?(blocked, blocker) do
 788       unfollow(blocked, blocker)
 789     end
 790
 791     info_cng =
 792       blocker.info
 793       |> User.Info.add_to_block(ap_id)
 794
 795     cng =
 796       change(blocker)
 797       |> put_embed(:info, info_cng)
 798
 799     update_and_set_cache(cng)
 800   end
 801
 802   # helper to handle the block given only an actor's AP id
 803   def block(blocker, %{ap_id: ap_id}) do
 804     block(blocker, User.get_by_ap_id(ap_id))
 805   end
 806
 807   def unblock(blocker, %{ap_id: ap_id}) do
 808     info_cng =
 809       blocker.info
 810       |> User.Info.remove_from_block(ap_id)
 811
 812     cng =
 813       change(blocker)
 814       |> put_embed(:info, info_cng)
 815
 816     update_and_set_cache(cng)
 817   end
 818
 819   def blocks?(user, %{ap_id: ap_id}) do
 820     blocks = user.info.blocks
 821     domain_blocks = user.info.domain_blocks
 822     %{host: host} = URI.parse(ap_id)
 823
 824     Enum.member?(blocks, ap_id) ||
 825       Enum.any?(domain_blocks, fn domain ->
 826         host == domain
 827       end)
 828   end
 829
 830   def blocked_users(user),
 831     do: Repo.all(from(u in User, where: u.ap_id in ^user.info.blocks))
 832
 833   def block_domain(user, domain) do
 834     info_cng =
 835       user.info
 836       |> User.Info.add_to_domain_block(domain)
 837
 838     cng =
 839       change(user)
 840       |> put_embed(:info, info_cng)
 841
 842     update_and_set_cache(cng)
 843   end
 844
 845   def unblock_domain(user, domain) do
 846     info_cng =
 847       user.info
 848       |> User.Info.remove_from_domain_block(domain)
 849
 850     cng =
 851       change(user)
 852       |> put_embed(:info, info_cng)
 853
 854     update_and_set_cache(cng)
 855   end
 856
 857   def local_user_query() do
 858     from(
 859       u in User,
 860       where: u.local == true,
 861       where: not is_nil(u.nickname)
 862     )
 863   end
 864
 865   def moderator_user_query() do
 866     from(
 867       u in User,
 868       where: u.local == true,
 869       where: fragment("?->'is_moderator' @> 'true'", u.info)
 870     )
 871   end
 872
 873   def deactivate(%User{} = user, status \\ true) do
 874     info_cng = User.Info.set_activation_status(user.info, status)
 875
 876     cng =
 877       change(user)
 878       |> put_embed(:info, info_cng)
 879
 880     update_and_set_cache(cng)
 881   end
 882
 883   def delete(%User{} = user) do
 884     {:ok, user} = User.deactivate(user)
 885
 886     # Remove all relationships
 887     {:ok, followers} = User.get_followers(user)
 888
 889     followers
 890     |> Enum.each(fn follower -> User.unfollow(follower, user) end)
 891
 892     {:ok, friends} = User.get_friends(user)
 893
 894     friends
 895     |> Enum.each(fn followed -> User.unfollow(user, followed) end)
 896
 897     query = from(a in Activity, where: a.actor == ^user.ap_id)
 898
 899     Repo.all(query)
 900     |> Enum.each(fn activity ->
 901       case activity.data["type"] do
 902         "Create" ->
 903           ActivityPub.delete(Object.normalize(activity.data["object"]))
 904
 905         # TODO: Do something with likes, follows, repeats.
 906         _ ->
 907           "Doing nothing"
 908       end
 909     end)
 910
 911     {:ok, user}
 912   end
 913
 914   def html_filter_policy(%User{info: %{no_rich_text: true}}) do
 915     Pleroma.HTML.Scrubber.TwitterText
 916   end
 917
 918   @default_scrubbers Pleroma.Config.get([:markup, :scrub_policy])
 919
 920   def html_filter_policy(_), do: @default_scrubbers
 921
 922   def get_or_fetch_by_ap_id(ap_id) do
 923     user = get_by_ap_id(ap_id)
 924
 925     if !is_nil(user) and !User.needs_update?(user) do
 926       user
 927     else
 928       ap_try = ActivityPub.make_user_from_ap_id(ap_id)
 929
 930       case ap_try do
 931         {:ok, user} ->
 932           user
 933
 934         _ ->
 935           case OStatus.make_user(ap_id) do
 936             {:ok, user} -> user
 937             _ -> {:error, "Could not fetch by AP id"}
 938           end
 939       end
 940     end
 941   end
 942
 943   def get_or_create_instance_user do
 944     relay_uri = "#{Pleroma.Web.Endpoint.url()}/relay"
 945
 946     if user = get_by_ap_id(relay_uri) do
 947       user
 948     else
 949       changes =
 950         %User{info: %User.Info{}}
 951         |> cast(%{}, [:ap_id, :nickname, :local])
 952         |> put_change(:ap_id, relay_uri)
 953         |> put_change(:nickname, nil)
 954         |> put_change(:local, true)
 955         |> put_change(:follower_address, relay_uri <> "/followers")
 956
 957       {:ok, user} = Repo.insert(changes)
 958       user
 959     end
 960   end
 961
 962   # AP style
 963   def public_key_from_info(%{
 964         source_data: %{"publicKey" => %{"publicKeyPem" => public_key_pem}}
 965       }) do
 966     key =
 967       public_key_pem
 968       |> :public_key.pem_decode()
 969       |> hd()
 970       |> :public_key.pem_entry_decode()
 971
 972     {:ok, key}
 973   end
 974
 975   # OStatus Magic Key
 976   def public_key_from_info(%{magic_key: magic_key}) do
 977     {:ok, Pleroma.Web.Salmon.decode_key(magic_key)}
 978   end
 979
 980   def get_public_key_for_ap_id(ap_id) do
 981     with %User{} = user <- get_or_fetch_by_ap_id(ap_id),
 982          {:ok, public_key} <- public_key_from_info(user.info) do
 983       {:ok, public_key}
 984     else
 985       _ -> :error
 986     end
 987   end
 988
 989   defp blank?(""), do: nil
 990   defp blank?(n), do: n
 991
 992   def insert_or_update_user(data) do
 993     data =
 994       data
 995       |> Map.put(:name, blank?(data[:name]) || data[:nickname])
 996
 997     cs = User.remote_user_creation(data)
 998
 999     Repo.insert(cs, on_conflict: :replace_all, conflict_target: :nickname)
1000   end
1001
1002   def ap_enabled?(%User{local: true}), do: true
1003   def ap_enabled?(%User{info: info}), do: info.ap_enabled
1004   def ap_enabled?(_), do: false
1005
1006   @doc "Gets or fetch a user by uri or nickname."
1007   @spec get_or_fetch(String.t()) :: User.t()
1008   def get_or_fetch("http" <> _host = uri), do: get_or_fetch_by_ap_id(uri)
1009   def get_or_fetch(nickname), do: get_or_fetch_by_nickname(nickname)
1010
1011   # wait a period of time and return newest version of the User structs
1012   # this is because we have synchronous follow APIs and need to simulate them
1013   # with an async handshake
1014   def wait_and_refresh(_, %User{local: true} = a, %User{local: true} = b) do
1015     with %User{} = a <- Repo.get(User, a.id),
1016          %User{} = b <- Repo.get(User, b.id) do
1017       {:ok, a, b}
1018     else
1019       _e ->
1020         :error
1021     end
1022   end
1023
1024   def wait_and_refresh(timeout, %User{} = a, %User{} = b) do
1025     with :ok <- :timer.sleep(timeout),
1026          %User{} = a <- Repo.get(User, a.id),
1027          %User{} = b <- Repo.get(User, b.id) do
1028       {:ok, a, b}
1029     else
1030       _e ->
1031         :error
1032     end
1033   end
1034
1035   def parse_bio(bio, user \\ %User{info: %{source_data: %{}}})
1036   def parse_bio(nil, _user), do: ""
1037   def parse_bio(bio, _user) when bio == "", do: bio
1038
1039   def parse_bio(bio, user) do
1040     mentions = Formatter.parse_mentions(bio)
1041     tags = Formatter.parse_tags(bio)
1042
1043     emoji =
1044       (user.info.source_data["tag"] || [])
1045       |> Enum.filter(fn %{"type" => t} -> t == "Emoji" end)
1046       |> Enum.map(fn %{"icon" => %{"url" => url}, "name" => name} ->
1047         {String.trim(name, ":"), url}
1048       end)
1049
1050     bio
1051     |> CommonUtils.format_input(mentions, tags, "text/plain")
1052     |> Formatter.emojify(emoji)
1053   end
1054
1055   def tag(user_identifiers, tags) when is_list(user_identifiers) do
1056     Repo.transaction(fn ->
1057       for user_identifier <- user_identifiers, do: tag(user_identifier, tags)
1058     end)
1059   end
1060
1061   def tag(nickname, tags) when is_binary(nickname),
1062     do: tag(User.get_by_nickname(nickname), tags)
1063
1064   def tag(%User{} = user, tags),
1065     do: update_tags(user, Enum.uniq((user.tags || []) ++ normalize_tags(tags)))
1066
1067   def untag(user_identifiers, tags) when is_list(user_identifiers) do
1068     Repo.transaction(fn ->
1069       for user_identifier <- user_identifiers, do: untag(user_identifier, tags)
1070     end)
1071   end
1072
1073   def untag(nickname, tags) when is_binary(nickname),
1074     do: untag(User.get_by_nickname(nickname), tags)
1075
1076   def untag(%User{} = user, tags),
1077     do: update_tags(user, (user.tags || []) -- normalize_tags(tags))
1078
1079   defp update_tags(%User{} = user, new_tags) do
1080     {:ok, updated_user} =
1081       user
1082       |> change(%{tags: new_tags})
1083       |> Repo.update()
1084
1085     updated_user
1086   end
1087
1088   defp normalize_tags(tags) do
1089     [tags]
1090     |> List.flatten()
1091     |> Enum.map(&String.downcase(&1))
1092   end
1093
1094   defp local_nickname_regex() do
1095     if Pleroma.Config.get([:instance, :extended_nickname_format]) do
1096       @extended_local_nickname_regex
1097     else
1098       @strict_local_nickname_regex
1099     end
1100   end
1101 end