git.squeep.com Git - akkoma/blob - lib/pleroma/user.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.User do
   6   use Ecto.Schema
   7
   8   import Ecto.{Changeset, Query}
   9   alias Pleroma.{Repo, User, Object, Web, Activity, Notification}
  10   alias Comeonin.Pbkdf2
  11   alias Pleroma.Formatter
  12   alias Pleroma.Web.CommonAPI.Utils, as: CommonUtils
  13   alias Pleroma.Web.{OStatus, Websub, OAuth}
  14   alias Pleroma.Web.ActivityPub.{Utils, ActivityPub}
  15
  16   require Logger
  17
  18   @type t :: %__MODULE__{}
  19
  20   @email_regex ~r/^[a-zA-Z0-9.!#$%&'*+\/=?^_`{|}~-]+@[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?(?:\.[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?)*$/
  21
  22   @strict_local_nickname_regex ~r/^[a-zA-Z\d]+$/
  23   @extended_local_nickname_regex ~r/^[a-zA-Z\d_-]+$/
  24
  25   schema "users" do
  26     field(:bio, :string)
  27     field(:email, :string)
  28     field(:name, :string)
  29     field(:nickname, :string)
  30     field(:password_hash, :string)
  31     field(:password, :string, virtual: true)
  32     field(:password_confirmation, :string, virtual: true)
  33     field(:following, {:array, :string}, default: [])
  34     field(:ap_id, :string)
  35     field(:avatar, :map)
  36     field(:local, :boolean, default: true)
  37     field(:follower_address, :string)
  38     field(:search_distance, :float, virtual: true)
  39     field(:tags, {:array, :string}, default: [])
  40     field(:last_refreshed_at, :naive_datetime)
  41     has_many(:notifications, Notification)
  42     embeds_one(:info, Pleroma.User.Info)
  43
  44     timestamps()
  45   end
  46
  47   def auth_active?(%User{local: false}), do: true
  48
  49   def auth_active?(%User{info: %User.Info{confirmation_pending: false}}), do: true
  50
  51   def auth_active?(%User{info: %User.Info{confirmation_pending: true}}),
  52     do: !Pleroma.Config.get([:instance, :account_activation_required])
  53
  54   def auth_active?(_), do: false
  55
  56   def visible_for?(user, for_user \\ nil)
  57
  58   def visible_for?(%User{id: user_id}, %User{id: for_id}) when user_id == for_id, do: true
  59
  60   def visible_for?(%User{} = user, for_user) do
  61     auth_active?(user) || superuser?(for_user)
  62   end
  63
  64   def visible_for?(_, _), do: false
  65
  66   def superuser?(%User{local: true, info: %User.Info{is_admin: true}}), do: true
  67   def superuser?(%User{local: true, info: %User.Info{is_moderator: true}}), do: true
  68   def superuser?(_), do: false
  69
  70   def avatar_url(user) do
  71     case user.avatar do
  72       %{"url" => [%{"href" => href} | _]} -> href
  73       _ -> "#{Web.base_url()}/images/avi.png"
  74     end
  75   end
  76
  77   def banner_url(user) do
  78     case user.info.banner do
  79       %{"url" => [%{"href" => href} | _]} -> href
  80       _ -> "#{Web.base_url()}/images/banner.png"
  81     end
  82   end
  83
  84   def profile_url(%User{info: %{source_data: %{"url" => url}}}), do: url
  85   def profile_url(%User{ap_id: ap_id}), do: ap_id
  86   def profile_url(_), do: nil
  87
  88   def ap_id(%User{nickname: nickname}) do
  89     "#{Web.base_url()}/users/#{nickname}"
  90   end
  91
  92   def ap_followers(%User{} = user) do
  93     "#{ap_id(user)}/followers"
  94   end
  95
  96   def follow_changeset(struct, params \\ %{}) do
  97     struct
  98     |> cast(params, [:following])
  99     |> validate_required([:following])
 100   end
 101
 102   def user_info(%User{} = user) do
 103     oneself = if user.local, do: 1, else: 0
 104
 105     %{
 106       following_count: length(user.following) - oneself,
 107       note_count: user.info.note_count,
 108       follower_count: user.info.follower_count,
 109       locked: user.info.locked,
 110       confirmation_pending: user.info.confirmation_pending,
 111       default_scope: user.info.default_scope
 112     }
 113   end
 114
 115   def remote_user_creation(params) do
 116     params =
 117       params
 118       |> Map.put(:info, params[:info] || %{})
 119
 120     info_cng = User.Info.remote_user_creation(%User.Info{}, params[:info])
 121
 122     changes =
 123       %User{}
 124       |> cast(params, [:bio, :name, :ap_id, :nickname, :avatar])
 125       |> validate_required([:name, :ap_id])
 126       |> unique_constraint(:nickname)
 127       |> validate_format(:nickname, @email_regex)
 128       |> validate_length(:bio, max: 5000)
 129       |> validate_length(:name, max: 100)
 130       |> put_change(:local, false)
 131       |> put_embed(:info, info_cng)
 132
 133     if changes.valid? do
 134       case info_cng.changes[:source_data] do
 135         %{"followers" => followers} ->
 136           changes
 137           |> put_change(:follower_address, followers)
 138
 139         _ ->
 140           followers = User.ap_followers(%User{nickname: changes.changes[:nickname]})
 141
 142           changes
 143           |> put_change(:follower_address, followers)
 144       end
 145     else
 146       changes
 147     end
 148   end
 149
 150   def update_changeset(struct, params \\ %{}) do
 151     struct
 152     |> cast(params, [:bio, :name, :avatar])
 153     |> unique_constraint(:nickname)
 154     |> validate_format(:nickname, local_nickname_regex())
 155     |> validate_length(:bio, max: 5000)
 156     |> validate_length(:name, min: 1, max: 100)
 157   end
 158
 159   def upgrade_changeset(struct, params \\ %{}) do
 160     params =
 161       params
 162       |> Map.put(:last_refreshed_at, NaiveDateTime.utc_now())
 163
 164     info_cng =
 165       struct.info
 166       |> User.Info.user_upgrade(params[:info])
 167
 168     struct
 169     |> cast(params, [:bio, :name, :follower_address, :avatar, :last_refreshed_at])
 170     |> unique_constraint(:nickname)
 171     |> validate_format(:nickname, local_nickname_regex())
 172     |> validate_length(:bio, max: 5000)
 173     |> validate_length(:name, max: 100)
 174     |> put_embed(:info, info_cng)
 175   end
 176
 177   def password_update_changeset(struct, params) do
 178     changeset =
 179       struct
 180       |> cast(params, [:password, :password_confirmation])
 181       |> validate_required([:password, :password_confirmation])
 182       |> validate_confirmation(:password)
 183
 184     OAuth.Token.delete_user_tokens(struct)
 185     OAuth.Authorization.delete_user_authorizations(struct)
 186
 187     if changeset.valid? do
 188       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 189
 190       changeset
 191       |> put_change(:password_hash, hashed)
 192     else
 193       changeset
 194     end
 195   end
 196
 197   def reset_password(user, data) do
 198     update_and_set_cache(password_update_changeset(user, data))
 199   end
 200
 201   def register_changeset(struct, params \\ %{}, opts \\ []) do
 202     confirmation_status =
 203       if opts[:confirmed] || !Pleroma.Config.get([:instance, :account_activation_required]) do
 204         :confirmed
 205       else
 206         :unconfirmed
 207       end
 208
 209     info_change = User.Info.confirmation_changeset(%User.Info{}, confirmation_status)
 210
 211     changeset =
 212       struct
 213       |> cast(params, [:bio, :email, :name, :nickname, :password, :password_confirmation])
 214       |> validate_required([:email, :name, :nickname, :password, :password_confirmation])
 215       |> validate_confirmation(:password)
 216       |> unique_constraint(:email)
 217       |> unique_constraint(:nickname)
 218       |> validate_exclusion(:nickname, Pleroma.Config.get([Pleroma.User, :restricted_nicknames]))
 219       |> validate_format(:nickname, local_nickname_regex())
 220       |> validate_format(:email, @email_regex)
 221       |> validate_length(:bio, max: 1000)
 222       |> validate_length(:name, min: 1, max: 100)
 223       |> put_change(:info, info_change)
 224
 225     if changeset.valid? do
 226       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 227       ap_id = User.ap_id(%User{nickname: changeset.changes[:nickname]})
 228       followers = User.ap_followers(%User{nickname: changeset.changes[:nickname]})
 229
 230       changeset
 231       |> put_change(:password_hash, hashed)
 232       |> put_change(:ap_id, ap_id)
 233       |> put_change(:following, [followers])
 234       |> put_change(:follower_address, followers)
 235     else
 236       changeset
 237     end
 238   end
 239
 240   defp autofollow_users(user) do
 241     candidates = Pleroma.Config.get([:instance, :autofollowed_nicknames])
 242
 243     autofollowed_users =
 244       from(u in User,
 245         where: u.local == true,
 246         where: u.nickname in ^candidates
 247       )
 248       |> Repo.all()
 249
 250     autofollowed_users
 251     |> Enum.reduce({:ok, user}, fn other_user, {:ok, user} ->
 252       follow(user, other_user)
 253     end)
 254   end
 255
 256   @doc "Inserts provided changeset, performs post-registration actions (confirmation email sending etc.)"
 257   def register(%Ecto.Changeset{} = changeset) do
 258     with {:ok, user} <- Repo.insert(changeset),
 259          {:ok, _} <- try_send_confirmation_email(user),
 260          {:ok, user} <- autofollow_users(user) do
 261       {:ok, user}
 262     end
 263   end
 264
 265   def try_send_confirmation_email(%User{} = user) do
 266     if user.info.confirmation_pending &&
 267          Pleroma.Config.get([:instance, :account_activation_required]) do
 268       user
 269       |> Pleroma.UserEmail.account_confirmation_email()
 270       |> Pleroma.Mailer.deliver()
 271     else
 272       {:ok, :noop}
 273     end
 274   end
 275
 276   def needs_update?(%User{local: true}), do: false
 277
 278   def needs_update?(%User{local: false, last_refreshed_at: nil}), do: true
 279
 280   def needs_update?(%User{local: false} = user) do
 281     NaiveDateTime.diff(NaiveDateTime.utc_now(), user.last_refreshed_at) >= 86400
 282   end
 283
 284   def needs_update?(_), do: true
 285
 286   def maybe_direct_follow(%User{} = follower, %User{local: true, info: %{locked: true}}) do
 287     {:ok, follower}
 288   end
 289
 290   def maybe_direct_follow(%User{} = follower, %User{local: true} = followed) do
 291     follow(follower, followed)
 292   end
 293
 294   def maybe_direct_follow(%User{} = follower, %User{} = followed) do
 295     if not User.ap_enabled?(followed) do
 296       follow(follower, followed)
 297     else
 298       {:ok, follower}
 299     end
 300   end
 301
 302   def maybe_follow(%User{} = follower, %User{info: _info} = followed) do
 303     if not following?(follower, followed) do
 304       follow(follower, followed)
 305     else
 306       {:ok, follower}
 307     end
 308   end
 309
 310   def follow(%User{} = follower, %User{info: info} = followed) do
 311     user_config = Application.get_env(:pleroma, :user)
 312     deny_follow_blocked = Keyword.get(user_config, :deny_follow_blocked)
 313
 314     ap_followers = followed.follower_address
 315
 316     cond do
 317       following?(follower, followed) or info.deactivated ->
 318         {:error, "Could not follow user: #{followed.nickname} is already on your list."}
 319
 320       deny_follow_blocked and blocks?(followed, follower) ->
 321         {:error, "Could not follow user: #{followed.nickname} blocked you."}
 322
 323       true ->
 324         if !followed.local && follower.local && !ap_enabled?(followed) do
 325           Websub.subscribe(follower, followed)
 326         end
 327
 328         following =
 329           [ap_followers | follower.following]
 330           |> Enum.uniq()
 331
 332         follower =
 333           follower
 334           |> follow_changeset(%{following: following})
 335           |> update_and_set_cache
 336
 337         {:ok, _} = update_follower_count(followed)
 338
 339         follower
 340     end
 341   end
 342
 343   def unfollow(%User{} = follower, %User{} = followed) do
 344     ap_followers = followed.follower_address
 345
 346     if following?(follower, followed) and follower.ap_id != followed.ap_id do
 347       following =
 348         follower.following
 349         |> List.delete(ap_followers)
 350
 351       {:ok, follower} =
 352         follower
 353         |> follow_changeset(%{following: following})
 354         |> update_and_set_cache
 355
 356       {:ok, followed} = update_follower_count(followed)
 357
 358       {:ok, follower, Utils.fetch_latest_follow(follower, followed)}
 359     else
 360       {:error, "Not subscribed!"}
 361     end
 362   end
 363
 364   @spec following?(User.t(), User.t()) :: boolean
 365   def following?(%User{} = follower, %User{} = followed) do
 366     Enum.member?(follower.following, followed.follower_address)
 367   end
 368
 369   def follow_import(%User{} = follower, followed_identifiers)
 370       when is_list(followed_identifiers) do
 371     Enum.map(
 372       followed_identifiers,
 373       fn followed_identifier ->
 374         with %User{} = followed <- get_or_fetch(followed_identifier),
 375              {:ok, follower} <- maybe_direct_follow(follower, followed),
 376              {:ok, _} <- ActivityPub.follow(follower, followed) do
 377           followed
 378         else
 379           err ->
 380             Logger.debug("follow_import failed for #{followed_identifier} with: #{inspect(err)}")
 381             err
 382         end
 383       end
 384     )
 385   end
 386
 387   def locked?(%User{} = user) do
 388     user.info.locked || false
 389   end
 390
 391   def get_by_ap_id(ap_id) do
 392     Repo.get_by(User, ap_id: ap_id)
 393   end
 394
 395   # This is mostly an SPC migration fix. This guesses the user nickname (by taking the last part of the ap_id and the domain) and tries to get that user
 396   def get_by_guessed_nickname(ap_id) do
 397     domain = URI.parse(ap_id).host
 398     name = List.last(String.split(ap_id, "/"))
 399     nickname = "#{name}@#{domain}"
 400
 401     get_by_nickname(nickname)
 402   end
 403
 404   def update_and_set_cache(changeset) do
 405     with {:ok, user} <- Repo.update(changeset) do
 406       Cachex.put(:user_cache, "ap_id:#{user.ap_id}", user)
 407       Cachex.put(:user_cache, "nickname:#{user.nickname}", user)
 408       Cachex.put(:user_cache, "user_info:#{user.id}", user_info(user))
 409       {:ok, user}
 410     else
 411       e -> e
 412     end
 413   end
 414
 415   def invalidate_cache(user) do
 416     Cachex.del(:user_cache, "ap_id:#{user.ap_id}")
 417     Cachex.del(:user_cache, "nickname:#{user.nickname}")
 418     Cachex.del(:user_cache, "user_info:#{user.id}")
 419   end
 420
 421   def get_cached_by_ap_id(ap_id) do
 422     key = "ap_id:#{ap_id}"
 423     Cachex.fetch!(:user_cache, key, fn _ -> get_by_ap_id(ap_id) end)
 424   end
 425
 426   def get_cached_by_nickname(nickname) do
 427     key = "nickname:#{nickname}"
 428     Cachex.fetch!(:user_cache, key, fn _ -> get_or_fetch_by_nickname(nickname) end)
 429   end
 430
 431   def get_by_nickname(nickname) do
 432     Repo.get_by(User, nickname: nickname) ||
 433       if Regex.match?(~r(@#{Pleroma.Web.Endpoint.host()})i, nickname) do
 434         [local_nickname, _] = String.split(nickname, "@")
 435         Repo.get_by(User, nickname: local_nickname)
 436       end
 437   end
 438
 439   def get_by_nickname_or_email(nickname_or_email) do
 440     case user = Repo.get_by(User, nickname: nickname_or_email) do
 441       %User{} -> user
 442       nil -> Repo.get_by(User, email: nickname_or_email)
 443     end
 444   end
 445
 446   def get_cached_user_info(user) do
 447     key = "user_info:#{user.id}"
 448     Cachex.fetch!(:user_cache, key, fn _ -> user_info(user) end)
 449   end
 450
 451   def fetch_by_nickname(nickname) do
 452     ap_try = ActivityPub.make_user_from_nickname(nickname)
 453
 454     case ap_try do
 455       {:ok, user} -> {:ok, user}
 456       _ -> OStatus.make_user(nickname)
 457     end
 458   end
 459
 460   def get_or_fetch_by_nickname(nickname) do
 461     with %User{} = user <- get_by_nickname(nickname) do
 462       user
 463     else
 464       _e ->
 465         with [_nick, _domain] <- String.split(nickname, "@"),
 466              {:ok, user} <- fetch_by_nickname(nickname) do
 467           user
 468         else
 469           _e -> nil
 470         end
 471     end
 472   end
 473
 474   def get_followers_query(%User{id: id, follower_address: follower_address}) do
 475     from(
 476       u in User,
 477       where: fragment("? <@ ?", ^[follower_address], u.following),
 478       where: u.id != ^id
 479     )
 480   end
 481
 482   def get_followers(user) do
 483     q = get_followers_query(user)
 484
 485     {:ok, Repo.all(q)}
 486   end
 487
 488   def get_friends_query(%User{id: id, following: following}) do
 489     from(
 490       u in User,
 491       where: u.follower_address in ^following,
 492       where: u.id != ^id
 493     )
 494   end
 495
 496   def get_friends(user) do
 497     q = get_friends_query(user)
 498
 499     {:ok, Repo.all(q)}
 500   end
 501
 502   def get_follow_requests_query(%User{} = user) do
 503     from(
 504       a in Activity,
 505       where:
 506         fragment(
 507           "? ->> 'type' = 'Follow'",
 508           a.data
 509         ),
 510       where:
 511         fragment(
 512           "? ->> 'state' = 'pending'",
 513           a.data
 514         ),
 515       where:
 516         fragment(
 517           "? @> ?",
 518           a.data,
 519           ^%{"object" => user.ap_id}
 520         )
 521     )
 522   end
 523
 524   def get_follow_requests(%User{} = user) do
 525     q = get_follow_requests_query(user)
 526     reqs = Repo.all(q)
 527
 528     users =
 529       Enum.map(reqs, fn req -> req.actor end)
 530       |> Enum.uniq()
 531       |> Enum.map(fn ap_id -> get_by_ap_id(ap_id) end)
 532       |> Enum.filter(fn u -> !is_nil(u) end)
 533       |> Enum.filter(fn u -> !following?(u, user) end)
 534
 535     {:ok, users}
 536   end
 537
 538   def increase_note_count(%User{} = user) do
 539     info_cng = User.Info.add_to_note_count(user.info, 1)
 540
 541     cng =
 542       change(user)
 543       |> put_embed(:info, info_cng)
 544
 545     update_and_set_cache(cng)
 546   end
 547
 548   def decrease_note_count(%User{} = user) do
 549     info_cng = User.Info.add_to_note_count(user.info, -1)
 550
 551     cng =
 552       change(user)
 553       |> put_embed(:info, info_cng)
 554
 555     update_and_set_cache(cng)
 556   end
 557
 558   def update_note_count(%User{} = user) do
 559     note_count_query =
 560       from(
 561         a in Object,
 562         where: fragment("?->>'actor' = ? and ?->>'type' = 'Note'", a.data, ^user.ap_id, a.data),
 563         select: count(a.id)
 564       )
 565
 566     note_count = Repo.one(note_count_query)
 567
 568     info_cng = User.Info.set_note_count(user.info, note_count)
 569
 570     cng =
 571       change(user)
 572       |> put_embed(:info, info_cng)
 573
 574     update_and_set_cache(cng)
 575   end
 576
 577   def update_follower_count(%User{} = user) do
 578     follower_count_query =
 579       from(
 580         u in User,
 581         where: ^user.follower_address in u.following,
 582         where: u.id != ^user.id,
 583         select: count(u.id)
 584       )
 585
 586     follower_count = Repo.one(follower_count_query)
 587
 588     info_cng =
 589       user.info
 590       |> User.Info.set_follower_count(follower_count)
 591
 592     cng =
 593       change(user)
 594       |> put_embed(:info, info_cng)
 595
 596     update_and_set_cache(cng)
 597   end
 598
 599   def get_users_from_set_query(ap_ids, false) do
 600     from(
 601       u in User,
 602       where: u.ap_id in ^ap_ids
 603     )
 604   end
 605
 606   def get_users_from_set_query(ap_ids, true) do
 607     query = get_users_from_set_query(ap_ids, false)
 608
 609     from(
 610       u in query,
 611       where: u.local == true
 612     )
 613   end
 614
 615   def get_users_from_set(ap_ids, local_only \\ true) do
 616     get_users_from_set_query(ap_ids, local_only)
 617     |> Repo.all()
 618   end
 619
 620   def get_recipients_from_activity(%Activity{recipients: to}) do
 621     query =
 622       from(
 623         u in User,
 624         where: u.ap_id in ^to,
 625         or_where: fragment("? && ?", u.following, ^to)
 626       )
 627
 628     query = from(u in query, where: u.local == true)
 629
 630     Repo.all(query)
 631   end
 632
 633   def search(query, resolve \\ false) do
 634     # strip the beginning @ off if there is a query
 635     query = String.trim_leading(query, "@")
 636
 637     if resolve do
 638       User.get_or_fetch_by_nickname(query)
 639     end
 640
 641     inner =
 642       from(
 643         u in User,
 644         select_merge: %{
 645           search_distance:
 646             fragment(
 647               "? <-> (? || coalesce(?, ''))",
 648               ^query,
 649               u.nickname,
 650               u.name
 651             )
 652         },
 653         where: not is_nil(u.nickname)
 654       )
 655
 656     q =
 657       from(
 658         s in subquery(inner),
 659         order_by: s.search_distance,
 660         limit: 20
 661       )
 662
 663     Repo.all(q)
 664   end
 665
 666   def blocks_import(%User{} = blocker, blocked_identifiers) when is_list(blocked_identifiers) do
 667     Enum.map(
 668       blocked_identifiers,
 669       fn blocked_identifier ->
 670         with %User{} = blocked <- get_or_fetch(blocked_identifier),
 671              {:ok, blocker} <- block(blocker, blocked),
 672              {:ok, _} <- ActivityPub.block(blocker, blocked) do
 673           blocked
 674         else
 675           err ->
 676             Logger.debug("blocks_import failed for #{blocked_identifier} with: #{inspect(err)}")
 677             err
 678         end
 679       end
 680     )
 681   end
 682
 683   def block(blocker, %User{ap_id: ap_id} = blocked) do
 684     # sever any follow relationships to prevent leaks per activitypub (Pleroma issue #213)
 685     blocker =
 686       if following?(blocker, blocked) do
 687         {:ok, blocker, _} = unfollow(blocker, blocked)
 688         blocker
 689       else
 690         blocker
 691       end
 692
 693     if following?(blocked, blocker) do
 694       unfollow(blocked, blocker)
 695     end
 696
 697     info_cng =
 698       blocker.info
 699       |> User.Info.add_to_block(ap_id)
 700
 701     cng =
 702       change(blocker)
 703       |> put_embed(:info, info_cng)
 704
 705     update_and_set_cache(cng)
 706   end
 707
 708   # helper to handle the block given only an actor's AP id
 709   def block(blocker, %{ap_id: ap_id}) do
 710     block(blocker, User.get_by_ap_id(ap_id))
 711   end
 712
 713   def unblock(blocker, %{ap_id: ap_id}) do
 714     info_cng =
 715       blocker.info
 716       |> User.Info.remove_from_block(ap_id)
 717
 718     cng =
 719       change(blocker)
 720       |> put_embed(:info, info_cng)
 721
 722     update_and_set_cache(cng)
 723   end
 724
 725   def blocks?(user, %{ap_id: ap_id}) do
 726     blocks = user.info.blocks
 727     domain_blocks = user.info.domain_blocks
 728     %{host: host} = URI.parse(ap_id)
 729
 730     Enum.member?(blocks, ap_id) ||
 731       Enum.any?(domain_blocks, fn domain ->
 732         host == domain
 733       end)
 734   end
 735
 736   def blocked_users(user),
 737     do: Repo.all(from(u in User, where: u.ap_id in ^user.info.blocks))
 738
 739   def block_domain(user, domain) do
 740     info_cng =
 741       user.info
 742       |> User.Info.add_to_domain_block(domain)
 743
 744     cng =
 745       change(user)
 746       |> put_embed(:info, info_cng)
 747
 748     update_and_set_cache(cng)
 749   end
 750
 751   def unblock_domain(user, domain) do
 752     info_cng =
 753       user.info
 754       |> User.Info.remove_from_domain_block(domain)
 755
 756     cng =
 757       change(user)
 758       |> put_embed(:info, info_cng)
 759
 760     update_and_set_cache(cng)
 761   end
 762
 763   def local_user_query() do
 764     from(
 765       u in User,
 766       where: u.local == true,
 767       where: not is_nil(u.nickname)
 768     )
 769   end
 770
 771   def moderator_user_query() do
 772     from(
 773       u in User,
 774       where: u.local == true,
 775       where: fragment("?->'is_moderator' @> 'true'", u.info)
 776     )
 777   end
 778
 779   def deactivate(%User{} = user, status \\ true) do
 780     info_cng = User.Info.set_activation_status(user.info, status)
 781
 782     cng =
 783       change(user)
 784       |> put_embed(:info, info_cng)
 785
 786     update_and_set_cache(cng)
 787   end
 788
 789   def delete(%User{} = user) do
 790     {:ok, user} = User.deactivate(user)
 791
 792     # Remove all relationships
 793     {:ok, followers} = User.get_followers(user)
 794
 795     followers
 796     |> Enum.each(fn follower -> User.unfollow(follower, user) end)
 797
 798     {:ok, friends} = User.get_friends(user)
 799
 800     friends
 801     |> Enum.each(fn followed -> User.unfollow(user, followed) end)
 802
 803     query = from(a in Activity, where: a.actor == ^user.ap_id)
 804
 805     Repo.all(query)
 806     |> Enum.each(fn activity ->
 807       case activity.data["type"] do
 808         "Create" ->
 809           ActivityPub.delete(Object.normalize(activity.data["object"]))
 810
 811         # TODO: Do something with likes, follows, repeats.
 812         _ ->
 813           "Doing nothing"
 814       end
 815     end)
 816
 817     {:ok, user}
 818   end
 819
 820   def html_filter_policy(%User{info: %{no_rich_text: true}}) do
 821     Pleroma.HTML.Scrubber.TwitterText
 822   end
 823
 824   @default_scrubbers Pleroma.Config.get([:markup, :scrub_policy])
 825
 826   def html_filter_policy(_), do: @default_scrubbers
 827
 828   def get_or_fetch_by_ap_id(ap_id) do
 829     user = get_by_ap_id(ap_id)
 830
 831     if !is_nil(user) and !User.needs_update?(user) do
 832       user
 833     else
 834       ap_try = ActivityPub.make_user_from_ap_id(ap_id)
 835
 836       case ap_try do
 837         {:ok, user} ->
 838           user
 839
 840         _ ->
 841           case OStatus.make_user(ap_id) do
 842             {:ok, user} -> user
 843             _ -> {:error, "Could not fetch by AP id"}
 844           end
 845       end
 846     end
 847   end
 848
 849   def get_or_create_instance_user do
 850     relay_uri = "#{Pleroma.Web.Endpoint.url()}/relay"
 851
 852     if user = get_by_ap_id(relay_uri) do
 853       user
 854     else
 855       changes =
 856         %User{info: %User.Info{}}
 857         |> cast(%{}, [:ap_id, :nickname, :local])
 858         |> put_change(:ap_id, relay_uri)
 859         |> put_change(:nickname, nil)
 860         |> put_change(:local, true)
 861         |> put_change(:follower_address, relay_uri <> "/followers")
 862
 863       {:ok, user} = Repo.insert(changes)
 864       user
 865     end
 866   end
 867
 868   # AP style
 869   def public_key_from_info(%{
 870         source_data: %{"publicKey" => %{"publicKeyPem" => public_key_pem}}
 871       }) do
 872     key =
 873       public_key_pem
 874       |> :public_key.pem_decode()
 875       |> hd()
 876       |> :public_key.pem_entry_decode()
 877
 878     {:ok, key}
 879   end
 880
 881   # OStatus Magic Key
 882   def public_key_from_info(%{magic_key: magic_key}) do
 883     {:ok, Pleroma.Web.Salmon.decode_key(magic_key)}
 884   end
 885
 886   def get_public_key_for_ap_id(ap_id) do
 887     with %User{} = user <- get_or_fetch_by_ap_id(ap_id),
 888          {:ok, public_key} <- public_key_from_info(user.info) do
 889       {:ok, public_key}
 890     else
 891       _ -> :error
 892     end
 893   end
 894
 895   defp blank?(""), do: nil
 896   defp blank?(n), do: n
 897
 898   def insert_or_update_user(data) do
 899     data =
 900       data
 901       |> Map.put(:name, blank?(data[:name]) || data[:nickname])
 902
 903     cs = User.remote_user_creation(data)
 904
 905     Repo.insert(cs, on_conflict: :replace_all, conflict_target: :nickname)
 906   end
 907
 908   def ap_enabled?(%User{local: true}), do: true
 909   def ap_enabled?(%User{info: info}), do: info.ap_enabled
 910   def ap_enabled?(_), do: false
 911
 912   @doc "Gets or fetch a user by uri or nickname."
 913   @spec get_or_fetch(String.t()) :: User.t()
 914   def get_or_fetch("http" <> _host = uri), do: get_or_fetch_by_ap_id(uri)
 915   def get_or_fetch(nickname), do: get_or_fetch_by_nickname(nickname)
 916
 917   # wait a period of time and return newest version of the User structs
 918   # this is because we have synchronous follow APIs and need to simulate them
 919   # with an async handshake
 920   def wait_and_refresh(_, %User{local: true} = a, %User{local: true} = b) do
 921     with %User{} = a <- Repo.get(User, a.id),
 922          %User{} = b <- Repo.get(User, b.id) do
 923       {:ok, a, b}
 924     else
 925       _e ->
 926         :error
 927     end
 928   end
 929
 930   def wait_and_refresh(timeout, %User{} = a, %User{} = b) do
 931     with :ok <- :timer.sleep(timeout),
 932          %User{} = a <- Repo.get(User, a.id),
 933          %User{} = b <- Repo.get(User, b.id) do
 934       {:ok, a, b}
 935     else
 936       _e ->
 937         :error
 938     end
 939   end
 940
 941   def parse_bio(bio, user \\ %User{info: %{source_data: %{}}})
 942   def parse_bio(nil, _user), do: ""
 943   def parse_bio(bio, _user) when bio == "", do: bio
 944
 945   def parse_bio(bio, user) do
 946     mentions = Formatter.parse_mentions(bio)
 947     tags = Formatter.parse_tags(bio)
 948
 949     emoji =
 950       (user.info.source_data["tag"] || [])
 951       |> Enum.filter(fn %{"type" => t} -> t == "Emoji" end)
 952       |> Enum.map(fn %{"icon" => %{"url" => url}, "name" => name} ->
 953         {String.trim(name, ":"), url}
 954       end)
 955
 956     bio
 957     |> CommonUtils.format_input(mentions, tags, "text/plain")
 958     |> Formatter.emojify(emoji)
 959   end
 960
 961   def tag(user_identifiers, tags) when is_list(user_identifiers) do
 962     Repo.transaction(fn ->
 963       for user_identifier <- user_identifiers, do: tag(user_identifier, tags)
 964     end)
 965   end
 966
 967   def tag(nickname, tags) when is_binary(nickname),
 968     do: tag(User.get_by_nickname(nickname), tags)
 969
 970   def tag(%User{} = user, tags),
 971     do: update_tags(user, Enum.uniq((user.tags || []) ++ normalize_tags(tags)))
 972
 973   def untag(user_identifiers, tags) when is_list(user_identifiers) do
 974     Repo.transaction(fn ->
 975       for user_identifier <- user_identifiers, do: untag(user_identifier, tags)
 976     end)
 977   end
 978
 979   def untag(nickname, tags) when is_binary(nickname),
 980     do: untag(User.get_by_nickname(nickname), tags)
 981
 982   def untag(%User{} = user, tags),
 983     do: update_tags(user, (user.tags || []) -- normalize_tags(tags))
 984
 985   defp update_tags(%User{} = user, new_tags) do
 986     {:ok, updated_user} =
 987       user
 988       |> change(%{tags: new_tags})
 989       |> Repo.update()
 990
 991     updated_user
 992   end
 993
 994   defp normalize_tags(tags) do
 995     [tags]
 996     |> List.flatten()
 997     |> Enum.map(&String.downcase(&1))
 998   end
 999
1000   defp local_nickname_regex() do
1001     if Pleroma.Config.get([:instance, :extended_nickname_format]) do
1002       @extended_local_nickname_regex
1003     else
1004       @strict_local_nickname_regex
1005     end
1006   end
1007 end