git.squeep.com Git - akkoma/blob - lib/pleroma/user.ex

   1 defmodule Pleroma.User do
   2   use Ecto.Schema
   3
   4   import Ecto.{Changeset, Query}
   5   alias Pleroma.{Repo, User, Object, Web, Activity, Notification}
   6   alias Comeonin.Pbkdf2
   7   alias Pleroma.Web.{OStatus, Websub}
   8   alias Pleroma.Web.ActivityPub.Utils
   9
  10   schema "users" do
  11     field :bio, :string
  12     field :email, :string
  13     field :name, :string
  14     field :nickname, :string
  15     field :password_hash, :string
  16     field :password, :string, virtual: true
  17     field :password_confirmation, :string, virtual: true
  18     field :following, {:array, :string}, default: []
  19     field :ap_id, :string
  20     field :avatar, :map
  21     field :local, :boolean, default: true
  22     field :info, :map, default: %{}
  23     field :follower_address, :string
  24     has_many :notifications, Notification
  25
  26     timestamps()
  27   end
  28
  29   def avatar_url(user) do
  30     case user.avatar do
  31       %{"url" => [%{"href" => href} | _]} -> href
  32       _ -> "https://placehold.it/48x48"
  33     end
  34   end
  35
  36   def banner_url(user) do
  37     case user.info["banner"] do
  38       %{"url" => [%{"href" => href} | _]} -> href
  39       _ -> nil
  40     end
  41   end
  42
  43   def ap_id(%User{nickname: nickname}) do
  44     "#{Web.base_url}/users/#{nickname}"
  45   end
  46
  47   def ap_followers(%User{} = user) do
  48     "#{ap_id(user)}/followers"
  49   end
  50
  51   def follow_changeset(struct, params \\ %{}) do
  52     struct
  53     |> cast(params, [:following])
  54     |> validate_required([:following])
  55   end
  56
  57   def info_changeset(struct, params \\ %{}) do
  58     struct
  59     |> cast(params, [:info])
  60     |> validate_required([:info])
  61   end
  62
  63   def user_info(%User{} = user) do
  64     oneself = if user.local, do: 1, else: 0
  65     %{
  66       following_count: length(user.following) - oneself,
  67       note_count: user.info["note_count"] || 0,
  68       follower_count: user.info["follower_count"] || 0
  69     }
  70   end
  71
  72   @email_regex ~r/^[a-zA-Z0-9.!#$%&'*+\/=?^_`{|}~-]+@[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?(?:\.[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?)*$/
  73   def remote_user_creation(params) do
  74     changes = %User{}
  75     |> cast(params, [:bio, :name, :ap_id, :nickname, :info, :avatar])
  76     |> validate_required([:name, :ap_id, :nickname])
  77     |> unique_constraint(:nickname)
  78     |> validate_format(:nickname, @email_regex)
  79     |> validate_length(:bio, max: 5000)
  80     |> validate_length(:name, max: 100)
  81     |> put_change(:local, false)
  82     if changes.valid? do
  83       followers = User.ap_followers(%User{nickname: changes.changes[:nickname]})
  84       changes
  85       |> put_change(:follower_address, followers)
  86     else
  87       changes
  88     end
  89   end
  90
  91   def update_changeset(struct, params \\ %{}) do
  92     struct
  93     |> cast(params, [:bio, :name])
  94     |> unique_constraint(:nickname)
  95     |> validate_format(:nickname, ~r/^[a-zA-Z\d]+$/)
  96     |> validate_length(:bio, min: 1, max: 1000)
  97     |> validate_length(:name, min: 1, max: 100)
  98   end
  99
 100   def password_update_changeset(struct, params) do
 101     changeset = struct
 102     |> cast(params, [:password, :password_confirmation])
 103     |> validate_required([:password, :password_confirmation])
 104     |> validate_confirmation(:password)
 105
 106     if changeset.valid? do
 107       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 108       changeset
 109       |> put_change(:password_hash, hashed)
 110     else
 111       changeset
 112     end
 113   end
 114
 115   def reset_password(user, data) do
 116     Repo.update(password_update_changeset(user, data))
 117   end
 118
 119   def register_changeset(struct, params \\ %{}) do
 120     changeset = struct
 121     |> cast(params, [:bio, :email, :name, :nickname, :password, :password_confirmation])
 122     |> validate_required([:bio, :email, :name, :nickname, :password, :password_confirmation])
 123     |> validate_confirmation(:password)
 124     |> unique_constraint(:email)
 125     |> unique_constraint(:nickname)
 126     |> validate_format(:nickname, ~r/^[a-zA-Z\d]+$/)
 127     |> validate_format(:email, @email_regex)
 128     |> validate_length(:bio, min: 1, max: 1000)
 129     |> validate_length(:name, min: 1, max: 100)
 130
 131     if changeset.valid? do
 132       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 133       ap_id = User.ap_id(%User{nickname: changeset.changes[:nickname]})
 134       followers = User.ap_followers(%User{nickname: changeset.changes[:nickname]})
 135       changeset
 136       |> put_change(:password_hash, hashed)
 137       |> put_change(:ap_id, ap_id)
 138       |> put_change(:following, [followers])
 139       |> put_change(:follower_address, followers)
 140     else
 141       changeset
 142     end
 143   end
 144
 145   def follow(%User{} = follower, %User{info: info} = followed) do
 146     ap_followers = followed.follower_address
 147     if following?(follower, followed) or info["deactivated"] do
 148       {:error,
 149        "Could not follow user: #{followed.nickname} is already on your list."}
 150     else
 151       if !followed.local && follower.local do
 152         Websub.subscribe(follower, followed)
 153       end
 154
 155       following = [ap_followers | follower.following]
 156       |> Enum.uniq
 157
 158       follower = follower
 159       |> follow_changeset(%{following: following})
 160       |> Repo.update
 161
 162       {:ok, _} = update_follower_count(followed)
 163
 164       follower
 165     end
 166   end
 167
 168   def unfollow(%User{} = follower, %User{} = followed) do
 169     ap_followers = followed.follower_address
 170     if following?(follower, followed) and follower.ap_id != followed.ap_id do
 171       following = follower.following
 172       |> List.delete(ap_followers)
 173
 174       { :ok, follower } = follower
 175       |> follow_changeset(%{following: following})
 176       |> Repo.update
 177
 178       {:ok, followed} = update_follower_count(followed)
 179
 180       {:ok, follower, Utils.fetch_latest_follow(follower, followed)}
 181     else
 182       {:error, "Not subscribed!"}
 183     end
 184   end
 185
 186   def following?(%User{} = follower, %User{} = followed) do
 187     Enum.member?(follower.following, followed.follower_address)
 188   end
 189
 190   def get_by_ap_id(ap_id) do
 191     Repo.get_by(User, ap_id: ap_id)
 192   end
 193
 194   def get_cached_by_ap_id(ap_id) do
 195     key = "ap_id:#{ap_id}"
 196     Cachex.get!(:user_cache, key, fallback: fn(_) -> get_by_ap_id(ap_id) end)
 197   end
 198
 199   def get_cached_by_nickname(nickname) do
 200     key = "nickname:#{nickname}"
 201     Cachex.get!(:user_cache, key, fallback: fn(_) -> get_or_fetch_by_nickname(nickname) end)
 202   end
 203
 204   def get_by_nickname(nickname) do
 205     Repo.get_by(User, nickname: nickname)
 206   end
 207
 208   def get_cached_user_info(user) do
 209     key = "user_info:#{user.id}"
 210     Cachex.get!(:user_cache, key, fallback: fn(_) -> user_info(user) end)
 211   end
 212
 213   def get_or_fetch_by_nickname(nickname) do
 214     with %User{} = user <- get_by_nickname(nickname)  do
 215       user
 216     else _e ->
 217       with [_nick, _domain] <- String.split(nickname, "@"),
 218            {:ok, user} <- OStatus.make_user(nickname) do
 219         user
 220       else _e -> nil
 221       end
 222     end
 223   end
 224
 225   # TODO: these queries could be more efficient if the type in postgresql wasn't map, but array.
 226   def get_followers(%User{id: id, follower_address: follower_address}) do
 227     q = from u in User,
 228       where: fragment("? @> ?", u.following, ^follower_address ),
 229       where: u.id != ^id
 230
 231     {:ok, Repo.all(q)}
 232   end
 233
 234   def get_friends(%User{id: id, following: following}) do
 235     q = from u in User,
 236       where: u.follower_address in ^following,
 237       where: u.id != ^id
 238
 239     {:ok, Repo.all(q)}
 240   end
 241
 242   def increase_note_count(%User{} = user) do
 243     note_count = (user.info["note_count"] || 0) + 1
 244     new_info = Map.put(user.info, "note_count", note_count)
 245
 246     cs = info_changeset(user, %{info: new_info})
 247
 248     Repo.update(cs)
 249   end
 250
 251   def update_note_count(%User{} = user) do
 252     note_count_query = from a in Object,
 253       where: fragment("?->>'actor' = ? and ?->>'type' = 'Note'", a.data, ^user.ap_id, a.data),
 254       select: count(a.id)
 255
 256     note_count = Repo.one(note_count_query)
 257
 258     new_info = Map.put(user.info, "note_count", note_count)
 259
 260     cs = info_changeset(user, %{info: new_info})
 261
 262     Repo.update(cs)
 263   end
 264
 265   def update_follower_count(%User{} = user) do
 266     follower_count_query = from u in User,
 267       where: fragment("? @> ?", u.following, ^user.follower_address),
 268       where: u.id != ^user.id,
 269       select: count(u.id)
 270
 271     follower_count = Repo.one(follower_count_query)
 272
 273     new_info = Map.put(user.info, "follower_count", follower_count)
 274
 275     cs = info_changeset(user, %{info: new_info})
 276
 277     Repo.update(cs)
 278   end
 279
 280   def get_notified_from_activity(%Activity{data: %{"to" => to}}) do
 281     query = from u in User,
 282       where: u.ap_id in ^to,
 283       where: u.local == true
 284
 285     Repo.all(query)
 286   end
 287
 288   def get_recipients_from_activity(%Activity{data: %{"to" => to}}) do
 289     query = from u in User,
 290       where: u.ap_id in ^to,
 291       or_where: fragment("? \\\?| ?", u.following, ^to)
 292
 293     query = from u in query,
 294       where: u.local == true
 295
 296     Repo.all(query)
 297   end
 298
 299   def search(query, resolve) do
 300     if resolve do
 301       User.get_or_fetch_by_nickname(query)
 302     end
 303     q = from u in User,
 304       where: fragment("(to_tsvector('english', ?) || to_tsvector('english', ?)) @@ plainto_tsquery('english', ?)", u.nickname, u.name, ^query),
 305       limit: 20
 306     Repo.all(q)
 307   end
 308
 309   def block(user, %{ap_id: ap_id}) do
 310     blocks = user.info["blocks"] || []
 311     new_blocks = Enum.uniq([ap_id | blocks])
 312     new_info = Map.put(user.info, "blocks", new_blocks)
 313
 314     cs = User.info_changeset(user, %{info: new_info})
 315     Repo.update(cs)
 316   end
 317
 318   def unblock(user, %{ap_id: ap_id}) do
 319     blocks = user.info["blocks"] || []
 320     new_blocks = List.delete(blocks, ap_id)
 321     new_info = Map.put(user.info, "blocks", new_blocks)
 322
 323     cs = User.info_changeset(user, %{info: new_info})
 324     Repo.update(cs)
 325   end
 326
 327   def blocks?(user, %{ap_id: ap_id}) do
 328     blocks = user.info["blocks"] || []
 329     Enum.member?(blocks, ap_id)
 330   end
 331
 332   def local_user_query() do
 333     from u in User,
 334       where: u.local == true
 335   end
 336
 337   def deactivate (%User{} = user) do
 338     new_info = Map.put(user.info, "deactivated", true)
 339     cs = User.info_changeset(user, %{info: new_info})
 340     Repo.update(cs)
 341   end
 342 end