git.squeep.com Git - akkoma/blob - lib/pleroma/user.ex

   1 defmodule Pleroma.User do
   2   use Ecto.Schema
   3
   4   import Ecto.{Changeset, Query}
   5   alias Pleroma.{Repo, User, Object, Web, Activity, Notification}
   6   alias Comeonin.Pbkdf2
   7   alias Pleroma.Formatter
   8   alias Pleroma.Web.CommonAPI.Utils, as: CommonUtils
   9   alias Pleroma.Web.{OStatus, Websub, OAuth}
  10   alias Pleroma.Web.ActivityPub.{Utils, ActivityPub}
  11
  12   schema "users" do
  13     field(:bio, :string)
  14     field(:email, :string)
  15     field(:name, :string)
  16     field(:nickname, :string)
  17     field(:password_hash, :string)
  18     field(:password, :string, virtual: true)
  19     field(:password_confirmation, :string, virtual: true)
  20     field(:following, {:array, :string}, default: [])
  21     field(:ap_id, :string)
  22     field(:avatar, :map)
  23     field(:local, :boolean, default: true)
  24     field(:follower_address, :string)
  25     field(:search_distance, :float, virtual: true)
  26     field(:last_refreshed_at, :naive_datetime)
  27     has_many(:notifications, Notification)
  28     embeds_one(:info, Pleroma.User.Info)
  29
  30     timestamps()
  31   end
  32
  33   def avatar_url(user) do
  34     case user.avatar do
  35       %{"url" => [%{"href" => href} | _]} -> href
  36       _ -> "#{Web.base_url()}/images/avi.png"
  37     end
  38   end
  39
  40   def banner_url(user) do
  41     case user.info.banner do
  42       %{"url" => [%{"href" => href} | _]} -> href
  43       _ -> "#{Web.base_url()}/images/banner.png"
  44     end
  45   end
  46
  47   def profile_url(%User{info: %{source_data: %{"url" => url}}}), do: url
  48   def profile_url(%User{ap_id: ap_id}), do: ap_id
  49   def profile_url(_), do: nil
  50
  51   def ap_id(%User{nickname: nickname}) do
  52     "#{Web.base_url()}/users/#{nickname}"
  53   end
  54
  55   def ap_followers(%User{} = user) do
  56     "#{ap_id(user)}/followers"
  57   end
  58
  59   def follow_changeset(struct, params \\ %{}) do
  60     struct
  61     |> cast(params, [:following])
  62     |> validate_required([:following])
  63   end
  64
  65   def user_info(%User{} = user) do
  66     oneself = if user.local, do: 1, else: 0
  67
  68     %{
  69       following_count: length(user.following) - oneself,
  70       note_count: user.info.note_count,
  71       follower_count: user.info.follower_count,
  72       locked: user.info.locked,
  73       default_scope: user.info.default_scope
  74     }
  75   end
  76
  77   @email_regex ~r/^[a-zA-Z0-9.!#$%&'*+\/=?^_`{|}~-]+@[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?(?:\.[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?)*$/
  78   def remote_user_creation(params) do
  79     params =
  80       params
  81       |> Map.put(:info, params[:info] || %{})
  82
  83     info_cng = User.Info.remote_user_creation(%User.Info{}, params[:info])
  84
  85     changes =
  86       %User{}
  87       |> cast(params, [:bio, :name, :ap_id, :nickname, :avatar])
  88       |> validate_required([:name, :ap_id])
  89       |> unique_constraint(:nickname)
  90       |> validate_format(:nickname, @email_regex)
  91       |> validate_length(:bio, max: 5000)
  92       |> validate_length(:name, max: 100)
  93       |> put_change(:local, false)
  94       |> put_embed(:info, info_cng)
  95
  96     if changes.valid? do
  97       case info_cng.changes[:source_data] do
  98         %{"followers" => followers} ->
  99           changes
 100           |> put_change(:follower_address, followers)
 101
 102         _ ->
 103           followers = User.ap_followers(%User{nickname: changes.changes[:nickname]})
 104
 105           changes
 106           |> put_change(:follower_address, followers)
 107       end
 108     else
 109       changes
 110     end
 111   end
 112
 113   def update_changeset(struct, params \\ %{}) do
 114     struct
 115     |> cast(params, [:bio, :name, :avatar])
 116     |> unique_constraint(:nickname)
 117     |> validate_format(:nickname, ~r/^[a-zA-Z\d]+$/)
 118     |> validate_length(:bio, max: 5000)
 119     |> validate_length(:name, min: 1, max: 100)
 120   end
 121
 122   def upgrade_changeset(struct, params \\ %{}) do
 123     params =
 124       params
 125       |> Map.put(:last_refreshed_at, NaiveDateTime.utc_now())
 126
 127     info_cng =
 128       struct.info
 129       |> User.Info.user_upgrade(params[:info])
 130
 131     struct
 132     |> cast(params, [:bio, :name, :follower_address, :avatar, :last_refreshed_at])
 133     |> unique_constraint(:nickname)
 134     |> validate_format(:nickname, ~r/^[a-zA-Z\d]+$/)
 135     |> validate_length(:bio, max: 5000)
 136     |> validate_length(:name, max: 100)
 137     |> put_embed(:info, info_cng)
 138   end
 139
 140   def password_update_changeset(struct, params) do
 141     changeset =
 142       struct
 143       |> cast(params, [:password, :password_confirmation])
 144       |> validate_required([:password, :password_confirmation])
 145       |> validate_confirmation(:password)
 146
 147     OAuth.Token.delete_user_tokens(struct)
 148     OAuth.Authorization.delete_user_authorizations(struct)
 149
 150     if changeset.valid? do
 151       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 152
 153       changeset
 154       |> put_change(:password_hash, hashed)
 155     else
 156       changeset
 157     end
 158   end
 159
 160   def reset_password(user, data) do
 161     update_and_set_cache(password_update_changeset(user, data))
 162   end
 163
 164   def register_changeset(struct, params \\ %{}) do
 165     changeset =
 166       struct
 167       |> cast(params, [:bio, :email, :name, :nickname, :password, :password_confirmation])
 168       |> validate_required([:email, :name, :nickname, :password, :password_confirmation])
 169       |> validate_confirmation(:password)
 170       |> unique_constraint(:email)
 171       |> unique_constraint(:nickname)
 172       |> validate_format(:nickname, ~r/^[a-zA-Z\d]+$/)
 173       |> validate_format(:email, @email_regex)
 174       |> validate_length(:bio, max: 1000)
 175       |> validate_length(:name, min: 1, max: 100)
 176       |> put_change(:info, %Pleroma.User.Info{})
 177
 178     if changeset.valid? do
 179       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 180       ap_id = User.ap_id(%User{nickname: changeset.changes[:nickname]})
 181       followers = User.ap_followers(%User{nickname: changeset.changes[:nickname]})
 182
 183       changeset
 184       |> put_change(:password_hash, hashed)
 185       |> put_change(:ap_id, ap_id)
 186       |> put_change(:following, [followers])
 187       |> put_change(:follower_address, followers)
 188     else
 189       changeset
 190     end
 191   end
 192
 193   def needs_update?(%User{local: true}), do: false
 194
 195   def needs_update?(%User{local: false, last_refreshed_at: nil}), do: true
 196
 197   def needs_update?(%User{local: false} = user) do
 198     NaiveDateTime.diff(NaiveDateTime.utc_now(), user.last_refreshed_at) >= 86400
 199   end
 200
 201   def needs_update?(_), do: true
 202
 203   def maybe_direct_follow(%User{} = follower, %User{local: true, info: %{locked: true}}) do
 204     {:ok, follower}
 205   end
 206
 207   def maybe_direct_follow(%User{} = follower, %User{local: true} = followed) do
 208     follow(follower, followed)
 209   end
 210
 211   def maybe_direct_follow(%User{} = follower, %User{} = followed) do
 212     if !User.ap_enabled?(followed) do
 213       follow(follower, followed)
 214     else
 215       {:ok, follower}
 216     end
 217   end
 218
 219   def maybe_follow(%User{} = follower, %User{info: info} = followed) do
 220     if not following?(follower, followed) do
 221       follow(follower, followed)
 222     else
 223       {:ok, follower}
 224     end
 225   end
 226
 227   def follow(%User{} = follower, %User{info: info} = followed) do
 228     user_config = Application.get_env(:pleroma, :user)
 229     deny_follow_blocked = Keyword.get(user_config, :deny_follow_blocked)
 230
 231     ap_followers = followed.follower_address
 232
 233     cond do
 234       following?(follower, followed) or info.deactivated ->
 235         {:error, "Could not follow user: #{followed.nickname} is already on your list."}
 236
 237       deny_follow_blocked and blocks?(followed, follower) ->
 238         {:error, "Could not follow user: #{followed.nickname} blocked you."}
 239
 240       true ->
 241         if !followed.local && follower.local && !ap_enabled?(followed) do
 242           Websub.subscribe(follower, followed)
 243         end
 244
 245         following =
 246           [ap_followers | follower.following]
 247           |> Enum.uniq()
 248
 249         follower =
 250           follower
 251           |> follow_changeset(%{following: following})
 252           |> update_and_set_cache
 253
 254         {:ok, _} = update_follower_count(followed)
 255
 256         follower
 257     end
 258   end
 259
 260   def unfollow(%User{} = follower, %User{} = followed) do
 261     ap_followers = followed.follower_address
 262
 263     if following?(follower, followed) and follower.ap_id != followed.ap_id do
 264       following =
 265         follower.following
 266         |> List.delete(ap_followers)
 267
 268       {:ok, follower} =
 269         follower
 270         |> follow_changeset(%{following: following})
 271         |> update_and_set_cache
 272
 273       {:ok, followed} = update_follower_count(followed)
 274
 275       {:ok, follower, Utils.fetch_latest_follow(follower, followed)}
 276     else
 277       {:error, "Not subscribed!"}
 278     end
 279   end
 280
 281   def following?(%User{} = follower, %User{} = followed) do
 282     Enum.member?(follower.following, followed.follower_address)
 283   end
 284
 285   def locked?(%User{} = user) do
 286     user.info.locked || false
 287   end
 288
 289   def get_by_ap_id(ap_id) do
 290     Repo.get_by(User, ap_id: ap_id)
 291   end
 292
 293   def update_and_set_cache(changeset) do
 294     with {:ok, user} <- Repo.update(changeset) do
 295       Cachex.put(:user_cache, "ap_id:#{user.ap_id}", user)
 296       Cachex.put(:user_cache, "nickname:#{user.nickname}", user)
 297       Cachex.put(:user_cache, "user_info:#{user.id}", user_info(user))
 298       {:ok, user}
 299     else
 300       e -> e
 301     end
 302   end
 303
 304   def invalidate_cache(user) do
 305     Cachex.del(:user_cache, "ap_id:#{user.ap_id}")
 306     Cachex.del(:user_cache, "nickname:#{user.nickname}")
 307     Cachex.del(:user_cache, "user_info:#{user.id}")
 308   end
 309
 310   def get_cached_by_ap_id(ap_id) do
 311     key = "ap_id:#{ap_id}"
 312     Cachex.fetch!(:user_cache, key, fn _ -> get_by_ap_id(ap_id) end)
 313   end
 314
 315   def get_cached_by_nickname(nickname) do
 316     key = "nickname:#{nickname}"
 317     Cachex.fetch!(:user_cache, key, fn _ -> get_or_fetch_by_nickname(nickname) end)
 318   end
 319
 320   def get_by_nickname(nickname) do
 321     Repo.get_by(User, nickname: nickname)
 322   end
 323
 324   def get_by_nickname_or_email(nickname_or_email) do
 325     case user = Repo.get_by(User, nickname: nickname_or_email) do
 326       %User{} -> user
 327       nil -> Repo.get_by(User, email: nickname_or_email)
 328     end
 329   end
 330
 331   def get_cached_user_info(user) do
 332     key = "user_info:#{user.id}"
 333     Cachex.fetch!(:user_cache, key, fn _ -> user_info(user) end)
 334   end
 335
 336   def fetch_by_nickname(nickname) do
 337     ap_try = ActivityPub.make_user_from_nickname(nickname)
 338
 339     case ap_try do
 340       {:ok, user} -> {:ok, user}
 341       _ -> OStatus.make_user(nickname)
 342     end
 343   end
 344
 345   def get_or_fetch_by_nickname(nickname) do
 346     with %User{} = user <- get_by_nickname(nickname) do
 347       user
 348     else
 349       _e ->
 350         with [_nick, _domain] <- String.split(nickname, "@"),
 351              {:ok, user} <- fetch_by_nickname(nickname) do
 352           user
 353         else
 354           _e -> nil
 355         end
 356     end
 357   end
 358
 359   def get_followers_query(%User{id: id, follower_address: follower_address}) do
 360     from(
 361       u in User,
 362       where: fragment("? <@ ?", ^[follower_address], u.following),
 363       where: u.id != ^id
 364     )
 365   end
 366
 367   def get_followers(user) do
 368     q = get_followers_query(user)
 369
 370     {:ok, Repo.all(q)}
 371   end
 372
 373   def get_friends_query(%User{id: id, following: following}) do
 374     from(
 375       u in User,
 376       where: u.follower_address in ^following,
 377       where: u.id != ^id
 378     )
 379   end
 380
 381   def get_friends(user) do
 382     q = get_friends_query(user)
 383
 384     {:ok, Repo.all(q)}
 385   end
 386
 387   def get_follow_requests_query(%User{} = user) do
 388     from(
 389       a in Activity,
 390       where:
 391         fragment(
 392           "? ->> 'type' = 'Follow'",
 393           a.data
 394         ),
 395       where:
 396         fragment(
 397           "? ->> 'state' = 'pending'",
 398           a.data
 399         ),
 400       where:
 401         fragment(
 402           "? @> ?",
 403           a.data,
 404           ^%{"object" => user.ap_id}
 405         )
 406     )
 407   end
 408
 409   def get_follow_requests(%User{} = user) do
 410     q = get_follow_requests_query(user)
 411     reqs = Repo.all(q)
 412
 413     users =
 414       Enum.map(reqs, fn req -> req.actor end)
 415       |> Enum.uniq()
 416       |> Enum.map(fn ap_id -> get_by_ap_id(ap_id) end)
 417       |> Enum.filter(fn u -> !following?(u, user) end)
 418
 419     {:ok, users}
 420   end
 421
 422   def increase_note_count(%User{} = user) do
 423     info_cng = User.Info.add_to_note_count(user.info, 1)
 424
 425     cng =
 426       change(user)
 427       |> put_embed(:info, info_cng)
 428
 429     update_and_set_cache(cng)
 430   end
 431
 432   def decrease_note_count(%User{} = user) do
 433     info_cng = User.Info.add_to_note_count(user.info, -1)
 434
 435     cng =
 436       change(user)
 437       |> put_embed(:info, info_cng)
 438
 439     update_and_set_cache(cng)
 440   end
 441
 442   def update_note_count(%User{} = user) do
 443     note_count_query =
 444       from(
 445         a in Object,
 446         where: fragment("?->>'actor' = ? and ?->>'type' = 'Note'", a.data, ^user.ap_id, a.data),
 447         select: count(a.id)
 448       )
 449
 450     note_count = Repo.one(note_count_query)
 451
 452     info_cng = User.Info.set_note_count(user.info, note_count)
 453
 454     cng =
 455       change(user)
 456       |> put_embed(:info, info_cng)
 457
 458     update_and_set_cache(cng)
 459   end
 460
 461   def update_follower_count(%User{} = user) do
 462     follower_count_query =
 463       from(
 464         u in User,
 465         where: ^user.follower_address in u.following,
 466         where: u.id != ^user.id,
 467         select: count(u.id)
 468       )
 469
 470     follower_count = Repo.one(follower_count_query)
 471
 472     info_cng =
 473       user.info
 474       |> User.Info.set_follower_count(follower_count)
 475
 476     cng =
 477       change(user)
 478       |> put_embed(:info, info_cng)
 479
 480     update_and_set_cache(cng)
 481   end
 482
 483   def get_users_from_set_query(ap_ids, false) do
 484     from(
 485       u in User,
 486       where: u.ap_id in ^ap_ids
 487     )
 488   end
 489
 490   def get_users_from_set_query(ap_ids, true) do
 491     query = get_users_from_set_query(ap_ids, false)
 492
 493     from(
 494       u in query,
 495       where: u.local == true
 496     )
 497   end
 498
 499   def get_users_from_set(ap_ids, local_only \\ true) do
 500     get_users_from_set_query(ap_ids, local_only)
 501     |> Repo.all()
 502   end
 503
 504   def get_recipients_from_activity(%Activity{recipients: to}) do
 505     query =
 506       from(
 507         u in User,
 508         where: u.ap_id in ^to,
 509         or_where: fragment("? && ?", u.following, ^to)
 510       )
 511
 512     query = from(u in query, where: u.local == true)
 513
 514     Repo.all(query)
 515   end
 516
 517   def search(query, resolve \\ false) do
 518     # strip the beginning @ off if there is a query
 519     query = String.trim_leading(query, "@")
 520
 521     if resolve do
 522       User.get_or_fetch_by_nickname(query)
 523     end
 524
 525     inner =
 526       from(
 527         u in User,
 528         select_merge: %{
 529           search_distance:
 530             fragment(
 531               "? <-> (? || ?)",
 532               ^query,
 533               u.nickname,
 534               u.name
 535             )
 536         },
 537         where: not is_nil(u.nickname)
 538       )
 539
 540     q =
 541       from(
 542         s in subquery(inner),
 543         order_by: s.search_distance,
 544         limit: 20
 545       )
 546
 547     Repo.all(q)
 548   end
 549
 550   def block(blocker, %User{ap_id: ap_id} = blocked) do
 551     # sever any follow relationships to prevent leaks per activitypub (Pleroma issue #213)
 552     blocker =
 553       if following?(blocker, blocked) do
 554         {:ok, blocker, _} = unfollow(blocker, blocked)
 555         blocker
 556       else
 557         blocker
 558       end
 559
 560     if following?(blocked, blocker) do
 561       unfollow(blocked, blocker)
 562     end
 563
 564     info_cng =
 565       blocker.info
 566       |> User.Info.add_to_block(ap_id)
 567
 568     cng =
 569       change(blocker)
 570       |> put_embed(:info, info_cng)
 571
 572     update_and_set_cache(cng)
 573   end
 574
 575   # helper to handle the block given only an actor's AP id
 576   def block(blocker, %{ap_id: ap_id}) do
 577     block(blocker, User.get_by_ap_id(ap_id))
 578   end
 579
 580   def unblock(blocker, %{ap_id: ap_id}) do
 581     info_cng =
 582       blocker.info
 583       |> User.Info.remove_from_block(ap_id)
 584
 585     cng =
 586       change(blocker)
 587       |> put_embed(:info, info_cng)
 588
 589     update_and_set_cache(cng)
 590   end
 591
 592   def blocks?(user, %{ap_id: ap_id}) do
 593     blocks = user.info.blocks
 594     domain_blocks = user.info.domain_blocks
 595     %{host: host} = URI.parse(ap_id)
 596
 597     Enum.member?(blocks, ap_id) ||
 598       Enum.any?(domain_blocks, fn domain ->
 599         host == domain
 600       end)
 601   end
 602
 603   def block_domain(user, domain) do
 604     info_cng =
 605       user.info
 606       |> User.Info.add_to_domain_block(domain)
 607
 608     cng =
 609       change(user)
 610       |> put_embed(:info, info_cng)
 611
 612     update_and_set_cache(cng)
 613   end
 614
 615   def unblock_domain(user, domain) do
 616     info_cng =
 617       user.info
 618       |> User.Info.remove_from_domain_block(domain)
 619
 620     cng =
 621       change(user)
 622       |> put_embed(:info, info_cng)
 623
 624     update_and_set_cache(cng)
 625   end
 626
 627   def local_user_query() do
 628     from(
 629       u in User,
 630       where: u.local == true,
 631       where: not is_nil(u.nickname)
 632     )
 633   end
 634
 635   def moderator_user_query() do
 636     from(
 637       u in User,
 638       where: u.local == true,
 639       where: fragment("?->'is_moderator' @> 'true'", u.info)
 640     )
 641   end
 642
 643   def deactivate(%User{} = user, status \\ true) do
 644     info_cng = User.Info.set_activation_status(user.info, status)
 645
 646     cng =
 647       change(user)
 648       |> put_embed(:info, info_cng)
 649
 650     update_and_set_cache(cng)
 651   end
 652
 653   def delete(%User{} = user) do
 654     {:ok, user} = User.deactivate(user)
 655
 656     # Remove all relationships
 657     {:ok, followers} = User.get_followers(user)
 658
 659     followers
 660     |> Enum.each(fn follower -> User.unfollow(follower, user) end)
 661
 662     {:ok, friends} = User.get_friends(user)
 663
 664     friends
 665     |> Enum.each(fn followed -> User.unfollow(user, followed) end)
 666
 667     query = from(a in Activity, where: a.actor == ^user.ap_id)
 668
 669     Repo.all(query)
 670     |> Enum.each(fn activity ->
 671       case activity.data["type"] do
 672         "Create" ->
 673           ActivityPub.delete(Object.normalize(activity.data["object"]))
 674
 675         # TODO: Do something with likes, follows, repeats.
 676         _ ->
 677           "Doing nothing"
 678       end
 679     end)
 680
 681     {:ok, user}
 682   end
 683
 684   def html_filter_policy(%User{info: %{no_rich_text: true}}) do
 685     Pleroma.HTML.Scrubber.TwitterText
 686   end
 687
 688   def html_filter_policy(_), do: nil
 689
 690   def get_or_fetch_by_ap_id(ap_id) do
 691     user = get_by_ap_id(ap_id)
 692
 693     if !is_nil(user) and !User.needs_update?(user) do
 694       user
 695     else
 696       ap_try = ActivityPub.make_user_from_ap_id(ap_id)
 697
 698       case ap_try do
 699         {:ok, user} ->
 700           user
 701
 702         _ ->
 703           case OStatus.make_user(ap_id) do
 704             {:ok, user} -> user
 705             _ -> {:error, "Could not fetch by AP id"}
 706           end
 707       end
 708     end
 709   end
 710
 711   def get_or_create_instance_user do
 712     relay_uri = "#{Pleroma.Web.Endpoint.url()}/relay"
 713
 714     if user = get_by_ap_id(relay_uri) do
 715       user
 716     else
 717       changes =
 718         %User{info: %User.Info{}}
 719         |> cast(%{}, [:ap_id, :nickname, :local])
 720         |> put_change(:ap_id, relay_uri)
 721         |> put_change(:nickname, nil)
 722         |> put_change(:local, true)
 723         |> put_change(:follower_address, relay_uri <> "/followers")
 724
 725       {:ok, user} = Repo.insert(changes)
 726       user
 727     end
 728   end
 729
 730   # AP style
 731   def public_key_from_info(%{
 732         source_data: %{"publicKey" => %{"publicKeyPem" => public_key_pem}}
 733       }) do
 734     key =
 735       :public_key.pem_decode(public_key_pem)
 736       |> hd()
 737       |> :public_key.pem_entry_decode()
 738
 739     {:ok, key}
 740   end
 741
 742   # OStatus Magic Key
 743   def public_key_from_info(%{magic_key: magic_key}) do
 744     {:ok, Pleroma.Web.Salmon.decode_key(magic_key)}
 745   end
 746
 747   def get_public_key_for_ap_id(ap_id) do
 748     with %User{} = user <- get_or_fetch_by_ap_id(ap_id),
 749          {:ok, public_key} <- public_key_from_info(user.info) do
 750       {:ok, public_key}
 751     else
 752       _ -> :error
 753     end
 754   end
 755
 756   defp blank?(""), do: nil
 757   defp blank?(n), do: n
 758
 759   def insert_or_update_user(data) do
 760     data =
 761       data
 762       |> Map.put(:name, blank?(data[:name]) || data[:nickname])
 763
 764     cs = User.remote_user_creation(data)
 765
 766     Repo.insert(cs, on_conflict: :replace_all, conflict_target: :nickname)
 767   end
 768
 769   def ap_enabled?(%User{local: true}), do: true
 770   def ap_enabled?(%User{info: info}), do: info.ap_enabled
 771   def ap_enabled?(_), do: false
 772
 773   def get_or_fetch(uri_or_nickname) do
 774     if String.starts_with?(uri_or_nickname, "http") do
 775       get_or_fetch_by_ap_id(uri_or_nickname)
 776     else
 777       get_or_fetch_by_nickname(uri_or_nickname)
 778     end
 779   end
 780
 781   # wait a period of time and return newest version of the User structs
 782   # this is because we have synchronous follow APIs and need to simulate them
 783   # with an async handshake
 784   def wait_and_refresh(_, %User{local: true} = a, %User{local: true} = b) do
 785     with %User{} = a <- Repo.get(User, a.id),
 786          %User{} = b <- Repo.get(User, b.id) do
 787       {:ok, a, b}
 788     else
 789       _e ->
 790         :error
 791     end
 792   end
 793
 794   def wait_and_refresh(timeout, %User{} = a, %User{} = b) do
 795     with :ok <- :timer.sleep(timeout),
 796          %User{} = a <- Repo.get(User, a.id),
 797          %User{} = b <- Repo.get(User, b.id) do
 798       {:ok, a, b}
 799     else
 800       _e ->
 801         :error
 802     end
 803   end
 804
 805   def parse_bio(bio, user \\ %User{info: %{source_data: %{}}}) do
 806     mentions = Formatter.parse_mentions(bio)
 807     tags = Formatter.parse_tags(bio)
 808
 809     emoji =
 810       (user.info.source_data["tag"] || [])
 811       |> Enum.filter(fn %{"type" => t} -> t == "Emoji" end)
 812       |> Enum.map(fn %{"icon" => %{"url" => url}, "name" => name} ->
 813         {String.trim(name, ":"), url}
 814       end)
 815
 816     CommonUtils.format_input(bio, mentions, tags, "text/plain") |> Formatter.emojify(emoji)
 817   end
 818 end