git.squeep.com Git - akkoma/blob - lib/pleroma/user.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.User do
   6   use Ecto.Schema
   7
   8   import Ecto.Changeset
   9   import Ecto.Query
  10   import Ecto, only: [assoc: 2]
  11
  12   alias Ecto.Multi
  13   alias Pleroma.Activity
  14   alias Pleroma.Config
  15   alias Pleroma.Conversation.Participation
  16   alias Pleroma.Delivery
  17   alias Pleroma.EctoType.ActivityPub.ObjectValidators
  18   alias Pleroma.Emoji
  19   alias Pleroma.FollowingRelationship
  20   alias Pleroma.Formatter
  21   alias Pleroma.HTML
  22   alias Pleroma.Keys
  23   alias Pleroma.MFA
  24   alias Pleroma.Notification
  25   alias Pleroma.Object
  26   alias Pleroma.Registration
  27   alias Pleroma.Repo
  28   alias Pleroma.User
  29   alias Pleroma.UserRelationship
  30   alias Pleroma.Web
  31   alias Pleroma.Web.ActivityPub.ActivityPub
  32   alias Pleroma.Web.ActivityPub.Builder
  33   alias Pleroma.Web.ActivityPub.Pipeline
  34   alias Pleroma.Web.ActivityPub.Utils
  35   alias Pleroma.Web.CommonAPI
  36   alias Pleroma.Web.CommonAPI.Utils, as: CommonUtils
  37   alias Pleroma.Web.OAuth
  38   alias Pleroma.Web.RelMe
  39   alias Pleroma.Workers.BackgroundWorker
  40
  41   require Logger
  42
  43   @type t :: %__MODULE__{}
  44   @type account_status ::
  45           :active
  46           | :deactivated
  47           | :password_reset_pending
  48           | :confirmation_pending
  49           | :approval_pending
  50   @primary_key {:id, FlakeId.Ecto.CompatType, autogenerate: true}
  51
  52   # credo:disable-for-next-line Credo.Check.Readability.MaxLineLength
  53   @email_regex ~r/^[a-zA-Z0-9.!#$%&'*+\/=?^_`{|}~-]+@[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?(?:\.[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?)*$/
  54
  55   @strict_local_nickname_regex ~r/^[a-zA-Z\d]+$/
  56   @extended_local_nickname_regex ~r/^[a-zA-Z\d_-]+$/
  57
  58   # AP ID user relationships (blocks, mutes etc.)
  59   # Format: [rel_type: [outgoing_rel: :outgoing_rel_target, incoming_rel: :incoming_rel_source]]
  60   @user_relationships_config [
  61     block: [
  62       blocker_blocks: :blocked_users,
  63       blockee_blocks: :blocker_users
  64     ],
  65     mute: [
  66       muter_mutes: :muted_users,
  67       mutee_mutes: :muter_users
  68     ],
  69     reblog_mute: [
  70       reblog_muter_mutes: :reblog_muted_users,
  71       reblog_mutee_mutes: :reblog_muter_users
  72     ],
  73     notification_mute: [
  74       notification_muter_mutes: :notification_muted_users,
  75       notification_mutee_mutes: :notification_muter_users
  76     ],
  77     # Note: `inverse_subscription` relationship is inverse: subscriber acts as relationship target
  78     inverse_subscription: [
  79       subscribee_subscriptions: :subscriber_users,
  80       subscriber_subscriptions: :subscribee_users
  81     ]
  82   ]
  83
  84   schema "users" do
  85     field(:bio, :string, default: "")
  86     field(:raw_bio, :string)
  87     field(:email, :string)
  88     field(:name, :string)
  89     field(:nickname, :string)
  90     field(:password_hash, :string)
  91     field(:password, :string, virtual: true)
  92     field(:password_confirmation, :string, virtual: true)
  93     field(:keys, :string)
  94     field(:public_key, :string)
  95     field(:ap_id, :string)
  96     field(:avatar, :map, default: %{})
  97     field(:local, :boolean, default: true)
  98     field(:follower_address, :string)
  99     field(:following_address, :string)
 100     field(:search_rank, :float, virtual: true)
 101     field(:search_type, :integer, virtual: true)
 102     field(:tags, {:array, :string}, default: [])
 103     field(:last_refreshed_at, :naive_datetime_usec)
 104     field(:last_digest_emailed_at, :naive_datetime)
 105     field(:banner, :map, default: %{})
 106     field(:background, :map, default: %{})
 107     field(:note_count, :integer, default: 0)
 108     field(:follower_count, :integer, default: 0)
 109     field(:following_count, :integer, default: 0)
 110     field(:locked, :boolean, default: false)
 111     field(:confirmation_pending, :boolean, default: false)
 112     field(:password_reset_pending, :boolean, default: false)
 113     field(:approval_pending, :boolean, default: false)
 114     field(:registration_reason, :string, default: nil)
 115     field(:confirmation_token, :string, default: nil)
 116     field(:default_scope, :string, default: "public")
 117     field(:domain_blocks, {:array, :string}, default: [])
 118     field(:deactivated, :boolean, default: false)
 119     field(:no_rich_text, :boolean, default: false)
 120     field(:ap_enabled, :boolean, default: false)
 121     field(:is_moderator, :boolean, default: false)
 122     field(:is_admin, :boolean, default: false)
 123     field(:show_role, :boolean, default: true)
 124     field(:mastofe_settings, :map, default: nil)
 125     field(:uri, ObjectValidators.Uri, default: nil)
 126     field(:hide_followers_count, :boolean, default: false)
 127     field(:hide_follows_count, :boolean, default: false)
 128     field(:hide_followers, :boolean, default: false)
 129     field(:hide_follows, :boolean, default: false)
 130     field(:hide_favorites, :boolean, default: true)
 131     field(:unread_conversation_count, :integer, default: 0)
 132     field(:pinned_activities, {:array, :string}, default: [])
 133     field(:email_notifications, :map, default: %{"digest" => false})
 134     field(:mascot, :map, default: nil)
 135     field(:emoji, :map, default: %{})
 136     field(:pleroma_settings_store, :map, default: %{})
 137     field(:fields, {:array, :map}, default: [])
 138     field(:raw_fields, {:array, :map}, default: [])
 139     field(:discoverable, :boolean, default: false)
 140     field(:invisible, :boolean, default: false)
 141     field(:allow_following_move, :boolean, default: true)
 142     field(:skip_thread_containment, :boolean, default: false)
 143     field(:actor_type, :string, default: "Person")
 144     field(:also_known_as, {:array, :string}, default: [])
 145     field(:inbox, :string)
 146     field(:shared_inbox, :string)
 147     field(:accepts_chat_messages, :boolean, default: nil)
 148
 149     embeds_one(
 150       :notification_settings,
 151       Pleroma.User.NotificationSetting,
 152       on_replace: :update
 153     )
 154
 155     has_many(:notifications, Notification)
 156     has_many(:registrations, Registration)
 157     has_many(:deliveries, Delivery)
 158
 159     has_many(:outgoing_relationships, UserRelationship, foreign_key: :source_id)
 160     has_many(:incoming_relationships, UserRelationship, foreign_key: :target_id)
 161
 162     for {relationship_type,
 163          [
 164            {outgoing_relation, outgoing_relation_target},
 165            {incoming_relation, incoming_relation_source}
 166          ]} <- @user_relationships_config do
 167       # Definitions of `has_many` relations: :blocker_blocks, :muter_mutes, :reblog_muter_mutes,
 168       #   :notification_muter_mutes, :subscribee_subscriptions
 169       has_many(outgoing_relation, UserRelationship,
 170         foreign_key: :source_id,
 171         where: [relationship_type: relationship_type]
 172       )
 173
 174       # Definitions of `has_many` relations: :blockee_blocks, :mutee_mutes, :reblog_mutee_mutes,
 175       #   :notification_mutee_mutes, :subscriber_subscriptions
 176       has_many(incoming_relation, UserRelationship,
 177         foreign_key: :target_id,
 178         where: [relationship_type: relationship_type]
 179       )
 180
 181       # Definitions of `has_many` relations: :blocked_users, :muted_users, :reblog_muted_users,
 182       #   :notification_muted_users, :subscriber_users
 183       has_many(outgoing_relation_target, through: [outgoing_relation, :target])
 184
 185       # Definitions of `has_many` relations: :blocker_users, :muter_users, :reblog_muter_users,
 186       #   :notification_muter_users, :subscribee_users
 187       has_many(incoming_relation_source, through: [incoming_relation, :source])
 188     end
 189
 190     # `:blocks` is deprecated (replaced with `blocked_users` relation)
 191     field(:blocks, {:array, :string}, default: [])
 192     # `:mutes` is deprecated (replaced with `muted_users` relation)
 193     field(:mutes, {:array, :string}, default: [])
 194     # `:muted_reblogs` is deprecated (replaced with `reblog_muted_users` relation)
 195     field(:muted_reblogs, {:array, :string}, default: [])
 196     # `:muted_notifications` is deprecated (replaced with `notification_muted_users` relation)
 197     field(:muted_notifications, {:array, :string}, default: [])
 198     # `:subscribers` is deprecated (replaced with `subscriber_users` relation)
 199     field(:subscribers, {:array, :string}, default: [])
 200
 201     embeds_one(
 202       :multi_factor_authentication_settings,
 203       MFA.Settings,
 204       on_replace: :delete
 205     )
 206
 207     timestamps()
 208   end
 209
 210   for {_relationship_type, [{_outgoing_relation, outgoing_relation_target}, _]} <-
 211         @user_relationships_config do
 212     # `def blocked_users_relation/2`, `def muted_users_relation/2`,
 213     #   `def reblog_muted_users_relation/2`, `def notification_muted_users/2`,
 214     #   `def subscriber_users/2`
 215     def unquote(:"#{outgoing_relation_target}_relation")(user, restrict_deactivated? \\ false) do
 216       target_users_query = assoc(user, unquote(outgoing_relation_target))
 217
 218       if restrict_deactivated? do
 219         restrict_deactivated(target_users_query)
 220       else
 221         target_users_query
 222       end
 223     end
 224
 225     # `def blocked_users/2`, `def muted_users/2`, `def reblog_muted_users/2`,
 226     #   `def notification_muted_users/2`, `def subscriber_users/2`
 227     def unquote(outgoing_relation_target)(user, restrict_deactivated? \\ false) do
 228       __MODULE__
 229       |> apply(unquote(:"#{outgoing_relation_target}_relation"), [
 230         user,
 231         restrict_deactivated?
 232       ])
 233       |> Repo.all()
 234     end
 235
 236     # `def blocked_users_ap_ids/2`, `def muted_users_ap_ids/2`, `def reblog_muted_users_ap_ids/2`,
 237     #   `def notification_muted_users_ap_ids/2`, `def subscriber_users_ap_ids/2`
 238     def unquote(:"#{outgoing_relation_target}_ap_ids")(user, restrict_deactivated? \\ false) do
 239       __MODULE__
 240       |> apply(unquote(:"#{outgoing_relation_target}_relation"), [
 241         user,
 242         restrict_deactivated?
 243       ])
 244       |> select([u], u.ap_id)
 245       |> Repo.all()
 246     end
 247   end
 248
 249   defdelegate following_count(user), to: FollowingRelationship
 250   defdelegate following(user), to: FollowingRelationship
 251   defdelegate following?(follower, followed), to: FollowingRelationship
 252   defdelegate following_ap_ids(user), to: FollowingRelationship
 253   defdelegate get_follow_requests(user), to: FollowingRelationship
 254   defdelegate search(query, opts \\ []), to: User.Search
 255
 256   @doc """
 257   Dumps Flake Id to SQL-compatible format (16-byte UUID).
 258   E.g. "9pQtDGXuq4p3VlcJEm" -> <<0, 0, 1, 110, 179, 218, 42, 92, 213, 41, 44, 227, 95, 213, 0, 0>>
 259   """
 260   def binary_id(source_id) when is_binary(source_id) do
 261     with {:ok, dumped_id} <- FlakeId.Ecto.CompatType.dump(source_id) do
 262       dumped_id
 263     else
 264       _ -> source_id
 265     end
 266   end
 267
 268   def binary_id(source_ids) when is_list(source_ids) do
 269     Enum.map(source_ids, &binary_id/1)
 270   end
 271
 272   def binary_id(%User{} = user), do: binary_id(user.id)
 273
 274   @doc "Returns status account"
 275   @spec account_status(User.t()) :: account_status()
 276   def account_status(%User{deactivated: true}), do: :deactivated
 277   def account_status(%User{password_reset_pending: true}), do: :password_reset_pending
 278   def account_status(%User{local: true, approval_pending: true}), do: :approval_pending
 279
 280   def account_status(%User{local: true, confirmation_pending: true}) do
 281     if Config.get([:instance, :account_activation_required]) do
 282       :confirmation_pending
 283     else
 284       :active
 285     end
 286   end
 287
 288   def account_status(%User{}), do: :active
 289
 290   @spec visible_for(User.t(), User.t() | nil) ::
 291           :visible
 292           | :invisible
 293           | :restricted_unauthenticated
 294           | :deactivated
 295           | :confirmation_pending
 296   def visible_for(user, for_user \\ nil)
 297
 298   def visible_for(%User{invisible: true}, _), do: :invisible
 299
 300   def visible_for(%User{id: user_id}, %User{id: user_id}), do: :visible
 301
 302   def visible_for(%User{} = user, nil) do
 303     if restrict_unauthenticated?(user) do
 304       :restrict_unauthenticated
 305     else
 306       visible_account_status(user)
 307     end
 308   end
 309
 310   def visible_for(%User{} = user, for_user) do
 311     if superuser?(for_user) do
 312       :visible
 313     else
 314       visible_account_status(user)
 315     end
 316   end
 317
 318   def visible_for(_, _), do: :invisible
 319
 320   defp restrict_unauthenticated?(%User{local: true}) do
 321     Config.restrict_unauthenticated_access?(:profiles, :local)
 322   end
 323
 324   defp restrict_unauthenticated?(%User{local: _}) do
 325     Config.restrict_unauthenticated_access?(:profiles, :remote)
 326   end
 327
 328   defp visible_account_status(user) do
 329     status = account_status(user)
 330
 331     if status in [:active, :password_reset_pending] do
 332       :visible
 333     else
 334       status
 335     end
 336   end
 337
 338   @spec superuser?(User.t()) :: boolean()
 339   def superuser?(%User{local: true, is_admin: true}), do: true
 340   def superuser?(%User{local: true, is_moderator: true}), do: true
 341   def superuser?(_), do: false
 342
 343   @spec invisible?(User.t()) :: boolean()
 344   def invisible?(%User{invisible: true}), do: true
 345   def invisible?(_), do: false
 346
 347   def avatar_url(user, options \\ []) do
 348     case user.avatar do
 349       %{"url" => [%{"href" => href} | _]} ->
 350         href
 351
 352       _ ->
 353         unless options[:no_default] do
 354           Config.get([:assets, :default_user_avatar], "#{Web.base_url()}/images/avi.png")
 355         end
 356     end
 357   end
 358
 359   def banner_url(user, options \\ []) do
 360     case user.banner do
 361       %{"url" => [%{"href" => href} | _]} -> href
 362       _ -> !options[:no_default] && "#{Web.base_url()}/images/banner.png"
 363     end
 364   end
 365
 366   # Should probably be renamed or removed
 367   def ap_id(%User{nickname: nickname}), do: "#{Web.base_url()}/users/#{nickname}"
 368
 369   def ap_followers(%User{follower_address: fa}) when is_binary(fa), do: fa
 370   def ap_followers(%User{} = user), do: "#{ap_id(user)}/followers"
 371
 372   @spec ap_following(User.t()) :: String.t()
 373   def ap_following(%User{following_address: fa}) when is_binary(fa), do: fa
 374   def ap_following(%User{} = user), do: "#{ap_id(user)}/following"
 375
 376   @spec restrict_deactivated(Ecto.Query.t()) :: Ecto.Query.t()
 377   def restrict_deactivated(query) do
 378     from(u in query, where: u.deactivated != ^true)
 379   end
 380
 381   defp truncate_fields_param(params) do
 382     if Map.has_key?(params, :fields) do
 383       Map.put(params, :fields, Enum.map(params[:fields], &truncate_field/1))
 384     else
 385       params
 386     end
 387   end
 388
 389   defp truncate_if_exists(params, key, max_length) do
 390     if Map.has_key?(params, key) and is_binary(params[key]) do
 391       {value, _chopped} = String.split_at(params[key], max_length)
 392       Map.put(params, key, value)
 393     else
 394       params
 395     end
 396   end
 397
 398   defp fix_follower_address(%{follower_address: _, following_address: _} = params), do: params
 399
 400   defp fix_follower_address(%{nickname: nickname} = params),
 401     do: Map.put(params, :follower_address, ap_followers(%User{nickname: nickname}))
 402
 403   defp fix_follower_address(params), do: params
 404
 405   def remote_user_changeset(struct \\ %User{local: false}, params) do
 406     bio_limit = Config.get([:instance, :user_bio_length], 5000)
 407     name_limit = Config.get([:instance, :user_name_length], 100)
 408
 409     name =
 410       case params[:name] do
 411         name when is_binary(name) and byte_size(name) > 0 -> name
 412         _ -> params[:nickname]
 413       end
 414
 415     params =
 416       params
 417       |> Map.put(:name, name)
 418       |> Map.put_new(:last_refreshed_at, NaiveDateTime.utc_now())
 419       |> truncate_if_exists(:name, name_limit)
 420       |> truncate_if_exists(:bio, bio_limit)
 421       |> truncate_fields_param()
 422       |> fix_follower_address()
 423
 424     struct
 425     |> cast(
 426       params,
 427       [
 428         :bio,
 429         :name,
 430         :emoji,
 431         :ap_id,
 432         :inbox,
 433         :shared_inbox,
 434         :nickname,
 435         :public_key,
 436         :avatar,
 437         :ap_enabled,
 438         :banner,
 439         :locked,
 440         :last_refreshed_at,
 441         :uri,
 442         :follower_address,
 443         :following_address,
 444         :hide_followers,
 445         :hide_follows,
 446         :hide_followers_count,
 447         :hide_follows_count,
 448         :follower_count,
 449         :fields,
 450         :following_count,
 451         :discoverable,
 452         :invisible,
 453         :actor_type,
 454         :also_known_as,
 455         :accepts_chat_messages
 456       ]
 457     )
 458     |> validate_required([:name, :ap_id])
 459     |> unique_constraint(:nickname)
 460     |> validate_format(:nickname, @email_regex)
 461     |> validate_length(:bio, max: bio_limit)
 462     |> validate_length(:name, max: name_limit)
 463     |> validate_fields(true)
 464   end
 465
 466   def update_changeset(struct, params \\ %{}) do
 467     bio_limit = Config.get([:instance, :user_bio_length], 5000)
 468     name_limit = Config.get([:instance, :user_name_length], 100)
 469
 470     struct
 471     |> cast(
 472       params,
 473       [
 474         :bio,
 475         :raw_bio,
 476         :name,
 477         :emoji,
 478         :avatar,
 479         :public_key,
 480         :inbox,
 481         :shared_inbox,
 482         :locked,
 483         :no_rich_text,
 484         :default_scope,
 485         :banner,
 486         :hide_follows,
 487         :hide_followers,
 488         :hide_followers_count,
 489         :hide_follows_count,
 490         :hide_favorites,
 491         :allow_following_move,
 492         :background,
 493         :show_role,
 494         :skip_thread_containment,
 495         :fields,
 496         :raw_fields,
 497         :pleroma_settings_store,
 498         :discoverable,
 499         :actor_type,
 500         :also_known_as,
 501         :accepts_chat_messages
 502       ]
 503     )
 504     |> unique_constraint(:nickname)
 505     |> validate_format(:nickname, local_nickname_regex())
 506     |> validate_length(:bio, max: bio_limit)
 507     |> validate_length(:name, min: 1, max: name_limit)
 508     |> validate_inclusion(:actor_type, ["Person", "Service"])
 509     |> put_fields()
 510     |> put_emoji()
 511     |> put_change_if_present(:bio, &{:ok, parse_bio(&1, struct)})
 512     |> put_change_if_present(:avatar, &put_upload(&1, :avatar))
 513     |> put_change_if_present(:banner, &put_upload(&1, :banner))
 514     |> put_change_if_present(:background, &put_upload(&1, :background))
 515     |> put_change_if_present(
 516       :pleroma_settings_store,
 517       &{:ok, Map.merge(struct.pleroma_settings_store, &1)}
 518     )
 519     |> validate_fields(false)
 520   end
 521
 522   defp put_fields(changeset) do
 523     if raw_fields = get_change(changeset, :raw_fields) do
 524       raw_fields =
 525         raw_fields
 526         |> Enum.filter(fn %{"name" => n} -> n != "" end)
 527
 528       fields =
 529         raw_fields
 530         |> Enum.map(fn f -> Map.update!(f, "value", &parse_fields(&1)) end)
 531
 532       changeset
 533       |> put_change(:raw_fields, raw_fields)
 534       |> put_change(:fields, fields)
 535     else
 536       changeset
 537     end
 538   end
 539
 540   defp parse_fields(value) do
 541     value
 542     |> Formatter.linkify(mentions_format: :full)
 543     |> elem(0)
 544   end
 545
 546   defp put_emoji(changeset) do
 547     emojified_fields = [:bio, :name, :raw_fields]
 548
 549     if Enum.any?(changeset.changes, fn {k, _} -> k in emojified_fields end) do
 550       bio = Emoji.Formatter.get_emoji_map(get_field(changeset, :bio))
 551       name = Emoji.Formatter.get_emoji_map(get_field(changeset, :name))
 552
 553       emoji = Map.merge(bio, name)
 554
 555       emoji =
 556         changeset
 557         |> get_field(:raw_fields)
 558         |> Enum.reduce(emoji, fn x, acc ->
 559           Map.merge(acc, Emoji.Formatter.get_emoji_map(x["name"] <> x["value"]))
 560         end)
 561
 562       put_change(changeset, :emoji, emoji)
 563     else
 564       changeset
 565     end
 566   end
 567
 568   defp put_change_if_present(changeset, map_field, value_function) do
 569     with {:ok, value} <- fetch_change(changeset, map_field),
 570          {:ok, new_value} <- value_function.(value) do
 571       put_change(changeset, map_field, new_value)
 572     else
 573       _ -> changeset
 574     end
 575   end
 576
 577   defp put_upload(value, type) do
 578     with %Plug.Upload{} <- value,
 579          {:ok, object} <- ActivityPub.upload(value, type: type) do
 580       {:ok, object.data}
 581     end
 582   end
 583
 584   def update_as_admin_changeset(struct, params) do
 585     struct
 586     |> update_changeset(params)
 587     |> cast(params, [:email])
 588     |> delete_change(:also_known_as)
 589     |> unique_constraint(:email)
 590     |> validate_format(:email, @email_regex)
 591     |> validate_inclusion(:actor_type, ["Person", "Service"])
 592   end
 593
 594   @spec update_as_admin(User.t(), map()) :: {:ok, User.t()} | {:error, Changeset.t()}
 595   def update_as_admin(user, params) do
 596     params = Map.put(params, "password_confirmation", params["password"])
 597     changeset = update_as_admin_changeset(user, params)
 598
 599     if params["password"] do
 600       reset_password(user, changeset, params)
 601     else
 602       User.update_and_set_cache(changeset)
 603     end
 604   end
 605
 606   def password_update_changeset(struct, params) do
 607     struct
 608     |> cast(params, [:password, :password_confirmation])
 609     |> validate_required([:password, :password_confirmation])
 610     |> validate_confirmation(:password)
 611     |> put_password_hash()
 612     |> put_change(:password_reset_pending, false)
 613   end
 614
 615   @spec reset_password(User.t(), map()) :: {:ok, User.t()} | {:error, Changeset.t()}
 616   def reset_password(%User{} = user, params) do
 617     reset_password(user, user, params)
 618   end
 619
 620   def reset_password(%User{id: user_id} = user, struct, params) do
 621     multi =
 622       Multi.new()
 623       |> Multi.update(:user, password_update_changeset(struct, params))
 624       |> Multi.delete_all(:tokens, OAuth.Token.Query.get_by_user(user_id))
 625       |> Multi.delete_all(:auth, OAuth.Authorization.delete_by_user_query(user))
 626
 627     case Repo.transaction(multi) do
 628       {:ok, %{user: user} = _} -> set_cache(user)
 629       {:error, _, changeset, _} -> {:error, changeset}
 630     end
 631   end
 632
 633   def update_password_reset_pending(user, value) do
 634     user
 635     |> change()
 636     |> put_change(:password_reset_pending, value)
 637     |> update_and_set_cache()
 638   end
 639
 640   def force_password_reset_async(user) do
 641     BackgroundWorker.enqueue("force_password_reset", %{"user_id" => user.id})
 642   end
 643
 644   @spec force_password_reset(User.t()) :: {:ok, User.t()} | {:error, Ecto.Changeset.t()}
 645   def force_password_reset(user), do: update_password_reset_pending(user, true)
 646
 647   # Used to auto-register LDAP accounts which won't have a password hash stored locally
 648   def register_changeset_ldap(struct, params = %{password: password})
 649       when is_nil(password) do
 650     params = Map.put_new(params, :accepts_chat_messages, true)
 651
 652     params =
 653       if Map.has_key?(params, :email) do
 654         Map.put_new(params, :email, params[:email])
 655       else
 656         params
 657       end
 658
 659     struct
 660     |> cast(params, [
 661       :name,
 662       :nickname,
 663       :email,
 664       :accepts_chat_messages
 665     ])
 666     |> validate_required([:name, :nickname])
 667     |> unique_constraint(:nickname)
 668     |> validate_exclusion(:nickname, Config.get([User, :restricted_nicknames]))
 669     |> validate_format(:nickname, local_nickname_regex())
 670     |> put_ap_id()
 671     |> unique_constraint(:ap_id)
 672     |> put_following_and_follower_address()
 673   end
 674
 675   def register_changeset(struct, params \\ %{}, opts \\ []) do
 676     bio_limit = Config.get([:instance, :user_bio_length], 5000)
 677     name_limit = Config.get([:instance, :user_name_length], 100)
 678     reason_limit = Config.get([:instance, :registration_reason_length], 500)
 679     params = Map.put_new(params, :accepts_chat_messages, true)
 680
 681     need_confirmation? =
 682       if is_nil(opts[:need_confirmation]) do
 683         Config.get([:instance, :account_activation_required])
 684       else
 685         opts[:need_confirmation]
 686       end
 687
 688     need_approval? =
 689       if is_nil(opts[:need_approval]) do
 690         Config.get([:instance, :account_approval_required])
 691       else
 692         opts[:need_approval]
 693       end
 694
 695     struct
 696     |> confirmation_changeset(need_confirmation: need_confirmation?)
 697     |> approval_changeset(need_approval: need_approval?)
 698     |> cast(params, [
 699       :bio,
 700       :raw_bio,
 701       :email,
 702       :name,
 703       :nickname,
 704       :password,
 705       :password_confirmation,
 706       :emoji,
 707       :accepts_chat_messages,
 708       :registration_reason
 709     ])
 710     |> validate_required([:name, :nickname, :password, :password_confirmation])
 711     |> validate_confirmation(:password)
 712     |> unique_constraint(:email)
 713     |> validate_format(:email, @email_regex)
 714     |> validate_change(:email, fn :email, email ->
 715       valid? =
 716         Config.get([User, :email_blacklist])
 717         |> Enum.all?(fn blacklisted_domain ->
 718           !String.ends_with?(email, ["@" <> blacklisted_domain, "." <> blacklisted_domain])
 719         end)
 720
 721       if valid?, do: [], else: [email: "Invalid email"]
 722     end)
 723     |> unique_constraint(:nickname)
 724     |> validate_exclusion(:nickname, Config.get([User, :restricted_nicknames]))
 725     |> validate_format(:nickname, local_nickname_regex())
 726     |> validate_length(:bio, max: bio_limit)
 727     |> validate_length(:name, min: 1, max: name_limit)
 728     |> validate_length(:registration_reason, max: reason_limit)
 729     |> maybe_validate_required_email(opts[:external])
 730     |> put_password_hash
 731     |> put_ap_id()
 732     |> unique_constraint(:ap_id)
 733     |> put_following_and_follower_address()
 734   end
 735
 736   def maybe_validate_required_email(changeset, true), do: changeset
 737
 738   def maybe_validate_required_email(changeset, _) do
 739     if Config.get([:instance, :account_activation_required]) do
 740       validate_required(changeset, [:email])
 741     else
 742       changeset
 743     end
 744   end
 745
 746   defp put_ap_id(changeset) do
 747     ap_id = ap_id(%User{nickname: get_field(changeset, :nickname)})
 748     put_change(changeset, :ap_id, ap_id)
 749   end
 750
 751   defp put_following_and_follower_address(changeset) do
 752     followers = ap_followers(%User{nickname: get_field(changeset, :nickname)})
 753
 754     changeset
 755     |> put_change(:follower_address, followers)
 756   end
 757
 758   defp autofollow_users(user) do
 759     candidates = Config.get([:instance, :autofollowed_nicknames])
 760
 761     autofollowed_users =
 762       User.Query.build(%{nickname: candidates, local: true, deactivated: false})
 763       |> Repo.all()
 764
 765     follow_all(user, autofollowed_users)
 766   end
 767
 768   @doc "Inserts provided changeset, performs post-registration actions (confirmation email sending etc.)"
 769   def register(%Ecto.Changeset{} = changeset) do
 770     with {:ok, user} <- Repo.insert(changeset) do
 771       post_register_action(user)
 772     end
 773   end
 774
 775   def post_register_action(%User{} = user) do
 776     with {:ok, user} <- autofollow_users(user),
 777          {:ok, user} <- set_cache(user),
 778          {:ok, _} <- send_welcome_email(user),
 779          {:ok, _} <- send_welcome_message(user),
 780          {:ok, _} <- send_welcome_chat_message(user),
 781          {:ok, _} <- try_send_confirmation_email(user) do
 782       {:ok, user}
 783     end
 784   end
 785
 786   def send_welcome_message(user) do
 787     if User.WelcomeMessage.enabled?() do
 788       User.WelcomeMessage.post_message(user)
 789       {:ok, :enqueued}
 790     else
 791       {:ok, :noop}
 792     end
 793   end
 794
 795   def send_welcome_chat_message(user) do
 796     if User.WelcomeChatMessage.enabled?() do
 797       User.WelcomeChatMessage.post_message(user)
 798       {:ok, :enqueued}
 799     else
 800       {:ok, :noop}
 801     end
 802   end
 803
 804   def send_welcome_email(%User{email: email} = user) when is_binary(email) do
 805     if User.WelcomeEmail.enabled?() do
 806       User.WelcomeEmail.send_email(user)
 807       {:ok, :enqueued}
 808     else
 809       {:ok, :noop}
 810     end
 811   end
 812
 813   def send_welcome_email(_), do: {:ok, :noop}
 814
 815   @spec try_send_confirmation_email(User.t()) :: {:ok, :enqueued | :noop}
 816   def try_send_confirmation_email(%User{confirmation_pending: true} = user) do
 817     if Config.get([:instance, :account_activation_required]) do
 818       send_confirmation_email(user)
 819       {:ok, :enqueued}
 820     else
 821       {:ok, :noop}
 822     end
 823   end
 824
 825   def try_send_confirmation_email(_), do: {:ok, :noop}
 826
 827   @spec send_confirmation_email(Uset.t()) :: User.t()
 828   def send_confirmation_email(%User{} = user) do
 829     user
 830     |> Pleroma.Emails.UserEmail.account_confirmation_email()
 831     |> Pleroma.Emails.Mailer.deliver_async()
 832
 833     user
 834   end
 835
 836   def needs_update?(%User{local: true}), do: false
 837
 838   def needs_update?(%User{local: false, last_refreshed_at: nil}), do: true
 839
 840   def needs_update?(%User{local: false} = user) do
 841     NaiveDateTime.diff(NaiveDateTime.utc_now(), user.last_refreshed_at) >= 86_400
 842   end
 843
 844   def needs_update?(_), do: true
 845
 846   @spec maybe_direct_follow(User.t(), User.t()) :: {:ok, User.t()} | {:error, String.t()}
 847
 848   # "Locked" (self-locked) users demand explicit authorization of follow requests
 849   def maybe_direct_follow(%User{} = follower, %User{local: true, locked: true} = followed) do
 850     follow(follower, followed, :follow_pending)
 851   end
 852
 853   def maybe_direct_follow(%User{} = follower, %User{local: true} = followed) do
 854     follow(follower, followed)
 855   end
 856
 857   def maybe_direct_follow(%User{} = follower, %User{} = followed) do
 858     if not ap_enabled?(followed) do
 859       follow(follower, followed)
 860     else
 861       {:ok, follower}
 862     end
 863   end
 864
 865   @doc "A mass follow for local users. Respects blocks in both directions but does not create activities."
 866   @spec follow_all(User.t(), list(User.t())) :: {atom(), User.t()}
 867   def follow_all(follower, followeds) do
 868     followeds
 869     |> Enum.reject(fn followed -> blocks?(follower, followed) || blocks?(followed, follower) end)
 870     |> Enum.each(&follow(follower, &1, :follow_accept))
 871
 872     set_cache(follower)
 873   end
 874
 875   def follow(%User{} = follower, %User{} = followed, state \\ :follow_accept) do
 876     deny_follow_blocked = Config.get([:user, :deny_follow_blocked])
 877
 878     cond do
 879       followed.deactivated ->
 880         {:error, "Could not follow user: #{followed.nickname} is deactivated."}
 881
 882       deny_follow_blocked and blocks?(followed, follower) ->
 883         {:error, "Could not follow user: #{followed.nickname} blocked you."}
 884
 885       true ->
 886         FollowingRelationship.follow(follower, followed, state)
 887
 888         {:ok, _} = update_follower_count(followed)
 889
 890         follower
 891         |> update_following_count()
 892     end
 893   end
 894
 895   def unfollow(%User{ap_id: ap_id}, %User{ap_id: ap_id}) do
 896     {:error, "Not subscribed!"}
 897   end
 898
 899   @spec unfollow(User.t(), User.t()) :: {:ok, User.t(), Activity.t()} | {:error, String.t()}
 900   def unfollow(%User{} = follower, %User{} = followed) do
 901     case do_unfollow(follower, followed) do
 902       {:ok, follower, followed} ->
 903         {:ok, follower, Utils.fetch_latest_follow(follower, followed)}
 904
 905       error ->
 906         error
 907     end
 908   end
 909
 910   @spec do_unfollow(User.t(), User.t()) :: {:ok, User.t(), User.t()} | {:error, String.t()}
 911   defp do_unfollow(%User{} = follower, %User{} = followed) do
 912     case get_follow_state(follower, followed) do
 913       state when state in [:follow_pending, :follow_accept] ->
 914         FollowingRelationship.unfollow(follower, followed)
 915         {:ok, followed} = update_follower_count(followed)
 916
 917         {:ok, follower} =
 918           follower
 919           |> update_following_count()
 920
 921         {:ok, follower, followed}
 922
 923       nil ->
 924         {:error, "Not subscribed!"}
 925     end
 926   end
 927
 928   @doc "Returns follow state as Pleroma.FollowingRelationship.State value"
 929   def get_follow_state(%User{} = follower, %User{} = following) do
 930     following_relationship = FollowingRelationship.get(follower, following)
 931     get_follow_state(follower, following, following_relationship)
 932   end
 933
 934   def get_follow_state(
 935         %User{} = follower,
 936         %User{} = following,
 937         following_relationship
 938       ) do
 939     case {following_relationship, following.local} do
 940       {nil, false} ->
 941         case Utils.fetch_latest_follow(follower, following) do
 942           %Activity{data: %{"state" => state}} when state in ["pending", "accept"] ->
 943             FollowingRelationship.state_to_enum(state)
 944
 945           _ ->
 946             nil
 947         end
 948
 949       {%{state: state}, _} ->
 950         state
 951
 952       {nil, _} ->
 953         nil
 954     end
 955   end
 956
 957   def locked?(%User{} = user) do
 958     user.locked || false
 959   end
 960
 961   def get_by_id(id) do
 962     Repo.get_by(User, id: id)
 963   end
 964
 965   def get_by_ap_id(ap_id) do
 966     Repo.get_by(User, ap_id: ap_id)
 967   end
 968
 969   def get_all_by_ap_id(ap_ids) do
 970     from(u in __MODULE__,
 971       where: u.ap_id in ^ap_ids
 972     )
 973     |> Repo.all()
 974   end
 975
 976   def get_all_by_ids(ids) do
 977     from(u in __MODULE__, where: u.id in ^ids)
 978     |> Repo.all()
 979   end
 980
 981   # This is mostly an SPC migration fix. This guesses the user nickname by taking the last part
 982   # of the ap_id and the domain and tries to get that user
 983   def get_by_guessed_nickname(ap_id) do
 984     domain = URI.parse(ap_id).host
 985     name = List.last(String.split(ap_id, "/"))
 986     nickname = "#{name}@#{domain}"
 987
 988     get_cached_by_nickname(nickname)
 989   end
 990
 991   def set_cache({:ok, user}), do: set_cache(user)
 992   def set_cache({:error, err}), do: {:error, err}
 993
 994   def set_cache(%User{} = user) do
 995     Cachex.put(:user_cache, "ap_id:#{user.ap_id}", user)
 996     Cachex.put(:user_cache, "nickname:#{user.nickname}", user)
 997     Cachex.put(:user_cache, "friends_ap_ids:#{user.nickname}", get_user_friends_ap_ids(user))
 998     {:ok, user}
 999   end
1000
1001   def update_and_set_cache(struct, params) do
1002     struct
1003     |> update_changeset(params)
1004     |> update_and_set_cache()
1005   end
1006
1007   def update_and_set_cache(changeset) do
1008     with {:ok, user} <- Repo.update(changeset, stale_error_field: :id) do
1009       set_cache(user)
1010     end
1011   end
1012
1013   def get_user_friends_ap_ids(user) do
1014     from(u in User.get_friends_query(user), select: u.ap_id)
1015     |> Repo.all()
1016   end
1017
1018   @spec get_cached_user_friends_ap_ids(User.t()) :: [String.t()]
1019   def get_cached_user_friends_ap_ids(user) do
1020     Cachex.fetch!(:user_cache, "friends_ap_ids:#{user.ap_id}", fn _ ->
1021       get_user_friends_ap_ids(user)
1022     end)
1023   end
1024
1025   def invalidate_cache(user) do
1026     Cachex.del(:user_cache, "ap_id:#{user.ap_id}")
1027     Cachex.del(:user_cache, "nickname:#{user.nickname}")
1028     Cachex.del(:user_cache, "friends_ap_ids:#{user.ap_id}")
1029   end
1030
1031   @spec get_cached_by_ap_id(String.t()) :: User.t() | nil
1032   def get_cached_by_ap_id(ap_id) do
1033     key = "ap_id:#{ap_id}"
1034
1035     with {:ok, nil} <- Cachex.get(:user_cache, key),
1036          user when not is_nil(user) <- get_by_ap_id(ap_id),
1037          {:ok, true} <- Cachex.put(:user_cache, key, user) do
1038       user
1039     else
1040       {:ok, user} -> user
1041       nil -> nil
1042     end
1043   end
1044
1045   def get_cached_by_id(id) do
1046     key = "id:#{id}"
1047
1048     ap_id =
1049       Cachex.fetch!(:user_cache, key, fn _ ->
1050         user = get_by_id(id)
1051
1052         if user do
1053           Cachex.put(:user_cache, "ap_id:#{user.ap_id}", user)
1054           {:commit, user.ap_id}
1055         else
1056           {:ignore, ""}
1057         end
1058       end)
1059
1060     get_cached_by_ap_id(ap_id)
1061   end
1062
1063   def get_cached_by_nickname(nickname) do
1064     key = "nickname:#{nickname}"
1065
1066     Cachex.fetch!(:user_cache, key, fn ->
1067       case get_or_fetch_by_nickname(nickname) do
1068         {:ok, user} -> {:commit, user}
1069         {:error, _error} -> {:ignore, nil}
1070       end
1071     end)
1072   end
1073
1074   def get_cached_by_nickname_or_id(nickname_or_id, opts \\ []) do
1075     restrict_to_local = Config.get([:instance, :limit_to_local_content])
1076
1077     cond do
1078       is_integer(nickname_or_id) or FlakeId.flake_id?(nickname_or_id) ->
1079         get_cached_by_id(nickname_or_id) || get_cached_by_nickname(nickname_or_id)
1080
1081       restrict_to_local == false or not String.contains?(nickname_or_id, "@") ->
1082         get_cached_by_nickname(nickname_or_id)
1083
1084       restrict_to_local == :unauthenticated and match?(%User{}, opts[:for]) ->
1085         get_cached_by_nickname(nickname_or_id)
1086
1087       true ->
1088         nil
1089     end
1090   end
1091
1092   @spec get_by_nickname(String.t()) :: User.t() | nil
1093   def get_by_nickname(nickname) do
1094     Repo.get_by(User, nickname: nickname) ||
1095       if Regex.match?(~r(@#{Pleroma.Web.Endpoint.host()})i, nickname) do
1096         Repo.get_by(User, nickname: local_nickname(nickname))
1097       end
1098   end
1099
1100   def get_by_email(email), do: Repo.get_by(User, email: email)
1101
1102   def get_by_nickname_or_email(nickname_or_email) do
1103     get_by_nickname(nickname_or_email) || get_by_email(nickname_or_email)
1104   end
1105
1106   def fetch_by_nickname(nickname), do: ActivityPub.make_user_from_nickname(nickname)
1107
1108   def get_or_fetch_by_nickname(nickname) do
1109     with %User{} = user <- get_by_nickname(nickname) do
1110       {:ok, user}
1111     else
1112       _e ->
1113         with [_nick, _domain] <- String.split(nickname, "@"),
1114              {:ok, user} <- fetch_by_nickname(nickname) do
1115           {:ok, user}
1116         else
1117           _e -> {:error, "not found " <> nickname}
1118         end
1119     end
1120   end
1121
1122   @spec get_followers_query(User.t(), pos_integer() | nil) :: Ecto.Query.t()
1123   def get_followers_query(%User{} = user, nil) do
1124     User.Query.build(%{followers: user, deactivated: false})
1125   end
1126
1127   def get_followers_query(%User{} = user, page) do
1128     user
1129     |> get_followers_query(nil)
1130     |> User.Query.paginate(page, 20)
1131   end
1132
1133   @spec get_followers_query(User.t()) :: Ecto.Query.t()
1134   def get_followers_query(%User{} = user), do: get_followers_query(user, nil)
1135
1136   @spec get_followers(User.t(), pos_integer() | nil) :: {:ok, list(User.t())}
1137   def get_followers(%User{} = user, page \\ nil) do
1138     user
1139     |> get_followers_query(page)
1140     |> Repo.all()
1141   end
1142
1143   @spec get_external_followers(User.t(), pos_integer() | nil) :: {:ok, list(User.t())}
1144   def get_external_followers(%User{} = user, page \\ nil) do
1145     user
1146     |> get_followers_query(page)
1147     |> User.Query.build(%{external: true})
1148     |> Repo.all()
1149   end
1150
1151   def get_followers_ids(%User{} = user, page \\ nil) do
1152     user
1153     |> get_followers_query(page)
1154     |> select([u], u.id)
1155     |> Repo.all()
1156   end
1157
1158   @spec get_friends_query(User.t(), pos_integer() | nil) :: Ecto.Query.t()
1159   def get_friends_query(%User{} = user, nil) do
1160     User.Query.build(%{friends: user, deactivated: false})
1161   end
1162
1163   def get_friends_query(%User{} = user, page) do
1164     user
1165     |> get_friends_query(nil)
1166     |> User.Query.paginate(page, 20)
1167   end
1168
1169   @spec get_friends_query(User.t()) :: Ecto.Query.t()
1170   def get_friends_query(%User{} = user), do: get_friends_query(user, nil)
1171
1172   def get_friends(%User{} = user, page \\ nil) do
1173     user
1174     |> get_friends_query(page)
1175     |> Repo.all()
1176   end
1177
1178   def get_friends_ap_ids(%User{} = user) do
1179     user
1180     |> get_friends_query(nil)
1181     |> select([u], u.ap_id)
1182     |> Repo.all()
1183   end
1184
1185   def get_friends_ids(%User{} = user, page \\ nil) do
1186     user
1187     |> get_friends_query(page)
1188     |> select([u], u.id)
1189     |> Repo.all()
1190   end
1191
1192   def increase_note_count(%User{} = user) do
1193     User
1194     |> where(id: ^user.id)
1195     |> update([u], inc: [note_count: 1])
1196     |> select([u], u)
1197     |> Repo.update_all([])
1198     |> case do
1199       {1, [user]} -> set_cache(user)
1200       _ -> {:error, user}
1201     end
1202   end
1203
1204   def decrease_note_count(%User{} = user) do
1205     User
1206     |> where(id: ^user.id)
1207     |> update([u],
1208       set: [
1209         note_count: fragment("greatest(0, note_count - 1)")
1210       ]
1211     )
1212     |> select([u], u)
1213     |> Repo.update_all([])
1214     |> case do
1215       {1, [user]} -> set_cache(user)
1216       _ -> {:error, user}
1217     end
1218   end
1219
1220   def update_note_count(%User{} = user, note_count \\ nil) do
1221     note_count =
1222       note_count ||
1223         from(
1224           a in Object,
1225           where: fragment("?->>'actor' = ? and ?->>'type' = 'Note'", a.data, ^user.ap_id, a.data),
1226           select: count(a.id)
1227         )
1228         |> Repo.one()
1229
1230     user
1231     |> cast(%{note_count: note_count}, [:note_count])
1232     |> update_and_set_cache()
1233   end
1234
1235   @spec maybe_fetch_follow_information(User.t()) :: User.t()
1236   def maybe_fetch_follow_information(user) do
1237     with {:ok, user} <- fetch_follow_information(user) do
1238       user
1239     else
1240       e ->
1241         Logger.error("Follower/Following counter update for #{user.ap_id} failed.\n#{inspect(e)}")
1242
1243         user
1244     end
1245   end
1246
1247   def fetch_follow_information(user) do
1248     with {:ok, info} <- ActivityPub.fetch_follow_information_for_user(user) do
1249       user
1250       |> follow_information_changeset(info)
1251       |> update_and_set_cache()
1252     end
1253   end
1254
1255   defp follow_information_changeset(user, params) do
1256     user
1257     |> cast(params, [
1258       :hide_followers,
1259       :hide_follows,
1260       :follower_count,
1261       :following_count,
1262       :hide_followers_count,
1263       :hide_follows_count
1264     ])
1265   end
1266
1267   @spec update_follower_count(User.t()) :: {:ok, User.t()}
1268   def update_follower_count(%User{} = user) do
1269     if user.local or !Config.get([:instance, :external_user_synchronization]) do
1270       follower_count = FollowingRelationship.follower_count(user)
1271
1272       user
1273       |> follow_information_changeset(%{follower_count: follower_count})
1274       |> update_and_set_cache
1275     else
1276       {:ok, maybe_fetch_follow_information(user)}
1277     end
1278   end
1279
1280   @spec update_following_count(User.t()) :: {:ok, User.t()}
1281   def update_following_count(%User{local: false} = user) do
1282     if Config.get([:instance, :external_user_synchronization]) do
1283       {:ok, maybe_fetch_follow_information(user)}
1284     else
1285       {:ok, user}
1286     end
1287   end
1288
1289   def update_following_count(%User{local: true} = user) do
1290     following_count = FollowingRelationship.following_count(user)
1291
1292     user
1293     |> follow_information_changeset(%{following_count: following_count})
1294     |> update_and_set_cache()
1295   end
1296
1297   def set_unread_conversation_count(%User{local: true} = user) do
1298     unread_query = Participation.unread_conversation_count_for_user(user)
1299
1300     User
1301     |> join(:inner, [u], p in subquery(unread_query))
1302     |> update([u, p],
1303       set: [unread_conversation_count: p.count]
1304     )
1305     |> where([u], u.id == ^user.id)
1306     |> select([u], u)
1307     |> Repo.update_all([])
1308     |> case do
1309       {1, [user]} -> set_cache(user)
1310       _ -> {:error, user}
1311     end
1312   end
1313
1314   def set_unread_conversation_count(user), do: {:ok, user}
1315
1316   def increment_unread_conversation_count(conversation, %User{local: true} = user) do
1317     unread_query =
1318       Participation.unread_conversation_count_for_user(user)
1319       |> where([p], p.conversation_id == ^conversation.id)
1320
1321     User
1322     |> join(:inner, [u], p in subquery(unread_query))
1323     |> update([u, p],
1324       inc: [unread_conversation_count: 1]
1325     )
1326     |> where([u], u.id == ^user.id)
1327     |> where([u, p], p.count == 0)
1328     |> select([u], u)
1329     |> Repo.update_all([])
1330     |> case do
1331       {1, [user]} -> set_cache(user)
1332       _ -> {:error, user}
1333     end
1334   end
1335
1336   def increment_unread_conversation_count(_, user), do: {:ok, user}
1337
1338   @spec get_users_from_set([String.t()], keyword()) :: [User.t()]
1339   def get_users_from_set(ap_ids, opts \\ []) do
1340     local_only = Keyword.get(opts, :local_only, true)
1341     criteria = %{ap_id: ap_ids, deactivated: false}
1342     criteria = if local_only, do: Map.put(criteria, :local, true), else: criteria
1343
1344     User.Query.build(criteria)
1345     |> Repo.all()
1346   end
1347
1348   @spec get_recipients_from_activity(Activity.t()) :: [User.t()]
1349   def get_recipients_from_activity(%Activity{recipients: to, actor: actor}) do
1350     to = [actor | to]
1351
1352     query = User.Query.build(%{recipients_from_activity: to, local: true, deactivated: false})
1353
1354     query
1355     |> Repo.all()
1356   end
1357
1358   @spec mute(User.t(), User.t(), map()) ::
1359           {:ok, list(UserRelationship.t())} | {:error, String.t()}
1360   def mute(%User{} = muter, %User{} = mutee, params \\ %{}) do
1361     notifications? = Map.get(params, :notifications, true)
1362     expires_in = Map.get(params, :expires_in, 0)
1363
1364     with {:ok, user_mute} <- UserRelationship.create_mute(muter, mutee),
1365          {:ok, user_notification_mute} <-
1366            (notifications? && UserRelationship.create_notification_mute(muter, mutee)) ||
1367              {:ok, nil} do
1368       if expires_in > 0 do
1369         Pleroma.Workers.MuteExpireWorker.enqueue(
1370           "unmute_user",
1371           %{"muter_id" => muter.id, "mutee_id" => mutee.id},
1372           schedule_in: expires_in
1373         )
1374       end
1375
1376       {:ok, Enum.filter([user_mute, user_notification_mute], & &1)}
1377     end
1378   end
1379
1380   def unmute(%User{} = muter, %User{} = mutee) do
1381     with {:ok, user_mute} <- UserRelationship.delete_mute(muter, mutee),
1382          {:ok, user_notification_mute} <-
1383            UserRelationship.delete_notification_mute(muter, mutee) do
1384       {:ok, [user_mute, user_notification_mute]}
1385     end
1386   end
1387
1388   def unmute(muter_id, mutee_id) do
1389     with {:muter, %User{} = muter} <- {:muter, User.get_by_id(muter_id)},
1390          {:mutee, %User{} = mutee} <- {:mutee, User.get_by_id(mutee_id)} do
1391       unmute(muter, mutee)
1392     else
1393       {who, result} = error ->
1394         Logger.warn(
1395           "User.unmute/2 failed. #{who}: #{result}, muter_id: #{muter_id}, mutee_id: #{mutee_id}"
1396         )
1397
1398         {:error, error}
1399     end
1400   end
1401
1402   def subscribe(%User{} = subscriber, %User{} = target) do
1403     deny_follow_blocked = Config.get([:user, :deny_follow_blocked])
1404
1405     if blocks?(target, subscriber) and deny_follow_blocked do
1406       {:error, "Could not subscribe: #{target.nickname} is blocking you"}
1407     else
1408       # Note: the relationship is inverse: subscriber acts as relationship target
1409       UserRelationship.create_inverse_subscription(target, subscriber)
1410     end
1411   end
1412
1413   def subscribe(%User{} = subscriber, %{ap_id: ap_id}) do
1414     with %User{} = subscribee <- get_cached_by_ap_id(ap_id) do
1415       subscribe(subscriber, subscribee)
1416     end
1417   end
1418
1419   def unsubscribe(%User{} = unsubscriber, %User{} = target) do
1420     # Note: the relationship is inverse: subscriber acts as relationship target
1421     UserRelationship.delete_inverse_subscription(target, unsubscriber)
1422   end
1423
1424   def unsubscribe(%User{} = unsubscriber, %{ap_id: ap_id}) do
1425     with %User{} = user <- get_cached_by_ap_id(ap_id) do
1426       unsubscribe(unsubscriber, user)
1427     end
1428   end
1429
1430   def block(%User{} = blocker, %User{} = blocked) do
1431     # sever any follow relationships to prevent leaks per activitypub (Pleroma issue #213)
1432     blocker =
1433       if following?(blocker, blocked) do
1434         {:ok, blocker, _} = unfollow(blocker, blocked)
1435         blocker
1436       else
1437         blocker
1438       end
1439
1440     # clear any requested follows as well
1441     blocked =
1442       case CommonAPI.reject_follow_request(blocked, blocker) do
1443         {:ok, %User{} = updated_blocked} -> updated_blocked
1444         nil -> blocked
1445       end
1446
1447     unsubscribe(blocked, blocker)
1448
1449     unfollowing_blocked = Config.get([:activitypub, :unfollow_blocked], true)
1450     if unfollowing_blocked && following?(blocked, blocker), do: unfollow(blocked, blocker)
1451
1452     {:ok, blocker} = update_follower_count(blocker)
1453     {:ok, blocker, _} = Participation.mark_all_as_read(blocker, blocked)
1454     add_to_block(blocker, blocked)
1455   end
1456
1457   # helper to handle the block given only an actor's AP id
1458   def block(%User{} = blocker, %{ap_id: ap_id}) do
1459     block(blocker, get_cached_by_ap_id(ap_id))
1460   end
1461
1462   def unblock(%User{} = blocker, %User{} = blocked) do
1463     remove_from_block(blocker, blocked)
1464   end
1465
1466   # helper to handle the block given only an actor's AP id
1467   def unblock(%User{} = blocker, %{ap_id: ap_id}) do
1468     unblock(blocker, get_cached_by_ap_id(ap_id))
1469   end
1470
1471   def mutes?(nil, _), do: false
1472   def mutes?(%User{} = user, %User{} = target), do: mutes_user?(user, target)
1473
1474   def mutes_user?(%User{} = user, %User{} = target) do
1475     UserRelationship.mute_exists?(user, target)
1476   end
1477
1478   @spec muted_notifications?(User.t() | nil, User.t() | map()) :: boolean()
1479   def muted_notifications?(nil, _), do: false
1480
1481   def muted_notifications?(%User{} = user, %User{} = target),
1482     do: UserRelationship.notification_mute_exists?(user, target)
1483
1484   def blocks?(nil, _), do: false
1485
1486   def blocks?(%User{} = user, %User{} = target) do
1487     blocks_user?(user, target) ||
1488       (blocks_domain?(user, target) and not User.following?(user, target))
1489   end
1490
1491   def blocks_user?(%User{} = user, %User{} = target) do
1492     UserRelationship.block_exists?(user, target)
1493   end
1494
1495   def blocks_user?(_, _), do: false
1496
1497   def blocks_domain?(%User{} = user, %User{} = target) do
1498     domain_blocks = Pleroma.Web.ActivityPub.MRF.subdomains_regex(user.domain_blocks)
1499     %{host: host} = URI.parse(target.ap_id)
1500     Pleroma.Web.ActivityPub.MRF.subdomain_match?(domain_blocks, host)
1501   end
1502
1503   def blocks_domain?(_, _), do: false
1504
1505   def subscribed_to?(%User{} = user, %User{} = target) do
1506     # Note: the relationship is inverse: subscriber acts as relationship target
1507     UserRelationship.inverse_subscription_exists?(target, user)
1508   end
1509
1510   def subscribed_to?(%User{} = user, %{ap_id: ap_id}) do
1511     with %User{} = target <- get_cached_by_ap_id(ap_id) do
1512       subscribed_to?(user, target)
1513     end
1514   end
1515
1516   @doc """
1517   Returns map of outgoing (blocked, muted etc.) relationships' user AP IDs by relation type.
1518   E.g. `outgoing_relationships_ap_ids(user, [:block])` -> `%{block: ["https://some.site/users/userapid"]}`
1519   """
1520   @spec outgoing_relationships_ap_ids(User.t(), list(atom())) :: %{atom() => list(String.t())}
1521   def outgoing_relationships_ap_ids(_user, []), do: %{}
1522
1523   def outgoing_relationships_ap_ids(nil, _relationship_types), do: %{}
1524
1525   def outgoing_relationships_ap_ids(%User{} = user, relationship_types)
1526       when is_list(relationship_types) do
1527     db_result =
1528       user
1529       |> assoc(:outgoing_relationships)
1530       |> join(:inner, [user_rel], u in assoc(user_rel, :target))
1531       |> where([user_rel, u], user_rel.relationship_type in ^relationship_types)
1532       |> select([user_rel, u], [user_rel.relationship_type, fragment("array_agg(?)", u.ap_id)])
1533       |> group_by([user_rel, u], user_rel.relationship_type)
1534       |> Repo.all()
1535       |> Enum.into(%{}, fn [k, v] -> {k, v} end)
1536
1537     Enum.into(
1538       relationship_types,
1539       %{},
1540       fn rel_type -> {rel_type, db_result[rel_type] || []} end
1541     )
1542   end
1543
1544   def incoming_relationships_ungrouped_ap_ids(user, relationship_types, ap_ids \\ nil)
1545
1546   def incoming_relationships_ungrouped_ap_ids(_user, [], _ap_ids), do: []
1547
1548   def incoming_relationships_ungrouped_ap_ids(nil, _relationship_types, _ap_ids), do: []
1549
1550   def incoming_relationships_ungrouped_ap_ids(%User{} = user, relationship_types, ap_ids)
1551       when is_list(relationship_types) do
1552     user
1553     |> assoc(:incoming_relationships)
1554     |> join(:inner, [user_rel], u in assoc(user_rel, :source))
1555     |> where([user_rel, u], user_rel.relationship_type in ^relationship_types)
1556     |> maybe_filter_on_ap_id(ap_ids)
1557     |> select([user_rel, u], u.ap_id)
1558     |> distinct(true)
1559     |> Repo.all()
1560   end
1561
1562   defp maybe_filter_on_ap_id(query, ap_ids) when is_list(ap_ids) do
1563     where(query, [user_rel, u], u.ap_id in ^ap_ids)
1564   end
1565
1566   defp maybe_filter_on_ap_id(query, _ap_ids), do: query
1567
1568   def deactivate_async(user, status \\ true) do
1569     BackgroundWorker.enqueue("deactivate_user", %{"user_id" => user.id, "status" => status})
1570   end
1571
1572   def deactivate(user, status \\ true)
1573
1574   def deactivate(users, status) when is_list(users) do
1575     Repo.transaction(fn ->
1576       for user <- users, do: deactivate(user, status)
1577     end)
1578   end
1579
1580   def deactivate(%User{} = user, status) do
1581     with {:ok, user} <- set_activation_status(user, status) do
1582       user
1583       |> get_followers()
1584       |> Enum.filter(& &1.local)
1585       |> Enum.each(&set_cache(update_following_count(&1)))
1586
1587       # Only update local user counts, remote will be update during the next pull.
1588       user
1589       |> get_friends()
1590       |> Enum.filter(& &1.local)
1591       |> Enum.each(&do_unfollow(user, &1))
1592
1593       {:ok, user}
1594     end
1595   end
1596
1597   def approve(users) when is_list(users) do
1598     Repo.transaction(fn ->
1599       Enum.map(users, fn user ->
1600         with {:ok, user} <- approve(user), do: user
1601       end)
1602     end)
1603   end
1604
1605   def approve(%User{} = user) do
1606     change(user, approval_pending: false)
1607     |> update_and_set_cache()
1608   end
1609
1610   def update_notification_settings(%User{} = user, settings) do
1611     user
1612     |> cast(%{notification_settings: settings}, [])
1613     |> cast_embed(:notification_settings)
1614     |> validate_required([:notification_settings])
1615     |> update_and_set_cache()
1616   end
1617
1618   @spec purge_user_changeset(User.t()) :: Changeset.t()
1619   def purge_user_changeset(user) do
1620     # "Right to be forgotten"
1621     # https://gdpr.eu/right-to-be-forgotten/
1622     change(user, %{
1623       bio: "",
1624       raw_bio: nil,
1625       email: nil,
1626       name: nil,
1627       password_hash: nil,
1628       keys: nil,
1629       public_key: nil,
1630       avatar: %{},
1631       tags: [],
1632       last_refreshed_at: nil,
1633       last_digest_emailed_at: nil,
1634       banner: %{},
1635       background: %{},
1636       note_count: 0,
1637       follower_count: 0,
1638       following_count: 0,
1639       locked: false,
1640       confirmation_pending: false,
1641       password_reset_pending: false,
1642       approval_pending: false,
1643       registration_reason: nil,
1644       confirmation_token: nil,
1645       domain_blocks: [],
1646       deactivated: true,
1647       ap_enabled: false,
1648       is_moderator: false,
1649       is_admin: false,
1650       mastofe_settings: nil,
1651       mascot: nil,
1652       emoji: %{},
1653       pleroma_settings_store: %{},
1654       fields: [],
1655       raw_fields: [],
1656       discoverable: false,
1657       also_known_as: []
1658     })
1659   end
1660
1661   def delete(users) when is_list(users) do
1662     for user <- users, do: delete(user)
1663   end
1664
1665   def delete(%User{} = user) do
1666     BackgroundWorker.enqueue("delete_user", %{"user_id" => user.id})
1667   end
1668
1669   defp delete_and_invalidate_cache(%User{} = user) do
1670     invalidate_cache(user)
1671     Repo.delete(user)
1672   end
1673
1674   defp delete_or_deactivate(%User{local: false} = user), do: delete_and_invalidate_cache(user)
1675
1676   defp delete_or_deactivate(%User{local: true} = user) do
1677     status = account_status(user)
1678
1679     case status do
1680       :confirmation_pending ->
1681         delete_and_invalidate_cache(user)
1682
1683       :approval_pending ->
1684         delete_and_invalidate_cache(user)
1685
1686       _ ->
1687         user
1688         |> purge_user_changeset()
1689         |> update_and_set_cache()
1690     end
1691   end
1692
1693   def perform(:force_password_reset, user), do: force_password_reset(user)
1694
1695   @spec perform(atom(), User.t()) :: {:ok, User.t()}
1696   def perform(:delete, %User{} = user) do
1697     # Remove all relationships
1698     user
1699     |> get_followers()
1700     |> Enum.each(fn follower ->
1701       ActivityPub.unfollow(follower, user)
1702       unfollow(follower, user)
1703     end)
1704
1705     user
1706     |> get_friends()
1707     |> Enum.each(fn followed ->
1708       ActivityPub.unfollow(user, followed)
1709       unfollow(user, followed)
1710     end)
1711
1712     delete_user_activities(user)
1713     delete_notifications_from_user_activities(user)
1714
1715     delete_outgoing_pending_follow_requests(user)
1716
1717     delete_or_deactivate(user)
1718   end
1719
1720   def perform(:deactivate_async, user, status), do: deactivate(user, status)
1721
1722   @spec external_users_query() :: Ecto.Query.t()
1723   def external_users_query do
1724     User.Query.build(%{
1725       external: true,
1726       active: true,
1727       order_by: :id
1728     })
1729   end
1730
1731   @spec external_users(keyword()) :: [User.t()]
1732   def external_users(opts \\ []) do
1733     query =
1734       external_users_query()
1735       |> select([u], struct(u, [:id, :ap_id]))
1736
1737     query =
1738       if opts[:max_id],
1739         do: where(query, [u], u.id > ^opts[:max_id]),
1740         else: query
1741
1742     query =
1743       if opts[:limit],
1744         do: limit(query, ^opts[:limit]),
1745         else: query
1746
1747     Repo.all(query)
1748   end
1749
1750   def delete_notifications_from_user_activities(%User{ap_id: ap_id}) do
1751     Notification
1752     |> join(:inner, [n], activity in assoc(n, :activity))
1753     |> where([n, a], fragment("? = ?", a.actor, ^ap_id))
1754     |> Repo.delete_all()
1755   end
1756
1757   def delete_user_activities(%User{ap_id: ap_id} = user) do
1758     ap_id
1759     |> Activity.Queries.by_actor()
1760     |> Repo.chunk_stream(50, :batches)
1761     |> Stream.each(fn activities ->
1762       Enum.each(activities, fn activity -> delete_activity(activity, user) end)
1763     end)
1764     |> Stream.run()
1765   end
1766
1767   defp delete_activity(%{data: %{"type" => "Create", "object" => object}} = activity, user) do
1768     with {_, %Object{}} <- {:find_object, Object.get_by_ap_id(object)},
1769          {:ok, delete_data, _} <- Builder.delete(user, object) do
1770       Pipeline.common_pipeline(delete_data, local: user.local)
1771     else
1772       {:find_object, nil} ->
1773         # We have the create activity, but not the object, it was probably pruned.
1774         # Insert a tombstone and try again
1775         with {:ok, tombstone_data, _} <- Builder.tombstone(user.ap_id, object),
1776              {:ok, _tombstone} <- Object.create(tombstone_data) do
1777           delete_activity(activity, user)
1778         end
1779
1780       e ->
1781         Logger.error("Could not delete #{object} created by #{activity.data["ap_id"]}")
1782         Logger.error("Error: #{inspect(e)}")
1783     end
1784   end
1785
1786   defp delete_activity(%{data: %{"type" => type}} = activity, user)
1787        when type in ["Like", "Announce"] do
1788     {:ok, undo, _} = Builder.undo(user, activity)
1789     Pipeline.common_pipeline(undo, local: user.local)
1790   end
1791
1792   defp delete_activity(_activity, _user), do: "Doing nothing"
1793
1794   defp delete_outgoing_pending_follow_requests(user) do
1795     user
1796     |> FollowingRelationship.outgoing_pending_follow_requests_query()
1797     |> Repo.delete_all()
1798   end
1799
1800   def html_filter_policy(%User{no_rich_text: true}) do
1801     Pleroma.HTML.Scrubber.TwitterText
1802   end
1803
1804   def html_filter_policy(_), do: Config.get([:markup, :scrub_policy])
1805
1806   def fetch_by_ap_id(ap_id, opts \\ []), do: ActivityPub.make_user_from_ap_id(ap_id, opts)
1807
1808   def get_or_fetch_by_ap_id(ap_id, opts \\ []) do
1809     cached_user = get_cached_by_ap_id(ap_id)
1810
1811     maybe_fetched_user = needs_update?(cached_user) && fetch_by_ap_id(ap_id, opts)
1812
1813     case {cached_user, maybe_fetched_user} do
1814       {_, {:ok, %User{} = user}} ->
1815         {:ok, user}
1816
1817       {%User{} = user, _} ->
1818         {:ok, user}
1819
1820       _ ->
1821         {:error, :not_found}
1822     end
1823   end
1824
1825   @doc """
1826   Creates an internal service actor by URI if missing.
1827   Optionally takes nickname for addressing.
1828   """
1829   @spec get_or_create_service_actor_by_ap_id(String.t(), String.t()) :: User.t() | nil
1830   def get_or_create_service_actor_by_ap_id(uri, nickname) do
1831     {_, user} =
1832       case get_cached_by_ap_id(uri) do
1833         nil ->
1834           with {:error, %{errors: errors}} <- create_service_actor(uri, nickname) do
1835             Logger.error("Cannot create service actor: #{uri}/.\n#{inspect(errors)}")
1836             {:error, nil}
1837           end
1838
1839         %User{invisible: false} = user ->
1840           set_invisible(user)
1841
1842         user ->
1843           {:ok, user}
1844       end
1845
1846     user
1847   end
1848
1849   @spec set_invisible(User.t()) :: {:ok, User.t()}
1850   defp set_invisible(user) do
1851     user
1852     |> change(%{invisible: true})
1853     |> update_and_set_cache()
1854   end
1855
1856   @spec create_service_actor(String.t(), String.t()) ::
1857           {:ok, User.t()} | {:error, Ecto.Changeset.t()}
1858   defp create_service_actor(uri, nickname) do
1859     %User{
1860       invisible: true,
1861       local: true,
1862       ap_id: uri,
1863       nickname: nickname,
1864       follower_address: uri <> "/followers"
1865     }
1866     |> change
1867     |> unique_constraint(:nickname)
1868     |> Repo.insert()
1869     |> set_cache()
1870   end
1871
1872   def public_key(%{public_key: public_key_pem}) when is_binary(public_key_pem) do
1873     key =
1874       public_key_pem
1875       |> :public_key.pem_decode()
1876       |> hd()
1877       |> :public_key.pem_entry_decode()
1878
1879     {:ok, key}
1880   end
1881
1882   def public_key(_), do: {:error, "key not found"}
1883
1884   def get_public_key_for_ap_id(ap_id, opts \\ []) do
1885     with {:ok, %User{} = user} <- get_or_fetch_by_ap_id(ap_id, opts),
1886          {:ok, public_key} <- public_key(user) do
1887       {:ok, public_key}
1888     else
1889       _ -> :error
1890     end
1891   end
1892
1893   def ap_enabled?(%User{local: true}), do: true
1894   def ap_enabled?(%User{ap_enabled: ap_enabled}), do: ap_enabled
1895   def ap_enabled?(_), do: false
1896
1897   @doc "Gets or fetch a user by uri or nickname."
1898   @spec get_or_fetch(String.t()) :: {:ok, User.t()} | {:error, String.t()}
1899   def get_or_fetch("http" <> _host = uri), do: get_or_fetch_by_ap_id(uri)
1900   def get_or_fetch(nickname), do: get_or_fetch_by_nickname(nickname)
1901
1902   # wait a period of time and return newest version of the User structs
1903   # this is because we have synchronous follow APIs and need to simulate them
1904   # with an async handshake
1905   def wait_and_refresh(_, %User{local: true} = a, %User{local: true} = b) do
1906     with %User{} = a <- get_cached_by_id(a.id),
1907          %User{} = b <- get_cached_by_id(b.id) do
1908       {:ok, a, b}
1909     else
1910       nil -> :error
1911     end
1912   end
1913
1914   def wait_and_refresh(timeout, %User{} = a, %User{} = b) do
1915     with :ok <- :timer.sleep(timeout),
1916          %User{} = a <- get_cached_by_id(a.id),
1917          %User{} = b <- get_cached_by_id(b.id) do
1918       {:ok, a, b}
1919     else
1920       nil -> :error
1921     end
1922   end
1923
1924   def parse_bio(bio) when is_binary(bio) and bio != "" do
1925     bio
1926     |> CommonUtils.format_input("text/plain", mentions_format: :full)
1927     |> elem(0)
1928   end
1929
1930   def parse_bio(_), do: ""
1931
1932   def parse_bio(bio, user) when is_binary(bio) and bio != "" do
1933     # TODO: get profile URLs other than user.ap_id
1934     profile_urls = [user.ap_id]
1935
1936     bio
1937     |> CommonUtils.format_input("text/plain",
1938       mentions_format: :full,
1939       rel: &RelMe.maybe_put_rel_me(&1, profile_urls)
1940     )
1941     |> elem(0)
1942   end
1943
1944   def parse_bio(_, _), do: ""
1945
1946   def tag(user_identifiers, tags) when is_list(user_identifiers) do
1947     Repo.transaction(fn ->
1948       for user_identifier <- user_identifiers, do: tag(user_identifier, tags)
1949     end)
1950   end
1951
1952   def tag(nickname, tags) when is_binary(nickname),
1953     do: tag(get_by_nickname(nickname), tags)
1954
1955   def tag(%User{} = user, tags),
1956     do: update_tags(user, Enum.uniq((user.tags || []) ++ normalize_tags(tags)))
1957
1958   def untag(user_identifiers, tags) when is_list(user_identifiers) do
1959     Repo.transaction(fn ->
1960       for user_identifier <- user_identifiers, do: untag(user_identifier, tags)
1961     end)
1962   end
1963
1964   def untag(nickname, tags) when is_binary(nickname),
1965     do: untag(get_by_nickname(nickname), tags)
1966
1967   def untag(%User{} = user, tags),
1968     do: update_tags(user, (user.tags || []) -- normalize_tags(tags))
1969
1970   defp update_tags(%User{} = user, new_tags) do
1971     {:ok, updated_user} =
1972       user
1973       |> change(%{tags: new_tags})
1974       |> update_and_set_cache()
1975
1976     updated_user
1977   end
1978
1979   defp normalize_tags(tags) do
1980     [tags]
1981     |> List.flatten()
1982     |> Enum.map(&String.downcase/1)
1983   end
1984
1985   defp local_nickname_regex do
1986     if Config.get([:instance, :extended_nickname_format]) do
1987       @extended_local_nickname_regex
1988     else
1989       @strict_local_nickname_regex
1990     end
1991   end
1992
1993   def local_nickname(nickname_or_mention) do
1994     nickname_or_mention
1995     |> full_nickname()
1996     |> String.split("@")
1997     |> hd()
1998   end
1999
2000   def full_nickname(nickname_or_mention),
2001     do: String.trim_leading(nickname_or_mention, "@")
2002
2003   def error_user(ap_id) do
2004     %User{
2005       name: ap_id,
2006       ap_id: ap_id,
2007       nickname: "erroruser@example.com",
2008       inserted_at: NaiveDateTime.utc_now()
2009     }
2010   end
2011
2012   @spec all_superusers() :: [User.t()]
2013   def all_superusers do
2014     User.Query.build(%{super_users: true, local: true, deactivated: false})
2015     |> Repo.all()
2016   end
2017
2018   def muting_reblogs?(%User{} = user, %User{} = target) do
2019     UserRelationship.reblog_mute_exists?(user, target)
2020   end
2021
2022   def showing_reblogs?(%User{} = user, %User{} = target) do
2023     not muting_reblogs?(user, target)
2024   end
2025
2026   @doc """
2027   The function returns a query to get users with no activity for given interval of days.
2028   Inactive users are those who didn't read any notification, or had any activity where
2029   the user is the activity's actor, during `inactivity_threshold` days.
2030   Deactivated users will not appear in this list.
2031
2032   ## Examples
2033
2034       iex> Pleroma.User.list_inactive_users()
2035       %Ecto.Query{}
2036   """
2037   @spec list_inactive_users_query(integer()) :: Ecto.Query.t()
2038   def list_inactive_users_query(inactivity_threshold \\ 7) do
2039     negative_inactivity_threshold = -inactivity_threshold
2040     now = NaiveDateTime.truncate(NaiveDateTime.utc_now(), :second)
2041     # Subqueries are not supported in `where` clauses, join gets too complicated.
2042     has_read_notifications =
2043       from(n in Pleroma.Notification,
2044         where: n.seen == true,
2045         group_by: n.id,
2046         having: max(n.updated_at) > datetime_add(^now, ^negative_inactivity_threshold, "day"),
2047         select: n.user_id
2048       )
2049       |> Pleroma.Repo.all()
2050
2051     from(u in Pleroma.User,
2052       left_join: a in Pleroma.Activity,
2053       on: u.ap_id == a.actor,
2054       where: not is_nil(u.nickname),
2055       where: u.deactivated != ^true,
2056       where: u.id not in ^has_read_notifications,
2057       group_by: u.id,
2058       having:
2059         max(a.inserted_at) < datetime_add(^now, ^negative_inactivity_threshold, "day") or
2060           is_nil(max(a.inserted_at))
2061     )
2062   end
2063
2064   @doc """
2065   Enable or disable email notifications for user
2066
2067   ## Examples
2068
2069       iex> Pleroma.User.switch_email_notifications(Pleroma.User{email_notifications: %{"digest" => false}}, "digest", true)
2070       Pleroma.User{email_notifications: %{"digest" => true}}
2071
2072       iex> Pleroma.User.switch_email_notifications(Pleroma.User{email_notifications: %{"digest" => true}}, "digest", false)
2073       Pleroma.User{email_notifications: %{"digest" => false}}
2074   """
2075   @spec switch_email_notifications(t(), String.t(), boolean()) ::
2076           {:ok, t()} | {:error, Ecto.Changeset.t()}
2077   def switch_email_notifications(user, type, status) do
2078     User.update_email_notifications(user, %{type => status})
2079   end
2080
2081   @doc """
2082   Set `last_digest_emailed_at` value for the user to current time
2083   """
2084   @spec touch_last_digest_emailed_at(t()) :: t()
2085   def touch_last_digest_emailed_at(user) do
2086     now = NaiveDateTime.truncate(NaiveDateTime.utc_now(), :second)
2087
2088     {:ok, updated_user} =
2089       user
2090       |> change(%{last_digest_emailed_at: now})
2091       |> update_and_set_cache()
2092
2093     updated_user
2094   end
2095
2096   @spec toggle_confirmation(User.t()) :: {:ok, User.t()} | {:error, Changeset.t()}
2097   def toggle_confirmation(%User{} = user) do
2098     user
2099     |> confirmation_changeset(need_confirmation: !user.confirmation_pending)
2100     |> update_and_set_cache()
2101   end
2102
2103   @spec toggle_confirmation([User.t()]) :: [{:ok, User.t()} | {:error, Changeset.t()}]
2104   def toggle_confirmation(users) do
2105     Enum.map(users, &toggle_confirmation/1)
2106   end
2107
2108   def get_mascot(%{mascot: %{} = mascot}) when not is_nil(mascot) do
2109     mascot
2110   end
2111
2112   def get_mascot(%{mascot: mascot}) when is_nil(mascot) do
2113     # use instance-default
2114     config = Config.get([:assets, :mascots])
2115     default_mascot = Config.get([:assets, :default_mascot])
2116     mascot = Keyword.get(config, default_mascot)
2117
2118     %{
2119       "id" => "default-mascot",
2120       "url" => mascot[:url],
2121       "preview_url" => mascot[:url],
2122       "pleroma" => %{
2123         "mime_type" => mascot[:mime_type]
2124       }
2125     }
2126   end
2127
2128   def ensure_keys_present(%{keys: keys} = user) when not is_nil(keys), do: {:ok, user}
2129
2130   def ensure_keys_present(%User{} = user) do
2131     with {:ok, pem} <- Keys.generate_rsa_pem() do
2132       user
2133       |> cast(%{keys: pem}, [:keys])
2134       |> validate_required([:keys])
2135       |> update_and_set_cache()
2136     end
2137   end
2138
2139   def get_ap_ids_by_nicknames(nicknames) do
2140     from(u in User,
2141       where: u.nickname in ^nicknames,
2142       select: u.ap_id
2143     )
2144     |> Repo.all()
2145   end
2146
2147   defp put_password_hash(
2148          %Ecto.Changeset{valid?: true, changes: %{password: password}} = changeset
2149        ) do
2150     change(changeset, password_hash: Pbkdf2.hash_pwd_salt(password))
2151   end
2152
2153   defp put_password_hash(changeset), do: changeset
2154
2155   def is_internal_user?(%User{nickname: nil}), do: true
2156   def is_internal_user?(%User{local: true, nickname: "internal." <> _}), do: true
2157   def is_internal_user?(_), do: false
2158
2159   # A hack because user delete activities have a fake id for whatever reason
2160   # TODO: Get rid of this
2161   def get_delivered_users_by_object_id("pleroma:fake_object_id"), do: []
2162
2163   def get_delivered_users_by_object_id(object_id) do
2164     from(u in User,
2165       inner_join: delivery in assoc(u, :deliveries),
2166       where: delivery.object_id == ^object_id
2167     )
2168     |> Repo.all()
2169   end
2170
2171   def change_email(user, email) do
2172     user
2173     |> cast(%{email: email}, [:email])
2174     |> validate_required([:email])
2175     |> unique_constraint(:email)
2176     |> validate_format(:email, @email_regex)
2177     |> update_and_set_cache()
2178   end
2179
2180   # Internal function; public one is `deactivate/2`
2181   defp set_activation_status(user, deactivated) do
2182     user
2183     |> cast(%{deactivated: deactivated}, [:deactivated])
2184     |> update_and_set_cache()
2185   end
2186
2187   def update_banner(user, banner) do
2188     user
2189     |> cast(%{banner: banner}, [:banner])
2190     |> update_and_set_cache()
2191   end
2192
2193   def update_background(user, background) do
2194     user
2195     |> cast(%{background: background}, [:background])
2196     |> update_and_set_cache()
2197   end
2198
2199   def roles(%{is_moderator: is_moderator, is_admin: is_admin}) do
2200     %{
2201       admin: is_admin,
2202       moderator: is_moderator
2203     }
2204   end
2205
2206   def validate_fields(changeset, remote? \\ false) do
2207     limit_name = if remote?, do: :max_remote_account_fields, else: :max_account_fields
2208     limit = Config.get([:instance, limit_name], 0)
2209
2210     changeset
2211     |> validate_length(:fields, max: limit)
2212     |> validate_change(:fields, fn :fields, fields ->
2213       if Enum.all?(fields, &valid_field?/1) do
2214         []
2215       else
2216         [fields: "invalid"]
2217       end
2218     end)
2219   end
2220
2221   defp valid_field?(%{"name" => name, "value" => value}) do
2222     name_limit = Config.get([:instance, :account_field_name_length], 255)
2223     value_limit = Config.get([:instance, :account_field_value_length], 255)
2224
2225     is_binary(name) && is_binary(value) && String.length(name) <= name_limit &&
2226       String.length(value) <= value_limit
2227   end
2228
2229   defp valid_field?(_), do: false
2230
2231   defp truncate_field(%{"name" => name, "value" => value}) do
2232     {name, _chopped} =
2233       String.split_at(name, Config.get([:instance, :account_field_name_length], 255))
2234
2235     {value, _chopped} =
2236       String.split_at(value, Config.get([:instance, :account_field_value_length], 255))
2237
2238     %{"name" => name, "value" => value}
2239   end
2240
2241   def admin_api_update(user, params) do
2242     user
2243     |> cast(params, [
2244       :is_moderator,
2245       :is_admin,
2246       :show_role
2247     ])
2248     |> update_and_set_cache()
2249   end
2250
2251   @doc "Signs user out of all applications"
2252   def global_sign_out(user) do
2253     OAuth.Authorization.delete_user_authorizations(user)
2254     OAuth.Token.delete_user_tokens(user)
2255   end
2256
2257   def mascot_update(user, url) do
2258     user
2259     |> cast(%{mascot: url}, [:mascot])
2260     |> validate_required([:mascot])
2261     |> update_and_set_cache()
2262   end
2263
2264   def mastodon_settings_update(user, settings) do
2265     user
2266     |> cast(%{mastofe_settings: settings}, [:mastofe_settings])
2267     |> validate_required([:mastofe_settings])
2268     |> update_and_set_cache()
2269   end
2270
2271   @spec confirmation_changeset(User.t(), keyword()) :: Changeset.t()
2272   def confirmation_changeset(user, need_confirmation: need_confirmation?) do
2273     params =
2274       if need_confirmation? do
2275         %{
2276           confirmation_pending: true,
2277           confirmation_token: :crypto.strong_rand_bytes(32) |> Base.url_encode64()
2278         }
2279       else
2280         %{
2281           confirmation_pending: false,
2282           confirmation_token: nil
2283         }
2284       end
2285
2286     cast(user, params, [:confirmation_pending, :confirmation_token])
2287   end
2288
2289   @spec approval_changeset(User.t(), keyword()) :: Changeset.t()
2290   def approval_changeset(user, need_approval: need_approval?) do
2291     params = if need_approval?, do: %{approval_pending: true}, else: %{approval_pending: false}
2292     cast(user, params, [:approval_pending])
2293   end
2294
2295   def add_pinnned_activity(user, %Pleroma.Activity{id: id}) do
2296     if id not in user.pinned_activities do
2297       max_pinned_statuses = Config.get([:instance, :max_pinned_statuses], 0)
2298       params = %{pinned_activities: user.pinned_activities ++ [id]}
2299
2300       # if pinned activity was scheduled for deletion, we remove job
2301       if expiration = Pleroma.Workers.PurgeExpiredActivity.get_expiration(id) do
2302         Oban.cancel_job(expiration.id)
2303       end
2304
2305       user
2306       |> cast(params, [:pinned_activities])
2307       |> validate_length(:pinned_activities,
2308         max: max_pinned_statuses,
2309         message: "You have already pinned the maximum number of statuses"
2310       )
2311     else
2312       change(user)
2313     end
2314     |> update_and_set_cache()
2315   end
2316
2317   def remove_pinnned_activity(user, %Pleroma.Activity{id: id, data: data}) do
2318     params = %{pinned_activities: List.delete(user.pinned_activities, id)}
2319
2320     # if pinned activity was scheduled for deletion, we reschedule it for deletion
2321     if data["expires_at"] do
2322       {:ok, expires_at, _} = DateTime.from_iso8601(data["expires_at"])
2323
2324       Pleroma.Workers.PurgeExpiredActivity.enqueue(%{
2325         activity_id: id,
2326         expires_at: expires_at
2327       })
2328     end
2329
2330     user
2331     |> cast(params, [:pinned_activities])
2332     |> update_and_set_cache()
2333   end
2334
2335   def update_email_notifications(user, settings) do
2336     email_notifications =
2337       user.email_notifications
2338       |> Map.merge(settings)
2339       |> Map.take(["digest"])
2340
2341     params = %{email_notifications: email_notifications}
2342     fields = [:email_notifications]
2343
2344     user
2345     |> cast(params, fields)
2346     |> validate_required(fields)
2347     |> update_and_set_cache()
2348   end
2349
2350   defp set_domain_blocks(user, domain_blocks) do
2351     params = %{domain_blocks: domain_blocks}
2352
2353     user
2354     |> cast(params, [:domain_blocks])
2355     |> validate_required([:domain_blocks])
2356     |> update_and_set_cache()
2357   end
2358
2359   def block_domain(user, domain_blocked) do
2360     set_domain_blocks(user, Enum.uniq([domain_blocked | user.domain_blocks]))
2361   end
2362
2363   def unblock_domain(user, domain_blocked) do
2364     set_domain_blocks(user, List.delete(user.domain_blocks, domain_blocked))
2365   end
2366
2367   @spec add_to_block(User.t(), User.t()) ::
2368           {:ok, UserRelationship.t()} | {:error, Ecto.Changeset.t()}
2369   defp add_to_block(%User{} = user, %User{} = blocked) do
2370     UserRelationship.create_block(user, blocked)
2371   end
2372
2373   @spec add_to_block(User.t(), User.t()) ::
2374           {:ok, UserRelationship.t()} | {:ok, nil} | {:error, Ecto.Changeset.t()}
2375   defp remove_from_block(%User{} = user, %User{} = blocked) do
2376     UserRelationship.delete_block(user, blocked)
2377   end
2378
2379   def set_invisible(user, invisible) do
2380     params = %{invisible: invisible}
2381
2382     user
2383     |> cast(params, [:invisible])
2384     |> validate_required([:invisible])
2385     |> update_and_set_cache()
2386   end
2387
2388   def sanitize_html(%User{} = user) do
2389     sanitize_html(user, nil)
2390   end
2391
2392   # User data that mastodon isn't filtering (treated as plaintext):
2393   # - field name
2394   # - display name
2395   def sanitize_html(%User{} = user, filter) do
2396     fields =
2397       Enum.map(user.fields, fn %{"name" => name, "value" => value} ->
2398         %{
2399           "name" => name,
2400           "value" => HTML.filter_tags(value, Pleroma.HTML.Scrubber.LinksOnly)
2401         }
2402       end)
2403
2404     user
2405     |> Map.put(:bio, HTML.filter_tags(user.bio, filter))
2406     |> Map.put(:fields, fields)
2407   end
2408 end