git.squeep.com Git - akkoma/blob - lib/pleroma/user.ex

   1 defmodule Pleroma.User do
   2   use Ecto.Schema
   3
   4   import Ecto.{Changeset, Query}
   5   alias Pleroma.{Repo, User, Object, Web, Activity, Notification}
   6   alias Comeonin.Pbkdf2
   7   alias Pleroma.Web.{OStatus, Websub, OAuth}
   8   alias Pleroma.Web.ActivityPub.{Utils, ActivityPub}
   9
  10   schema "users" do
  11     field(:bio, :string)
  12     field(:email, :string)
  13     field(:name, :string)
  14     field(:nickname, :string)
  15     field(:password_hash, :string)
  16     field(:password, :string, virtual: true)
  17     field(:password_confirmation, :string, virtual: true)
  18     field(:following, {:array, :string}, default: [])
  19     field(:ap_id, :string)
  20     field(:avatar, :map)
  21     field(:local, :boolean, default: true)
  22     field(:info, :map, default: %{})
  23     field(:follower_address, :string)
  24     field(:search_distance, :float, virtual: true)
  25     field(:last_refreshed_at, :naive_datetime)
  26     has_many(:notifications, Notification)
  27
  28     timestamps()
  29   end
  30
  31   def avatar_url(user) do
  32     case user.avatar do
  33       %{"url" => [%{"href" => href} | _]} -> href
  34       _ -> "#{Web.base_url()}/images/avi.png"
  35     end
  36   end
  37
  38   def banner_url(user) do
  39     case user.info["banner"] do
  40       %{"url" => [%{"href" => href} | _]} -> href
  41       _ -> "#{Web.base_url()}/images/banner.png"
  42     end
  43   end
  44
  45   def profile_url(%User{info: %{"source_data" => %{"url" => url}}}), do: url
  46   def profile_url(%User{ap_id: ap_id}), do: ap_id
  47   def profile_url(_), do: nil
  48
  49   def ap_id(%User{nickname: nickname}) do
  50     "#{Web.base_url()}/users/#{nickname}"
  51   end
  52
  53   def ap_followers(%User{} = user) do
  54     "#{ap_id(user)}/followers"
  55   end
  56
  57   def follow_changeset(struct, params \\ %{}) do
  58     struct
  59     |> cast(params, [:following])
  60     |> validate_required([:following])
  61   end
  62
  63   def info_changeset(struct, params \\ %{}) do
  64     struct
  65     |> cast(params, [:info])
  66     |> validate_required([:info])
  67   end
  68
  69   def user_info(%User{} = user) do
  70     oneself = if user.local, do: 1, else: 0
  71
  72     %{
  73       following_count: length(user.following) - oneself,
  74       note_count: user.info["note_count"] || 0,
  75       follower_count: user.info["follower_count"] || 0,
  76       locked: user.info["locked"] || false,
  77       default_scope: user.info["default_scope"] || "public"
  78     }
  79   end
  80
  81   @email_regex ~r/^[a-zA-Z0-9.!#$%&'*+\/=?^_`{|}~-]+@[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?(?:\.[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?)*$/
  82   def remote_user_creation(params) do
  83     changes =
  84       %User{}
  85       |> cast(params, [:bio, :name, :ap_id, :nickname, :info, :avatar])
  86       |> validate_required([:name, :ap_id])
  87       |> unique_constraint(:nickname)
  88       |> validate_format(:nickname, @email_regex)
  89       |> validate_length(:bio, max: 5000)
  90       |> validate_length(:name, max: 100)
  91       |> put_change(:local, false)
  92
  93     if changes.valid? do
  94       case changes.changes[:info]["source_data"] do
  95         %{"followers" => followers} ->
  96           changes
  97           |> put_change(:follower_address, followers)
  98
  99         _ ->
 100           followers = User.ap_followers(%User{nickname: changes.changes[:nickname]})
 101
 102           changes
 103           |> put_change(:follower_address, followers)
 104       end
 105     else
 106       changes
 107     end
 108   end
 109
 110   def update_changeset(struct, params \\ %{}) do
 111     struct
 112     |> cast(params, [:bio, :name])
 113     |> unique_constraint(:nickname)
 114     |> validate_format(:nickname, ~r/^[a-zA-Z\d]+$/)
 115     |> validate_length(:bio, max: 5000)
 116     |> validate_length(:name, min: 1, max: 100)
 117   end
 118
 119   def upgrade_changeset(struct, params \\ %{}) do
 120     params =
 121       params
 122       |> Map.put(:last_refreshed_at, NaiveDateTime.utc_now())
 123
 124     struct
 125     |> cast(params, [:bio, :name, :info, :follower_address, :avatar, :last_refreshed_at])
 126     |> unique_constraint(:nickname)
 127     |> validate_format(:nickname, ~r/^[a-zA-Z\d]+$/)
 128     |> validate_length(:bio, max: 5000)
 129     |> validate_length(:name, max: 100)
 130   end
 131
 132   def password_update_changeset(struct, params) do
 133     changeset =
 134       struct
 135       |> cast(params, [:password, :password_confirmation])
 136       |> validate_required([:password, :password_confirmation])
 137       |> validate_confirmation(:password)
 138
 139     OAuth.Token.delete_user_tokens(struct)
 140     OAuth.Authorization.delete_user_authorizations(struct)
 141
 142     if changeset.valid? do
 143       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 144
 145       changeset
 146       |> put_change(:password_hash, hashed)
 147     else
 148       changeset
 149     end
 150   end
 151
 152   def reset_password(user, data) do
 153     update_and_set_cache(password_update_changeset(user, data))
 154   end
 155
 156   def register_changeset(struct, params \\ %{}) do
 157     changeset =
 158       struct
 159       |> cast(params, [:bio, :email, :name, :nickname, :password, :password_confirmation])
 160       |> validate_required([:email, :name, :nickname, :password, :password_confirmation])
 161       |> validate_confirmation(:password)
 162       |> unique_constraint(:email)
 163       |> unique_constraint(:nickname)
 164       |> validate_format(:nickname, ~r/^[a-zA-Z\d]+$/)
 165       |> validate_format(:email, @email_regex)
 166       |> validate_length(:bio, max: 1000)
 167       |> validate_length(:name, min: 1, max: 100)
 168
 169     if changeset.valid? do
 170       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 171       ap_id = User.ap_id(%User{nickname: changeset.changes[:nickname]})
 172       followers = User.ap_followers(%User{nickname: changeset.changes[:nickname]})
 173
 174       changeset
 175       |> put_change(:password_hash, hashed)
 176       |> put_change(:ap_id, ap_id)
 177       |> put_change(:following, [followers])
 178       |> put_change(:follower_address, followers)
 179     else
 180       changeset
 181     end
 182   end
 183
 184   def needs_update?(%User{local: true}), do: false
 185
 186   def needs_update?(%User{local: false, last_refreshed_at: nil}), do: true
 187
 188   def needs_update?(%User{local: false} = user) do
 189     NaiveDateTime.diff(NaiveDateTime.utc_now(), user.last_refreshed_at) >= 86400
 190   end
 191
 192   def needs_update?(_), do: true
 193
 194   def maybe_direct_follow(%User{} = follower, %User{local: true, info: %{"locked" => true}}) do
 195     {:ok, follower}
 196   end
 197
 198   def maybe_direct_follow(%User{} = follower, %User{local: true} = followed) do
 199     follow(follower, followed)
 200   end
 201
 202   def maybe_direct_follow(%User{} = follower, %User{} = followed) do
 203     if !User.ap_enabled?(followed) do
 204       follow(follower, followed)
 205     else
 206       {:ok, follower}
 207     end
 208   end
 209
 210   def maybe_follow(%User{} = follower, %User{info: info} = followed) do
 211     if not following?(follower, followed) do
 212       follow(follower, followed)
 213     else
 214       {:ok, follower}
 215     end
 216   end
 217
 218   def follow(%User{} = follower, %User{info: info} = followed) do
 219     user_config = Application.get_env(:pleroma, :user)
 220     deny_follow_blocked = Keyword.get(user_config, :deny_follow_blocked)
 221
 222     ap_followers = followed.follower_address
 223
 224     cond do
 225       following?(follower, followed) or info["deactivated"] ->
 226         {:error, "Could not follow user: #{followed.nickname} is already on your list."}
 227
 228       deny_follow_blocked and blocks?(followed, follower) ->
 229         {:error, "Could not follow user: #{followed.nickname} blocked you."}
 230
 231       true ->
 232         if !followed.local && follower.local && !ap_enabled?(followed) do
 233           Websub.subscribe(follower, followed)
 234         end
 235
 236         following =
 237           [ap_followers | follower.following]
 238           |> Enum.uniq()
 239
 240         follower =
 241           follower
 242           |> follow_changeset(%{following: following})
 243           |> update_and_set_cache
 244
 245         {:ok, _} = update_follower_count(followed)
 246
 247         follower
 248     end
 249   end
 250
 251   def unfollow(%User{} = follower, %User{} = followed) do
 252     ap_followers = followed.follower_address
 253
 254     if following?(follower, followed) and follower.ap_id != followed.ap_id do
 255       following =
 256         follower.following
 257         |> List.delete(ap_followers)
 258
 259       {:ok, follower} =
 260         follower
 261         |> follow_changeset(%{following: following})
 262         |> update_and_set_cache
 263
 264       {:ok, followed} = update_follower_count(followed)
 265
 266       {:ok, follower, Utils.fetch_latest_follow(follower, followed)}
 267     else
 268       {:error, "Not subscribed!"}
 269     end
 270   end
 271
 272   def following?(%User{} = follower, %User{} = followed) do
 273     Enum.member?(follower.following, followed.follower_address)
 274   end
 275
 276   def locked?(%User{} = user) do
 277     user.info["locked"] || false
 278   end
 279
 280   def get_by_ap_id(ap_id) do
 281     Repo.get_by(User, ap_id: ap_id)
 282   end
 283
 284   def update_and_set_cache(changeset) do
 285     with {:ok, user} <- Repo.update(changeset) do
 286       Cachex.put(:user_cache, "ap_id:#{user.ap_id}", user)
 287       Cachex.put(:user_cache, "nickname:#{user.nickname}", user)
 288       Cachex.put(:user_cache, "user_info:#{user.id}", user_info(user))
 289       {:ok, user}
 290     else
 291       e -> e
 292     end
 293   end
 294
 295   def invalidate_cache(user) do
 296     Cachex.del(:user_cache, "ap_id:#{user.ap_id}")
 297     Cachex.del(:user_cache, "nickname:#{user.nickname}")
 298   end
 299
 300   def get_cached_by_ap_id(ap_id) do
 301     key = "ap_id:#{ap_id}"
 302     Cachex.fetch!(:user_cache, key, fn _ -> get_by_ap_id(ap_id) end)
 303   end
 304
 305   def get_cached_by_nickname(nickname) do
 306     key = "nickname:#{nickname}"
 307     Cachex.fetch!(:user_cache, key, fn _ -> get_or_fetch_by_nickname(nickname) end)
 308   end
 309
 310   def get_by_nickname(nickname) do
 311     Repo.get_by(User, nickname: nickname)
 312   end
 313
 314   def get_by_nickname_or_email(nickname_or_email) do
 315     case user = Repo.get_by(User, nickname: nickname_or_email) do
 316       %User{} -> user
 317       nil -> Repo.get_by(User, email: nickname_or_email)
 318     end
 319   end
 320
 321   def get_cached_user_info(user) do
 322     key = "user_info:#{user.id}"
 323     Cachex.fetch!(:user_cache, key, fn _ -> user_info(user) end)
 324   end
 325
 326   def fetch_by_nickname(nickname) do
 327     ap_try = ActivityPub.make_user_from_nickname(nickname)
 328
 329     case ap_try do
 330       {:ok, user} -> {:ok, user}
 331       _ -> OStatus.make_user(nickname)
 332     end
 333   end
 334
 335   def get_or_fetch_by_nickname(nickname) do
 336     with %User{} = user <- get_by_nickname(nickname) do
 337       user
 338     else
 339       _e ->
 340         with [_nick, _domain] <- String.split(nickname, "@"),
 341              {:ok, user} <- fetch_by_nickname(nickname) do
 342           user
 343         else
 344           _e -> nil
 345         end
 346     end
 347   end
 348
 349   def get_followers_query(%User{id: id, follower_address: follower_address}) do
 350     from(
 351       u in User,
 352       where: fragment("? <@ ?", ^[follower_address], u.following),
 353       where: u.id != ^id
 354     )
 355   end
 356
 357   def get_followers(user) do
 358     q = get_followers_query(user)
 359
 360     {:ok, Repo.all(q)}
 361   end
 362
 363   def get_friends_query(%User{id: id, following: following}) do
 364     from(
 365       u in User,
 366       where: u.follower_address in ^following,
 367       where: u.id != ^id
 368     )
 369   end
 370
 371   def get_friends(user) do
 372     q = get_friends_query(user)
 373
 374     {:ok, Repo.all(q)}
 375   end
 376
 377   def get_follow_requests_query(%User{} = user) do
 378     from(
 379       a in Activity,
 380       where:
 381         fragment(
 382           "? ->> 'type' = 'Follow'",
 383           a.data
 384         ),
 385       where:
 386         fragment(
 387           "? ->> 'state' = 'pending'",
 388           a.data
 389         ),
 390       where:
 391         fragment(
 392           "? @> ?",
 393           a.data,
 394           ^%{"object" => user.ap_id}
 395         )
 396     )
 397   end
 398
 399   def get_follow_requests(%User{} = user) do
 400     q = get_follow_requests_query(user)
 401     reqs = Repo.all(q)
 402
 403     users =
 404       Enum.map(reqs, fn req -> req.actor end)
 405       |> Enum.uniq()
 406       |> Enum.map(fn ap_id -> get_by_ap_id(ap_id) end)
 407       |> Enum.filter(fn u -> !following?(u, user) end)
 408
 409     {:ok, users}
 410   end
 411
 412   def increase_note_count(%User{} = user) do
 413     note_count = (user.info["note_count"] || 0) + 1
 414     new_info = Map.put(user.info, "note_count", note_count)
 415
 416     cs = info_changeset(user, %{info: new_info})
 417
 418     update_and_set_cache(cs)
 419   end
 420
 421   def decrease_note_count(%User{} = user) do
 422     note_count = user.info["note_count"] || 0
 423     note_count = if note_count <= 0, do: 0, else: note_count - 1
 424     new_info = Map.put(user.info, "note_count", note_count)
 425
 426     cs = info_changeset(user, %{info: new_info})
 427
 428     update_and_set_cache(cs)
 429   end
 430
 431   def update_note_count(%User{} = user) do
 432     note_count_query =
 433       from(
 434         a in Object,
 435         where: fragment("?->>'actor' = ? and ?->>'type' = 'Note'", a.data, ^user.ap_id, a.data),
 436         select: count(a.id)
 437       )
 438
 439     note_count = Repo.one(note_count_query)
 440
 441     new_info = Map.put(user.info, "note_count", note_count)
 442
 443     cs = info_changeset(user, %{info: new_info})
 444
 445     update_and_set_cache(cs)
 446   end
 447
 448   def update_follower_count(%User{} = user) do
 449     follower_count_query =
 450       from(
 451         u in User,
 452         where: ^user.follower_address in u.following,
 453         where: u.id != ^user.id,
 454         select: count(u.id)
 455       )
 456
 457     follower_count = Repo.one(follower_count_query)
 458
 459     new_info = Map.put(user.info, "follower_count", follower_count)
 460
 461     cs = info_changeset(user, %{info: new_info})
 462
 463     update_and_set_cache(cs)
 464   end
 465
 466   def get_notified_from_activity_query(to) do
 467     from(
 468       u in User,
 469       where: u.ap_id in ^to,
 470       where: u.local == true
 471     )
 472   end
 473
 474   def get_notified_from_activity(%Activity{recipients: to, data: %{"type" => "Announce"} = data}) do
 475     object = Object.normalize(data["object"])
 476     actor = User.get_cached_by_ap_id(data["actor"])
 477
 478     # ensure that the actor who published the announced object appears only once
 479     to =
 480       if actor.nickname != nil do
 481         to ++ [object.data["actor"]]
 482       else
 483         to
 484       end
 485       |> Enum.uniq()
 486
 487     query = get_notified_from_activity_query(to)
 488
 489     Repo.all(query)
 490   end
 491
 492   def get_notified_from_activity(%Activity{recipients: to}) do
 493     query = get_notified_from_activity_query(to)
 494
 495     Repo.all(query)
 496   end
 497
 498   def get_recipients_from_activity(%Activity{recipients: to}) do
 499     query =
 500       from(
 501         u in User,
 502         where: u.ap_id in ^to,
 503         or_where: fragment("? && ?", u.following, ^to)
 504       )
 505
 506     query = from(u in query, where: u.local == true)
 507
 508     Repo.all(query)
 509   end
 510
 511   def search(query, resolve) do
 512     # strip the beginning @ off if there is a query
 513     query = String.trim_leading(query, "@")
 514
 515     if resolve do
 516       User.get_or_fetch_by_nickname(query)
 517     end
 518
 519     inner =
 520       from(
 521         u in User,
 522         select_merge: %{
 523           search_distance:
 524             fragment(
 525               "? <-> (? || ?)",
 526               ^query,
 527               u.nickname,
 528               u.name
 529             )
 530         },
 531         where: not is_nil(u.nickname)
 532       )
 533
 534     q =
 535       from(
 536         s in subquery(inner),
 537         order_by: s.search_distance,
 538         limit: 20
 539       )
 540
 541     Repo.all(q)
 542   end
 543
 544   def block(blocker, %User{ap_id: ap_id} = blocked) do
 545     # sever any follow relationships to prevent leaks per activitypub (Pleroma issue #213)
 546     blocker =
 547       if following?(blocker, blocked) do
 548         {:ok, blocker, _} = unfollow(blocker, blocked)
 549         blocker
 550       else
 551         blocker
 552       end
 553
 554     if following?(blocked, blocker) do
 555       unfollow(blocked, blocker)
 556     end
 557
 558     blocks = blocker.info["blocks"] || []
 559     new_blocks = Enum.uniq([ap_id | blocks])
 560     new_info = Map.put(blocker.info, "blocks", new_blocks)
 561
 562     cs = User.info_changeset(blocker, %{info: new_info})
 563     update_and_set_cache(cs)
 564   end
 565
 566   # helper to handle the block given only an actor's AP id
 567   def block(blocker, %{ap_id: ap_id}) do
 568     block(blocker, User.get_by_ap_id(ap_id))
 569   end
 570
 571   def unblock(user, %{ap_id: ap_id}) do
 572     blocks = user.info["blocks"] || []
 573     new_blocks = List.delete(blocks, ap_id)
 574     new_info = Map.put(user.info, "blocks", new_blocks)
 575
 576     cs = User.info_changeset(user, %{info: new_info})
 577     update_and_set_cache(cs)
 578   end
 579
 580   def blocks?(user, %{ap_id: ap_id}) do
 581     blocks = user.info["blocks"] || []
 582     domain_blocks = user.info["domain_blocks"] || []
 583     %{host: host} = URI.parse(ap_id)
 584
 585     Enum.member?(blocks, ap_id) ||
 586       Enum.any?(domain_blocks, fn domain ->
 587         host == domain
 588       end)
 589   end
 590
 591   def block_domain(user, domain) do
 592     domain_blocks = user.info["domain_blocks"] || []
 593     new_blocks = Enum.uniq([domain | domain_blocks])
 594     new_info = Map.put(user.info, "domain_blocks", new_blocks)
 595
 596     cs = User.info_changeset(user, %{info: new_info})
 597     update_and_set_cache(cs)
 598   end
 599
 600   def unblock_domain(user, domain) do
 601     blocks = user.info["domain_blocks"] || []
 602     new_blocks = List.delete(blocks, domain)
 603     new_info = Map.put(user.info, "domain_blocks", new_blocks)
 604
 605     cs = User.info_changeset(user, %{info: new_info})
 606     update_and_set_cache(cs)
 607   end
 608
 609   def local_user_query() do
 610     from(
 611       u in User,
 612       where: u.local == true,
 613       where: not is_nil(u.nickname)
 614     )
 615   end
 616
 617   def moderator_user_query() do
 618     from(
 619       u in User,
 620       where: u.local == true,
 621       where: fragment("?->'is_moderator' @> 'true'", u.info)
 622     )
 623   end
 624
 625   def deactivate(%User{} = user) do
 626     new_info = Map.put(user.info, "deactivated", true)
 627     cs = User.info_changeset(user, %{info: new_info})
 628     update_and_set_cache(cs)
 629   end
 630
 631   def delete(%User{} = user) do
 632     {:ok, user} = User.deactivate(user)
 633
 634     # Remove all relationships
 635     {:ok, followers} = User.get_followers(user)
 636
 637     followers
 638     |> Enum.each(fn follower -> User.unfollow(follower, user) end)
 639
 640     {:ok, friends} = User.get_friends(user)
 641
 642     friends
 643     |> Enum.each(fn followed -> User.unfollow(user, followed) end)
 644
 645     query = from(a in Activity, where: a.actor == ^user.ap_id)
 646
 647     Repo.all(query)
 648     |> Enum.each(fn activity ->
 649       case activity.data["type"] do
 650         "Create" ->
 651           ActivityPub.delete(Object.normalize(activity.data["object"]))
 652
 653         # TODO: Do something with likes, follows, repeats.
 654         _ ->
 655           "Doing nothing"
 656       end
 657     end)
 658
 659     :ok
 660   end
 661
 662   def html_filter_policy(%User{info: %{"no_rich_text" => true}}) do
 663     Pleroma.HTML.Scrubber.TwitterText
 664   end
 665
 666   def html_filter_policy(_), do: nil
 667
 668   def get_or_fetch_by_ap_id(ap_id) do
 669     user = get_by_ap_id(ap_id)
 670
 671     if !is_nil(user) and !User.needs_update?(user) do
 672       user
 673     else
 674       ap_try = ActivityPub.make_user_from_ap_id(ap_id)
 675
 676       case ap_try do
 677         {:ok, user} ->
 678           user
 679
 680         _ ->
 681           case OStatus.make_user(ap_id) do
 682             {:ok, user} -> user
 683             _ -> {:error, "Could not fetch by AP id"}
 684           end
 685       end
 686     end
 687   end
 688
 689   def get_or_create_instance_user do
 690     relay_uri = "#{Pleroma.Web.Endpoint.url()}/relay"
 691
 692     if user = get_by_ap_id(relay_uri) do
 693       user
 694     else
 695       changes =
 696         %User{}
 697         |> cast(%{}, [:ap_id, :nickname, :local])
 698         |> put_change(:ap_id, relay_uri)
 699         |> put_change(:nickname, nil)
 700         |> put_change(:local, true)
 701         |> put_change(:follower_address, relay_uri <> "/followers")
 702
 703       {:ok, user} = Repo.insert(changes)
 704       user
 705     end
 706   end
 707
 708   # AP style
 709   def public_key_from_info(%{
 710         "source_data" => %{"publicKey" => %{"publicKeyPem" => public_key_pem}}
 711       }) do
 712     key =
 713       :public_key.pem_decode(public_key_pem)
 714       |> hd()
 715       |> :public_key.pem_entry_decode()
 716
 717     {:ok, key}
 718   end
 719
 720   # OStatus Magic Key
 721   def public_key_from_info(%{"magic_key" => magic_key}) do
 722     {:ok, Pleroma.Web.Salmon.decode_key(magic_key)}
 723   end
 724
 725   def get_public_key_for_ap_id(ap_id) do
 726     with %User{} = user <- get_or_fetch_by_ap_id(ap_id),
 727          {:ok, public_key} <- public_key_from_info(user.info) do
 728       {:ok, public_key}
 729     else
 730       _ -> :error
 731     end
 732   end
 733
 734   defp blank?(""), do: nil
 735   defp blank?(n), do: n
 736
 737   def insert_or_update_user(data) do
 738     data =
 739       data
 740       |> Map.put(:name, blank?(data[:name]) || data[:nickname])
 741
 742     cs = User.remote_user_creation(data)
 743     Repo.insert(cs, on_conflict: :replace_all, conflict_target: :nickname)
 744   end
 745
 746   def ap_enabled?(%User{local: true}), do: true
 747   def ap_enabled?(%User{info: info}), do: info["ap_enabled"]
 748   def ap_enabled?(_), do: false
 749
 750   def get_or_fetch(uri_or_nickname) do
 751     if String.starts_with?(uri_or_nickname, "http") do
 752       get_or_fetch_by_ap_id(uri_or_nickname)
 753     else
 754       get_or_fetch_by_nickname(uri_or_nickname)
 755     end
 756   end
 757
 758   # wait a period of time and return newest version of the User structs
 759   # this is because we have synchronous follow APIs and need to simulate them
 760   # with an async handshake
 761   def wait_and_refresh(_, %User{local: true} = a, %User{local: true} = b) do
 762     with %User{} = a <- Repo.get(User, a.id),
 763          %User{} = b <- Repo.get(User, b.id) do
 764       {:ok, a, b}
 765     else
 766       _e ->
 767         :error
 768     end
 769   end
 770
 771   def wait_and_refresh(timeout, %User{} = a, %User{} = b) do
 772     with :ok <- :timer.sleep(timeout),
 773          %User{} = a <- Repo.get(User, a.id),
 774          %User{} = b <- Repo.get(User, b.id) do
 775       {:ok, a, b}
 776     else
 777       _e ->
 778         :error
 779     end
 780   end
 781 end