git.squeep.com Git - akkoma/blob - lib/pleroma/user.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.User do
   6   use Ecto.Schema
   7
   8   import Ecto.{Changeset, Query}
   9   alias Pleroma.{Repo, User, Object, Web, Activity, Notification}
  10   alias Comeonin.Pbkdf2
  11   alias Pleroma.Formatter
  12   alias Pleroma.Web.CommonAPI.Utils, as: CommonUtils
  13   alias Pleroma.Web.{OStatus, Websub, OAuth}
  14   alias Pleroma.Web.ActivityPub.{Utils, ActivityPub}
  15
  16   require Logger
  17
  18   @type t :: %__MODULE__{}
  19
  20   @primary_key {:id, Pleroma.FlakeId, autogenerate: true}
  21
  22   @email_regex ~r/^[a-zA-Z0-9.!#$%&'*+\/=?^_`{|}~-]+@[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?(?:\.[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?)*$/
  23
  24   @strict_local_nickname_regex ~r/^[a-zA-Z\d]+$/
  25   @extended_local_nickname_regex ~r/^[a-zA-Z\d_-]+$/
  26
  27   schema "users" do
  28     field(:bio, :string)
  29     field(:email, :string)
  30     field(:name, :string)
  31     field(:nickname, :string)
  32     field(:password_hash, :string)
  33     field(:password, :string, virtual: true)
  34     field(:password_confirmation, :string, virtual: true)
  35     field(:following, {:array, :string}, default: [])
  36     field(:ap_id, :string)
  37     field(:avatar, :map)
  38     field(:local, :boolean, default: true)
  39     field(:follower_address, :string)
  40     field(:search_rank, :float, virtual: true)
  41     field(:tags, {:array, :string}, default: [])
  42     field(:last_refreshed_at, :naive_datetime)
  43     has_many(:notifications, Notification)
  44     embeds_one(:info, Pleroma.User.Info)
  45
  46     timestamps()
  47   end
  48
  49   def auth_active?(%User{local: false}), do: true
  50
  51   def auth_active?(%User{info: %User.Info{confirmation_pending: false}}), do: true
  52
  53   def auth_active?(%User{info: %User.Info{confirmation_pending: true}}),
  54     do: !Pleroma.Config.get([:instance, :account_activation_required])
  55
  56   def auth_active?(_), do: false
  57
  58   def visible_for?(user, for_user \\ nil)
  59
  60   def visible_for?(%User{id: user_id}, %User{id: for_id}) when user_id == for_id, do: true
  61
  62   def visible_for?(%User{} = user, for_user) do
  63     auth_active?(user) || superuser?(for_user)
  64   end
  65
  66   def visible_for?(_, _), do: false
  67
  68   def superuser?(%User{local: true, info: %User.Info{is_admin: true}}), do: true
  69   def superuser?(%User{local: true, info: %User.Info{is_moderator: true}}), do: true
  70   def superuser?(_), do: false
  71
  72   def avatar_url(user) do
  73     case user.avatar do
  74       %{"url" => [%{"href" => href} | _]} -> href
  75       _ -> "#{Web.base_url()}/images/avi.png"
  76     end
  77   end
  78
  79   def banner_url(user) do
  80     case user.info.banner do
  81       %{"url" => [%{"href" => href} | _]} -> href
  82       _ -> "#{Web.base_url()}/images/banner.png"
  83     end
  84   end
  85
  86   def profile_url(%User{info: %{source_data: %{"url" => url}}}), do: url
  87   def profile_url(%User{ap_id: ap_id}), do: ap_id
  88   def profile_url(_), do: nil
  89
  90   def ap_id(%User{nickname: nickname}) do
  91     "#{Web.base_url()}/users/#{nickname}"
  92   end
  93
  94   def ap_followers(%User{} = user) do
  95     "#{ap_id(user)}/followers"
  96   end
  97
  98   def follow_changeset(struct, params \\ %{}) do
  99     struct
 100     |> cast(params, [:following])
 101     |> validate_required([:following])
 102   end
 103
 104   def user_info(%User{} = user) do
 105     oneself = if user.local, do: 1, else: 0
 106
 107     %{
 108       following_count: length(user.following) - oneself,
 109       note_count: user.info.note_count,
 110       follower_count: user.info.follower_count,
 111       locked: user.info.locked,
 112       confirmation_pending: user.info.confirmation_pending,
 113       default_scope: user.info.default_scope
 114     }
 115   end
 116
 117   def remote_user_creation(params) do
 118     params =
 119       params
 120       |> Map.put(:info, params[:info] || %{})
 121
 122     info_cng = User.Info.remote_user_creation(%User.Info{}, params[:info])
 123
 124     changes =
 125       %User{}
 126       |> cast(params, [:bio, :name, :ap_id, :nickname, :avatar])
 127       |> validate_required([:name, :ap_id])
 128       |> unique_constraint(:nickname)
 129       |> validate_format(:nickname, @email_regex)
 130       |> validate_length(:bio, max: 5000)
 131       |> validate_length(:name, max: 100)
 132       |> put_change(:local, false)
 133       |> put_embed(:info, info_cng)
 134
 135     if changes.valid? do
 136       case info_cng.changes[:source_data] do
 137         %{"followers" => followers} ->
 138           changes
 139           |> put_change(:follower_address, followers)
 140
 141         _ ->
 142           followers = User.ap_followers(%User{nickname: changes.changes[:nickname]})
 143
 144           changes
 145           |> put_change(:follower_address, followers)
 146       end
 147     else
 148       changes
 149     end
 150   end
 151
 152   def update_changeset(struct, params \\ %{}) do
 153     struct
 154     |> cast(params, [:bio, :name, :avatar])
 155     |> unique_constraint(:nickname)
 156     |> validate_format(:nickname, local_nickname_regex())
 157     |> validate_length(:bio, max: 5000)
 158     |> validate_length(:name, min: 1, max: 100)
 159   end
 160
 161   def upgrade_changeset(struct, params \\ %{}) do
 162     params =
 163       params
 164       |> Map.put(:last_refreshed_at, NaiveDateTime.utc_now())
 165
 166     info_cng =
 167       struct.info
 168       |> User.Info.user_upgrade(params[:info])
 169
 170     struct
 171     |> cast(params, [:bio, :name, :follower_address, :avatar, :last_refreshed_at])
 172     |> unique_constraint(:nickname)
 173     |> validate_format(:nickname, local_nickname_regex())
 174     |> validate_length(:bio, max: 5000)
 175     |> validate_length(:name, max: 100)
 176     |> put_embed(:info, info_cng)
 177   end
 178
 179   def password_update_changeset(struct, params) do
 180     changeset =
 181       struct
 182       |> cast(params, [:password, :password_confirmation])
 183       |> validate_required([:password, :password_confirmation])
 184       |> validate_confirmation(:password)
 185
 186     OAuth.Token.delete_user_tokens(struct)
 187     OAuth.Authorization.delete_user_authorizations(struct)
 188
 189     if changeset.valid? do
 190       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 191
 192       changeset
 193       |> put_change(:password_hash, hashed)
 194     else
 195       changeset
 196     end
 197   end
 198
 199   def reset_password(user, data) do
 200     update_and_set_cache(password_update_changeset(user, data))
 201   end
 202
 203   def register_changeset(struct, params \\ %{}, opts \\ []) do
 204     confirmation_status =
 205       if opts[:confirmed] || !Pleroma.Config.get([:instance, :account_activation_required]) do
 206         :confirmed
 207       else
 208         :unconfirmed
 209       end
 210
 211     info_change = User.Info.confirmation_changeset(%User.Info{}, confirmation_status)
 212
 213     changeset =
 214       struct
 215       |> cast(params, [:bio, :email, :name, :nickname, :password, :password_confirmation])
 216       |> validate_required([:email, :name, :nickname, :password, :password_confirmation])
 217       |> validate_confirmation(:password)
 218       |> unique_constraint(:email)
 219       |> unique_constraint(:nickname)
 220       |> validate_exclusion(:nickname, Pleroma.Config.get([Pleroma.User, :restricted_nicknames]))
 221       |> validate_format(:nickname, local_nickname_regex())
 222       |> validate_format(:email, @email_regex)
 223       |> validate_length(:bio, max: 1000)
 224       |> validate_length(:name, min: 1, max: 100)
 225       |> put_change(:info, info_change)
 226
 227     if changeset.valid? do
 228       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 229       ap_id = User.ap_id(%User{nickname: changeset.changes[:nickname]})
 230       followers = User.ap_followers(%User{nickname: changeset.changes[:nickname]})
 231
 232       changeset
 233       |> put_change(:password_hash, hashed)
 234       |> put_change(:ap_id, ap_id)
 235       |> put_change(:following, [followers])
 236       |> put_change(:follower_address, followers)
 237     else
 238       changeset
 239     end
 240   end
 241
 242   defp autofollow_users(user) do
 243     candidates = Pleroma.Config.get([:instance, :autofollowed_nicknames])
 244
 245     autofollowed_users =
 246       from(u in User,
 247         where: u.local == true,
 248         where: u.nickname in ^candidates
 249       )
 250       |> Repo.all()
 251
 252     follow_all(user, autofollowed_users)
 253   end
 254
 255   @doc "Inserts provided changeset, performs post-registration actions (confirmation email sending etc.)"
 256   def register(%Ecto.Changeset{} = changeset) do
 257     with {:ok, user} <- Repo.insert(changeset),
 258          {:ok, _} <- try_send_confirmation_email(user),
 259          {:ok, user} <- autofollow_users(user) do
 260       {:ok, user}
 261     end
 262   end
 263
 264   def try_send_confirmation_email(%User{} = user) do
 265     if user.info.confirmation_pending &&
 266          Pleroma.Config.get([:instance, :account_activation_required]) do
 267       user
 268       |> Pleroma.UserEmail.account_confirmation_email()
 269       |> Pleroma.Mailer.deliver()
 270     else
 271       {:ok, :noop}
 272     end
 273   end
 274
 275   def needs_update?(%User{local: true}), do: false
 276
 277   def needs_update?(%User{local: false, last_refreshed_at: nil}), do: true
 278
 279   def needs_update?(%User{local: false} = user) do
 280     NaiveDateTime.diff(NaiveDateTime.utc_now(), user.last_refreshed_at) >= 86400
 281   end
 282
 283   def needs_update?(_), do: true
 284
 285   def maybe_direct_follow(%User{} = follower, %User{local: true, info: %{locked: true}}) do
 286     {:ok, follower}
 287   end
 288
 289   def maybe_direct_follow(%User{} = follower, %User{local: true} = followed) do
 290     follow(follower, followed)
 291   end
 292
 293   def maybe_direct_follow(%User{} = follower, %User{} = followed) do
 294     if not User.ap_enabled?(followed) do
 295       follow(follower, followed)
 296     else
 297       {:ok, follower}
 298     end
 299   end
 300
 301   def maybe_follow(%User{} = follower, %User{info: _info} = followed) do
 302     if not following?(follower, followed) do
 303       follow(follower, followed)
 304     else
 305       {:ok, follower}
 306     end
 307   end
 308
 309   @doc "A mass follow for local users. Ignores blocks and has no side effects"
 310   @spec follow_all(User.t(), list(User.t())) :: {atom(), User.t()}
 311   def follow_all(follower, followeds) do
 312     following =
 313       (follower.following ++ Enum.map(followeds, fn %{follower_address: fa} -> fa end))
 314       |> Enum.uniq()
 315
 316     {:ok, follower} =
 317       follower
 318       |> follow_changeset(%{following: following})
 319       |> update_and_set_cache
 320
 321     Enum.each(followeds, fn followed ->
 322       update_follower_count(followed)
 323     end)
 324
 325     {:ok, follower}
 326   end
 327
 328   def follow(%User{} = follower, %User{info: info} = followed) do
 329     user_config = Application.get_env(:pleroma, :user)
 330     deny_follow_blocked = Keyword.get(user_config, :deny_follow_blocked)
 331
 332     ap_followers = followed.follower_address
 333
 334     cond do
 335       following?(follower, followed) or info.deactivated ->
 336         {:error, "Could not follow user: #{followed.nickname} is already on your list."}
 337
 338       deny_follow_blocked and blocks?(followed, follower) ->
 339         {:error, "Could not follow user: #{followed.nickname} blocked you."}
 340
 341       true ->
 342         if !followed.local && follower.local && !ap_enabled?(followed) do
 343           Websub.subscribe(follower, followed)
 344         end
 345
 346         following =
 347           [ap_followers | follower.following]
 348           |> Enum.uniq()
 349
 350         follower =
 351           follower
 352           |> follow_changeset(%{following: following})
 353           |> update_and_set_cache
 354
 355         {:ok, _} = update_follower_count(followed)
 356
 357         follower
 358     end
 359   end
 360
 361   def unfollow(%User{} = follower, %User{} = followed) do
 362     ap_followers = followed.follower_address
 363
 364     if following?(follower, followed) and follower.ap_id != followed.ap_id do
 365       following =
 366         follower.following
 367         |> List.delete(ap_followers)
 368
 369       {:ok, follower} =
 370         follower
 371         |> follow_changeset(%{following: following})
 372         |> update_and_set_cache
 373
 374       {:ok, followed} = update_follower_count(followed)
 375
 376       {:ok, follower, Utils.fetch_latest_follow(follower, followed)}
 377     else
 378       {:error, "Not subscribed!"}
 379     end
 380   end
 381
 382   @spec following?(User.t(), User.t()) :: boolean
 383   def following?(%User{} = follower, %User{} = followed) do
 384     Enum.member?(follower.following, followed.follower_address)
 385   end
 386
 387   def follow_import(%User{} = follower, followed_identifiers)
 388       when is_list(followed_identifiers) do
 389     Enum.map(
 390       followed_identifiers,
 391       fn followed_identifier ->
 392         with %User{} = followed <- get_or_fetch(followed_identifier),
 393              {:ok, follower} <- maybe_direct_follow(follower, followed),
 394              {:ok, _} <- ActivityPub.follow(follower, followed) do
 395           followed
 396         else
 397           err ->
 398             Logger.debug("follow_import failed for #{followed_identifier} with: #{inspect(err)}")
 399             err
 400         end
 401       end
 402     )
 403   end
 404
 405   def locked?(%User{} = user) do
 406     user.info.locked || false
 407   end
 408
 409   def get_by_ap_id(ap_id) do
 410     Repo.get_by(User, ap_id: ap_id)
 411   end
 412
 413   # This is mostly an SPC migration fix. This guesses the user nickname (by taking the last part of the ap_id and the domain) and tries to get that user
 414   def get_by_guessed_nickname(ap_id) do
 415     domain = URI.parse(ap_id).host
 416     name = List.last(String.split(ap_id, "/"))
 417     nickname = "#{name}@#{domain}"
 418
 419     get_by_nickname(nickname)
 420   end
 421
 422   def update_and_set_cache(changeset) do
 423     with {:ok, user} <- Repo.update(changeset) do
 424       Cachex.put(:user_cache, "ap_id:#{user.ap_id}", user)
 425       Cachex.put(:user_cache, "nickname:#{user.nickname}", user)
 426       Cachex.put(:user_cache, "user_info:#{user.id}", user_info(user))
 427       {:ok, user}
 428     else
 429       e -> e
 430     end
 431   end
 432
 433   def invalidate_cache(user) do
 434     Cachex.del(:user_cache, "ap_id:#{user.ap_id}")
 435     Cachex.del(:user_cache, "nickname:#{user.nickname}")
 436     Cachex.del(:user_cache, "user_info:#{user.id}")
 437   end
 438
 439   def get_cached_by_ap_id(ap_id) do
 440     key = "ap_id:#{ap_id}"
 441     Cachex.fetch!(:user_cache, key, fn _ -> get_by_ap_id(ap_id) end)
 442   end
 443
 444   def get_cached_by_nickname(nickname) do
 445     key = "nickname:#{nickname}"
 446     Cachex.fetch!(:user_cache, key, fn _ -> get_or_fetch_by_nickname(nickname) end)
 447   end
 448
 449   def get_by_nickname(nickname) do
 450     Repo.get_by(User, nickname: nickname) ||
 451       if Regex.match?(~r(@#{Pleroma.Web.Endpoint.host()})i, nickname) do
 452         Repo.get_by(User, nickname: local_nickname(nickname))
 453       end
 454   end
 455
 456   def get_by_nickname_or_email(nickname_or_email) do
 457     case user = Repo.get_by(User, nickname: nickname_or_email) do
 458       %User{} -> user
 459       nil -> Repo.get_by(User, email: nickname_or_email)
 460     end
 461   end
 462
 463   def get_cached_user_info(user) do
 464     key = "user_info:#{user.id}"
 465     Cachex.fetch!(:user_cache, key, fn _ -> user_info(user) end)
 466   end
 467
 468   def fetch_by_nickname(nickname) do
 469     ap_try = ActivityPub.make_user_from_nickname(nickname)
 470
 471     case ap_try do
 472       {:ok, user} -> {:ok, user}
 473       _ -> OStatus.make_user(nickname)
 474     end
 475   end
 476
 477   def get_or_fetch_by_nickname(nickname) do
 478     with %User{} = user <- get_by_nickname(nickname) do
 479       user
 480     else
 481       _e ->
 482         with [_nick, _domain] <- String.split(nickname, "@"),
 483              {:ok, user} <- fetch_by_nickname(nickname) do
 484           user
 485         else
 486           _e -> nil
 487         end
 488     end
 489   end
 490
 491   def get_followers_query(%User{id: id, follower_address: follower_address}, nil) do
 492     from(
 493       u in User,
 494       where: fragment("? <@ ?", ^[follower_address], u.following),
 495       where: u.id != ^id
 496     )
 497   end
 498
 499   def get_followers_query(user, page) do
 500     from(
 501       u in get_followers_query(user, nil),
 502       limit: 20,
 503       offset: ^((page - 1) * 20)
 504     )
 505   end
 506
 507   def get_followers_query(user), do: get_followers_query(user, nil)
 508
 509   def get_followers(user, page \\ nil) do
 510     q = get_followers_query(user, page)
 511
 512     {:ok, Repo.all(q)}
 513   end
 514
 515   def get_followers_ids(user, page \\ nil) do
 516     q = get_followers_query(user, page)
 517
 518     Repo.all(from(u in q, select: u.id))
 519   end
 520
 521   def get_friends_query(%User{id: id, following: following}, nil) do
 522     from(
 523       u in User,
 524       where: u.follower_address in ^following,
 525       where: u.id != ^id
 526     )
 527   end
 528
 529   def get_friends_query(user, page) do
 530     from(
 531       u in get_friends_query(user, nil),
 532       limit: 20,
 533       offset: ^((page - 1) * 20)
 534     )
 535   end
 536
 537   def get_friends_query(user), do: get_friends_query(user, nil)
 538
 539   def get_friends(user, page \\ nil) do
 540     q = get_friends_query(user, page)
 541
 542     {:ok, Repo.all(q)}
 543   end
 544
 545   def get_friends_ids(user, page \\ nil) do
 546     q = get_friends_query(user, page)
 547
 548     Repo.all(from(u in q, select: u.id))
 549   end
 550
 551   def get_follow_requests_query(%User{} = user) do
 552     from(
 553       a in Activity,
 554       where:
 555         fragment(
 556           "? ->> 'type' = 'Follow'",
 557           a.data
 558         ),
 559       where:
 560         fragment(
 561           "? ->> 'state' = 'pending'",
 562           a.data
 563         ),
 564       where:
 565         fragment(
 566           "? @> ?",
 567           a.data,
 568           ^%{"object" => user.ap_id}
 569         )
 570     )
 571   end
 572
 573   def get_follow_requests(%User{} = user) do
 574     q = get_follow_requests_query(user)
 575     reqs = Repo.all(q)
 576
 577     users =
 578       Enum.map(reqs, fn req -> req.actor end)
 579       |> Enum.uniq()
 580       |> Enum.map(fn ap_id -> get_by_ap_id(ap_id) end)
 581       |> Enum.filter(fn u -> !is_nil(u) end)
 582       |> Enum.filter(fn u -> !following?(u, user) end)
 583
 584     {:ok, users}
 585   end
 586
 587   def increase_note_count(%User{} = user) do
 588     info_cng = User.Info.add_to_note_count(user.info, 1)
 589
 590     cng =
 591       change(user)
 592       |> put_embed(:info, info_cng)
 593
 594     update_and_set_cache(cng)
 595   end
 596
 597   def decrease_note_count(%User{} = user) do
 598     info_cng = User.Info.add_to_note_count(user.info, -1)
 599
 600     cng =
 601       change(user)
 602       |> put_embed(:info, info_cng)
 603
 604     update_and_set_cache(cng)
 605   end
 606
 607   def update_note_count(%User{} = user) do
 608     note_count_query =
 609       from(
 610         a in Object,
 611         where: fragment("?->>'actor' = ? and ?->>'type' = 'Note'", a.data, ^user.ap_id, a.data),
 612         select: count(a.id)
 613       )
 614
 615     note_count = Repo.one(note_count_query)
 616
 617     info_cng = User.Info.set_note_count(user.info, note_count)
 618
 619     cng =
 620       change(user)
 621       |> put_embed(:info, info_cng)
 622
 623     update_and_set_cache(cng)
 624   end
 625
 626   def update_follower_count(%User{} = user) do
 627     follower_count_query =
 628       from(
 629         u in User,
 630         where: ^user.follower_address in u.following,
 631         where: u.id != ^user.id,
 632         select: count(u.id)
 633       )
 634
 635     follower_count = Repo.one(follower_count_query)
 636
 637     info_cng =
 638       user.info
 639       |> User.Info.set_follower_count(follower_count)
 640
 641     cng =
 642       change(user)
 643       |> put_embed(:info, info_cng)
 644
 645     update_and_set_cache(cng)
 646   end
 647
 648   def get_users_from_set_query(ap_ids, false) do
 649     from(
 650       u in User,
 651       where: u.ap_id in ^ap_ids
 652     )
 653   end
 654
 655   def get_users_from_set_query(ap_ids, true) do
 656     query = get_users_from_set_query(ap_ids, false)
 657
 658     from(
 659       u in query,
 660       where: u.local == true
 661     )
 662   end
 663
 664   def get_users_from_set(ap_ids, local_only \\ true) do
 665     get_users_from_set_query(ap_ids, local_only)
 666     |> Repo.all()
 667   end
 668
 669   def get_recipients_from_activity(%Activity{recipients: to}) do
 670     query =
 671       from(
 672         u in User,
 673         where: u.ap_id in ^to,
 674         or_where: fragment("? && ?", u.following, ^to)
 675       )
 676
 677     query = from(u in query, where: u.local == true)
 678
 679     Repo.all(query)
 680   end
 681
 682   def search(query, resolve \\ false, for_user \\ nil) do
 683     # Strip the beginning @ off if there is a query
 684     query = String.trim_leading(query, "@")
 685
 686     if resolve, do: User.get_or_fetch_by_nickname(query)
 687
 688     fts_results = do_search(fts_search_subquery(query), for_user)
 689
 690     {:ok, trigram_results} =
 691       Repo.transaction(fn ->
 692         Ecto.Adapters.SQL.query(Repo, "select set_limit(0.25)", [])
 693         do_search(trigram_search_subquery(query), for_user)
 694       end)
 695
 696     Enum.uniq_by(fts_results ++ trigram_results, & &1.id)
 697   end
 698
 699   defp do_search(subquery, for_user, options \\ []) do
 700     q =
 701       from(
 702         s in subquery(subquery),
 703         order_by: [desc: s.search_rank],
 704         limit: ^(options[:limit] || 20)
 705       )
 706
 707     results =
 708       q
 709       |> Repo.all()
 710       |> Enum.filter(&(&1.search_rank > 0))
 711
 712     boost_search_results(results, for_user)
 713   end
 714
 715   defp fts_search_subquery(query) do
 716     processed_query =
 717       query
 718       |> String.replace(~r/\W+/, " ")
 719       |> String.trim()
 720       |> String.split()
 721       |> Enum.map(&(&1 <> ":*"))
 722       |> Enum.join(" | ")
 723
 724     from(
 725       u in User,
 726       select_merge: %{
 727         search_rank:
 728           fragment(
 729             """
 730             ts_rank_cd(
 731               setweight(to_tsvector('simple', regexp_replace(?, '\\W', ' ', 'g')), 'A') ||
 732               setweight(to_tsvector('simple', regexp_replace(coalesce(?, ''), '\\W', ' ', 'g')), 'B'),
 733               to_tsquery('simple', ?),
 734               32
 735             )
 736             """,
 737             u.nickname,
 738             u.name,
 739             ^processed_query
 740           )
 741       },
 742       where:
 743         fragment(
 744           """
 745             (setweight(to_tsvector('simple', regexp_replace(?, '\\W', ' ', 'g')), 'A') ||
 746             setweight(to_tsvector('simple', regexp_replace(coalesce(?, ''), '\\W', ' ', 'g')), 'B')) @@ to_tsquery('simple', ?)
 747           """,
 748           u.nickname,
 749           u.name,
 750           ^processed_query
 751         )
 752     )
 753   end
 754
 755   defp trigram_search_subquery(query) do
 756     from(
 757       u in User,
 758       select_merge: %{
 759         search_rank:
 760           fragment(
 761             "similarity(?, trim(? || ' ' || coalesce(?, '')))",
 762             ^query,
 763             u.nickname,
 764             u.name
 765           )
 766       },
 767       where: fragment("trim(? || ' ' || coalesce(?, '')) % ?", u.nickname, u.name, ^query)
 768     )
 769   end
 770
 771   defp boost_search_results(results, nil), do: results
 772
 773   defp boost_search_results(results, for_user) do
 774     friends_ids = get_friends_ids(for_user)
 775     followers_ids = get_followers_ids(for_user)
 776
 777     Enum.map(
 778       results,
 779       fn u ->
 780         search_rank_coef =
 781           cond do
 782             u.id in friends_ids ->
 783               1.2
 784
 785             u.id in followers_ids ->
 786               1.1
 787
 788             true ->
 789               1
 790           end
 791
 792         Map.put(u, :search_rank, u.search_rank * search_rank_coef)
 793       end
 794     )
 795     |> Enum.sort_by(&(-&1.search_rank))
 796   end
 797
 798   def blocks_import(%User{} = blocker, blocked_identifiers) when is_list(blocked_identifiers) do
 799     Enum.map(
 800       blocked_identifiers,
 801       fn blocked_identifier ->
 802         with %User{} = blocked <- get_or_fetch(blocked_identifier),
 803              {:ok, blocker} <- block(blocker, blocked),
 804              {:ok, _} <- ActivityPub.block(blocker, blocked) do
 805           blocked
 806         else
 807           err ->
 808             Logger.debug("blocks_import failed for #{blocked_identifier} with: #{inspect(err)}")
 809             err
 810         end
 811       end
 812     )
 813   end
 814
 815   def block(blocker, %User{ap_id: ap_id} = blocked) do
 816     # sever any follow relationships to prevent leaks per activitypub (Pleroma issue #213)
 817     blocker =
 818       if following?(blocker, blocked) do
 819         {:ok, blocker, _} = unfollow(blocker, blocked)
 820         blocker
 821       else
 822         blocker
 823       end
 824
 825     if following?(blocked, blocker) do
 826       unfollow(blocked, blocker)
 827     end
 828
 829     info_cng =
 830       blocker.info
 831       |> User.Info.add_to_block(ap_id)
 832
 833     cng =
 834       change(blocker)
 835       |> put_embed(:info, info_cng)
 836
 837     update_and_set_cache(cng)
 838   end
 839
 840   # helper to handle the block given only an actor's AP id
 841   def block(blocker, %{ap_id: ap_id}) do
 842     block(blocker, User.get_by_ap_id(ap_id))
 843   end
 844
 845   def unblock(blocker, %{ap_id: ap_id}) do
 846     info_cng =
 847       blocker.info
 848       |> User.Info.remove_from_block(ap_id)
 849
 850     cng =
 851       change(blocker)
 852       |> put_embed(:info, info_cng)
 853
 854     update_and_set_cache(cng)
 855   end
 856
 857   def blocks?(user, %{ap_id: ap_id}) do
 858     blocks = user.info.blocks
 859     domain_blocks = user.info.domain_blocks
 860     %{host: host} = URI.parse(ap_id)
 861
 862     Enum.member?(blocks, ap_id) ||
 863       Enum.any?(domain_blocks, fn domain ->
 864         host == domain
 865       end)
 866   end
 867
 868   def blocked_users(user),
 869     do: Repo.all(from(u in User, where: u.ap_id in ^user.info.blocks))
 870
 871   def block_domain(user, domain) do
 872     info_cng =
 873       user.info
 874       |> User.Info.add_to_domain_block(domain)
 875
 876     cng =
 877       change(user)
 878       |> put_embed(:info, info_cng)
 879
 880     update_and_set_cache(cng)
 881   end
 882
 883   def unblock_domain(user, domain) do
 884     info_cng =
 885       user.info
 886       |> User.Info.remove_from_domain_block(domain)
 887
 888     cng =
 889       change(user)
 890       |> put_embed(:info, info_cng)
 891
 892     update_and_set_cache(cng)
 893   end
 894
 895   def local_user_query do
 896     from(
 897       u in User,
 898       where: u.local == true,
 899       where: not is_nil(u.nickname)
 900     )
 901   end
 902
 903   def active_local_user_query do
 904     from(
 905       u in local_user_query(),
 906       where: fragment("not (?->'deactivated' @> 'true')", u.info)
 907     )
 908   end
 909
 910   def moderator_user_query do
 911     from(
 912       u in User,
 913       where: u.local == true,
 914       where: fragment("?->'is_moderator' @> 'true'", u.info)
 915     )
 916   end
 917
 918   def deactivate(%User{} = user, status \\ true) do
 919     info_cng = User.Info.set_activation_status(user.info, status)
 920
 921     cng =
 922       change(user)
 923       |> put_embed(:info, info_cng)
 924
 925     update_and_set_cache(cng)
 926   end
 927
 928   def delete(%User{} = user) do
 929     {:ok, user} = User.deactivate(user)
 930
 931     # Remove all relationships
 932     {:ok, followers} = User.get_followers(user)
 933
 934     followers
 935     |> Enum.each(fn follower -> User.unfollow(follower, user) end)
 936
 937     {:ok, friends} = User.get_friends(user)
 938
 939     friends
 940     |> Enum.each(fn followed -> User.unfollow(user, followed) end)
 941
 942     query = from(a in Activity, where: a.actor == ^user.ap_id)
 943
 944     Repo.all(query)
 945     |> Enum.each(fn activity ->
 946       case activity.data["type"] do
 947         "Create" ->
 948           ActivityPub.delete(Object.normalize(activity.data["object"]))
 949
 950         # TODO: Do something with likes, follows, repeats.
 951         _ ->
 952           "Doing nothing"
 953       end
 954     end)
 955
 956     {:ok, user}
 957   end
 958
 959   def html_filter_policy(%User{info: %{no_rich_text: true}}) do
 960     Pleroma.HTML.Scrubber.TwitterText
 961   end
 962
 963   @default_scrubbers Pleroma.Config.get([:markup, :scrub_policy])
 964
 965   def html_filter_policy(_), do: @default_scrubbers
 966
 967   def get_or_fetch_by_ap_id(ap_id) do
 968     user = get_by_ap_id(ap_id)
 969
 970     if !is_nil(user) and !User.needs_update?(user) do
 971       user
 972     else
 973       ap_try = ActivityPub.make_user_from_ap_id(ap_id)
 974
 975       case ap_try do
 976         {:ok, user} ->
 977           user
 978
 979         _ ->
 980           case OStatus.make_user(ap_id) do
 981             {:ok, user} -> user
 982             _ -> {:error, "Could not fetch by AP id"}
 983           end
 984       end
 985     end
 986   end
 987
 988   def get_or_create_instance_user do
 989     relay_uri = "#{Pleroma.Web.Endpoint.url()}/relay"
 990
 991     if user = get_by_ap_id(relay_uri) do
 992       user
 993     else
 994       changes =
 995         %User{info: %User.Info{}}
 996         |> cast(%{}, [:ap_id, :nickname, :local])
 997         |> put_change(:ap_id, relay_uri)
 998         |> put_change(:nickname, nil)
 999         |> put_change(:local, true)
1000         |> put_change(:follower_address, relay_uri <> "/followers")
1001
1002       {:ok, user} = Repo.insert(changes)
1003       user
1004     end
1005   end
1006
1007   # AP style
1008   def public_key_from_info(%{
1009         source_data: %{"publicKey" => %{"publicKeyPem" => public_key_pem}}
1010       }) do
1011     key =
1012       public_key_pem
1013       |> :public_key.pem_decode()
1014       |> hd()
1015       |> :public_key.pem_entry_decode()
1016
1017     {:ok, key}
1018   end
1019
1020   # OStatus Magic Key
1021   def public_key_from_info(%{magic_key: magic_key}) do
1022     {:ok, Pleroma.Web.Salmon.decode_key(magic_key)}
1023   end
1024
1025   def get_public_key_for_ap_id(ap_id) do
1026     with %User{} = user <- get_or_fetch_by_ap_id(ap_id),
1027          {:ok, public_key} <- public_key_from_info(user.info) do
1028       {:ok, public_key}
1029     else
1030       _ -> :error
1031     end
1032   end
1033
1034   defp blank?(""), do: nil
1035   defp blank?(n), do: n
1036
1037   def insert_or_update_user(data) do
1038     data =
1039       data
1040       |> Map.put(:name, blank?(data[:name]) || data[:nickname])
1041
1042     cs = User.remote_user_creation(data)
1043
1044     Repo.insert(cs, on_conflict: :replace_all, conflict_target: :nickname)
1045   end
1046
1047   def ap_enabled?(%User{local: true}), do: true
1048   def ap_enabled?(%User{info: info}), do: info.ap_enabled
1049   def ap_enabled?(_), do: false
1050
1051   @doc "Gets or fetch a user by uri or nickname."
1052   @spec get_or_fetch(String.t()) :: User.t()
1053   def get_or_fetch("http" <> _host = uri), do: get_or_fetch_by_ap_id(uri)
1054   def get_or_fetch(nickname), do: get_or_fetch_by_nickname(nickname)
1055
1056   # wait a period of time and return newest version of the User structs
1057   # this is because we have synchronous follow APIs and need to simulate them
1058   # with an async handshake
1059   def wait_and_refresh(_, %User{local: true} = a, %User{local: true} = b) do
1060     with %User{} = a <- Repo.get(User, a.id),
1061          %User{} = b <- Repo.get(User, b.id) do
1062       {:ok, a, b}
1063     else
1064       _e ->
1065         :error
1066     end
1067   end
1068
1069   def wait_and_refresh(timeout, %User{} = a, %User{} = b) do
1070     with :ok <- :timer.sleep(timeout),
1071          %User{} = a <- Repo.get(User, a.id),
1072          %User{} = b <- Repo.get(User, b.id) do
1073       {:ok, a, b}
1074     else
1075       _e ->
1076         :error
1077     end
1078   end
1079
1080   def parse_bio(bio, user \\ %User{info: %{source_data: %{}}})
1081   def parse_bio(nil, _user), do: ""
1082   def parse_bio(bio, _user) when bio == "", do: bio
1083
1084   def parse_bio(bio, user) do
1085     mentions = Formatter.parse_mentions(bio)
1086     tags = Formatter.parse_tags(bio)
1087
1088     emoji =
1089       (user.info.source_data["tag"] || [])
1090       |> Enum.filter(fn %{"type" => t} -> t == "Emoji" end)
1091       |> Enum.map(fn %{"icon" => %{"url" => url}, "name" => name} ->
1092         {String.trim(name, ":"), url}
1093       end)
1094
1095     bio
1096     |> CommonUtils.format_input(mentions, tags, "text/plain", user_links: [format: :full])
1097     |> Formatter.emojify(emoji)
1098   end
1099
1100   def tag(user_identifiers, tags) when is_list(user_identifiers) do
1101     Repo.transaction(fn ->
1102       for user_identifier <- user_identifiers, do: tag(user_identifier, tags)
1103     end)
1104   end
1105
1106   def tag(nickname, tags) when is_binary(nickname),
1107     do: tag(User.get_by_nickname(nickname), tags)
1108
1109   def tag(%User{} = user, tags),
1110     do: update_tags(user, Enum.uniq((user.tags || []) ++ normalize_tags(tags)))
1111
1112   def untag(user_identifiers, tags) when is_list(user_identifiers) do
1113     Repo.transaction(fn ->
1114       for user_identifier <- user_identifiers, do: untag(user_identifier, tags)
1115     end)
1116   end
1117
1118   def untag(nickname, tags) when is_binary(nickname),
1119     do: untag(User.get_by_nickname(nickname), tags)
1120
1121   def untag(%User{} = user, tags),
1122     do: update_tags(user, (user.tags || []) -- normalize_tags(tags))
1123
1124   defp update_tags(%User{} = user, new_tags) do
1125     {:ok, updated_user} =
1126       user
1127       |> change(%{tags: new_tags})
1128       |> Repo.update()
1129
1130     updated_user
1131   end
1132
1133   defp normalize_tags(tags) do
1134     [tags]
1135     |> List.flatten()
1136     |> Enum.map(&String.downcase(&1))
1137   end
1138
1139   defp local_nickname_regex() do
1140     if Pleroma.Config.get([:instance, :extended_nickname_format]) do
1141       @extended_local_nickname_regex
1142     else
1143       @strict_local_nickname_regex
1144     end
1145   end
1146
1147   def local_nickname(nickname_or_mention) do
1148     nickname_or_mention
1149     |> full_nickname()
1150     |> String.split("@")
1151     |> hd()
1152   end
1153
1154   def full_nickname(nickname_or_mention),
1155     do: String.trim_leading(nickname_or_mention, "@")
1156
1157   def error_user(ap_id) do
1158     %User{
1159       name: ap_id,
1160       ap_id: ap_id,
1161       info: %User.Info{},
1162       nickname: "erroruser@example.com",
1163       inserted_at: NaiveDateTime.utc_now()
1164     }
1165   end
1166 end