git.squeep.com Git - akkoma/blob - lib/pleroma/user.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.User do
   6   use Ecto.Schema
   7
   8   import Ecto.{Changeset, Query}
   9   alias Pleroma.{Repo, User, Object, Web, Activity, Notification}
  10   alias Comeonin.Pbkdf2
  11   alias Pleroma.Formatter
  12   alias Pleroma.Web.CommonAPI.Utils, as: CommonUtils
  13   alias Pleroma.Web.{OStatus, Websub, OAuth}
  14   alias Pleroma.Web.ActivityPub.{Utils, ActivityPub}
  15
  16   require Logger
  17
  18   @type t :: %__MODULE__{}
  19
  20   @email_regex ~r/^[a-zA-Z0-9.!#$%&'*+\/=?^_`{|}~-]+@[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?(?:\.[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?)*$/
  21
  22   @strict_local_nickname_regex ~r/^[a-zA-Z\d]+$/
  23   @extended_local_nickname_regex ~r/^[a-zA-Z\d_-]+$/
  24
  25   schema "users" do
  26     field(:bio, :string)
  27     field(:email, :string)
  28     field(:name, :string)
  29     field(:nickname, :string)
  30     field(:password_hash, :string)
  31     field(:password, :string, virtual: true)
  32     field(:password_confirmation, :string, virtual: true)
  33     field(:following, {:array, :string}, default: [])
  34     field(:ap_id, :string)
  35     field(:avatar, :map)
  36     field(:local, :boolean, default: true)
  37     field(:follower_address, :string)
  38     field(:search_distance, :float, virtual: true)
  39     field(:tags, {:array, :string}, default: [])
  40     field(:last_refreshed_at, :naive_datetime)
  41     has_many(:notifications, Notification)
  42     embeds_one(:info, Pleroma.User.Info)
  43
  44     timestamps()
  45   end
  46
  47   def auth_active?(%User{local: false}), do: true
  48
  49   def auth_active?(%User{info: %User.Info{confirmation_pending: false}}), do: true
  50
  51   def auth_active?(%User{info: %User.Info{confirmation_pending: true}}),
  52     do: !Pleroma.Config.get([:instance, :account_activation_required])
  53
  54   def auth_active?(_), do: false
  55
  56   def visible_for?(user, for_user \\ nil)
  57
  58   def visible_for?(%User{id: user_id}, %User{id: for_id}) when user_id == for_id, do: true
  59
  60   def visible_for?(%User{} = user, for_user) do
  61     auth_active?(user) || superuser?(for_user)
  62   end
  63
  64   def visible_for?(_, _), do: false
  65
  66   def superuser?(%User{local: true, info: %User.Info{is_admin: true}}), do: true
  67   def superuser?(%User{local: true, info: %User.Info{is_moderator: true}}), do: true
  68   def superuser?(_), do: false
  69
  70   def avatar_url(user) do
  71     case user.avatar do
  72       %{"url" => [%{"href" => href} | _]} -> href
  73       _ -> "#{Web.base_url()}/images/avi.png"
  74     end
  75   end
  76
  77   def banner_url(user) do
  78     case user.info.banner do
  79       %{"url" => [%{"href" => href} | _]} -> href
  80       _ -> "#{Web.base_url()}/images/banner.png"
  81     end
  82   end
  83
  84   def profile_url(%User{info: %{source_data: %{"url" => url}}}), do: url
  85   def profile_url(%User{ap_id: ap_id}), do: ap_id
  86   def profile_url(_), do: nil
  87
  88   def ap_id(%User{nickname: nickname}) do
  89     "#{Web.base_url()}/users/#{nickname}"
  90   end
  91
  92   def ap_followers(%User{} = user) do
  93     "#{ap_id(user)}/followers"
  94   end
  95
  96   def follow_changeset(struct, params \\ %{}) do
  97     struct
  98     |> cast(params, [:following])
  99     |> validate_required([:following])
 100   end
 101
 102   def user_info(%User{} = user) do
 103     oneself = if user.local, do: 1, else: 0
 104
 105     %{
 106       following_count: length(user.following) - oneself,
 107       note_count: user.info.note_count,
 108       follower_count: user.info.follower_count,
 109       locked: user.info.locked,
 110       confirmation_pending: user.info.confirmation_pending,
 111       default_scope: user.info.default_scope
 112     }
 113   end
 114
 115   def remote_user_creation(params) do
 116     params =
 117       params
 118       |> Map.put(:info, params[:info] || %{})
 119
 120     info_cng = User.Info.remote_user_creation(%User.Info{}, params[:info])
 121
 122     changes =
 123       %User{}
 124       |> cast(params, [:bio, :name, :ap_id, :nickname, :avatar])
 125       |> validate_required([:name, :ap_id])
 126       |> unique_constraint(:nickname)
 127       |> validate_format(:nickname, @email_regex)
 128       |> validate_length(:bio, max: 5000)
 129       |> validate_length(:name, max: 100)
 130       |> put_change(:local, false)
 131       |> put_embed(:info, info_cng)
 132
 133     if changes.valid? do
 134       case info_cng.changes[:source_data] do
 135         %{"followers" => followers} ->
 136           changes
 137           |> put_change(:follower_address, followers)
 138
 139         _ ->
 140           followers = User.ap_followers(%User{nickname: changes.changes[:nickname]})
 141
 142           changes
 143           |> put_change(:follower_address, followers)
 144       end
 145     else
 146       changes
 147     end
 148   end
 149
 150   def update_changeset(struct, params \\ %{}) do
 151     struct
 152     |> cast(params, [:bio, :name, :avatar])
 153     |> unique_constraint(:nickname)
 154     |> validate_format(:nickname, local_nickname_regex())
 155     |> validate_length(:bio, max: 5000)
 156     |> validate_length(:name, min: 1, max: 100)
 157   end
 158
 159   def upgrade_changeset(struct, params \\ %{}) do
 160     params =
 161       params
 162       |> Map.put(:last_refreshed_at, NaiveDateTime.utc_now())
 163
 164     info_cng =
 165       struct.info
 166       |> User.Info.user_upgrade(params[:info])
 167
 168     struct
 169     |> cast(params, [:bio, :name, :follower_address, :avatar, :last_refreshed_at])
 170     |> unique_constraint(:nickname)
 171     |> validate_format(:nickname, local_nickname_regex())
 172     |> validate_length(:bio, max: 5000)
 173     |> validate_length(:name, max: 100)
 174     |> put_embed(:info, info_cng)
 175   end
 176
 177   def password_update_changeset(struct, params) do
 178     changeset =
 179       struct
 180       |> cast(params, [:password, :password_confirmation])
 181       |> validate_required([:password, :password_confirmation])
 182       |> validate_confirmation(:password)
 183
 184     OAuth.Token.delete_user_tokens(struct)
 185     OAuth.Authorization.delete_user_authorizations(struct)
 186
 187     if changeset.valid? do
 188       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 189
 190       changeset
 191       |> put_change(:password_hash, hashed)
 192     else
 193       changeset
 194     end
 195   end
 196
 197   def reset_password(user, data) do
 198     update_and_set_cache(password_update_changeset(user, data))
 199   end
 200
 201   def register_changeset(struct, params \\ %{}, opts \\ []) do
 202     confirmation_status =
 203       if opts[:confirmed] || !Pleroma.Config.get([:instance, :account_activation_required]) do
 204         :confirmed
 205       else
 206         :unconfirmed
 207       end
 208
 209     info_change = User.Info.confirmation_changeset(%User.Info{}, confirmation_status)
 210
 211     changeset =
 212       struct
 213       |> cast(params, [:bio, :email, :name, :nickname, :password, :password_confirmation])
 214       |> validate_required([:email, :name, :nickname, :password, :password_confirmation])
 215       |> validate_confirmation(:password)
 216       |> unique_constraint(:email)
 217       |> unique_constraint(:nickname)
 218       |> validate_exclusion(:nickname, Pleroma.Config.get([Pleroma.User, :restricted_nicknames]))
 219       |> validate_format(:nickname, local_nickname_regex())
 220       |> validate_format(:email, @email_regex)
 221       |> validate_length(:bio, max: 1000)
 222       |> validate_length(:name, min: 1, max: 100)
 223       |> put_change(:info, info_change)
 224
 225     if changeset.valid? do
 226       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 227       ap_id = User.ap_id(%User{nickname: changeset.changes[:nickname]})
 228       followers = User.ap_followers(%User{nickname: changeset.changes[:nickname]})
 229
 230       changeset
 231       |> put_change(:password_hash, hashed)
 232       |> put_change(:ap_id, ap_id)
 233       |> put_change(:following, [followers])
 234       |> put_change(:follower_address, followers)
 235     else
 236       changeset
 237     end
 238   end
 239
 240   defp autofollow_users(user) do
 241     candidates = Pleroma.Config.get([:instance, :autofollowed_nicknames])
 242
 243     autofollowed_users =
 244       from(u in User,
 245         where: u.local == true,
 246         where: u.nickname in ^candidates
 247       )
 248       |> Repo.all()
 249
 250     follow_all(user, autofollowed_users)
 251   end
 252
 253   @doc "Inserts provided changeset, performs post-registration actions (confirmation email sending etc.)"
 254   def register(%Ecto.Changeset{} = changeset) do
 255     with {:ok, user} <- Repo.insert(changeset),
 256          {:ok, _} <- try_send_confirmation_email(user),
 257          {:ok, user} <- autofollow_users(user) do
 258       {:ok, user}
 259     end
 260   end
 261
 262   def try_send_confirmation_email(%User{} = user) do
 263     if user.info.confirmation_pending &&
 264          Pleroma.Config.get([:instance, :account_activation_required]) do
 265       user
 266       |> Pleroma.UserEmail.account_confirmation_email()
 267       |> Pleroma.Mailer.deliver()
 268     else
 269       {:ok, :noop}
 270     end
 271   end
 272
 273   def needs_update?(%User{local: true}), do: false
 274
 275   def needs_update?(%User{local: false, last_refreshed_at: nil}), do: true
 276
 277   def needs_update?(%User{local: false} = user) do
 278     NaiveDateTime.diff(NaiveDateTime.utc_now(), user.last_refreshed_at) >= 86400
 279   end
 280
 281   def needs_update?(_), do: true
 282
 283   def maybe_direct_follow(%User{} = follower, %User{local: true, info: %{locked: true}}) do
 284     {:ok, follower}
 285   end
 286
 287   def maybe_direct_follow(%User{} = follower, %User{local: true} = followed) do
 288     follow(follower, followed)
 289   end
 290
 291   def maybe_direct_follow(%User{} = follower, %User{} = followed) do
 292     if not User.ap_enabled?(followed) do
 293       follow(follower, followed)
 294     else
 295       {:ok, follower}
 296     end
 297   end
 298
 299   def maybe_follow(%User{} = follower, %User{info: _info} = followed) do
 300     if not following?(follower, followed) do
 301       follow(follower, followed)
 302     else
 303       {:ok, follower}
 304     end
 305   end
 306
 307   @doc "A mass follow for local users. Ignores blocks and has no side effects"
 308   @spec follow_all(User.t(), list(User.t())) :: {atom(), User.t()}
 309   def follow_all(follower, followeds) do
 310     following =
 311       (follower.following ++ Enum.map(followeds, fn %{follower_address: fa} -> fa end))
 312       |> Enum.uniq()
 313
 314     {:ok, follower} =
 315       follower
 316       |> follow_changeset(%{following: following})
 317       |> update_and_set_cache
 318
 319     Enum.each(followeds, fn followed ->
 320       update_follower_count(followed)
 321     end)
 322
 323     {:ok, follower}
 324   end
 325
 326   def follow(%User{} = follower, %User{info: info} = followed) do
 327     user_config = Application.get_env(:pleroma, :user)
 328     deny_follow_blocked = Keyword.get(user_config, :deny_follow_blocked)
 329
 330     ap_followers = followed.follower_address
 331
 332     cond do
 333       following?(follower, followed) or info.deactivated ->
 334         {:error, "Could not follow user: #{followed.nickname} is already on your list."}
 335
 336       deny_follow_blocked and blocks?(followed, follower) ->
 337         {:error, "Could not follow user: #{followed.nickname} blocked you."}
 338
 339       true ->
 340         if !followed.local && follower.local && !ap_enabled?(followed) do
 341           Websub.subscribe(follower, followed)
 342         end
 343
 344         following =
 345           [ap_followers | follower.following]
 346           |> Enum.uniq()
 347
 348         follower =
 349           follower
 350           |> follow_changeset(%{following: following})
 351           |> update_and_set_cache
 352
 353         {:ok, _} = update_follower_count(followed)
 354
 355         follower
 356     end
 357   end
 358
 359   def unfollow(%User{} = follower, %User{} = followed) do
 360     ap_followers = followed.follower_address
 361
 362     if following?(follower, followed) and follower.ap_id != followed.ap_id do
 363       following =
 364         follower.following
 365         |> List.delete(ap_followers)
 366
 367       {:ok, follower} =
 368         follower
 369         |> follow_changeset(%{following: following})
 370         |> update_and_set_cache
 371
 372       {:ok, followed} = update_follower_count(followed)
 373
 374       {:ok, follower, Utils.fetch_latest_follow(follower, followed)}
 375     else
 376       {:error, "Not subscribed!"}
 377     end
 378   end
 379
 380   @spec following?(User.t(), User.t()) :: boolean
 381   def following?(%User{} = follower, %User{} = followed) do
 382     Enum.member?(follower.following, followed.follower_address)
 383   end
 384
 385   def follow_import(%User{} = follower, followed_identifiers)
 386       when is_list(followed_identifiers) do
 387     Enum.map(
 388       followed_identifiers,
 389       fn followed_identifier ->
 390         with %User{} = followed <- get_or_fetch(followed_identifier),
 391              {:ok, follower} <- maybe_direct_follow(follower, followed),
 392              {:ok, _} <- ActivityPub.follow(follower, followed) do
 393           followed
 394         else
 395           err ->
 396             Logger.debug("follow_import failed for #{followed_identifier} with: #{inspect(err)}")
 397             err
 398         end
 399       end
 400     )
 401   end
 402
 403   def locked?(%User{} = user) do
 404     user.info.locked || false
 405   end
 406
 407   def get_by_id(id) do
 408     Repo.get_by(User, id: id)
 409   end
 410
 411   def get_by_ap_id(ap_id) do
 412     Repo.get_by(User, ap_id: ap_id)
 413   end
 414
 415   # This is mostly an SPC migration fix. This guesses the user nickname (by taking the last part of the ap_id and the domain) and tries to get that user
 416   def get_by_guessed_nickname(ap_id) do
 417     domain = URI.parse(ap_id).host
 418     name = List.last(String.split(ap_id, "/"))
 419     nickname = "#{name}@#{domain}"
 420
 421     get_by_nickname(nickname)
 422   end
 423
 424   def update_and_set_cache(changeset) do
 425     with {:ok, user} <- Repo.update(changeset) do
 426       Cachex.put(:user_cache, "ap_id:#{user.ap_id}", user)
 427       Cachex.put(:user_cache, "nickname:#{user.nickname}", user)
 428       Cachex.put(:user_cache, "user_info:#{user.id}", user_info(user))
 429       {:ok, user}
 430     else
 431       e -> e
 432     end
 433   end
 434
 435   def invalidate_cache(user) do
 436     Cachex.del(:user_cache, "ap_id:#{user.ap_id}")
 437     Cachex.del(:user_cache, "nickname:#{user.nickname}")
 438     Cachex.del(:user_cache, "user_info:#{user.id}")
 439   end
 440
 441   def get_cached_by_ap_id(ap_id) do
 442     key = "ap_id:#{ap_id}"
 443     Cachex.fetch!(:user_cache, key, fn _ -> get_by_ap_id(ap_id) end)
 444   end
 445
 446   def get_cached_by_id(id) do
 447     key = "id:#{id}"
 448
 449     ap_id =
 450       Cachex.fetch!(:user_cache, key, fn _ ->
 451         user = get_by_id(id)
 452         Cachex.put(:user_cache, "ap_id:#{user.ap_id}", user)
 453         {:commit, user.ap_id}
 454       end)
 455
 456     get_cached_by_ap_id(ap_id)
 457   end
 458
 459   def get_cached_by_nickname(nickname) do
 460     key = "nickname:#{nickname}"
 461     Cachex.fetch!(:user_cache, key, fn _ -> get_or_fetch_by_nickname(nickname) end)
 462   end
 463
 464   def get_cached_by_nickname_or_id(nickname_or_id) do
 465     try do
 466       # TODO: convert to UUIDs when !654 is merged
 467       maybe_id = String.to_integer(nickname_or_id)
 468       user = get_cached_by_id(maybe_id)
 469
 470       if user == nil do
 471         raise ArgumentError, message: "No such user id"
 472       else
 473         user
 474       end
 475     rescue
 476       ArgumentError ->
 477         get_cached_by_nickname(nickname_or_id)
 478     end
 479   end
 480
 481   def get_by_nickname(nickname) do
 482     Repo.get_by(User, nickname: nickname) ||
 483       if Regex.match?(~r(@#{Pleroma.Web.Endpoint.host()})i, nickname) do
 484         [local_nickname, _] = String.split(nickname, "@")
 485         Repo.get_by(User, nickname: local_nickname)
 486       end
 487   end
 488
 489   def get_by_nickname_or_email(nickname_or_email) do
 490     case user = Repo.get_by(User, nickname: nickname_or_email) do
 491       %User{} -> user
 492       nil -> Repo.get_by(User, email: nickname_or_email)
 493     end
 494   end
 495
 496   def get_cached_user_info(user) do
 497     key = "user_info:#{user.id}"
 498     Cachex.fetch!(:user_cache, key, fn _ -> user_info(user) end)
 499   end
 500
 501   def fetch_by_nickname(nickname) do
 502     ap_try = ActivityPub.make_user_from_nickname(nickname)
 503
 504     case ap_try do
 505       {:ok, user} -> {:ok, user}
 506       _ -> OStatus.make_user(nickname)
 507     end
 508   end
 509
 510   def get_or_fetch_by_nickname(nickname) do
 511     with %User{} = user <- get_by_nickname(nickname) do
 512       user
 513     else
 514       _e ->
 515         with [_nick, _domain] <- String.split(nickname, "@"),
 516              {:ok, user} <- fetch_by_nickname(nickname) do
 517           user
 518         else
 519           _e -> nil
 520         end
 521     end
 522   end
 523
 524   def get_followers_query(%User{id: id, follower_address: follower_address}, nil) do
 525     from(
 526       u in User,
 527       where: fragment("? <@ ?", ^[follower_address], u.following),
 528       where: u.id != ^id
 529     )
 530   end
 531
 532   def get_followers_query(user, page) do
 533     from(
 534       u in get_followers_query(user, nil),
 535       limit: 20,
 536       offset: ^((page - 1) * 20)
 537     )
 538   end
 539
 540   def get_followers_query(user), do: get_followers_query(user, nil)
 541
 542   def get_followers(user, page \\ nil) do
 543     q = get_followers_query(user, page)
 544
 545     {:ok, Repo.all(q)}
 546   end
 547
 548   def get_friends_query(%User{id: id, following: following}, nil) do
 549     from(
 550       u in User,
 551       where: u.follower_address in ^following,
 552       where: u.id != ^id
 553     )
 554   end
 555
 556   def get_friends_query(user, page) do
 557     from(
 558       u in get_friends_query(user, nil),
 559       limit: 20,
 560       offset: ^((page - 1) * 20)
 561     )
 562   end
 563
 564   def get_friends_query(user), do: get_friends_query(user, nil)
 565
 566   def get_friends(user, page \\ nil) do
 567     q = get_friends_query(user, page)
 568
 569     {:ok, Repo.all(q)}
 570   end
 571
 572   def get_follow_requests_query(%User{} = user) do
 573     from(
 574       a in Activity,
 575       where:
 576         fragment(
 577           "? ->> 'type' = 'Follow'",
 578           a.data
 579         ),
 580       where:
 581         fragment(
 582           "? ->> 'state' = 'pending'",
 583           a.data
 584         ),
 585       where:
 586         fragment(
 587           "? @> ?",
 588           a.data,
 589           ^%{"object" => user.ap_id}
 590         )
 591     )
 592   end
 593
 594   def get_follow_requests(%User{} = user) do
 595     q = get_follow_requests_query(user)
 596     reqs = Repo.all(q)
 597
 598     users =
 599       Enum.map(reqs, fn req -> req.actor end)
 600       |> Enum.uniq()
 601       |> Enum.map(fn ap_id -> get_by_ap_id(ap_id) end)
 602       |> Enum.filter(fn u -> !is_nil(u) end)
 603       |> Enum.filter(fn u -> !following?(u, user) end)
 604
 605     {:ok, users}
 606   end
 607
 608   def increase_note_count(%User{} = user) do
 609     info_cng = User.Info.add_to_note_count(user.info, 1)
 610
 611     cng =
 612       change(user)
 613       |> put_embed(:info, info_cng)
 614
 615     update_and_set_cache(cng)
 616   end
 617
 618   def decrease_note_count(%User{} = user) do
 619     info_cng = User.Info.add_to_note_count(user.info, -1)
 620
 621     cng =
 622       change(user)
 623       |> put_embed(:info, info_cng)
 624
 625     update_and_set_cache(cng)
 626   end
 627
 628   def update_note_count(%User{} = user) do
 629     note_count_query =
 630       from(
 631         a in Object,
 632         where: fragment("?->>'actor' = ? and ?->>'type' = 'Note'", a.data, ^user.ap_id, a.data),
 633         select: count(a.id)
 634       )
 635
 636     note_count = Repo.one(note_count_query)
 637
 638     info_cng = User.Info.set_note_count(user.info, note_count)
 639
 640     cng =
 641       change(user)
 642       |> put_embed(:info, info_cng)
 643
 644     update_and_set_cache(cng)
 645   end
 646
 647   def update_follower_count(%User{} = user) do
 648     follower_count_query =
 649       from(
 650         u in User,
 651         where: ^user.follower_address in u.following,
 652         where: u.id != ^user.id,
 653         select: count(u.id)
 654       )
 655
 656     follower_count = Repo.one(follower_count_query)
 657
 658     info_cng =
 659       user.info
 660       |> User.Info.set_follower_count(follower_count)
 661
 662     cng =
 663       change(user)
 664       |> put_embed(:info, info_cng)
 665
 666     update_and_set_cache(cng)
 667   end
 668
 669   def get_users_from_set_query(ap_ids, false) do
 670     from(
 671       u in User,
 672       where: u.ap_id in ^ap_ids
 673     )
 674   end
 675
 676   def get_users_from_set_query(ap_ids, true) do
 677     query = get_users_from_set_query(ap_ids, false)
 678
 679     from(
 680       u in query,
 681       where: u.local == true
 682     )
 683   end
 684
 685   def get_users_from_set(ap_ids, local_only \\ true) do
 686     get_users_from_set_query(ap_ids, local_only)
 687     |> Repo.all()
 688   end
 689
 690   def get_recipients_from_activity(%Activity{recipients: to}) do
 691     query =
 692       from(
 693         u in User,
 694         where: u.ap_id in ^to,
 695         or_where: fragment("? && ?", u.following, ^to)
 696       )
 697
 698     query = from(u in query, where: u.local == true)
 699
 700     Repo.all(query)
 701   end
 702
 703   def search(query, resolve \\ false) do
 704     # strip the beginning @ off if there is a query
 705     query = String.trim_leading(query, "@")
 706
 707     if resolve do
 708       User.get_or_fetch_by_nickname(query)
 709     end
 710
 711     inner =
 712       from(
 713         u in User,
 714         select_merge: %{
 715           search_distance:
 716             fragment(
 717               "? <-> (? || coalesce(?, ''))",
 718               ^query,
 719               u.nickname,
 720               u.name
 721             )
 722         },
 723         where: not is_nil(u.nickname)
 724       )
 725
 726     q =
 727       from(
 728         s in subquery(inner),
 729         order_by: s.search_distance,
 730         limit: 20
 731       )
 732
 733     Repo.all(q)
 734   end
 735
 736   def blocks_import(%User{} = blocker, blocked_identifiers) when is_list(blocked_identifiers) do
 737     Enum.map(
 738       blocked_identifiers,
 739       fn blocked_identifier ->
 740         with %User{} = blocked <- get_or_fetch(blocked_identifier),
 741              {:ok, blocker} <- block(blocker, blocked),
 742              {:ok, _} <- ActivityPub.block(blocker, blocked) do
 743           blocked
 744         else
 745           err ->
 746             Logger.debug("blocks_import failed for #{blocked_identifier} with: #{inspect(err)}")
 747             err
 748         end
 749       end
 750     )
 751   end
 752
 753   def block(blocker, %User{ap_id: ap_id} = blocked) do
 754     # sever any follow relationships to prevent leaks per activitypub (Pleroma issue #213)
 755     blocker =
 756       if following?(blocker, blocked) do
 757         {:ok, blocker, _} = unfollow(blocker, blocked)
 758         blocker
 759       else
 760         blocker
 761       end
 762
 763     if following?(blocked, blocker) do
 764       unfollow(blocked, blocker)
 765     end
 766
 767     info_cng =
 768       blocker.info
 769       |> User.Info.add_to_block(ap_id)
 770
 771     cng =
 772       change(blocker)
 773       |> put_embed(:info, info_cng)
 774
 775     update_and_set_cache(cng)
 776   end
 777
 778   # helper to handle the block given only an actor's AP id
 779   def block(blocker, %{ap_id: ap_id}) do
 780     block(blocker, User.get_by_ap_id(ap_id))
 781   end
 782
 783   def unblock(blocker, %{ap_id: ap_id}) do
 784     info_cng =
 785       blocker.info
 786       |> User.Info.remove_from_block(ap_id)
 787
 788     cng =
 789       change(blocker)
 790       |> put_embed(:info, info_cng)
 791
 792     update_and_set_cache(cng)
 793   end
 794
 795   def blocks?(user, %{ap_id: ap_id}) do
 796     blocks = user.info.blocks
 797     domain_blocks = user.info.domain_blocks
 798     %{host: host} = URI.parse(ap_id)
 799
 800     Enum.member?(blocks, ap_id) ||
 801       Enum.any?(domain_blocks, fn domain ->
 802         host == domain
 803       end)
 804   end
 805
 806   def blocked_users(user),
 807     do: Repo.all(from(u in User, where: u.ap_id in ^user.info.blocks))
 808
 809   def block_domain(user, domain) do
 810     info_cng =
 811       user.info
 812       |> User.Info.add_to_domain_block(domain)
 813
 814     cng =
 815       change(user)
 816       |> put_embed(:info, info_cng)
 817
 818     update_and_set_cache(cng)
 819   end
 820
 821   def unblock_domain(user, domain) do
 822     info_cng =
 823       user.info
 824       |> User.Info.remove_from_domain_block(domain)
 825
 826     cng =
 827       change(user)
 828       |> put_embed(:info, info_cng)
 829
 830     update_and_set_cache(cng)
 831   end
 832
 833   def local_user_query() do
 834     from(
 835       u in User,
 836       where: u.local == true,
 837       where: not is_nil(u.nickname)
 838     )
 839   end
 840
 841   def moderator_user_query() do
 842     from(
 843       u in User,
 844       where: u.local == true,
 845       where: fragment("?->'is_moderator' @> 'true'", u.info)
 846     )
 847   end
 848
 849   def deactivate(%User{} = user, status \\ true) do
 850     info_cng = User.Info.set_activation_status(user.info, status)
 851
 852     cng =
 853       change(user)
 854       |> put_embed(:info, info_cng)
 855
 856     update_and_set_cache(cng)
 857   end
 858
 859   def delete(%User{} = user) do
 860     {:ok, user} = User.deactivate(user)
 861
 862     # Remove all relationships
 863     {:ok, followers} = User.get_followers(user)
 864
 865     followers
 866     |> Enum.each(fn follower -> User.unfollow(follower, user) end)
 867
 868     {:ok, friends} = User.get_friends(user)
 869
 870     friends
 871     |> Enum.each(fn followed -> User.unfollow(user, followed) end)
 872
 873     query = from(a in Activity, where: a.actor == ^user.ap_id)
 874
 875     Repo.all(query)
 876     |> Enum.each(fn activity ->
 877       case activity.data["type"] do
 878         "Create" ->
 879           ActivityPub.delete(Object.normalize(activity.data["object"]))
 880
 881         # TODO: Do something with likes, follows, repeats.
 882         _ ->
 883           "Doing nothing"
 884       end
 885     end)
 886
 887     {:ok, user}
 888   end
 889
 890   def html_filter_policy(%User{info: %{no_rich_text: true}}) do
 891     Pleroma.HTML.Scrubber.TwitterText
 892   end
 893
 894   @default_scrubbers Pleroma.Config.get([:markup, :scrub_policy])
 895
 896   def html_filter_policy(_), do: @default_scrubbers
 897
 898   def get_or_fetch_by_ap_id(ap_id) do
 899     user = get_by_ap_id(ap_id)
 900
 901     if !is_nil(user) and !User.needs_update?(user) do
 902       user
 903     else
 904       ap_try = ActivityPub.make_user_from_ap_id(ap_id)
 905
 906       case ap_try do
 907         {:ok, user} ->
 908           user
 909
 910         _ ->
 911           case OStatus.make_user(ap_id) do
 912             {:ok, user} -> user
 913             _ -> {:error, "Could not fetch by AP id"}
 914           end
 915       end
 916     end
 917   end
 918
 919   def get_or_create_instance_user do
 920     relay_uri = "#{Pleroma.Web.Endpoint.url()}/relay"
 921
 922     if user = get_by_ap_id(relay_uri) do
 923       user
 924     else
 925       changes =
 926         %User{info: %User.Info{}}
 927         |> cast(%{}, [:ap_id, :nickname, :local])
 928         |> put_change(:ap_id, relay_uri)
 929         |> put_change(:nickname, nil)
 930         |> put_change(:local, true)
 931         |> put_change(:follower_address, relay_uri <> "/followers")
 932
 933       {:ok, user} = Repo.insert(changes)
 934       user
 935     end
 936   end
 937
 938   # AP style
 939   def public_key_from_info(%{
 940         source_data: %{"publicKey" => %{"publicKeyPem" => public_key_pem}}
 941       }) do
 942     key =
 943       public_key_pem
 944       |> :public_key.pem_decode()
 945       |> hd()
 946       |> :public_key.pem_entry_decode()
 947
 948     {:ok, key}
 949   end
 950
 951   # OStatus Magic Key
 952   def public_key_from_info(%{magic_key: magic_key}) do
 953     {:ok, Pleroma.Web.Salmon.decode_key(magic_key)}
 954   end
 955
 956   def get_public_key_for_ap_id(ap_id) do
 957     with %User{} = user <- get_or_fetch_by_ap_id(ap_id),
 958          {:ok, public_key} <- public_key_from_info(user.info) do
 959       {:ok, public_key}
 960     else
 961       _ -> :error
 962     end
 963   end
 964
 965   defp blank?(""), do: nil
 966   defp blank?(n), do: n
 967
 968   def insert_or_update_user(data) do
 969     data =
 970       data
 971       |> Map.put(:name, blank?(data[:name]) || data[:nickname])
 972
 973     cs = User.remote_user_creation(data)
 974
 975     Repo.insert(cs, on_conflict: :replace_all, conflict_target: :nickname)
 976   end
 977
 978   def ap_enabled?(%User{local: true}), do: true
 979   def ap_enabled?(%User{info: info}), do: info.ap_enabled
 980   def ap_enabled?(_), do: false
 981
 982   @doc "Gets or fetch a user by uri or nickname."
 983   @spec get_or_fetch(String.t()) :: User.t()
 984   def get_or_fetch("http" <> _host = uri), do: get_or_fetch_by_ap_id(uri)
 985   def get_or_fetch(nickname), do: get_or_fetch_by_nickname(nickname)
 986
 987   # wait a period of time and return newest version of the User structs
 988   # this is because we have synchronous follow APIs and need to simulate them
 989   # with an async handshake
 990   def wait_and_refresh(_, %User{local: true} = a, %User{local: true} = b) do
 991     with %User{} = a <- Repo.get(User, a.id),
 992          %User{} = b <- Repo.get(User, b.id) do
 993       {:ok, a, b}
 994     else
 995       _e ->
 996         :error
 997     end
 998   end
 999
1000   def wait_and_refresh(timeout, %User{} = a, %User{} = b) do
1001     with :ok <- :timer.sleep(timeout),
1002          %User{} = a <- Repo.get(User, a.id),
1003          %User{} = b <- Repo.get(User, b.id) do
1004       {:ok, a, b}
1005     else
1006       _e ->
1007         :error
1008     end
1009   end
1010
1011   def parse_bio(bio, user \\ %User{info: %{source_data: %{}}})
1012   def parse_bio(nil, _user), do: ""
1013   def parse_bio(bio, _user) when bio == "", do: bio
1014
1015   def parse_bio(bio, user) do
1016     mentions = Formatter.parse_mentions(bio)
1017     tags = Formatter.parse_tags(bio)
1018
1019     emoji =
1020       (user.info.source_data["tag"] || [])
1021       |> Enum.filter(fn %{"type" => t} -> t == "Emoji" end)
1022       |> Enum.map(fn %{"icon" => %{"url" => url}, "name" => name} ->
1023         {String.trim(name, ":"), url}
1024       end)
1025
1026     bio
1027     |> CommonUtils.format_input(mentions, tags, "text/plain")
1028     |> Formatter.emojify(emoji)
1029   end
1030
1031   def tag(user_identifiers, tags) when is_list(user_identifiers) do
1032     Repo.transaction(fn ->
1033       for user_identifier <- user_identifiers, do: tag(user_identifier, tags)
1034     end)
1035   end
1036
1037   def tag(nickname, tags) when is_binary(nickname),
1038     do: tag(User.get_by_nickname(nickname), tags)
1039
1040   def tag(%User{} = user, tags),
1041     do: update_tags(user, Enum.uniq((user.tags || []) ++ normalize_tags(tags)))
1042
1043   def untag(user_identifiers, tags) when is_list(user_identifiers) do
1044     Repo.transaction(fn ->
1045       for user_identifier <- user_identifiers, do: untag(user_identifier, tags)
1046     end)
1047   end
1048
1049   def untag(nickname, tags) when is_binary(nickname),
1050     do: untag(User.get_by_nickname(nickname), tags)
1051
1052   def untag(%User{} = user, tags),
1053     do: update_tags(user, (user.tags || []) -- normalize_tags(tags))
1054
1055   defp update_tags(%User{} = user, new_tags) do
1056     {:ok, updated_user} =
1057       user
1058       |> change(%{tags: new_tags})
1059       |> Repo.update()
1060
1061     updated_user
1062   end
1063
1064   defp normalize_tags(tags) do
1065     [tags]
1066     |> List.flatten()
1067     |> Enum.map(&String.downcase(&1))
1068   end
1069
1070   defp local_nickname_regex() do
1071     if Pleroma.Config.get([:instance, :extended_nickname_format]) do
1072       @extended_local_nickname_regex
1073     else
1074       @strict_local_nickname_regex
1075     end
1076   end
1077 end