git.squeep.com Git - akkoma/blob - lib/pleroma/user.ex

   1 defmodule Pleroma.User do
   2   use Ecto.Schema
   3
   4   import Ecto.{Changeset, Query}
   5   alias Pleroma.{Repo, User, Object, Web, Activity, Notification}
   6   alias Comeonin.Pbkdf2
   7   alias Pleroma.Web.{OStatus, Websub}
   8   alias Pleroma.Web.ActivityPub.{Utils, ActivityPub}
   9
  10   schema "users" do
  11     field(:bio, :string)
  12     field(:email, :string)
  13     field(:name, :string)
  14     field(:nickname, :string)
  15     field(:password_hash, :string)
  16     field(:password, :string, virtual: true)
  17     field(:password_confirmation, :string, virtual: true)
  18     field(:following, {:array, :string}, default: [])
  19     field(:ap_id, :string)
  20     field(:avatar, :map)
  21     field(:local, :boolean, default: true)
  22     field(:info, :map, default: %{})
  23     field(:follower_address, :string)
  24     field(:search_distance, :float, virtual: true)
  25     has_many(:notifications, Notification)
  26
  27     timestamps()
  28   end
  29
  30   def avatar_url(user) do
  31     case user.avatar do
  32       %{"url" => [%{"href" => href} | _]} -> href
  33       _ -> "#{Web.base_url()}/images/avi.png"
  34     end
  35   end
  36
  37   def banner_url(user) do
  38     case user.info["banner"] do
  39       %{"url" => [%{"href" => href} | _]} -> href
  40       _ -> "#{Web.base_url()}/images/banner.png"
  41     end
  42   end
  43
  44   def ap_id(%User{nickname: nickname}) do
  45     "#{Web.base_url()}/users/#{nickname}"
  46   end
  47
  48   def ap_followers(%User{} = user) do
  49     "#{ap_id(user)}/followers"
  50   end
  51
  52   def follow_changeset(struct, params \\ %{}) do
  53     struct
  54     |> cast(params, [:following])
  55     |> validate_required([:following])
  56   end
  57
  58   def info_changeset(struct, params \\ %{}) do
  59     struct
  60     |> cast(params, [:info])
  61     |> validate_required([:info])
  62   end
  63
  64   def user_info(%User{} = user) do
  65     oneself = if user.local, do: 1, else: 0
  66
  67     %{
  68       following_count: length(user.following) - oneself,
  69       note_count: user.info["note_count"] || 0,
  70       follower_count: user.info["follower_count"] || 0,
  71       locked: user.info["locked"] || false
  72     }
  73   end
  74
  75   @email_regex ~r/^[a-zA-Z0-9.!#$%&'*+\/=?^_`{|}~-]+@[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?(?:\.[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?)*$/
  76   def remote_user_creation(params) do
  77     changes =
  78       %User{}
  79       |> cast(params, [:bio, :name, :ap_id, :nickname, :info, :avatar])
  80       |> validate_required([:name, :ap_id, :nickname])
  81       |> unique_constraint(:nickname)
  82       |> validate_format(:nickname, @email_regex)
  83       |> validate_length(:bio, max: 5000)
  84       |> validate_length(:name, max: 100)
  85       |> put_change(:local, false)
  86
  87     if changes.valid? do
  88       case changes.changes[:info]["source_data"] do
  89         %{"followers" => followers} ->
  90           changes
  91           |> put_change(:follower_address, followers)
  92
  93         _ ->
  94           followers = User.ap_followers(%User{nickname: changes.changes[:nickname]})
  95
  96           changes
  97           |> put_change(:follower_address, followers)
  98       end
  99     else
 100       changes
 101     end
 102   end
 103
 104   def update_changeset(struct, params \\ %{}) do
 105     struct
 106     |> cast(params, [:bio, :name])
 107     |> unique_constraint(:nickname)
 108     |> validate_format(:nickname, ~r/^[a-zA-Z\d]+$/)
 109     |> validate_length(:bio, max: 5000)
 110     |> validate_length(:name, min: 1, max: 100)
 111   end
 112
 113   def upgrade_changeset(struct, params \\ %{}) do
 114     struct
 115     |> cast(params, [:bio, :name, :info, :follower_address, :avatar])
 116     |> unique_constraint(:nickname)
 117     |> validate_format(:nickname, ~r/^[a-zA-Z\d]+$/)
 118     |> validate_length(:bio, max: 5000)
 119     |> validate_length(:name, max: 100)
 120   end
 121
 122   def password_update_changeset(struct, params) do
 123     changeset =
 124       struct
 125       |> cast(params, [:password, :password_confirmation])
 126       |> validate_required([:password, :password_confirmation])
 127       |> validate_confirmation(:password)
 128
 129     if changeset.valid? do
 130       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 131
 132       changeset
 133       |> put_change(:password_hash, hashed)
 134     else
 135       changeset
 136     end
 137   end
 138
 139   def reset_password(user, data) do
 140     update_and_set_cache(password_update_changeset(user, data))
 141   end
 142
 143   def register_changeset(struct, params \\ %{}) do
 144     changeset =
 145       struct
 146       |> cast(params, [:bio, :email, :name, :nickname, :password, :password_confirmation])
 147       |> validate_required([:email, :name, :nickname, :password, :password_confirmation])
 148       |> validate_confirmation(:password)
 149       |> unique_constraint(:email)
 150       |> unique_constraint(:nickname)
 151       |> validate_format(:nickname, ~r/^[a-zA-Z\d]+$/)
 152       |> validate_format(:email, @email_regex)
 153       |> validate_length(:bio, max: 1000)
 154       |> validate_length(:name, min: 1, max: 100)
 155
 156     if changeset.valid? do
 157       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 158       ap_id = User.ap_id(%User{nickname: changeset.changes[:nickname]})
 159       followers = User.ap_followers(%User{nickname: changeset.changes[:nickname]})
 160
 161       changeset
 162       |> put_change(:password_hash, hashed)
 163       |> put_change(:ap_id, ap_id)
 164       |> put_change(:following, [followers])
 165       |> put_change(:follower_address, followers)
 166     else
 167       changeset
 168     end
 169   end
 170
 171   def maybe_direct_follow(%User{} = follower, %User{info: info} = followed) do
 172     user_config = Application.get_env(:pleroma, :user)
 173     deny_follow_blocked = Keyword.get(user_config, :deny_follow_blocked)
 174
 175     user_info = user_info(followed)
 176
 177     should_direct_follow =
 178       cond do
 179         # if the account is locked, don't pre-create the relationship
 180         user_info[:locked] == true ->
 181           false
 182
 183         # if the users are blocking each other, we shouldn't even be here, but check for it anyway
 184         deny_follow_blocked and
 185             (User.blocks?(follower, followed) or User.blocks?(followed, follower)) ->
 186           false
 187
 188         # if OStatus, then there is no three-way handshake to follow
 189         User.ap_enabled?(followed) != true ->
 190           true
 191
 192         # if there are no other reasons not to, just pre-create the relationship
 193         true ->
 194           true
 195       end
 196
 197     if should_direct_follow do
 198       follow(follower, followed)
 199     else
 200       {:ok, follower}
 201     end
 202   end
 203
 204   def maybe_follow(%User{} = follower, %User{info: info} = followed) do
 205     if not following?(follower, followed) do
 206       follow(follower, followed)
 207     else
 208       {:ok, follower}
 209     end
 210   end
 211
 212   def follow(%User{} = follower, %User{info: info} = followed) do
 213     user_config = Application.get_env(:pleroma, :user)
 214     deny_follow_blocked = Keyword.get(user_config, :deny_follow_blocked)
 215
 216     ap_followers = followed.follower_address
 217
 218     cond do
 219       following?(follower, followed) or info["deactivated"] ->
 220         {:error, "Could not follow user: #{followed.nickname} is already on your list."}
 221
 222       deny_follow_blocked and blocks?(followed, follower) ->
 223         {:error, "Could not follow user: #{followed.nickname} blocked you."}
 224
 225       true ->
 226         if !followed.local && follower.local && !ap_enabled?(followed) do
 227           Websub.subscribe(follower, followed)
 228         end
 229
 230         following =
 231           [ap_followers | follower.following]
 232           |> Enum.uniq()
 233
 234         follower =
 235           follower
 236           |> follow_changeset(%{following: following})
 237           |> update_and_set_cache
 238
 239         {:ok, _} = update_follower_count(followed)
 240
 241         follower
 242     end
 243   end
 244
 245   def unfollow(%User{} = follower, %User{} = followed) do
 246     ap_followers = followed.follower_address
 247
 248     if following?(follower, followed) and follower.ap_id != followed.ap_id do
 249       following =
 250         follower.following
 251         |> List.delete(ap_followers)
 252
 253       {:ok, follower} =
 254         follower
 255         |> follow_changeset(%{following: following})
 256         |> update_and_set_cache
 257
 258       {:ok, followed} = update_follower_count(followed)
 259
 260       {:ok, follower, Utils.fetch_latest_follow(follower, followed)}
 261     else
 262       {:error, "Not subscribed!"}
 263     end
 264   end
 265
 266   def following?(%User{} = follower, %User{} = followed) do
 267     Enum.member?(follower.following, followed.follower_address)
 268   end
 269
 270   def locked?(%User{} = user) do
 271     user.info["locked"] || false
 272   end
 273
 274   def get_by_ap_id(ap_id) do
 275     Repo.get_by(User, ap_id: ap_id)
 276   end
 277
 278   def update_and_set_cache(changeset) do
 279     with {:ok, user} <- Repo.update(changeset) do
 280       Cachex.put(:user_cache, "ap_id:#{user.ap_id}", user)
 281       Cachex.put(:user_cache, "nickname:#{user.nickname}", user)
 282       Cachex.put(:user_cache, "user_info:#{user.id}", user_info(user))
 283       {:ok, user}
 284     else
 285       e -> e
 286     end
 287   end
 288
 289   def invalidate_cache(user) do
 290     Cachex.del(:user_cache, "ap_id:#{user.ap_id}")
 291     Cachex.del(:user_cache, "nickname:#{user.nickname}")
 292   end
 293
 294   def get_cached_by_ap_id(ap_id) do
 295     key = "ap_id:#{ap_id}"
 296     Cachex.fetch!(:user_cache, key, fn _ -> get_by_ap_id(ap_id) end)
 297   end
 298
 299   def get_cached_by_nickname(nickname) do
 300     key = "nickname:#{nickname}"
 301     Cachex.fetch!(:user_cache, key, fn _ -> get_or_fetch_by_nickname(nickname) end)
 302   end
 303
 304   def get_by_nickname(nickname) do
 305     Repo.get_by(User, nickname: nickname)
 306   end
 307
 308   def get_by_nickname_or_email(nickname_or_email) do
 309     case user = Repo.get_by(User, nickname: nickname_or_email) do
 310       %User{} -> user
 311       nil -> Repo.get_by(User, email: nickname_or_email)
 312     end
 313   end
 314
 315   def get_cached_user_info(user) do
 316     key = "user_info:#{user.id}"
 317     Cachex.fetch!(:user_cache, key, fn _ -> user_info(user) end)
 318   end
 319
 320   def fetch_by_nickname(nickname) do
 321     ap_try = ActivityPub.make_user_from_nickname(nickname)
 322
 323     case ap_try do
 324       {:ok, user} -> {:ok, user}
 325       _ -> OStatus.make_user(nickname)
 326     end
 327   end
 328
 329   def get_or_fetch_by_nickname(nickname) do
 330     with %User{} = user <- get_by_nickname(nickname) do
 331       user
 332     else
 333       _e ->
 334         with [_nick, _domain] <- String.split(nickname, "@"),
 335              {:ok, user} <- fetch_by_nickname(nickname) do
 336           user
 337         else
 338           _e -> nil
 339         end
 340     end
 341   end
 342
 343   def get_followers_query(%User{id: id, follower_address: follower_address}) do
 344     from(
 345       u in User,
 346       where: fragment("? <@ ?", ^[follower_address], u.following),
 347       where: u.id != ^id
 348     )
 349   end
 350
 351   def get_followers(user) do
 352     q = get_followers_query(user)
 353
 354     {:ok, Repo.all(q)}
 355   end
 356
 357   def get_friends_query(%User{id: id, following: following}) do
 358     from(
 359       u in User,
 360       where: u.follower_address in ^following,
 361       where: u.id != ^id
 362     )
 363   end
 364
 365   def get_friends(user) do
 366     q = get_friends_query(user)
 367
 368     {:ok, Repo.all(q)}
 369   end
 370
 371   def get_follow_requests_query(%User{} = user) do
 372     from(
 373       a in Activity,
 374       where:
 375         fragment(
 376           "? ->> 'type' = 'Follow'",
 377           a.data
 378         ),
 379       where:
 380         fragment(
 381           "? ->> 'state' = 'pending'",
 382           a.data
 383         ),
 384       where:
 385         fragment(
 386           "? @> ?",
 387           a.data,
 388           ^%{"object" => user.ap_id}
 389         )
 390     )
 391   end
 392
 393   def get_follow_requests(%User{} = user) do
 394     q = get_follow_requests_query(user)
 395     reqs = Repo.all(q)
 396
 397     users =
 398       Enum.map(reqs, fn req -> req.actor end)
 399       |> Enum.uniq()
 400       |> Enum.map(fn ap_id -> get_by_ap_id(ap_id) end)
 401
 402     {:ok, users}
 403   end
 404
 405   def increase_note_count(%User{} = user) do
 406     note_count = (user.info["note_count"] || 0) + 1
 407     new_info = Map.put(user.info, "note_count", note_count)
 408
 409     cs = info_changeset(user, %{info: new_info})
 410
 411     update_and_set_cache(cs)
 412   end
 413
 414   def decrease_note_count(%User{} = user) do
 415     note_count = user.info["note_count"] || 0
 416     note_count = if note_count <= 0, do: 0, else: note_count - 1
 417     new_info = Map.put(user.info, "note_count", note_count)
 418
 419     cs = info_changeset(user, %{info: new_info})
 420
 421     update_and_set_cache(cs)
 422   end
 423
 424   def update_note_count(%User{} = user) do
 425     note_count_query =
 426       from(
 427         a in Object,
 428         where: fragment("?->>'actor' = ? and ?->>'type' = 'Note'", a.data, ^user.ap_id, a.data),
 429         select: count(a.id)
 430       )
 431
 432     note_count = Repo.one(note_count_query)
 433
 434     new_info = Map.put(user.info, "note_count", note_count)
 435
 436     cs = info_changeset(user, %{info: new_info})
 437
 438     update_and_set_cache(cs)
 439   end
 440
 441   def update_follower_count(%User{} = user) do
 442     follower_count_query =
 443       from(
 444         u in User,
 445         where: ^user.follower_address in u.following,
 446         where: u.id != ^user.id,
 447         select: count(u.id)
 448       )
 449
 450     follower_count = Repo.one(follower_count_query)
 451
 452     new_info = Map.put(user.info, "follower_count", follower_count)
 453
 454     cs = info_changeset(user, %{info: new_info})
 455
 456     update_and_set_cache(cs)
 457   end
 458
 459   def get_notified_from_activity(%Activity{recipients: to}) do
 460     query =
 461       from(
 462         u in User,
 463         where: u.ap_id in ^to,
 464         where: u.local == true
 465       )
 466
 467     Repo.all(query)
 468   end
 469
 470   def get_recipients_from_activity(%Activity{recipients: to}) do
 471     query =
 472       from(
 473         u in User,
 474         where: u.ap_id in ^to,
 475         or_where: fragment("? && ?", u.following, ^to)
 476       )
 477
 478     query = from(u in query, where: u.local == true)
 479
 480     Repo.all(query)
 481   end
 482
 483   def search(query, resolve) do
 484     # strip the beginning @ off if there is a query
 485     query = String.trim_leading(query, "@")
 486
 487     if resolve do
 488       User.get_or_fetch_by_nickname(query)
 489     end
 490
 491     inner =
 492       from(
 493         u in User,
 494         select_merge: %{
 495           search_distance:
 496             fragment(
 497               "? <-> (? || ?)",
 498               ^query,
 499               u.nickname,
 500               u.name
 501             )
 502         }
 503       )
 504
 505     q =
 506       from(
 507         s in subquery(inner),
 508         order_by: s.search_distance,
 509         limit: 20
 510       )
 511
 512     Repo.all(q)
 513   end
 514
 515   def block(blocker, %User{ap_id: ap_id} = blocked) do
 516     # sever any follow relationships to prevent leaks per activitypub (Pleroma issue #213)
 517     blocker =
 518       if following?(blocker, blocked) do
 519         {:ok, blocker, _} = unfollow(blocker, blocked)
 520         blocker
 521       else
 522         blocker
 523       end
 524
 525     if following?(blocked, blocker) do
 526       unfollow(blocked, blocker)
 527     end
 528
 529     blocks = blocker.info["blocks"] || []
 530     new_blocks = Enum.uniq([ap_id | blocks])
 531     new_info = Map.put(blocker.info, "blocks", new_blocks)
 532
 533     cs = User.info_changeset(blocker, %{info: new_info})
 534     update_and_set_cache(cs)
 535   end
 536
 537   # helper to handle the block given only an actor's AP id
 538   def block(blocker, %{ap_id: ap_id}) do
 539     block(blocker, User.get_by_ap_id(ap_id))
 540   end
 541
 542   def unblock(user, %{ap_id: ap_id}) do
 543     blocks = user.info["blocks"] || []
 544     new_blocks = List.delete(blocks, ap_id)
 545     new_info = Map.put(user.info, "blocks", new_blocks)
 546
 547     cs = User.info_changeset(user, %{info: new_info})
 548     update_and_set_cache(cs)
 549   end
 550
 551   def blocks?(user, %{ap_id: ap_id}) do
 552     blocks = user.info["blocks"] || []
 553     domain_blocks = user.info["domain_blocks"] || []
 554     %{host: host} = URI.parse(ap_id)
 555
 556     Enum.member?(blocks, ap_id) ||
 557       Enum.any?(domain_blocks, fn domain ->
 558         host == domain
 559       end)
 560   end
 561
 562   def block_domain(user, domain) do
 563     domain_blocks = user.info["domain_blocks"] || []
 564     new_blocks = Enum.uniq([domain | domain_blocks])
 565     new_info = Map.put(user.info, "domain_blocks", new_blocks)
 566
 567     cs = User.info_changeset(user, %{info: new_info})
 568     update_and_set_cache(cs)
 569   end
 570
 571   def unblock_domain(user, domain) do
 572     blocks = user.info["domain_blocks"] || []
 573     new_blocks = List.delete(blocks, domain)
 574     new_info = Map.put(user.info, "domain_blocks", new_blocks)
 575
 576     cs = User.info_changeset(user, %{info: new_info})
 577     update_and_set_cache(cs)
 578   end
 579
 580   def local_user_query() do
 581     from(u in User, where: u.local == true)
 582   end
 583
 584   def deactivate(%User{} = user) do
 585     new_info = Map.put(user.info, "deactivated", true)
 586     cs = User.info_changeset(user, %{info: new_info})
 587     update_and_set_cache(cs)
 588   end
 589
 590   def delete(%User{} = user) do
 591     {:ok, user} = User.deactivate(user)
 592
 593     # Remove all relationships
 594     {:ok, followers} = User.get_followers(user)
 595
 596     followers
 597     |> Enum.each(fn follower -> User.unfollow(follower, user) end)
 598
 599     {:ok, friends} = User.get_friends(user)
 600
 601     friends
 602     |> Enum.each(fn followed -> User.unfollow(user, followed) end)
 603
 604     query = from(a in Activity, where: a.actor == ^user.ap_id)
 605
 606     Repo.all(query)
 607     |> Enum.each(fn activity ->
 608       case activity.data["type"] do
 609         "Create" ->
 610           ActivityPub.delete(Object.normalize(activity.data["object"]))
 611
 612         # TODO: Do something with likes, follows, repeats.
 613         _ ->
 614           "Doing nothing"
 615       end
 616     end)
 617
 618     :ok
 619   end
 620
 621   def get_or_fetch_by_ap_id(ap_id) do
 622     if user = get_by_ap_id(ap_id) do
 623       user
 624     else
 625       ap_try = ActivityPub.make_user_from_ap_id(ap_id)
 626
 627       case ap_try do
 628         {:ok, user} ->
 629           user
 630
 631         _ ->
 632           case OStatus.make_user(ap_id) do
 633             {:ok, user} -> user
 634             _ -> {:error, "Could not fetch by AP id"}
 635           end
 636       end
 637     end
 638   end
 639
 640   # AP style
 641   def public_key_from_info(%{
 642         "source_data" => %{"publicKey" => %{"publicKeyPem" => public_key_pem}}
 643       }) do
 644     key =
 645       :public_key.pem_decode(public_key_pem)
 646       |> hd()
 647       |> :public_key.pem_entry_decode()
 648
 649     {:ok, key}
 650   end
 651
 652   # OStatus Magic Key
 653   def public_key_from_info(%{"magic_key" => magic_key}) do
 654     {:ok, Pleroma.Web.Salmon.decode_key(magic_key)}
 655   end
 656
 657   def get_public_key_for_ap_id(ap_id) do
 658     with %User{} = user <- get_or_fetch_by_ap_id(ap_id),
 659          {:ok, public_key} <- public_key_from_info(user.info) do
 660       {:ok, public_key}
 661     else
 662       _ -> :error
 663     end
 664   end
 665
 666   defp blank?(""), do: nil
 667   defp blank?(n), do: n
 668
 669   def insert_or_update_user(data) do
 670     data =
 671       data
 672       |> Map.put(:name, blank?(data[:name]) || data[:nickname])
 673
 674     cs = User.remote_user_creation(data)
 675     Repo.insert(cs, on_conflict: :replace_all, conflict_target: :nickname)
 676   end
 677
 678   def ap_enabled?(%User{info: info}), do: info["ap_enabled"]
 679   def ap_enabled?(_), do: false
 680
 681   def get_or_fetch(uri_or_nickname) do
 682     if String.starts_with?(uri_or_nickname, "http") do
 683       get_or_fetch_by_ap_id(uri_or_nickname)
 684     else
 685       get_or_fetch_by_nickname(uri_or_nickname)
 686     end
 687   end
 688 end