git.squeep.com Git - akkoma/blob - lib/pleroma/user.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.User do
   6   use Ecto.Schema
   7
   8   import Ecto.{Changeset, Query}
   9   alias Pleroma.{Repo, User, Object, Web, Activity, Notification}
  10   alias Comeonin.Pbkdf2
  11   alias Pleroma.Formatter
  12   alias Pleroma.Web.CommonAPI.Utils, as: CommonUtils
  13   alias Pleroma.Web.{OStatus, Websub, OAuth}
  14   alias Pleroma.Web.ActivityPub.{Utils, ActivityPub}
  15
  16   require Logger
  17
  18   @type t :: %__MODULE__{}
  19
  20   @email_regex ~r/^[a-zA-Z0-9.!#$%&'*+\/=?^_`{|}~-]+@[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?(?:\.[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?)*$/
  21
  22   @strict_local_nickname_regex ~r/^[a-zA-Z\d]+$/
  23   @extended_local_nickname_regex ~r/^[a-zA-Z\d_-]+$/
  24
  25   schema "users" do
  26     field(:bio, :string)
  27     field(:email, :string)
  28     field(:name, :string)
  29     field(:nickname, :string)
  30     field(:password_hash, :string)
  31     field(:password, :string, virtual: true)
  32     field(:password_confirmation, :string, virtual: true)
  33     field(:following, {:array, :string}, default: [])
  34     field(:ap_id, :string)
  35     field(:avatar, :map)
  36     field(:local, :boolean, default: true)
  37     field(:follower_address, :string)
  38     field(:search_distance, :float, virtual: true)
  39     field(:tags, {:array, :string}, default: [])
  40     field(:last_refreshed_at, :naive_datetime)
  41     has_many(:notifications, Notification)
  42     embeds_one(:info, Pleroma.User.Info)
  43
  44     timestamps()
  45   end
  46
  47   def auth_active?(%User{} = user) do
  48     (user.info && !user.info.confirmation_pending) ||
  49       !Pleroma.Config.get([:instance, :account_activation_required])
  50   end
  51
  52   def remote_or_auth_active?(%User{local: false}), do: true
  53   def remote_or_auth_active?(%User{local: true} = user), do: auth_active?(user)
  54
  55   def visible_for?(%User{} = user, for_user \\ nil) do
  56     User.remote_or_auth_active?(user) || (for_user && for_user.id == user.id) ||
  57       User.superuser?(for_user)
  58   end
  59
  60   def superuser?(nil), do: false
  61   def superuser?(%User{} = user), do: user.info && User.Info.superuser?(user.info)
  62
  63   def avatar_url(user) do
  64     case user.avatar do
  65       %{"url" => [%{"href" => href} | _]} -> href
  66       _ -> "#{Web.base_url()}/images/avi.png"
  67     end
  68   end
  69
  70   def banner_url(user) do
  71     case user.info.banner do
  72       %{"url" => [%{"href" => href} | _]} -> href
  73       _ -> "#{Web.base_url()}/images/banner.png"
  74     end
  75   end
  76
  77   def profile_url(%User{info: %{source_data: %{"url" => url}}}), do: url
  78   def profile_url(%User{ap_id: ap_id}), do: ap_id
  79   def profile_url(_), do: nil
  80
  81   def ap_id(%User{nickname: nickname}) do
  82     "#{Web.base_url()}/users/#{nickname}"
  83   end
  84
  85   def ap_followers(%User{} = user) do
  86     "#{ap_id(user)}/followers"
  87   end
  88
  89   def follow_changeset(struct, params \\ %{}) do
  90     struct
  91     |> cast(params, [:following])
  92     |> validate_required([:following])
  93   end
  94
  95   def user_info(%User{} = user) do
  96     oneself = if user.local, do: 1, else: 0
  97
  98     %{
  99       following_count: length(user.following) - oneself,
 100       note_count: user.info.note_count,
 101       follower_count: user.info.follower_count,
 102       locked: user.info.locked,
 103       confirmation_pending: user.info.confirmation_pending,
 104       default_scope: user.info.default_scope
 105     }
 106   end
 107
 108   def remote_user_creation(params) do
 109     params =
 110       params
 111       |> Map.put(:info, params[:info] || %{})
 112
 113     info_cng = User.Info.remote_user_creation(%User.Info{}, params[:info])
 114
 115     changes =
 116       %User{}
 117       |> cast(params, [:bio, :name, :ap_id, :nickname, :avatar])
 118       |> validate_required([:name, :ap_id])
 119       |> unique_constraint(:nickname)
 120       |> validate_format(:nickname, @email_regex)
 121       |> validate_length(:bio, max: 5000)
 122       |> validate_length(:name, max: 100)
 123       |> put_change(:local, false)
 124       |> put_embed(:info, info_cng)
 125
 126     if changes.valid? do
 127       case info_cng.changes[:source_data] do
 128         %{"followers" => followers} ->
 129           changes
 130           |> put_change(:follower_address, followers)
 131
 132         _ ->
 133           followers = User.ap_followers(%User{nickname: changes.changes[:nickname]})
 134
 135           changes
 136           |> put_change(:follower_address, followers)
 137       end
 138     else
 139       changes
 140     end
 141   end
 142
 143   def update_changeset(struct, params \\ %{}) do
 144     struct
 145     |> cast(params, [:bio, :name, :avatar])
 146     |> unique_constraint(:nickname)
 147     |> validate_format(:nickname, local_nickname_regex())
 148     |> validate_length(:bio, max: 5000)
 149     |> validate_length(:name, min: 1, max: 100)
 150   end
 151
 152   def upgrade_changeset(struct, params \\ %{}) do
 153     params =
 154       params
 155       |> Map.put(:last_refreshed_at, NaiveDateTime.utc_now())
 156
 157     info_cng =
 158       struct.info
 159       |> User.Info.user_upgrade(params[:info])
 160
 161     struct
 162     |> cast(params, [:bio, :name, :follower_address, :avatar, :last_refreshed_at])
 163     |> unique_constraint(:nickname)
 164     |> validate_format(:nickname, local_nickname_regex())
 165     |> validate_length(:bio, max: 5000)
 166     |> validate_length(:name, max: 100)
 167     |> put_embed(:info, info_cng)
 168   end
 169
 170   def password_update_changeset(struct, params) do
 171     changeset =
 172       struct
 173       |> cast(params, [:password, :password_confirmation])
 174       |> validate_required([:password, :password_confirmation])
 175       |> validate_confirmation(:password)
 176
 177     OAuth.Token.delete_user_tokens(struct)
 178     OAuth.Authorization.delete_user_authorizations(struct)
 179
 180     if changeset.valid? do
 181       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 182
 183       changeset
 184       |> put_change(:password_hash, hashed)
 185     else
 186       changeset
 187     end
 188   end
 189
 190   def reset_password(user, data) do
 191     update_and_set_cache(password_update_changeset(user, data))
 192   end
 193
 194   def register_changeset(struct, params \\ %{}, opts \\ []) do
 195     confirmation_status =
 196       if opts[:confirmed] || !Pleroma.Config.get([:instance, :account_activation_required]) do
 197         :confirmed
 198       else
 199         :unconfirmed
 200       end
 201
 202     info_change = User.Info.confirmation_changeset(%User.Info{}, confirmation_status)
 203
 204     changeset =
 205       struct
 206       |> cast(params, [:bio, :email, :name, :nickname, :password, :password_confirmation])
 207       |> validate_required([:email, :name, :nickname, :password, :password_confirmation])
 208       |> validate_confirmation(:password)
 209       |> unique_constraint(:email)
 210       |> unique_constraint(:nickname)
 211       |> validate_exclusion(:nickname, Pleroma.Config.get([Pleroma.User, :restricted_nicknames]))
 212       |> validate_format(:nickname, local_nickname_regex())
 213       |> validate_format(:email, @email_regex)
 214       |> validate_length(:bio, max: 1000)
 215       |> validate_length(:name, min: 1, max: 100)
 216       |> put_change(:info, info_change)
 217
 218     if changeset.valid? do
 219       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 220       ap_id = User.ap_id(%User{nickname: changeset.changes[:nickname]})
 221       followers = User.ap_followers(%User{nickname: changeset.changes[:nickname]})
 222
 223       changeset
 224       |> put_change(:password_hash, hashed)
 225       |> put_change(:ap_id, ap_id)
 226       |> put_change(:following, [followers])
 227       |> put_change(:follower_address, followers)
 228     else
 229       changeset
 230     end
 231   end
 232
 233   @doc "Inserts provided changeset, performs post-registration actions (confirmation email sending etc.)"
 234   def register(%Ecto.Changeset{} = changeset) do
 235     with {:ok, user} <- Repo.insert(changeset),
 236          {:ok, _} = try_send_confirmation_email(user) do
 237       {:ok, user}
 238     end
 239   end
 240
 241   def try_send_confirmation_email(%User{} = user) do
 242     if user.info.confirmation_pending &&
 243          Pleroma.Config.get([:instance, :account_activation_required]) do
 244       user
 245       |> Pleroma.UserEmail.account_confirmation_email()
 246       |> Pleroma.Mailer.deliver()
 247     else
 248       {:ok, :noop}
 249     end
 250   end
 251
 252   def needs_update?(%User{local: true}), do: false
 253
 254   def needs_update?(%User{local: false, last_refreshed_at: nil}), do: true
 255
 256   def needs_update?(%User{local: false} = user) do
 257     NaiveDateTime.diff(NaiveDateTime.utc_now(), user.last_refreshed_at) >= 86400
 258   end
 259
 260   def needs_update?(_), do: true
 261
 262   def maybe_direct_follow(%User{} = follower, %User{local: true, info: %{locked: true}}) do
 263     {:ok, follower}
 264   end
 265
 266   def maybe_direct_follow(%User{} = follower, %User{local: true} = followed) do
 267     follow(follower, followed)
 268   end
 269
 270   def maybe_direct_follow(%User{} = follower, %User{} = followed) do
 271     if not User.ap_enabled?(followed) do
 272       follow(follower, followed)
 273     else
 274       {:ok, follower}
 275     end
 276   end
 277
 278   def maybe_follow(%User{} = follower, %User{info: _info} = followed) do
 279     if not following?(follower, followed) do
 280       follow(follower, followed)
 281     else
 282       {:ok, follower}
 283     end
 284   end
 285
 286   def follow(%User{} = follower, %User{info: info} = followed) do
 287     user_config = Application.get_env(:pleroma, :user)
 288     deny_follow_blocked = Keyword.get(user_config, :deny_follow_blocked)
 289
 290     ap_followers = followed.follower_address
 291
 292     cond do
 293       following?(follower, followed) or info.deactivated ->
 294         {:error, "Could not follow user: #{followed.nickname} is already on your list."}
 295
 296       deny_follow_blocked and blocks?(followed, follower) ->
 297         {:error, "Could not follow user: #{followed.nickname} blocked you."}
 298
 299       true ->
 300         if !followed.local && follower.local && !ap_enabled?(followed) do
 301           Websub.subscribe(follower, followed)
 302         end
 303
 304         following =
 305           [ap_followers | follower.following]
 306           |> Enum.uniq()
 307
 308         follower =
 309           follower
 310           |> follow_changeset(%{following: following})
 311           |> update_and_set_cache
 312
 313         {:ok, _} = update_follower_count(followed)
 314
 315         follower
 316     end
 317   end
 318
 319   def unfollow(%User{} = follower, %User{} = followed) do
 320     ap_followers = followed.follower_address
 321
 322     if following?(follower, followed) and follower.ap_id != followed.ap_id do
 323       following =
 324         follower.following
 325         |> List.delete(ap_followers)
 326
 327       {:ok, follower} =
 328         follower
 329         |> follow_changeset(%{following: following})
 330         |> update_and_set_cache
 331
 332       {:ok, followed} = update_follower_count(followed)
 333
 334       {:ok, follower, Utils.fetch_latest_follow(follower, followed)}
 335     else
 336       {:error, "Not subscribed!"}
 337     end
 338   end
 339
 340   @spec following?(User.t(), User.t()) :: boolean
 341   def following?(%User{} = follower, %User{} = followed) do
 342     Enum.member?(follower.following, followed.follower_address)
 343   end
 344
 345   def follow_import(%User{} = follower, followed_identifiers)
 346       when is_list(followed_identifiers) do
 347     Enum.map(
 348       followed_identifiers,
 349       fn followed_identifier ->
 350         with %User{} = followed <- get_or_fetch(followed_identifier),
 351              {:ok, follower} <- maybe_direct_follow(follower, followed),
 352              {:ok, _} <- ActivityPub.follow(follower, followed) do
 353           followed
 354         else
 355           err ->
 356             Logger.debug("follow_import failed for #{followed_identifier} with: #{inspect(err)}")
 357             err
 358         end
 359       end
 360     )
 361   end
 362
 363   def locked?(%User{} = user) do
 364     user.info.locked || false
 365   end
 366
 367   def get_by_ap_id(ap_id) do
 368     Repo.get_by(User, ap_id: ap_id)
 369   end
 370
 371   # This is mostly an SPC migration fix. This guesses the user nickname (by taking the last part of the ap_id and the domain) and tries to get that user
 372   def get_by_guessed_nickname(ap_id) do
 373     domain = URI.parse(ap_id).host
 374     name = List.last(String.split(ap_id, "/"))
 375     nickname = "#{name}@#{domain}"
 376
 377     get_by_nickname(nickname)
 378   end
 379
 380   def update_and_set_cache(changeset) do
 381     with {:ok, user} <- Repo.update(changeset) do
 382       Cachex.put(:user_cache, "ap_id:#{user.ap_id}", user)
 383       Cachex.put(:user_cache, "nickname:#{user.nickname}", user)
 384       Cachex.put(:user_cache, "user_info:#{user.id}", user_info(user))
 385       {:ok, user}
 386     else
 387       e -> e
 388     end
 389   end
 390
 391   def invalidate_cache(user) do
 392     Cachex.del(:user_cache, "ap_id:#{user.ap_id}")
 393     Cachex.del(:user_cache, "nickname:#{user.nickname}")
 394     Cachex.del(:user_cache, "user_info:#{user.id}")
 395   end
 396
 397   def get_cached_by_ap_id(ap_id) do
 398     key = "ap_id:#{ap_id}"
 399     Cachex.fetch!(:user_cache, key, fn _ -> get_by_ap_id(ap_id) end)
 400   end
 401
 402   def get_cached_by_nickname(nickname) do
 403     key = "nickname:#{nickname}"
 404     Cachex.fetch!(:user_cache, key, fn _ -> get_or_fetch_by_nickname(nickname) end)
 405   end
 406
 407   def get_by_nickname(nickname) do
 408     Repo.get_by(User, nickname: nickname) ||
 409       if Regex.match?(~r(@#{Pleroma.Web.Endpoint.host()})i, nickname) do
 410         [local_nickname, _] = String.split(nickname, "@")
 411         Repo.get_by(User, nickname: local_nickname)
 412       end
 413   end
 414
 415   def get_by_nickname_or_email(nickname_or_email) do
 416     case user = Repo.get_by(User, nickname: nickname_or_email) do
 417       %User{} -> user
 418       nil -> Repo.get_by(User, email: nickname_or_email)
 419     end
 420   end
 421
 422   def get_cached_user_info(user) do
 423     key = "user_info:#{user.id}"
 424     Cachex.fetch!(:user_cache, key, fn _ -> user_info(user) end)
 425   end
 426
 427   def fetch_by_nickname(nickname) do
 428     ap_try = ActivityPub.make_user_from_nickname(nickname)
 429
 430     case ap_try do
 431       {:ok, user} -> {:ok, user}
 432       _ -> OStatus.make_user(nickname)
 433     end
 434   end
 435
 436   def get_or_fetch_by_nickname(nickname) do
 437     with %User{} = user <- get_by_nickname(nickname) do
 438       user
 439     else
 440       _e ->
 441         with [_nick, _domain] <- String.split(nickname, "@"),
 442              {:ok, user} <- fetch_by_nickname(nickname) do
 443           user
 444         else
 445           _e -> nil
 446         end
 447     end
 448   end
 449
 450   def get_followers_query(%User{id: id, follower_address: follower_address}) do
 451     from(
 452       u in User,
 453       where: fragment("? <@ ?", ^[follower_address], u.following),
 454       where: u.id != ^id
 455     )
 456   end
 457
 458   def get_followers(user) do
 459     q = get_followers_query(user)
 460
 461     {:ok, Repo.all(q)}
 462   end
 463
 464   def get_friends_query(%User{id: id, following: following}) do
 465     from(
 466       u in User,
 467       where: u.follower_address in ^following,
 468       where: u.id != ^id
 469     )
 470   end
 471
 472   def get_friends(user) do
 473     q = get_friends_query(user)
 474
 475     {:ok, Repo.all(q)}
 476   end
 477
 478   def get_follow_requests_query(%User{} = user) do
 479     from(
 480       a in Activity,
 481       where:
 482         fragment(
 483           "? ->> 'type' = 'Follow'",
 484           a.data
 485         ),
 486       where:
 487         fragment(
 488           "? ->> 'state' = 'pending'",
 489           a.data
 490         ),
 491       where:
 492         fragment(
 493           "? @> ?",
 494           a.data,
 495           ^%{"object" => user.ap_id}
 496         )
 497     )
 498   end
 499
 500   def get_follow_requests(%User{} = user) do
 501     q = get_follow_requests_query(user)
 502     reqs = Repo.all(q)
 503
 504     users =
 505       Enum.map(reqs, fn req -> req.actor end)
 506       |> Enum.uniq()
 507       |> Enum.map(fn ap_id -> get_by_ap_id(ap_id) end)
 508       |> Enum.filter(fn u -> !is_nil(u) end)
 509       |> Enum.filter(fn u -> !following?(u, user) end)
 510
 511     {:ok, users}
 512   end
 513
 514   def increase_note_count(%User{} = user) do
 515     info_cng = User.Info.add_to_note_count(user.info, 1)
 516
 517     cng =
 518       change(user)
 519       |> put_embed(:info, info_cng)
 520
 521     update_and_set_cache(cng)
 522   end
 523
 524   def decrease_note_count(%User{} = user) do
 525     info_cng = User.Info.add_to_note_count(user.info, -1)
 526
 527     cng =
 528       change(user)
 529       |> put_embed(:info, info_cng)
 530
 531     update_and_set_cache(cng)
 532   end
 533
 534   def update_note_count(%User{} = user) do
 535     note_count_query =
 536       from(
 537         a in Object,
 538         where: fragment("?->>'actor' = ? and ?->>'type' = 'Note'", a.data, ^user.ap_id, a.data),
 539         select: count(a.id)
 540       )
 541
 542     note_count = Repo.one(note_count_query)
 543
 544     info_cng = User.Info.set_note_count(user.info, note_count)
 545
 546     cng =
 547       change(user)
 548       |> put_embed(:info, info_cng)
 549
 550     update_and_set_cache(cng)
 551   end
 552
 553   def update_follower_count(%User{} = user) do
 554     follower_count_query =
 555       from(
 556         u in User,
 557         where: ^user.follower_address in u.following,
 558         where: u.id != ^user.id,
 559         select: count(u.id)
 560       )
 561
 562     follower_count = Repo.one(follower_count_query)
 563
 564     info_cng =
 565       user.info
 566       |> User.Info.set_follower_count(follower_count)
 567
 568     cng =
 569       change(user)
 570       |> put_embed(:info, info_cng)
 571
 572     update_and_set_cache(cng)
 573   end
 574
 575   def get_users_from_set_query(ap_ids, false) do
 576     from(
 577       u in User,
 578       where: u.ap_id in ^ap_ids
 579     )
 580   end
 581
 582   def get_users_from_set_query(ap_ids, true) do
 583     query = get_users_from_set_query(ap_ids, false)
 584
 585     from(
 586       u in query,
 587       where: u.local == true
 588     )
 589   end
 590
 591   def get_users_from_set(ap_ids, local_only \\ true) do
 592     get_users_from_set_query(ap_ids, local_only)
 593     |> Repo.all()
 594   end
 595
 596   def get_recipients_from_activity(%Activity{recipients: to}) do
 597     query =
 598       from(
 599         u in User,
 600         where: u.ap_id in ^to,
 601         or_where: fragment("? && ?", u.following, ^to)
 602       )
 603
 604     query = from(u in query, where: u.local == true)
 605
 606     Repo.all(query)
 607   end
 608
 609   def search(query, resolve \\ false) do
 610     # strip the beginning @ off if there is a query
 611     query = String.trim_leading(query, "@")
 612
 613     if resolve do
 614       User.get_or_fetch_by_nickname(query)
 615     end
 616
 617     inner =
 618       from(
 619         u in User,
 620         select_merge: %{
 621           search_distance:
 622             fragment(
 623               "? <-> (? || coalesce(?, ''))",
 624               ^query,
 625               u.nickname,
 626               u.name
 627             )
 628         },
 629         where: not is_nil(u.nickname)
 630       )
 631
 632     q =
 633       from(
 634         s in subquery(inner),
 635         order_by: s.search_distance,
 636         limit: 20
 637       )
 638
 639     Repo.all(q)
 640   end
 641
 642   def blocks_import(%User{} = blocker, blocked_identifiers) when is_list(blocked_identifiers) do
 643     Enum.map(
 644       blocked_identifiers,
 645       fn blocked_identifier ->
 646         with %User{} = blocked <- get_or_fetch(blocked_identifier),
 647              {:ok, blocker} <- block(blocker, blocked),
 648              {:ok, _} <- ActivityPub.block(blocker, blocked) do
 649           blocked
 650         else
 651           err ->
 652             Logger.debug("blocks_import failed for #{blocked_identifier} with: #{inspect(err)}")
 653             err
 654         end
 655       end
 656     )
 657   end
 658
 659   def block(blocker, %User{ap_id: ap_id} = blocked) do
 660     # sever any follow relationships to prevent leaks per activitypub (Pleroma issue #213)
 661     blocker =
 662       if following?(blocker, blocked) do
 663         {:ok, blocker, _} = unfollow(blocker, blocked)
 664         blocker
 665       else
 666         blocker
 667       end
 668
 669     if following?(blocked, blocker) do
 670       unfollow(blocked, blocker)
 671     end
 672
 673     info_cng =
 674       blocker.info
 675       |> User.Info.add_to_block(ap_id)
 676
 677     cng =
 678       change(blocker)
 679       |> put_embed(:info, info_cng)
 680
 681     update_and_set_cache(cng)
 682   end
 683
 684   # helper to handle the block given only an actor's AP id
 685   def block(blocker, %{ap_id: ap_id}) do
 686     block(blocker, User.get_by_ap_id(ap_id))
 687   end
 688
 689   def unblock(blocker, %{ap_id: ap_id}) do
 690     info_cng =
 691       blocker.info
 692       |> User.Info.remove_from_block(ap_id)
 693
 694     cng =
 695       change(blocker)
 696       |> put_embed(:info, info_cng)
 697
 698     update_and_set_cache(cng)
 699   end
 700
 701   def blocks?(user, %{ap_id: ap_id}) do
 702     blocks = user.info.blocks
 703     domain_blocks = user.info.domain_blocks
 704     %{host: host} = URI.parse(ap_id)
 705
 706     Enum.member?(blocks, ap_id) ||
 707       Enum.any?(domain_blocks, fn domain ->
 708         host == domain
 709       end)
 710   end
 711
 712   def blocked_users(user),
 713     do: Repo.all(from(u in User, where: u.ap_id in ^user.info.blocks))
 714
 715   def block_domain(user, domain) do
 716     info_cng =
 717       user.info
 718       |> User.Info.add_to_domain_block(domain)
 719
 720     cng =
 721       change(user)
 722       |> put_embed(:info, info_cng)
 723
 724     update_and_set_cache(cng)
 725   end
 726
 727   def unblock_domain(user, domain) do
 728     info_cng =
 729       user.info
 730       |> User.Info.remove_from_domain_block(domain)
 731
 732     cng =
 733       change(user)
 734       |> put_embed(:info, info_cng)
 735
 736     update_and_set_cache(cng)
 737   end
 738
 739   def local_user_query() do
 740     from(
 741       u in User,
 742       where: u.local == true,
 743       where: not is_nil(u.nickname)
 744     )
 745   end
 746
 747   def moderator_user_query() do
 748     from(
 749       u in User,
 750       where: u.local == true,
 751       where: fragment("?->'is_moderator' @> 'true'", u.info)
 752     )
 753   end
 754
 755   def deactivate(%User{} = user, status \\ true) do
 756     info_cng = User.Info.set_activation_status(user.info, status)
 757
 758     cng =
 759       change(user)
 760       |> put_embed(:info, info_cng)
 761
 762     update_and_set_cache(cng)
 763   end
 764
 765   def delete(%User{} = user) do
 766     {:ok, user} = User.deactivate(user)
 767
 768     # Remove all relationships
 769     {:ok, followers} = User.get_followers(user)
 770
 771     followers
 772     |> Enum.each(fn follower -> User.unfollow(follower, user) end)
 773
 774     {:ok, friends} = User.get_friends(user)
 775
 776     friends
 777     |> Enum.each(fn followed -> User.unfollow(user, followed) end)
 778
 779     query = from(a in Activity, where: a.actor == ^user.ap_id)
 780
 781     Repo.all(query)
 782     |> Enum.each(fn activity ->
 783       case activity.data["type"] do
 784         "Create" ->
 785           ActivityPub.delete(Object.normalize(activity.data["object"]))
 786
 787         # TODO: Do something with likes, follows, repeats.
 788         _ ->
 789           "Doing nothing"
 790       end
 791     end)
 792
 793     {:ok, user}
 794   end
 795
 796   def html_filter_policy(%User{info: %{no_rich_text: true}}) do
 797     Pleroma.HTML.Scrubber.TwitterText
 798   end
 799
 800   @default_scrubbers Pleroma.Config.get([:markup, :scrub_policy])
 801
 802   def html_filter_policy(_), do: @default_scrubbers
 803
 804   def get_or_fetch_by_ap_id(ap_id) do
 805     user = get_by_ap_id(ap_id)
 806
 807     if !is_nil(user) and !User.needs_update?(user) do
 808       user
 809     else
 810       ap_try = ActivityPub.make_user_from_ap_id(ap_id)
 811
 812       case ap_try do
 813         {:ok, user} ->
 814           user
 815
 816         _ ->
 817           case OStatus.make_user(ap_id) do
 818             {:ok, user} -> user
 819             _ -> {:error, "Could not fetch by AP id"}
 820           end
 821       end
 822     end
 823   end
 824
 825   def get_or_create_instance_user do
 826     relay_uri = "#{Pleroma.Web.Endpoint.url()}/relay"
 827
 828     if user = get_by_ap_id(relay_uri) do
 829       user
 830     else
 831       changes =
 832         %User{info: %User.Info{}}
 833         |> cast(%{}, [:ap_id, :nickname, :local])
 834         |> put_change(:ap_id, relay_uri)
 835         |> put_change(:nickname, nil)
 836         |> put_change(:local, true)
 837         |> put_change(:follower_address, relay_uri <> "/followers")
 838
 839       {:ok, user} = Repo.insert(changes)
 840       user
 841     end
 842   end
 843
 844   # AP style
 845   def public_key_from_info(%{
 846         source_data: %{"publicKey" => %{"publicKeyPem" => public_key_pem}}
 847       }) do
 848     key =
 849       public_key_pem
 850       |> :public_key.pem_decode()
 851       |> hd()
 852       |> :public_key.pem_entry_decode()
 853
 854     {:ok, key}
 855   end
 856
 857   # OStatus Magic Key
 858   def public_key_from_info(%{magic_key: magic_key}) do
 859     {:ok, Pleroma.Web.Salmon.decode_key(magic_key)}
 860   end
 861
 862   def get_public_key_for_ap_id(ap_id) do
 863     with %User{} = user <- get_or_fetch_by_ap_id(ap_id),
 864          {:ok, public_key} <- public_key_from_info(user.info) do
 865       {:ok, public_key}
 866     else
 867       _ -> :error
 868     end
 869   end
 870
 871   defp blank?(""), do: nil
 872   defp blank?(n), do: n
 873
 874   def insert_or_update_user(data) do
 875     data =
 876       data
 877       |> Map.put(:name, blank?(data[:name]) || data[:nickname])
 878
 879     cs = User.remote_user_creation(data)
 880
 881     Repo.insert(cs, on_conflict: :replace_all, conflict_target: :nickname)
 882   end
 883
 884   def ap_enabled?(%User{local: true}), do: true
 885   def ap_enabled?(%User{info: info}), do: info.ap_enabled
 886   def ap_enabled?(_), do: false
 887
 888   @doc "Gets or fetch a user by uri or nickname."
 889   @spec get_or_fetch(String.t()) :: User.t()
 890   def get_or_fetch("http" <> _host = uri), do: get_or_fetch_by_ap_id(uri)
 891   def get_or_fetch(nickname), do: get_or_fetch_by_nickname(nickname)
 892
 893   # wait a period of time and return newest version of the User structs
 894   # this is because we have synchronous follow APIs and need to simulate them
 895   # with an async handshake
 896   def wait_and_refresh(_, %User{local: true} = a, %User{local: true} = b) do
 897     with %User{} = a <- Repo.get(User, a.id),
 898          %User{} = b <- Repo.get(User, b.id) do
 899       {:ok, a, b}
 900     else
 901       _e ->
 902         :error
 903     end
 904   end
 905
 906   def wait_and_refresh(timeout, %User{} = a, %User{} = b) do
 907     with :ok <- :timer.sleep(timeout),
 908          %User{} = a <- Repo.get(User, a.id),
 909          %User{} = b <- Repo.get(User, b.id) do
 910       {:ok, a, b}
 911     else
 912       _e ->
 913         :error
 914     end
 915   end
 916
 917   def parse_bio(bio, user \\ %User{info: %{source_data: %{}}})
 918   def parse_bio(nil, _user), do: ""
 919   def parse_bio(bio, _user) when bio == "", do: bio
 920
 921   def parse_bio(bio, user) do
 922     mentions = Formatter.parse_mentions(bio)
 923     tags = Formatter.parse_tags(bio)
 924
 925     emoji =
 926       (user.info.source_data["tag"] || [])
 927       |> Enum.filter(fn %{"type" => t} -> t == "Emoji" end)
 928       |> Enum.map(fn %{"icon" => %{"url" => url}, "name" => name} ->
 929         {String.trim(name, ":"), url}
 930       end)
 931
 932     bio
 933     |> CommonUtils.format_input(mentions, tags, "text/plain")
 934     |> Formatter.emojify(emoji)
 935   end
 936
 937   def tag(user_identifiers, tags) when is_list(user_identifiers) do
 938     Repo.transaction(fn ->
 939       for user_identifier <- user_identifiers, do: tag(user_identifier, tags)
 940     end)
 941   end
 942
 943   def tag(nickname, tags) when is_binary(nickname),
 944     do: tag(User.get_by_nickname(nickname), tags)
 945
 946   def tag(%User{} = user, tags),
 947     do: update_tags(user, Enum.uniq((user.tags || []) ++ normalize_tags(tags)))
 948
 949   def untag(user_identifiers, tags) when is_list(user_identifiers) do
 950     Repo.transaction(fn ->
 951       for user_identifier <- user_identifiers, do: untag(user_identifier, tags)
 952     end)
 953   end
 954
 955   def untag(nickname, tags) when is_binary(nickname),
 956     do: untag(User.get_by_nickname(nickname), tags)
 957
 958   def untag(%User{} = user, tags),
 959     do: update_tags(user, (user.tags || []) -- normalize_tags(tags))
 960
 961   defp update_tags(%User{} = user, new_tags) do
 962     {:ok, updated_user} =
 963       user
 964       |> change(%{tags: new_tags})
 965       |> Repo.update()
 966
 967     updated_user
 968   end
 969
 970   defp normalize_tags(tags) do
 971     [tags]
 972     |> List.flatten()
 973     |> Enum.map(&String.downcase(&1))
 974   end
 975
 976   defp local_nickname_regex() do
 977     if Pleroma.Config.get([:instance, :extended_nickname_format]) do
 978       @extended_local_nickname_regex
 979     else
 980       @strict_local_nickname_regex
 981     end
 982   end
 983 end