git.squeep.com Git - akkoma/blob - lib/pleroma/user.ex

   1 defmodule Pleroma.User do
   2   use Ecto.Schema
   3
   4   import Ecto.{Changeset, Query}
   5   alias Pleroma.{Repo, User, Object, Web, Activity, Notification}
   6   alias Comeonin.Pbkdf2
   7   alias Pleroma.Formatter
   8   alias Pleroma.Web.CommonAPI.Utils, as: CommonUtils
   9   alias Pleroma.Web.{OStatus, Websub, OAuth}
  10   alias Pleroma.Web.ActivityPub.{Utils, ActivityPub}
  11
  12   @type t :: %__MODULE__{}
  13
  14   @email_regex ~r/^[a-zA-Z0-9.!#$%&'*+\/=?^_`{|}~-]+@[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?(?:\.[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?)*$/
  15
  16   @strict_local_nickname_regex ~r/^[a-zA-Z\d]+$/
  17   @extended_local_nickname_regex ~r/^[a-zA-Z\d_-]+$/
  18
  19   schema "users" do
  20     field(:bio, :string)
  21     field(:email, :string)
  22     field(:name, :string)
  23     field(:nickname, :string)
  24     field(:password_hash, :string)
  25     field(:password, :string, virtual: true)
  26     field(:password_confirmation, :string, virtual: true)
  27     field(:following, {:array, :string}, default: [])
  28     field(:ap_id, :string)
  29     field(:avatar, :map)
  30     field(:local, :boolean, default: true)
  31     field(:follower_address, :string)
  32     field(:search_distance, :float, virtual: true)
  33     field(:tags, {:array, :string}, default: [])
  34     field(:last_refreshed_at, :naive_datetime)
  35     has_many(:notifications, Notification)
  36     embeds_one(:info, Pleroma.User.Info)
  37
  38     timestamps()
  39   end
  40
  41   def auth_active?(user), do: user.info && !user.info.confirmation_pending
  42
  43   def avatar_url(user) do
  44     case user.avatar do
  45       %{"url" => [%{"href" => href} | _]} -> href
  46       _ -> "#{Web.base_url()}/images/avi.png"
  47     end
  48   end
  49
  50   def banner_url(user) do
  51     case user.info.banner do
  52       %{"url" => [%{"href" => href} | _]} -> href
  53       _ -> "#{Web.base_url()}/images/banner.png"
  54     end
  55   end
  56
  57   def profile_url(%User{info: %{source_data: %{"url" => url}}}), do: url
  58   def profile_url(%User{ap_id: ap_id}), do: ap_id
  59   def profile_url(_), do: nil
  60
  61   def ap_id(%User{nickname: nickname}) do
  62     "#{Web.base_url()}/users/#{nickname}"
  63   end
  64
  65   def ap_followers(%User{} = user) do
  66     "#{ap_id(user)}/followers"
  67   end
  68
  69   def follow_changeset(struct, params \\ %{}) do
  70     struct
  71     |> cast(params, [:following])
  72     |> validate_required([:following])
  73   end
  74
  75   def user_info(%User{} = user) do
  76     oneself = if user.local, do: 1, else: 0
  77
  78     %{
  79       following_count: length(user.following) - oneself,
  80       note_count: user.info.note_count,
  81       follower_count: user.info.follower_count,
  82       locked: user.info.locked,
  83       default_scope: user.info.default_scope
  84     }
  85   end
  86
  87   def remote_user_creation(params) do
  88     params =
  89       params
  90       |> Map.put(:info, params[:info] || %{})
  91
  92     info_cng = User.Info.remote_user_creation(%User.Info{}, params[:info])
  93
  94     changes =
  95       %User{}
  96       |> cast(params, [:bio, :name, :ap_id, :nickname, :avatar])
  97       |> validate_required([:name, :ap_id])
  98       |> unique_constraint(:nickname)
  99       |> validate_format(:nickname, @email_regex)
 100       |> validate_length(:bio, max: 5000)
 101       |> validate_length(:name, max: 100)
 102       |> put_change(:local, false)
 103       |> put_embed(:info, info_cng)
 104
 105     if changes.valid? do
 106       case info_cng.changes[:source_data] do
 107         %{"followers" => followers} ->
 108           changes
 109           |> put_change(:follower_address, followers)
 110
 111         _ ->
 112           followers = User.ap_followers(%User{nickname: changes.changes[:nickname]})
 113
 114           changes
 115           |> put_change(:follower_address, followers)
 116       end
 117     else
 118       changes
 119     end
 120   end
 121
 122   def update_changeset(struct, params \\ %{}) do
 123     struct
 124     |> cast(params, [:bio, :name, :avatar])
 125     |> unique_constraint(:nickname)
 126     |> validate_format(:nickname, local_nickname_regex())
 127     |> validate_length(:bio, max: 5000)
 128     |> validate_length(:name, min: 1, max: 100)
 129   end
 130
 131   def upgrade_changeset(struct, params \\ %{}) do
 132     params =
 133       params
 134       |> Map.put(:last_refreshed_at, NaiveDateTime.utc_now())
 135
 136     info_cng =
 137       struct.info
 138       |> User.Info.user_upgrade(params[:info])
 139
 140     struct
 141     |> cast(params, [:bio, :name, :follower_address, :avatar, :last_refreshed_at])
 142     |> unique_constraint(:nickname)
 143     |> validate_format(:nickname, local_nickname_regex())
 144     |> validate_length(:bio, max: 5000)
 145     |> validate_length(:name, max: 100)
 146     |> put_embed(:info, info_cng)
 147   end
 148
 149   def password_update_changeset(struct, params) do
 150     changeset =
 151       struct
 152       |> cast(params, [:password, :password_confirmation])
 153       |> validate_required([:password, :password_confirmation])
 154       |> validate_confirmation(:password)
 155
 156     OAuth.Token.delete_user_tokens(struct)
 157     OAuth.Authorization.delete_user_authorizations(struct)
 158
 159     if changeset.valid? do
 160       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 161
 162       changeset
 163       |> put_change(:password_hash, hashed)
 164     else
 165       changeset
 166     end
 167   end
 168
 169   def reset_password(user, data) do
 170     update_and_set_cache(password_update_changeset(user, data))
 171   end
 172
 173   def register_changeset(struct, params \\ %{}) do
 174     changeset =
 175       struct
 176       |> cast(params, [:bio, :email, :name, :nickname, :password, :password_confirmation])
 177       |> validate_required([:email, :name, :nickname, :password, :password_confirmation])
 178       |> validate_confirmation(:password)
 179       |> unique_constraint(:email)
 180       |> unique_constraint(:nickname)
 181       |> validate_format(:nickname, local_nickname_regex())
 182       |> validate_format(:email, @email_regex)
 183       |> validate_length(:bio, max: 1000)
 184       |> validate_length(:name, min: 1, max: 100)
 185       |> put_change(:info, %Pleroma.User.Info{})
 186
 187     if changeset.valid? do
 188       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 189       ap_id = User.ap_id(%User{nickname: changeset.changes[:nickname]})
 190       followers = User.ap_followers(%User{nickname: changeset.changes[:nickname]})
 191
 192       changeset
 193       |> put_change(:password_hash, hashed)
 194       |> put_change(:ap_id, ap_id)
 195       |> put_change(:following, [followers])
 196       |> put_change(:follower_address, followers)
 197     else
 198       changeset
 199     end
 200   end
 201
 202   def needs_update?(%User{local: true}), do: false
 203
 204   def needs_update?(%User{local: false, last_refreshed_at: nil}), do: true
 205
 206   def needs_update?(%User{local: false} = user) do
 207     NaiveDateTime.diff(NaiveDateTime.utc_now(), user.last_refreshed_at) >= 86400
 208   end
 209
 210   def needs_update?(_), do: true
 211
 212   def maybe_direct_follow(%User{} = follower, %User{local: true, info: %{locked: true}}) do
 213     {:ok, follower}
 214   end
 215
 216   def maybe_direct_follow(%User{} = follower, %User{local: true} = followed) do
 217     follow(follower, followed)
 218   end
 219
 220   def maybe_direct_follow(%User{} = follower, %User{} = followed) do
 221     if not User.ap_enabled?(followed) do
 222       follow(follower, followed)
 223     else
 224       {:ok, follower}
 225     end
 226   end
 227
 228   def maybe_follow(%User{} = follower, %User{info: _info} = followed) do
 229     if not following?(follower, followed) do
 230       follow(follower, followed)
 231     else
 232       {:ok, follower}
 233     end
 234   end
 235
 236   def follow(%User{} = follower, %User{info: info} = followed) do
 237     user_config = Application.get_env(:pleroma, :user)
 238     deny_follow_blocked = Keyword.get(user_config, :deny_follow_blocked)
 239
 240     ap_followers = followed.follower_address
 241
 242     cond do
 243       following?(follower, followed) or info.deactivated ->
 244         {:error, "Could not follow user: #{followed.nickname} is already on your list."}
 245
 246       deny_follow_blocked and blocks?(followed, follower) ->
 247         {:error, "Could not follow user: #{followed.nickname} blocked you."}
 248
 249       true ->
 250         if !followed.local && follower.local && !ap_enabled?(followed) do
 251           Websub.subscribe(follower, followed)
 252         end
 253
 254         following =
 255           [ap_followers | follower.following]
 256           |> Enum.uniq()
 257
 258         follower =
 259           follower
 260           |> follow_changeset(%{following: following})
 261           |> update_and_set_cache
 262
 263         {:ok, _} = update_follower_count(followed)
 264
 265         follower
 266     end
 267   end
 268
 269   def unfollow(%User{} = follower, %User{} = followed) do
 270     ap_followers = followed.follower_address
 271
 272     if following?(follower, followed) and follower.ap_id != followed.ap_id do
 273       following =
 274         follower.following
 275         |> List.delete(ap_followers)
 276
 277       {:ok, follower} =
 278         follower
 279         |> follow_changeset(%{following: following})
 280         |> update_and_set_cache
 281
 282       {:ok, followed} = update_follower_count(followed)
 283
 284       {:ok, follower, Utils.fetch_latest_follow(follower, followed)}
 285     else
 286       {:error, "Not subscribed!"}
 287     end
 288   end
 289
 290   @spec following?(User.t(), User.t()) :: boolean
 291   def following?(%User{} = follower, %User{} = followed) do
 292     Enum.member?(follower.following, followed.follower_address)
 293   end
 294
 295   def locked?(%User{} = user) do
 296     user.info.locked || false
 297   end
 298
 299   def get_by_ap_id(ap_id) do
 300     Repo.get_by(User, ap_id: ap_id)
 301   end
 302
 303   def update_and_set_cache(changeset) do
 304     with {:ok, user} <- Repo.update(changeset) do
 305       Cachex.put(:user_cache, "ap_id:#{user.ap_id}", user)
 306       Cachex.put(:user_cache, "nickname:#{user.nickname}", user)
 307       Cachex.put(:user_cache, "user_info:#{user.id}", user_info(user))
 308       {:ok, user}
 309     else
 310       e -> e
 311     end
 312   end
 313
 314   def invalidate_cache(user) do
 315     Cachex.del(:user_cache, "ap_id:#{user.ap_id}")
 316     Cachex.del(:user_cache, "nickname:#{user.nickname}")
 317     Cachex.del(:user_cache, "user_info:#{user.id}")
 318   end
 319
 320   def get_cached_by_ap_id(ap_id) do
 321     key = "ap_id:#{ap_id}"
 322     Cachex.fetch!(:user_cache, key, fn _ -> get_by_ap_id(ap_id) end)
 323   end
 324
 325   def get_cached_by_nickname(nickname) do
 326     key = "nickname:#{nickname}"
 327     Cachex.fetch!(:user_cache, key, fn _ -> get_or_fetch_by_nickname(nickname) end)
 328   end
 329
 330   def get_by_nickname(nickname) do
 331     Repo.get_by(User, nickname: nickname)
 332   end
 333
 334   def get_by_nickname_or_email(nickname_or_email) do
 335     case user = Repo.get_by(User, nickname: nickname_or_email) do
 336       %User{} -> user
 337       nil -> Repo.get_by(User, email: nickname_or_email)
 338     end
 339   end
 340
 341   def get_cached_user_info(user) do
 342     key = "user_info:#{user.id}"
 343     Cachex.fetch!(:user_cache, key, fn _ -> user_info(user) end)
 344   end
 345
 346   def fetch_by_nickname(nickname) do
 347     ap_try = ActivityPub.make_user_from_nickname(nickname)
 348
 349     case ap_try do
 350       {:ok, user} -> {:ok, user}
 351       _ -> OStatus.make_user(nickname)
 352     end
 353   end
 354
 355   def get_or_fetch_by_nickname(nickname) do
 356     with %User{} = user <- get_by_nickname(nickname) do
 357       user
 358     else
 359       _e ->
 360         with [_nick, _domain] <- String.split(nickname, "@"),
 361              {:ok, user} <- fetch_by_nickname(nickname) do
 362           user
 363         else
 364           _e -> nil
 365         end
 366     end
 367   end
 368
 369   def get_by_confirmation_token(token) do
 370     Repo.one(from(u in User, where: fragment("? ->> 'confirmation_token' = ?", u.info, ^token)))
 371   end
 372
 373   def get_followers_query(%User{id: id, follower_address: follower_address}) do
 374     from(
 375       u in User,
 376       where: fragment("? <@ ?", ^[follower_address], u.following),
 377       where: u.id != ^id
 378     )
 379   end
 380
 381   def get_followers(user) do
 382     q = get_followers_query(user)
 383
 384     {:ok, Repo.all(q)}
 385   end
 386
 387   def get_friends_query(%User{id: id, following: following}) do
 388     from(
 389       u in User,
 390       where: u.follower_address in ^following,
 391       where: u.id != ^id
 392     )
 393   end
 394
 395   def get_friends(user) do
 396     q = get_friends_query(user)
 397
 398     {:ok, Repo.all(q)}
 399   end
 400
 401   def get_follow_requests_query(%User{} = user) do
 402     from(
 403       a in Activity,
 404       where:
 405         fragment(
 406           "? ->> 'type' = 'Follow'",
 407           a.data
 408         ),
 409       where:
 410         fragment(
 411           "? ->> 'state' = 'pending'",
 412           a.data
 413         ),
 414       where:
 415         fragment(
 416           "? @> ?",
 417           a.data,
 418           ^%{"object" => user.ap_id}
 419         )
 420     )
 421   end
 422
 423   def get_follow_requests(%User{} = user) do
 424     q = get_follow_requests_query(user)
 425     reqs = Repo.all(q)
 426
 427     users =
 428       Enum.map(reqs, fn req -> req.actor end)
 429       |> Enum.uniq()
 430       |> Enum.map(fn ap_id -> get_by_ap_id(ap_id) end)
 431       |> Enum.filter(fn u -> !following?(u, user) end)
 432
 433     {:ok, users}
 434   end
 435
 436   def increase_note_count(%User{} = user) do
 437     info_cng = User.Info.add_to_note_count(user.info, 1)
 438
 439     cng =
 440       change(user)
 441       |> put_embed(:info, info_cng)
 442
 443     update_and_set_cache(cng)
 444   end
 445
 446   def decrease_note_count(%User{} = user) do
 447     info_cng = User.Info.add_to_note_count(user.info, -1)
 448
 449     cng =
 450       change(user)
 451       |> put_embed(:info, info_cng)
 452
 453     update_and_set_cache(cng)
 454   end
 455
 456   def update_note_count(%User{} = user) do
 457     note_count_query =
 458       from(
 459         a in Object,
 460         where: fragment("?->>'actor' = ? and ?->>'type' = 'Note'", a.data, ^user.ap_id, a.data),
 461         select: count(a.id)
 462       )
 463
 464     note_count = Repo.one(note_count_query)
 465
 466     info_cng = User.Info.set_note_count(user.info, note_count)
 467
 468     cng =
 469       change(user)
 470       |> put_embed(:info, info_cng)
 471
 472     update_and_set_cache(cng)
 473   end
 474
 475   def update_follower_count(%User{} = user) do
 476     follower_count_query =
 477       from(
 478         u in User,
 479         where: ^user.follower_address in u.following,
 480         where: u.id != ^user.id,
 481         select: count(u.id)
 482       )
 483
 484     follower_count = Repo.one(follower_count_query)
 485
 486     info_cng =
 487       user.info
 488       |> User.Info.set_follower_count(follower_count)
 489
 490     cng =
 491       change(user)
 492       |> put_embed(:info, info_cng)
 493
 494     update_and_set_cache(cng)
 495   end
 496
 497   def get_users_from_set_query(ap_ids, false) do
 498     from(
 499       u in User,
 500       where: u.ap_id in ^ap_ids
 501     )
 502   end
 503
 504   def get_users_from_set_query(ap_ids, true) do
 505     query = get_users_from_set_query(ap_ids, false)
 506
 507     from(
 508       u in query,
 509       where: u.local == true
 510     )
 511   end
 512
 513   def get_users_from_set(ap_ids, local_only \\ true) do
 514     get_users_from_set_query(ap_ids, local_only)
 515     |> Repo.all()
 516   end
 517
 518   def get_recipients_from_activity(%Activity{recipients: to}) do
 519     query =
 520       from(
 521         u in User,
 522         where: u.ap_id in ^to,
 523         or_where: fragment("? && ?", u.following, ^to)
 524       )
 525
 526     query = from(u in query, where: u.local == true)
 527
 528     Repo.all(query)
 529   end
 530
 531   def search(query, resolve \\ false) do
 532     # strip the beginning @ off if there is a query
 533     query = String.trim_leading(query, "@")
 534
 535     if resolve do
 536       User.get_or_fetch_by_nickname(query)
 537     end
 538
 539     inner =
 540       from(
 541         u in User,
 542         select_merge: %{
 543           search_distance:
 544             fragment(
 545               "? <-> (? || ?)",
 546               ^query,
 547               u.nickname,
 548               u.name
 549             )
 550         },
 551         where: not is_nil(u.nickname)
 552       )
 553
 554     q =
 555       from(
 556         s in subquery(inner),
 557         order_by: s.search_distance,
 558         limit: 20
 559       )
 560
 561     Repo.all(q)
 562   end
 563
 564   def block(blocker, %User{ap_id: ap_id} = blocked) do
 565     # sever any follow relationships to prevent leaks per activitypub (Pleroma issue #213)
 566     blocker =
 567       if following?(blocker, blocked) do
 568         {:ok, blocker, _} = unfollow(blocker, blocked)
 569         blocker
 570       else
 571         blocker
 572       end
 573
 574     if following?(blocked, blocker) do
 575       unfollow(blocked, blocker)
 576     end
 577
 578     info_cng =
 579       blocker.info
 580       |> User.Info.add_to_block(ap_id)
 581
 582     cng =
 583       change(blocker)
 584       |> put_embed(:info, info_cng)
 585
 586     update_and_set_cache(cng)
 587   end
 588
 589   # helper to handle the block given only an actor's AP id
 590   def block(blocker, %{ap_id: ap_id}) do
 591     block(blocker, User.get_by_ap_id(ap_id))
 592   end
 593
 594   def unblock(blocker, %{ap_id: ap_id}) do
 595     info_cng =
 596       blocker.info
 597       |> User.Info.remove_from_block(ap_id)
 598
 599     cng =
 600       change(blocker)
 601       |> put_embed(:info, info_cng)
 602
 603     update_and_set_cache(cng)
 604   end
 605
 606   def blocks?(user, %{ap_id: ap_id}) do
 607     blocks = user.info.blocks
 608     domain_blocks = user.info.domain_blocks
 609     %{host: host} = URI.parse(ap_id)
 610
 611     Enum.member?(blocks, ap_id) ||
 612       Enum.any?(domain_blocks, fn domain ->
 613         host == domain
 614       end)
 615   end
 616
 617   def block_domain(user, domain) do
 618     info_cng =
 619       user.info
 620       |> User.Info.add_to_domain_block(domain)
 621
 622     cng =
 623       change(user)
 624       |> put_embed(:info, info_cng)
 625
 626     update_and_set_cache(cng)
 627   end
 628
 629   def unblock_domain(user, domain) do
 630     info_cng =
 631       user.info
 632       |> User.Info.remove_from_domain_block(domain)
 633
 634     cng =
 635       change(user)
 636       |> put_embed(:info, info_cng)
 637
 638     update_and_set_cache(cng)
 639   end
 640
 641   def local_user_query() do
 642     from(
 643       u in User,
 644       where: u.local == true,
 645       where: not is_nil(u.nickname)
 646     )
 647   end
 648
 649   def moderator_user_query() do
 650     from(
 651       u in User,
 652       where: u.local == true,
 653       where: fragment("?->'is_moderator' @> 'true'", u.info)
 654     )
 655   end
 656
 657   def deactivate(%User{} = user, status \\ true) do
 658     info_cng = User.Info.set_activation_status(user.info, status)
 659
 660     cng =
 661       change(user)
 662       |> put_embed(:info, info_cng)
 663
 664     update_and_set_cache(cng)
 665   end
 666
 667   def delete(%User{} = user) do
 668     {:ok, user} = User.deactivate(user)
 669
 670     # Remove all relationships
 671     {:ok, followers} = User.get_followers(user)
 672
 673     followers
 674     |> Enum.each(fn follower -> User.unfollow(follower, user) end)
 675
 676     {:ok, friends} = User.get_friends(user)
 677
 678     friends
 679     |> Enum.each(fn followed -> User.unfollow(user, followed) end)
 680
 681     query = from(a in Activity, where: a.actor == ^user.ap_id)
 682
 683     Repo.all(query)
 684     |> Enum.each(fn activity ->
 685       case activity.data["type"] do
 686         "Create" ->
 687           ActivityPub.delete(Object.normalize(activity.data["object"]))
 688
 689         # TODO: Do something with likes, follows, repeats.
 690         _ ->
 691           "Doing nothing"
 692       end
 693     end)
 694
 695     {:ok, user}
 696   end
 697
 698   def html_filter_policy(%User{info: %{no_rich_text: true}}) do
 699     Pleroma.HTML.Scrubber.TwitterText
 700   end
 701
 702   def html_filter_policy(_), do: nil
 703
 704   def get_or_fetch_by_ap_id(ap_id) do
 705     user = get_by_ap_id(ap_id)
 706
 707     if !is_nil(user) and !User.needs_update?(user) do
 708       user
 709     else
 710       ap_try = ActivityPub.make_user_from_ap_id(ap_id)
 711
 712       case ap_try do
 713         {:ok, user} ->
 714           user
 715
 716         _ ->
 717           case OStatus.make_user(ap_id) do
 718             {:ok, user} -> user
 719             _ -> {:error, "Could not fetch by AP id"}
 720           end
 721       end
 722     end
 723   end
 724
 725   def get_or_create_instance_user do
 726     relay_uri = "#{Pleroma.Web.Endpoint.url()}/relay"
 727
 728     if user = get_by_ap_id(relay_uri) do
 729       user
 730     else
 731       changes =
 732         %User{info: %User.Info{}}
 733         |> cast(%{}, [:ap_id, :nickname, :local])
 734         |> put_change(:ap_id, relay_uri)
 735         |> put_change(:nickname, nil)
 736         |> put_change(:local, true)
 737         |> put_change(:follower_address, relay_uri <> "/followers")
 738
 739       {:ok, user} = Repo.insert(changes)
 740       user
 741     end
 742   end
 743
 744   # AP style
 745   def public_key_from_info(%{
 746         source_data: %{"publicKey" => %{"publicKeyPem" => public_key_pem}}
 747       }) do
 748     key =
 749       public_key_pem
 750       |> :public_key.pem_decode()
 751       |> hd()
 752       |> :public_key.pem_entry_decode()
 753
 754     {:ok, key}
 755   end
 756
 757   # OStatus Magic Key
 758   def public_key_from_info(%{magic_key: magic_key}) do
 759     {:ok, Pleroma.Web.Salmon.decode_key(magic_key)}
 760   end
 761
 762   def get_public_key_for_ap_id(ap_id) do
 763     with %User{} = user <- get_or_fetch_by_ap_id(ap_id),
 764          {:ok, public_key} <- public_key_from_info(user.info) do
 765       {:ok, public_key}
 766     else
 767       _ -> :error
 768     end
 769   end
 770
 771   defp blank?(""), do: nil
 772   defp blank?(n), do: n
 773
 774   def insert_or_update_user(data) do
 775     data =
 776       data
 777       |> Map.put(:name, blank?(data[:name]) || data[:nickname])
 778
 779     cs = User.remote_user_creation(data)
 780
 781     Repo.insert(cs, on_conflict: :replace_all, conflict_target: :nickname)
 782   end
 783
 784   def ap_enabled?(%User{local: true}), do: true
 785   def ap_enabled?(%User{info: info}), do: info.ap_enabled
 786   def ap_enabled?(_), do: false
 787
 788   @doc "Gets or fetch a user by uri or nickname."
 789   @spec get_or_fetch(String.t()) :: User.t()
 790   def get_or_fetch("http" <> _host = uri), do: get_or_fetch_by_ap_id(uri)
 791   def get_or_fetch(nickname), do: get_or_fetch_by_nickname(nickname)
 792
 793   # wait a period of time and return newest version of the User structs
 794   # this is because we have synchronous follow APIs and need to simulate them
 795   # with an async handshake
 796   def wait_and_refresh(_, %User{local: true} = a, %User{local: true} = b) do
 797     with %User{} = a <- Repo.get(User, a.id),
 798          %User{} = b <- Repo.get(User, b.id) do
 799       {:ok, a, b}
 800     else
 801       _e ->
 802         :error
 803     end
 804   end
 805
 806   def wait_and_refresh(timeout, %User{} = a, %User{} = b) do
 807     with :ok <- :timer.sleep(timeout),
 808          %User{} = a <- Repo.get(User, a.id),
 809          %User{} = b <- Repo.get(User, b.id) do
 810       {:ok, a, b}
 811     else
 812       _e ->
 813         :error
 814     end
 815   end
 816
 817   def parse_bio(bio, user \\ %User{info: %{source_data: %{}}})
 818   def parse_bio(nil, _user), do: ""
 819   def parse_bio(bio, _user) when bio == "", do: bio
 820
 821   def parse_bio(bio, user) do
 822     mentions = Formatter.parse_mentions(bio)
 823     tags = Formatter.parse_tags(bio)
 824
 825     emoji =
 826       (user.info.source_data["tag"] || [])
 827       |> Enum.filter(fn %{"type" => t} -> t == "Emoji" end)
 828       |> Enum.map(fn %{"icon" => %{"url" => url}, "name" => name} ->
 829         {String.trim(name, ":"), url}
 830       end)
 831
 832     bio
 833     |> CommonUtils.format_input(mentions, tags, "text/plain")
 834     |> Formatter.emojify(emoji)
 835   end
 836
 837   def tag(user_identifiers, tags) when is_list(user_identifiers) do
 838     Repo.transaction(fn ->
 839       for user_identifier <- user_identifiers, do: tag(user_identifier, tags)
 840     end)
 841   end
 842
 843   def tag(nickname, tags) when is_binary(nickname),
 844     do: tag(User.get_by_nickname(nickname), tags)
 845
 846   def tag(%User{} = user, tags),
 847     do: update_tags(user, Enum.uniq((user.tags || []) ++ normalize_tags(tags)))
 848
 849   def untag(user_identifiers, tags) when is_list(user_identifiers) do
 850     Repo.transaction(fn ->
 851       for user_identifier <- user_identifiers, do: untag(user_identifier, tags)
 852     end)
 853   end
 854
 855   def untag(nickname, tags) when is_binary(nickname),
 856     do: untag(User.get_by_nickname(nickname), tags)
 857
 858   def untag(%User{} = user, tags),
 859     do: update_tags(user, (user.tags || []) -- normalize_tags(tags))
 860
 861   defp update_tags(%User{} = user, new_tags) do
 862     {:ok, updated_user} =
 863       user
 864       |> change(%{tags: new_tags})
 865       |> Repo.update()
 866
 867     updated_user
 868   end
 869
 870   defp normalize_tags(tags) do
 871     [tags]
 872     |> List.flatten()
 873     |> Enum.map(&String.downcase(&1))
 874   end
 875
 876   defp local_nickname_regex() do
 877     if Pleroma.Config.get([:instance, :extended_nickname_format]) do
 878       @extended_local_nickname_regex
 879     else
 880       @strict_local_nickname_regex
 881     end
 882   end
 883 end