git.squeep.com Git - akkoma/blob - lib/pleroma/user.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.User do
   6   use Ecto.Schema
   7
   8   import Ecto.{Changeset, Query}
   9   alias Pleroma.{Repo, User, Object, Web, Activity, Notification}
  10   alias Comeonin.Pbkdf2
  11   alias Pleroma.Formatter
  12   alias Pleroma.Web.CommonAPI.Utils, as: CommonUtils
  13   alias Pleroma.Web.{OStatus, Websub, OAuth}
  14   alias Pleroma.Web.ActivityPub.{Utils, ActivityPub}
  15
  16   require Logger
  17
  18   @type t :: %__MODULE__{}
  19
  20   @email_regex ~r/^[a-zA-Z0-9.!#$%&'*+\/=?^_`{|}~-]+@[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?(?:\.[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?)*$/
  21
  22   @strict_local_nickname_regex ~r/^[a-zA-Z\d]+$/
  23   @extended_local_nickname_regex ~r/^[a-zA-Z\d_-]+$/
  24
  25   schema "users" do
  26     field(:bio, :string)
  27     field(:email, :string)
  28     field(:name, :string)
  29     field(:nickname, :string)
  30     field(:password_hash, :string)
  31     field(:password, :string, virtual: true)
  32     field(:password_confirmation, :string, virtual: true)
  33     field(:following, {:array, :string}, default: [])
  34     field(:ap_id, :string)
  35     field(:avatar, :map)
  36     field(:local, :boolean, default: true)
  37     field(:follower_address, :string)
  38     field(:search_rank, :float, virtual: true)
  39     field(:tags, {:array, :string}, default: [])
  40     field(:last_refreshed_at, :naive_datetime)
  41     has_many(:notifications, Notification)
  42     embeds_one(:info, Pleroma.User.Info)
  43
  44     timestamps()
  45   end
  46
  47   def auth_active?(%User{local: false}), do: true
  48
  49   def auth_active?(%User{info: %User.Info{confirmation_pending: false}}), do: true
  50
  51   def auth_active?(%User{info: %User.Info{confirmation_pending: true}}),
  52     do: !Pleroma.Config.get([:instance, :account_activation_required])
  53
  54   def auth_active?(_), do: false
  55
  56   def visible_for?(user, for_user \\ nil)
  57
  58   def visible_for?(%User{id: user_id}, %User{id: for_id}) when user_id == for_id, do: true
  59
  60   def visible_for?(%User{} = user, for_user) do
  61     auth_active?(user) || superuser?(for_user)
  62   end
  63
  64   def visible_for?(_, _), do: false
  65
  66   def superuser?(%User{local: true, info: %User.Info{is_admin: true}}), do: true
  67   def superuser?(%User{local: true, info: %User.Info{is_moderator: true}}), do: true
  68   def superuser?(_), do: false
  69
  70   def avatar_url(user) do
  71     case user.avatar do
  72       %{"url" => [%{"href" => href} | _]} -> href
  73       _ -> "#{Web.base_url()}/images/avi.png"
  74     end
  75   end
  76
  77   def banner_url(user) do
  78     case user.info.banner do
  79       %{"url" => [%{"href" => href} | _]} -> href
  80       _ -> "#{Web.base_url()}/images/banner.png"
  81     end
  82   end
  83
  84   def profile_url(%User{info: %{source_data: %{"url" => url}}}), do: url
  85   def profile_url(%User{ap_id: ap_id}), do: ap_id
  86   def profile_url(_), do: nil
  87
  88   def ap_id(%User{nickname: nickname}) do
  89     "#{Web.base_url()}/users/#{nickname}"
  90   end
  91
  92   def ap_followers(%User{} = user) do
  93     "#{ap_id(user)}/followers"
  94   end
  95
  96   def follow_changeset(struct, params \\ %{}) do
  97     struct
  98     |> cast(params, [:following])
  99     |> validate_required([:following])
 100   end
 101
 102   def user_info(%User{} = user) do
 103     oneself = if user.local, do: 1, else: 0
 104
 105     %{
 106       following_count: length(user.following) - oneself,
 107       note_count: user.info.note_count,
 108       follower_count: user.info.follower_count,
 109       locked: user.info.locked,
 110       confirmation_pending: user.info.confirmation_pending,
 111       default_scope: user.info.default_scope
 112     }
 113   end
 114
 115   def remote_user_creation(params) do
 116     params =
 117       params
 118       |> Map.put(:info, params[:info] || %{})
 119
 120     info_cng = User.Info.remote_user_creation(%User.Info{}, params[:info])
 121
 122     changes =
 123       %User{}
 124       |> cast(params, [:bio, :name, :ap_id, :nickname, :avatar])
 125       |> validate_required([:name, :ap_id])
 126       |> unique_constraint(:nickname)
 127       |> validate_format(:nickname, @email_regex)
 128       |> validate_length(:bio, max: 5000)
 129       |> validate_length(:name, max: 100)
 130       |> put_change(:local, false)
 131       |> put_embed(:info, info_cng)
 132
 133     if changes.valid? do
 134       case info_cng.changes[:source_data] do
 135         %{"followers" => followers} ->
 136           changes
 137           |> put_change(:follower_address, followers)
 138
 139         _ ->
 140           followers = User.ap_followers(%User{nickname: changes.changes[:nickname]})
 141
 142           changes
 143           |> put_change(:follower_address, followers)
 144       end
 145     else
 146       changes
 147     end
 148   end
 149
 150   def update_changeset(struct, params \\ %{}) do
 151     struct
 152     |> cast(params, [:bio, :name, :avatar])
 153     |> unique_constraint(:nickname)
 154     |> validate_format(:nickname, local_nickname_regex())
 155     |> validate_length(:bio, max: 5000)
 156     |> validate_length(:name, min: 1, max: 100)
 157   end
 158
 159   def upgrade_changeset(struct, params \\ %{}) do
 160     params =
 161       params
 162       |> Map.put(:last_refreshed_at, NaiveDateTime.utc_now())
 163
 164     info_cng =
 165       struct.info
 166       |> User.Info.user_upgrade(params[:info])
 167
 168     struct
 169     |> cast(params, [:bio, :name, :follower_address, :avatar, :last_refreshed_at])
 170     |> unique_constraint(:nickname)
 171     |> validate_format(:nickname, local_nickname_regex())
 172     |> validate_length(:bio, max: 5000)
 173     |> validate_length(:name, max: 100)
 174     |> put_embed(:info, info_cng)
 175   end
 176
 177   def password_update_changeset(struct, params) do
 178     changeset =
 179       struct
 180       |> cast(params, [:password, :password_confirmation])
 181       |> validate_required([:password, :password_confirmation])
 182       |> validate_confirmation(:password)
 183
 184     OAuth.Token.delete_user_tokens(struct)
 185     OAuth.Authorization.delete_user_authorizations(struct)
 186
 187     if changeset.valid? do
 188       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 189
 190       changeset
 191       |> put_change(:password_hash, hashed)
 192     else
 193       changeset
 194     end
 195   end
 196
 197   def reset_password(user, data) do
 198     update_and_set_cache(password_update_changeset(user, data))
 199   end
 200
 201   def register_changeset(struct, params \\ %{}, opts \\ []) do
 202     confirmation_status =
 203       if opts[:confirmed] || !Pleroma.Config.get([:instance, :account_activation_required]) do
 204         :confirmed
 205       else
 206         :unconfirmed
 207       end
 208
 209     info_change = User.Info.confirmation_changeset(%User.Info{}, confirmation_status)
 210
 211     changeset =
 212       struct
 213       |> cast(params, [:bio, :email, :name, :nickname, :password, :password_confirmation])
 214       |> validate_required([:email, :name, :nickname, :password, :password_confirmation])
 215       |> validate_confirmation(:password)
 216       |> unique_constraint(:email)
 217       |> unique_constraint(:nickname)
 218       |> validate_exclusion(:nickname, Pleroma.Config.get([Pleroma.User, :restricted_nicknames]))
 219       |> validate_format(:nickname, local_nickname_regex())
 220       |> validate_format(:email, @email_regex)
 221       |> validate_length(:bio, max: 1000)
 222       |> validate_length(:name, min: 1, max: 100)
 223       |> put_change(:info, info_change)
 224
 225     if changeset.valid? do
 226       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 227       ap_id = User.ap_id(%User{nickname: changeset.changes[:nickname]})
 228       followers = User.ap_followers(%User{nickname: changeset.changes[:nickname]})
 229
 230       changeset
 231       |> put_change(:password_hash, hashed)
 232       |> put_change(:ap_id, ap_id)
 233       |> put_change(:following, [followers])
 234       |> put_change(:follower_address, followers)
 235     else
 236       changeset
 237     end
 238   end
 239
 240   defp autofollow_users(user) do
 241     candidates = Pleroma.Config.get([:instance, :autofollowed_nicknames])
 242
 243     autofollowed_users =
 244       from(u in User,
 245         where: u.local == true,
 246         where: u.nickname in ^candidates
 247       )
 248       |> Repo.all()
 249
 250     follow_all(user, autofollowed_users)
 251   end
 252
 253   @doc "Inserts provided changeset, performs post-registration actions (confirmation email sending etc.)"
 254   def register(%Ecto.Changeset{} = changeset) do
 255     with {:ok, user} <- Repo.insert(changeset),
 256          {:ok, _} <- try_send_confirmation_email(user),
 257          {:ok, user} <- autofollow_users(user) do
 258       {:ok, user}
 259     end
 260   end
 261
 262   def try_send_confirmation_email(%User{} = user) do
 263     if user.info.confirmation_pending &&
 264          Pleroma.Config.get([:instance, :account_activation_required]) do
 265       user
 266       |> Pleroma.UserEmail.account_confirmation_email()
 267       |> Pleroma.Mailer.deliver()
 268     else
 269       {:ok, :noop}
 270     end
 271   end
 272
 273   def needs_update?(%User{local: true}), do: false
 274
 275   def needs_update?(%User{local: false, last_refreshed_at: nil}), do: true
 276
 277   def needs_update?(%User{local: false} = user) do
 278     NaiveDateTime.diff(NaiveDateTime.utc_now(), user.last_refreshed_at) >= 86400
 279   end
 280
 281   def needs_update?(_), do: true
 282
 283   def maybe_direct_follow(%User{} = follower, %User{local: true, info: %{locked: true}}) do
 284     {:ok, follower}
 285   end
 286
 287   def maybe_direct_follow(%User{} = follower, %User{local: true} = followed) do
 288     follow(follower, followed)
 289   end
 290
 291   def maybe_direct_follow(%User{} = follower, %User{} = followed) do
 292     if not User.ap_enabled?(followed) do
 293       follow(follower, followed)
 294     else
 295       {:ok, follower}
 296     end
 297   end
 298
 299   def maybe_follow(%User{} = follower, %User{info: _info} = followed) do
 300     if not following?(follower, followed) do
 301       follow(follower, followed)
 302     else
 303       {:ok, follower}
 304     end
 305   end
 306
 307   @doc "A mass follow for local users. Ignores blocks and has no side effects"
 308   @spec follow_all(User.t(), list(User.t())) :: {atom(), User.t()}
 309   def follow_all(follower, followeds) do
 310     following =
 311       (follower.following ++ Enum.map(followeds, fn %{follower_address: fa} -> fa end))
 312       |> Enum.uniq()
 313
 314     {:ok, follower} =
 315       follower
 316       |> follow_changeset(%{following: following})
 317       |> update_and_set_cache
 318
 319     Enum.each(followeds, fn followed ->
 320       update_follower_count(followed)
 321     end)
 322
 323     {:ok, follower}
 324   end
 325
 326   def follow(%User{} = follower, %User{info: info} = followed) do
 327     user_config = Application.get_env(:pleroma, :user)
 328     deny_follow_blocked = Keyword.get(user_config, :deny_follow_blocked)
 329
 330     ap_followers = followed.follower_address
 331
 332     cond do
 333       following?(follower, followed) or info.deactivated ->
 334         {:error, "Could not follow user: #{followed.nickname} is already on your list."}
 335
 336       deny_follow_blocked and blocks?(followed, follower) ->
 337         {:error, "Could not follow user: #{followed.nickname} blocked you."}
 338
 339       true ->
 340         if !followed.local && follower.local && !ap_enabled?(followed) do
 341           Websub.subscribe(follower, followed)
 342         end
 343
 344         following =
 345           [ap_followers | follower.following]
 346           |> Enum.uniq()
 347
 348         follower =
 349           follower
 350           |> follow_changeset(%{following: following})
 351           |> update_and_set_cache
 352
 353         {:ok, _} = update_follower_count(followed)
 354
 355         follower
 356     end
 357   end
 358
 359   def unfollow(%User{} = follower, %User{} = followed) do
 360     ap_followers = followed.follower_address
 361
 362     if following?(follower, followed) and follower.ap_id != followed.ap_id do
 363       following =
 364         follower.following
 365         |> List.delete(ap_followers)
 366
 367       {:ok, follower} =
 368         follower
 369         |> follow_changeset(%{following: following})
 370         |> update_and_set_cache
 371
 372       {:ok, followed} = update_follower_count(followed)
 373
 374       {:ok, follower, Utils.fetch_latest_follow(follower, followed)}
 375     else
 376       {:error, "Not subscribed!"}
 377     end
 378   end
 379
 380   @spec following?(User.t(), User.t()) :: boolean
 381   def following?(%User{} = follower, %User{} = followed) do
 382     Enum.member?(follower.following, followed.follower_address)
 383   end
 384
 385   def follow_import(%User{} = follower, followed_identifiers)
 386       when is_list(followed_identifiers) do
 387     Enum.map(
 388       followed_identifiers,
 389       fn followed_identifier ->
 390         with %User{} = followed <- get_or_fetch(followed_identifier),
 391              {:ok, follower} <- maybe_direct_follow(follower, followed),
 392              {:ok, _} <- ActivityPub.follow(follower, followed) do
 393           followed
 394         else
 395           err ->
 396             Logger.debug("follow_import failed for #{followed_identifier} with: #{inspect(err)}")
 397             err
 398         end
 399       end
 400     )
 401   end
 402
 403   def locked?(%User{} = user) do
 404     user.info.locked || false
 405   end
 406
 407   def get_by_ap_id(ap_id) do
 408     Repo.get_by(User, ap_id: ap_id)
 409   end
 410
 411   # This is mostly an SPC migration fix. This guesses the user nickname (by taking the last part of the ap_id and the domain) and tries to get that user
 412   def get_by_guessed_nickname(ap_id) do
 413     domain = URI.parse(ap_id).host
 414     name = List.last(String.split(ap_id, "/"))
 415     nickname = "#{name}@#{domain}"
 416
 417     get_by_nickname(nickname)
 418   end
 419
 420   def update_and_set_cache(changeset) do
 421     with {:ok, user} <- Repo.update(changeset) do
 422       Cachex.put(:user_cache, "ap_id:#{user.ap_id}", user)
 423       Cachex.put(:user_cache, "nickname:#{user.nickname}", user)
 424       Cachex.put(:user_cache, "user_info:#{user.id}", user_info(user))
 425       {:ok, user}
 426     else
 427       e -> e
 428     end
 429   end
 430
 431   def invalidate_cache(user) do
 432     Cachex.del(:user_cache, "ap_id:#{user.ap_id}")
 433     Cachex.del(:user_cache, "nickname:#{user.nickname}")
 434     Cachex.del(:user_cache, "user_info:#{user.id}")
 435   end
 436
 437   def get_cached_by_ap_id(ap_id) do
 438     key = "ap_id:#{ap_id}"
 439     Cachex.fetch!(:user_cache, key, fn _ -> get_by_ap_id(ap_id) end)
 440   end
 441
 442   def get_cached_by_nickname(nickname) do
 443     key = "nickname:#{nickname}"
 444     Cachex.fetch!(:user_cache, key, fn _ -> get_or_fetch_by_nickname(nickname) end)
 445   end
 446
 447   def get_by_nickname(nickname) do
 448     Repo.get_by(User, nickname: nickname) ||
 449       if Regex.match?(~r(@#{Pleroma.Web.Endpoint.host()})i, nickname) do
 450         [local_nickname, _] = String.split(nickname, "@")
 451         Repo.get_by(User, nickname: local_nickname)
 452       end
 453   end
 454
 455   def get_by_nickname_or_email(nickname_or_email) do
 456     case user = Repo.get_by(User, nickname: nickname_or_email) do
 457       %User{} -> user
 458       nil -> Repo.get_by(User, email: nickname_or_email)
 459     end
 460   end
 461
 462   def get_cached_user_info(user) do
 463     key = "user_info:#{user.id}"
 464     Cachex.fetch!(:user_cache, key, fn _ -> user_info(user) end)
 465   end
 466
 467   def fetch_by_nickname(nickname) do
 468     ap_try = ActivityPub.make_user_from_nickname(nickname)
 469
 470     case ap_try do
 471       {:ok, user} -> {:ok, user}
 472       _ -> OStatus.make_user(nickname)
 473     end
 474   end
 475
 476   def get_or_fetch_by_nickname(nickname) do
 477     with %User{} = user <- get_by_nickname(nickname) do
 478       user
 479     else
 480       _e ->
 481         with [_nick, _domain] <- String.split(nickname, "@"),
 482              {:ok, user} <- fetch_by_nickname(nickname) do
 483           user
 484         else
 485           _e -> nil
 486         end
 487     end
 488   end
 489
 490   def get_followers_query(%User{id: id, follower_address: follower_address}, nil) do
 491     from(
 492       u in User,
 493       where: fragment("? <@ ?", ^[follower_address], u.following),
 494       where: u.id != ^id
 495     )
 496   end
 497
 498   def get_followers_query(user, page) do
 499     from(
 500       u in get_followers_query(user, nil),
 501       limit: 20,
 502       offset: ^((page - 1) * 20)
 503     )
 504   end
 505
 506   def get_followers_query(user), do: get_followers_query(user, nil)
 507
 508   def get_followers(user, page \\ nil) do
 509     q = get_followers_query(user, page)
 510
 511     {:ok, Repo.all(q)}
 512   end
 513
 514   def get_followers_ids(user, page \\ nil) do
 515     q = get_followers_query(user, page)
 516
 517     Repo.all(from(u in q, select: u.id))
 518   end
 519
 520   def get_friends_query(%User{id: id, following: following}, nil) do
 521     from(
 522       u in User,
 523       where: u.follower_address in ^following,
 524       where: u.id != ^id
 525     )
 526   end
 527
 528   def get_friends_query(user, page) do
 529     from(
 530       u in get_friends_query(user, nil),
 531       limit: 20,
 532       offset: ^((page - 1) * 20)
 533     )
 534   end
 535
 536   def get_friends_query(user), do: get_friends_query(user, nil)
 537
 538   def get_friends(user, page \\ nil) do
 539     q = get_friends_query(user, page)
 540
 541     {:ok, Repo.all(q)}
 542   end
 543
 544   def get_friends_ids(user, page \\ nil) do
 545     q = get_friends_query(user, page)
 546
 547     Repo.all(from(u in q, select: u.id))
 548   end
 549
 550   def get_follow_requests_query(%User{} = user) do
 551     from(
 552       a in Activity,
 553       where:
 554         fragment(
 555           "? ->> 'type' = 'Follow'",
 556           a.data
 557         ),
 558       where:
 559         fragment(
 560           "? ->> 'state' = 'pending'",
 561           a.data
 562         ),
 563       where:
 564         fragment(
 565           "? @> ?",
 566           a.data,
 567           ^%{"object" => user.ap_id}
 568         )
 569     )
 570   end
 571
 572   def get_follow_requests(%User{} = user) do
 573     q = get_follow_requests_query(user)
 574     reqs = Repo.all(q)
 575
 576     users =
 577       Enum.map(reqs, fn req -> req.actor end)
 578       |> Enum.uniq()
 579       |> Enum.map(fn ap_id -> get_by_ap_id(ap_id) end)
 580       |> Enum.filter(fn u -> !is_nil(u) end)
 581       |> Enum.filter(fn u -> !following?(u, user) end)
 582
 583     {:ok, users}
 584   end
 585
 586   def increase_note_count(%User{} = user) do
 587     info_cng = User.Info.add_to_note_count(user.info, 1)
 588
 589     cng =
 590       change(user)
 591       |> put_embed(:info, info_cng)
 592
 593     update_and_set_cache(cng)
 594   end
 595
 596   def decrease_note_count(%User{} = user) do
 597     info_cng = User.Info.add_to_note_count(user.info, -1)
 598
 599     cng =
 600       change(user)
 601       |> put_embed(:info, info_cng)
 602
 603     update_and_set_cache(cng)
 604   end
 605
 606   def update_note_count(%User{} = user) do
 607     note_count_query =
 608       from(
 609         a in Object,
 610         where: fragment("?->>'actor' = ? and ?->>'type' = 'Note'", a.data, ^user.ap_id, a.data),
 611         select: count(a.id)
 612       )
 613
 614     note_count = Repo.one(note_count_query)
 615
 616     info_cng = User.Info.set_note_count(user.info, note_count)
 617
 618     cng =
 619       change(user)
 620       |> put_embed(:info, info_cng)
 621
 622     update_and_set_cache(cng)
 623   end
 624
 625   def update_follower_count(%User{} = user) do
 626     follower_count_query =
 627       from(
 628         u in User,
 629         where: ^user.follower_address in u.following,
 630         where: u.id != ^user.id,
 631         select: count(u.id)
 632       )
 633
 634     follower_count = Repo.one(follower_count_query)
 635
 636     info_cng =
 637       user.info
 638       |> User.Info.set_follower_count(follower_count)
 639
 640     cng =
 641       change(user)
 642       |> put_embed(:info, info_cng)
 643
 644     update_and_set_cache(cng)
 645   end
 646
 647   def get_users_from_set_query(ap_ids, false) do
 648     from(
 649       u in User,
 650       where: u.ap_id in ^ap_ids
 651     )
 652   end
 653
 654   def get_users_from_set_query(ap_ids, true) do
 655     query = get_users_from_set_query(ap_ids, false)
 656
 657     from(
 658       u in query,
 659       where: u.local == true
 660     )
 661   end
 662
 663   def get_users_from_set(ap_ids, local_only \\ true) do
 664     get_users_from_set_query(ap_ids, local_only)
 665     |> Repo.all()
 666   end
 667
 668   def get_recipients_from_activity(%Activity{recipients: to}) do
 669     query =
 670       from(
 671         u in User,
 672         where: u.ap_id in ^to,
 673         or_where: fragment("? && ?", u.following, ^to)
 674       )
 675
 676     query = from(u in query, where: u.local == true)
 677
 678     Repo.all(query)
 679   end
 680
 681   def search(query, resolve \\ false, for_user \\ nil) do
 682     # Strip the beginning @ off if there is a query
 683     query = String.trim_leading(query, "@")
 684
 685     if resolve, do: User.get_or_fetch_by_nickname(query)
 686
 687     fts_results = do_search(fts_search_subquery(query), for_user)
 688
 689     {:ok, trigram_results} =
 690       Repo.transaction(fn ->
 691         Ecto.Adapters.SQL.query(Repo, "select set_limit(0.25)", [])
 692         do_search(trigram_search_subquery(query), for_user)
 693       end)
 694
 695     Enum.uniq_by(fts_results ++ trigram_results, & &1.id)
 696   end
 697
 698   defp do_search(subquery, for_user, options \\ []) do
 699     q =
 700       from(
 701         s in subquery(subquery),
 702         order_by: [desc: s.search_rank],
 703         limit: ^(options[:limit] || 20)
 704       )
 705
 706     results =
 707       q
 708       |> Repo.all()
 709       |> Enum.filter(&(&1.search_rank > 0))
 710
 711     boost_search_results(results, for_user)
 712   end
 713
 714   defp fts_search_subquery(query) do
 715     processed_query =
 716       query
 717       |> String.replace(~r/\W+/, " ")
 718       |> String.trim()
 719       |> String.split()
 720       |> Enum.map(&(&1 <> ":*"))
 721       |> Enum.join(" | ")
 722
 723     from(
 724       u in User,
 725       select_merge: %{
 726         search_rank:
 727           fragment(
 728             """
 729             ts_rank_cd(
 730               setweight(to_tsvector('simple', regexp_replace(?, '\\W', ' ', 'g')), 'A') ||
 731               setweight(to_tsvector('simple', regexp_replace(coalesce(?, ''), '\\W', ' ', 'g')), 'B'),
 732               to_tsquery('simple', ?),
 733               32
 734             )
 735             """,
 736             u.nickname,
 737             u.name,
 738             ^processed_query
 739           )
 740       },
 741       where:
 742         fragment(
 743           """
 744             (setweight(to_tsvector('simple', regexp_replace(?, '\\W', ' ', 'g')), 'A') ||
 745             setweight(to_tsvector('simple', regexp_replace(coalesce(?, ''), '\\W', ' ', 'g')), 'B')) @@ to_tsquery('simple', ?)
 746           """,
 747           u.nickname,
 748           u.name,
 749           ^processed_query
 750         )
 751     )
 752   end
 753
 754   defp trigram_search_subquery(query) do
 755     from(
 756       u in User,
 757       select_merge: %{
 758         search_rank:
 759           fragment(
 760             "similarity(?, trim(? || ' ' || coalesce(?, '')))",
 761             ^query,
 762             u.nickname,
 763             u.name
 764           )
 765       },
 766       where: fragment("trim(? || ' ' || coalesce(?, '')) % ?", u.nickname, u.name, ^query)
 767     )
 768   end
 769
 770   defp boost_search_results(results, nil), do: results
 771
 772   defp boost_search_results(results, for_user) do
 773     friends_ids = get_friends_ids(for_user)
 774     followers_ids = get_followers_ids(for_user)
 775
 776     Enum.map(
 777       results,
 778       fn u ->
 779         search_rank_coef =
 780           cond do
 781             u.id in friends_ids ->
 782               1.2
 783
 784             u.id in followers_ids ->
 785               1.1
 786
 787             true ->
 788               1
 789           end
 790
 791         Map.put(u, :search_rank, u.search_rank * search_rank_coef)
 792       end
 793     )
 794     |> Enum.sort_by(&(-&1.search_rank))
 795   end
 796
 797   def blocks_import(%User{} = blocker, blocked_identifiers) when is_list(blocked_identifiers) do
 798     Enum.map(
 799       blocked_identifiers,
 800       fn blocked_identifier ->
 801         with %User{} = blocked <- get_or_fetch(blocked_identifier),
 802              {:ok, blocker} <- block(blocker, blocked),
 803              {:ok, _} <- ActivityPub.block(blocker, blocked) do
 804           blocked
 805         else
 806           err ->
 807             Logger.debug("blocks_import failed for #{blocked_identifier} with: #{inspect(err)}")
 808             err
 809         end
 810       end
 811     )
 812   end
 813
 814   def block(blocker, %User{ap_id: ap_id} = blocked) do
 815     # sever any follow relationships to prevent leaks per activitypub (Pleroma issue #213)
 816     blocker =
 817       if following?(blocker, blocked) do
 818         {:ok, blocker, _} = unfollow(blocker, blocked)
 819         blocker
 820       else
 821         blocker
 822       end
 823
 824     if following?(blocked, blocker) do
 825       unfollow(blocked, blocker)
 826     end
 827
 828     info_cng =
 829       blocker.info
 830       |> User.Info.add_to_block(ap_id)
 831
 832     cng =
 833       change(blocker)
 834       |> put_embed(:info, info_cng)
 835
 836     update_and_set_cache(cng)
 837   end
 838
 839   # helper to handle the block given only an actor's AP id
 840   def block(blocker, %{ap_id: ap_id}) do
 841     block(blocker, User.get_by_ap_id(ap_id))
 842   end
 843
 844   def unblock(blocker, %{ap_id: ap_id}) do
 845     info_cng =
 846       blocker.info
 847       |> User.Info.remove_from_block(ap_id)
 848
 849     cng =
 850       change(blocker)
 851       |> put_embed(:info, info_cng)
 852
 853     update_and_set_cache(cng)
 854   end
 855
 856   def blocks?(user, %{ap_id: ap_id}) do
 857     blocks = user.info.blocks
 858     domain_blocks = user.info.domain_blocks
 859     %{host: host} = URI.parse(ap_id)
 860
 861     Enum.member?(blocks, ap_id) ||
 862       Enum.any?(domain_blocks, fn domain ->
 863         host == domain
 864       end)
 865   end
 866
 867   def blocked_users(user),
 868     do: Repo.all(from(u in User, where: u.ap_id in ^user.info.blocks))
 869
 870   def block_domain(user, domain) do
 871     info_cng =
 872       user.info
 873       |> User.Info.add_to_domain_block(domain)
 874
 875     cng =
 876       change(user)
 877       |> put_embed(:info, info_cng)
 878
 879     update_and_set_cache(cng)
 880   end
 881
 882   def unblock_domain(user, domain) do
 883     info_cng =
 884       user.info
 885       |> User.Info.remove_from_domain_block(domain)
 886
 887     cng =
 888       change(user)
 889       |> put_embed(:info, info_cng)
 890
 891     update_and_set_cache(cng)
 892   end
 893
 894   def local_user_query() do
 895     from(
 896       u in User,
 897       where: u.local == true,
 898       where: not is_nil(u.nickname)
 899     )
 900   end
 901
 902   def moderator_user_query() do
 903     from(
 904       u in User,
 905       where: u.local == true,
 906       where: fragment("?->'is_moderator' @> 'true'", u.info)
 907     )
 908   end
 909
 910   def deactivate(%User{} = user, status \\ true) do
 911     info_cng = User.Info.set_activation_status(user.info, status)
 912
 913     cng =
 914       change(user)
 915       |> put_embed(:info, info_cng)
 916
 917     update_and_set_cache(cng)
 918   end
 919
 920   def delete(%User{} = user) do
 921     {:ok, user} = User.deactivate(user)
 922
 923     # Remove all relationships
 924     {:ok, followers} = User.get_followers(user)
 925
 926     followers
 927     |> Enum.each(fn follower -> User.unfollow(follower, user) end)
 928
 929     {:ok, friends} = User.get_friends(user)
 930
 931     friends
 932     |> Enum.each(fn followed -> User.unfollow(user, followed) end)
 933
 934     query = from(a in Activity, where: a.actor == ^user.ap_id)
 935
 936     Repo.all(query)
 937     |> Enum.each(fn activity ->
 938       case activity.data["type"] do
 939         "Create" ->
 940           ActivityPub.delete(Object.normalize(activity.data["object"]))
 941
 942         # TODO: Do something with likes, follows, repeats.
 943         _ ->
 944           "Doing nothing"
 945       end
 946     end)
 947
 948     {:ok, user}
 949   end
 950
 951   def html_filter_policy(%User{info: %{no_rich_text: true}}) do
 952     Pleroma.HTML.Scrubber.TwitterText
 953   end
 954
 955   @default_scrubbers Pleroma.Config.get([:markup, :scrub_policy])
 956
 957   def html_filter_policy(_), do: @default_scrubbers
 958
 959   def get_or_fetch_by_ap_id(ap_id) do
 960     user = get_by_ap_id(ap_id)
 961
 962     if !is_nil(user) and !User.needs_update?(user) do
 963       user
 964     else
 965       ap_try = ActivityPub.make_user_from_ap_id(ap_id)
 966
 967       case ap_try do
 968         {:ok, user} ->
 969           user
 970
 971         _ ->
 972           case OStatus.make_user(ap_id) do
 973             {:ok, user} -> user
 974             _ -> {:error, "Could not fetch by AP id"}
 975           end
 976       end
 977     end
 978   end
 979
 980   def get_or_create_instance_user do
 981     relay_uri = "#{Pleroma.Web.Endpoint.url()}/relay"
 982
 983     if user = get_by_ap_id(relay_uri) do
 984       user
 985     else
 986       changes =
 987         %User{info: %User.Info{}}
 988         |> cast(%{}, [:ap_id, :nickname, :local])
 989         |> put_change(:ap_id, relay_uri)
 990         |> put_change(:nickname, nil)
 991         |> put_change(:local, true)
 992         |> put_change(:follower_address, relay_uri <> "/followers")
 993
 994       {:ok, user} = Repo.insert(changes)
 995       user
 996     end
 997   end
 998
 999   # AP style
1000   def public_key_from_info(%{
1001         source_data: %{"publicKey" => %{"publicKeyPem" => public_key_pem}}
1002       }) do
1003     key =
1004       public_key_pem
1005       |> :public_key.pem_decode()
1006       |> hd()
1007       |> :public_key.pem_entry_decode()
1008
1009     {:ok, key}
1010   end
1011
1012   # OStatus Magic Key
1013   def public_key_from_info(%{magic_key: magic_key}) do
1014     {:ok, Pleroma.Web.Salmon.decode_key(magic_key)}
1015   end
1016
1017   def get_public_key_for_ap_id(ap_id) do
1018     with %User{} = user <- get_or_fetch_by_ap_id(ap_id),
1019          {:ok, public_key} <- public_key_from_info(user.info) do
1020       {:ok, public_key}
1021     else
1022       _ -> :error
1023     end
1024   end
1025
1026   defp blank?(""), do: nil
1027   defp blank?(n), do: n
1028
1029   def insert_or_update_user(data) do
1030     data =
1031       data
1032       |> Map.put(:name, blank?(data[:name]) || data[:nickname])
1033
1034     cs = User.remote_user_creation(data)
1035
1036     Repo.insert(cs, on_conflict: :replace_all, conflict_target: :nickname)
1037   end
1038
1039   def ap_enabled?(%User{local: true}), do: true
1040   def ap_enabled?(%User{info: info}), do: info.ap_enabled
1041   def ap_enabled?(_), do: false
1042
1043   @doc "Gets or fetch a user by uri or nickname."
1044   @spec get_or_fetch(String.t()) :: User.t()
1045   def get_or_fetch("http" <> _host = uri), do: get_or_fetch_by_ap_id(uri)
1046   def get_or_fetch(nickname), do: get_or_fetch_by_nickname(nickname)
1047
1048   # wait a period of time and return newest version of the User structs
1049   # this is because we have synchronous follow APIs and need to simulate them
1050   # with an async handshake
1051   def wait_and_refresh(_, %User{local: true} = a, %User{local: true} = b) do
1052     with %User{} = a <- Repo.get(User, a.id),
1053          %User{} = b <- Repo.get(User, b.id) do
1054       {:ok, a, b}
1055     else
1056       _e ->
1057         :error
1058     end
1059   end
1060
1061   def wait_and_refresh(timeout, %User{} = a, %User{} = b) do
1062     with :ok <- :timer.sleep(timeout),
1063          %User{} = a <- Repo.get(User, a.id),
1064          %User{} = b <- Repo.get(User, b.id) do
1065       {:ok, a, b}
1066     else
1067       _e ->
1068         :error
1069     end
1070   end
1071
1072   def parse_bio(bio, user \\ %User{info: %{source_data: %{}}})
1073   def parse_bio(nil, _user), do: ""
1074   def parse_bio(bio, _user) when bio == "", do: bio
1075
1076   def parse_bio(bio, user) do
1077     mentions = Formatter.parse_mentions(bio)
1078     tags = Formatter.parse_tags(bio)
1079
1080     emoji =
1081       (user.info.source_data["tag"] || [])
1082       |> Enum.filter(fn %{"type" => t} -> t == "Emoji" end)
1083       |> Enum.map(fn %{"icon" => %{"url" => url}, "name" => name} ->
1084         {String.trim(name, ":"), url}
1085       end)
1086
1087     bio
1088     |> CommonUtils.format_input(mentions, tags, "text/plain")
1089     |> Formatter.emojify(emoji)
1090   end
1091
1092   def tag(user_identifiers, tags) when is_list(user_identifiers) do
1093     Repo.transaction(fn ->
1094       for user_identifier <- user_identifiers, do: tag(user_identifier, tags)
1095     end)
1096   end
1097
1098   def tag(nickname, tags) when is_binary(nickname),
1099     do: tag(User.get_by_nickname(nickname), tags)
1100
1101   def tag(%User{} = user, tags),
1102     do: update_tags(user, Enum.uniq((user.tags || []) ++ normalize_tags(tags)))
1103
1104   def untag(user_identifiers, tags) when is_list(user_identifiers) do
1105     Repo.transaction(fn ->
1106       for user_identifier <- user_identifiers, do: untag(user_identifier, tags)
1107     end)
1108   end
1109
1110   def untag(nickname, tags) when is_binary(nickname),
1111     do: untag(User.get_by_nickname(nickname), tags)
1112
1113   def untag(%User{} = user, tags),
1114     do: update_tags(user, (user.tags || []) -- normalize_tags(tags))
1115
1116   defp update_tags(%User{} = user, new_tags) do
1117     {:ok, updated_user} =
1118       user
1119       |> change(%{tags: new_tags})
1120       |> Repo.update()
1121
1122     updated_user
1123   end
1124
1125   defp normalize_tags(tags) do
1126     [tags]
1127     |> List.flatten()
1128     |> Enum.map(&String.downcase(&1))
1129   end
1130
1131   defp local_nickname_regex() do
1132     if Pleroma.Config.get([:instance, :extended_nickname_format]) do
1133       @extended_local_nickname_regex
1134     else
1135       @strict_local_nickname_regex
1136     end
1137   end
1138 end