git.squeep.com Git - akkoma/blob - lib/pleroma/user.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.User do
   6   use Ecto.Schema
   7
   8   import Ecto.{Changeset, Query}
   9   alias Pleroma.{Repo, User, Object, Web, Activity, Notification}
  10   alias Comeonin.Pbkdf2
  11   alias Pleroma.Formatter
  12   alias Pleroma.Web.CommonAPI.Utils, as: CommonUtils
  13   alias Pleroma.Web.{OStatus, Websub, OAuth}
  14   alias Pleroma.Web.ActivityPub.{Utils, ActivityPub}
  15
  16   require Logger
  17
  18   @type t :: %__MODULE__{}
  19
  20   @email_regex ~r/^[a-zA-Z0-9.!#$%&'*+\/=?^_`{|}~-]+@[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?(?:\.[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?)*$/
  21
  22   @strict_local_nickname_regex ~r/^[a-zA-Z\d]+$/
  23   @extended_local_nickname_regex ~r/^[a-zA-Z\d_-]+$/
  24
  25   schema "users" do
  26     field(:bio, :string)
  27     field(:email, :string)
  28     field(:name, :string)
  29     field(:nickname, :string)
  30     field(:password_hash, :string)
  31     field(:password, :string, virtual: true)
  32     field(:password_confirmation, :string, virtual: true)
  33     field(:following, {:array, :string}, default: [])
  34     field(:ap_id, :string)
  35     field(:avatar, :map)
  36     field(:local, :boolean, default: true)
  37     field(:follower_address, :string)
  38     field(:search_distance, :float, virtual: true)
  39     field(:tags, {:array, :string}, default: [])
  40     field(:last_refreshed_at, :naive_datetime)
  41     has_many(:notifications, Notification)
  42     embeds_one(:info, Pleroma.User.Info)
  43
  44     timestamps()
  45   end
  46
  47   def auth_active?(%User{} = user) do
  48     (user.info && !user.info.confirmation_pending) ||
  49       !Pleroma.Config.get([:instance, :account_activation_required])
  50   end
  51
  52   def remote_or_auth_active?(%User{} = user), do: !user.local || auth_active?(user)
  53
  54   def visible_for?(%User{} = user, for_user \\ nil) do
  55     User.remote_or_auth_active?(user) || (for_user && for_user.id == user.id) ||
  56       User.superuser?(for_user)
  57   end
  58
  59   def superuser?(nil), do: false
  60   def superuser?(%User{} = user), do: user.info && User.Info.superuser?(user.info)
  61
  62   def avatar_url(user) do
  63     case user.avatar do
  64       %{"url" => [%{"href" => href} | _]} -> href
  65       _ -> "#{Web.base_url()}/images/avi.png"
  66     end
  67   end
  68
  69   def banner_url(user) do
  70     case user.info.banner do
  71       %{"url" => [%{"href" => href} | _]} -> href
  72       _ -> "#{Web.base_url()}/images/banner.png"
  73     end
  74   end
  75
  76   def profile_url(%User{info: %{source_data: %{"url" => url}}}), do: url
  77   def profile_url(%User{ap_id: ap_id}), do: ap_id
  78   def profile_url(_), do: nil
  79
  80   def ap_id(%User{nickname: nickname}) do
  81     "#{Web.base_url()}/users/#{nickname}"
  82   end
  83
  84   def ap_followers(%User{} = user) do
  85     "#{ap_id(user)}/followers"
  86   end
  87
  88   def follow_changeset(struct, params \\ %{}) do
  89     struct
  90     |> cast(params, [:following])
  91     |> validate_required([:following])
  92   end
  93
  94   def user_info(%User{} = user) do
  95     oneself = if user.local, do: 1, else: 0
  96
  97     %{
  98       following_count: length(user.following) - oneself,
  99       note_count: user.info.note_count,
 100       follower_count: user.info.follower_count,
 101       locked: user.info.locked,
 102       confirmation_pending: user.info.confirmation_pending,
 103       default_scope: user.info.default_scope
 104     }
 105   end
 106
 107   def remote_user_creation(params) do
 108     params =
 109       params
 110       |> Map.put(:info, params[:info] || %{})
 111
 112     info_cng = User.Info.remote_user_creation(%User.Info{}, params[:info])
 113
 114     changes =
 115       %User{}
 116       |> cast(params, [:bio, :name, :ap_id, :nickname, :avatar])
 117       |> validate_required([:name, :ap_id])
 118       |> unique_constraint(:nickname)
 119       |> validate_format(:nickname, @email_regex)
 120       |> validate_length(:bio, max: 5000)
 121       |> validate_length(:name, max: 100)
 122       |> put_change(:local, false)
 123       |> put_embed(:info, info_cng)
 124
 125     if changes.valid? do
 126       case info_cng.changes[:source_data] do
 127         %{"followers" => followers} ->
 128           changes
 129           |> put_change(:follower_address, followers)
 130
 131         _ ->
 132           followers = User.ap_followers(%User{nickname: changes.changes[:nickname]})
 133
 134           changes
 135           |> put_change(:follower_address, followers)
 136       end
 137     else
 138       changes
 139     end
 140   end
 141
 142   def update_changeset(struct, params \\ %{}) do
 143     struct
 144     |> cast(params, [:bio, :name, :avatar])
 145     |> unique_constraint(:nickname)
 146     |> validate_format(:nickname, local_nickname_regex())
 147     |> validate_length(:bio, max: 5000)
 148     |> validate_length(:name, min: 1, max: 100)
 149   end
 150
 151   def upgrade_changeset(struct, params \\ %{}) do
 152     params =
 153       params
 154       |> Map.put(:last_refreshed_at, NaiveDateTime.utc_now())
 155
 156     info_cng =
 157       struct.info
 158       |> User.Info.user_upgrade(params[:info])
 159
 160     struct
 161     |> cast(params, [:bio, :name, :follower_address, :avatar, :last_refreshed_at])
 162     |> unique_constraint(:nickname)
 163     |> validate_format(:nickname, local_nickname_regex())
 164     |> validate_length(:bio, max: 5000)
 165     |> validate_length(:name, max: 100)
 166     |> put_embed(:info, info_cng)
 167   end
 168
 169   def password_update_changeset(struct, params) do
 170     changeset =
 171       struct
 172       |> cast(params, [:password, :password_confirmation])
 173       |> validate_required([:password, :password_confirmation])
 174       |> validate_confirmation(:password)
 175
 176     OAuth.Token.delete_user_tokens(struct)
 177     OAuth.Authorization.delete_user_authorizations(struct)
 178
 179     if changeset.valid? do
 180       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 181
 182       changeset
 183       |> put_change(:password_hash, hashed)
 184     else
 185       changeset
 186     end
 187   end
 188
 189   def reset_password(user, data) do
 190     update_and_set_cache(password_update_changeset(user, data))
 191   end
 192
 193   def register_changeset(struct, params \\ %{}, opts \\ []) do
 194     confirmation_status =
 195       if opts[:confirmed] || !Pleroma.Config.get([:instance, :account_activation_required]) do
 196         :confirmed
 197       else
 198         :unconfirmed
 199       end
 200
 201     info_change = User.Info.confirmation_changeset(%User.Info{}, confirmation_status)
 202
 203     changeset =
 204       struct
 205       |> cast(params, [:bio, :email, :name, :nickname, :password, :password_confirmation])
 206       |> validate_required([:email, :name, :nickname, :password, :password_confirmation])
 207       |> validate_confirmation(:password)
 208       |> unique_constraint(:email)
 209       |> unique_constraint(:nickname)
 210       |> validate_exclusion(:nickname, Pleroma.Config.get([Pleroma.User, :restricted_nicknames]))
 211       |> validate_format(:nickname, local_nickname_regex())
 212       |> validate_format(:email, @email_regex)
 213       |> validate_length(:bio, max: 1000)
 214       |> validate_length(:name, min: 1, max: 100)
 215       |> put_change(:info, info_change)
 216
 217     if changeset.valid? do
 218       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 219       ap_id = User.ap_id(%User{nickname: changeset.changes[:nickname]})
 220       followers = User.ap_followers(%User{nickname: changeset.changes[:nickname]})
 221
 222       changeset
 223       |> put_change(:password_hash, hashed)
 224       |> put_change(:ap_id, ap_id)
 225       |> put_change(:following, [followers])
 226       |> put_change(:follower_address, followers)
 227     else
 228       changeset
 229     end
 230   end
 231
 232   @doc "Inserts provided changeset, performs post-registration actions (confirmation email sending etc.)"
 233   def register(%Ecto.Changeset{} = changeset) do
 234     with {:ok, user} <- Repo.insert(changeset),
 235          {:ok, _} = try_send_confirmation_email(user) do
 236       {:ok, user}
 237     end
 238   end
 239
 240   def try_send_confirmation_email(%User{} = user) do
 241     if user.info.confirmation_pending &&
 242          Pleroma.Config.get([:instance, :account_activation_required]) do
 243       user
 244       |> Pleroma.UserEmail.account_confirmation_email()
 245       |> Pleroma.Mailer.deliver()
 246     else
 247       {:ok, :noop}
 248     end
 249   end
 250
 251   def needs_update?(%User{local: true}), do: false
 252
 253   def needs_update?(%User{local: false, last_refreshed_at: nil}), do: true
 254
 255   def needs_update?(%User{local: false} = user) do
 256     NaiveDateTime.diff(NaiveDateTime.utc_now(), user.last_refreshed_at) >= 86400
 257   end
 258
 259   def needs_update?(_), do: true
 260
 261   def maybe_direct_follow(%User{} = follower, %User{local: true, info: %{locked: true}}) do
 262     {:ok, follower}
 263   end
 264
 265   def maybe_direct_follow(%User{} = follower, %User{local: true} = followed) do
 266     follow(follower, followed)
 267   end
 268
 269   def maybe_direct_follow(%User{} = follower, %User{} = followed) do
 270     if not User.ap_enabled?(followed) do
 271       follow(follower, followed)
 272     else
 273       {:ok, follower}
 274     end
 275   end
 276
 277   def maybe_follow(%User{} = follower, %User{info: _info} = followed) do
 278     if not following?(follower, followed) do
 279       follow(follower, followed)
 280     else
 281       {:ok, follower}
 282     end
 283   end
 284
 285   def follow(%User{} = follower, %User{info: info} = followed) do
 286     user_config = Application.get_env(:pleroma, :user)
 287     deny_follow_blocked = Keyword.get(user_config, :deny_follow_blocked)
 288
 289     ap_followers = followed.follower_address
 290
 291     cond do
 292       following?(follower, followed) or info.deactivated ->
 293         {:error, "Could not follow user: #{followed.nickname} is already on your list."}
 294
 295       deny_follow_blocked and blocks?(followed, follower) ->
 296         {:error, "Could not follow user: #{followed.nickname} blocked you."}
 297
 298       true ->
 299         if !followed.local && follower.local && !ap_enabled?(followed) do
 300           Websub.subscribe(follower, followed)
 301         end
 302
 303         following =
 304           [ap_followers | follower.following]
 305           |> Enum.uniq()
 306
 307         follower =
 308           follower
 309           |> follow_changeset(%{following: following})
 310           |> update_and_set_cache
 311
 312         {:ok, _} = update_follower_count(followed)
 313
 314         follower
 315     end
 316   end
 317
 318   def unfollow(%User{} = follower, %User{} = followed) do
 319     ap_followers = followed.follower_address
 320
 321     if following?(follower, followed) and follower.ap_id != followed.ap_id do
 322       following =
 323         follower.following
 324         |> List.delete(ap_followers)
 325
 326       {:ok, follower} =
 327         follower
 328         |> follow_changeset(%{following: following})
 329         |> update_and_set_cache
 330
 331       {:ok, followed} = update_follower_count(followed)
 332
 333       {:ok, follower, Utils.fetch_latest_follow(follower, followed)}
 334     else
 335       {:error, "Not subscribed!"}
 336     end
 337   end
 338
 339   @spec following?(User.t(), User.t()) :: boolean
 340   def following?(%User{} = follower, %User{} = followed) do
 341     Enum.member?(follower.following, followed.follower_address)
 342   end
 343
 344   def follow_import(%User{} = follower, followed_identifiers)
 345       when is_list(followed_identifiers) do
 346     Enum.map(
 347       followed_identifiers,
 348       fn followed_identifier ->
 349         with %User{} = followed <- get_or_fetch(followed_identifier),
 350              {:ok, follower} <- maybe_direct_follow(follower, followed),
 351              {:ok, _} <- ActivityPub.follow(follower, followed) do
 352           followed
 353         else
 354           err ->
 355             Logger.debug("follow_import failed for #{followed_identifier} with: #{inspect(err)}")
 356             err
 357         end
 358       end
 359     )
 360   end
 361
 362   def locked?(%User{} = user) do
 363     user.info.locked || false
 364   end
 365
 366   def get_by_ap_id(ap_id) do
 367     Repo.get_by(User, ap_id: ap_id)
 368   end
 369
 370   def update_and_set_cache(changeset) do
 371     with {:ok, user} <- Repo.update(changeset) do
 372       Cachex.put(:user_cache, "ap_id:#{user.ap_id}", user)
 373       Cachex.put(:user_cache, "nickname:#{user.nickname}", user)
 374       Cachex.put(:user_cache, "user_info:#{user.id}", user_info(user))
 375       {:ok, user}
 376     else
 377       e -> e
 378     end
 379   end
 380
 381   def invalidate_cache(user) do
 382     Cachex.del(:user_cache, "ap_id:#{user.ap_id}")
 383     Cachex.del(:user_cache, "nickname:#{user.nickname}")
 384     Cachex.del(:user_cache, "user_info:#{user.id}")
 385   end
 386
 387   def get_cached_by_ap_id(ap_id) do
 388     key = "ap_id:#{ap_id}"
 389     Cachex.fetch!(:user_cache, key, fn _ -> get_by_ap_id(ap_id) end)
 390   end
 391
 392   def get_cached_by_nickname(nickname) do
 393     key = "nickname:#{nickname}"
 394     Cachex.fetch!(:user_cache, key, fn _ -> get_or_fetch_by_nickname(nickname) end)
 395   end
 396
 397   def get_by_nickname(nickname) do
 398     Repo.get_by(User, nickname: nickname) ||
 399       if Regex.match?(~r(@#{Pleroma.Web.Endpoint.host()})i, nickname) do
 400         [local_nickname, _] = String.split(nickname, "@")
 401         Repo.get_by(User, nickname: local_nickname)
 402       end
 403   end
 404
 405   def get_by_nickname_or_email(nickname_or_email) do
 406     case user = Repo.get_by(User, nickname: nickname_or_email) do
 407       %User{} -> user
 408       nil -> Repo.get_by(User, email: nickname_or_email)
 409     end
 410   end
 411
 412   def get_cached_user_info(user) do
 413     key = "user_info:#{user.id}"
 414     Cachex.fetch!(:user_cache, key, fn _ -> user_info(user) end)
 415   end
 416
 417   def fetch_by_nickname(nickname) do
 418     ap_try = ActivityPub.make_user_from_nickname(nickname)
 419
 420     case ap_try do
 421       {:ok, user} -> {:ok, user}
 422       _ -> OStatus.make_user(nickname)
 423     end
 424   end
 425
 426   def get_or_fetch_by_nickname(nickname) do
 427     with %User{} = user <- get_by_nickname(nickname) do
 428       user
 429     else
 430       _e ->
 431         with [_nick, _domain] <- String.split(nickname, "@"),
 432              {:ok, user} <- fetch_by_nickname(nickname) do
 433           user
 434         else
 435           _e -> nil
 436         end
 437     end
 438   end
 439
 440   def get_followers_query(%User{id: id, follower_address: follower_address}) do
 441     from(
 442       u in User,
 443       where: fragment("? <@ ?", ^[follower_address], u.following),
 444       where: u.id != ^id
 445     )
 446   end
 447
 448   def get_followers(user) do
 449     q = get_followers_query(user)
 450
 451     {:ok, Repo.all(q)}
 452   end
 453
 454   def get_friends_query(%User{id: id, following: following}) do
 455     from(
 456       u in User,
 457       where: u.follower_address in ^following,
 458       where: u.id != ^id
 459     )
 460   end
 461
 462   def get_friends(user) do
 463     q = get_friends_query(user)
 464
 465     {:ok, Repo.all(q)}
 466   end
 467
 468   def get_follow_requests_query(%User{} = user) do
 469     from(
 470       a in Activity,
 471       where:
 472         fragment(
 473           "? ->> 'type' = 'Follow'",
 474           a.data
 475         ),
 476       where:
 477         fragment(
 478           "? ->> 'state' = 'pending'",
 479           a.data
 480         ),
 481       where:
 482         fragment(
 483           "? @> ?",
 484           a.data,
 485           ^%{"object" => user.ap_id}
 486         )
 487     )
 488   end
 489
 490   def get_follow_requests(%User{} = user) do
 491     q = get_follow_requests_query(user)
 492     reqs = Repo.all(q)
 493
 494     users =
 495       Enum.map(reqs, fn req -> req.actor end)
 496       |> Enum.uniq()
 497       |> Enum.map(fn ap_id -> get_by_ap_id(ap_id) end)
 498       |> Enum.filter(fn u -> !is_nil(u) end)
 499       |> Enum.filter(fn u -> !following?(u, user) end)
 500
 501     {:ok, users}
 502   end
 503
 504   def increase_note_count(%User{} = user) do
 505     info_cng = User.Info.add_to_note_count(user.info, 1)
 506
 507     cng =
 508       change(user)
 509       |> put_embed(:info, info_cng)
 510
 511     update_and_set_cache(cng)
 512   end
 513
 514   def decrease_note_count(%User{} = user) do
 515     info_cng = User.Info.add_to_note_count(user.info, -1)
 516
 517     cng =
 518       change(user)
 519       |> put_embed(:info, info_cng)
 520
 521     update_and_set_cache(cng)
 522   end
 523
 524   def update_note_count(%User{} = user) do
 525     note_count_query =
 526       from(
 527         a in Object,
 528         where: fragment("?->>'actor' = ? and ?->>'type' = 'Note'", a.data, ^user.ap_id, a.data),
 529         select: count(a.id)
 530       )
 531
 532     note_count = Repo.one(note_count_query)
 533
 534     info_cng = User.Info.set_note_count(user.info, note_count)
 535
 536     cng =
 537       change(user)
 538       |> put_embed(:info, info_cng)
 539
 540     update_and_set_cache(cng)
 541   end
 542
 543   def update_follower_count(%User{} = user) do
 544     follower_count_query =
 545       from(
 546         u in User,
 547         where: ^user.follower_address in u.following,
 548         where: u.id != ^user.id,
 549         select: count(u.id)
 550       )
 551
 552     follower_count = Repo.one(follower_count_query)
 553
 554     info_cng =
 555       user.info
 556       |> User.Info.set_follower_count(follower_count)
 557
 558     cng =
 559       change(user)
 560       |> put_embed(:info, info_cng)
 561
 562     update_and_set_cache(cng)
 563   end
 564
 565   def get_users_from_set_query(ap_ids, false) do
 566     from(
 567       u in User,
 568       where: u.ap_id in ^ap_ids
 569     )
 570   end
 571
 572   def get_users_from_set_query(ap_ids, true) do
 573     query = get_users_from_set_query(ap_ids, false)
 574
 575     from(
 576       u in query,
 577       where: u.local == true
 578     )
 579   end
 580
 581   def get_users_from_set(ap_ids, local_only \\ true) do
 582     get_users_from_set_query(ap_ids, local_only)
 583     |> Repo.all()
 584   end
 585
 586   def get_recipients_from_activity(%Activity{recipients: to}) do
 587     query =
 588       from(
 589         u in User,
 590         where: u.ap_id in ^to,
 591         or_where: fragment("? && ?", u.following, ^to)
 592       )
 593
 594     query = from(u in query, where: u.local == true)
 595
 596     Repo.all(query)
 597   end
 598
 599   def search(query, resolve \\ false) do
 600     # strip the beginning @ off if there is a query
 601     query = String.trim_leading(query, "@")
 602
 603     if resolve do
 604       User.get_or_fetch_by_nickname(query)
 605     end
 606
 607     inner =
 608       from(
 609         u in User,
 610         select_merge: %{
 611           search_distance:
 612             fragment(
 613               "? <-> (? || ?)",
 614               ^query,
 615               u.nickname,
 616               u.name
 617             )
 618         },
 619         where: not is_nil(u.nickname)
 620       )
 621
 622     q =
 623       from(
 624         s in subquery(inner),
 625         order_by: s.search_distance,
 626         limit: 20
 627       )
 628
 629     Repo.all(q)
 630   end
 631
 632   def blocks_import(%User{} = blocker, blocked_identifiers) when is_list(blocked_identifiers) do
 633     Enum.map(
 634       blocked_identifiers,
 635       fn blocked_identifier ->
 636         with %User{} = blocked <- get_or_fetch(blocked_identifier),
 637              {:ok, blocker} <- block(blocker, blocked),
 638              {:ok, _} <- ActivityPub.block(blocker, blocked) do
 639           blocked
 640         else
 641           err ->
 642             Logger.debug("blocks_import failed for #{blocked_identifier} with: #{inspect(err)}")
 643             err
 644         end
 645       end
 646     )
 647   end
 648
 649   def block(blocker, %User{ap_id: ap_id} = blocked) do
 650     # sever any follow relationships to prevent leaks per activitypub (Pleroma issue #213)
 651     blocker =
 652       if following?(blocker, blocked) do
 653         {:ok, blocker, _} = unfollow(blocker, blocked)
 654         blocker
 655       else
 656         blocker
 657       end
 658
 659     if following?(blocked, blocker) do
 660       unfollow(blocked, blocker)
 661     end
 662
 663     info_cng =
 664       blocker.info
 665       |> User.Info.add_to_block(ap_id)
 666
 667     cng =
 668       change(blocker)
 669       |> put_embed(:info, info_cng)
 670
 671     update_and_set_cache(cng)
 672   end
 673
 674   # helper to handle the block given only an actor's AP id
 675   def block(blocker, %{ap_id: ap_id}) do
 676     block(blocker, User.get_by_ap_id(ap_id))
 677   end
 678
 679   def unblock(blocker, %{ap_id: ap_id}) do
 680     info_cng =
 681       blocker.info
 682       |> User.Info.remove_from_block(ap_id)
 683
 684     cng =
 685       change(blocker)
 686       |> put_embed(:info, info_cng)
 687
 688     update_and_set_cache(cng)
 689   end
 690
 691   def blocks?(user, %{ap_id: ap_id}) do
 692     blocks = user.info.blocks
 693     domain_blocks = user.info.domain_blocks
 694     %{host: host} = URI.parse(ap_id)
 695
 696     Enum.member?(blocks, ap_id) ||
 697       Enum.any?(domain_blocks, fn domain ->
 698         host == domain
 699       end)
 700   end
 701
 702   def blocked_users(user),
 703     do: Repo.all(from(u in User, where: u.ap_id in ^user.info.blocks))
 704
 705   def block_domain(user, domain) do
 706     info_cng =
 707       user.info
 708       |> User.Info.add_to_domain_block(domain)
 709
 710     cng =
 711       change(user)
 712       |> put_embed(:info, info_cng)
 713
 714     update_and_set_cache(cng)
 715   end
 716
 717   def unblock_domain(user, domain) do
 718     info_cng =
 719       user.info
 720       |> User.Info.remove_from_domain_block(domain)
 721
 722     cng =
 723       change(user)
 724       |> put_embed(:info, info_cng)
 725
 726     update_and_set_cache(cng)
 727   end
 728
 729   def local_user_query() do
 730     from(
 731       u in User,
 732       where: u.local == true,
 733       where: not is_nil(u.nickname)
 734     )
 735   end
 736
 737   def moderator_user_query() do
 738     from(
 739       u in User,
 740       where: u.local == true,
 741       where: fragment("?->'is_moderator' @> 'true'", u.info)
 742     )
 743   end
 744
 745   def deactivate(%User{} = user, status \\ true) do
 746     info_cng = User.Info.set_activation_status(user.info, status)
 747
 748     cng =
 749       change(user)
 750       |> put_embed(:info, info_cng)
 751
 752     update_and_set_cache(cng)
 753   end
 754
 755   def delete(%User{} = user) do
 756     {:ok, user} = User.deactivate(user)
 757
 758     # Remove all relationships
 759     {:ok, followers} = User.get_followers(user)
 760
 761     followers
 762     |> Enum.each(fn follower -> User.unfollow(follower, user) end)
 763
 764     {:ok, friends} = User.get_friends(user)
 765
 766     friends
 767     |> Enum.each(fn followed -> User.unfollow(user, followed) end)
 768
 769     query = from(a in Activity, where: a.actor == ^user.ap_id)
 770
 771     Repo.all(query)
 772     |> Enum.each(fn activity ->
 773       case activity.data["type"] do
 774         "Create" ->
 775           ActivityPub.delete(Object.normalize(activity.data["object"]))
 776
 777         # TODO: Do something with likes, follows, repeats.
 778         _ ->
 779           "Doing nothing"
 780       end
 781     end)
 782
 783     {:ok, user}
 784   end
 785
 786   def html_filter_policy(%User{info: %{no_rich_text: true}}) do
 787     Pleroma.HTML.Scrubber.TwitterText
 788   end
 789
 790   @default_scrubbers Pleroma.Config.get([:markup, :scrub_policy])
 791
 792   def html_filter_policy(_), do: @default_scrubbers
 793
 794   def get_or_fetch_by_ap_id(ap_id) do
 795     user = get_by_ap_id(ap_id)
 796
 797     if !is_nil(user) and !User.needs_update?(user) do
 798       user
 799     else
 800       ap_try = ActivityPub.make_user_from_ap_id(ap_id)
 801
 802       case ap_try do
 803         {:ok, user} ->
 804           user
 805
 806         _ ->
 807           case OStatus.make_user(ap_id) do
 808             {:ok, user} -> user
 809             _ -> {:error, "Could not fetch by AP id"}
 810           end
 811       end
 812     end
 813   end
 814
 815   def get_or_create_instance_user do
 816     relay_uri = "#{Pleroma.Web.Endpoint.url()}/relay"
 817
 818     if user = get_by_ap_id(relay_uri) do
 819       user
 820     else
 821       changes =
 822         %User{info: %User.Info{}}
 823         |> cast(%{}, [:ap_id, :nickname, :local])
 824         |> put_change(:ap_id, relay_uri)
 825         |> put_change(:nickname, nil)
 826         |> put_change(:local, true)
 827         |> put_change(:follower_address, relay_uri <> "/followers")
 828
 829       {:ok, user} = Repo.insert(changes)
 830       user
 831     end
 832   end
 833
 834   # AP style
 835   def public_key_from_info(%{
 836         source_data: %{"publicKey" => %{"publicKeyPem" => public_key_pem}}
 837       }) do
 838     key =
 839       public_key_pem
 840       |> :public_key.pem_decode()
 841       |> hd()
 842       |> :public_key.pem_entry_decode()
 843
 844     {:ok, key}
 845   end
 846
 847   # OStatus Magic Key
 848   def public_key_from_info(%{magic_key: magic_key}) do
 849     {:ok, Pleroma.Web.Salmon.decode_key(magic_key)}
 850   end
 851
 852   def get_public_key_for_ap_id(ap_id) do
 853     with %User{} = user <- get_or_fetch_by_ap_id(ap_id),
 854          {:ok, public_key} <- public_key_from_info(user.info) do
 855       {:ok, public_key}
 856     else
 857       _ -> :error
 858     end
 859   end
 860
 861   defp blank?(""), do: nil
 862   defp blank?(n), do: n
 863
 864   def insert_or_update_user(data) do
 865     data =
 866       data
 867       |> Map.put(:name, blank?(data[:name]) || data[:nickname])
 868
 869     cs = User.remote_user_creation(data)
 870
 871     Repo.insert(cs, on_conflict: :replace_all, conflict_target: :nickname)
 872   end
 873
 874   def ap_enabled?(%User{local: true}), do: true
 875   def ap_enabled?(%User{info: info}), do: info.ap_enabled
 876   def ap_enabled?(_), do: false
 877
 878   @doc "Gets or fetch a user by uri or nickname."
 879   @spec get_or_fetch(String.t()) :: User.t()
 880   def get_or_fetch("http" <> _host = uri), do: get_or_fetch_by_ap_id(uri)
 881   def get_or_fetch(nickname), do: get_or_fetch_by_nickname(nickname)
 882
 883   # wait a period of time and return newest version of the User structs
 884   # this is because we have synchronous follow APIs and need to simulate them
 885   # with an async handshake
 886   def wait_and_refresh(_, %User{local: true} = a, %User{local: true} = b) do
 887     with %User{} = a <- Repo.get(User, a.id),
 888          %User{} = b <- Repo.get(User, b.id) do
 889       {:ok, a, b}
 890     else
 891       _e ->
 892         :error
 893     end
 894   end
 895
 896   def wait_and_refresh(timeout, %User{} = a, %User{} = b) do
 897     with :ok <- :timer.sleep(timeout),
 898          %User{} = a <- Repo.get(User, a.id),
 899          %User{} = b <- Repo.get(User, b.id) do
 900       {:ok, a, b}
 901     else
 902       _e ->
 903         :error
 904     end
 905   end
 906
 907   def parse_bio(bio, user \\ %User{info: %{source_data: %{}}})
 908   def parse_bio(nil, _user), do: ""
 909   def parse_bio(bio, _user) when bio == "", do: bio
 910
 911   def parse_bio(bio, user) do
 912     mentions = Formatter.parse_mentions(bio)
 913     tags = Formatter.parse_tags(bio)
 914
 915     emoji =
 916       (user.info.source_data["tag"] || [])
 917       |> Enum.filter(fn %{"type" => t} -> t == "Emoji" end)
 918       |> Enum.map(fn %{"icon" => %{"url" => url}, "name" => name} ->
 919         {String.trim(name, ":"), url}
 920       end)
 921
 922     bio
 923     |> CommonUtils.format_input(mentions, tags, "text/plain")
 924     |> Formatter.emojify(emoji)
 925   end
 926
 927   def tag(user_identifiers, tags) when is_list(user_identifiers) do
 928     Repo.transaction(fn ->
 929       for user_identifier <- user_identifiers, do: tag(user_identifier, tags)
 930     end)
 931   end
 932
 933   def tag(nickname, tags) when is_binary(nickname),
 934     do: tag(User.get_by_nickname(nickname), tags)
 935
 936   def tag(%User{} = user, tags),
 937     do: update_tags(user, Enum.uniq((user.tags || []) ++ normalize_tags(tags)))
 938
 939   def untag(user_identifiers, tags) when is_list(user_identifiers) do
 940     Repo.transaction(fn ->
 941       for user_identifier <- user_identifiers, do: untag(user_identifier, tags)
 942     end)
 943   end
 944
 945   def untag(nickname, tags) when is_binary(nickname),
 946     do: untag(User.get_by_nickname(nickname), tags)
 947
 948   def untag(%User{} = user, tags),
 949     do: update_tags(user, (user.tags || []) -- normalize_tags(tags))
 950
 951   defp update_tags(%User{} = user, new_tags) do
 952     {:ok, updated_user} =
 953       user
 954       |> change(%{tags: new_tags})
 955       |> Repo.update()
 956
 957     updated_user
 958   end
 959
 960   defp normalize_tags(tags) do
 961     [tags]
 962     |> List.flatten()
 963     |> Enum.map(&String.downcase(&1))
 964   end
 965
 966   defp local_nickname_regex() do
 967     if Pleroma.Config.get([:instance, :extended_nickname_format]) do
 968       @extended_local_nickname_regex
 969     else
 970       @strict_local_nickname_regex
 971     end
 972   end
 973 end