git.squeep.com Git - akkoma/blob - lib/pleroma/user.ex

   1 defmodule Pleroma.User do
   2   use Ecto.Schema
   3
   4   import Ecto.{Changeset, Query}
   5   alias Pleroma.{Repo, User, Object, Web, Activity, Notification}
   6   alias Comeonin.Pbkdf2
   7   alias Pleroma.Formatter
   8   alias Pleroma.Web.CommonAPI.Utils, as: CommonUtils
   9   alias Pleroma.Web.{OStatus, Websub, OAuth}
  10   alias Pleroma.Web.ActivityPub.{Utils, ActivityPub}
  11
  12   @type t :: %__MODULE__{}
  13
  14   @email_regex ~r/^[a-zA-Z0-9.!#$%&'*+\/=?^_`{|}~-]+@[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?(?:\.[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?)*$/
  15
  16   @strict_local_nickname_regex ~r/^[a-zA-Z\d]+$/
  17   @extended_local_nickname_regex ~r/^[a-zA-Z\d_-]+$/
  18
  19   schema "users" do
  20     field(:bio, :string)
  21     field(:email, :string)
  22     field(:name, :string)
  23     field(:nickname, :string)
  24     field(:password_hash, :string)
  25     field(:password, :string, virtual: true)
  26     field(:password_confirmation, :string, virtual: true)
  27     field(:following, {:array, :string}, default: [])
  28     field(:ap_id, :string)
  29     field(:avatar, :map)
  30     field(:local, :boolean, default: true)
  31     field(:follower_address, :string)
  32     field(:search_distance, :float, virtual: true)
  33     field(:tags, {:array, :string}, default: [])
  34     field(:last_refreshed_at, :naive_datetime)
  35     has_many(:notifications, Notification)
  36     embeds_one(:info, Pleroma.User.Info)
  37
  38     timestamps()
  39   end
  40
  41   def auth_active?(%User{} = user), do: user.info && !user.info.confirmation_pending
  42
  43   def superuser?(%User{} = user), do: user.info && User.Info.superuser?(user.info)
  44
  45   def avatar_url(user) do
  46     case user.avatar do
  47       %{"url" => [%{"href" => href} | _]} -> href
  48       _ -> "#{Web.base_url()}/images/avi.png"
  49     end
  50   end
  51
  52   def banner_url(user) do
  53     case user.info.banner do
  54       %{"url" => [%{"href" => href} | _]} -> href
  55       _ -> "#{Web.base_url()}/images/banner.png"
  56     end
  57   end
  58
  59   def profile_url(%User{info: %{source_data: %{"url" => url}}}), do: url
  60   def profile_url(%User{ap_id: ap_id}), do: ap_id
  61   def profile_url(_), do: nil
  62
  63   def ap_id(%User{nickname: nickname}) do
  64     "#{Web.base_url()}/users/#{nickname}"
  65   end
  66
  67   def ap_followers(%User{} = user) do
  68     "#{ap_id(user)}/followers"
  69   end
  70
  71   def follow_changeset(struct, params \\ %{}) do
  72     struct
  73     |> cast(params, [:following])
  74     |> validate_required([:following])
  75   end
  76
  77   def user_info(%User{} = user) do
  78     oneself = if user.local, do: 1, else: 0
  79
  80     %{
  81       following_count: length(user.following) - oneself,
  82       note_count: user.info.note_count,
  83       follower_count: user.info.follower_count,
  84       locked: user.info.locked,
  85       confirmation_pending: user.info.confirmation_pending,
  86       default_scope: user.info.default_scope
  87     }
  88   end
  89
  90   def remote_user_creation(params) do
  91     params =
  92       params
  93       |> Map.put(:info, params[:info] || %{})
  94
  95     info_cng = User.Info.remote_user_creation(%User.Info{}, params[:info])
  96
  97     changes =
  98       %User{}
  99       |> cast(params, [:bio, :name, :ap_id, :nickname, :avatar])
 100       |> validate_required([:name, :ap_id])
 101       |> unique_constraint(:nickname)
 102       |> validate_format(:nickname, @email_regex)
 103       |> validate_length(:bio, max: 5000)
 104       |> validate_length(:name, max: 100)
 105       |> put_change(:local, false)
 106       |> put_embed(:info, info_cng)
 107
 108     if changes.valid? do
 109       case info_cng.changes[:source_data] do
 110         %{"followers" => followers} ->
 111           changes
 112           |> put_change(:follower_address, followers)
 113
 114         _ ->
 115           followers = User.ap_followers(%User{nickname: changes.changes[:nickname]})
 116
 117           changes
 118           |> put_change(:follower_address, followers)
 119       end
 120     else
 121       changes
 122     end
 123   end
 124
 125   def update_changeset(struct, params \\ %{}) do
 126     struct
 127     |> cast(params, [:bio, :name, :avatar])
 128     |> unique_constraint(:nickname)
 129     |> validate_format(:nickname, local_nickname_regex())
 130     |> validate_length(:bio, max: 5000)
 131     |> validate_length(:name, min: 1, max: 100)
 132   end
 133
 134   def upgrade_changeset(struct, params \\ %{}) do
 135     params =
 136       params
 137       |> Map.put(:last_refreshed_at, NaiveDateTime.utc_now())
 138
 139     info_cng =
 140       struct.info
 141       |> User.Info.user_upgrade(params[:info])
 142
 143     struct
 144     |> cast(params, [:bio, :name, :follower_address, :avatar, :last_refreshed_at])
 145     |> unique_constraint(:nickname)
 146     |> validate_format(:nickname, local_nickname_regex())
 147     |> validate_length(:bio, max: 5000)
 148     |> validate_length(:name, max: 100)
 149     |> put_embed(:info, info_cng)
 150   end
 151
 152   def password_update_changeset(struct, params) do
 153     changeset =
 154       struct
 155       |> cast(params, [:password, :password_confirmation])
 156       |> validate_required([:password, :password_confirmation])
 157       |> validate_confirmation(:password)
 158
 159     OAuth.Token.delete_user_tokens(struct)
 160     OAuth.Authorization.delete_user_authorizations(struct)
 161
 162     if changeset.valid? do
 163       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 164
 165       changeset
 166       |> put_change(:password_hash, hashed)
 167     else
 168       changeset
 169     end
 170   end
 171
 172   def reset_password(user, data) do
 173     update_and_set_cache(password_update_changeset(user, data))
 174   end
 175
 176   def register_changeset(struct, params \\ %{}, opts \\ []) do
 177     confirmation_status =
 178       if opts[:confirmed] || !Pleroma.Config.get([:instance, :account_activation_required]) do
 179         :confirmed
 180       else
 181         :unconfirmed
 182       end
 183
 184     info_change = User.Info.confirmation_changeset(%User.Info{}, confirmation_status)
 185
 186     changeset =
 187       struct
 188       |> cast(params, [:bio, :email, :name, :nickname, :password, :password_confirmation])
 189       |> validate_required([:email, :name, :nickname, :password, :password_confirmation])
 190       |> validate_confirmation(:password)
 191       |> unique_constraint(:email)
 192       |> unique_constraint(:nickname)
 193       |> validate_format(:nickname, local_nickname_regex())
 194       |> validate_format(:email, @email_regex)
 195       |> validate_length(:bio, max: 1000)
 196       |> validate_length(:name, min: 1, max: 100)
 197       |> put_change(:info, info_change)
 198
 199     if changeset.valid? do
 200       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 201       ap_id = User.ap_id(%User{nickname: changeset.changes[:nickname]})
 202       followers = User.ap_followers(%User{nickname: changeset.changes[:nickname]})
 203
 204       changeset
 205       |> put_change(:password_hash, hashed)
 206       |> put_change(:ap_id, ap_id)
 207       |> put_change(:following, [followers])
 208       |> put_change(:follower_address, followers)
 209     else
 210       changeset
 211     end
 212   end
 213
 214   @doc "Inserts provided changeset, performs post-registration actions (confirmation email sending etc.)"
 215   def register(%Ecto.Changeset{} = changeset) do
 216     with {:ok, user} <- Repo.insert(changeset),
 217          {:ok, _} = try_send_confirmation_email(user) do
 218       {:ok, user}
 219     end
 220   end
 221
 222   def try_send_confirmation_email(%User{} = user) do
 223     if user.info.confirmation_pending do
 224       user
 225       |> Pleroma.UserEmail.account_confirmation_email()
 226       |> Pleroma.Mailer.deliver()
 227     else
 228       {:ok, :noop}
 229     end
 230   end
 231
 232   def needs_update?(%User{local: true}), do: false
 233
 234   def needs_update?(%User{local: false, last_refreshed_at: nil}), do: true
 235
 236   def needs_update?(%User{local: false} = user) do
 237     NaiveDateTime.diff(NaiveDateTime.utc_now(), user.last_refreshed_at) >= 86400
 238   end
 239
 240   def needs_update?(_), do: true
 241
 242   def maybe_direct_follow(%User{} = follower, %User{local: true, info: %{locked: true}}) do
 243     {:ok, follower}
 244   end
 245
 246   def maybe_direct_follow(%User{} = follower, %User{local: true} = followed) do
 247     follow(follower, followed)
 248   end
 249
 250   def maybe_direct_follow(%User{} = follower, %User{} = followed) do
 251     if not User.ap_enabled?(followed) do
 252       follow(follower, followed)
 253     else
 254       {:ok, follower}
 255     end
 256   end
 257
 258   def maybe_follow(%User{} = follower, %User{info: _info} = followed) do
 259     if not following?(follower, followed) do
 260       follow(follower, followed)
 261     else
 262       {:ok, follower}
 263     end
 264   end
 265
 266   def follow(%User{} = follower, %User{info: info} = followed) do
 267     user_config = Application.get_env(:pleroma, :user)
 268     deny_follow_blocked = Keyword.get(user_config, :deny_follow_blocked)
 269
 270     ap_followers = followed.follower_address
 271
 272     cond do
 273       following?(follower, followed) or info.deactivated ->
 274         {:error, "Could not follow user: #{followed.nickname} is already on your list."}
 275
 276       deny_follow_blocked and blocks?(followed, follower) ->
 277         {:error, "Could not follow user: #{followed.nickname} blocked you."}
 278
 279       true ->
 280         if !followed.local && follower.local && !ap_enabled?(followed) do
 281           Websub.subscribe(follower, followed)
 282         end
 283
 284         following =
 285           [ap_followers | follower.following]
 286           |> Enum.uniq()
 287
 288         follower =
 289           follower
 290           |> follow_changeset(%{following: following})
 291           |> update_and_set_cache
 292
 293         {:ok, _} = update_follower_count(followed)
 294
 295         follower
 296     end
 297   end
 298
 299   def unfollow(%User{} = follower, %User{} = followed) do
 300     ap_followers = followed.follower_address
 301
 302     if following?(follower, followed) and follower.ap_id != followed.ap_id do
 303       following =
 304         follower.following
 305         |> List.delete(ap_followers)
 306
 307       {:ok, follower} =
 308         follower
 309         |> follow_changeset(%{following: following})
 310         |> update_and_set_cache
 311
 312       {:ok, followed} = update_follower_count(followed)
 313
 314       {:ok, follower, Utils.fetch_latest_follow(follower, followed)}
 315     else
 316       {:error, "Not subscribed!"}
 317     end
 318   end
 319
 320   @spec following?(User.t(), User.t()) :: boolean
 321   def following?(%User{} = follower, %User{} = followed) do
 322     Enum.member?(follower.following, followed.follower_address)
 323   end
 324
 325   def locked?(%User{} = user) do
 326     user.info.locked || false
 327   end
 328
 329   def get_by_ap_id(ap_id) do
 330     Repo.get_by(User, ap_id: ap_id)
 331   end
 332
 333   def update_and_set_cache(changeset) do
 334     with {:ok, user} <- Repo.update(changeset) do
 335       Cachex.put(:user_cache, "ap_id:#{user.ap_id}", user)
 336       Cachex.put(:user_cache, "nickname:#{user.nickname}", user)
 337       Cachex.put(:user_cache, "user_info:#{user.id}", user_info(user))
 338       {:ok, user}
 339     else
 340       e -> e
 341     end
 342   end
 343
 344   def invalidate_cache(user) do
 345     Cachex.del(:user_cache, "ap_id:#{user.ap_id}")
 346     Cachex.del(:user_cache, "nickname:#{user.nickname}")
 347     Cachex.del(:user_cache, "user_info:#{user.id}")
 348   end
 349
 350   def get_cached_by_ap_id(ap_id) do
 351     key = "ap_id:#{ap_id}"
 352     Cachex.fetch!(:user_cache, key, fn _ -> get_by_ap_id(ap_id) end)
 353   end
 354
 355   def get_cached_by_nickname(nickname) do
 356     key = "nickname:#{nickname}"
 357     Cachex.fetch!(:user_cache, key, fn _ -> get_or_fetch_by_nickname(nickname) end)
 358   end
 359
 360   def get_by_nickname(nickname) do
 361     Repo.get_by(User, nickname: nickname)
 362   end
 363
 364   def get_by_nickname_or_email(nickname_or_email) do
 365     case user = Repo.get_by(User, nickname: nickname_or_email) do
 366       %User{} -> user
 367       nil -> Repo.get_by(User, email: nickname_or_email)
 368     end
 369   end
 370
 371   def get_cached_user_info(user) do
 372     key = "user_info:#{user.id}"
 373     Cachex.fetch!(:user_cache, key, fn _ -> user_info(user) end)
 374   end
 375
 376   def fetch_by_nickname(nickname) do
 377     ap_try = ActivityPub.make_user_from_nickname(nickname)
 378
 379     case ap_try do
 380       {:ok, user} -> {:ok, user}
 381       _ -> OStatus.make_user(nickname)
 382     end
 383   end
 384
 385   def get_or_fetch_by_nickname(nickname) do
 386     with %User{} = user <- get_by_nickname(nickname) do
 387       user
 388     else
 389       _e ->
 390         with [_nick, _domain] <- String.split(nickname, "@"),
 391              {:ok, user} <- fetch_by_nickname(nickname) do
 392           user
 393         else
 394           _e -> nil
 395         end
 396     end
 397   end
 398
 399   def get_followers_query(%User{id: id, follower_address: follower_address}) do
 400     from(
 401       u in User,
 402       where: fragment("? <@ ?", ^[follower_address], u.following),
 403       where: u.id != ^id
 404     )
 405   end
 406
 407   def get_followers(user) do
 408     q = get_followers_query(user)
 409
 410     {:ok, Repo.all(q)}
 411   end
 412
 413   def get_friends_query(%User{id: id, following: following}) do
 414     from(
 415       u in User,
 416       where: u.follower_address in ^following,
 417       where: u.id != ^id
 418     )
 419   end
 420
 421   def get_friends(user) do
 422     q = get_friends_query(user)
 423
 424     {:ok, Repo.all(q)}
 425   end
 426
 427   def get_follow_requests_query(%User{} = user) do
 428     from(
 429       a in Activity,
 430       where:
 431         fragment(
 432           "? ->> 'type' = 'Follow'",
 433           a.data
 434         ),
 435       where:
 436         fragment(
 437           "? ->> 'state' = 'pending'",
 438           a.data
 439         ),
 440       where:
 441         fragment(
 442           "? @> ?",
 443           a.data,
 444           ^%{"object" => user.ap_id}
 445         )
 446     )
 447   end
 448
 449   def get_follow_requests(%User{} = user) do
 450     q = get_follow_requests_query(user)
 451     reqs = Repo.all(q)
 452
 453     users =
 454       Enum.map(reqs, fn req -> req.actor end)
 455       |> Enum.uniq()
 456       |> Enum.map(fn ap_id -> get_by_ap_id(ap_id) end)
 457       |> Enum.filter(fn u -> !following?(u, user) end)
 458
 459     {:ok, users}
 460   end
 461
 462   def increase_note_count(%User{} = user) do
 463     info_cng = User.Info.add_to_note_count(user.info, 1)
 464
 465     cng =
 466       change(user)
 467       |> put_embed(:info, info_cng)
 468
 469     update_and_set_cache(cng)
 470   end
 471
 472   def decrease_note_count(%User{} = user) do
 473     info_cng = User.Info.add_to_note_count(user.info, -1)
 474
 475     cng =
 476       change(user)
 477       |> put_embed(:info, info_cng)
 478
 479     update_and_set_cache(cng)
 480   end
 481
 482   def update_note_count(%User{} = user) do
 483     note_count_query =
 484       from(
 485         a in Object,
 486         where: fragment("?->>'actor' = ? and ?->>'type' = 'Note'", a.data, ^user.ap_id, a.data),
 487         select: count(a.id)
 488       )
 489
 490     note_count = Repo.one(note_count_query)
 491
 492     info_cng = User.Info.set_note_count(user.info, note_count)
 493
 494     cng =
 495       change(user)
 496       |> put_embed(:info, info_cng)
 497
 498     update_and_set_cache(cng)
 499   end
 500
 501   def update_follower_count(%User{} = user) do
 502     follower_count_query =
 503       from(
 504         u in User,
 505         where: ^user.follower_address in u.following,
 506         where: u.id != ^user.id,
 507         select: count(u.id)
 508       )
 509
 510     follower_count = Repo.one(follower_count_query)
 511
 512     info_cng =
 513       user.info
 514       |> User.Info.set_follower_count(follower_count)
 515
 516     cng =
 517       change(user)
 518       |> put_embed(:info, info_cng)
 519
 520     update_and_set_cache(cng)
 521   end
 522
 523   def get_users_from_set_query(ap_ids, false) do
 524     from(
 525       u in User,
 526       where: u.ap_id in ^ap_ids
 527     )
 528   end
 529
 530   def get_users_from_set_query(ap_ids, true) do
 531     query = get_users_from_set_query(ap_ids, false)
 532
 533     from(
 534       u in query,
 535       where: u.local == true
 536     )
 537   end
 538
 539   def get_users_from_set(ap_ids, local_only \\ true) do
 540     get_users_from_set_query(ap_ids, local_only)
 541     |> Repo.all()
 542   end
 543
 544   def get_recipients_from_activity(%Activity{recipients: to}) do
 545     query =
 546       from(
 547         u in User,
 548         where: u.ap_id in ^to,
 549         or_where: fragment("? && ?", u.following, ^to)
 550       )
 551
 552     query = from(u in query, where: u.local == true)
 553
 554     Repo.all(query)
 555   end
 556
 557   def search(query, resolve \\ false) do
 558     # strip the beginning @ off if there is a query
 559     query = String.trim_leading(query, "@")
 560
 561     if resolve do
 562       User.get_or_fetch_by_nickname(query)
 563     end
 564
 565     inner =
 566       from(
 567         u in User,
 568         select_merge: %{
 569           search_distance:
 570             fragment(
 571               "? <-> (? || ?)",
 572               ^query,
 573               u.nickname,
 574               u.name
 575             )
 576         },
 577         where: not is_nil(u.nickname)
 578       )
 579
 580     q =
 581       from(
 582         s in subquery(inner),
 583         order_by: s.search_distance,
 584         limit: 20
 585       )
 586
 587     Repo.all(q)
 588   end
 589
 590   def block(blocker, %User{ap_id: ap_id} = blocked) do
 591     # sever any follow relationships to prevent leaks per activitypub (Pleroma issue #213)
 592     blocker =
 593       if following?(blocker, blocked) do
 594         {:ok, blocker, _} = unfollow(blocker, blocked)
 595         blocker
 596       else
 597         blocker
 598       end
 599
 600     if following?(blocked, blocker) do
 601       unfollow(blocked, blocker)
 602     end
 603
 604     info_cng =
 605       blocker.info
 606       |> User.Info.add_to_block(ap_id)
 607
 608     cng =
 609       change(blocker)
 610       |> put_embed(:info, info_cng)
 611
 612     update_and_set_cache(cng)
 613   end
 614
 615   # helper to handle the block given only an actor's AP id
 616   def block(blocker, %{ap_id: ap_id}) do
 617     block(blocker, User.get_by_ap_id(ap_id))
 618   end
 619
 620   def unblock(blocker, %{ap_id: ap_id}) do
 621     info_cng =
 622       blocker.info
 623       |> User.Info.remove_from_block(ap_id)
 624
 625     cng =
 626       change(blocker)
 627       |> put_embed(:info, info_cng)
 628
 629     update_and_set_cache(cng)
 630   end
 631
 632   def blocks?(user, %{ap_id: ap_id}) do
 633     blocks = user.info.blocks
 634     domain_blocks = user.info.domain_blocks
 635     %{host: host} = URI.parse(ap_id)
 636
 637     Enum.member?(blocks, ap_id) ||
 638       Enum.any?(domain_blocks, fn domain ->
 639         host == domain
 640       end)
 641   end
 642
 643   def block_domain(user, domain) do
 644     info_cng =
 645       user.info
 646       |> User.Info.add_to_domain_block(domain)
 647
 648     cng =
 649       change(user)
 650       |> put_embed(:info, info_cng)
 651
 652     update_and_set_cache(cng)
 653   end
 654
 655   def unblock_domain(user, domain) do
 656     info_cng =
 657       user.info
 658       |> User.Info.remove_from_domain_block(domain)
 659
 660     cng =
 661       change(user)
 662       |> put_embed(:info, info_cng)
 663
 664     update_and_set_cache(cng)
 665   end
 666
 667   def local_user_query() do
 668     from(
 669       u in User,
 670       where: u.local == true,
 671       where: not is_nil(u.nickname)
 672     )
 673   end
 674
 675   def moderator_user_query() do
 676     from(
 677       u in User,
 678       where: u.local == true,
 679       where: fragment("?->'is_moderator' @> 'true'", u.info)
 680     )
 681   end
 682
 683   def deactivate(%User{} = user, status \\ true) do
 684     info_cng = User.Info.set_activation_status(user.info, status)
 685
 686     cng =
 687       change(user)
 688       |> put_embed(:info, info_cng)
 689
 690     update_and_set_cache(cng)
 691   end
 692
 693   def delete(%User{} = user) do
 694     {:ok, user} = User.deactivate(user)
 695
 696     # Remove all relationships
 697     {:ok, followers} = User.get_followers(user)
 698
 699     followers
 700     |> Enum.each(fn follower -> User.unfollow(follower, user) end)
 701
 702     {:ok, friends} = User.get_friends(user)
 703
 704     friends
 705     |> Enum.each(fn followed -> User.unfollow(user, followed) end)
 706
 707     query = from(a in Activity, where: a.actor == ^user.ap_id)
 708
 709     Repo.all(query)
 710     |> Enum.each(fn activity ->
 711       case activity.data["type"] do
 712         "Create" ->
 713           ActivityPub.delete(Object.normalize(activity.data["object"]))
 714
 715         # TODO: Do something with likes, follows, repeats.
 716         _ ->
 717           "Doing nothing"
 718       end
 719     end)
 720
 721     {:ok, user}
 722   end
 723
 724   def html_filter_policy(%User{info: %{no_rich_text: true}}) do
 725     Pleroma.HTML.Scrubber.TwitterText
 726   end
 727
 728   def html_filter_policy(_), do: nil
 729
 730   def get_or_fetch_by_ap_id(ap_id) do
 731     user = get_by_ap_id(ap_id)
 732
 733     if !is_nil(user) and !User.needs_update?(user) do
 734       user
 735     else
 736       ap_try = ActivityPub.make_user_from_ap_id(ap_id)
 737
 738       case ap_try do
 739         {:ok, user} ->
 740           user
 741
 742         _ ->
 743           case OStatus.make_user(ap_id) do
 744             {:ok, user} -> user
 745             _ -> {:error, "Could not fetch by AP id"}
 746           end
 747       end
 748     end
 749   end
 750
 751   def get_or_create_instance_user do
 752     relay_uri = "#{Pleroma.Web.Endpoint.url()}/relay"
 753
 754     if user = get_by_ap_id(relay_uri) do
 755       user
 756     else
 757       changes =
 758         %User{info: %User.Info{}}
 759         |> cast(%{}, [:ap_id, :nickname, :local])
 760         |> put_change(:ap_id, relay_uri)
 761         |> put_change(:nickname, nil)
 762         |> put_change(:local, true)
 763         |> put_change(:follower_address, relay_uri <> "/followers")
 764
 765       {:ok, user} = Repo.insert(changes)
 766       user
 767     end
 768   end
 769
 770   # AP style
 771   def public_key_from_info(%{
 772         source_data: %{"publicKey" => %{"publicKeyPem" => public_key_pem}}
 773       }) do
 774     key =
 775       public_key_pem
 776       |> :public_key.pem_decode()
 777       |> hd()
 778       |> :public_key.pem_entry_decode()
 779
 780     {:ok, key}
 781   end
 782
 783   # OStatus Magic Key
 784   def public_key_from_info(%{magic_key: magic_key}) do
 785     {:ok, Pleroma.Web.Salmon.decode_key(magic_key)}
 786   end
 787
 788   def get_public_key_for_ap_id(ap_id) do
 789     with %User{} = user <- get_or_fetch_by_ap_id(ap_id),
 790          {:ok, public_key} <- public_key_from_info(user.info) do
 791       {:ok, public_key}
 792     else
 793       _ -> :error
 794     end
 795   end
 796
 797   defp blank?(""), do: nil
 798   defp blank?(n), do: n
 799
 800   def insert_or_update_user(data) do
 801     data =
 802       data
 803       |> Map.put(:name, blank?(data[:name]) || data[:nickname])
 804
 805     cs = User.remote_user_creation(data)
 806
 807     Repo.insert(cs, on_conflict: :replace_all, conflict_target: :nickname)
 808   end
 809
 810   def ap_enabled?(%User{local: true}), do: true
 811   def ap_enabled?(%User{info: info}), do: info.ap_enabled
 812   def ap_enabled?(_), do: false
 813
 814   @doc "Gets or fetch a user by uri or nickname."
 815   @spec get_or_fetch(String.t()) :: User.t()
 816   def get_or_fetch("http" <> _host = uri), do: get_or_fetch_by_ap_id(uri)
 817   def get_or_fetch(nickname), do: get_or_fetch_by_nickname(nickname)
 818
 819   # wait a period of time and return newest version of the User structs
 820   # this is because we have synchronous follow APIs and need to simulate them
 821   # with an async handshake
 822   def wait_and_refresh(_, %User{local: true} = a, %User{local: true} = b) do
 823     with %User{} = a <- Repo.get(User, a.id),
 824          %User{} = b <- Repo.get(User, b.id) do
 825       {:ok, a, b}
 826     else
 827       _e ->
 828         :error
 829     end
 830   end
 831
 832   def wait_and_refresh(timeout, %User{} = a, %User{} = b) do
 833     with :ok <- :timer.sleep(timeout),
 834          %User{} = a <- Repo.get(User, a.id),
 835          %User{} = b <- Repo.get(User, b.id) do
 836       {:ok, a, b}
 837     else
 838       _e ->
 839         :error
 840     end
 841   end
 842
 843   def parse_bio(bio, user \\ %User{info: %{source_data: %{}}})
 844   def parse_bio(nil, _user), do: ""
 845   def parse_bio(bio, _user) when bio == "", do: bio
 846
 847   def parse_bio(bio, user) do
 848     mentions = Formatter.parse_mentions(bio)
 849     tags = Formatter.parse_tags(bio)
 850
 851     emoji =
 852       (user.info.source_data["tag"] || [])
 853       |> Enum.filter(fn %{"type" => t} -> t == "Emoji" end)
 854       |> Enum.map(fn %{"icon" => %{"url" => url}, "name" => name} ->
 855         {String.trim(name, ":"), url}
 856       end)
 857
 858     bio
 859     |> CommonUtils.format_input(mentions, tags, "text/plain")
 860     |> Formatter.emojify(emoji)
 861   end
 862
 863   def tag(user_identifiers, tags) when is_list(user_identifiers) do
 864     Repo.transaction(fn ->
 865       for user_identifier <- user_identifiers, do: tag(user_identifier, tags)
 866     end)
 867   end
 868
 869   def tag(nickname, tags) when is_binary(nickname),
 870     do: tag(User.get_by_nickname(nickname), tags)
 871
 872   def tag(%User{} = user, tags),
 873     do: update_tags(user, Enum.uniq((user.tags || []) ++ normalize_tags(tags)))
 874
 875   def untag(user_identifiers, tags) when is_list(user_identifiers) do
 876     Repo.transaction(fn ->
 877       for user_identifier <- user_identifiers, do: untag(user_identifier, tags)
 878     end)
 879   end
 880
 881   def untag(nickname, tags) when is_binary(nickname),
 882     do: untag(User.get_by_nickname(nickname), tags)
 883
 884   def untag(%User{} = user, tags),
 885     do: update_tags(user, (user.tags || []) -- normalize_tags(tags))
 886
 887   defp update_tags(%User{} = user, new_tags) do
 888     {:ok, updated_user} =
 889       user
 890       |> change(%{tags: new_tags})
 891       |> Repo.update()
 892
 893     updated_user
 894   end
 895
 896   defp normalize_tags(tags) do
 897     [tags]
 898     |> List.flatten()
 899     |> Enum.map(&String.downcase(&1))
 900   end
 901
 902   defp local_nickname_regex() do
 903     if Pleroma.Config.get([:instance, :extended_nickname_format]) do
 904       @extended_local_nickname_regex
 905     else
 906       @strict_local_nickname_regex
 907     end
 908   end
 909 end