git.squeep.com Git - akkoma/blob - lib/pleroma/user.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.User do
   6   use Ecto.Schema
   7
   8   import Ecto.{Changeset, Query}
   9   alias Pleroma.{Repo, User, Object, Web, Activity, Notification}
  10   alias Comeonin.Pbkdf2
  11   alias Pleroma.Formatter
  12   alias Pleroma.Web.CommonAPI.Utils, as: CommonUtils
  13   alias Pleroma.Web.{OStatus, Websub, OAuth}
  14   alias Pleroma.Web.ActivityPub.{Utils, ActivityPub}
  15
  16   require Logger
  17
  18   @type t :: %__MODULE__{}
  19
  20   @email_regex ~r/^[a-zA-Z0-9.!#$%&'*+\/=?^_`{|}~-]+@[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?(?:\.[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?)*$/
  21
  22   @strict_local_nickname_regex ~r/^[a-zA-Z\d]+$/
  23   @extended_local_nickname_regex ~r/^[a-zA-Z\d_-]+$/
  24
  25   schema "users" do
  26     field(:bio, :string)
  27     field(:email, :string)
  28     field(:name, :string)
  29     field(:nickname, :string)
  30     field(:password_hash, :string)
  31     field(:password, :string, virtual: true)
  32     field(:password_confirmation, :string, virtual: true)
  33     field(:following, {:array, :string}, default: [])
  34     field(:ap_id, :string)
  35     field(:avatar, :map)
  36     field(:local, :boolean, default: true)
  37     field(:follower_address, :string)
  38     field(:search_distance, :float, virtual: true)
  39     field(:tags, {:array, :string}, default: [])
  40     field(:last_refreshed_at, :naive_datetime)
  41     has_many(:notifications, Notification)
  42     embeds_one(:info, Pleroma.User.Info)
  43
  44     timestamps()
  45   end
  46
  47   def auth_active?(%User{local: false}), do: true
  48
  49   def auth_active?(%User{info: %User.Info{confirmation_pending: false}}), do: true
  50
  51   def auth_active?(%User{info: %User.Info{confirmation_pending: true}}),
  52     do: !Pleroma.Config.get([:instance, :account_activation_required])
  53
  54   def auth_active?(_), do: false
  55
  56   def visible_for?(user, for_user \\ nil)
  57
  58   def visible_for?(%User{id: user_id}, %User{id: for_id}) when user_id == for_id, do: true
  59
  60   def visible_for?(%User{} = user, for_user) do
  61     auth_active?(user) || superuser?(for_user)
  62   end
  63
  64   def visible_for?(_, _), do: false
  65
  66   def superuser?(%User{local: true, info: %User.Info{is_admin: true}}), do: true
  67   def superuser?(%User{local: true, info: %User.Info{is_moderator: true}}), do: true
  68   def superuser?(_), do: false
  69
  70   def avatar_url(user) do
  71     case user.avatar do
  72       %{"url" => [%{"href" => href} | _]} -> href
  73       _ -> "#{Web.base_url()}/images/avi.png"
  74     end
  75   end
  76
  77   def banner_url(user) do
  78     case user.info.banner do
  79       %{"url" => [%{"href" => href} | _]} -> href
  80       _ -> "#{Web.base_url()}/images/banner.png"
  81     end
  82   end
  83
  84   def profile_url(%User{info: %{source_data: %{"url" => url}}}), do: url
  85   def profile_url(%User{ap_id: ap_id}), do: ap_id
  86   def profile_url(_), do: nil
  87
  88   def ap_id(%User{nickname: nickname}) do
  89     "#{Web.base_url()}/users/#{nickname}"
  90   end
  91
  92   def ap_followers(%User{} = user) do
  93     "#{ap_id(user)}/followers"
  94   end
  95
  96   def follow_changeset(struct, params \\ %{}) do
  97     struct
  98     |> cast(params, [:following])
  99     |> validate_required([:following])
 100   end
 101
 102   def user_info(%User{} = user) do
 103     oneself = if user.local, do: 1, else: 0
 104
 105     %{
 106       following_count: length(user.following) - oneself,
 107       note_count: user.info.note_count,
 108       follower_count: user.info.follower_count,
 109       locked: user.info.locked,
 110       confirmation_pending: user.info.confirmation_pending,
 111       default_scope: user.info.default_scope
 112     }
 113   end
 114
 115   def remote_user_creation(params) do
 116     params =
 117       params
 118       |> Map.put(:info, params[:info] || %{})
 119
 120     info_cng = User.Info.remote_user_creation(%User.Info{}, params[:info])
 121
 122     changes =
 123       %User{}
 124       |> cast(params, [:bio, :name, :ap_id, :nickname, :avatar])
 125       |> validate_required([:name, :ap_id])
 126       |> unique_constraint(:nickname)
 127       |> validate_format(:nickname, @email_regex)
 128       |> validate_length(:bio, max: 5000)
 129       |> validate_length(:name, max: 100)
 130       |> put_change(:local, false)
 131       |> put_embed(:info, info_cng)
 132
 133     if changes.valid? do
 134       case info_cng.changes[:source_data] do
 135         %{"followers" => followers} ->
 136           changes
 137           |> put_change(:follower_address, followers)
 138
 139         _ ->
 140           followers = User.ap_followers(%User{nickname: changes.changes[:nickname]})
 141
 142           changes
 143           |> put_change(:follower_address, followers)
 144       end
 145     else
 146       changes
 147     end
 148   end
 149
 150   def update_changeset(struct, params \\ %{}) do
 151     struct
 152     |> cast(params, [:bio, :name, :avatar])
 153     |> unique_constraint(:nickname)
 154     |> validate_format(:nickname, local_nickname_regex())
 155     |> validate_length(:bio, max: 5000)
 156     |> validate_length(:name, min: 1, max: 100)
 157   end
 158
 159   def upgrade_changeset(struct, params \\ %{}) do
 160     params =
 161       params
 162       |> Map.put(:last_refreshed_at, NaiveDateTime.utc_now())
 163
 164     info_cng =
 165       struct.info
 166       |> User.Info.user_upgrade(params[:info])
 167
 168     struct
 169     |> cast(params, [:bio, :name, :follower_address, :avatar, :last_refreshed_at])
 170     |> unique_constraint(:nickname)
 171     |> validate_format(:nickname, local_nickname_regex())
 172     |> validate_length(:bio, max: 5000)
 173     |> validate_length(:name, max: 100)
 174     |> put_embed(:info, info_cng)
 175   end
 176
 177   def password_update_changeset(struct, params) do
 178     changeset =
 179       struct
 180       |> cast(params, [:password, :password_confirmation])
 181       |> validate_required([:password, :password_confirmation])
 182       |> validate_confirmation(:password)
 183
 184     OAuth.Token.delete_user_tokens(struct)
 185     OAuth.Authorization.delete_user_authorizations(struct)
 186
 187     if changeset.valid? do
 188       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 189
 190       changeset
 191       |> put_change(:password_hash, hashed)
 192     else
 193       changeset
 194     end
 195   end
 196
 197   def reset_password(user, data) do
 198     update_and_set_cache(password_update_changeset(user, data))
 199   end
 200
 201   def register_changeset(struct, params \\ %{}, opts \\ []) do
 202     confirmation_status =
 203       if opts[:confirmed] || !Pleroma.Config.get([:instance, :account_activation_required]) do
 204         :confirmed
 205       else
 206         :unconfirmed
 207       end
 208
 209     info_change = User.Info.confirmation_changeset(%User.Info{}, confirmation_status)
 210
 211     changeset =
 212       struct
 213       |> cast(params, [:bio, :email, :name, :nickname, :password, :password_confirmation])
 214       |> validate_required([:email, :name, :nickname, :password, :password_confirmation])
 215       |> validate_confirmation(:password)
 216       |> unique_constraint(:email)
 217       |> unique_constraint(:nickname)
 218       |> validate_exclusion(:nickname, Pleroma.Config.get([Pleroma.User, :restricted_nicknames]))
 219       |> validate_format(:nickname, local_nickname_regex())
 220       |> validate_format(:email, @email_regex)
 221       |> validate_length(:bio, max: 1000)
 222       |> validate_length(:name, min: 1, max: 100)
 223       |> put_change(:info, info_change)
 224
 225     if changeset.valid? do
 226       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 227       ap_id = User.ap_id(%User{nickname: changeset.changes[:nickname]})
 228       followers = User.ap_followers(%User{nickname: changeset.changes[:nickname]})
 229
 230       changeset
 231       |> put_change(:password_hash, hashed)
 232       |> put_change(:ap_id, ap_id)
 233       |> put_change(:following, [followers])
 234       |> put_change(:follower_address, followers)
 235     else
 236       changeset
 237     end
 238   end
 239
 240   defp autofollow_users(user) do
 241     candidates = Pleroma.Config.get([:instance, :autofollowed_nicknames])
 242
 243     autofollowed_users =
 244       from(u in User,
 245         where: u.local == true,
 246         where: u.nickname in ^candidates
 247       )
 248       |> Repo.all()
 249
 250     follow_all(user, autofollowed_users)
 251   end
 252
 253   @doc "Inserts provided changeset, performs post-registration actions (confirmation email sending etc.)"
 254   def register(%Ecto.Changeset{} = changeset) do
 255     with {:ok, user} <- Repo.insert(changeset),
 256          {:ok, _} <- try_send_confirmation_email(user),
 257          {:ok, user} <- autofollow_users(user) do
 258       {:ok, user}
 259     end
 260   end
 261
 262   def try_send_confirmation_email(%User{} = user) do
 263     if user.info.confirmation_pending &&
 264          Pleroma.Config.get([:instance, :account_activation_required]) do
 265       user
 266       |> Pleroma.UserEmail.account_confirmation_email()
 267       |> Pleroma.Mailer.deliver()
 268     else
 269       {:ok, :noop}
 270     end
 271   end
 272
 273   def needs_update?(%User{local: true}), do: false
 274
 275   def needs_update?(%User{local: false, last_refreshed_at: nil}), do: true
 276
 277   def needs_update?(%User{local: false} = user) do
 278     NaiveDateTime.diff(NaiveDateTime.utc_now(), user.last_refreshed_at) >= 86400
 279   end
 280
 281   def needs_update?(_), do: true
 282
 283   def maybe_direct_follow(%User{} = follower, %User{local: true, info: %{locked: true}}) do
 284     {:ok, follower}
 285   end
 286
 287   def maybe_direct_follow(%User{} = follower, %User{local: true} = followed) do
 288     follow(follower, followed)
 289   end
 290
 291   def maybe_direct_follow(%User{} = follower, %User{} = followed) do
 292     if not User.ap_enabled?(followed) do
 293       follow(follower, followed)
 294     else
 295       {:ok, follower}
 296     end
 297   end
 298
 299   def maybe_follow(%User{} = follower, %User{info: _info} = followed) do
 300     if not following?(follower, followed) do
 301       follow(follower, followed)
 302     else
 303       {:ok, follower}
 304     end
 305   end
 306
 307   @doc "A mass follow for local users. Ignores blocks and has no side effects"
 308   @spec follow_all(User.t(), list(User.t())) :: {atom(), User.t()}
 309   def follow_all(follower, followeds) do
 310     following =
 311       (follower.following ++ Enum.map(followeds, fn %{follower_address: fa} -> fa end))
 312       |> Enum.uniq()
 313
 314     {:ok, follower} =
 315       follower
 316       |> follow_changeset(%{following: following})
 317       |> update_and_set_cache
 318
 319     Enum.each(followeds, fn followed ->
 320       update_follower_count(followed)
 321     end)
 322
 323     {:ok, follower}
 324   end
 325
 326   def follow(%User{} = follower, %User{info: info} = followed) do
 327     user_config = Application.get_env(:pleroma, :user)
 328     deny_follow_blocked = Keyword.get(user_config, :deny_follow_blocked)
 329
 330     ap_followers = followed.follower_address
 331
 332     cond do
 333       following?(follower, followed) or info.deactivated ->
 334         {:error, "Could not follow user: #{followed.nickname} is already on your list."}
 335
 336       deny_follow_blocked and blocks?(followed, follower) ->
 337         {:error, "Could not follow user: #{followed.nickname} blocked you."}
 338
 339       true ->
 340         if !followed.local && follower.local && !ap_enabled?(followed) do
 341           Websub.subscribe(follower, followed)
 342         end
 343
 344         following =
 345           [ap_followers | follower.following]
 346           |> Enum.uniq()
 347
 348         follower =
 349           follower
 350           |> follow_changeset(%{following: following})
 351           |> update_and_set_cache
 352
 353         {:ok, _} = update_follower_count(followed)
 354
 355         follower
 356     end
 357   end
 358
 359   def unfollow(%User{} = follower, %User{} = followed) do
 360     ap_followers = followed.follower_address
 361
 362     if following?(follower, followed) and follower.ap_id != followed.ap_id do
 363       following =
 364         follower.following
 365         |> List.delete(ap_followers)
 366
 367       {:ok, follower} =
 368         follower
 369         |> follow_changeset(%{following: following})
 370         |> update_and_set_cache
 371
 372       {:ok, followed} = update_follower_count(followed)
 373
 374       {:ok, follower, Utils.fetch_latest_follow(follower, followed)}
 375     else
 376       {:error, "Not subscribed!"}
 377     end
 378   end
 379
 380   @spec following?(User.t(), User.t()) :: boolean
 381   def following?(%User{} = follower, %User{} = followed) do
 382     Enum.member?(follower.following, followed.follower_address)
 383   end
 384
 385   def follow_import(%User{} = follower, followed_identifiers)
 386       when is_list(followed_identifiers) do
 387     Enum.map(
 388       followed_identifiers,
 389       fn followed_identifier ->
 390         with %User{} = followed <- get_or_fetch(followed_identifier),
 391              {:ok, follower} <- maybe_direct_follow(follower, followed),
 392              {:ok, _} <- ActivityPub.follow(follower, followed) do
 393           followed
 394         else
 395           err ->
 396             Logger.debug("follow_import failed for #{followed_identifier} with: #{inspect(err)}")
 397             err
 398         end
 399       end
 400     )
 401   end
 402
 403   def locked?(%User{} = user) do
 404     user.info.locked || false
 405   end
 406
 407   def get_by_id(id) do
 408     Repo.get_by(User, id: id)
 409   end
 410
 411   def get_by_ap_id(ap_id) do
 412     Repo.get_by(User, ap_id: ap_id)
 413   end
 414
 415   # This is mostly an SPC migration fix. This guesses the user nickname (by taking the last part of the ap_id and the domain) and tries to get that user
 416   def get_by_guessed_nickname(ap_id) do
 417     domain = URI.parse(ap_id).host
 418     name = List.last(String.split(ap_id, "/"))
 419     nickname = "#{name}@#{domain}"
 420
 421     get_by_nickname(nickname)
 422   end
 423
 424   def update_and_set_cache(changeset) do
 425     with {:ok, user} <- Repo.update(changeset) do
 426       Cachex.put(:user_cache, "ap_id:#{user.ap_id}", user)
 427       Cachex.put(:user_cache, "nickname:#{user.nickname}", user)
 428       Cachex.put(:user_cache, "user_info:#{user.id}", user_info(user))
 429       {:ok, user}
 430     else
 431       e -> e
 432     end
 433   end
 434
 435   def invalidate_cache(user) do
 436     Cachex.del(:user_cache, "ap_id:#{user.ap_id}")
 437     Cachex.del(:user_cache, "nickname:#{user.nickname}")
 438     Cachex.del(:user_cache, "user_info:#{user.id}")
 439   end
 440
 441   def get_cached_by_ap_id(ap_id) do
 442     key = "ap_id:#{ap_id}"
 443     Cachex.fetch!(:user_cache, key, fn _ -> get_by_ap_id(ap_id) end)
 444   end
 445
 446   def get_cached_by_id(id) do
 447     key = "id:#{id}"
 448
 449     ap_id =
 450       Cachex.fetch!(:user_cache, key, fn _ ->
 451         user = get_by_id(id)
 452
 453         if user do
 454           Cachex.put(:user_cache, "ap_id:#{user.ap_id}", user)
 455           {:commit, user.ap_id}
 456         else
 457           {:ignore, ""}
 458         end
 459       end)
 460
 461     get_cached_by_ap_id(ap_id)
 462   end
 463
 464   def get_cached_by_nickname(nickname) do
 465     key = "nickname:#{nickname}"
 466     Cachex.fetch!(:user_cache, key, fn _ -> get_or_fetch_by_nickname(nickname) end)
 467   end
 468
 469   def get_cached_by_nickname_or_id(nickname_or_id) do
 470     get_cached_by_id(nickname_or_id) || get_cached_by_nickname(nickname_or_id)
 471   end
 472
 473   def get_by_nickname(nickname) do
 474     Repo.get_by(User, nickname: nickname) ||
 475       if Regex.match?(~r(@#{Pleroma.Web.Endpoint.host()})i, nickname) do
 476         [local_nickname, _] = String.split(nickname, "@")
 477         Repo.get_by(User, nickname: local_nickname)
 478       end
 479   end
 480
 481   def get_by_nickname_or_email(nickname_or_email) do
 482     case user = Repo.get_by(User, nickname: nickname_or_email) do
 483       %User{} -> user
 484       nil -> Repo.get_by(User, email: nickname_or_email)
 485     end
 486   end
 487
 488   def get_cached_user_info(user) do
 489     key = "user_info:#{user.id}"
 490     Cachex.fetch!(:user_cache, key, fn _ -> user_info(user) end)
 491   end
 492
 493   def fetch_by_nickname(nickname) do
 494     ap_try = ActivityPub.make_user_from_nickname(nickname)
 495
 496     case ap_try do
 497       {:ok, user} -> {:ok, user}
 498       _ -> OStatus.make_user(nickname)
 499     end
 500   end
 501
 502   def get_or_fetch_by_nickname(nickname) do
 503     with %User{} = user <- get_by_nickname(nickname) do
 504       user
 505     else
 506       _e ->
 507         with [_nick, _domain] <- String.split(nickname, "@"),
 508              {:ok, user} <- fetch_by_nickname(nickname) do
 509           user
 510         else
 511           _e -> nil
 512         end
 513     end
 514   end
 515
 516   def get_followers_query(%User{id: id, follower_address: follower_address}, nil) do
 517     from(
 518       u in User,
 519       where: fragment("? <@ ?", ^[follower_address], u.following),
 520       where: u.id != ^id
 521     )
 522   end
 523
 524   def get_followers_query(user, page) do
 525     from(
 526       u in get_followers_query(user, nil),
 527       limit: 20,
 528       offset: ^((page - 1) * 20)
 529     )
 530   end
 531
 532   def get_followers_query(user), do: get_followers_query(user, nil)
 533
 534   def get_followers(user, page \\ nil) do
 535     q = get_followers_query(user, page)
 536
 537     {:ok, Repo.all(q)}
 538   end
 539
 540   def get_friends_query(%User{id: id, following: following}, nil) do
 541     from(
 542       u in User,
 543       where: u.follower_address in ^following,
 544       where: u.id != ^id
 545     )
 546   end
 547
 548   def get_friends_query(user, page) do
 549     from(
 550       u in get_friends_query(user, nil),
 551       limit: 20,
 552       offset: ^((page - 1) * 20)
 553     )
 554   end
 555
 556   def get_friends_query(user), do: get_friends_query(user, nil)
 557
 558   def get_friends(user, page \\ nil) do
 559     q = get_friends_query(user, page)
 560
 561     {:ok, Repo.all(q)}
 562   end
 563
 564   def get_follow_requests_query(%User{} = user) do
 565     from(
 566       a in Activity,
 567       where:
 568         fragment(
 569           "? ->> 'type' = 'Follow'",
 570           a.data
 571         ),
 572       where:
 573         fragment(
 574           "? ->> 'state' = 'pending'",
 575           a.data
 576         ),
 577       where:
 578         fragment(
 579           "? @> ?",
 580           a.data,
 581           ^%{"object" => user.ap_id}
 582         )
 583     )
 584   end
 585
 586   def get_follow_requests(%User{} = user) do
 587     q = get_follow_requests_query(user)
 588     reqs = Repo.all(q)
 589
 590     users =
 591       Enum.map(reqs, fn req -> req.actor end)
 592       |> Enum.uniq()
 593       |> Enum.map(fn ap_id -> get_by_ap_id(ap_id) end)
 594       |> Enum.filter(fn u -> !is_nil(u) end)
 595       |> Enum.filter(fn u -> !following?(u, user) end)
 596
 597     {:ok, users}
 598   end
 599
 600   def increase_note_count(%User{} = user) do
 601     info_cng = User.Info.add_to_note_count(user.info, 1)
 602
 603     cng =
 604       change(user)
 605       |> put_embed(:info, info_cng)
 606
 607     update_and_set_cache(cng)
 608   end
 609
 610   def decrease_note_count(%User{} = user) do
 611     info_cng = User.Info.add_to_note_count(user.info, -1)
 612
 613     cng =
 614       change(user)
 615       |> put_embed(:info, info_cng)
 616
 617     update_and_set_cache(cng)
 618   end
 619
 620   def update_note_count(%User{} = user) do
 621     note_count_query =
 622       from(
 623         a in Object,
 624         where: fragment("?->>'actor' = ? and ?->>'type' = 'Note'", a.data, ^user.ap_id, a.data),
 625         select: count(a.id)
 626       )
 627
 628     note_count = Repo.one(note_count_query)
 629
 630     info_cng = User.Info.set_note_count(user.info, note_count)
 631
 632     cng =
 633       change(user)
 634       |> put_embed(:info, info_cng)
 635
 636     update_and_set_cache(cng)
 637   end
 638
 639   def update_follower_count(%User{} = user) do
 640     follower_count_query =
 641       from(
 642         u in User,
 643         where: ^user.follower_address in u.following,
 644         where: u.id != ^user.id,
 645         select: count(u.id)
 646       )
 647
 648     follower_count = Repo.one(follower_count_query)
 649
 650     info_cng =
 651       user.info
 652       |> User.Info.set_follower_count(follower_count)
 653
 654     cng =
 655       change(user)
 656       |> put_embed(:info, info_cng)
 657
 658     update_and_set_cache(cng)
 659   end
 660
 661   def get_users_from_set_query(ap_ids, false) do
 662     from(
 663       u in User,
 664       where: u.ap_id in ^ap_ids
 665     )
 666   end
 667
 668   def get_users_from_set_query(ap_ids, true) do
 669     query = get_users_from_set_query(ap_ids, false)
 670
 671     from(
 672       u in query,
 673       where: u.local == true
 674     )
 675   end
 676
 677   def get_users_from_set(ap_ids, local_only \\ true) do
 678     get_users_from_set_query(ap_ids, local_only)
 679     |> Repo.all()
 680   end
 681
 682   def get_recipients_from_activity(%Activity{recipients: to}) do
 683     query =
 684       from(
 685         u in User,
 686         where: u.ap_id in ^to,
 687         or_where: fragment("? && ?", u.following, ^to)
 688       )
 689
 690     query = from(u in query, where: u.local == true)
 691
 692     Repo.all(query)
 693   end
 694
 695   def search(query, resolve \\ false) do
 696     # strip the beginning @ off if there is a query
 697     query = String.trim_leading(query, "@")
 698
 699     if resolve do
 700       User.get_or_fetch_by_nickname(query)
 701     end
 702
 703     inner =
 704       from(
 705         u in User,
 706         select_merge: %{
 707           search_distance:
 708             fragment(
 709               "? <-> (? || coalesce(?, ''))",
 710               ^query,
 711               u.nickname,
 712               u.name
 713             )
 714         },
 715         where: not is_nil(u.nickname)
 716       )
 717
 718     q =
 719       from(
 720         s in subquery(inner),
 721         order_by: s.search_distance,
 722         limit: 20
 723       )
 724
 725     Repo.all(q)
 726   end
 727
 728   def blocks_import(%User{} = blocker, blocked_identifiers) when is_list(blocked_identifiers) do
 729     Enum.map(
 730       blocked_identifiers,
 731       fn blocked_identifier ->
 732         with %User{} = blocked <- get_or_fetch(blocked_identifier),
 733              {:ok, blocker} <- block(blocker, blocked),
 734              {:ok, _} <- ActivityPub.block(blocker, blocked) do
 735           blocked
 736         else
 737           err ->
 738             Logger.debug("blocks_import failed for #{blocked_identifier} with: #{inspect(err)}")
 739             err
 740         end
 741       end
 742     )
 743   end
 744
 745   def block(blocker, %User{ap_id: ap_id} = blocked) do
 746     # sever any follow relationships to prevent leaks per activitypub (Pleroma issue #213)
 747     blocker =
 748       if following?(blocker, blocked) do
 749         {:ok, blocker, _} = unfollow(blocker, blocked)
 750         blocker
 751       else
 752         blocker
 753       end
 754
 755     if following?(blocked, blocker) do
 756       unfollow(blocked, blocker)
 757     end
 758
 759     info_cng =
 760       blocker.info
 761       |> User.Info.add_to_block(ap_id)
 762
 763     cng =
 764       change(blocker)
 765       |> put_embed(:info, info_cng)
 766
 767     update_and_set_cache(cng)
 768   end
 769
 770   # helper to handle the block given only an actor's AP id
 771   def block(blocker, %{ap_id: ap_id}) do
 772     block(blocker, User.get_by_ap_id(ap_id))
 773   end
 774
 775   def unblock(blocker, %{ap_id: ap_id}) do
 776     info_cng =
 777       blocker.info
 778       |> User.Info.remove_from_block(ap_id)
 779
 780     cng =
 781       change(blocker)
 782       |> put_embed(:info, info_cng)
 783
 784     update_and_set_cache(cng)
 785   end
 786
 787   def blocks?(user, %{ap_id: ap_id}) do
 788     blocks = user.info.blocks
 789     domain_blocks = user.info.domain_blocks
 790     %{host: host} = URI.parse(ap_id)
 791
 792     Enum.member?(blocks, ap_id) ||
 793       Enum.any?(domain_blocks, fn domain ->
 794         host == domain
 795       end)
 796   end
 797
 798   def blocked_users(user),
 799     do: Repo.all(from(u in User, where: u.ap_id in ^user.info.blocks))
 800
 801   def block_domain(user, domain) do
 802     info_cng =
 803       user.info
 804       |> User.Info.add_to_domain_block(domain)
 805
 806     cng =
 807       change(user)
 808       |> put_embed(:info, info_cng)
 809
 810     update_and_set_cache(cng)
 811   end
 812
 813   def unblock_domain(user, domain) do
 814     info_cng =
 815       user.info
 816       |> User.Info.remove_from_domain_block(domain)
 817
 818     cng =
 819       change(user)
 820       |> put_embed(:info, info_cng)
 821
 822     update_and_set_cache(cng)
 823   end
 824
 825   def local_user_query() do
 826     from(
 827       u in User,
 828       where: u.local == true,
 829       where: not is_nil(u.nickname)
 830     )
 831   end
 832
 833   def moderator_user_query() do
 834     from(
 835       u in User,
 836       where: u.local == true,
 837       where: fragment("?->'is_moderator' @> 'true'", u.info)
 838     )
 839   end
 840
 841   def deactivate(%User{} = user, status \\ true) do
 842     info_cng = User.Info.set_activation_status(user.info, status)
 843
 844     cng =
 845       change(user)
 846       |> put_embed(:info, info_cng)
 847
 848     update_and_set_cache(cng)
 849   end
 850
 851   def delete(%User{} = user) do
 852     {:ok, user} = User.deactivate(user)
 853
 854     # Remove all relationships
 855     {:ok, followers} = User.get_followers(user)
 856
 857     followers
 858     |> Enum.each(fn follower -> User.unfollow(follower, user) end)
 859
 860     {:ok, friends} = User.get_friends(user)
 861
 862     friends
 863     |> Enum.each(fn followed -> User.unfollow(user, followed) end)
 864
 865     query = from(a in Activity, where: a.actor == ^user.ap_id)
 866
 867     Repo.all(query)
 868     |> Enum.each(fn activity ->
 869       case activity.data["type"] do
 870         "Create" ->
 871           ActivityPub.delete(Object.normalize(activity.data["object"]))
 872
 873         # TODO: Do something with likes, follows, repeats.
 874         _ ->
 875           "Doing nothing"
 876       end
 877     end)
 878
 879     {:ok, user}
 880   end
 881
 882   def html_filter_policy(%User{info: %{no_rich_text: true}}) do
 883     Pleroma.HTML.Scrubber.TwitterText
 884   end
 885
 886   @default_scrubbers Pleroma.Config.get([:markup, :scrub_policy])
 887
 888   def html_filter_policy(_), do: @default_scrubbers
 889
 890   def get_or_fetch_by_ap_id(ap_id) do
 891     user = get_by_ap_id(ap_id)
 892
 893     if !is_nil(user) and !User.needs_update?(user) do
 894       user
 895     else
 896       ap_try = ActivityPub.make_user_from_ap_id(ap_id)
 897
 898       case ap_try do
 899         {:ok, user} ->
 900           user
 901
 902         _ ->
 903           case OStatus.make_user(ap_id) do
 904             {:ok, user} -> user
 905             _ -> {:error, "Could not fetch by AP id"}
 906           end
 907       end
 908     end
 909   end
 910
 911   def get_or_create_instance_user do
 912     relay_uri = "#{Pleroma.Web.Endpoint.url()}/relay"
 913
 914     if user = get_by_ap_id(relay_uri) do
 915       user
 916     else
 917       changes =
 918         %User{info: %User.Info{}}
 919         |> cast(%{}, [:ap_id, :nickname, :local])
 920         |> put_change(:ap_id, relay_uri)
 921         |> put_change(:nickname, nil)
 922         |> put_change(:local, true)
 923         |> put_change(:follower_address, relay_uri <> "/followers")
 924
 925       {:ok, user} = Repo.insert(changes)
 926       user
 927     end
 928   end
 929
 930   # AP style
 931   def public_key_from_info(%{
 932         source_data: %{"publicKey" => %{"publicKeyPem" => public_key_pem}}
 933       }) do
 934     key =
 935       public_key_pem
 936       |> :public_key.pem_decode()
 937       |> hd()
 938       |> :public_key.pem_entry_decode()
 939
 940     {:ok, key}
 941   end
 942
 943   # OStatus Magic Key
 944   def public_key_from_info(%{magic_key: magic_key}) do
 945     {:ok, Pleroma.Web.Salmon.decode_key(magic_key)}
 946   end
 947
 948   def get_public_key_for_ap_id(ap_id) do
 949     with %User{} = user <- get_or_fetch_by_ap_id(ap_id),
 950          {:ok, public_key} <- public_key_from_info(user.info) do
 951       {:ok, public_key}
 952     else
 953       _ -> :error
 954     end
 955   end
 956
 957   defp blank?(""), do: nil
 958   defp blank?(n), do: n
 959
 960   def insert_or_update_user(data) do
 961     data =
 962       data
 963       |> Map.put(:name, blank?(data[:name]) || data[:nickname])
 964
 965     cs = User.remote_user_creation(data)
 966
 967     Repo.insert(cs, on_conflict: :replace_all, conflict_target: :nickname)
 968   end
 969
 970   def ap_enabled?(%User{local: true}), do: true
 971   def ap_enabled?(%User{info: info}), do: info.ap_enabled
 972   def ap_enabled?(_), do: false
 973
 974   @doc "Gets or fetch a user by uri or nickname."
 975   @spec get_or_fetch(String.t()) :: User.t()
 976   def get_or_fetch("http" <> _host = uri), do: get_or_fetch_by_ap_id(uri)
 977   def get_or_fetch(nickname), do: get_or_fetch_by_nickname(nickname)
 978
 979   # wait a period of time and return newest version of the User structs
 980   # this is because we have synchronous follow APIs and need to simulate them
 981   # with an async handshake
 982   def wait_and_refresh(_, %User{local: true} = a, %User{local: true} = b) do
 983     with %User{} = a <- Repo.get(User, a.id),
 984          %User{} = b <- Repo.get(User, b.id) do
 985       {:ok, a, b}
 986     else
 987       _e ->
 988         :error
 989     end
 990   end
 991
 992   def wait_and_refresh(timeout, %User{} = a, %User{} = b) do
 993     with :ok <- :timer.sleep(timeout),
 994          %User{} = a <- Repo.get(User, a.id),
 995          %User{} = b <- Repo.get(User, b.id) do
 996       {:ok, a, b}
 997     else
 998       _e ->
 999         :error
1000     end
1001   end
1002
1003   def parse_bio(bio, user \\ %User{info: %{source_data: %{}}})
1004   def parse_bio(nil, _user), do: ""
1005   def parse_bio(bio, _user) when bio == "", do: bio
1006
1007   def parse_bio(bio, user) do
1008     mentions = Formatter.parse_mentions(bio)
1009     tags = Formatter.parse_tags(bio)
1010
1011     emoji =
1012       (user.info.source_data["tag"] || [])
1013       |> Enum.filter(fn %{"type" => t} -> t == "Emoji" end)
1014       |> Enum.map(fn %{"icon" => %{"url" => url}, "name" => name} ->
1015         {String.trim(name, ":"), url}
1016       end)
1017
1018     bio
1019     |> CommonUtils.format_input(mentions, tags, "text/plain")
1020     |> Formatter.emojify(emoji)
1021   end
1022
1023   def tag(user_identifiers, tags) when is_list(user_identifiers) do
1024     Repo.transaction(fn ->
1025       for user_identifier <- user_identifiers, do: tag(user_identifier, tags)
1026     end)
1027   end
1028
1029   def tag(nickname, tags) when is_binary(nickname),
1030     do: tag(User.get_by_nickname(nickname), tags)
1031
1032   def tag(%User{} = user, tags),
1033     do: update_tags(user, Enum.uniq((user.tags || []) ++ normalize_tags(tags)))
1034
1035   def untag(user_identifiers, tags) when is_list(user_identifiers) do
1036     Repo.transaction(fn ->
1037       for user_identifier <- user_identifiers, do: untag(user_identifier, tags)
1038     end)
1039   end
1040
1041   def untag(nickname, tags) when is_binary(nickname),
1042     do: untag(User.get_by_nickname(nickname), tags)
1043
1044   def untag(%User{} = user, tags),
1045     do: update_tags(user, (user.tags || []) -- normalize_tags(tags))
1046
1047   defp update_tags(%User{} = user, new_tags) do
1048     {:ok, updated_user} =
1049       user
1050       |> change(%{tags: new_tags})
1051       |> Repo.update()
1052
1053     updated_user
1054   end
1055
1056   defp normalize_tags(tags) do
1057     [tags]
1058     |> List.flatten()
1059     |> Enum.map(&String.downcase(&1))
1060   end
1061
1062   defp local_nickname_regex() do
1063     if Pleroma.Config.get([:instance, :extended_nickname_format]) do
1064       @extended_local_nickname_regex
1065     else
1066       @strict_local_nickname_regex
1067     end
1068   end
1069 end