git.squeep.com Git - akkoma/blob - lib/pleroma/user.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.User do
   6   use Ecto.Schema
   7
   8   import Ecto.{Changeset, Query}
   9   alias Pleroma.{Repo, User, Object, Web, Activity, Notification}
  10   alias Comeonin.Pbkdf2
  11   alias Pleroma.Formatter
  12   alias Pleroma.Web.CommonAPI.Utils, as: CommonUtils
  13   alias Pleroma.Web.{OStatus, Websub, OAuth}
  14   alias Pleroma.Web.ActivityPub.{Utils, ActivityPub}
  15
  16   require Logger
  17
  18   @type t :: %__MODULE__{}
  19
  20   @email_regex ~r/^[a-zA-Z0-9.!#$%&'*+\/=?^_`{|}~-]+@[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?(?:\.[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?)*$/
  21
  22   @strict_local_nickname_regex ~r/^[a-zA-Z\d]+$/
  23   @extended_local_nickname_regex ~r/^[a-zA-Z\d_-]+$/
  24
  25   schema "users" do
  26     field(:bio, :string)
  27     field(:email, :string)
  28     field(:name, :string)
  29     field(:nickname, :string)
  30     field(:password_hash, :string)
  31     field(:password, :string, virtual: true)
  32     field(:password_confirmation, :string, virtual: true)
  33     field(:following, {:array, :string}, default: [])
  34     field(:ap_id, :string)
  35     field(:avatar, :map)
  36     field(:local, :boolean, default: true)
  37     field(:follower_address, :string)
  38     field(:search_distance, :float, virtual: true)
  39     field(:tags, {:array, :string}, default: [])
  40     field(:last_refreshed_at, :naive_datetime)
  41     has_many(:notifications, Notification)
  42     embeds_one(:info, Pleroma.User.Info)
  43
  44     timestamps()
  45   end
  46
  47   def auth_active?(%User{local: false}), do: true
  48
  49   def auth_active?(%User{info: %User.Info{confirmation_pending: false}}), do: true
  50
  51   def auth_active?(%User{info: %User.Info{confirmation_pending: true}}),
  52     do: !Pleroma.Config.get([:instance, :account_activation_required])
  53
  54   def auth_active?(_), do: false
  55
  56   def visible_for?(user, for_user \\ nil)
  57
  58   def visible_for?(%User{id: user_id}, %User{id: for_id}) when user_id == for_id, do: true
  59
  60   def visible_for?(%User{} = user, for_user) do
  61     auth_active?(user) || superuser?(for_user)
  62   end
  63
  64   def visible_for?(_, _), do: false
  65
  66   def superuser?(%User{local: true, info: %User.Info{is_admin: true}}), do: true
  67   def superuser?(%User{local: true, info: %User.Info{is_moderator: true}}), do: true
  68   def superuser?(_), do: false
  69
  70   def avatar_url(user) do
  71     case user.avatar do
  72       %{"url" => [%{"href" => href} | _]} -> href
  73       _ -> "#{Web.base_url()}/images/avi.png"
  74     end
  75   end
  76
  77   def banner_url(user) do
  78     case user.info.banner do
  79       %{"url" => [%{"href" => href} | _]} -> href
  80       _ -> "#{Web.base_url()}/images/banner.png"
  81     end
  82   end
  83
  84   def profile_url(%User{info: %{source_data: %{"url" => url}}}), do: url
  85   def profile_url(%User{ap_id: ap_id}), do: ap_id
  86   def profile_url(_), do: nil
  87
  88   def ap_id(%User{nickname: nickname}) do
  89     "#{Web.base_url()}/users/#{nickname}"
  90   end
  91
  92   def ap_followers(%User{} = user) do
  93     "#{ap_id(user)}/followers"
  94   end
  95
  96   def follow_changeset(struct, params \\ %{}) do
  97     struct
  98     |> cast(params, [:following])
  99     |> validate_required([:following])
 100   end
 101
 102   def user_info(%User{} = user) do
 103     oneself = if user.local, do: 1, else: 0
 104
 105     %{
 106       following_count: length(user.following) - oneself,
 107       note_count: user.info.note_count,
 108       follower_count: user.info.follower_count,
 109       locked: user.info.locked,
 110       confirmation_pending: user.info.confirmation_pending,
 111       default_scope: user.info.default_scope
 112     }
 113   end
 114
 115   def remote_user_creation(params) do
 116     params =
 117       params
 118       |> Map.put(:info, params[:info] || %{})
 119
 120     info_cng = User.Info.remote_user_creation(%User.Info{}, params[:info])
 121
 122     changes =
 123       %User{}
 124       |> cast(params, [:bio, :name, :ap_id, :nickname, :avatar])
 125       |> validate_required([:name, :ap_id])
 126       |> unique_constraint(:nickname)
 127       |> validate_format(:nickname, @email_regex)
 128       |> validate_length(:bio, max: 5000)
 129       |> validate_length(:name, max: 100)
 130       |> put_change(:local, false)
 131       |> put_embed(:info, info_cng)
 132
 133     if changes.valid? do
 134       case info_cng.changes[:source_data] do
 135         %{"followers" => followers} ->
 136           changes
 137           |> put_change(:follower_address, followers)
 138
 139         _ ->
 140           followers = User.ap_followers(%User{nickname: changes.changes[:nickname]})
 141
 142           changes
 143           |> put_change(:follower_address, followers)
 144       end
 145     else
 146       changes
 147     end
 148   end
 149
 150   def update_changeset(struct, params \\ %{}) do
 151     struct
 152     |> cast(params, [:bio, :name, :avatar])
 153     |> unique_constraint(:nickname)
 154     |> validate_format(:nickname, local_nickname_regex())
 155     |> validate_length(:bio, max: 5000)
 156     |> validate_length(:name, min: 1, max: 100)
 157   end
 158
 159   def upgrade_changeset(struct, params \\ %{}) do
 160     params =
 161       params
 162       |> Map.put(:last_refreshed_at, NaiveDateTime.utc_now())
 163
 164     info_cng =
 165       struct.info
 166       |> User.Info.user_upgrade(params[:info])
 167
 168     struct
 169     |> cast(params, [:bio, :name, :follower_address, :avatar, :last_refreshed_at])
 170     |> unique_constraint(:nickname)
 171     |> validate_format(:nickname, local_nickname_regex())
 172     |> validate_length(:bio, max: 5000)
 173     |> validate_length(:name, max: 100)
 174     |> put_embed(:info, info_cng)
 175   end
 176
 177   def password_update_changeset(struct, params) do
 178     changeset =
 179       struct
 180       |> cast(params, [:password, :password_confirmation])
 181       |> validate_required([:password, :password_confirmation])
 182       |> validate_confirmation(:password)
 183
 184     OAuth.Token.delete_user_tokens(struct)
 185     OAuth.Authorization.delete_user_authorizations(struct)
 186
 187     if changeset.valid? do
 188       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 189
 190       changeset
 191       |> put_change(:password_hash, hashed)
 192     else
 193       changeset
 194     end
 195   end
 196
 197   def reset_password(user, data) do
 198     update_and_set_cache(password_update_changeset(user, data))
 199   end
 200
 201   def register_changeset(struct, params \\ %{}, opts \\ []) do
 202     confirmation_status =
 203       if opts[:confirmed] || !Pleroma.Config.get([:instance, :account_activation_required]) do
 204         :confirmed
 205       else
 206         :unconfirmed
 207       end
 208
 209     info_change = User.Info.confirmation_changeset(%User.Info{}, confirmation_status)
 210
 211     changeset =
 212       struct
 213       |> cast(params, [:bio, :email, :name, :nickname, :password, :password_confirmation])
 214       |> validate_required([:email, :name, :nickname, :password, :password_confirmation])
 215       |> validate_confirmation(:password)
 216       |> unique_constraint(:email)
 217       |> unique_constraint(:nickname)
 218       |> validate_exclusion(:nickname, Pleroma.Config.get([Pleroma.User, :restricted_nicknames]))
 219       |> validate_format(:nickname, local_nickname_regex())
 220       |> validate_format(:email, @email_regex)
 221       |> validate_length(:bio, max: 1000)
 222       |> validate_length(:name, min: 1, max: 100)
 223       |> put_change(:info, info_change)
 224
 225     if changeset.valid? do
 226       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 227       ap_id = User.ap_id(%User{nickname: changeset.changes[:nickname]})
 228       followers = User.ap_followers(%User{nickname: changeset.changes[:nickname]})
 229
 230       changeset
 231       |> put_change(:password_hash, hashed)
 232       |> put_change(:ap_id, ap_id)
 233       |> put_change(:following, [followers])
 234       |> put_change(:follower_address, followers)
 235     else
 236       changeset
 237     end
 238   end
 239
 240   defp autofollow_users(user) do
 241     candidates = Pleroma.Config.get([:instance, :autofollowed_nicknames])
 242
 243     autofollowed_users =
 244       from(u in User,
 245         where: u.local == true,
 246         where: u.nickname in ^candidates
 247       )
 248       |> Repo.all()
 249
 250     autofollowed_users
 251     |> Enum.reduce({:ok, user}, fn other_user, {:ok, user} ->
 252       follow(user, other_user)
 253     end)
 254   end
 255
 256   @doc "Inserts provided changeset, performs post-registration actions (confirmation email sending etc.)"
 257   def register(%Ecto.Changeset{} = changeset) do
 258     with {:ok, user} <- Repo.insert(changeset),
 259          {:ok, _} <- try_send_confirmation_email(user),
 260          {:ok, user} <- autofollow_users(user) do
 261       {:ok, user}
 262     end
 263   end
 264
 265   def try_send_confirmation_email(%User{} = user) do
 266     if user.info.confirmation_pending &&
 267          Pleroma.Config.get([:instance, :account_activation_required]) do
 268       user
 269       |> Pleroma.UserEmail.account_confirmation_email()
 270       |> Pleroma.Mailer.deliver()
 271     else
 272       {:ok, :noop}
 273     end
 274   end
 275
 276   def needs_update?(%User{local: true}), do: false
 277
 278   def needs_update?(%User{local: false, last_refreshed_at: nil}), do: true
 279
 280   def needs_update?(%User{local: false} = user) do
 281     NaiveDateTime.diff(NaiveDateTime.utc_now(), user.last_refreshed_at) >= 86400
 282   end
 283
 284   def needs_update?(_), do: true
 285
 286   def maybe_direct_follow(%User{} = follower, %User{local: true, info: %{locked: true}}) do
 287     {:ok, follower}
 288   end
 289
 290   def maybe_direct_follow(%User{} = follower, %User{local: true} = followed) do
 291     follow(follower, followed)
 292   end
 293
 294   def maybe_direct_follow(%User{} = follower, %User{} = followed) do
 295     if not User.ap_enabled?(followed) do
 296       follow(follower, followed)
 297     else
 298       {:ok, follower}
 299     end
 300   end
 301
 302   def maybe_follow(%User{} = follower, %User{info: _info} = followed) do
 303     if not following?(follower, followed) do
 304       follow(follower, followed)
 305     else
 306       {:ok, follower}
 307     end
 308   end
 309
 310   @doc "A mass follow for local users. Ignores blocks and has no side effects"
 311   @spec follow_all(User.t(), list(User.t())) :: {atom(), User.t()}
 312   def follow_all(follower, followeds) do
 313     following =
 314       (follower.following ++ Enum.map(followeds, fn %{follower_address: fa} -> fa end))
 315       |> Enum.uniq()
 316
 317     {:ok, follower} =
 318       follower
 319       |> follow_changeset(%{following: following})
 320       |> update_and_set_cache
 321
 322     Enum.each(followeds, fn followed ->
 323       update_follower_count(followed)
 324     end)
 325
 326     {:ok, follower}
 327   end
 328
 329   def follow(%User{} = follower, %User{info: info} = followed) do
 330     user_config = Application.get_env(:pleroma, :user)
 331     deny_follow_blocked = Keyword.get(user_config, :deny_follow_blocked)
 332
 333     ap_followers = followed.follower_address
 334
 335     cond do
 336       following?(follower, followed) or info.deactivated ->
 337         {:error, "Could not follow user: #{followed.nickname} is already on your list."}
 338
 339       deny_follow_blocked and blocks?(followed, follower) ->
 340         {:error, "Could not follow user: #{followed.nickname} blocked you."}
 341
 342       true ->
 343         if !followed.local && follower.local && !ap_enabled?(followed) do
 344           Websub.subscribe(follower, followed)
 345         end
 346
 347         following =
 348           [ap_followers | follower.following]
 349           |> Enum.uniq()
 350
 351         follower =
 352           follower
 353           |> follow_changeset(%{following: following})
 354           |> update_and_set_cache
 355
 356         {:ok, _} = update_follower_count(followed)
 357
 358         follower
 359     end
 360   end
 361
 362   def unfollow(%User{} = follower, %User{} = followed) do
 363     ap_followers = followed.follower_address
 364
 365     if following?(follower, followed) and follower.ap_id != followed.ap_id do
 366       following =
 367         follower.following
 368         |> List.delete(ap_followers)
 369
 370       {:ok, follower} =
 371         follower
 372         |> follow_changeset(%{following: following})
 373         |> update_and_set_cache
 374
 375       {:ok, followed} = update_follower_count(followed)
 376
 377       {:ok, follower, Utils.fetch_latest_follow(follower, followed)}
 378     else
 379       {:error, "Not subscribed!"}
 380     end
 381   end
 382
 383   @spec following?(User.t(), User.t()) :: boolean
 384   def following?(%User{} = follower, %User{} = followed) do
 385     Enum.member?(follower.following, followed.follower_address)
 386   end
 387
 388   def follow_import(%User{} = follower, followed_identifiers)
 389       when is_list(followed_identifiers) do
 390     Enum.map(
 391       followed_identifiers,
 392       fn followed_identifier ->
 393         with %User{} = followed <- get_or_fetch(followed_identifier),
 394              {:ok, follower} <- maybe_direct_follow(follower, followed),
 395              {:ok, _} <- ActivityPub.follow(follower, followed) do
 396           followed
 397         else
 398           err ->
 399             Logger.debug("follow_import failed for #{followed_identifier} with: #{inspect(err)}")
 400             err
 401         end
 402       end
 403     )
 404   end
 405
 406   def locked?(%User{} = user) do
 407     user.info.locked || false
 408   end
 409
 410   def get_by_ap_id(ap_id) do
 411     Repo.get_by(User, ap_id: ap_id)
 412   end
 413
 414   # This is mostly an SPC migration fix. This guesses the user nickname (by taking the last part of the ap_id and the domain) and tries to get that user
 415   def get_by_guessed_nickname(ap_id) do
 416     domain = URI.parse(ap_id).host
 417     name = List.last(String.split(ap_id, "/"))
 418     nickname = "#{name}@#{domain}"
 419
 420     get_by_nickname(nickname)
 421   end
 422
 423   def update_and_set_cache(changeset) do
 424     with {:ok, user} <- Repo.update(changeset) do
 425       Cachex.put(:user_cache, "ap_id:#{user.ap_id}", user)
 426       Cachex.put(:user_cache, "nickname:#{user.nickname}", user)
 427       Cachex.put(:user_cache, "user_info:#{user.id}", user_info(user))
 428       {:ok, user}
 429     else
 430       e -> e
 431     end
 432   end
 433
 434   def invalidate_cache(user) do
 435     Cachex.del(:user_cache, "ap_id:#{user.ap_id}")
 436     Cachex.del(:user_cache, "nickname:#{user.nickname}")
 437     Cachex.del(:user_cache, "user_info:#{user.id}")
 438   end
 439
 440   def get_cached_by_ap_id(ap_id) do
 441     key = "ap_id:#{ap_id}"
 442     Cachex.fetch!(:user_cache, key, fn _ -> get_by_ap_id(ap_id) end)
 443   end
 444
 445   def get_cached_by_nickname(nickname) do
 446     key = "nickname:#{nickname}"
 447     Cachex.fetch!(:user_cache, key, fn _ -> get_or_fetch_by_nickname(nickname) end)
 448   end
 449
 450   def get_by_nickname(nickname) do
 451     Repo.get_by(User, nickname: nickname) ||
 452       if Regex.match?(~r(@#{Pleroma.Web.Endpoint.host()})i, nickname) do
 453         [local_nickname, _] = String.split(nickname, "@")
 454         Repo.get_by(User, nickname: local_nickname)
 455       end
 456   end
 457
 458   def get_by_nickname_or_email(nickname_or_email) do
 459     case user = Repo.get_by(User, nickname: nickname_or_email) do
 460       %User{} -> user
 461       nil -> Repo.get_by(User, email: nickname_or_email)
 462     end
 463   end
 464
 465   def get_cached_user_info(user) do
 466     key = "user_info:#{user.id}"
 467     Cachex.fetch!(:user_cache, key, fn _ -> user_info(user) end)
 468   end
 469
 470   def fetch_by_nickname(nickname) do
 471     ap_try = ActivityPub.make_user_from_nickname(nickname)
 472
 473     case ap_try do
 474       {:ok, user} -> {:ok, user}
 475       _ -> OStatus.make_user(nickname)
 476     end
 477   end
 478
 479   def get_or_fetch_by_nickname(nickname) do
 480     with %User{} = user <- get_by_nickname(nickname) do
 481       user
 482     else
 483       _e ->
 484         with [_nick, _domain] <- String.split(nickname, "@"),
 485              {:ok, user} <- fetch_by_nickname(nickname) do
 486           user
 487         else
 488           _e -> nil
 489         end
 490     end
 491   end
 492
 493   def get_followers_query(%User{id: id, follower_address: follower_address}) do
 494     from(
 495       u in User,
 496       where: fragment("? <@ ?", ^[follower_address], u.following),
 497       where: u.id != ^id
 498     )
 499   end
 500
 501   def get_followers(user) do
 502     q = get_followers_query(user)
 503
 504     {:ok, Repo.all(q)}
 505   end
 506
 507   def get_friends_query(%User{id: id, following: following}) do
 508     from(
 509       u in User,
 510       where: u.follower_address in ^following,
 511       where: u.id != ^id
 512     )
 513   end
 514
 515   def get_friends(user) do
 516     q = get_friends_query(user)
 517
 518     {:ok, Repo.all(q)}
 519   end
 520
 521   def get_follow_requests_query(%User{} = user) do
 522     from(
 523       a in Activity,
 524       where:
 525         fragment(
 526           "? ->> 'type' = 'Follow'",
 527           a.data
 528         ),
 529       where:
 530         fragment(
 531           "? ->> 'state' = 'pending'",
 532           a.data
 533         ),
 534       where:
 535         fragment(
 536           "? @> ?",
 537           a.data,
 538           ^%{"object" => user.ap_id}
 539         )
 540     )
 541   end
 542
 543   def get_follow_requests(%User{} = user) do
 544     q = get_follow_requests_query(user)
 545     reqs = Repo.all(q)
 546
 547     users =
 548       Enum.map(reqs, fn req -> req.actor end)
 549       |> Enum.uniq()
 550       |> Enum.map(fn ap_id -> get_by_ap_id(ap_id) end)
 551       |> Enum.filter(fn u -> !is_nil(u) end)
 552       |> Enum.filter(fn u -> !following?(u, user) end)
 553
 554     {:ok, users}
 555   end
 556
 557   def increase_note_count(%User{} = user) do
 558     info_cng = User.Info.add_to_note_count(user.info, 1)
 559
 560     cng =
 561       change(user)
 562       |> put_embed(:info, info_cng)
 563
 564     update_and_set_cache(cng)
 565   end
 566
 567   def decrease_note_count(%User{} = user) do
 568     info_cng = User.Info.add_to_note_count(user.info, -1)
 569
 570     cng =
 571       change(user)
 572       |> put_embed(:info, info_cng)
 573
 574     update_and_set_cache(cng)
 575   end
 576
 577   def update_note_count(%User{} = user) do
 578     note_count_query =
 579       from(
 580         a in Object,
 581         where: fragment("?->>'actor' = ? and ?->>'type' = 'Note'", a.data, ^user.ap_id, a.data),
 582         select: count(a.id)
 583       )
 584
 585     note_count = Repo.one(note_count_query)
 586
 587     info_cng = User.Info.set_note_count(user.info, note_count)
 588
 589     cng =
 590       change(user)
 591       |> put_embed(:info, info_cng)
 592
 593     update_and_set_cache(cng)
 594   end
 595
 596   def update_follower_count(%User{} = user) do
 597     follower_count_query =
 598       from(
 599         u in User,
 600         where: ^user.follower_address in u.following,
 601         where: u.id != ^user.id,
 602         select: count(u.id)
 603       )
 604
 605     follower_count = Repo.one(follower_count_query)
 606
 607     info_cng =
 608       user.info
 609       |> User.Info.set_follower_count(follower_count)
 610
 611     cng =
 612       change(user)
 613       |> put_embed(:info, info_cng)
 614
 615     update_and_set_cache(cng)
 616   end
 617
 618   def get_users_from_set_query(ap_ids, false) do
 619     from(
 620       u in User,
 621       where: u.ap_id in ^ap_ids
 622     )
 623   end
 624
 625   def get_users_from_set_query(ap_ids, true) do
 626     query = get_users_from_set_query(ap_ids, false)
 627
 628     from(
 629       u in query,
 630       where: u.local == true
 631     )
 632   end
 633
 634   def get_users_from_set(ap_ids, local_only \\ true) do
 635     get_users_from_set_query(ap_ids, local_only)
 636     |> Repo.all()
 637   end
 638
 639   def get_recipients_from_activity(%Activity{recipients: to}) do
 640     query =
 641       from(
 642         u in User,
 643         where: u.ap_id in ^to,
 644         or_where: fragment("? && ?", u.following, ^to)
 645       )
 646
 647     query = from(u in query, where: u.local == true)
 648
 649     Repo.all(query)
 650   end
 651
 652   def search(query, resolve \\ false) do
 653     # strip the beginning @ off if there is a query
 654     query = String.trim_leading(query, "@")
 655
 656     if resolve do
 657       User.get_or_fetch_by_nickname(query)
 658     end
 659
 660     inner =
 661       from(
 662         u in User,
 663         select_merge: %{
 664           search_distance:
 665             fragment(
 666               "? <-> (? || coalesce(?, ''))",
 667               ^query,
 668               u.nickname,
 669               u.name
 670             )
 671         },
 672         where: not is_nil(u.nickname)
 673       )
 674
 675     q =
 676       from(
 677         s in subquery(inner),
 678         order_by: s.search_distance,
 679         limit: 20
 680       )
 681
 682     Repo.all(q)
 683   end
 684
 685   def blocks_import(%User{} = blocker, blocked_identifiers) when is_list(blocked_identifiers) do
 686     Enum.map(
 687       blocked_identifiers,
 688       fn blocked_identifier ->
 689         with %User{} = blocked <- get_or_fetch(blocked_identifier),
 690              {:ok, blocker} <- block(blocker, blocked),
 691              {:ok, _} <- ActivityPub.block(blocker, blocked) do
 692           blocked
 693         else
 694           err ->
 695             Logger.debug("blocks_import failed for #{blocked_identifier} with: #{inspect(err)}")
 696             err
 697         end
 698       end
 699     )
 700   end
 701
 702   def block(blocker, %User{ap_id: ap_id} = blocked) do
 703     # sever any follow relationships to prevent leaks per activitypub (Pleroma issue #213)
 704     blocker =
 705       if following?(blocker, blocked) do
 706         {:ok, blocker, _} = unfollow(blocker, blocked)
 707         blocker
 708       else
 709         blocker
 710       end
 711
 712     if following?(blocked, blocker) do
 713       unfollow(blocked, blocker)
 714     end
 715
 716     info_cng =
 717       blocker.info
 718       |> User.Info.add_to_block(ap_id)
 719
 720     cng =
 721       change(blocker)
 722       |> put_embed(:info, info_cng)
 723
 724     update_and_set_cache(cng)
 725   end
 726
 727   # helper to handle the block given only an actor's AP id
 728   def block(blocker, %{ap_id: ap_id}) do
 729     block(blocker, User.get_by_ap_id(ap_id))
 730   end
 731
 732   def unblock(blocker, %{ap_id: ap_id}) do
 733     info_cng =
 734       blocker.info
 735       |> User.Info.remove_from_block(ap_id)
 736
 737     cng =
 738       change(blocker)
 739       |> put_embed(:info, info_cng)
 740
 741     update_and_set_cache(cng)
 742   end
 743
 744   def blocks?(user, %{ap_id: ap_id}) do
 745     blocks = user.info.blocks
 746     domain_blocks = user.info.domain_blocks
 747     %{host: host} = URI.parse(ap_id)
 748
 749     Enum.member?(blocks, ap_id) ||
 750       Enum.any?(domain_blocks, fn domain ->
 751         host == domain
 752       end)
 753   end
 754
 755   def blocked_users(user),
 756     do: Repo.all(from(u in User, where: u.ap_id in ^user.info.blocks))
 757
 758   def block_domain(user, domain) do
 759     info_cng =
 760       user.info
 761       |> User.Info.add_to_domain_block(domain)
 762
 763     cng =
 764       change(user)
 765       |> put_embed(:info, info_cng)
 766
 767     update_and_set_cache(cng)
 768   end
 769
 770   def unblock_domain(user, domain) do
 771     info_cng =
 772       user.info
 773       |> User.Info.remove_from_domain_block(domain)
 774
 775     cng =
 776       change(user)
 777       |> put_embed(:info, info_cng)
 778
 779     update_and_set_cache(cng)
 780   end
 781
 782   def local_user_query() do
 783     from(
 784       u in User,
 785       where: u.local == true,
 786       where: not is_nil(u.nickname)
 787     )
 788   end
 789
 790   def moderator_user_query() do
 791     from(
 792       u in User,
 793       where: u.local == true,
 794       where: fragment("?->'is_moderator' @> 'true'", u.info)
 795     )
 796   end
 797
 798   def deactivate(%User{} = user, status \\ true) do
 799     info_cng = User.Info.set_activation_status(user.info, status)
 800
 801     cng =
 802       change(user)
 803       |> put_embed(:info, info_cng)
 804
 805     update_and_set_cache(cng)
 806   end
 807
 808   def delete(%User{} = user) do
 809     {:ok, user} = User.deactivate(user)
 810
 811     # Remove all relationships
 812     {:ok, followers} = User.get_followers(user)
 813
 814     followers
 815     |> Enum.each(fn follower -> User.unfollow(follower, user) end)
 816
 817     {:ok, friends} = User.get_friends(user)
 818
 819     friends
 820     |> Enum.each(fn followed -> User.unfollow(user, followed) end)
 821
 822     query = from(a in Activity, where: a.actor == ^user.ap_id)
 823
 824     Repo.all(query)
 825     |> Enum.each(fn activity ->
 826       case activity.data["type"] do
 827         "Create" ->
 828           ActivityPub.delete(Object.normalize(activity.data["object"]))
 829
 830         # TODO: Do something with likes, follows, repeats.
 831         _ ->
 832           "Doing nothing"
 833       end
 834     end)
 835
 836     {:ok, user}
 837   end
 838
 839   def html_filter_policy(%User{info: %{no_rich_text: true}}) do
 840     Pleroma.HTML.Scrubber.TwitterText
 841   end
 842
 843   @default_scrubbers Pleroma.Config.get([:markup, :scrub_policy])
 844
 845   def html_filter_policy(_), do: @default_scrubbers
 846
 847   def get_or_fetch_by_ap_id(ap_id) do
 848     user = get_by_ap_id(ap_id)
 849
 850     if !is_nil(user) and !User.needs_update?(user) do
 851       user
 852     else
 853       ap_try = ActivityPub.make_user_from_ap_id(ap_id)
 854
 855       case ap_try do
 856         {:ok, user} ->
 857           user
 858
 859         _ ->
 860           case OStatus.make_user(ap_id) do
 861             {:ok, user} -> user
 862             _ -> {:error, "Could not fetch by AP id"}
 863           end
 864       end
 865     end
 866   end
 867
 868   def get_or_create_instance_user do
 869     relay_uri = "#{Pleroma.Web.Endpoint.url()}/relay"
 870
 871     if user = get_by_ap_id(relay_uri) do
 872       user
 873     else
 874       changes =
 875         %User{info: %User.Info{}}
 876         |> cast(%{}, [:ap_id, :nickname, :local])
 877         |> put_change(:ap_id, relay_uri)
 878         |> put_change(:nickname, nil)
 879         |> put_change(:local, true)
 880         |> put_change(:follower_address, relay_uri <> "/followers")
 881
 882       {:ok, user} = Repo.insert(changes)
 883       user
 884     end
 885   end
 886
 887   # AP style
 888   def public_key_from_info(%{
 889         source_data: %{"publicKey" => %{"publicKeyPem" => public_key_pem}}
 890       }) do
 891     key =
 892       public_key_pem
 893       |> :public_key.pem_decode()
 894       |> hd()
 895       |> :public_key.pem_entry_decode()
 896
 897     {:ok, key}
 898   end
 899
 900   # OStatus Magic Key
 901   def public_key_from_info(%{magic_key: magic_key}) do
 902     {:ok, Pleroma.Web.Salmon.decode_key(magic_key)}
 903   end
 904
 905   def get_public_key_for_ap_id(ap_id) do
 906     with %User{} = user <- get_or_fetch_by_ap_id(ap_id),
 907          {:ok, public_key} <- public_key_from_info(user.info) do
 908       {:ok, public_key}
 909     else
 910       _ -> :error
 911     end
 912   end
 913
 914   defp blank?(""), do: nil
 915   defp blank?(n), do: n
 916
 917   def insert_or_update_user(data) do
 918     data =
 919       data
 920       |> Map.put(:name, blank?(data[:name]) || data[:nickname])
 921
 922     cs = User.remote_user_creation(data)
 923
 924     Repo.insert(cs, on_conflict: :replace_all, conflict_target: :nickname)
 925   end
 926
 927   def ap_enabled?(%User{local: true}), do: true
 928   def ap_enabled?(%User{info: info}), do: info.ap_enabled
 929   def ap_enabled?(_), do: false
 930
 931   @doc "Gets or fetch a user by uri or nickname."
 932   @spec get_or_fetch(String.t()) :: User.t()
 933   def get_or_fetch("http" <> _host = uri), do: get_or_fetch_by_ap_id(uri)
 934   def get_or_fetch(nickname), do: get_or_fetch_by_nickname(nickname)
 935
 936   # wait a period of time and return newest version of the User structs
 937   # this is because we have synchronous follow APIs and need to simulate them
 938   # with an async handshake
 939   def wait_and_refresh(_, %User{local: true} = a, %User{local: true} = b) do
 940     with %User{} = a <- Repo.get(User, a.id),
 941          %User{} = b <- Repo.get(User, b.id) do
 942       {:ok, a, b}
 943     else
 944       _e ->
 945         :error
 946     end
 947   end
 948
 949   def wait_and_refresh(timeout, %User{} = a, %User{} = b) do
 950     with :ok <- :timer.sleep(timeout),
 951          %User{} = a <- Repo.get(User, a.id),
 952          %User{} = b <- Repo.get(User, b.id) do
 953       {:ok, a, b}
 954     else
 955       _e ->
 956         :error
 957     end
 958   end
 959
 960   def parse_bio(bio, user \\ %User{info: %{source_data: %{}}})
 961   def parse_bio(nil, _user), do: ""
 962   def parse_bio(bio, _user) when bio == "", do: bio
 963
 964   def parse_bio(bio, user) do
 965     mentions = Formatter.parse_mentions(bio)
 966     tags = Formatter.parse_tags(bio)
 967
 968     emoji =
 969       (user.info.source_data["tag"] || [])
 970       |> Enum.filter(fn %{"type" => t} -> t == "Emoji" end)
 971       |> Enum.map(fn %{"icon" => %{"url" => url}, "name" => name} ->
 972         {String.trim(name, ":"), url}
 973       end)
 974
 975     bio
 976     |> CommonUtils.format_input(mentions, tags, "text/plain")
 977     |> Formatter.emojify(emoji)
 978   end
 979
 980   def tag(user_identifiers, tags) when is_list(user_identifiers) do
 981     Repo.transaction(fn ->
 982       for user_identifier <- user_identifiers, do: tag(user_identifier, tags)
 983     end)
 984   end
 985
 986   def tag(nickname, tags) when is_binary(nickname),
 987     do: tag(User.get_by_nickname(nickname), tags)
 988
 989   def tag(%User{} = user, tags),
 990     do: update_tags(user, Enum.uniq((user.tags || []) ++ normalize_tags(tags)))
 991
 992   def untag(user_identifiers, tags) when is_list(user_identifiers) do
 993     Repo.transaction(fn ->
 994       for user_identifier <- user_identifiers, do: untag(user_identifier, tags)
 995     end)
 996   end
 997
 998   def untag(nickname, tags) when is_binary(nickname),
 999     do: untag(User.get_by_nickname(nickname), tags)
1000
1001   def untag(%User{} = user, tags),
1002     do: update_tags(user, (user.tags || []) -- normalize_tags(tags))
1003
1004   defp update_tags(%User{} = user, new_tags) do
1005     {:ok, updated_user} =
1006       user
1007       |> change(%{tags: new_tags})
1008       |> Repo.update()
1009
1010     updated_user
1011   end
1012
1013   defp normalize_tags(tags) do
1014     [tags]
1015     |> List.flatten()
1016     |> Enum.map(&String.downcase(&1))
1017   end
1018
1019   defp local_nickname_regex() do
1020     if Pleroma.Config.get([:instance, :extended_nickname_format]) do
1021       @extended_local_nickname_regex
1022     else
1023       @strict_local_nickname_regex
1024     end
1025   end
1026 end