git.squeep.com Git - akkoma/blob - lib/pleroma/user.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.User do
   6   use Ecto.Schema
   7
   8   import Ecto.{Changeset, Query}
   9   alias Pleroma.{Repo, User, Object, Web, Activity, Notification}
  10   alias Comeonin.Pbkdf2
  11   alias Pleroma.Formatter
  12   alias Pleroma.Web.CommonAPI.Utils, as: CommonUtils
  13   alias Pleroma.Web.{OStatus, Websub, OAuth}
  14   alias Pleroma.Web.ActivityPub.{Utils, ActivityPub}
  15
  16   require Logger
  17
  18   @type t :: %__MODULE__{}
  19
  20   @primary_key {:id, Pleroma.FlakeId, autogenerate: true}
  21
  22   @email_regex ~r/^[a-zA-Z0-9.!#$%&'*+\/=?^_`{|}~-]+@[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?(?:\.[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?)*$/
  23
  24   @strict_local_nickname_regex ~r/^[a-zA-Z\d]+$/
  25   @extended_local_nickname_regex ~r/^[a-zA-Z\d_-]+$/
  26
  27   schema "users" do
  28     field(:bio, :string)
  29     field(:email, :string)
  30     field(:name, :string)
  31     field(:nickname, :string)
  32     field(:password_hash, :string)
  33     field(:password, :string, virtual: true)
  34     field(:password_confirmation, :string, virtual: true)
  35     field(:following, {:array, :string}, default: [])
  36     field(:ap_id, :string)
  37     field(:avatar, :map)
  38     field(:local, :boolean, default: true)
  39     field(:follower_address, :string)
  40     field(:search_rank, :float, virtual: true)
  41     field(:tags, {:array, :string}, default: [])
  42     field(:last_refreshed_at, :naive_datetime)
  43     has_many(:notifications, Notification)
  44     embeds_one(:info, Pleroma.User.Info)
  45
  46     timestamps()
  47   end
  48
  49   def auth_active?(%User{local: false}), do: true
  50
  51   def auth_active?(%User{info: %User.Info{confirmation_pending: false}}), do: true
  52
  53   def auth_active?(%User{info: %User.Info{confirmation_pending: true}}),
  54     do: !Pleroma.Config.get([:instance, :account_activation_required])
  55
  56   def auth_active?(_), do: false
  57
  58   def visible_for?(user, for_user \\ nil)
  59
  60   def visible_for?(%User{id: user_id}, %User{id: for_id}) when user_id == for_id, do: true
  61
  62   def visible_for?(%User{} = user, for_user) do
  63     auth_active?(user) || superuser?(for_user)
  64   end
  65
  66   def visible_for?(_, _), do: false
  67
  68   def superuser?(%User{local: true, info: %User.Info{is_admin: true}}), do: true
  69   def superuser?(%User{local: true, info: %User.Info{is_moderator: true}}), do: true
  70   def superuser?(_), do: false
  71
  72   def avatar_url(user) do
  73     case user.avatar do
  74       %{"url" => [%{"href" => href} | _]} -> href
  75       _ -> "#{Web.base_url()}/images/avi.png"
  76     end
  77   end
  78
  79   def banner_url(user) do
  80     case user.info.banner do
  81       %{"url" => [%{"href" => href} | _]} -> href
  82       _ -> "#{Web.base_url()}/images/banner.png"
  83     end
  84   end
  85
  86   def profile_url(%User{info: %{source_data: %{"url" => url}}}), do: url
  87   def profile_url(%User{ap_id: ap_id}), do: ap_id
  88   def profile_url(_), do: nil
  89
  90   def ap_id(%User{nickname: nickname}) do
  91     "#{Web.base_url()}/users/#{nickname}"
  92   end
  93
  94   def ap_followers(%User{} = user) do
  95     "#{ap_id(user)}/followers"
  96   end
  97
  98   def follow_changeset(struct, params \\ %{}) do
  99     struct
 100     |> cast(params, [:following])
 101     |> validate_required([:following])
 102   end
 103
 104   def user_info(%User{} = user) do
 105     oneself = if user.local, do: 1, else: 0
 106
 107     %{
 108       following_count: length(user.following) - oneself,
 109       note_count: user.info.note_count,
 110       follower_count: user.info.follower_count,
 111       locked: user.info.locked,
 112       confirmation_pending: user.info.confirmation_pending,
 113       default_scope: user.info.default_scope
 114     }
 115   end
 116
 117   def remote_user_creation(params) do
 118     params =
 119       params
 120       |> Map.put(:info, params[:info] || %{})
 121
 122     info_cng = User.Info.remote_user_creation(%User.Info{}, params[:info])
 123
 124     changes =
 125       %User{}
 126       |> cast(params, [:bio, :name, :ap_id, :nickname, :avatar])
 127       |> validate_required([:name, :ap_id])
 128       |> unique_constraint(:nickname)
 129       |> validate_format(:nickname, @email_regex)
 130       |> validate_length(:bio, max: 5000)
 131       |> validate_length(:name, max: 100)
 132       |> put_change(:local, false)
 133       |> put_embed(:info, info_cng)
 134
 135     if changes.valid? do
 136       case info_cng.changes[:source_data] do
 137         %{"followers" => followers} ->
 138           changes
 139           |> put_change(:follower_address, followers)
 140
 141         _ ->
 142           followers = User.ap_followers(%User{nickname: changes.changes[:nickname]})
 143
 144           changes
 145           |> put_change(:follower_address, followers)
 146       end
 147     else
 148       changes
 149     end
 150   end
 151
 152   def update_changeset(struct, params \\ %{}) do
 153     struct
 154     |> cast(params, [:bio, :name, :avatar])
 155     |> unique_constraint(:nickname)
 156     |> validate_format(:nickname, local_nickname_regex())
 157     |> validate_length(:bio, max: 5000)
 158     |> validate_length(:name, min: 1, max: 100)
 159   end
 160
 161   def upgrade_changeset(struct, params \\ %{}) do
 162     params =
 163       params
 164       |> Map.put(:last_refreshed_at, NaiveDateTime.utc_now())
 165
 166     info_cng =
 167       struct.info
 168       |> User.Info.user_upgrade(params[:info])
 169
 170     struct
 171     |> cast(params, [:bio, :name, :follower_address, :avatar, :last_refreshed_at])
 172     |> unique_constraint(:nickname)
 173     |> validate_format(:nickname, local_nickname_regex())
 174     |> validate_length(:bio, max: 5000)
 175     |> validate_length(:name, max: 100)
 176     |> put_embed(:info, info_cng)
 177   end
 178
 179   def password_update_changeset(struct, params) do
 180     changeset =
 181       struct
 182       |> cast(params, [:password, :password_confirmation])
 183       |> validate_required([:password, :password_confirmation])
 184       |> validate_confirmation(:password)
 185
 186     OAuth.Token.delete_user_tokens(struct)
 187     OAuth.Authorization.delete_user_authorizations(struct)
 188
 189     if changeset.valid? do
 190       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 191
 192       changeset
 193       |> put_change(:password_hash, hashed)
 194     else
 195       changeset
 196     end
 197   end
 198
 199   def reset_password(user, data) do
 200     update_and_set_cache(password_update_changeset(user, data))
 201   end
 202
 203   def register_changeset(struct, params \\ %{}, opts \\ []) do
 204     confirmation_status =
 205       if opts[:confirmed] || !Pleroma.Config.get([:instance, :account_activation_required]) do
 206         :confirmed
 207       else
 208         :unconfirmed
 209       end
 210
 211     info_change = User.Info.confirmation_changeset(%User.Info{}, confirmation_status)
 212
 213     changeset =
 214       struct
 215       |> cast(params, [:bio, :email, :name, :nickname, :password, :password_confirmation])
 216       |> validate_required([:email, :name, :nickname, :password, :password_confirmation])
 217       |> validate_confirmation(:password)
 218       |> unique_constraint(:email)
 219       |> unique_constraint(:nickname)
 220       |> validate_exclusion(:nickname, Pleroma.Config.get([Pleroma.User, :restricted_nicknames]))
 221       |> validate_format(:nickname, local_nickname_regex())
 222       |> validate_format(:email, @email_regex)
 223       |> validate_length(:bio, max: 1000)
 224       |> validate_length(:name, min: 1, max: 100)
 225       |> put_change(:info, info_change)
 226
 227     if changeset.valid? do
 228       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 229       ap_id = User.ap_id(%User{nickname: changeset.changes[:nickname]})
 230       followers = User.ap_followers(%User{nickname: changeset.changes[:nickname]})
 231
 232       changeset
 233       |> put_change(:password_hash, hashed)
 234       |> put_change(:ap_id, ap_id)
 235       |> put_change(:following, [followers])
 236       |> put_change(:follower_address, followers)
 237     else
 238       changeset
 239     end
 240   end
 241
 242   defp autofollow_users(user) do
 243     candidates = Pleroma.Config.get([:instance, :autofollowed_nicknames])
 244
 245     autofollowed_users =
 246       from(u in User,
 247         where: u.local == true,
 248         where: u.nickname in ^candidates
 249       )
 250       |> Repo.all()
 251
 252     follow_all(user, autofollowed_users)
 253   end
 254
 255   @doc "Inserts provided changeset, performs post-registration actions (confirmation email sending etc.)"
 256   def register(%Ecto.Changeset{} = changeset) do
 257     with {:ok, user} <- Repo.insert(changeset),
 258          {:ok, _} <- try_send_confirmation_email(user),
 259          {:ok, user} <- autofollow_users(user) do
 260       {:ok, user}
 261     end
 262   end
 263
 264   def try_send_confirmation_email(%User{} = user) do
 265     if user.info.confirmation_pending &&
 266          Pleroma.Config.get([:instance, :account_activation_required]) do
 267       user
 268       |> Pleroma.UserEmail.account_confirmation_email()
 269       |> Pleroma.Mailer.deliver()
 270     else
 271       {:ok, :noop}
 272     end
 273   end
 274
 275   def needs_update?(%User{local: true}), do: false
 276
 277   def needs_update?(%User{local: false, last_refreshed_at: nil}), do: true
 278
 279   def needs_update?(%User{local: false} = user) do
 280     NaiveDateTime.diff(NaiveDateTime.utc_now(), user.last_refreshed_at) >= 86400
 281   end
 282
 283   def needs_update?(_), do: true
 284
 285   def maybe_direct_follow(%User{} = follower, %User{local: true, info: %{locked: true}}) do
 286     {:ok, follower}
 287   end
 288
 289   def maybe_direct_follow(%User{} = follower, %User{local: true} = followed) do
 290     follow(follower, followed)
 291   end
 292
 293   def maybe_direct_follow(%User{} = follower, %User{} = followed) do
 294     if not User.ap_enabled?(followed) do
 295       follow(follower, followed)
 296     else
 297       {:ok, follower}
 298     end
 299   end
 300
 301   def maybe_follow(%User{} = follower, %User{info: _info} = followed) do
 302     if not following?(follower, followed) do
 303       follow(follower, followed)
 304     else
 305       {:ok, follower}
 306     end
 307   end
 308
 309   @doc "A mass follow for local users. Ignores blocks and has no side effects"
 310   @spec follow_all(User.t(), list(User.t())) :: {atom(), User.t()}
 311   def follow_all(follower, followeds) do
 312     following =
 313       (follower.following ++ Enum.map(followeds, fn %{follower_address: fa} -> fa end))
 314       |> Enum.uniq()
 315
 316     {:ok, follower} =
 317       follower
 318       |> follow_changeset(%{following: following})
 319       |> update_and_set_cache
 320
 321     Enum.each(followeds, fn followed ->
 322       update_follower_count(followed)
 323     end)
 324
 325     {:ok, follower}
 326   end
 327
 328   def follow(%User{} = follower, %User{info: info} = followed) do
 329     user_config = Application.get_env(:pleroma, :user)
 330     deny_follow_blocked = Keyword.get(user_config, :deny_follow_blocked)
 331
 332     ap_followers = followed.follower_address
 333
 334     cond do
 335       following?(follower, followed) or info.deactivated ->
 336         {:error, "Could not follow user: #{followed.nickname} is already on your list."}
 337
 338       deny_follow_blocked and blocks?(followed, follower) ->
 339         {:error, "Could not follow user: #{followed.nickname} blocked you."}
 340
 341       true ->
 342         if !followed.local && follower.local && !ap_enabled?(followed) do
 343           Websub.subscribe(follower, followed)
 344         end
 345
 346         following =
 347           [ap_followers | follower.following]
 348           |> Enum.uniq()
 349
 350         follower =
 351           follower
 352           |> follow_changeset(%{following: following})
 353           |> update_and_set_cache
 354
 355         {:ok, _} = update_follower_count(followed)
 356
 357         follower
 358     end
 359   end
 360
 361   def unfollow(%User{} = follower, %User{} = followed) do
 362     ap_followers = followed.follower_address
 363
 364     if following?(follower, followed) and follower.ap_id != followed.ap_id do
 365       following =
 366         follower.following
 367         |> List.delete(ap_followers)
 368
 369       {:ok, follower} =
 370         follower
 371         |> follow_changeset(%{following: following})
 372         |> update_and_set_cache
 373
 374       {:ok, followed} = update_follower_count(followed)
 375
 376       {:ok, follower, Utils.fetch_latest_follow(follower, followed)}
 377     else
 378       {:error, "Not subscribed!"}
 379     end
 380   end
 381
 382   @spec following?(User.t(), User.t()) :: boolean
 383   def following?(%User{} = follower, %User{} = followed) do
 384     Enum.member?(follower.following, followed.follower_address)
 385   end
 386
 387   def follow_import(%User{} = follower, followed_identifiers)
 388       when is_list(followed_identifiers) do
 389     Enum.map(
 390       followed_identifiers,
 391       fn followed_identifier ->
 392         with %User{} = followed <- get_or_fetch(followed_identifier),
 393              {:ok, follower} <- maybe_direct_follow(follower, followed),
 394              {:ok, _} <- ActivityPub.follow(follower, followed) do
 395           followed
 396         else
 397           err ->
 398             Logger.debug("follow_import failed for #{followed_identifier} with: #{inspect(err)}")
 399             err
 400         end
 401       end
 402     )
 403   end
 404
 405   def locked?(%User{} = user) do
 406     user.info.locked || false
 407   end
 408
 409   def get_by_id(id) do
 410     Repo.get_by(User, id: id)
 411   end
 412
 413   def get_by_ap_id(ap_id) do
 414     Repo.get_by(User, ap_id: ap_id)
 415   end
 416
 417   # This is mostly an SPC migration fix. This guesses the user nickname (by taking the last part of the ap_id and the domain) and tries to get that user
 418   def get_by_guessed_nickname(ap_id) do
 419     domain = URI.parse(ap_id).host
 420     name = List.last(String.split(ap_id, "/"))
 421     nickname = "#{name}@#{domain}"
 422
 423     get_by_nickname(nickname)
 424   end
 425
 426   def update_and_set_cache(changeset) do
 427     with {:ok, user} <- Repo.update(changeset) do
 428       Cachex.put(:user_cache, "ap_id:#{user.ap_id}", user)
 429       Cachex.put(:user_cache, "nickname:#{user.nickname}", user)
 430       Cachex.put(:user_cache, "user_info:#{user.id}", user_info(user))
 431       {:ok, user}
 432     else
 433       e -> e
 434     end
 435   end
 436
 437   def invalidate_cache(user) do
 438     Cachex.del(:user_cache, "ap_id:#{user.ap_id}")
 439     Cachex.del(:user_cache, "nickname:#{user.nickname}")
 440     Cachex.del(:user_cache, "user_info:#{user.id}")
 441   end
 442
 443   def get_cached_by_ap_id(ap_id) do
 444     key = "ap_id:#{ap_id}"
 445     Cachex.fetch!(:user_cache, key, fn _ -> get_by_ap_id(ap_id) end)
 446   end
 447
 448   def get_cached_by_id(id) do
 449     key = "id:#{id}"
 450
 451     ap_id =
 452       Cachex.fetch!(:user_cache, key, fn _ ->
 453         user = get_by_id(id)
 454
 455         if user do
 456           Cachex.put(:user_cache, "ap_id:#{user.ap_id}", user)
 457           {:commit, user.ap_id}
 458         else
 459           {:ignore, ""}
 460         end
 461       end)
 462
 463     get_cached_by_ap_id(ap_id)
 464   end
 465
 466   def get_cached_by_nickname(nickname) do
 467     key = "nickname:#{nickname}"
 468     Cachex.fetch!(:user_cache, key, fn _ -> get_or_fetch_by_nickname(nickname) end)
 469   end
 470
 471   def get_cached_by_nickname_or_id(nickname_or_id) do
 472     get_cached_by_id(nickname_or_id) || get_cached_by_nickname(nickname_or_id)
 473   end
 474
 475   def get_by_nickname(nickname) do
 476     Repo.get_by(User, nickname: nickname) ||
 477       if Regex.match?(~r(@#{Pleroma.Web.Endpoint.host()})i, nickname) do
 478         Repo.get_by(User, nickname: local_nickname(nickname))
 479       end
 480   end
 481
 482   def get_by_nickname_or_email(nickname_or_email) do
 483     case user = Repo.get_by(User, nickname: nickname_or_email) do
 484       %User{} -> user
 485       nil -> Repo.get_by(User, email: nickname_or_email)
 486     end
 487   end
 488
 489   def get_cached_user_info(user) do
 490     key = "user_info:#{user.id}"
 491     Cachex.fetch!(:user_cache, key, fn _ -> user_info(user) end)
 492   end
 493
 494   def fetch_by_nickname(nickname) do
 495     ap_try = ActivityPub.make_user_from_nickname(nickname)
 496
 497     case ap_try do
 498       {:ok, user} -> {:ok, user}
 499       _ -> OStatus.make_user(nickname)
 500     end
 501   end
 502
 503   def get_or_fetch_by_nickname(nickname) do
 504     with %User{} = user <- get_by_nickname(nickname) do
 505       user
 506     else
 507       _e ->
 508         with [_nick, _domain] <- String.split(nickname, "@"),
 509              {:ok, user} <- fetch_by_nickname(nickname) do
 510           user
 511         else
 512           _e -> nil
 513         end
 514     end
 515   end
 516
 517   def get_followers_query(%User{id: id, follower_address: follower_address}, nil) do
 518     from(
 519       u in User,
 520       where: fragment("? <@ ?", ^[follower_address], u.following),
 521       where: u.id != ^id
 522     )
 523   end
 524
 525   def get_followers_query(user, page) do
 526     from(
 527       u in get_followers_query(user, nil),
 528       limit: 20,
 529       offset: ^((page - 1) * 20)
 530     )
 531   end
 532
 533   def get_followers_query(user), do: get_followers_query(user, nil)
 534
 535   def get_followers(user, page \\ nil) do
 536     q = get_followers_query(user, page)
 537
 538     {:ok, Repo.all(q)}
 539   end
 540
 541   def get_followers_ids(user, page \\ nil) do
 542     q = get_followers_query(user, page)
 543
 544     Repo.all(from(u in q, select: u.id))
 545   end
 546
 547   def get_friends_query(%User{id: id, following: following}, nil) do
 548     from(
 549       u in User,
 550       where: u.follower_address in ^following,
 551       where: u.id != ^id
 552     )
 553   end
 554
 555   def get_friends_query(user, page) do
 556     from(
 557       u in get_friends_query(user, nil),
 558       limit: 20,
 559       offset: ^((page - 1) * 20)
 560     )
 561   end
 562
 563   def get_friends_query(user), do: get_friends_query(user, nil)
 564
 565   def get_friends(user, page \\ nil) do
 566     q = get_friends_query(user, page)
 567
 568     {:ok, Repo.all(q)}
 569   end
 570
 571   def get_friends_ids(user, page \\ nil) do
 572     q = get_friends_query(user, page)
 573
 574     Repo.all(from(u in q, select: u.id))
 575   end
 576
 577   def get_follow_requests_query(%User{} = user) do
 578     from(
 579       a in Activity,
 580       where:
 581         fragment(
 582           "? ->> 'type' = 'Follow'",
 583           a.data
 584         ),
 585       where:
 586         fragment(
 587           "? ->> 'state' = 'pending'",
 588           a.data
 589         ),
 590       where:
 591         fragment(
 592           "? @> ?",
 593           a.data,
 594           ^%{"object" => user.ap_id}
 595         )
 596     )
 597   end
 598
 599   def get_follow_requests(%User{} = user) do
 600     q = get_follow_requests_query(user)
 601     reqs = Repo.all(q)
 602
 603     users =
 604       Enum.map(reqs, fn req -> req.actor end)
 605       |> Enum.uniq()
 606       |> Enum.map(fn ap_id -> get_by_ap_id(ap_id) end)
 607       |> Enum.filter(fn u -> !is_nil(u) end)
 608       |> Enum.filter(fn u -> !following?(u, user) end)
 609
 610     {:ok, users}
 611   end
 612
 613   def increase_note_count(%User{} = user) do
 614     info_cng = User.Info.add_to_note_count(user.info, 1)
 615
 616     cng =
 617       change(user)
 618       |> put_embed(:info, info_cng)
 619
 620     update_and_set_cache(cng)
 621   end
 622
 623   def decrease_note_count(%User{} = user) do
 624     info_cng = User.Info.add_to_note_count(user.info, -1)
 625
 626     cng =
 627       change(user)
 628       |> put_embed(:info, info_cng)
 629
 630     update_and_set_cache(cng)
 631   end
 632
 633   def update_note_count(%User{} = user) do
 634     note_count_query =
 635       from(
 636         a in Object,
 637         where: fragment("?->>'actor' = ? and ?->>'type' = 'Note'", a.data, ^user.ap_id, a.data),
 638         select: count(a.id)
 639       )
 640
 641     note_count = Repo.one(note_count_query)
 642
 643     info_cng = User.Info.set_note_count(user.info, note_count)
 644
 645     cng =
 646       change(user)
 647       |> put_embed(:info, info_cng)
 648
 649     update_and_set_cache(cng)
 650   end
 651
 652   def update_follower_count(%User{} = user) do
 653     follower_count_query =
 654       from(
 655         u in User,
 656         where: ^user.follower_address in u.following,
 657         where: u.id != ^user.id,
 658         select: count(u.id)
 659       )
 660
 661     follower_count = Repo.one(follower_count_query)
 662
 663     info_cng =
 664       user.info
 665       |> User.Info.set_follower_count(follower_count)
 666
 667     cng =
 668       change(user)
 669       |> put_embed(:info, info_cng)
 670
 671     update_and_set_cache(cng)
 672   end
 673
 674   def get_users_from_set_query(ap_ids, false) do
 675     from(
 676       u in User,
 677       where: u.ap_id in ^ap_ids
 678     )
 679   end
 680
 681   def get_users_from_set_query(ap_ids, true) do
 682     query = get_users_from_set_query(ap_ids, false)
 683
 684     from(
 685       u in query,
 686       where: u.local == true
 687     )
 688   end
 689
 690   def get_users_from_set(ap_ids, local_only \\ true) do
 691     get_users_from_set_query(ap_ids, local_only)
 692     |> Repo.all()
 693   end
 694
 695   def get_recipients_from_activity(%Activity{recipients: to}) do
 696     query =
 697       from(
 698         u in User,
 699         where: u.ap_id in ^to,
 700         or_where: fragment("? && ?", u.following, ^to)
 701       )
 702
 703     query = from(u in query, where: u.local == true)
 704
 705     Repo.all(query)
 706   end
 707
 708   def search(query, resolve \\ false, for_user \\ nil) do
 709     # Strip the beginning @ off if there is a query
 710     query = String.trim_leading(query, "@")
 711
 712     if resolve, do: User.get_or_fetch_by_nickname(query)
 713
 714     fts_results = do_search(fts_search_subquery(query), for_user)
 715
 716     {:ok, trigram_results} =
 717       Repo.transaction(fn ->
 718         Ecto.Adapters.SQL.query(Repo, "select set_limit(0.25)", [])
 719         do_search(trigram_search_subquery(query), for_user)
 720       end)
 721
 722     Enum.uniq_by(fts_results ++ trigram_results, & &1.id)
 723   end
 724
 725   defp do_search(subquery, for_user, options \\ []) do
 726     q =
 727       from(
 728         s in subquery(subquery),
 729         order_by: [desc: s.search_rank],
 730         limit: ^(options[:limit] || 20)
 731       )
 732
 733     results =
 734       q
 735       |> Repo.all()
 736       |> Enum.filter(&(&1.search_rank > 0))
 737
 738     boost_search_results(results, for_user)
 739   end
 740
 741   defp fts_search_subquery(query) do
 742     processed_query =
 743       query
 744       |> String.replace(~r/\W+/, " ")
 745       |> String.trim()
 746       |> String.split()
 747       |> Enum.map(&(&1 <> ":*"))
 748       |> Enum.join(" | ")
 749
 750     from(
 751       u in User,
 752       select_merge: %{
 753         search_rank:
 754           fragment(
 755             """
 756             ts_rank_cd(
 757               setweight(to_tsvector('simple', regexp_replace(?, '\\W', ' ', 'g')), 'A') ||
 758               setweight(to_tsvector('simple', regexp_replace(coalesce(?, ''), '\\W', ' ', 'g')), 'B'),
 759               to_tsquery('simple', ?),
 760               32
 761             )
 762             """,
 763             u.nickname,
 764             u.name,
 765             ^processed_query
 766           )
 767       },
 768       where:
 769         fragment(
 770           """
 771             (setweight(to_tsvector('simple', regexp_replace(?, '\\W', ' ', 'g')), 'A') ||
 772             setweight(to_tsvector('simple', regexp_replace(coalesce(?, ''), '\\W', ' ', 'g')), 'B')) @@ to_tsquery('simple', ?)
 773           """,
 774           u.nickname,
 775           u.name,
 776           ^processed_query
 777         )
 778     )
 779   end
 780
 781   defp trigram_search_subquery(query) do
 782     from(
 783       u in User,
 784       select_merge: %{
 785         search_rank:
 786           fragment(
 787             "similarity(?, trim(? || ' ' || coalesce(?, '')))",
 788             ^query,
 789             u.nickname,
 790             u.name
 791           )
 792       },
 793       where: fragment("trim(? || ' ' || coalesce(?, '')) % ?", u.nickname, u.name, ^query)
 794     )
 795   end
 796
 797   defp boost_search_results(results, nil), do: results
 798
 799   defp boost_search_results(results, for_user) do
 800     friends_ids = get_friends_ids(for_user)
 801     followers_ids = get_followers_ids(for_user)
 802
 803     Enum.map(
 804       results,
 805       fn u ->
 806         search_rank_coef =
 807           cond do
 808             u.id in friends_ids ->
 809               1.2
 810
 811             u.id in followers_ids ->
 812               1.1
 813
 814             true ->
 815               1
 816           end
 817
 818         Map.put(u, :search_rank, u.search_rank * search_rank_coef)
 819       end
 820     )
 821     |> Enum.sort_by(&(-&1.search_rank))
 822   end
 823
 824   def blocks_import(%User{} = blocker, blocked_identifiers) when is_list(blocked_identifiers) do
 825     Enum.map(
 826       blocked_identifiers,
 827       fn blocked_identifier ->
 828         with %User{} = blocked <- get_or_fetch(blocked_identifier),
 829              {:ok, blocker} <- block(blocker, blocked),
 830              {:ok, _} <- ActivityPub.block(blocker, blocked) do
 831           blocked
 832         else
 833           err ->
 834             Logger.debug("blocks_import failed for #{blocked_identifier} with: #{inspect(err)}")
 835             err
 836         end
 837       end
 838     )
 839   end
 840
 841   def block(blocker, %User{ap_id: ap_id} = blocked) do
 842     # sever any follow relationships to prevent leaks per activitypub (Pleroma issue #213)
 843     blocker =
 844       if following?(blocker, blocked) do
 845         {:ok, blocker, _} = unfollow(blocker, blocked)
 846         blocker
 847       else
 848         blocker
 849       end
 850
 851     if following?(blocked, blocker) do
 852       unfollow(blocked, blocker)
 853     end
 854
 855     info_cng =
 856       blocker.info
 857       |> User.Info.add_to_block(ap_id)
 858
 859     cng =
 860       change(blocker)
 861       |> put_embed(:info, info_cng)
 862
 863     update_and_set_cache(cng)
 864   end
 865
 866   # helper to handle the block given only an actor's AP id
 867   def block(blocker, %{ap_id: ap_id}) do
 868     block(blocker, User.get_by_ap_id(ap_id))
 869   end
 870
 871   def unblock(blocker, %{ap_id: ap_id}) do
 872     info_cng =
 873       blocker.info
 874       |> User.Info.remove_from_block(ap_id)
 875
 876     cng =
 877       change(blocker)
 878       |> put_embed(:info, info_cng)
 879
 880     update_and_set_cache(cng)
 881   end
 882
 883   def blocks?(user, %{ap_id: ap_id}) do
 884     blocks = user.info.blocks
 885     domain_blocks = user.info.domain_blocks
 886     %{host: host} = URI.parse(ap_id)
 887
 888     Enum.member?(blocks, ap_id) ||
 889       Enum.any?(domain_blocks, fn domain ->
 890         host == domain
 891       end)
 892   end
 893
 894   def blocked_users(user),
 895     do: Repo.all(from(u in User, where: u.ap_id in ^user.info.blocks))
 896
 897   def block_domain(user, domain) do
 898     info_cng =
 899       user.info
 900       |> User.Info.add_to_domain_block(domain)
 901
 902     cng =
 903       change(user)
 904       |> put_embed(:info, info_cng)
 905
 906     update_and_set_cache(cng)
 907   end
 908
 909   def unblock_domain(user, domain) do
 910     info_cng =
 911       user.info
 912       |> User.Info.remove_from_domain_block(domain)
 913
 914     cng =
 915       change(user)
 916       |> put_embed(:info, info_cng)
 917
 918     update_and_set_cache(cng)
 919   end
 920
 921   def local_user_query do
 922     from(
 923       u in User,
 924       where: u.local == true,
 925       where: not is_nil(u.nickname)
 926     )
 927   end
 928
 929   def active_local_user_query do
 930     from(
 931       u in local_user_query(),
 932       where: fragment("not (?->'deactivated' @> 'true')", u.info)
 933     )
 934   end
 935
 936   def moderator_user_query do
 937     from(
 938       u in User,
 939       where: u.local == true,
 940       where: fragment("?->'is_moderator' @> 'true'", u.info)
 941     )
 942   end
 943
 944   def deactivate(%User{} = user, status \\ true) do
 945     info_cng = User.Info.set_activation_status(user.info, status)
 946
 947     cng =
 948       change(user)
 949       |> put_embed(:info, info_cng)
 950
 951     update_and_set_cache(cng)
 952   end
 953
 954   def delete(%User{} = user) do
 955     {:ok, user} = User.deactivate(user)
 956
 957     # Remove all relationships
 958     {:ok, followers} = User.get_followers(user)
 959
 960     followers
 961     |> Enum.each(fn follower -> User.unfollow(follower, user) end)
 962
 963     {:ok, friends} = User.get_friends(user)
 964
 965     friends
 966     |> Enum.each(fn followed -> User.unfollow(user, followed) end)
 967
 968     query = from(a in Activity, where: a.actor == ^user.ap_id)
 969
 970     Repo.all(query)
 971     |> Enum.each(fn activity ->
 972       case activity.data["type"] do
 973         "Create" ->
 974           ActivityPub.delete(Object.normalize(activity.data["object"]))
 975
 976         # TODO: Do something with likes, follows, repeats.
 977         _ ->
 978           "Doing nothing"
 979       end
 980     end)
 981
 982     {:ok, user}
 983   end
 984
 985   def html_filter_policy(%User{info: %{no_rich_text: true}}) do
 986     Pleroma.HTML.Scrubber.TwitterText
 987   end
 988
 989   @default_scrubbers Pleroma.Config.get([:markup, :scrub_policy])
 990
 991   def html_filter_policy(_), do: @default_scrubbers
 992
 993   def get_or_fetch_by_ap_id(ap_id) do
 994     user = get_by_ap_id(ap_id)
 995
 996     if !is_nil(user) and !User.needs_update?(user) do
 997       user
 998     else
 999       ap_try = ActivityPub.make_user_from_ap_id(ap_id)
1000
1001       case ap_try do
1002         {:ok, user} ->
1003           user
1004
1005         _ ->
1006           case OStatus.make_user(ap_id) do
1007             {:ok, user} -> user
1008             _ -> {:error, "Could not fetch by AP id"}
1009           end
1010       end
1011     end
1012   end
1013
1014   def get_or_create_instance_user do
1015     relay_uri = "#{Pleroma.Web.Endpoint.url()}/relay"
1016
1017     if user = get_by_ap_id(relay_uri) do
1018       user
1019     else
1020       changes =
1021         %User{info: %User.Info{}}
1022         |> cast(%{}, [:ap_id, :nickname, :local])
1023         |> put_change(:ap_id, relay_uri)
1024         |> put_change(:nickname, nil)
1025         |> put_change(:local, true)
1026         |> put_change(:follower_address, relay_uri <> "/followers")
1027
1028       {:ok, user} = Repo.insert(changes)
1029       user
1030     end
1031   end
1032
1033   # AP style
1034   def public_key_from_info(%{
1035         source_data: %{"publicKey" => %{"publicKeyPem" => public_key_pem}}
1036       }) do
1037     key =
1038       public_key_pem
1039       |> :public_key.pem_decode()
1040       |> hd()
1041       |> :public_key.pem_entry_decode()
1042
1043     {:ok, key}
1044   end
1045
1046   # OStatus Magic Key
1047   def public_key_from_info(%{magic_key: magic_key}) do
1048     {:ok, Pleroma.Web.Salmon.decode_key(magic_key)}
1049   end
1050
1051   def get_public_key_for_ap_id(ap_id) do
1052     with %User{} = user <- get_or_fetch_by_ap_id(ap_id),
1053          {:ok, public_key} <- public_key_from_info(user.info) do
1054       {:ok, public_key}
1055     else
1056       _ -> :error
1057     end
1058   end
1059
1060   defp blank?(""), do: nil
1061   defp blank?(n), do: n
1062
1063   def insert_or_update_user(data) do
1064     data =
1065       data
1066       |> Map.put(:name, blank?(data[:name]) || data[:nickname])
1067
1068     cs = User.remote_user_creation(data)
1069
1070     Repo.insert(cs, on_conflict: :replace_all, conflict_target: :nickname)
1071   end
1072
1073   def ap_enabled?(%User{local: true}), do: true
1074   def ap_enabled?(%User{info: info}), do: info.ap_enabled
1075   def ap_enabled?(_), do: false
1076
1077   @doc "Gets or fetch a user by uri or nickname."
1078   @spec get_or_fetch(String.t()) :: User.t()
1079   def get_or_fetch("http" <> _host = uri), do: get_or_fetch_by_ap_id(uri)
1080   def get_or_fetch(nickname), do: get_or_fetch_by_nickname(nickname)
1081
1082   # wait a period of time and return newest version of the User structs
1083   # this is because we have synchronous follow APIs and need to simulate them
1084   # with an async handshake
1085   def wait_and_refresh(_, %User{local: true} = a, %User{local: true} = b) do
1086     with %User{} = a <- Repo.get(User, a.id),
1087          %User{} = b <- Repo.get(User, b.id) do
1088       {:ok, a, b}
1089     else
1090       _e ->
1091         :error
1092     end
1093   end
1094
1095   def wait_and_refresh(timeout, %User{} = a, %User{} = b) do
1096     with :ok <- :timer.sleep(timeout),
1097          %User{} = a <- Repo.get(User, a.id),
1098          %User{} = b <- Repo.get(User, b.id) do
1099       {:ok, a, b}
1100     else
1101       _e ->
1102         :error
1103     end
1104   end
1105
1106   def parse_bio(bio, user \\ %User{info: %{source_data: %{}}})
1107   def parse_bio(nil, _user), do: ""
1108   def parse_bio(bio, _user) when bio == "", do: bio
1109
1110   def parse_bio(bio, user) do
1111     mentions = Formatter.parse_mentions(bio)
1112     tags = Formatter.parse_tags(bio)
1113
1114     emoji =
1115       (user.info.source_data["tag"] || [])
1116       |> Enum.filter(fn %{"type" => t} -> t == "Emoji" end)
1117       |> Enum.map(fn %{"icon" => %{"url" => url}, "name" => name} ->
1118         {String.trim(name, ":"), url}
1119       end)
1120
1121     bio
1122     |> CommonUtils.format_input(mentions, tags, "text/plain", user_links: [format: :full])
1123     |> Formatter.emojify(emoji)
1124   end
1125
1126   def tag(user_identifiers, tags) when is_list(user_identifiers) do
1127     Repo.transaction(fn ->
1128       for user_identifier <- user_identifiers, do: tag(user_identifier, tags)
1129     end)
1130   end
1131
1132   def tag(nickname, tags) when is_binary(nickname),
1133     do: tag(User.get_by_nickname(nickname), tags)
1134
1135   def tag(%User{} = user, tags),
1136     do: update_tags(user, Enum.uniq((user.tags || []) ++ normalize_tags(tags)))
1137
1138   def untag(user_identifiers, tags) when is_list(user_identifiers) do
1139     Repo.transaction(fn ->
1140       for user_identifier <- user_identifiers, do: untag(user_identifier, tags)
1141     end)
1142   end
1143
1144   def untag(nickname, tags) when is_binary(nickname),
1145     do: untag(User.get_by_nickname(nickname), tags)
1146
1147   def untag(%User{} = user, tags),
1148     do: update_tags(user, (user.tags || []) -- normalize_tags(tags))
1149
1150   defp update_tags(%User{} = user, new_tags) do
1151     {:ok, updated_user} =
1152       user
1153       |> change(%{tags: new_tags})
1154       |> Repo.update()
1155
1156     updated_user
1157   end
1158
1159   defp normalize_tags(tags) do
1160     [tags]
1161     |> List.flatten()
1162     |> Enum.map(&String.downcase(&1))
1163   end
1164
1165   defp local_nickname_regex() do
1166     if Pleroma.Config.get([:instance, :extended_nickname_format]) do
1167       @extended_local_nickname_regex
1168     else
1169       @strict_local_nickname_regex
1170     end
1171   end
1172
1173   def local_nickname(nickname_or_mention) do
1174     nickname_or_mention
1175     |> full_nickname()
1176     |> String.split("@")
1177     |> hd()
1178   end
1179
1180   def full_nickname(nickname_or_mention),
1181     do: String.trim_leading(nickname_or_mention, "@")
1182
1183   def error_user(ap_id) do
1184     %User{
1185       name: ap_id,
1186       ap_id: ap_id,
1187       info: %User.Info{},
1188       nickname: "erroruser@example.com",
1189       inserted_at: NaiveDateTime.utc_now()
1190     }
1191   end
1192 end