git.squeep.com Git - akkoma/blob - lib/pleroma/user.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.User do
   6   use Ecto.Schema
   7
   8   import Ecto.{Changeset, Query}
   9   alias Pleroma.{Repo, User, Object, Web, Activity, Notification}
  10   alias Comeonin.Pbkdf2
  11   alias Pleroma.Formatter
  12   alias Pleroma.Web.CommonAPI.Utils, as: CommonUtils
  13   alias Pleroma.Web.{OStatus, Websub, OAuth}
  14   alias Pleroma.Web.ActivityPub.{Utils, ActivityPub}
  15
  16   require Logger
  17
  18   @type t :: %__MODULE__{}
  19
  20   @primary_key {:id, Pleroma.FlakeId, autogenerate: true}
  21
  22   @email_regex ~r/^[a-zA-Z0-9.!#$%&'*+\/=?^_`{|}~-]+@[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?(?:\.[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?)*$/
  23
  24   @strict_local_nickname_regex ~r/^[a-zA-Z\d]+$/
  25   @extended_local_nickname_regex ~r/^[a-zA-Z\d_-]+$/
  26
  27   schema "users" do
  28     field(:bio, :string)
  29     field(:email, :string)
  30     field(:name, :string)
  31     field(:nickname, :string)
  32     field(:password_hash, :string)
  33     field(:password, :string, virtual: true)
  34     field(:password_confirmation, :string, virtual: true)
  35     field(:following, {:array, :string}, default: [])
  36     field(:ap_id, :string)
  37     field(:avatar, :map)
  38     field(:local, :boolean, default: true)
  39     field(:follower_address, :string)
  40     field(:search_rank, :float, virtual: true)
  41     field(:tags, {:array, :string}, default: [])
  42     field(:bookmarks, {:array, :string}, default: [])
  43     field(:last_refreshed_at, :naive_datetime)
  44     has_many(:notifications, Notification)
  45     embeds_one(:info, Pleroma.User.Info)
  46
  47     timestamps()
  48   end
  49
  50   def auth_active?(%User{local: false}), do: true
  51
  52   def auth_active?(%User{info: %User.Info{confirmation_pending: false}}), do: true
  53
  54   def auth_active?(%User{info: %User.Info{confirmation_pending: true}}),
  55     do: !Pleroma.Config.get([:instance, :account_activation_required])
  56
  57   def auth_active?(_), do: false
  58
  59   def visible_for?(user, for_user \\ nil)
  60
  61   def visible_for?(%User{id: user_id}, %User{id: for_id}) when user_id == for_id, do: true
  62
  63   def visible_for?(%User{} = user, for_user) do
  64     auth_active?(user) || superuser?(for_user)
  65   end
  66
  67   def visible_for?(_, _), do: false
  68
  69   def superuser?(%User{local: true, info: %User.Info{is_admin: true}}), do: true
  70   def superuser?(%User{local: true, info: %User.Info{is_moderator: true}}), do: true
  71   def superuser?(_), do: false
  72
  73   def avatar_url(user) do
  74     case user.avatar do
  75       %{"url" => [%{"href" => href} | _]} -> href
  76       _ -> "#{Web.base_url()}/images/avi.png"
  77     end
  78   end
  79
  80   def banner_url(user) do
  81     case user.info.banner do
  82       %{"url" => [%{"href" => href} | _]} -> href
  83       _ -> "#{Web.base_url()}/images/banner.png"
  84     end
  85   end
  86
  87   def profile_url(%User{info: %{source_data: %{"url" => url}}}), do: url
  88   def profile_url(%User{ap_id: ap_id}), do: ap_id
  89   def profile_url(_), do: nil
  90
  91   def ap_id(%User{nickname: nickname}) do
  92     "#{Web.base_url()}/users/#{nickname}"
  93   end
  94
  95   def ap_followers(%User{} = user) do
  96     "#{ap_id(user)}/followers"
  97   end
  98
  99   def follow_changeset(struct, params \\ %{}) do
 100     struct
 101     |> cast(params, [:following])
 102     |> validate_required([:following])
 103   end
 104
 105   def user_info(%User{} = user) do
 106     oneself = if user.local, do: 1, else: 0
 107
 108     %{
 109       following_count: length(user.following) - oneself,
 110       note_count: user.info.note_count,
 111       follower_count: user.info.follower_count,
 112       locked: user.info.locked,
 113       confirmation_pending: user.info.confirmation_pending,
 114       default_scope: user.info.default_scope
 115     }
 116   end
 117
 118   def remote_user_creation(params) do
 119     params =
 120       params
 121       |> Map.put(:info, params[:info] || %{})
 122
 123     info_cng = User.Info.remote_user_creation(%User.Info{}, params[:info])
 124
 125     changes =
 126       %User{}
 127       |> cast(params, [:bio, :name, :ap_id, :nickname, :avatar])
 128       |> validate_required([:name, :ap_id])
 129       |> unique_constraint(:nickname)
 130       |> validate_format(:nickname, @email_regex)
 131       |> validate_length(:bio, max: 5000)
 132       |> validate_length(:name, max: 100)
 133       |> put_change(:local, false)
 134       |> put_embed(:info, info_cng)
 135
 136     if changes.valid? do
 137       case info_cng.changes[:source_data] do
 138         %{"followers" => followers} ->
 139           changes
 140           |> put_change(:follower_address, followers)
 141
 142         _ ->
 143           followers = User.ap_followers(%User{nickname: changes.changes[:nickname]})
 144
 145           changes
 146           |> put_change(:follower_address, followers)
 147       end
 148     else
 149       changes
 150     end
 151   end
 152
 153   def update_changeset(struct, params \\ %{}) do
 154     struct
 155     |> cast(params, [:bio, :name, :avatar])
 156     |> unique_constraint(:nickname)
 157     |> validate_format(:nickname, local_nickname_regex())
 158     |> validate_length(:bio, max: 5000)
 159     |> validate_length(:name, min: 1, max: 100)
 160   end
 161
 162   def upgrade_changeset(struct, params \\ %{}) do
 163     params =
 164       params
 165       |> Map.put(:last_refreshed_at, NaiveDateTime.utc_now())
 166
 167     info_cng =
 168       struct.info
 169       |> User.Info.user_upgrade(params[:info])
 170
 171     struct
 172     |> cast(params, [:bio, :name, :follower_address, :avatar, :last_refreshed_at])
 173     |> unique_constraint(:nickname)
 174     |> validate_format(:nickname, local_nickname_regex())
 175     |> validate_length(:bio, max: 5000)
 176     |> validate_length(:name, max: 100)
 177     |> put_embed(:info, info_cng)
 178   end
 179
 180   def password_update_changeset(struct, params) do
 181     changeset =
 182       struct
 183       |> cast(params, [:password, :password_confirmation])
 184       |> validate_required([:password, :password_confirmation])
 185       |> validate_confirmation(:password)
 186
 187     OAuth.Token.delete_user_tokens(struct)
 188     OAuth.Authorization.delete_user_authorizations(struct)
 189
 190     if changeset.valid? do
 191       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 192
 193       changeset
 194       |> put_change(:password_hash, hashed)
 195     else
 196       changeset
 197     end
 198   end
 199
 200   def reset_password(user, data) do
 201     update_and_set_cache(password_update_changeset(user, data))
 202   end
 203
 204   def register_changeset(struct, params \\ %{}, opts \\ []) do
 205     confirmation_status =
 206       if opts[:confirmed] || !Pleroma.Config.get([:instance, :account_activation_required]) do
 207         :confirmed
 208       else
 209         :unconfirmed
 210       end
 211
 212     info_change = User.Info.confirmation_changeset(%User.Info{}, confirmation_status)
 213
 214     changeset =
 215       struct
 216       |> cast(params, [:bio, :email, :name, :nickname, :password, :password_confirmation])
 217       |> validate_required([:email, :name, :nickname, :password, :password_confirmation])
 218       |> validate_confirmation(:password)
 219       |> unique_constraint(:email)
 220       |> unique_constraint(:nickname)
 221       |> validate_exclusion(:nickname, Pleroma.Config.get([Pleroma.User, :restricted_nicknames]))
 222       |> validate_format(:nickname, local_nickname_regex())
 223       |> validate_format(:email, @email_regex)
 224       |> validate_length(:bio, max: 1000)
 225       |> validate_length(:name, min: 1, max: 100)
 226       |> put_change(:info, info_change)
 227
 228     if changeset.valid? do
 229       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 230       ap_id = User.ap_id(%User{nickname: changeset.changes[:nickname]})
 231       followers = User.ap_followers(%User{nickname: changeset.changes[:nickname]})
 232
 233       changeset
 234       |> put_change(:password_hash, hashed)
 235       |> put_change(:ap_id, ap_id)
 236       |> put_change(:following, [followers])
 237       |> put_change(:follower_address, followers)
 238     else
 239       changeset
 240     end
 241   end
 242
 243   defp autofollow_users(user) do
 244     candidates = Pleroma.Config.get([:instance, :autofollowed_nicknames])
 245
 246     autofollowed_users =
 247       from(u in User,
 248         where: u.local == true,
 249         where: u.nickname in ^candidates
 250       )
 251       |> Repo.all()
 252
 253     follow_all(user, autofollowed_users)
 254   end
 255
 256   @doc "Inserts provided changeset, performs post-registration actions (confirmation email sending etc.)"
 257   def register(%Ecto.Changeset{} = changeset) do
 258     with {:ok, user} <- Repo.insert(changeset),
 259          {:ok, _} <- try_send_confirmation_email(user),
 260          {:ok, user} <- autofollow_users(user) do
 261       {:ok, user}
 262     end
 263   end
 264
 265   def try_send_confirmation_email(%User{} = user) do
 266     if user.info.confirmation_pending &&
 267          Pleroma.Config.get([:instance, :account_activation_required]) do
 268       user
 269       |> Pleroma.UserEmail.account_confirmation_email()
 270       |> Pleroma.Mailer.deliver()
 271     else
 272       {:ok, :noop}
 273     end
 274   end
 275
 276   def needs_update?(%User{local: true}), do: false
 277
 278   def needs_update?(%User{local: false, last_refreshed_at: nil}), do: true
 279
 280   def needs_update?(%User{local: false} = user) do
 281     NaiveDateTime.diff(NaiveDateTime.utc_now(), user.last_refreshed_at) >= 86400
 282   end
 283
 284   def needs_update?(_), do: true
 285
 286   def maybe_direct_follow(%User{} = follower, %User{local: true, info: %{locked: true}}) do
 287     {:ok, follower}
 288   end
 289
 290   def maybe_direct_follow(%User{} = follower, %User{local: true} = followed) do
 291     follow(follower, followed)
 292   end
 293
 294   def maybe_direct_follow(%User{} = follower, %User{} = followed) do
 295     if not User.ap_enabled?(followed) do
 296       follow(follower, followed)
 297     else
 298       {:ok, follower}
 299     end
 300   end
 301
 302   def maybe_follow(%User{} = follower, %User{info: _info} = followed) do
 303     if not following?(follower, followed) do
 304       follow(follower, followed)
 305     else
 306       {:ok, follower}
 307     end
 308   end
 309
 310   @doc "A mass follow for local users. Ignores blocks and has no side effects"
 311   @spec follow_all(User.t(), list(User.t())) :: {atom(), User.t()}
 312   def follow_all(follower, followeds) do
 313     followed_addresses = Enum.map(followeds, fn %{follower_address: fa} -> fa end)
 314
 315     q =
 316       from(u in User,
 317         where: u.id == ^follower.id,
 318         update: [set: [following: fragment("array_cat(?, ?)", u.following, ^followed_addresses)]]
 319       )
 320
 321     {1, [follower]} = Repo.update_all(q, [], returning: true)
 322
 323     Enum.each(followeds, fn followed ->
 324       update_follower_count(followed)
 325     end)
 326
 327     set_cache(follower)
 328   end
 329
 330   def follow(%User{} = follower, %User{info: info} = followed) do
 331     user_config = Application.get_env(:pleroma, :user)
 332     deny_follow_blocked = Keyword.get(user_config, :deny_follow_blocked)
 333
 334     ap_followers = followed.follower_address
 335
 336     cond do
 337       following?(follower, followed) or info.deactivated ->
 338         {:error, "Could not follow user: #{followed.nickname} is already on your list."}
 339
 340       deny_follow_blocked and blocks?(followed, follower) ->
 341         {:error, "Could not follow user: #{followed.nickname} blocked you."}
 342
 343       true ->
 344         if !followed.local && follower.local && !ap_enabled?(followed) do
 345           Websub.subscribe(follower, followed)
 346         end
 347
 348         q =
 349           from(u in User,
 350             where: u.id == ^follower.id,
 351             update: [push: [following: ^ap_followers]]
 352           )
 353
 354         {1, [follower]} = Repo.update_all(q, [], returning: true)
 355
 356         {:ok, _} = update_follower_count(followed)
 357
 358         set_cache(follower)
 359     end
 360   end
 361
 362   def unfollow(%User{} = follower, %User{} = followed) do
 363     ap_followers = followed.follower_address
 364
 365     if following?(follower, followed) and follower.ap_id != followed.ap_id do
 366       q =
 367         from(u in User,
 368           where: u.id == ^follower.id,
 369           update: [pull: [following: ^ap_followers]]
 370         )
 371
 372       {1, [follower]} = Repo.update_all(q, [], returning: true)
 373
 374       {:ok, followed} = update_follower_count(followed)
 375
 376       set_cache(follower)
 377
 378       {:ok, follower, Utils.fetch_latest_follow(follower, followed)}
 379     else
 380       {:error, "Not subscribed!"}
 381     end
 382   end
 383
 384   @spec following?(User.t(), User.t()) :: boolean
 385   def following?(%User{} = follower, %User{} = followed) do
 386     Enum.member?(follower.following, followed.follower_address)
 387   end
 388
 389   def follow_import(%User{} = follower, followed_identifiers)
 390       when is_list(followed_identifiers) do
 391     Enum.map(
 392       followed_identifiers,
 393       fn followed_identifier ->
 394         with %User{} = followed <- get_or_fetch(followed_identifier),
 395              {:ok, follower} <- maybe_direct_follow(follower, followed),
 396              {:ok, _} <- ActivityPub.follow(follower, followed) do
 397           followed
 398         else
 399           err ->
 400             Logger.debug("follow_import failed for #{followed_identifier} with: #{inspect(err)}")
 401             err
 402         end
 403       end
 404     )
 405   end
 406
 407   def locked?(%User{} = user) do
 408     user.info.locked || false
 409   end
 410
 411   def get_by_id(id) do
 412     Repo.get_by(User, id: id)
 413   end
 414
 415   def get_by_ap_id(ap_id) do
 416     Repo.get_by(User, ap_id: ap_id)
 417   end
 418
 419   # This is mostly an SPC migration fix. This guesses the user nickname (by taking the last part of the ap_id and the domain) and tries to get that user
 420   def get_by_guessed_nickname(ap_id) do
 421     domain = URI.parse(ap_id).host
 422     name = List.last(String.split(ap_id, "/"))
 423     nickname = "#{name}@#{domain}"
 424
 425     get_by_nickname(nickname)
 426   end
 427
 428   def set_cache(user) do
 429     Cachex.put(:user_cache, "ap_id:#{user.ap_id}", user)
 430     Cachex.put(:user_cache, "nickname:#{user.nickname}", user)
 431     Cachex.put(:user_cache, "user_info:#{user.id}", user_info(user))
 432     {:ok, user}
 433   end
 434
 435   def update_and_set_cache(changeset) do
 436     with {:ok, user} <- Repo.update(changeset) do
 437       set_cache(user)
 438     else
 439       e -> e
 440     end
 441   end
 442
 443   def invalidate_cache(user) do
 444     Cachex.del(:user_cache, "ap_id:#{user.ap_id}")
 445     Cachex.del(:user_cache, "nickname:#{user.nickname}")
 446     Cachex.del(:user_cache, "user_info:#{user.id}")
 447   end
 448
 449   def get_cached_by_ap_id(ap_id) do
 450     key = "ap_id:#{ap_id}"
 451     Cachex.fetch!(:user_cache, key, fn _ -> get_by_ap_id(ap_id) end)
 452   end
 453
 454   def get_cached_by_id(id) do
 455     key = "id:#{id}"
 456
 457     ap_id =
 458       Cachex.fetch!(:user_cache, key, fn _ ->
 459         user = get_by_id(id)
 460
 461         if user do
 462           Cachex.put(:user_cache, "ap_id:#{user.ap_id}", user)
 463           {:commit, user.ap_id}
 464         else
 465           {:ignore, ""}
 466         end
 467       end)
 468
 469     get_cached_by_ap_id(ap_id)
 470   end
 471
 472   def get_cached_by_nickname(nickname) do
 473     key = "nickname:#{nickname}"
 474     Cachex.fetch!(:user_cache, key, fn _ -> get_or_fetch_by_nickname(nickname) end)
 475   end
 476
 477   def get_cached_by_nickname_or_id(nickname_or_id) do
 478     get_cached_by_id(nickname_or_id) || get_cached_by_nickname(nickname_or_id)
 479   end
 480
 481   def get_by_nickname(nickname) do
 482     Repo.get_by(User, nickname: nickname) ||
 483       if Regex.match?(~r(@#{Pleroma.Web.Endpoint.host()})i, nickname) do
 484         Repo.get_by(User, nickname: local_nickname(nickname))
 485       end
 486   end
 487
 488   def get_by_nickname_or_email(nickname_or_email) do
 489     case user = Repo.get_by(User, nickname: nickname_or_email) do
 490       %User{} -> user
 491       nil -> Repo.get_by(User, email: nickname_or_email)
 492     end
 493   end
 494
 495   def get_cached_user_info(user) do
 496     key = "user_info:#{user.id}"
 497     Cachex.fetch!(:user_cache, key, fn _ -> user_info(user) end)
 498   end
 499
 500   def fetch_by_nickname(nickname) do
 501     ap_try = ActivityPub.make_user_from_nickname(nickname)
 502
 503     case ap_try do
 504       {:ok, user} -> {:ok, user}
 505       _ -> OStatus.make_user(nickname)
 506     end
 507   end
 508
 509   def get_or_fetch_by_nickname(nickname) do
 510     with %User{} = user <- get_by_nickname(nickname) do
 511       user
 512     else
 513       _e ->
 514         with [_nick, _domain] <- String.split(nickname, "@"),
 515              {:ok, user} <- fetch_by_nickname(nickname) do
 516           user
 517         else
 518           _e -> nil
 519         end
 520     end
 521   end
 522
 523   def get_followers_query(%User{id: id, follower_address: follower_address}, nil) do
 524     from(
 525       u in User,
 526       where: fragment("? <@ ?", ^[follower_address], u.following),
 527       where: u.id != ^id
 528     )
 529   end
 530
 531   def get_followers_query(user, page) do
 532     from(
 533       u in get_followers_query(user, nil),
 534       limit: 20,
 535       offset: ^((page - 1) * 20)
 536     )
 537   end
 538
 539   def get_followers_query(user), do: get_followers_query(user, nil)
 540
 541   def get_followers(user, page \\ nil) do
 542     q = get_followers_query(user, page)
 543
 544     {:ok, Repo.all(q)}
 545   end
 546
 547   def get_followers_ids(user, page \\ nil) do
 548     q = get_followers_query(user, page)
 549
 550     Repo.all(from(u in q, select: u.id))
 551   end
 552
 553   def get_friends_query(%User{id: id, following: following}, nil) do
 554     from(
 555       u in User,
 556       where: u.follower_address in ^following,
 557       where: u.id != ^id
 558     )
 559   end
 560
 561   def get_friends_query(user, page) do
 562     from(
 563       u in get_friends_query(user, nil),
 564       limit: 20,
 565       offset: ^((page - 1) * 20)
 566     )
 567   end
 568
 569   def get_friends_query(user), do: get_friends_query(user, nil)
 570
 571   def get_friends(user, page \\ nil) do
 572     q = get_friends_query(user, page)
 573
 574     {:ok, Repo.all(q)}
 575   end
 576
 577   def get_friends_ids(user, page \\ nil) do
 578     q = get_friends_query(user, page)
 579
 580     Repo.all(from(u in q, select: u.id))
 581   end
 582
 583   def get_follow_requests_query(%User{} = user) do
 584     from(
 585       a in Activity,
 586       where:
 587         fragment(
 588           "? ->> 'type' = 'Follow'",
 589           a.data
 590         ),
 591       where:
 592         fragment(
 593           "? ->> 'state' = 'pending'",
 594           a.data
 595         ),
 596       where:
 597         fragment(
 598           "? @> ?",
 599           a.data,
 600           ^%{"object" => user.ap_id}
 601         )
 602     )
 603   end
 604
 605   def get_follow_requests(%User{} = user) do
 606     q = get_follow_requests_query(user)
 607     reqs = Repo.all(q)
 608
 609     users =
 610       Enum.map(reqs, fn req -> req.actor end)
 611       |> Enum.uniq()
 612       |> Enum.map(fn ap_id -> get_by_ap_id(ap_id) end)
 613       |> Enum.filter(fn u -> !is_nil(u) end)
 614       |> Enum.filter(fn u -> !following?(u, user) end)
 615
 616     {:ok, users}
 617   end
 618
 619   def increase_note_count(%User{} = user) do
 620     info_cng = User.Info.add_to_note_count(user.info, 1)
 621
 622     cng =
 623       change(user)
 624       |> put_embed(:info, info_cng)
 625
 626     update_and_set_cache(cng)
 627   end
 628
 629   def decrease_note_count(%User{} = user) do
 630     info_cng = User.Info.add_to_note_count(user.info, -1)
 631
 632     cng =
 633       change(user)
 634       |> put_embed(:info, info_cng)
 635
 636     update_and_set_cache(cng)
 637   end
 638
 639   def update_note_count(%User{} = user) do
 640     note_count_query =
 641       from(
 642         a in Object,
 643         where: fragment("?->>'actor' = ? and ?->>'type' = 'Note'", a.data, ^user.ap_id, a.data),
 644         select: count(a.id)
 645       )
 646
 647     note_count = Repo.one(note_count_query)
 648
 649     info_cng = User.Info.set_note_count(user.info, note_count)
 650
 651     cng =
 652       change(user)
 653       |> put_embed(:info, info_cng)
 654
 655     update_and_set_cache(cng)
 656   end
 657
 658   def update_follower_count(%User{} = user) do
 659     follower_count_query =
 660       from(
 661         u in User,
 662         where: ^user.follower_address in u.following,
 663         where: u.id != ^user.id,
 664         select: count(u.id)
 665       )
 666
 667     follower_count = Repo.one(follower_count_query)
 668
 669     info_cng =
 670       user.info
 671       |> User.Info.set_follower_count(follower_count)
 672
 673     cng =
 674       change(user)
 675       |> put_embed(:info, info_cng)
 676
 677     update_and_set_cache(cng)
 678   end
 679
 680   def get_users_from_set_query(ap_ids, false) do
 681     from(
 682       u in User,
 683       where: u.ap_id in ^ap_ids
 684     )
 685   end
 686
 687   def get_users_from_set_query(ap_ids, true) do
 688     query = get_users_from_set_query(ap_ids, false)
 689
 690     from(
 691       u in query,
 692       where: u.local == true
 693     )
 694   end
 695
 696   def get_users_from_set(ap_ids, local_only \\ true) do
 697     get_users_from_set_query(ap_ids, local_only)
 698     |> Repo.all()
 699   end
 700
 701   def get_recipients_from_activity(%Activity{recipients: to}) do
 702     query =
 703       from(
 704         u in User,
 705         where: u.ap_id in ^to,
 706         or_where: fragment("? && ?", u.following, ^to)
 707       )
 708
 709     query = from(u in query, where: u.local == true)
 710
 711     Repo.all(query)
 712   end
 713
 714   def search(query, resolve \\ false, for_user \\ nil) do
 715     # Strip the beginning @ off if there is a query
 716     query = String.trim_leading(query, "@")
 717
 718     if resolve, do: User.get_or_fetch_by_nickname(query)
 719
 720     fts_results = do_search(fts_search_subquery(query), for_user)
 721
 722     {:ok, trigram_results} =
 723       Repo.transaction(fn ->
 724         Ecto.Adapters.SQL.query(Repo, "select set_limit(0.25)", [])
 725         do_search(trigram_search_subquery(query), for_user)
 726       end)
 727
 728     Enum.uniq_by(fts_results ++ trigram_results, & &1.id)
 729   end
 730
 731   defp do_search(subquery, for_user, options \\ []) do
 732     q =
 733       from(
 734         s in subquery(subquery),
 735         order_by: [desc: s.search_rank],
 736         limit: ^(options[:limit] || 20)
 737       )
 738
 739     results =
 740       q
 741       |> Repo.all()
 742       |> Enum.filter(&(&1.search_rank > 0))
 743
 744     boost_search_results(results, for_user)
 745   end
 746
 747   defp fts_search_subquery(query) do
 748     processed_query =
 749       query
 750       |> String.replace(~r/\W+/, " ")
 751       |> String.trim()
 752       |> String.split()
 753       |> Enum.map(&(&1 <> ":*"))
 754       |> Enum.join(" | ")
 755
 756     from(
 757       u in User,
 758       select_merge: %{
 759         search_rank:
 760           fragment(
 761             """
 762             ts_rank_cd(
 763               setweight(to_tsvector('simple', regexp_replace(?, '\\W', ' ', 'g')), 'A') ||
 764               setweight(to_tsvector('simple', regexp_replace(coalesce(?, ''), '\\W', ' ', 'g')), 'B'),
 765               to_tsquery('simple', ?),
 766               32
 767             )
 768             """,
 769             u.nickname,
 770             u.name,
 771             ^processed_query
 772           )
 773       },
 774       where:
 775         fragment(
 776           """
 777             (setweight(to_tsvector('simple', regexp_replace(?, '\\W', ' ', 'g')), 'A') ||
 778             setweight(to_tsvector('simple', regexp_replace(coalesce(?, ''), '\\W', ' ', 'g')), 'B')) @@ to_tsquery('simple', ?)
 779           """,
 780           u.nickname,
 781           u.name,
 782           ^processed_query
 783         )
 784     )
 785   end
 786
 787   defp trigram_search_subquery(query) do
 788     from(
 789       u in User,
 790       select_merge: %{
 791         search_rank:
 792           fragment(
 793             "similarity(?, trim(? || ' ' || coalesce(?, '')))",
 794             ^query,
 795             u.nickname,
 796             u.name
 797           )
 798       },
 799       where: fragment("trim(? || ' ' || coalesce(?, '')) % ?", u.nickname, u.name, ^query)
 800     )
 801   end
 802
 803   defp boost_search_results(results, nil), do: results
 804
 805   defp boost_search_results(results, for_user) do
 806     friends_ids = get_friends_ids(for_user)
 807     followers_ids = get_followers_ids(for_user)
 808
 809     Enum.map(
 810       results,
 811       fn u ->
 812         search_rank_coef =
 813           cond do
 814             u.id in friends_ids ->
 815               1.2
 816
 817             u.id in followers_ids ->
 818               1.1
 819
 820             true ->
 821               1
 822           end
 823
 824         Map.put(u, :search_rank, u.search_rank * search_rank_coef)
 825       end
 826     )
 827     |> Enum.sort_by(&(-&1.search_rank))
 828   end
 829
 830   def blocks_import(%User{} = blocker, blocked_identifiers) when is_list(blocked_identifiers) do
 831     Enum.map(
 832       blocked_identifiers,
 833       fn blocked_identifier ->
 834         with %User{} = blocked <- get_or_fetch(blocked_identifier),
 835              {:ok, blocker} <- block(blocker, blocked),
 836              {:ok, _} <- ActivityPub.block(blocker, blocked) do
 837           blocked
 838         else
 839           err ->
 840             Logger.debug("blocks_import failed for #{blocked_identifier} with: #{inspect(err)}")
 841             err
 842         end
 843       end
 844     )
 845   end
 846
 847   def block(blocker, %User{ap_id: ap_id} = blocked) do
 848     # sever any follow relationships to prevent leaks per activitypub (Pleroma issue #213)
 849     blocker =
 850       if following?(blocker, blocked) do
 851         {:ok, blocker, _} = unfollow(blocker, blocked)
 852         blocker
 853       else
 854         blocker
 855       end
 856
 857     if following?(blocked, blocker) do
 858       unfollow(blocked, blocker)
 859     end
 860
 861     info_cng =
 862       blocker.info
 863       |> User.Info.add_to_block(ap_id)
 864
 865     cng =
 866       change(blocker)
 867       |> put_embed(:info, info_cng)
 868
 869     update_and_set_cache(cng)
 870   end
 871
 872   # helper to handle the block given only an actor's AP id
 873   def block(blocker, %{ap_id: ap_id}) do
 874     block(blocker, User.get_by_ap_id(ap_id))
 875   end
 876
 877   def unblock(blocker, %{ap_id: ap_id}) do
 878     info_cng =
 879       blocker.info
 880       |> User.Info.remove_from_block(ap_id)
 881
 882     cng =
 883       change(blocker)
 884       |> put_embed(:info, info_cng)
 885
 886     update_and_set_cache(cng)
 887   end
 888
 889   def blocks?(user, %{ap_id: ap_id}) do
 890     blocks = user.info.blocks
 891     domain_blocks = user.info.domain_blocks
 892     %{host: host} = URI.parse(ap_id)
 893
 894     Enum.member?(blocks, ap_id) ||
 895       Enum.any?(domain_blocks, fn domain ->
 896         host == domain
 897       end)
 898   end
 899
 900   def blocked_users(user),
 901     do: Repo.all(from(u in User, where: u.ap_id in ^user.info.blocks))
 902
 903   def block_domain(user, domain) do
 904     info_cng =
 905       user.info
 906       |> User.Info.add_to_domain_block(domain)
 907
 908     cng =
 909       change(user)
 910       |> put_embed(:info, info_cng)
 911
 912     update_and_set_cache(cng)
 913   end
 914
 915   def unblock_domain(user, domain) do
 916     info_cng =
 917       user.info
 918       |> User.Info.remove_from_domain_block(domain)
 919
 920     cng =
 921       change(user)
 922       |> put_embed(:info, info_cng)
 923
 924     update_and_set_cache(cng)
 925   end
 926
 927   def local_user_query do
 928     from(
 929       u in User,
 930       where: u.local == true,
 931       where: not is_nil(u.nickname)
 932     )
 933   end
 934
 935   def active_local_user_query do
 936     from(
 937       u in local_user_query(),
 938       where: fragment("not (?->'deactivated' @> 'true')", u.info)
 939     )
 940   end
 941
 942   def moderator_user_query do
 943     from(
 944       u in User,
 945       where: u.local == true,
 946       where: fragment("?->'is_moderator' @> 'true'", u.info)
 947     )
 948   end
 949
 950   def deactivate(%User{} = user, status \\ true) do
 951     info_cng = User.Info.set_activation_status(user.info, status)
 952
 953     cng =
 954       change(user)
 955       |> put_embed(:info, info_cng)
 956
 957     update_and_set_cache(cng)
 958   end
 959
 960   def delete(%User{} = user) do
 961     {:ok, user} = User.deactivate(user)
 962
 963     # Remove all relationships
 964     {:ok, followers} = User.get_followers(user)
 965
 966     followers
 967     |> Enum.each(fn follower -> User.unfollow(follower, user) end)
 968
 969     {:ok, friends} = User.get_friends(user)
 970
 971     friends
 972     |> Enum.each(fn followed -> User.unfollow(user, followed) end)
 973
 974     query = from(a in Activity, where: a.actor == ^user.ap_id)
 975
 976     Repo.all(query)
 977     |> Enum.each(fn activity ->
 978       case activity.data["type"] do
 979         "Create" ->
 980           ActivityPub.delete(Object.normalize(activity.data["object"]))
 981
 982         # TODO: Do something with likes, follows, repeats.
 983         _ ->
 984           "Doing nothing"
 985       end
 986     end)
 987
 988     {:ok, user}
 989   end
 990
 991   def html_filter_policy(%User{info: %{no_rich_text: true}}) do
 992     Pleroma.HTML.Scrubber.TwitterText
 993   end
 994
 995   @default_scrubbers Pleroma.Config.get([:markup, :scrub_policy])
 996
 997   def html_filter_policy(_), do: @default_scrubbers
 998
 999   def get_or_fetch_by_ap_id(ap_id) do
1000     user = get_by_ap_id(ap_id)
1001
1002     if !is_nil(user) and !User.needs_update?(user) do
1003       user
1004     else
1005       ap_try = ActivityPub.make_user_from_ap_id(ap_id)
1006
1007       case ap_try do
1008         {:ok, user} ->
1009           user
1010
1011         _ ->
1012           case OStatus.make_user(ap_id) do
1013             {:ok, user} -> user
1014             _ -> {:error, "Could not fetch by AP id"}
1015           end
1016       end
1017     end
1018   end
1019
1020   def get_or_create_instance_user do
1021     relay_uri = "#{Pleroma.Web.Endpoint.url()}/relay"
1022
1023     if user = get_by_ap_id(relay_uri) do
1024       user
1025     else
1026       changes =
1027         %User{info: %User.Info{}}
1028         |> cast(%{}, [:ap_id, :nickname, :local])
1029         |> put_change(:ap_id, relay_uri)
1030         |> put_change(:nickname, nil)
1031         |> put_change(:local, true)
1032         |> put_change(:follower_address, relay_uri <> "/followers")
1033
1034       {:ok, user} = Repo.insert(changes)
1035       user
1036     end
1037   end
1038
1039   # AP style
1040   def public_key_from_info(%{
1041         source_data: %{"publicKey" => %{"publicKeyPem" => public_key_pem}}
1042       }) do
1043     key =
1044       public_key_pem
1045       |> :public_key.pem_decode()
1046       |> hd()
1047       |> :public_key.pem_entry_decode()
1048
1049     {:ok, key}
1050   end
1051
1052   # OStatus Magic Key
1053   def public_key_from_info(%{magic_key: magic_key}) do
1054     {:ok, Pleroma.Web.Salmon.decode_key(magic_key)}
1055   end
1056
1057   def get_public_key_for_ap_id(ap_id) do
1058     with %User{} = user <- get_or_fetch_by_ap_id(ap_id),
1059          {:ok, public_key} <- public_key_from_info(user.info) do
1060       {:ok, public_key}
1061     else
1062       _ -> :error
1063     end
1064   end
1065
1066   defp blank?(""), do: nil
1067   defp blank?(n), do: n
1068
1069   def insert_or_update_user(data) do
1070     data =
1071       data
1072       |> Map.put(:name, blank?(data[:name]) || data[:nickname])
1073
1074     cs = User.remote_user_creation(data)
1075
1076     Repo.insert(cs, on_conflict: :replace_all, conflict_target: :nickname)
1077   end
1078
1079   def ap_enabled?(%User{local: true}), do: true
1080   def ap_enabled?(%User{info: info}), do: info.ap_enabled
1081   def ap_enabled?(_), do: false
1082
1083   @doc "Gets or fetch a user by uri or nickname."
1084   @spec get_or_fetch(String.t()) :: User.t()
1085   def get_or_fetch("http" <> _host = uri), do: get_or_fetch_by_ap_id(uri)
1086   def get_or_fetch(nickname), do: get_or_fetch_by_nickname(nickname)
1087
1088   # wait a period of time and return newest version of the User structs
1089   # this is because we have synchronous follow APIs and need to simulate them
1090   # with an async handshake
1091   def wait_and_refresh(_, %User{local: true} = a, %User{local: true} = b) do
1092     with %User{} = a <- Repo.get(User, a.id),
1093          %User{} = b <- Repo.get(User, b.id) do
1094       {:ok, a, b}
1095     else
1096       _e ->
1097         :error
1098     end
1099   end
1100
1101   def wait_and_refresh(timeout, %User{} = a, %User{} = b) do
1102     with :ok <- :timer.sleep(timeout),
1103          %User{} = a <- Repo.get(User, a.id),
1104          %User{} = b <- Repo.get(User, b.id) do
1105       {:ok, a, b}
1106     else
1107       _e ->
1108         :error
1109     end
1110   end
1111
1112   def parse_bio(bio, user \\ %User{info: %{source_data: %{}}})
1113   def parse_bio(nil, _user), do: ""
1114   def parse_bio(bio, _user) when bio == "", do: bio
1115
1116   def parse_bio(bio, user) do
1117     mentions = Formatter.parse_mentions(bio)
1118     tags = Formatter.parse_tags(bio)
1119
1120     emoji =
1121       (user.info.source_data["tag"] || [])
1122       |> Enum.filter(fn %{"type" => t} -> t == "Emoji" end)
1123       |> Enum.map(fn %{"icon" => %{"url" => url}, "name" => name} ->
1124         {String.trim(name, ":"), url}
1125       end)
1126
1127     bio
1128     |> CommonUtils.format_input(mentions, tags, "text/plain", user_links: [format: :full])
1129     |> Formatter.emojify(emoji)
1130   end
1131
1132   def tag(user_identifiers, tags) when is_list(user_identifiers) do
1133     Repo.transaction(fn ->
1134       for user_identifier <- user_identifiers, do: tag(user_identifier, tags)
1135     end)
1136   end
1137
1138   def tag(nickname, tags) when is_binary(nickname),
1139     do: tag(User.get_by_nickname(nickname), tags)
1140
1141   def tag(%User{} = user, tags),
1142     do: update_tags(user, Enum.uniq((user.tags || []) ++ normalize_tags(tags)))
1143
1144   def untag(user_identifiers, tags) when is_list(user_identifiers) do
1145     Repo.transaction(fn ->
1146       for user_identifier <- user_identifiers, do: untag(user_identifier, tags)
1147     end)
1148   end
1149
1150   def untag(nickname, tags) when is_binary(nickname),
1151     do: untag(User.get_by_nickname(nickname), tags)
1152
1153   def untag(%User{} = user, tags),
1154     do: update_tags(user, (user.tags || []) -- normalize_tags(tags))
1155
1156   defp update_tags(%User{} = user, new_tags) do
1157     {:ok, updated_user} =
1158       user
1159       |> change(%{tags: new_tags})
1160       |> Repo.update()
1161
1162     updated_user
1163   end
1164
1165   def bookmark(%User{} = user, status_id) do
1166     bookmarks = Enum.uniq(user.bookmarks ++ [status_id])
1167     update_bookmarks(user, bookmarks)
1168   end
1169
1170   def unbookmark(%User{} = user, status_id) do
1171     bookmarks = Enum.uniq(user.bookmarks -- [status_id])
1172     update_bookmarks(user, bookmarks)
1173   end
1174
1175   def update_bookmarks(%User{} = user, bookmarks) do
1176     user
1177     |> change(%{bookmarks: bookmarks})
1178     |> update_and_set_cache
1179   end
1180
1181   defp normalize_tags(tags) do
1182     [tags]
1183     |> List.flatten()
1184     |> Enum.map(&String.downcase(&1))
1185   end
1186
1187   defp local_nickname_regex() do
1188     if Pleroma.Config.get([:instance, :extended_nickname_format]) do
1189       @extended_local_nickname_regex
1190     else
1191       @strict_local_nickname_regex
1192     end
1193   end
1194
1195   def local_nickname(nickname_or_mention) do
1196     nickname_or_mention
1197     |> full_nickname()
1198     |> String.split("@")
1199     |> hd()
1200   end
1201
1202   def full_nickname(nickname_or_mention),
1203     do: String.trim_leading(nickname_or_mention, "@")
1204
1205   def error_user(ap_id) do
1206     %User{
1207       name: ap_id,
1208       ap_id: ap_id,
1209       info: %User.Info{},
1210       nickname: "erroruser@example.com",
1211       inserted_at: NaiveDateTime.utc_now()
1212     }
1213   end
1214 end