git.squeep.com Git - akkoma/blob - lib/pleroma/user.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.User do
   6   use Ecto.Schema
   7
   8   import Ecto.{Changeset, Query}
   9   alias Pleroma.{Repo, User, Object, Web, Activity, Notification}
  10   alias Comeonin.Pbkdf2
  11   alias Pleroma.Formatter
  12   alias Pleroma.Web.CommonAPI.Utils, as: CommonUtils
  13   alias Pleroma.Web.{OStatus, Websub, OAuth}
  14   alias Pleroma.Web.ActivityPub.{Utils, ActivityPub}
  15
  16   require Logger
  17
  18   @type t :: %__MODULE__{}
  19
  20   @primary_key {:id, Pleroma.FlakeId, autogenerate: true}
  21
  22   @email_regex ~r/^[a-zA-Z0-9.!#$%&'*+\/=?^_`{|}~-]+@[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?(?:\.[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?)*$/
  23
  24   @strict_local_nickname_regex ~r/^[a-zA-Z\d]+$/
  25   @extended_local_nickname_regex ~r/^[a-zA-Z\d_-]+$/
  26
  27   schema "users" do
  28     field(:bio, :string)
  29     field(:email, :string)
  30     field(:name, :string)
  31     field(:nickname, :string)
  32     field(:password_hash, :string)
  33     field(:password, :string, virtual: true)
  34     field(:password_confirmation, :string, virtual: true)
  35     field(:following, {:array, :string}, default: [])
  36     field(:ap_id, :string)
  37     field(:avatar, :map)
  38     field(:local, :boolean, default: true)
  39     field(:follower_address, :string)
  40     field(:search_rank, :float, virtual: true)
  41     field(:tags, {:array, :string}, default: [])
  42     field(:bookmarks, {:array, :string}, default: [])
  43     field(:last_refreshed_at, :naive_datetime)
  44     has_many(:notifications, Notification)
  45     embeds_one(:info, Pleroma.User.Info)
  46
  47     timestamps()
  48   end
  49
  50   def auth_active?(%User{local: false}), do: true
  51
  52   def auth_active?(%User{info: %User.Info{confirmation_pending: false}}), do: true
  53
  54   def auth_active?(%User{info: %User.Info{confirmation_pending: true}}),
  55     do: !Pleroma.Config.get([:instance, :account_activation_required])
  56
  57   def auth_active?(_), do: false
  58
  59   def visible_for?(user, for_user \\ nil)
  60
  61   def visible_for?(%User{id: user_id}, %User{id: for_id}) when user_id == for_id, do: true
  62
  63   def visible_for?(%User{} = user, for_user) do
  64     auth_active?(user) || superuser?(for_user)
  65   end
  66
  67   def visible_for?(_, _), do: false
  68
  69   def superuser?(%User{local: true, info: %User.Info{is_admin: true}}), do: true
  70   def superuser?(%User{local: true, info: %User.Info{is_moderator: true}}), do: true
  71   def superuser?(_), do: false
  72
  73   def avatar_url(user) do
  74     case user.avatar do
  75       %{"url" => [%{"href" => href} | _]} -> href
  76       _ -> "#{Web.base_url()}/images/avi.png"
  77     end
  78   end
  79
  80   def banner_url(user) do
  81     case user.info.banner do
  82       %{"url" => [%{"href" => href} | _]} -> href
  83       _ -> "#{Web.base_url()}/images/banner.png"
  84     end
  85   end
  86
  87   def profile_url(%User{info: %{source_data: %{"url" => url}}}), do: url
  88   def profile_url(%User{ap_id: ap_id}), do: ap_id
  89   def profile_url(_), do: nil
  90
  91   def ap_id(%User{nickname: nickname}) do
  92     "#{Web.base_url()}/users/#{nickname}"
  93   end
  94
  95   def ap_followers(%User{} = user) do
  96     "#{ap_id(user)}/followers"
  97   end
  98
  99   def follow_changeset(struct, params \\ %{}) do
 100     struct
 101     |> cast(params, [:following])
 102     |> validate_required([:following])
 103   end
 104
 105   def user_info(%User{} = user) do
 106     oneself = if user.local, do: 1, else: 0
 107
 108     %{
 109       following_count: length(user.following) - oneself,
 110       note_count: user.info.note_count,
 111       follower_count: user.info.follower_count,
 112       locked: user.info.locked,
 113       confirmation_pending: user.info.confirmation_pending,
 114       default_scope: user.info.default_scope
 115     }
 116   end
 117
 118   def remote_user_creation(params) do
 119     params =
 120       params
 121       |> Map.put(:info, params[:info] || %{})
 122
 123     info_cng = User.Info.remote_user_creation(%User.Info{}, params[:info])
 124
 125     changes =
 126       %User{}
 127       |> cast(params, [:bio, :name, :ap_id, :nickname, :avatar])
 128       |> validate_required([:name, :ap_id])
 129       |> unique_constraint(:nickname)
 130       |> validate_format(:nickname, @email_regex)
 131       |> validate_length(:bio, max: 5000)
 132       |> validate_length(:name, max: 100)
 133       |> put_change(:local, false)
 134       |> put_embed(:info, info_cng)
 135
 136     if changes.valid? do
 137       case info_cng.changes[:source_data] do
 138         %{"followers" => followers} ->
 139           changes
 140           |> put_change(:follower_address, followers)
 141
 142         _ ->
 143           followers = User.ap_followers(%User{nickname: changes.changes[:nickname]})
 144
 145           changes
 146           |> put_change(:follower_address, followers)
 147       end
 148     else
 149       changes
 150     end
 151   end
 152
 153   def update_changeset(struct, params \\ %{}) do
 154     struct
 155     |> cast(params, [:bio, :name, :avatar])
 156     |> unique_constraint(:nickname)
 157     |> validate_format(:nickname, local_nickname_regex())
 158     |> validate_length(:bio, max: 5000)
 159     |> validate_length(:name, min: 1, max: 100)
 160   end
 161
 162   def upgrade_changeset(struct, params \\ %{}) do
 163     params =
 164       params
 165       |> Map.put(:last_refreshed_at, NaiveDateTime.utc_now())
 166
 167     info_cng =
 168       struct.info
 169       |> User.Info.user_upgrade(params[:info])
 170
 171     struct
 172     |> cast(params, [:bio, :name, :follower_address, :avatar, :last_refreshed_at])
 173     |> unique_constraint(:nickname)
 174     |> validate_format(:nickname, local_nickname_regex())
 175     |> validate_length(:bio, max: 5000)
 176     |> validate_length(:name, max: 100)
 177     |> put_embed(:info, info_cng)
 178   end
 179
 180   def password_update_changeset(struct, params) do
 181     changeset =
 182       struct
 183       |> cast(params, [:password, :password_confirmation])
 184       |> validate_required([:password, :password_confirmation])
 185       |> validate_confirmation(:password)
 186
 187     OAuth.Token.delete_user_tokens(struct)
 188     OAuth.Authorization.delete_user_authorizations(struct)
 189
 190     if changeset.valid? do
 191       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 192
 193       changeset
 194       |> put_change(:password_hash, hashed)
 195     else
 196       changeset
 197     end
 198   end
 199
 200   def reset_password(user, data) do
 201     update_and_set_cache(password_update_changeset(user, data))
 202   end
 203
 204   def register_changeset(struct, params \\ %{}, opts \\ []) do
 205     confirmation_status =
 206       if opts[:confirmed] || !Pleroma.Config.get([:instance, :account_activation_required]) do
 207         :confirmed
 208       else
 209         :unconfirmed
 210       end
 211
 212     info_change = User.Info.confirmation_changeset(%User.Info{}, confirmation_status)
 213
 214     changeset =
 215       struct
 216       |> cast(params, [:bio, :email, :name, :nickname, :password, :password_confirmation])
 217       |> validate_required([:email, :name, :nickname, :password, :password_confirmation])
 218       |> validate_confirmation(:password)
 219       |> unique_constraint(:email)
 220       |> unique_constraint(:nickname)
 221       |> validate_exclusion(:nickname, Pleroma.Config.get([Pleroma.User, :restricted_nicknames]))
 222       |> validate_format(:nickname, local_nickname_regex())
 223       |> validate_format(:email, @email_regex)
 224       |> validate_length(:bio, max: 1000)
 225       |> validate_length(:name, min: 1, max: 100)
 226       |> put_change(:info, info_change)
 227
 228     if changeset.valid? do
 229       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 230       ap_id = User.ap_id(%User{nickname: changeset.changes[:nickname]})
 231       followers = User.ap_followers(%User{nickname: changeset.changes[:nickname]})
 232
 233       changeset
 234       |> put_change(:password_hash, hashed)
 235       |> put_change(:ap_id, ap_id)
 236       |> put_change(:following, [followers])
 237       |> put_change(:follower_address, followers)
 238     else
 239       changeset
 240     end
 241   end
 242
 243   defp autofollow_users(user) do
 244     candidates = Pleroma.Config.get([:instance, :autofollowed_nicknames])
 245
 246     autofollowed_users =
 247       from(u in User,
 248         where: u.local == true,
 249         where: u.nickname in ^candidates
 250       )
 251       |> Repo.all()
 252
 253     follow_all(user, autofollowed_users)
 254   end
 255
 256   @doc "Inserts provided changeset, performs post-registration actions (confirmation email sending etc.)"
 257   def register(%Ecto.Changeset{} = changeset) do
 258     with {:ok, user} <- Repo.insert(changeset),
 259          {:ok, _} <- try_send_confirmation_email(user),
 260          {:ok, user} <- autofollow_users(user) do
 261       {:ok, user}
 262     end
 263   end
 264
 265   def try_send_confirmation_email(%User{} = user) do
 266     if user.info.confirmation_pending &&
 267          Pleroma.Config.get([:instance, :account_activation_required]) do
 268       user
 269       |> Pleroma.UserEmail.account_confirmation_email()
 270       |> Pleroma.Mailer.deliver()
 271     else
 272       {:ok, :noop}
 273     end
 274   end
 275
 276   def needs_update?(%User{local: true}), do: false
 277
 278   def needs_update?(%User{local: false, last_refreshed_at: nil}), do: true
 279
 280   def needs_update?(%User{local: false} = user) do
 281     NaiveDateTime.diff(NaiveDateTime.utc_now(), user.last_refreshed_at) >= 86400
 282   end
 283
 284   def needs_update?(_), do: true
 285
 286   def maybe_direct_follow(%User{} = follower, %User{local: true, info: %{locked: true}}) do
 287     {:ok, follower}
 288   end
 289
 290   def maybe_direct_follow(%User{} = follower, %User{local: true} = followed) do
 291     follow(follower, followed)
 292   end
 293
 294   def maybe_direct_follow(%User{} = follower, %User{} = followed) do
 295     if not User.ap_enabled?(followed) do
 296       follow(follower, followed)
 297     else
 298       {:ok, follower}
 299     end
 300   end
 301
 302   def maybe_follow(%User{} = follower, %User{info: _info} = followed) do
 303     if not following?(follower, followed) do
 304       follow(follower, followed)
 305     else
 306       {:ok, follower}
 307     end
 308   end
 309
 310   @doc "A mass follow for local users. Ignores blocks and has no side effects"
 311   @spec follow_all(User.t(), list(User.t())) :: {atom(), User.t()}
 312   def follow_all(follower, followeds) do
 313     followed_addresses = Enum.map(followeds, fn %{follower_address: fa} -> fa end)
 314
 315     q =
 316       from(u in User,
 317         where: u.id == ^follower.id,
 318         update: [
 319           set: [
 320             following:
 321               fragment(
 322                 "array(select distinct unnest (array_cat(?, ?)))",
 323                 u.following,
 324                 ^followed_addresses
 325               )
 326           ]
 327         ]
 328       )
 329
 330     {1, [follower]} = Repo.update_all(q, [], returning: true)
 331
 332     Enum.each(followeds, fn followed ->
 333       update_follower_count(followed)
 334     end)
 335
 336     set_cache(follower)
 337   end
 338
 339   def follow(%User{} = follower, %User{info: info} = followed) do
 340     user_config = Application.get_env(:pleroma, :user)
 341     deny_follow_blocked = Keyword.get(user_config, :deny_follow_blocked)
 342
 343     ap_followers = followed.follower_address
 344
 345     cond do
 346       following?(follower, followed) or info.deactivated ->
 347         {:error, "Could not follow user: #{followed.nickname} is already on your list."}
 348
 349       deny_follow_blocked and blocks?(followed, follower) ->
 350         {:error, "Could not follow user: #{followed.nickname} blocked you."}
 351
 352       true ->
 353         if !followed.local && follower.local && !ap_enabled?(followed) do
 354           Websub.subscribe(follower, followed)
 355         end
 356
 357         q =
 358           from(u in User,
 359             where: u.id == ^follower.id,
 360             update: [push: [following: ^ap_followers]]
 361           )
 362
 363         {1, [follower]} = Repo.update_all(q, [], returning: true)
 364
 365         {:ok, _} = update_follower_count(followed)
 366
 367         set_cache(follower)
 368     end
 369   end
 370
 371   def unfollow(%User{} = follower, %User{} = followed) do
 372     ap_followers = followed.follower_address
 373
 374     if following?(follower, followed) and follower.ap_id != followed.ap_id do
 375       q =
 376         from(u in User,
 377           where: u.id == ^follower.id,
 378           update: [pull: [following: ^ap_followers]]
 379         )
 380
 381       {1, [follower]} = Repo.update_all(q, [], returning: true)
 382
 383       {:ok, followed} = update_follower_count(followed)
 384
 385       set_cache(follower)
 386
 387       {:ok, follower, Utils.fetch_latest_follow(follower, followed)}
 388     else
 389       {:error, "Not subscribed!"}
 390     end
 391   end
 392
 393   @spec following?(User.t(), User.t()) :: boolean
 394   def following?(%User{} = follower, %User{} = followed) do
 395     Enum.member?(follower.following, followed.follower_address)
 396   end
 397
 398   def follow_import(%User{} = follower, followed_identifiers)
 399       when is_list(followed_identifiers) do
 400     Enum.map(
 401       followed_identifiers,
 402       fn followed_identifier ->
 403         with %User{} = followed <- get_or_fetch(followed_identifier),
 404              {:ok, follower} <- maybe_direct_follow(follower, followed),
 405              {:ok, _} <- ActivityPub.follow(follower, followed) do
 406           followed
 407         else
 408           err ->
 409             Logger.debug("follow_import failed for #{followed_identifier} with: #{inspect(err)}")
 410             err
 411         end
 412       end
 413     )
 414   end
 415
 416   def locked?(%User{} = user) do
 417     user.info.locked || false
 418   end
 419
 420   def get_by_id(id) do
 421     Repo.get_by(User, id: id)
 422   end
 423
 424   def get_by_ap_id(ap_id) do
 425     Repo.get_by(User, ap_id: ap_id)
 426   end
 427
 428   # This is mostly an SPC migration fix. This guesses the user nickname (by taking the last part of the ap_id and the domain) and tries to get that user
 429   def get_by_guessed_nickname(ap_id) do
 430     domain = URI.parse(ap_id).host
 431     name = List.last(String.split(ap_id, "/"))
 432     nickname = "#{name}@#{domain}"
 433
 434     get_by_nickname(nickname)
 435   end
 436
 437   def set_cache(user) do
 438     Cachex.put(:user_cache, "ap_id:#{user.ap_id}", user)
 439     Cachex.put(:user_cache, "nickname:#{user.nickname}", user)
 440     Cachex.put(:user_cache, "user_info:#{user.id}", user_info(user))
 441     {:ok, user}
 442   end
 443
 444   def update_and_set_cache(changeset) do
 445     with {:ok, user} <- Repo.update(changeset) do
 446       set_cache(user)
 447     else
 448       e -> e
 449     end
 450   end
 451
 452   def invalidate_cache(user) do
 453     Cachex.del(:user_cache, "ap_id:#{user.ap_id}")
 454     Cachex.del(:user_cache, "nickname:#{user.nickname}")
 455     Cachex.del(:user_cache, "user_info:#{user.id}")
 456   end
 457
 458   def get_cached_by_ap_id(ap_id) do
 459     key = "ap_id:#{ap_id}"
 460     Cachex.fetch!(:user_cache, key, fn _ -> get_by_ap_id(ap_id) end)
 461   end
 462
 463   def get_cached_by_id(id) do
 464     key = "id:#{id}"
 465
 466     ap_id =
 467       Cachex.fetch!(:user_cache, key, fn _ ->
 468         user = get_by_id(id)
 469
 470         if user do
 471           Cachex.put(:user_cache, "ap_id:#{user.ap_id}", user)
 472           {:commit, user.ap_id}
 473         else
 474           {:ignore, ""}
 475         end
 476       end)
 477
 478     get_cached_by_ap_id(ap_id)
 479   end
 480
 481   def get_cached_by_nickname(nickname) do
 482     key = "nickname:#{nickname}"
 483     Cachex.fetch!(:user_cache, key, fn _ -> get_or_fetch_by_nickname(nickname) end)
 484   end
 485
 486   def get_cached_by_nickname_or_id(nickname_or_id) do
 487     get_cached_by_id(nickname_or_id) || get_cached_by_nickname(nickname_or_id)
 488   end
 489
 490   def get_by_nickname(nickname) do
 491     Repo.get_by(User, nickname: nickname) ||
 492       if Regex.match?(~r(@#{Pleroma.Web.Endpoint.host()})i, nickname) do
 493         Repo.get_by(User, nickname: local_nickname(nickname))
 494       end
 495   end
 496
 497   def get_by_nickname_or_email(nickname_or_email) do
 498     case user = Repo.get_by(User, nickname: nickname_or_email) do
 499       %User{} -> user
 500       nil -> Repo.get_by(User, email: nickname_or_email)
 501     end
 502   end
 503
 504   def get_cached_user_info(user) do
 505     key = "user_info:#{user.id}"
 506     Cachex.fetch!(:user_cache, key, fn _ -> user_info(user) end)
 507   end
 508
 509   def fetch_by_nickname(nickname) do
 510     ap_try = ActivityPub.make_user_from_nickname(nickname)
 511
 512     case ap_try do
 513       {:ok, user} -> {:ok, user}
 514       _ -> OStatus.make_user(nickname)
 515     end
 516   end
 517
 518   def get_or_fetch_by_nickname(nickname) do
 519     with %User{} = user <- get_by_nickname(nickname) do
 520       user
 521     else
 522       _e ->
 523         with [_nick, _domain] <- String.split(nickname, "@"),
 524              {:ok, user} <- fetch_by_nickname(nickname) do
 525           user
 526         else
 527           _e -> nil
 528         end
 529     end
 530   end
 531
 532   def get_followers_query(%User{id: id, follower_address: follower_address}, nil) do
 533     from(
 534       u in User,
 535       where: fragment("? <@ ?", ^[follower_address], u.following),
 536       where: u.id != ^id
 537     )
 538   end
 539
 540   def get_followers_query(user, page) do
 541     from(
 542       u in get_followers_query(user, nil),
 543       limit: 20,
 544       offset: ^((page - 1) * 20)
 545     )
 546   end
 547
 548   def get_followers_query(user), do: get_followers_query(user, nil)
 549
 550   def get_followers(user, page \\ nil) do
 551     q = get_followers_query(user, page)
 552
 553     {:ok, Repo.all(q)}
 554   end
 555
 556   def get_followers_ids(user, page \\ nil) do
 557     q = get_followers_query(user, page)
 558
 559     Repo.all(from(u in q, select: u.id))
 560   end
 561
 562   def get_friends_query(%User{id: id, following: following}, nil) do
 563     from(
 564       u in User,
 565       where: u.follower_address in ^following,
 566       where: u.id != ^id
 567     )
 568   end
 569
 570   def get_friends_query(user, page) do
 571     from(
 572       u in get_friends_query(user, nil),
 573       limit: 20,
 574       offset: ^((page - 1) * 20)
 575     )
 576   end
 577
 578   def get_friends_query(user), do: get_friends_query(user, nil)
 579
 580   def get_friends(user, page \\ nil) do
 581     q = get_friends_query(user, page)
 582
 583     {:ok, Repo.all(q)}
 584   end
 585
 586   def get_friends_ids(user, page \\ nil) do
 587     q = get_friends_query(user, page)
 588
 589     Repo.all(from(u in q, select: u.id))
 590   end
 591
 592   def get_follow_requests_query(%User{} = user) do
 593     from(
 594       a in Activity,
 595       where:
 596         fragment(
 597           "? ->> 'type' = 'Follow'",
 598           a.data
 599         ),
 600       where:
 601         fragment(
 602           "? ->> 'state' = 'pending'",
 603           a.data
 604         ),
 605       where:
 606         fragment(
 607           "? @> ?",
 608           a.data,
 609           ^%{"object" => user.ap_id}
 610         )
 611     )
 612   end
 613
 614   def get_follow_requests(%User{} = user) do
 615     q = get_follow_requests_query(user)
 616     reqs = Repo.all(q)
 617
 618     users =
 619       Enum.map(reqs, fn req -> req.actor end)
 620       |> Enum.uniq()
 621       |> Enum.map(fn ap_id -> get_by_ap_id(ap_id) end)
 622       |> Enum.filter(fn u -> !is_nil(u) end)
 623       |> Enum.filter(fn u -> !following?(u, user) end)
 624
 625     {:ok, users}
 626   end
 627
 628   def increase_note_count(%User{} = user) do
 629     info_cng = User.Info.add_to_note_count(user.info, 1)
 630
 631     cng =
 632       change(user)
 633       |> put_embed(:info, info_cng)
 634
 635     update_and_set_cache(cng)
 636   end
 637
 638   def decrease_note_count(%User{} = user) do
 639     info_cng = User.Info.add_to_note_count(user.info, -1)
 640
 641     cng =
 642       change(user)
 643       |> put_embed(:info, info_cng)
 644
 645     update_and_set_cache(cng)
 646   end
 647
 648   def update_note_count(%User{} = user) do
 649     note_count_query =
 650       from(
 651         a in Object,
 652         where: fragment("?->>'actor' = ? and ?->>'type' = 'Note'", a.data, ^user.ap_id, a.data),
 653         select: count(a.id)
 654       )
 655
 656     note_count = Repo.one(note_count_query)
 657
 658     info_cng = User.Info.set_note_count(user.info, note_count)
 659
 660     cng =
 661       change(user)
 662       |> put_embed(:info, info_cng)
 663
 664     update_and_set_cache(cng)
 665   end
 666
 667   def update_follower_count(%User{} = user) do
 668     follower_count_query =
 669       from(
 670         u in User,
 671         where: ^user.follower_address in u.following,
 672         where: u.id != ^user.id,
 673         select: count(u.id)
 674       )
 675
 676     follower_count = Repo.one(follower_count_query)
 677
 678     info_cng =
 679       user.info
 680       |> User.Info.set_follower_count(follower_count)
 681
 682     cng =
 683       change(user)
 684       |> put_embed(:info, info_cng)
 685
 686     update_and_set_cache(cng)
 687   end
 688
 689   def get_users_from_set_query(ap_ids, false) do
 690     from(
 691       u in User,
 692       where: u.ap_id in ^ap_ids
 693     )
 694   end
 695
 696   def get_users_from_set_query(ap_ids, true) do
 697     query = get_users_from_set_query(ap_ids, false)
 698
 699     from(
 700       u in query,
 701       where: u.local == true
 702     )
 703   end
 704
 705   def get_users_from_set(ap_ids, local_only \\ true) do
 706     get_users_from_set_query(ap_ids, local_only)
 707     |> Repo.all()
 708   end
 709
 710   def get_recipients_from_activity(%Activity{recipients: to}) do
 711     query =
 712       from(
 713         u in User,
 714         where: u.ap_id in ^to,
 715         or_where: fragment("? && ?", u.following, ^to)
 716       )
 717
 718     query = from(u in query, where: u.local == true)
 719
 720     Repo.all(query)
 721   end
 722
 723   def search(query, resolve \\ false, for_user \\ nil) do
 724     # Strip the beginning @ off if there is a query
 725     query = String.trim_leading(query, "@")
 726
 727     if resolve, do: User.get_or_fetch_by_nickname(query)
 728
 729     fts_results = do_search(fts_search_subquery(query), for_user)
 730
 731     {:ok, trigram_results} =
 732       Repo.transaction(fn ->
 733         Ecto.Adapters.SQL.query(Repo, "select set_limit(0.25)", [])
 734         do_search(trigram_search_subquery(query), for_user)
 735       end)
 736
 737     Enum.uniq_by(fts_results ++ trigram_results, & &1.id)
 738   end
 739
 740   defp do_search(subquery, for_user, options \\ []) do
 741     q =
 742       from(
 743         s in subquery(subquery),
 744         order_by: [desc: s.search_rank],
 745         limit: ^(options[:limit] || 20)
 746       )
 747
 748     results =
 749       q
 750       |> Repo.all()
 751       |> Enum.filter(&(&1.search_rank > 0))
 752
 753     boost_search_results(results, for_user)
 754   end
 755
 756   defp fts_search_subquery(query) do
 757     processed_query =
 758       query
 759       |> String.replace(~r/\W+/, " ")
 760       |> String.trim()
 761       |> String.split()
 762       |> Enum.map(&(&1 <> ":*"))
 763       |> Enum.join(" | ")
 764
 765     from(
 766       u in User,
 767       select_merge: %{
 768         search_rank:
 769           fragment(
 770             """
 771             ts_rank_cd(
 772               setweight(to_tsvector('simple', regexp_replace(?, '\\W', ' ', 'g')), 'A') ||
 773               setweight(to_tsvector('simple', regexp_replace(coalesce(?, ''), '\\W', ' ', 'g')), 'B'),
 774               to_tsquery('simple', ?),
 775               32
 776             )
 777             """,
 778             u.nickname,
 779             u.name,
 780             ^processed_query
 781           )
 782       },
 783       where:
 784         fragment(
 785           """
 786             (setweight(to_tsvector('simple', regexp_replace(?, '\\W', ' ', 'g')), 'A') ||
 787             setweight(to_tsvector('simple', regexp_replace(coalesce(?, ''), '\\W', ' ', 'g')), 'B')) @@ to_tsquery('simple', ?)
 788           """,
 789           u.nickname,
 790           u.name,
 791           ^processed_query
 792         )
 793     )
 794   end
 795
 796   defp trigram_search_subquery(query) do
 797     from(
 798       u in User,
 799       select_merge: %{
 800         search_rank:
 801           fragment(
 802             "similarity(?, trim(? || ' ' || coalesce(?, '')))",
 803             ^query,
 804             u.nickname,
 805             u.name
 806           )
 807       },
 808       where: fragment("trim(? || ' ' || coalesce(?, '')) % ?", u.nickname, u.name, ^query)
 809     )
 810   end
 811
 812   defp boost_search_results(results, nil), do: results
 813
 814   defp boost_search_results(results, for_user) do
 815     friends_ids = get_friends_ids(for_user)
 816     followers_ids = get_followers_ids(for_user)
 817
 818     Enum.map(
 819       results,
 820       fn u ->
 821         search_rank_coef =
 822           cond do
 823             u.id in friends_ids ->
 824               1.2
 825
 826             u.id in followers_ids ->
 827               1.1
 828
 829             true ->
 830               1
 831           end
 832
 833         Map.put(u, :search_rank, u.search_rank * search_rank_coef)
 834       end
 835     )
 836     |> Enum.sort_by(&(-&1.search_rank))
 837   end
 838
 839   def blocks_import(%User{} = blocker, blocked_identifiers) when is_list(blocked_identifiers) do
 840     Enum.map(
 841       blocked_identifiers,
 842       fn blocked_identifier ->
 843         with %User{} = blocked <- get_or_fetch(blocked_identifier),
 844              {:ok, blocker} <- block(blocker, blocked),
 845              {:ok, _} <- ActivityPub.block(blocker, blocked) do
 846           blocked
 847         else
 848           err ->
 849             Logger.debug("blocks_import failed for #{blocked_identifier} with: #{inspect(err)}")
 850             err
 851         end
 852       end
 853     )
 854   end
 855
 856   def block(blocker, %User{ap_id: ap_id} = blocked) do
 857     # sever any follow relationships to prevent leaks per activitypub (Pleroma issue #213)
 858     blocker =
 859       if following?(blocker, blocked) do
 860         {:ok, blocker, _} = unfollow(blocker, blocked)
 861         blocker
 862       else
 863         blocker
 864       end
 865
 866     if following?(blocked, blocker) do
 867       unfollow(blocked, blocker)
 868     end
 869
 870     info_cng =
 871       blocker.info
 872       |> User.Info.add_to_block(ap_id)
 873
 874     cng =
 875       change(blocker)
 876       |> put_embed(:info, info_cng)
 877
 878     update_and_set_cache(cng)
 879   end
 880
 881   # helper to handle the block given only an actor's AP id
 882   def block(blocker, %{ap_id: ap_id}) do
 883     block(blocker, User.get_by_ap_id(ap_id))
 884   end
 885
 886   def unblock(blocker, %{ap_id: ap_id}) do
 887     info_cng =
 888       blocker.info
 889       |> User.Info.remove_from_block(ap_id)
 890
 891     cng =
 892       change(blocker)
 893       |> put_embed(:info, info_cng)
 894
 895     update_and_set_cache(cng)
 896   end
 897
 898   def blocks?(user, %{ap_id: ap_id}) do
 899     blocks = user.info.blocks
 900     domain_blocks = user.info.domain_blocks
 901     %{host: host} = URI.parse(ap_id)
 902
 903     Enum.member?(blocks, ap_id) ||
 904       Enum.any?(domain_blocks, fn domain ->
 905         host == domain
 906       end)
 907   end
 908
 909   def blocked_users(user),
 910     do: Repo.all(from(u in User, where: u.ap_id in ^user.info.blocks))
 911
 912   def block_domain(user, domain) do
 913     info_cng =
 914       user.info
 915       |> User.Info.add_to_domain_block(domain)
 916
 917     cng =
 918       change(user)
 919       |> put_embed(:info, info_cng)
 920
 921     update_and_set_cache(cng)
 922   end
 923
 924   def unblock_domain(user, domain) do
 925     info_cng =
 926       user.info
 927       |> User.Info.remove_from_domain_block(domain)
 928
 929     cng =
 930       change(user)
 931       |> put_embed(:info, info_cng)
 932
 933     update_and_set_cache(cng)
 934   end
 935
 936   def local_user_query do
 937     from(
 938       u in User,
 939       where: u.local == true,
 940       where: not is_nil(u.nickname)
 941     )
 942   end
 943
 944   def active_local_user_query do
 945     from(
 946       u in local_user_query(),
 947       where: fragment("not (?->'deactivated' @> 'true')", u.info)
 948     )
 949   end
 950
 951   def moderator_user_query do
 952     from(
 953       u in User,
 954       where: u.local == true,
 955       where: fragment("?->'is_moderator' @> 'true'", u.info)
 956     )
 957   end
 958
 959   def deactivate(%User{} = user, status \\ true) do
 960     info_cng = User.Info.set_activation_status(user.info, status)
 961
 962     cng =
 963       change(user)
 964       |> put_embed(:info, info_cng)
 965
 966     update_and_set_cache(cng)
 967   end
 968
 969   def delete(%User{} = user) do
 970     {:ok, user} = User.deactivate(user)
 971
 972     # Remove all relationships
 973     {:ok, followers} = User.get_followers(user)
 974
 975     followers
 976     |> Enum.each(fn follower -> User.unfollow(follower, user) end)
 977
 978     {:ok, friends} = User.get_friends(user)
 979
 980     friends
 981     |> Enum.each(fn followed -> User.unfollow(user, followed) end)
 982
 983     query = from(a in Activity, where: a.actor == ^user.ap_id)
 984
 985     Repo.all(query)
 986     |> Enum.each(fn activity ->
 987       case activity.data["type"] do
 988         "Create" ->
 989           ActivityPub.delete(Object.normalize(activity.data["object"]))
 990
 991         # TODO: Do something with likes, follows, repeats.
 992         _ ->
 993           "Doing nothing"
 994       end
 995     end)
 996
 997     {:ok, user}
 998   end
 999
1000   def html_filter_policy(%User{info: %{no_rich_text: true}}) do
1001     Pleroma.HTML.Scrubber.TwitterText
1002   end
1003
1004   @default_scrubbers Pleroma.Config.get([:markup, :scrub_policy])
1005
1006   def html_filter_policy(_), do: @default_scrubbers
1007
1008   def get_or_fetch_by_ap_id(ap_id) do
1009     user = get_by_ap_id(ap_id)
1010
1011     if !is_nil(user) and !User.needs_update?(user) do
1012       user
1013     else
1014       ap_try = ActivityPub.make_user_from_ap_id(ap_id)
1015
1016       case ap_try do
1017         {:ok, user} ->
1018           user
1019
1020         _ ->
1021           case OStatus.make_user(ap_id) do
1022             {:ok, user} -> user
1023             _ -> {:error, "Could not fetch by AP id"}
1024           end
1025       end
1026     end
1027   end
1028
1029   def get_or_create_instance_user do
1030     relay_uri = "#{Pleroma.Web.Endpoint.url()}/relay"
1031
1032     if user = get_by_ap_id(relay_uri) do
1033       user
1034     else
1035       changes =
1036         %User{info: %User.Info{}}
1037         |> cast(%{}, [:ap_id, :nickname, :local])
1038         |> put_change(:ap_id, relay_uri)
1039         |> put_change(:nickname, nil)
1040         |> put_change(:local, true)
1041         |> put_change(:follower_address, relay_uri <> "/followers")
1042
1043       {:ok, user} = Repo.insert(changes)
1044       user
1045     end
1046   end
1047
1048   # AP style
1049   def public_key_from_info(%{
1050         source_data: %{"publicKey" => %{"publicKeyPem" => public_key_pem}}
1051       }) do
1052     key =
1053       public_key_pem
1054       |> :public_key.pem_decode()
1055       |> hd()
1056       |> :public_key.pem_entry_decode()
1057
1058     {:ok, key}
1059   end
1060
1061   # OStatus Magic Key
1062   def public_key_from_info(%{magic_key: magic_key}) do
1063     {:ok, Pleroma.Web.Salmon.decode_key(magic_key)}
1064   end
1065
1066   def get_public_key_for_ap_id(ap_id) do
1067     with %User{} = user <- get_or_fetch_by_ap_id(ap_id),
1068          {:ok, public_key} <- public_key_from_info(user.info) do
1069       {:ok, public_key}
1070     else
1071       _ -> :error
1072     end
1073   end
1074
1075   defp blank?(""), do: nil
1076   defp blank?(n), do: n
1077
1078   def insert_or_update_user(data) do
1079     data =
1080       data
1081       |> Map.put(:name, blank?(data[:name]) || data[:nickname])
1082
1083     cs = User.remote_user_creation(data)
1084
1085     Repo.insert(cs, on_conflict: :replace_all, conflict_target: :nickname)
1086   end
1087
1088   def ap_enabled?(%User{local: true}), do: true
1089   def ap_enabled?(%User{info: info}), do: info.ap_enabled
1090   def ap_enabled?(_), do: false
1091
1092   @doc "Gets or fetch a user by uri or nickname."
1093   @spec get_or_fetch(String.t()) :: User.t()
1094   def get_or_fetch("http" <> _host = uri), do: get_or_fetch_by_ap_id(uri)
1095   def get_or_fetch(nickname), do: get_or_fetch_by_nickname(nickname)
1096
1097   # wait a period of time and return newest version of the User structs
1098   # this is because we have synchronous follow APIs and need to simulate them
1099   # with an async handshake
1100   def wait_and_refresh(_, %User{local: true} = a, %User{local: true} = b) do
1101     with %User{} = a <- Repo.get(User, a.id),
1102          %User{} = b <- Repo.get(User, b.id) do
1103       {:ok, a, b}
1104     else
1105       _e ->
1106         :error
1107     end
1108   end
1109
1110   def wait_and_refresh(timeout, %User{} = a, %User{} = b) do
1111     with :ok <- :timer.sleep(timeout),
1112          %User{} = a <- Repo.get(User, a.id),
1113          %User{} = b <- Repo.get(User, b.id) do
1114       {:ok, a, b}
1115     else
1116       _e ->
1117         :error
1118     end
1119   end
1120
1121   def parse_bio(bio, user \\ %User{info: %{source_data: %{}}})
1122   def parse_bio(nil, _user), do: ""
1123   def parse_bio(bio, _user) when bio == "", do: bio
1124
1125   def parse_bio(bio, user) do
1126     mentions = Formatter.parse_mentions(bio)
1127     tags = Formatter.parse_tags(bio)
1128
1129     emoji =
1130       (user.info.source_data["tag"] || [])
1131       |> Enum.filter(fn %{"type" => t} -> t == "Emoji" end)
1132       |> Enum.map(fn %{"icon" => %{"url" => url}, "name" => name} ->
1133         {String.trim(name, ":"), url}
1134       end)
1135
1136     bio
1137     |> CommonUtils.format_input(mentions, tags, "text/plain", user_links: [format: :full])
1138     |> Formatter.emojify(emoji)
1139   end
1140
1141   def tag(user_identifiers, tags) when is_list(user_identifiers) do
1142     Repo.transaction(fn ->
1143       for user_identifier <- user_identifiers, do: tag(user_identifier, tags)
1144     end)
1145   end
1146
1147   def tag(nickname, tags) when is_binary(nickname),
1148     do: tag(User.get_by_nickname(nickname), tags)
1149
1150   def tag(%User{} = user, tags),
1151     do: update_tags(user, Enum.uniq((user.tags || []) ++ normalize_tags(tags)))
1152
1153   def untag(user_identifiers, tags) when is_list(user_identifiers) do
1154     Repo.transaction(fn ->
1155       for user_identifier <- user_identifiers, do: untag(user_identifier, tags)
1156     end)
1157   end
1158
1159   def untag(nickname, tags) when is_binary(nickname),
1160     do: untag(User.get_by_nickname(nickname), tags)
1161
1162   def untag(%User{} = user, tags),
1163     do: update_tags(user, (user.tags || []) -- normalize_tags(tags))
1164
1165   defp update_tags(%User{} = user, new_tags) do
1166     {:ok, updated_user} =
1167       user
1168       |> change(%{tags: new_tags})
1169       |> Repo.update()
1170
1171     updated_user
1172   end
1173
1174   def bookmark(%User{} = user, status_id) do
1175     bookmarks = Enum.uniq(user.bookmarks ++ [status_id])
1176     update_bookmarks(user, bookmarks)
1177   end
1178
1179   def unbookmark(%User{} = user, status_id) do
1180     bookmarks = Enum.uniq(user.bookmarks -- [status_id])
1181     update_bookmarks(user, bookmarks)
1182   end
1183
1184   def update_bookmarks(%User{} = user, bookmarks) do
1185     user
1186     |> change(%{bookmarks: bookmarks})
1187     |> update_and_set_cache
1188   end
1189
1190   defp normalize_tags(tags) do
1191     [tags]
1192     |> List.flatten()
1193     |> Enum.map(&String.downcase(&1))
1194   end
1195
1196   defp local_nickname_regex() do
1197     if Pleroma.Config.get([:instance, :extended_nickname_format]) do
1198       @extended_local_nickname_regex
1199     else
1200       @strict_local_nickname_regex
1201     end
1202   end
1203
1204   def local_nickname(nickname_or_mention) do
1205     nickname_or_mention
1206     |> full_nickname()
1207     |> String.split("@")
1208     |> hd()
1209   end
1210
1211   def full_nickname(nickname_or_mention),
1212     do: String.trim_leading(nickname_or_mention, "@")
1213
1214   def error_user(ap_id) do
1215     %User{
1216       name: ap_id,
1217       ap_id: ap_id,
1218       info: %User.Info{},
1219       nickname: "erroruser@example.com",
1220       inserted_at: NaiveDateTime.utc_now()
1221     }
1222   end
1223 end