git.squeep.com Git - akkoma/blob - lib/pleroma/user.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2018 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.User do
   6   use Ecto.Schema
   7
   8   import Ecto.{Changeset, Query}
   9   alias Pleroma.{Repo, User, Object, Web, Activity, Notification}
  10   alias Comeonin.Pbkdf2
  11   alias Pleroma.Formatter
  12   alias Pleroma.Web.CommonAPI.Utils, as: CommonUtils
  13   alias Pleroma.Web.{OStatus, Websub, OAuth}
  14   alias Pleroma.Web.ActivityPub.{Utils, ActivityPub}
  15
  16   @type t :: %__MODULE__{}
  17
  18   @email_regex ~r/^[a-zA-Z0-9.!#$%&'*+\/=?^_`{|}~-]+@[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?(?:\.[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?)*$/
  19
  20   @strict_local_nickname_regex ~r/^[a-zA-Z\d]+$/
  21   @extended_local_nickname_regex ~r/^[a-zA-Z\d_-]+$/
  22
  23   schema "users" do
  24     field(:bio, :string)
  25     field(:email, :string)
  26     field(:name, :string)
  27     field(:nickname, :string)
  28     field(:password_hash, :string)
  29     field(:password, :string, virtual: true)
  30     field(:password_confirmation, :string, virtual: true)
  31     field(:following, {:array, :string}, default: [])
  32     field(:ap_id, :string)
  33     field(:avatar, :map)
  34     field(:local, :boolean, default: true)
  35     field(:follower_address, :string)
  36     field(:search_distance, :float, virtual: true)
  37     field(:tags, {:array, :string}, default: [])
  38     field(:last_refreshed_at, :naive_datetime)
  39     has_many(:notifications, Notification)
  40     embeds_one(:info, Pleroma.User.Info)
  41
  42     timestamps()
  43   end
  44
  45   def auth_active?(%User{} = user) do
  46     (user.info && !user.info.confirmation_pending) ||
  47       !Pleroma.Config.get([:instance, :account_activation_required])
  48   end
  49
  50   def remote_or_auth_active?(%User{} = user), do: !user.local || auth_active?(user)
  51
  52   def superuser?(%User{} = user), do: user.info && User.Info.superuser?(user.info)
  53
  54   def avatar_url(user) do
  55     case user.avatar do
  56       %{"url" => [%{"href" => href} | _]} -> href
  57       _ -> "#{Web.base_url()}/images/avi.png"
  58     end
  59   end
  60
  61   def banner_url(user) do
  62     case user.info.banner do
  63       %{"url" => [%{"href" => href} | _]} -> href
  64       _ -> "#{Web.base_url()}/images/banner.png"
  65     end
  66   end
  67
  68   def profile_url(%User{info: %{source_data: %{"url" => url}}}), do: url
  69   def profile_url(%User{ap_id: ap_id}), do: ap_id
  70   def profile_url(_), do: nil
  71
  72   def ap_id(%User{nickname: nickname}) do
  73     "#{Web.base_url()}/users/#{nickname}"
  74   end
  75
  76   def ap_followers(%User{} = user) do
  77     "#{ap_id(user)}/followers"
  78   end
  79
  80   def follow_changeset(struct, params \\ %{}) do
  81     struct
  82     |> cast(params, [:following])
  83     |> validate_required([:following])
  84   end
  85
  86   def user_info(%User{} = user) do
  87     oneself = if user.local, do: 1, else: 0
  88
  89     %{
  90       following_count: length(user.following) - oneself,
  91       note_count: user.info.note_count,
  92       follower_count: user.info.follower_count,
  93       locked: user.info.locked,
  94       confirmation_pending: user.info.confirmation_pending,
  95       default_scope: user.info.default_scope
  96     }
  97   end
  98
  99   def remote_user_creation(params) do
 100     params =
 101       params
 102       |> Map.put(:info, params[:info] || %{})
 103
 104     info_cng = User.Info.remote_user_creation(%User.Info{}, params[:info])
 105
 106     changes =
 107       %User{}
 108       |> cast(params, [:bio, :name, :ap_id, :nickname, :avatar])
 109       |> validate_required([:name, :ap_id])
 110       |> unique_constraint(:nickname)
 111       |> validate_format(:nickname, @email_regex)
 112       |> validate_length(:bio, max: 5000)
 113       |> validate_length(:name, max: 100)
 114       |> put_change(:local, false)
 115       |> put_embed(:info, info_cng)
 116
 117     if changes.valid? do
 118       case info_cng.changes[:source_data] do
 119         %{"followers" => followers} ->
 120           changes
 121           |> put_change(:follower_address, followers)
 122
 123         _ ->
 124           followers = User.ap_followers(%User{nickname: changes.changes[:nickname]})
 125
 126           changes
 127           |> put_change(:follower_address, followers)
 128       end
 129     else
 130       changes
 131     end
 132   end
 133
 134   def update_changeset(struct, params \\ %{}) do
 135     struct
 136     |> cast(params, [:bio, :name, :avatar])
 137     |> unique_constraint(:nickname)
 138     |> validate_format(:nickname, local_nickname_regex())
 139     |> validate_length(:bio, max: 5000)
 140     |> validate_length(:name, min: 1, max: 100)
 141   end
 142
 143   def upgrade_changeset(struct, params \\ %{}) do
 144     params =
 145       params
 146       |> Map.put(:last_refreshed_at, NaiveDateTime.utc_now())
 147
 148     info_cng =
 149       struct.info
 150       |> User.Info.user_upgrade(params[:info])
 151
 152     struct
 153     |> cast(params, [:bio, :name, :follower_address, :avatar, :last_refreshed_at])
 154     |> unique_constraint(:nickname)
 155     |> validate_format(:nickname, local_nickname_regex())
 156     |> validate_length(:bio, max: 5000)
 157     |> validate_length(:name, max: 100)
 158     |> put_embed(:info, info_cng)
 159   end
 160
 161   def password_update_changeset(struct, params) do
 162     changeset =
 163       struct
 164       |> cast(params, [:password, :password_confirmation])
 165       |> validate_required([:password, :password_confirmation])
 166       |> validate_confirmation(:password)
 167
 168     OAuth.Token.delete_user_tokens(struct)
 169     OAuth.Authorization.delete_user_authorizations(struct)
 170
 171     if changeset.valid? do
 172       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 173
 174       changeset
 175       |> put_change(:password_hash, hashed)
 176     else
 177       changeset
 178     end
 179   end
 180
 181   def reset_password(user, data) do
 182     update_and_set_cache(password_update_changeset(user, data))
 183   end
 184
 185   def register_changeset(struct, params \\ %{}, opts \\ []) do
 186     confirmation_status =
 187       if opts[:confirmed] || !Pleroma.Config.get([:instance, :account_activation_required]) do
 188         :confirmed
 189       else
 190         :unconfirmed
 191       end
 192
 193     info_change = User.Info.confirmation_changeset(%User.Info{}, confirmation_status)
 194
 195     changeset =
 196       struct
 197       |> cast(params, [:bio, :email, :name, :nickname, :password, :password_confirmation])
 198       |> validate_required([:email, :name, :nickname, :password, :password_confirmation])
 199       |> validate_confirmation(:password)
 200       |> unique_constraint(:email)
 201       |> unique_constraint(:nickname)
 202       |> validate_format(:nickname, local_nickname_regex())
 203       |> validate_format(:email, @email_regex)
 204       |> validate_length(:bio, max: 1000)
 205       |> validate_length(:name, min: 1, max: 100)
 206       |> put_change(:info, info_change)
 207
 208     if changeset.valid? do
 209       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 210       ap_id = User.ap_id(%User{nickname: changeset.changes[:nickname]})
 211       followers = User.ap_followers(%User{nickname: changeset.changes[:nickname]})
 212
 213       changeset
 214       |> put_change(:password_hash, hashed)
 215       |> put_change(:ap_id, ap_id)
 216       |> put_change(:following, [followers])
 217       |> put_change(:follower_address, followers)
 218     else
 219       changeset
 220     end
 221   end
 222
 223   @doc "Inserts provided changeset, performs post-registration actions (confirmation email sending etc.)"
 224   def register(%Ecto.Changeset{} = changeset) do
 225     with {:ok, user} <- Repo.insert(changeset),
 226          {:ok, _} = try_send_confirmation_email(user) do
 227       {:ok, user}
 228     end
 229   end
 230
 231   def try_send_confirmation_email(%User{} = user) do
 232     if user.info.confirmation_pending &&
 233          Pleroma.Config.get([:instance, :account_activation_required]) do
 234       user
 235       |> Pleroma.UserEmail.account_confirmation_email()
 236       |> Pleroma.Mailer.deliver()
 237     else
 238       {:ok, :noop}
 239     end
 240   end
 241
 242   def needs_update?(%User{local: true}), do: false
 243
 244   def needs_update?(%User{local: false, last_refreshed_at: nil}), do: true
 245
 246   def needs_update?(%User{local: false} = user) do
 247     NaiveDateTime.diff(NaiveDateTime.utc_now(), user.last_refreshed_at) >= 86400
 248   end
 249
 250   def needs_update?(_), do: true
 251
 252   def maybe_direct_follow(%User{} = follower, %User{local: true, info: %{locked: true}}) do
 253     {:ok, follower}
 254   end
 255
 256   def maybe_direct_follow(%User{} = follower, %User{local: true} = followed) do
 257     follow(follower, followed)
 258   end
 259
 260   def maybe_direct_follow(%User{} = follower, %User{} = followed) do
 261     if not User.ap_enabled?(followed) do
 262       follow(follower, followed)
 263     else
 264       {:ok, follower}
 265     end
 266   end
 267
 268   def maybe_follow(%User{} = follower, %User{info: _info} = followed) do
 269     if not following?(follower, followed) do
 270       follow(follower, followed)
 271     else
 272       {:ok, follower}
 273     end
 274   end
 275
 276   def follow(%User{} = follower, %User{info: info} = followed) do
 277     user_config = Application.get_env(:pleroma, :user)
 278     deny_follow_blocked = Keyword.get(user_config, :deny_follow_blocked)
 279
 280     ap_followers = followed.follower_address
 281
 282     cond do
 283       following?(follower, followed) or info.deactivated ->
 284         {:error, "Could not follow user: #{followed.nickname} is already on your list."}
 285
 286       deny_follow_blocked and blocks?(followed, follower) ->
 287         {:error, "Could not follow user: #{followed.nickname} blocked you."}
 288
 289       true ->
 290         if !followed.local && follower.local && !ap_enabled?(followed) do
 291           Websub.subscribe(follower, followed)
 292         end
 293
 294         following =
 295           [ap_followers | follower.following]
 296           |> Enum.uniq()
 297
 298         follower =
 299           follower
 300           |> follow_changeset(%{following: following})
 301           |> update_and_set_cache
 302
 303         {:ok, _} = update_follower_count(followed)
 304
 305         follower
 306     end
 307   end
 308
 309   def unfollow(%User{} = follower, %User{} = followed) do
 310     ap_followers = followed.follower_address
 311
 312     if following?(follower, followed) and follower.ap_id != followed.ap_id do
 313       following =
 314         follower.following
 315         |> List.delete(ap_followers)
 316
 317       {:ok, follower} =
 318         follower
 319         |> follow_changeset(%{following: following})
 320         |> update_and_set_cache
 321
 322       {:ok, followed} = update_follower_count(followed)
 323
 324       {:ok, follower, Utils.fetch_latest_follow(follower, followed)}
 325     else
 326       {:error, "Not subscribed!"}
 327     end
 328   end
 329
 330   @spec following?(User.t(), User.t()) :: boolean
 331   def following?(%User{} = follower, %User{} = followed) do
 332     Enum.member?(follower.following, followed.follower_address)
 333   end
 334
 335   def locked?(%User{} = user) do
 336     user.info.locked || false
 337   end
 338
 339   def get_by_ap_id(ap_id) do
 340     Repo.get_by(User, ap_id: ap_id)
 341   end
 342
 343   def update_and_set_cache(changeset) do
 344     with {:ok, user} <- Repo.update(changeset) do
 345       Cachex.put(:user_cache, "ap_id:#{user.ap_id}", user)
 346       Cachex.put(:user_cache, "nickname:#{user.nickname}", user)
 347       Cachex.put(:user_cache, "user_info:#{user.id}", user_info(user))
 348       {:ok, user}
 349     else
 350       e -> e
 351     end
 352   end
 353
 354   def invalidate_cache(user) do
 355     Cachex.del(:user_cache, "ap_id:#{user.ap_id}")
 356     Cachex.del(:user_cache, "nickname:#{user.nickname}")
 357     Cachex.del(:user_cache, "user_info:#{user.id}")
 358   end
 359
 360   def get_cached_by_ap_id(ap_id) do
 361     key = "ap_id:#{ap_id}"
 362     Cachex.fetch!(:user_cache, key, fn _ -> get_by_ap_id(ap_id) end)
 363   end
 364
 365   def get_cached_by_nickname(nickname) do
 366     key = "nickname:#{nickname}"
 367     Cachex.fetch!(:user_cache, key, fn _ -> get_or_fetch_by_nickname(nickname) end)
 368   end
 369
 370   def get_by_nickname(nickname) do
 371     Repo.get_by(User, nickname: nickname)
 372   end
 373
 374   def get_by_nickname_or_email(nickname_or_email) do
 375     case user = Repo.get_by(User, nickname: nickname_or_email) do
 376       %User{} -> user
 377       nil -> Repo.get_by(User, email: nickname_or_email)
 378     end
 379   end
 380
 381   def get_cached_user_info(user) do
 382     key = "user_info:#{user.id}"
 383     Cachex.fetch!(:user_cache, key, fn _ -> user_info(user) end)
 384   end
 385
 386   def fetch_by_nickname(nickname) do
 387     ap_try = ActivityPub.make_user_from_nickname(nickname)
 388
 389     case ap_try do
 390       {:ok, user} -> {:ok, user}
 391       _ -> OStatus.make_user(nickname)
 392     end
 393   end
 394
 395   def get_or_fetch_by_nickname(nickname) do
 396     with %User{} = user <- get_by_nickname(nickname) do
 397       user
 398     else
 399       _e ->
 400         with [_nick, _domain] <- String.split(nickname, "@"),
 401              {:ok, user} <- fetch_by_nickname(nickname) do
 402           user
 403         else
 404           _e -> nil
 405         end
 406     end
 407   end
 408
 409   def get_followers_query(%User{id: id, follower_address: follower_address}) do
 410     from(
 411       u in User,
 412       where: fragment("? <@ ?", ^[follower_address], u.following),
 413       where: u.id != ^id
 414     )
 415   end
 416
 417   def get_followers(user) do
 418     q = get_followers_query(user)
 419
 420     {:ok, Repo.all(q)}
 421   end
 422
 423   def get_friends_query(%User{id: id, following: following}) do
 424     from(
 425       u in User,
 426       where: u.follower_address in ^following,
 427       where: u.id != ^id
 428     )
 429   end
 430
 431   def get_friends(user) do
 432     q = get_friends_query(user)
 433
 434     {:ok, Repo.all(q)}
 435   end
 436
 437   def get_follow_requests_query(%User{} = user) do
 438     from(
 439       a in Activity,
 440       where:
 441         fragment(
 442           "? ->> 'type' = 'Follow'",
 443           a.data
 444         ),
 445       where:
 446         fragment(
 447           "? ->> 'state' = 'pending'",
 448           a.data
 449         ),
 450       where:
 451         fragment(
 452           "? @> ?",
 453           a.data,
 454           ^%{"object" => user.ap_id}
 455         )
 456     )
 457   end
 458
 459   def get_follow_requests(%User{} = user) do
 460     q = get_follow_requests_query(user)
 461     reqs = Repo.all(q)
 462
 463     users =
 464       Enum.map(reqs, fn req -> req.actor end)
 465       |> Enum.uniq()
 466       |> Enum.map(fn ap_id -> get_by_ap_id(ap_id) end)
 467       |> Enum.filter(fn u -> !following?(u, user) end)
 468
 469     {:ok, users}
 470   end
 471
 472   def increase_note_count(%User{} = user) do
 473     info_cng = User.Info.add_to_note_count(user.info, 1)
 474
 475     cng =
 476       change(user)
 477       |> put_embed(:info, info_cng)
 478
 479     update_and_set_cache(cng)
 480   end
 481
 482   def decrease_note_count(%User{} = user) do
 483     info_cng = User.Info.add_to_note_count(user.info, -1)
 484
 485     cng =
 486       change(user)
 487       |> put_embed(:info, info_cng)
 488
 489     update_and_set_cache(cng)
 490   end
 491
 492   def update_note_count(%User{} = user) do
 493     note_count_query =
 494       from(
 495         a in Object,
 496         where: fragment("?->>'actor' = ? and ?->>'type' = 'Note'", a.data, ^user.ap_id, a.data),
 497         select: count(a.id)
 498       )
 499
 500     note_count = Repo.one(note_count_query)
 501
 502     info_cng = User.Info.set_note_count(user.info, note_count)
 503
 504     cng =
 505       change(user)
 506       |> put_embed(:info, info_cng)
 507
 508     update_and_set_cache(cng)
 509   end
 510
 511   def update_follower_count(%User{} = user) do
 512     follower_count_query =
 513       from(
 514         u in User,
 515         where: ^user.follower_address in u.following,
 516         where: u.id != ^user.id,
 517         select: count(u.id)
 518       )
 519
 520     follower_count = Repo.one(follower_count_query)
 521
 522     info_cng =
 523       user.info
 524       |> User.Info.set_follower_count(follower_count)
 525
 526     cng =
 527       change(user)
 528       |> put_embed(:info, info_cng)
 529
 530     update_and_set_cache(cng)
 531   end
 532
 533   def get_users_from_set_query(ap_ids, false) do
 534     from(
 535       u in User,
 536       where: u.ap_id in ^ap_ids
 537     )
 538   end
 539
 540   def get_users_from_set_query(ap_ids, true) do
 541     query = get_users_from_set_query(ap_ids, false)
 542
 543     from(
 544       u in query,
 545       where: u.local == true
 546     )
 547   end
 548
 549   def get_users_from_set(ap_ids, local_only \\ true) do
 550     get_users_from_set_query(ap_ids, local_only)
 551     |> Repo.all()
 552   end
 553
 554   def get_recipients_from_activity(%Activity{recipients: to}) do
 555     query =
 556       from(
 557         u in User,
 558         where: u.ap_id in ^to,
 559         or_where: fragment("? && ?", u.following, ^to)
 560       )
 561
 562     query = from(u in query, where: u.local == true)
 563
 564     Repo.all(query)
 565   end
 566
 567   def search(query, resolve \\ false) do
 568     # strip the beginning @ off if there is a query
 569     query = String.trim_leading(query, "@")
 570
 571     if resolve do
 572       User.get_or_fetch_by_nickname(query)
 573     end
 574
 575     inner =
 576       from(
 577         u in User,
 578         select_merge: %{
 579           search_distance:
 580             fragment(
 581               "? <-> (? || ?)",
 582               ^query,
 583               u.nickname,
 584               u.name
 585             )
 586         },
 587         where: not is_nil(u.nickname)
 588       )
 589
 590     q =
 591       from(
 592         s in subquery(inner),
 593         order_by: s.search_distance,
 594         limit: 20
 595       )
 596
 597     Repo.all(q)
 598   end
 599
 600   def block(blocker, %User{ap_id: ap_id} = blocked) do
 601     # sever any follow relationships to prevent leaks per activitypub (Pleroma issue #213)
 602     blocker =
 603       if following?(blocker, blocked) do
 604         {:ok, blocker, _} = unfollow(blocker, blocked)
 605         blocker
 606       else
 607         blocker
 608       end
 609
 610     if following?(blocked, blocker) do
 611       unfollow(blocked, blocker)
 612     end
 613
 614     info_cng =
 615       blocker.info
 616       |> User.Info.add_to_block(ap_id)
 617
 618     cng =
 619       change(blocker)
 620       |> put_embed(:info, info_cng)
 621
 622     update_and_set_cache(cng)
 623   end
 624
 625   # helper to handle the block given only an actor's AP id
 626   def block(blocker, %{ap_id: ap_id}) do
 627     block(blocker, User.get_by_ap_id(ap_id))
 628   end
 629
 630   def unblock(blocker, %{ap_id: ap_id}) do
 631     info_cng =
 632       blocker.info
 633       |> User.Info.remove_from_block(ap_id)
 634
 635     cng =
 636       change(blocker)
 637       |> put_embed(:info, info_cng)
 638
 639     update_and_set_cache(cng)
 640   end
 641
 642   def blocks?(user, %{ap_id: ap_id}) do
 643     blocks = user.info.blocks
 644     domain_blocks = user.info.domain_blocks
 645     %{host: host} = URI.parse(ap_id)
 646
 647     Enum.member?(blocks, ap_id) ||
 648       Enum.any?(domain_blocks, fn domain ->
 649         host == domain
 650       end)
 651   end
 652
 653   def block_domain(user, domain) do
 654     info_cng =
 655       user.info
 656       |> User.Info.add_to_domain_block(domain)
 657
 658     cng =
 659       change(user)
 660       |> put_embed(:info, info_cng)
 661
 662     update_and_set_cache(cng)
 663   end
 664
 665   def unblock_domain(user, domain) do
 666     info_cng =
 667       user.info
 668       |> User.Info.remove_from_domain_block(domain)
 669
 670     cng =
 671       change(user)
 672       |> put_embed(:info, info_cng)
 673
 674     update_and_set_cache(cng)
 675   end
 676
 677   def local_user_query() do
 678     from(
 679       u in User,
 680       where: u.local == true,
 681       where: not is_nil(u.nickname)
 682     )
 683   end
 684
 685   def moderator_user_query() do
 686     from(
 687       u in User,
 688       where: u.local == true,
 689       where: fragment("?->'is_moderator' @> 'true'", u.info)
 690     )
 691   end
 692
 693   def deactivate(%User{} = user, status \\ true) do
 694     info_cng = User.Info.set_activation_status(user.info, status)
 695
 696     cng =
 697       change(user)
 698       |> put_embed(:info, info_cng)
 699
 700     update_and_set_cache(cng)
 701   end
 702
 703   def delete(%User{} = user) do
 704     {:ok, user} = User.deactivate(user)
 705
 706     # Remove all relationships
 707     {:ok, followers} = User.get_followers(user)
 708
 709     followers
 710     |> Enum.each(fn follower -> User.unfollow(follower, user) end)
 711
 712     {:ok, friends} = User.get_friends(user)
 713
 714     friends
 715     |> Enum.each(fn followed -> User.unfollow(user, followed) end)
 716
 717     query = from(a in Activity, where: a.actor == ^user.ap_id)
 718
 719     Repo.all(query)
 720     |> Enum.each(fn activity ->
 721       case activity.data["type"] do
 722         "Create" ->
 723           ActivityPub.delete(Object.normalize(activity.data["object"]))
 724
 725         # TODO: Do something with likes, follows, repeats.
 726         _ ->
 727           "Doing nothing"
 728       end
 729     end)
 730
 731     {:ok, user}
 732   end
 733
 734   def html_filter_policy(%User{info: %{no_rich_text: true}}) do
 735     Pleroma.HTML.Scrubber.TwitterText
 736   end
 737
 738   def html_filter_policy(_), do: nil
 739
 740   def get_or_fetch_by_ap_id(ap_id) do
 741     user = get_by_ap_id(ap_id)
 742
 743     if !is_nil(user) and !User.needs_update?(user) do
 744       user
 745     else
 746       ap_try = ActivityPub.make_user_from_ap_id(ap_id)
 747
 748       case ap_try do
 749         {:ok, user} ->
 750           user
 751
 752         _ ->
 753           case OStatus.make_user(ap_id) do
 754             {:ok, user} -> user
 755             _ -> {:error, "Could not fetch by AP id"}
 756           end
 757       end
 758     end
 759   end
 760
 761   def get_or_create_instance_user do
 762     relay_uri = "#{Pleroma.Web.Endpoint.url()}/relay"
 763
 764     if user = get_by_ap_id(relay_uri) do
 765       user
 766     else
 767       changes =
 768         %User{info: %User.Info{}}
 769         |> cast(%{}, [:ap_id, :nickname, :local])
 770         |> put_change(:ap_id, relay_uri)
 771         |> put_change(:nickname, nil)
 772         |> put_change(:local, true)
 773         |> put_change(:follower_address, relay_uri <> "/followers")
 774
 775       {:ok, user} = Repo.insert(changes)
 776       user
 777     end
 778   end
 779
 780   # AP style
 781   def public_key_from_info(%{
 782         source_data: %{"publicKey" => %{"publicKeyPem" => public_key_pem}}
 783       }) do
 784     key =
 785       public_key_pem
 786       |> :public_key.pem_decode()
 787       |> hd()
 788       |> :public_key.pem_entry_decode()
 789
 790     {:ok, key}
 791   end
 792
 793   # OStatus Magic Key
 794   def public_key_from_info(%{magic_key: magic_key}) do
 795     {:ok, Pleroma.Web.Salmon.decode_key(magic_key)}
 796   end
 797
 798   def get_public_key_for_ap_id(ap_id) do
 799     with %User{} = user <- get_or_fetch_by_ap_id(ap_id),
 800          {:ok, public_key} <- public_key_from_info(user.info) do
 801       {:ok, public_key}
 802     else
 803       _ -> :error
 804     end
 805   end
 806
 807   defp blank?(""), do: nil
 808   defp blank?(n), do: n
 809
 810   def insert_or_update_user(data) do
 811     data =
 812       data
 813       |> Map.put(:name, blank?(data[:name]) || data[:nickname])
 814
 815     cs = User.remote_user_creation(data)
 816
 817     Repo.insert(cs, on_conflict: :replace_all, conflict_target: :nickname)
 818   end
 819
 820   def ap_enabled?(%User{local: true}), do: true
 821   def ap_enabled?(%User{info: info}), do: info.ap_enabled
 822   def ap_enabled?(_), do: false
 823
 824   @doc "Gets or fetch a user by uri or nickname."
 825   @spec get_or_fetch(String.t()) :: User.t()
 826   def get_or_fetch("http" <> _host = uri), do: get_or_fetch_by_ap_id(uri)
 827   def get_or_fetch(nickname), do: get_or_fetch_by_nickname(nickname)
 828
 829   # wait a period of time and return newest version of the User structs
 830   # this is because we have synchronous follow APIs and need to simulate them
 831   # with an async handshake
 832   def wait_and_refresh(_, %User{local: true} = a, %User{local: true} = b) do
 833     with %User{} = a <- Repo.get(User, a.id),
 834          %User{} = b <- Repo.get(User, b.id) do
 835       {:ok, a, b}
 836     else
 837       _e ->
 838         :error
 839     end
 840   end
 841
 842   def wait_and_refresh(timeout, %User{} = a, %User{} = b) do
 843     with :ok <- :timer.sleep(timeout),
 844          %User{} = a <- Repo.get(User, a.id),
 845          %User{} = b <- Repo.get(User, b.id) do
 846       {:ok, a, b}
 847     else
 848       _e ->
 849         :error
 850     end
 851   end
 852
 853   def parse_bio(bio, user \\ %User{info: %{source_data: %{}}})
 854   def parse_bio(nil, _user), do: ""
 855   def parse_bio(bio, _user) when bio == "", do: bio
 856
 857   def parse_bio(bio, user) do
 858     mentions = Formatter.parse_mentions(bio)
 859     tags = Formatter.parse_tags(bio)
 860
 861     emoji =
 862       (user.info.source_data["tag"] || [])
 863       |> Enum.filter(fn %{"type" => t} -> t == "Emoji" end)
 864       |> Enum.map(fn %{"icon" => %{"url" => url}, "name" => name} ->
 865         {String.trim(name, ":"), url}
 866       end)
 867
 868     bio
 869     |> CommonUtils.format_input(mentions, tags, "text/plain")
 870     |> Formatter.emojify(emoji)
 871   end
 872
 873   def tag(user_identifiers, tags) when is_list(user_identifiers) do
 874     Repo.transaction(fn ->
 875       for user_identifier <- user_identifiers, do: tag(user_identifier, tags)
 876     end)
 877   end
 878
 879   def tag(nickname, tags) when is_binary(nickname),
 880     do: tag(User.get_by_nickname(nickname), tags)
 881
 882   def tag(%User{} = user, tags),
 883     do: update_tags(user, Enum.uniq((user.tags || []) ++ normalize_tags(tags)))
 884
 885   def untag(user_identifiers, tags) when is_list(user_identifiers) do
 886     Repo.transaction(fn ->
 887       for user_identifier <- user_identifiers, do: untag(user_identifier, tags)
 888     end)
 889   end
 890
 891   def untag(nickname, tags) when is_binary(nickname),
 892     do: untag(User.get_by_nickname(nickname), tags)
 893
 894   def untag(%User{} = user, tags),
 895     do: update_tags(user, (user.tags || []) -- normalize_tags(tags))
 896
 897   defp update_tags(%User{} = user, new_tags) do
 898     {:ok, updated_user} =
 899       user
 900       |> change(%{tags: new_tags})
 901       |> Repo.update()
 902
 903     updated_user
 904   end
 905
 906   defp normalize_tags(tags) do
 907     [tags]
 908     |> List.flatten()
 909     |> Enum.map(&String.downcase(&1))
 910   end
 911
 912   defp local_nickname_regex() do
 913     if Pleroma.Config.get([:instance, :extended_nickname_format]) do
 914       @extended_local_nickname_regex
 915     else
 916       @strict_local_nickname_regex
 917     end
 918   end
 919 end