git.squeep.com Git - akkoma/blob - lib/pleroma/user.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.User do
   6   use Ecto.Schema
   7
   8   import Ecto.{Changeset, Query}
   9   alias Pleroma.{Repo, User, Object, Web, Activity, Notification}
  10   alias Comeonin.Pbkdf2
  11   alias Pleroma.Formatter
  12   alias Pleroma.Web.CommonAPI.Utils, as: CommonUtils
  13   alias Pleroma.Web.{OStatus, Websub, OAuth}
  14   alias Pleroma.Web.ActivityPub.{Utils, ActivityPub}
  15
  16   require Logger
  17
  18   @type t :: %__MODULE__{}
  19
  20   @email_regex ~r/^[a-zA-Z0-9.!#$%&'*+\/=?^_`{|}~-]+@[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?(?:\.[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?)*$/
  21
  22   @strict_local_nickname_regex ~r/^[a-zA-Z\d]+$/
  23   @extended_local_nickname_regex ~r/^[a-zA-Z\d_-]+$/
  24
  25   schema "users" do
  26     field(:bio, :string)
  27     field(:email, :string)
  28     field(:name, :string)
  29     field(:nickname, :string)
  30     field(:password_hash, :string)
  31     field(:password, :string, virtual: true)
  32     field(:password_confirmation, :string, virtual: true)
  33     field(:following, {:array, :string}, default: [])
  34     field(:ap_id, :string)
  35     field(:avatar, :map)
  36     field(:local, :boolean, default: true)
  37     field(:follower_address, :string)
  38     field(:search_rank, :float, virtual: true)
  39     field(:tags, {:array, :string}, default: [])
  40     field(:last_refreshed_at, :naive_datetime)
  41     has_many(:notifications, Notification)
  42     embeds_one(:info, Pleroma.User.Info)
  43
  44     timestamps()
  45   end
  46
  47   def auth_active?(%User{local: false}), do: true
  48
  49   def auth_active?(%User{info: %User.Info{confirmation_pending: false}}), do: true
  50
  51   def auth_active?(%User{info: %User.Info{confirmation_pending: true}}),
  52     do: !Pleroma.Config.get([:instance, :account_activation_required])
  53
  54   def auth_active?(_), do: false
  55
  56   def visible_for?(user, for_user \\ nil)
  57
  58   def visible_for?(%User{id: user_id}, %User{id: for_id}) when user_id == for_id, do: true
  59
  60   def visible_for?(%User{} = user, for_user) do
  61     auth_active?(user) || superuser?(for_user)
  62   end
  63
  64   def visible_for?(_, _), do: false
  65
  66   def superuser?(%User{local: true, info: %User.Info{is_admin: true}}), do: true
  67   def superuser?(%User{local: true, info: %User.Info{is_moderator: true}}), do: true
  68   def superuser?(_), do: false
  69
  70   def avatar_url(user) do
  71     case user.avatar do
  72       %{"url" => [%{"href" => href} | _]} -> href
  73       _ -> "#{Web.base_url()}/images/avi.png"
  74     end
  75   end
  76
  77   def banner_url(user) do
  78     case user.info.banner do
  79       %{"url" => [%{"href" => href} | _]} -> href
  80       _ -> "#{Web.base_url()}/images/banner.png"
  81     end
  82   end
  83
  84   def profile_url(%User{info: %{source_data: %{"url" => url}}}), do: url
  85   def profile_url(%User{ap_id: ap_id}), do: ap_id
  86   def profile_url(_), do: nil
  87
  88   def ap_id(%User{nickname: nickname}) do
  89     "#{Web.base_url()}/users/#{nickname}"
  90   end
  91
  92   def ap_followers(%User{} = user) do
  93     "#{ap_id(user)}/followers"
  94   end
  95
  96   def follow_changeset(struct, params \\ %{}) do
  97     struct
  98     |> cast(params, [:following])
  99     |> validate_required([:following])
 100   end
 101
 102   def user_info(%User{} = user) do
 103     oneself = if user.local, do: 1, else: 0
 104
 105     %{
 106       following_count: length(user.following) - oneself,
 107       note_count: user.info.note_count,
 108       follower_count: user.info.follower_count,
 109       locked: user.info.locked,
 110       confirmation_pending: user.info.confirmation_pending,
 111       default_scope: user.info.default_scope
 112     }
 113   end
 114
 115   def remote_user_creation(params) do
 116     params =
 117       params
 118       |> Map.put(:info, params[:info] || %{})
 119
 120     info_cng = User.Info.remote_user_creation(%User.Info{}, params[:info])
 121
 122     changes =
 123       %User{}
 124       |> cast(params, [:bio, :name, :ap_id, :nickname, :avatar])
 125       |> validate_required([:name, :ap_id])
 126       |> unique_constraint(:nickname)
 127       |> validate_format(:nickname, @email_regex)
 128       |> validate_length(:bio, max: 5000)
 129       |> validate_length(:name, max: 100)
 130       |> put_change(:local, false)
 131       |> put_embed(:info, info_cng)
 132
 133     if changes.valid? do
 134       case info_cng.changes[:source_data] do
 135         %{"followers" => followers} ->
 136           changes
 137           |> put_change(:follower_address, followers)
 138
 139         _ ->
 140           followers = User.ap_followers(%User{nickname: changes.changes[:nickname]})
 141
 142           changes
 143           |> put_change(:follower_address, followers)
 144       end
 145     else
 146       changes
 147     end
 148   end
 149
 150   def update_changeset(struct, params \\ %{}) do
 151     struct
 152     |> cast(params, [:bio, :name, :avatar])
 153     |> unique_constraint(:nickname)
 154     |> validate_format(:nickname, local_nickname_regex())
 155     |> validate_length(:bio, max: 5000)
 156     |> validate_length(:name, min: 1, max: 100)
 157   end
 158
 159   def upgrade_changeset(struct, params \\ %{}) do
 160     params =
 161       params
 162       |> Map.put(:last_refreshed_at, NaiveDateTime.utc_now())
 163
 164     info_cng =
 165       struct.info
 166       |> User.Info.user_upgrade(params[:info])
 167
 168     struct
 169     |> cast(params, [:bio, :name, :follower_address, :avatar, :last_refreshed_at])
 170     |> unique_constraint(:nickname)
 171     |> validate_format(:nickname, local_nickname_regex())
 172     |> validate_length(:bio, max: 5000)
 173     |> validate_length(:name, max: 100)
 174     |> put_embed(:info, info_cng)
 175   end
 176
 177   def password_update_changeset(struct, params) do
 178     changeset =
 179       struct
 180       |> cast(params, [:password, :password_confirmation])
 181       |> validate_required([:password, :password_confirmation])
 182       |> validate_confirmation(:password)
 183
 184     OAuth.Token.delete_user_tokens(struct)
 185     OAuth.Authorization.delete_user_authorizations(struct)
 186
 187     if changeset.valid? do
 188       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 189
 190       changeset
 191       |> put_change(:password_hash, hashed)
 192     else
 193       changeset
 194     end
 195   end
 196
 197   def reset_password(user, data) do
 198     update_and_set_cache(password_update_changeset(user, data))
 199   end
 200
 201   def register_changeset(struct, params \\ %{}, opts \\ []) do
 202     confirmation_status =
 203       if opts[:confirmed] || !Pleroma.Config.get([:instance, :account_activation_required]) do
 204         :confirmed
 205       else
 206         :unconfirmed
 207       end
 208
 209     info_change = User.Info.confirmation_changeset(%User.Info{}, confirmation_status)
 210
 211     changeset =
 212       struct
 213       |> cast(params, [:bio, :email, :name, :nickname, :password, :password_confirmation])
 214       |> validate_required([:email, :name, :nickname, :password, :password_confirmation])
 215       |> validate_confirmation(:password)
 216       |> unique_constraint(:email)
 217       |> unique_constraint(:nickname)
 218       |> validate_exclusion(:nickname, Pleroma.Config.get([Pleroma.User, :restricted_nicknames]))
 219       |> validate_format(:nickname, local_nickname_regex())
 220       |> validate_format(:email, @email_regex)
 221       |> validate_length(:bio, max: 1000)
 222       |> validate_length(:name, min: 1, max: 100)
 223       |> put_change(:info, info_change)
 224
 225     if changeset.valid? do
 226       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 227       ap_id = User.ap_id(%User{nickname: changeset.changes[:nickname]})
 228       followers = User.ap_followers(%User{nickname: changeset.changes[:nickname]})
 229
 230       changeset
 231       |> put_change(:password_hash, hashed)
 232       |> put_change(:ap_id, ap_id)
 233       |> put_change(:following, [followers])
 234       |> put_change(:follower_address, followers)
 235     else
 236       changeset
 237     end
 238   end
 239
 240   defp autofollow_users(user) do
 241     candidates = Pleroma.Config.get([:instance, :autofollowed_nicknames])
 242
 243     autofollowed_users =
 244       from(u in User,
 245         where: u.local == true,
 246         where: u.nickname in ^candidates
 247       )
 248       |> Repo.all()
 249
 250     follow_all(user, autofollowed_users)
 251   end
 252
 253   @doc "Inserts provided changeset, performs post-registration actions (confirmation email sending etc.)"
 254   def register(%Ecto.Changeset{} = changeset) do
 255     with {:ok, user} <- Repo.insert(changeset),
 256          {:ok, _} <- try_send_confirmation_email(user),
 257          {:ok, user} <- autofollow_users(user) do
 258       {:ok, user}
 259     end
 260   end
 261
 262   def try_send_confirmation_email(%User{} = user) do
 263     if user.info.confirmation_pending &&
 264          Pleroma.Config.get([:instance, :account_activation_required]) do
 265       user
 266       |> Pleroma.UserEmail.account_confirmation_email()
 267       |> Pleroma.Mailer.deliver()
 268     else
 269       {:ok, :noop}
 270     end
 271   end
 272
 273   def needs_update?(%User{local: true}), do: false
 274
 275   def needs_update?(%User{local: false, last_refreshed_at: nil}), do: true
 276
 277   def needs_update?(%User{local: false} = user) do
 278     NaiveDateTime.diff(NaiveDateTime.utc_now(), user.last_refreshed_at) >= 86400
 279   end
 280
 281   def needs_update?(_), do: true
 282
 283   def maybe_direct_follow(%User{} = follower, %User{local: true, info: %{locked: true}}) do
 284     {:ok, follower}
 285   end
 286
 287   def maybe_direct_follow(%User{} = follower, %User{local: true} = followed) do
 288     follow(follower, followed)
 289   end
 290
 291   def maybe_direct_follow(%User{} = follower, %User{} = followed) do
 292     if not User.ap_enabled?(followed) do
 293       follow(follower, followed)
 294     else
 295       {:ok, follower}
 296     end
 297   end
 298
 299   def maybe_follow(%User{} = follower, %User{info: _info} = followed) do
 300     if not following?(follower, followed) do
 301       follow(follower, followed)
 302     else
 303       {:ok, follower}
 304     end
 305   end
 306
 307   @doc "A mass follow for local users. Ignores blocks and has no side effects"
 308   @spec follow_all(User.t(), list(User.t())) :: {atom(), User.t()}
 309   def follow_all(follower, followeds) do
 310     following =
 311       (follower.following ++ Enum.map(followeds, fn %{follower_address: fa} -> fa end))
 312       |> Enum.uniq()
 313
 314     {:ok, follower} =
 315       follower
 316       |> follow_changeset(%{following: following})
 317       |> update_and_set_cache
 318
 319     Enum.each(followeds, fn followed ->
 320       update_follower_count(followed)
 321     end)
 322
 323     {:ok, follower}
 324   end
 325
 326   def follow(%User{} = follower, %User{info: info} = followed) do
 327     user_config = Application.get_env(:pleroma, :user)
 328     deny_follow_blocked = Keyword.get(user_config, :deny_follow_blocked)
 329
 330     ap_followers = followed.follower_address
 331
 332     cond do
 333       following?(follower, followed) or info.deactivated ->
 334         {:error, "Could not follow user: #{followed.nickname} is already on your list."}
 335
 336       deny_follow_blocked and blocks?(followed, follower) ->
 337         {:error, "Could not follow user: #{followed.nickname} blocked you."}
 338
 339       true ->
 340         if !followed.local && follower.local && !ap_enabled?(followed) do
 341           Websub.subscribe(follower, followed)
 342         end
 343
 344         following =
 345           [ap_followers | follower.following]
 346           |> Enum.uniq()
 347
 348         follower =
 349           follower
 350           |> follow_changeset(%{following: following})
 351           |> update_and_set_cache
 352
 353         {:ok, _} = update_follower_count(followed)
 354
 355         follower
 356     end
 357   end
 358
 359   def unfollow(%User{} = follower, %User{} = followed) do
 360     ap_followers = followed.follower_address
 361
 362     if following?(follower, followed) and follower.ap_id != followed.ap_id do
 363       following =
 364         follower.following
 365         |> List.delete(ap_followers)
 366
 367       {:ok, follower} =
 368         follower
 369         |> follow_changeset(%{following: following})
 370         |> update_and_set_cache
 371
 372       {:ok, followed} = update_follower_count(followed)
 373
 374       {:ok, follower, Utils.fetch_latest_follow(follower, followed)}
 375     else
 376       {:error, "Not subscribed!"}
 377     end
 378   end
 379
 380   @spec following?(User.t(), User.t()) :: boolean
 381   def following?(%User{} = follower, %User{} = followed) do
 382     Enum.member?(follower.following, followed.follower_address)
 383   end
 384
 385   def follow_import(%User{} = follower, followed_identifiers)
 386       when is_list(followed_identifiers) do
 387     Enum.map(
 388       followed_identifiers,
 389       fn followed_identifier ->
 390         with %User{} = followed <- get_or_fetch(followed_identifier),
 391              {:ok, follower} <- maybe_direct_follow(follower, followed),
 392              {:ok, _} <- ActivityPub.follow(follower, followed) do
 393           followed
 394         else
 395           err ->
 396             Logger.debug("follow_import failed for #{followed_identifier} with: #{inspect(err)}")
 397             err
 398         end
 399       end
 400     )
 401   end
 402
 403   def locked?(%User{} = user) do
 404     user.info.locked || false
 405   end
 406
 407   def get_by_ap_id(ap_id) do
 408     Repo.get_by(User, ap_id: ap_id)
 409   end
 410
 411   # This is mostly an SPC migration fix. This guesses the user nickname (by taking the last part of the ap_id and the domain) and tries to get that user
 412   def get_by_guessed_nickname(ap_id) do
 413     domain = URI.parse(ap_id).host
 414     name = List.last(String.split(ap_id, "/"))
 415     nickname = "#{name}@#{domain}"
 416
 417     get_by_nickname(nickname)
 418   end
 419
 420   def update_and_set_cache(changeset) do
 421     with {:ok, user} <- Repo.update(changeset) do
 422       Cachex.put(:user_cache, "ap_id:#{user.ap_id}", user)
 423       Cachex.put(:user_cache, "nickname:#{user.nickname}", user)
 424       Cachex.put(:user_cache, "user_info:#{user.id}", user_info(user))
 425       {:ok, user}
 426     else
 427       e -> e
 428     end
 429   end
 430
 431   def invalidate_cache(user) do
 432     Cachex.del(:user_cache, "ap_id:#{user.ap_id}")
 433     Cachex.del(:user_cache, "nickname:#{user.nickname}")
 434     Cachex.del(:user_cache, "user_info:#{user.id}")
 435   end
 436
 437   def get_cached_by_ap_id(ap_id) do
 438     key = "ap_id:#{ap_id}"
 439     Cachex.fetch!(:user_cache, key, fn _ -> get_by_ap_id(ap_id) end)
 440   end
 441
 442   def get_cached_by_nickname(nickname) do
 443     key = "nickname:#{nickname}"
 444     Cachex.fetch!(:user_cache, key, fn _ -> get_or_fetch_by_nickname(nickname) end)
 445   end
 446
 447   def get_by_nickname(nickname) do
 448     Repo.get_by(User, nickname: nickname) ||
 449       if Regex.match?(~r(@#{Pleroma.Web.Endpoint.host()})i, nickname) do
 450         Repo.get_by(User, nickname: local_nickname(nickname))
 451       end
 452   end
 453
 454   def get_by_nickname_or_email(nickname_or_email) do
 455     case user = Repo.get_by(User, nickname: nickname_or_email) do
 456       %User{} -> user
 457       nil -> Repo.get_by(User, email: nickname_or_email)
 458     end
 459   end
 460
 461   def get_cached_user_info(user) do
 462     key = "user_info:#{user.id}"
 463     Cachex.fetch!(:user_cache, key, fn _ -> user_info(user) end)
 464   end
 465
 466   def fetch_by_nickname(nickname) do
 467     ap_try = ActivityPub.make_user_from_nickname(nickname)
 468
 469     case ap_try do
 470       {:ok, user} -> {:ok, user}
 471       _ -> OStatus.make_user(nickname)
 472     end
 473   end
 474
 475   def get_or_fetch_by_nickname(nickname) do
 476     with %User{} = user <- get_by_nickname(nickname) do
 477       user
 478     else
 479       _e ->
 480         with [_nick, _domain] <- String.split(nickname, "@"),
 481              {:ok, user} <- fetch_by_nickname(nickname) do
 482           user
 483         else
 484           _e -> nil
 485         end
 486     end
 487   end
 488
 489   def get_followers_query(%User{id: id, follower_address: follower_address}, nil) do
 490     from(
 491       u in User,
 492       where: fragment("? <@ ?", ^[follower_address], u.following),
 493       where: u.id != ^id
 494     )
 495   end
 496
 497   def get_followers_query(user, page) do
 498     from(
 499       u in get_followers_query(user, nil),
 500       limit: 20,
 501       offset: ^((page - 1) * 20)
 502     )
 503   end
 504
 505   def get_followers_query(user), do: get_followers_query(user, nil)
 506
 507   def get_followers(user, page \\ nil) do
 508     q = get_followers_query(user, page)
 509
 510     {:ok, Repo.all(q)}
 511   end
 512
 513   def get_followers_ids(user, page \\ nil) do
 514     q = get_followers_query(user, page)
 515
 516     Repo.all(from(u in q, select: u.id))
 517   end
 518
 519   def get_friends_query(%User{id: id, following: following}, nil) do
 520     from(
 521       u in User,
 522       where: u.follower_address in ^following,
 523       where: u.id != ^id
 524     )
 525   end
 526
 527   def get_friends_query(user, page) do
 528     from(
 529       u in get_friends_query(user, nil),
 530       limit: 20,
 531       offset: ^((page - 1) * 20)
 532     )
 533   end
 534
 535   def get_friends_query(user), do: get_friends_query(user, nil)
 536
 537   def get_friends(user, page \\ nil) do
 538     q = get_friends_query(user, page)
 539
 540     {:ok, Repo.all(q)}
 541   end
 542
 543   def get_friends_ids(user, page \\ nil) do
 544     q = get_friends_query(user, page)
 545
 546     Repo.all(from(u in q, select: u.id))
 547   end
 548
 549   def get_follow_requests_query(%User{} = user) do
 550     from(
 551       a in Activity,
 552       where:
 553         fragment(
 554           "? ->> 'type' = 'Follow'",
 555           a.data
 556         ),
 557       where:
 558         fragment(
 559           "? ->> 'state' = 'pending'",
 560           a.data
 561         ),
 562       where:
 563         fragment(
 564           "? @> ?",
 565           a.data,
 566           ^%{"object" => user.ap_id}
 567         )
 568     )
 569   end
 570
 571   def get_follow_requests(%User{} = user) do
 572     q = get_follow_requests_query(user)
 573     reqs = Repo.all(q)
 574
 575     users =
 576       Enum.map(reqs, fn req -> req.actor end)
 577       |> Enum.uniq()
 578       |> Enum.map(fn ap_id -> get_by_ap_id(ap_id) end)
 579       |> Enum.filter(fn u -> !is_nil(u) end)
 580       |> Enum.filter(fn u -> !following?(u, user) end)
 581
 582     {:ok, users}
 583   end
 584
 585   def increase_note_count(%User{} = user) do
 586     info_cng = User.Info.add_to_note_count(user.info, 1)
 587
 588     cng =
 589       change(user)
 590       |> put_embed(:info, info_cng)
 591
 592     update_and_set_cache(cng)
 593   end
 594
 595   def decrease_note_count(%User{} = user) do
 596     info_cng = User.Info.add_to_note_count(user.info, -1)
 597
 598     cng =
 599       change(user)
 600       |> put_embed(:info, info_cng)
 601
 602     update_and_set_cache(cng)
 603   end
 604
 605   def update_note_count(%User{} = user) do
 606     note_count_query =
 607       from(
 608         a in Object,
 609         where: fragment("?->>'actor' = ? and ?->>'type' = 'Note'", a.data, ^user.ap_id, a.data),
 610         select: count(a.id)
 611       )
 612
 613     note_count = Repo.one(note_count_query)
 614
 615     info_cng = User.Info.set_note_count(user.info, note_count)
 616
 617     cng =
 618       change(user)
 619       |> put_embed(:info, info_cng)
 620
 621     update_and_set_cache(cng)
 622   end
 623
 624   def update_follower_count(%User{} = user) do
 625     follower_count_query =
 626       from(
 627         u in User,
 628         where: ^user.follower_address in u.following,
 629         where: u.id != ^user.id,
 630         select: count(u.id)
 631       )
 632
 633     follower_count = Repo.one(follower_count_query)
 634
 635     info_cng =
 636       user.info
 637       |> User.Info.set_follower_count(follower_count)
 638
 639     cng =
 640       change(user)
 641       |> put_embed(:info, info_cng)
 642
 643     update_and_set_cache(cng)
 644   end
 645
 646   def get_users_from_set_query(ap_ids, false) do
 647     from(
 648       u in User,
 649       where: u.ap_id in ^ap_ids
 650     )
 651   end
 652
 653   def get_users_from_set_query(ap_ids, true) do
 654     query = get_users_from_set_query(ap_ids, false)
 655
 656     from(
 657       u in query,
 658       where: u.local == true
 659     )
 660   end
 661
 662   def get_users_from_set(ap_ids, local_only \\ true) do
 663     get_users_from_set_query(ap_ids, local_only)
 664     |> Repo.all()
 665   end
 666
 667   def get_recipients_from_activity(%Activity{recipients: to}) do
 668     query =
 669       from(
 670         u in User,
 671         where: u.ap_id in ^to,
 672         or_where: fragment("? && ?", u.following, ^to)
 673       )
 674
 675     query = from(u in query, where: u.local == true)
 676
 677     Repo.all(query)
 678   end
 679
 680   def search(query, resolve \\ false, for_user \\ nil) do
 681     # Strip the beginning @ off if there is a query
 682     query = String.trim_leading(query, "@")
 683
 684     if resolve, do: User.get_or_fetch_by_nickname(query)
 685
 686     fts_results = do_search(fts_search_subquery(query), for_user)
 687
 688     {:ok, trigram_results} =
 689       Repo.transaction(fn ->
 690         Ecto.Adapters.SQL.query(Repo, "select set_limit(0.25)", [])
 691         do_search(trigram_search_subquery(query), for_user)
 692       end)
 693
 694     Enum.uniq_by(fts_results ++ trigram_results, & &1.id)
 695   end
 696
 697   defp do_search(subquery, for_user, options \\ []) do
 698     q =
 699       from(
 700         s in subquery(subquery),
 701         order_by: [desc: s.search_rank],
 702         limit: ^(options[:limit] || 20)
 703       )
 704
 705     results =
 706       q
 707       |> Repo.all()
 708       |> Enum.filter(&(&1.search_rank > 0))
 709
 710     boost_search_results(results, for_user)
 711   end
 712
 713   defp fts_search_subquery(query) do
 714     processed_query =
 715       query
 716       |> String.replace(~r/\W+/, " ")
 717       |> String.trim()
 718       |> String.split()
 719       |> Enum.map(&(&1 <> ":*"))
 720       |> Enum.join(" | ")
 721
 722     from(
 723       u in User,
 724       select_merge: %{
 725         search_rank:
 726           fragment(
 727             """
 728             ts_rank_cd(
 729               setweight(to_tsvector('simple', regexp_replace(?, '\\W', ' ', 'g')), 'A') ||
 730               setweight(to_tsvector('simple', regexp_replace(coalesce(?, ''), '\\W', ' ', 'g')), 'B'),
 731               to_tsquery('simple', ?),
 732               32
 733             )
 734             """,
 735             u.nickname,
 736             u.name,
 737             ^processed_query
 738           )
 739       },
 740       where:
 741         fragment(
 742           """
 743             (setweight(to_tsvector('simple', regexp_replace(?, '\\W', ' ', 'g')), 'A') ||
 744             setweight(to_tsvector('simple', regexp_replace(coalesce(?, ''), '\\W', ' ', 'g')), 'B')) @@ to_tsquery('simple', ?)
 745           """,
 746           u.nickname,
 747           u.name,
 748           ^processed_query
 749         )
 750     )
 751   end
 752
 753   defp trigram_search_subquery(query) do
 754     from(
 755       u in User,
 756       select_merge: %{
 757         search_rank:
 758           fragment(
 759             "similarity(?, trim(? || ' ' || coalesce(?, '')))",
 760             ^query,
 761             u.nickname,
 762             u.name
 763           )
 764       },
 765       where: fragment("trim(? || ' ' || coalesce(?, '')) % ?", u.nickname, u.name, ^query)
 766     )
 767   end
 768
 769   defp boost_search_results(results, nil), do: results
 770
 771   defp boost_search_results(results, for_user) do
 772     friends_ids = get_friends_ids(for_user)
 773     followers_ids = get_followers_ids(for_user)
 774
 775     Enum.map(
 776       results,
 777       fn u ->
 778         search_rank_coef =
 779           cond do
 780             u.id in friends_ids ->
 781               1.2
 782
 783             u.id in followers_ids ->
 784               1.1
 785
 786             true ->
 787               1
 788           end
 789
 790         Map.put(u, :search_rank, u.search_rank * search_rank_coef)
 791       end
 792     )
 793     |> Enum.sort_by(&(-&1.search_rank))
 794   end
 795
 796   def blocks_import(%User{} = blocker, blocked_identifiers) when is_list(blocked_identifiers) do
 797     Enum.map(
 798       blocked_identifiers,
 799       fn blocked_identifier ->
 800         with %User{} = blocked <- get_or_fetch(blocked_identifier),
 801              {:ok, blocker} <- block(blocker, blocked),
 802              {:ok, _} <- ActivityPub.block(blocker, blocked) do
 803           blocked
 804         else
 805           err ->
 806             Logger.debug("blocks_import failed for #{blocked_identifier} with: #{inspect(err)}")
 807             err
 808         end
 809       end
 810     )
 811   end
 812
 813   def block(blocker, %User{ap_id: ap_id} = blocked) do
 814     # sever any follow relationships to prevent leaks per activitypub (Pleroma issue #213)
 815     blocker =
 816       if following?(blocker, blocked) do
 817         {:ok, blocker, _} = unfollow(blocker, blocked)
 818         blocker
 819       else
 820         blocker
 821       end
 822
 823     if following?(blocked, blocker) do
 824       unfollow(blocked, blocker)
 825     end
 826
 827     info_cng =
 828       blocker.info
 829       |> User.Info.add_to_block(ap_id)
 830
 831     cng =
 832       change(blocker)
 833       |> put_embed(:info, info_cng)
 834
 835     update_and_set_cache(cng)
 836   end
 837
 838   # helper to handle the block given only an actor's AP id
 839   def block(blocker, %{ap_id: ap_id}) do
 840     block(blocker, User.get_by_ap_id(ap_id))
 841   end
 842
 843   def unblock(blocker, %{ap_id: ap_id}) do
 844     info_cng =
 845       blocker.info
 846       |> User.Info.remove_from_block(ap_id)
 847
 848     cng =
 849       change(blocker)
 850       |> put_embed(:info, info_cng)
 851
 852     update_and_set_cache(cng)
 853   end
 854
 855   def blocks?(user, %{ap_id: ap_id}) do
 856     blocks = user.info.blocks
 857     domain_blocks = user.info.domain_blocks
 858     %{host: host} = URI.parse(ap_id)
 859
 860     Enum.member?(blocks, ap_id) ||
 861       Enum.any?(domain_blocks, fn domain ->
 862         host == domain
 863       end)
 864   end
 865
 866   def blocked_users(user),
 867     do: Repo.all(from(u in User, where: u.ap_id in ^user.info.blocks))
 868
 869   def block_domain(user, domain) do
 870     info_cng =
 871       user.info
 872       |> User.Info.add_to_domain_block(domain)
 873
 874     cng =
 875       change(user)
 876       |> put_embed(:info, info_cng)
 877
 878     update_and_set_cache(cng)
 879   end
 880
 881   def unblock_domain(user, domain) do
 882     info_cng =
 883       user.info
 884       |> User.Info.remove_from_domain_block(domain)
 885
 886     cng =
 887       change(user)
 888       |> put_embed(:info, info_cng)
 889
 890     update_and_set_cache(cng)
 891   end
 892
 893   def local_user_query do
 894     from(
 895       u in User,
 896       where: u.local == true,
 897       where: not is_nil(u.nickname)
 898     )
 899   end
 900
 901   def active_local_user_query do
 902     from(
 903       u in local_user_query(),
 904       where: fragment("not (?->'deactivated' @> 'true')", u.info)
 905     )
 906   end
 907
 908   def moderator_user_query do
 909     from(
 910       u in User,
 911       where: u.local == true,
 912       where: fragment("?->'is_moderator' @> 'true'", u.info)
 913     )
 914   end
 915
 916   def deactivate(%User{} = user, status \\ true) do
 917     info_cng = User.Info.set_activation_status(user.info, status)
 918
 919     cng =
 920       change(user)
 921       |> put_embed(:info, info_cng)
 922
 923     update_and_set_cache(cng)
 924   end
 925
 926   def delete(%User{} = user) do
 927     {:ok, user} = User.deactivate(user)
 928
 929     # Remove all relationships
 930     {:ok, followers} = User.get_followers(user)
 931
 932     followers
 933     |> Enum.each(fn follower -> User.unfollow(follower, user) end)
 934
 935     {:ok, friends} = User.get_friends(user)
 936
 937     friends
 938     |> Enum.each(fn followed -> User.unfollow(user, followed) end)
 939
 940     query = from(a in Activity, where: a.actor == ^user.ap_id)
 941
 942     Repo.all(query)
 943     |> Enum.each(fn activity ->
 944       case activity.data["type"] do
 945         "Create" ->
 946           ActivityPub.delete(Object.normalize(activity.data["object"]))
 947
 948         # TODO: Do something with likes, follows, repeats.
 949         _ ->
 950           "Doing nothing"
 951       end
 952     end)
 953
 954     {:ok, user}
 955   end
 956
 957   def html_filter_policy(%User{info: %{no_rich_text: true}}) do
 958     Pleroma.HTML.Scrubber.TwitterText
 959   end
 960
 961   @default_scrubbers Pleroma.Config.get([:markup, :scrub_policy])
 962
 963   def html_filter_policy(_), do: @default_scrubbers
 964
 965   def get_or_fetch_by_ap_id(ap_id) do
 966     user = get_by_ap_id(ap_id)
 967
 968     if !is_nil(user) and !User.needs_update?(user) do
 969       user
 970     else
 971       ap_try = ActivityPub.make_user_from_ap_id(ap_id)
 972
 973       case ap_try do
 974         {:ok, user} ->
 975           user
 976
 977         _ ->
 978           case OStatus.make_user(ap_id) do
 979             {:ok, user} -> user
 980             _ -> {:error, "Could not fetch by AP id"}
 981           end
 982       end
 983     end
 984   end
 985
 986   def get_or_create_instance_user do
 987     relay_uri = "#{Pleroma.Web.Endpoint.url()}/relay"
 988
 989     if user = get_by_ap_id(relay_uri) do
 990       user
 991     else
 992       changes =
 993         %User{info: %User.Info{}}
 994         |> cast(%{}, [:ap_id, :nickname, :local])
 995         |> put_change(:ap_id, relay_uri)
 996         |> put_change(:nickname, nil)
 997         |> put_change(:local, true)
 998         |> put_change(:follower_address, relay_uri <> "/followers")
 999
1000       {:ok, user} = Repo.insert(changes)
1001       user
1002     end
1003   end
1004
1005   # AP style
1006   def public_key_from_info(%{
1007         source_data: %{"publicKey" => %{"publicKeyPem" => public_key_pem}}
1008       }) do
1009     key =
1010       public_key_pem
1011       |> :public_key.pem_decode()
1012       |> hd()
1013       |> :public_key.pem_entry_decode()
1014
1015     {:ok, key}
1016   end
1017
1018   # OStatus Magic Key
1019   def public_key_from_info(%{magic_key: magic_key}) do
1020     {:ok, Pleroma.Web.Salmon.decode_key(magic_key)}
1021   end
1022
1023   def get_public_key_for_ap_id(ap_id) do
1024     with %User{} = user <- get_or_fetch_by_ap_id(ap_id),
1025          {:ok, public_key} <- public_key_from_info(user.info) do
1026       {:ok, public_key}
1027     else
1028       _ -> :error
1029     end
1030   end
1031
1032   defp blank?(""), do: nil
1033   defp blank?(n), do: n
1034
1035   def insert_or_update_user(data) do
1036     data =
1037       data
1038       |> Map.put(:name, blank?(data[:name]) || data[:nickname])
1039
1040     cs = User.remote_user_creation(data)
1041
1042     Repo.insert(cs, on_conflict: :replace_all, conflict_target: :nickname)
1043   end
1044
1045   def ap_enabled?(%User{local: true}), do: true
1046   def ap_enabled?(%User{info: info}), do: info.ap_enabled
1047   def ap_enabled?(_), do: false
1048
1049   @doc "Gets or fetch a user by uri or nickname."
1050   @spec get_or_fetch(String.t()) :: User.t()
1051   def get_or_fetch("http" <> _host = uri), do: get_or_fetch_by_ap_id(uri)
1052   def get_or_fetch(nickname), do: get_or_fetch_by_nickname(nickname)
1053
1054   # wait a period of time and return newest version of the User structs
1055   # this is because we have synchronous follow APIs and need to simulate them
1056   # with an async handshake
1057   def wait_and_refresh(_, %User{local: true} = a, %User{local: true} = b) do
1058     with %User{} = a <- Repo.get(User, a.id),
1059          %User{} = b <- Repo.get(User, b.id) do
1060       {:ok, a, b}
1061     else
1062       _e ->
1063         :error
1064     end
1065   end
1066
1067   def wait_and_refresh(timeout, %User{} = a, %User{} = b) do
1068     with :ok <- :timer.sleep(timeout),
1069          %User{} = a <- Repo.get(User, a.id),
1070          %User{} = b <- Repo.get(User, b.id) do
1071       {:ok, a, b}
1072     else
1073       _e ->
1074         :error
1075     end
1076   end
1077
1078   def parse_bio(bio, user \\ %User{info: %{source_data: %{}}})
1079   def parse_bio(nil, _user), do: ""
1080   def parse_bio(bio, _user) when bio == "", do: bio
1081
1082   def parse_bio(bio, user) do
1083     mentions = Formatter.parse_mentions(bio)
1084     tags = Formatter.parse_tags(bio)
1085
1086     emoji =
1087       (user.info.source_data["tag"] || [])
1088       |> Enum.filter(fn %{"type" => t} -> t == "Emoji" end)
1089       |> Enum.map(fn %{"icon" => %{"url" => url}, "name" => name} ->
1090         {String.trim(name, ":"), url}
1091       end)
1092
1093     bio
1094     |> CommonUtils.format_input(mentions, tags, "text/plain", user_links: [format: :full])
1095     |> Formatter.emojify(emoji)
1096   end
1097
1098   def tag(user_identifiers, tags) when is_list(user_identifiers) do
1099     Repo.transaction(fn ->
1100       for user_identifier <- user_identifiers, do: tag(user_identifier, tags)
1101     end)
1102   end
1103
1104   def tag(nickname, tags) when is_binary(nickname),
1105     do: tag(User.get_by_nickname(nickname), tags)
1106
1107   def tag(%User{} = user, tags),
1108     do: update_tags(user, Enum.uniq((user.tags || []) ++ normalize_tags(tags)))
1109
1110   def untag(user_identifiers, tags) when is_list(user_identifiers) do
1111     Repo.transaction(fn ->
1112       for user_identifier <- user_identifiers, do: untag(user_identifier, tags)
1113     end)
1114   end
1115
1116   def untag(nickname, tags) when is_binary(nickname),
1117     do: untag(User.get_by_nickname(nickname), tags)
1118
1119   def untag(%User{} = user, tags),
1120     do: update_tags(user, (user.tags || []) -- normalize_tags(tags))
1121
1122   defp update_tags(%User{} = user, new_tags) do
1123     {:ok, updated_user} =
1124       user
1125       |> change(%{tags: new_tags})
1126       |> Repo.update()
1127
1128     updated_user
1129   end
1130
1131   defp normalize_tags(tags) do
1132     [tags]
1133     |> List.flatten()
1134     |> Enum.map(&String.downcase(&1))
1135   end
1136
1137   defp local_nickname_regex() do
1138     if Pleroma.Config.get([:instance, :extended_nickname_format]) do
1139       @extended_local_nickname_regex
1140     else
1141       @strict_local_nickname_regex
1142     end
1143   end
1144
1145   def local_nickname(nickname_or_mention) do
1146     nickname_or_mention
1147     |> full_nickname()
1148     |> String.split("@")
1149     |> hd()
1150   end
1151
1152   def full_nickname(nickname_or_mention),
1153     do: String.trim_leading(nickname_or_mention, "@")
1154
1155   def error_user(ap_id) do
1156     %User{
1157       name: ap_id,
1158       ap_id: ap_id,
1159       info: %User.Info{},
1160       nickname: "erroruser@example.com",
1161       inserted_at: NaiveDateTime.utc_now()
1162     }
1163   end
1164 end