git.squeep.com Git - akkoma/blob - lib/pleroma/user.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2018 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.User do
   6   use Ecto.Schema
   7
   8   import Ecto.{Changeset, Query}
   9   alias Pleroma.{Repo, User, Object, Web, Activity, Notification}
  10   alias Comeonin.Pbkdf2
  11   alias Pleroma.Formatter
  12   alias Pleroma.Web.CommonAPI.Utils, as: CommonUtils
  13   alias Pleroma.Web.{OStatus, Websub, OAuth}
  14   alias Pleroma.Web.ActivityPub.{Utils, ActivityPub}
  15
  16   require Logger
  17
  18   @type t :: %__MODULE__{}
  19
  20   @email_regex ~r/^[a-zA-Z0-9.!#$%&'*+\/=?^_`{|}~-]+@[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?(?:\.[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?)*$/
  21
  22   @strict_local_nickname_regex ~r/^[a-zA-Z\d]+$/
  23   @extended_local_nickname_regex ~r/^[a-zA-Z\d_-]+$/
  24
  25   schema "users" do
  26     field(:bio, :string)
  27     field(:email, :string)
  28     field(:name, :string)
  29     field(:nickname, :string)
  30     field(:password_hash, :string)
  31     field(:password, :string, virtual: true)
  32     field(:password_confirmation, :string, virtual: true)
  33     field(:following, {:array, :string}, default: [])
  34     field(:ap_id, :string)
  35     field(:avatar, :map)
  36     field(:local, :boolean, default: true)
  37     field(:follower_address, :string)
  38     field(:search_distance, :float, virtual: true)
  39     field(:tags, {:array, :string}, default: [])
  40     field(:last_refreshed_at, :naive_datetime)
  41     has_many(:notifications, Notification)
  42     embeds_one(:info, Pleroma.User.Info)
  43
  44     timestamps()
  45   end
  46
  47   def auth_active?(%User{} = user) do
  48     (user.info && !user.info.confirmation_pending) ||
  49       !Pleroma.Config.get([:instance, :account_activation_required])
  50   end
  51
  52   def superuser?(%User{} = user), do: user.info && User.Info.superuser?(user.info)
  53
  54   def avatar_url(user) do
  55     case user.avatar do
  56       %{"url" => [%{"href" => href} | _]} -> href
  57       _ -> "#{Web.base_url()}/images/avi.png"
  58     end
  59   end
  60
  61   def banner_url(user) do
  62     case user.info.banner do
  63       %{"url" => [%{"href" => href} | _]} -> href
  64       _ -> "#{Web.base_url()}/images/banner.png"
  65     end
  66   end
  67
  68   def profile_url(%User{info: %{source_data: %{"url" => url}}}), do: url
  69   def profile_url(%User{ap_id: ap_id}), do: ap_id
  70   def profile_url(_), do: nil
  71
  72   def ap_id(%User{nickname: nickname}) do
  73     "#{Web.base_url()}/users/#{nickname}"
  74   end
  75
  76   def ap_followers(%User{} = user) do
  77     "#{ap_id(user)}/followers"
  78   end
  79
  80   def follow_changeset(struct, params \\ %{}) do
  81     struct
  82     |> cast(params, [:following])
  83     |> validate_required([:following])
  84   end
  85
  86   def user_info(%User{} = user) do
  87     oneself = if user.local, do: 1, else: 0
  88
  89     %{
  90       following_count: length(user.following) - oneself,
  91       note_count: user.info.note_count,
  92       follower_count: user.info.follower_count,
  93       locked: user.info.locked,
  94       confirmation_pending: user.info.confirmation_pending,
  95       default_scope: user.info.default_scope
  96     }
  97   end
  98
  99   def remote_user_creation(params) do
 100     params =
 101       params
 102       |> Map.put(:info, params[:info] || %{})
 103
 104     info_cng = User.Info.remote_user_creation(%User.Info{}, params[:info])
 105
 106     changes =
 107       %User{}
 108       |> cast(params, [:bio, :name, :ap_id, :nickname, :avatar])
 109       |> validate_required([:name, :ap_id])
 110       |> unique_constraint(:nickname)
 111       |> validate_format(:nickname, @email_regex)
 112       |> validate_length(:bio, max: 5000)
 113       |> validate_length(:name, max: 100)
 114       |> put_change(:local, false)
 115       |> put_embed(:info, info_cng)
 116
 117     if changes.valid? do
 118       case info_cng.changes[:source_data] do
 119         %{"followers" => followers} ->
 120           changes
 121           |> put_change(:follower_address, followers)
 122
 123         _ ->
 124           followers = User.ap_followers(%User{nickname: changes.changes[:nickname]})
 125
 126           changes
 127           |> put_change(:follower_address, followers)
 128       end
 129     else
 130       changes
 131     end
 132   end
 133
 134   def update_changeset(struct, params \\ %{}) do
 135     struct
 136     |> cast(params, [:bio, :name, :avatar])
 137     |> unique_constraint(:nickname)
 138     |> validate_format(:nickname, local_nickname_regex())
 139     |> validate_length(:bio, max: 5000)
 140     |> validate_length(:name, min: 1, max: 100)
 141   end
 142
 143   def upgrade_changeset(struct, params \\ %{}) do
 144     params =
 145       params
 146       |> Map.put(:last_refreshed_at, NaiveDateTime.utc_now())
 147
 148     info_cng =
 149       struct.info
 150       |> User.Info.user_upgrade(params[:info])
 151
 152     struct
 153     |> cast(params, [:bio, :name, :follower_address, :avatar, :last_refreshed_at])
 154     |> unique_constraint(:nickname)
 155     |> validate_format(:nickname, local_nickname_regex())
 156     |> validate_length(:bio, max: 5000)
 157     |> validate_length(:name, max: 100)
 158     |> put_embed(:info, info_cng)
 159   end
 160
 161   def password_update_changeset(struct, params) do
 162     changeset =
 163       struct
 164       |> cast(params, [:password, :password_confirmation])
 165       |> validate_required([:password, :password_confirmation])
 166       |> validate_confirmation(:password)
 167
 168     OAuth.Token.delete_user_tokens(struct)
 169     OAuth.Authorization.delete_user_authorizations(struct)
 170
 171     if changeset.valid? do
 172       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 173
 174       changeset
 175       |> put_change(:password_hash, hashed)
 176     else
 177       changeset
 178     end
 179   end
 180
 181   def reset_password(user, data) do
 182     update_and_set_cache(password_update_changeset(user, data))
 183   end
 184
 185   def register_changeset(struct, params \\ %{}, opts \\ []) do
 186     confirmation_status =
 187       if opts[:confirmed] || !Pleroma.Config.get([:instance, :account_activation_required]) do
 188         :confirmed
 189       else
 190         :unconfirmed
 191       end
 192
 193     info_change = User.Info.confirmation_changeset(%User.Info{}, confirmation_status)
 194
 195     changeset =
 196       struct
 197       |> cast(params, [:bio, :email, :name, :nickname, :password, :password_confirmation])
 198       |> validate_required([:email, :name, :nickname, :password, :password_confirmation])
 199       |> validate_confirmation(:password)
 200       |> unique_constraint(:email)
 201       |> unique_constraint(:nickname)
 202       |> validate_exclusion(:nickname, Pleroma.Config.get([Pleroma.User, :restricted_nicknames]))
 203       |> validate_format(:nickname, local_nickname_regex())
 204       |> validate_format(:email, @email_regex)
 205       |> validate_length(:bio, max: 1000)
 206       |> validate_length(:name, min: 1, max: 100)
 207       |> put_change(:info, info_change)
 208
 209     if changeset.valid? do
 210       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 211       ap_id = User.ap_id(%User{nickname: changeset.changes[:nickname]})
 212       followers = User.ap_followers(%User{nickname: changeset.changes[:nickname]})
 213
 214       changeset
 215       |> put_change(:password_hash, hashed)
 216       |> put_change(:ap_id, ap_id)
 217       |> put_change(:following, [followers])
 218       |> put_change(:follower_address, followers)
 219     else
 220       changeset
 221     end
 222   end
 223
 224   @doc "Inserts provided changeset, performs post-registration actions (confirmation email sending etc.)"
 225   def register(%Ecto.Changeset{} = changeset) do
 226     with {:ok, user} <- Repo.insert(changeset),
 227          {:ok, _} = try_send_confirmation_email(user) do
 228       {:ok, user}
 229     end
 230   end
 231
 232   def try_send_confirmation_email(%User{} = user) do
 233     if user.info.confirmation_pending &&
 234          Pleroma.Config.get([:instance, :account_activation_required]) do
 235       user
 236       |> Pleroma.UserEmail.account_confirmation_email()
 237       |> Pleroma.Mailer.deliver()
 238     else
 239       {:ok, :noop}
 240     end
 241   end
 242
 243   def needs_update?(%User{local: true}), do: false
 244
 245   def needs_update?(%User{local: false, last_refreshed_at: nil}), do: true
 246
 247   def needs_update?(%User{local: false} = user) do
 248     NaiveDateTime.diff(NaiveDateTime.utc_now(), user.last_refreshed_at) >= 86400
 249   end
 250
 251   def needs_update?(_), do: true
 252
 253   def maybe_direct_follow(%User{} = follower, %User{local: true, info: %{locked: true}}) do
 254     {:ok, follower}
 255   end
 256
 257   def maybe_direct_follow(%User{} = follower, %User{local: true} = followed) do
 258     follow(follower, followed)
 259   end
 260
 261   def maybe_direct_follow(%User{} = follower, %User{} = followed) do
 262     if not User.ap_enabled?(followed) do
 263       follow(follower, followed)
 264     else
 265       {:ok, follower}
 266     end
 267   end
 268
 269   def maybe_follow(%User{} = follower, %User{info: _info} = followed) do
 270     if not following?(follower, followed) do
 271       follow(follower, followed)
 272     else
 273       {:ok, follower}
 274     end
 275   end
 276
 277   def follow(%User{} = follower, %User{info: info} = followed) do
 278     user_config = Application.get_env(:pleroma, :user)
 279     deny_follow_blocked = Keyword.get(user_config, :deny_follow_blocked)
 280
 281     ap_followers = followed.follower_address
 282
 283     cond do
 284       following?(follower, followed) or info.deactivated ->
 285         {:error, "Could not follow user: #{followed.nickname} is already on your list."}
 286
 287       deny_follow_blocked and blocks?(followed, follower) ->
 288         {:error, "Could not follow user: #{followed.nickname} blocked you."}
 289
 290       true ->
 291         if !followed.local && follower.local && !ap_enabled?(followed) do
 292           Websub.subscribe(follower, followed)
 293         end
 294
 295         following =
 296           [ap_followers | follower.following]
 297           |> Enum.uniq()
 298
 299         follower =
 300           follower
 301           |> follow_changeset(%{following: following})
 302           |> update_and_set_cache
 303
 304         {:ok, _} = update_follower_count(followed)
 305
 306         follower
 307     end
 308   end
 309
 310   def unfollow(%User{} = follower, %User{} = followed) do
 311     ap_followers = followed.follower_address
 312
 313     if following?(follower, followed) and follower.ap_id != followed.ap_id do
 314       following =
 315         follower.following
 316         |> List.delete(ap_followers)
 317
 318       {:ok, follower} =
 319         follower
 320         |> follow_changeset(%{following: following})
 321         |> update_and_set_cache
 322
 323       {:ok, followed} = update_follower_count(followed)
 324
 325       {:ok, follower, Utils.fetch_latest_follow(follower, followed)}
 326     else
 327       {:error, "Not subscribed!"}
 328     end
 329   end
 330
 331   @spec following?(User.t(), User.t()) :: boolean
 332   def following?(%User{} = follower, %User{} = followed) do
 333     Enum.member?(follower.following, followed.follower_address)
 334   end
 335
 336   def follow_import(%User{} = follower, followed_identifiers)
 337       when is_list(followed_identifiers) do
 338     Enum.map(
 339       followed_identifiers,
 340       fn followed_identifier ->
 341         with %User{} = followed <- get_or_fetch(followed_identifier),
 342              {:ok, follower} <- maybe_direct_follow(follower, followed),
 343              {:ok, _} <- ActivityPub.follow(follower, followed) do
 344           followed
 345         else
 346           err ->
 347             Logger.debug("follow_import failed for #{followed_identifier} with: #{inspect(err)}")
 348             err
 349         end
 350       end
 351     )
 352   end
 353
 354   def locked?(%User{} = user) do
 355     user.info.locked || false
 356   end
 357
 358   def get_by_ap_id(ap_id) do
 359     Repo.get_by(User, ap_id: ap_id)
 360   end
 361
 362   def update_and_set_cache(changeset) do
 363     with {:ok, user} <- Repo.update(changeset) do
 364       Cachex.put(:user_cache, "ap_id:#{user.ap_id}", user)
 365       Cachex.put(:user_cache, "nickname:#{user.nickname}", user)
 366       Cachex.put(:user_cache, "user_info:#{user.id}", user_info(user))
 367       {:ok, user}
 368     else
 369       e -> e
 370     end
 371   end
 372
 373   def invalidate_cache(user) do
 374     Cachex.del(:user_cache, "ap_id:#{user.ap_id}")
 375     Cachex.del(:user_cache, "nickname:#{user.nickname}")
 376     Cachex.del(:user_cache, "user_info:#{user.id}")
 377   end
 378
 379   def get_cached_by_ap_id(ap_id) do
 380     key = "ap_id:#{ap_id}"
 381     Cachex.fetch!(:user_cache, key, fn _ -> get_by_ap_id(ap_id) end)
 382   end
 383
 384   def get_cached_by_nickname(nickname) do
 385     key = "nickname:#{nickname}"
 386     Cachex.fetch!(:user_cache, key, fn _ -> get_or_fetch_by_nickname(nickname) end)
 387   end
 388
 389   def get_by_nickname(nickname) do
 390     Repo.get_by(User, nickname: nickname)
 391   end
 392
 393   def get_by_nickname_or_email(nickname_or_email) do
 394     case user = Repo.get_by(User, nickname: nickname_or_email) do
 395       %User{} -> user
 396       nil -> Repo.get_by(User, email: nickname_or_email)
 397     end
 398   end
 399
 400   def get_cached_user_info(user) do
 401     key = "user_info:#{user.id}"
 402     Cachex.fetch!(:user_cache, key, fn _ -> user_info(user) end)
 403   end
 404
 405   def fetch_by_nickname(nickname) do
 406     ap_try = ActivityPub.make_user_from_nickname(nickname)
 407
 408     case ap_try do
 409       {:ok, user} -> {:ok, user}
 410       _ -> OStatus.make_user(nickname)
 411     end
 412   end
 413
 414   def get_or_fetch_by_nickname(nickname) do
 415     with %User{} = user <- get_by_nickname(nickname) do
 416       user
 417     else
 418       _e ->
 419         with [_nick, _domain] <- String.split(nickname, "@"),
 420              {:ok, user} <- fetch_by_nickname(nickname) do
 421           user
 422         else
 423           _e -> nil
 424         end
 425     end
 426   end
 427
 428   def get_followers_query(%User{id: id, follower_address: follower_address}) do
 429     from(
 430       u in User,
 431       where: fragment("? <@ ?", ^[follower_address], u.following),
 432       where: u.id != ^id
 433     )
 434   end
 435
 436   def get_followers(user) do
 437     q = get_followers_query(user)
 438
 439     {:ok, Repo.all(q)}
 440   end
 441
 442   def get_friends_query(%User{id: id, following: following}) do
 443     from(
 444       u in User,
 445       where: u.follower_address in ^following,
 446       where: u.id != ^id
 447     )
 448   end
 449
 450   def get_friends(user) do
 451     q = get_friends_query(user)
 452
 453     {:ok, Repo.all(q)}
 454   end
 455
 456   def get_follow_requests_query(%User{} = user) do
 457     from(
 458       a in Activity,
 459       where:
 460         fragment(
 461           "? ->> 'type' = 'Follow'",
 462           a.data
 463         ),
 464       where:
 465         fragment(
 466           "? ->> 'state' = 'pending'",
 467           a.data
 468         ),
 469       where:
 470         fragment(
 471           "? @> ?",
 472           a.data,
 473           ^%{"object" => user.ap_id}
 474         )
 475     )
 476   end
 477
 478   def get_follow_requests(%User{} = user) do
 479     q = get_follow_requests_query(user)
 480     reqs = Repo.all(q)
 481
 482     users =
 483       Enum.map(reqs, fn req -> req.actor end)
 484       |> Enum.uniq()
 485       |> Enum.map(fn ap_id -> get_by_ap_id(ap_id) end)
 486       |> Enum.filter(fn u -> !following?(u, user) end)
 487
 488     {:ok, users}
 489   end
 490
 491   def increase_note_count(%User{} = user) do
 492     info_cng = User.Info.add_to_note_count(user.info, 1)
 493
 494     cng =
 495       change(user)
 496       |> put_embed(:info, info_cng)
 497
 498     update_and_set_cache(cng)
 499   end
 500
 501   def decrease_note_count(%User{} = user) do
 502     info_cng = User.Info.add_to_note_count(user.info, -1)
 503
 504     cng =
 505       change(user)
 506       |> put_embed(:info, info_cng)
 507
 508     update_and_set_cache(cng)
 509   end
 510
 511   def update_note_count(%User{} = user) do
 512     note_count_query =
 513       from(
 514         a in Object,
 515         where: fragment("?->>'actor' = ? and ?->>'type' = 'Note'", a.data, ^user.ap_id, a.data),
 516         select: count(a.id)
 517       )
 518
 519     note_count = Repo.one(note_count_query)
 520
 521     info_cng = User.Info.set_note_count(user.info, note_count)
 522
 523     cng =
 524       change(user)
 525       |> put_embed(:info, info_cng)
 526
 527     update_and_set_cache(cng)
 528   end
 529
 530   def update_follower_count(%User{} = user) do
 531     follower_count_query =
 532       from(
 533         u in User,
 534         where: ^user.follower_address in u.following,
 535         where: u.id != ^user.id,
 536         select: count(u.id)
 537       )
 538
 539     follower_count = Repo.one(follower_count_query)
 540
 541     info_cng =
 542       user.info
 543       |> User.Info.set_follower_count(follower_count)
 544
 545     cng =
 546       change(user)
 547       |> put_embed(:info, info_cng)
 548
 549     update_and_set_cache(cng)
 550   end
 551
 552   def get_users_from_set_query(ap_ids, false) do
 553     from(
 554       u in User,
 555       where: u.ap_id in ^ap_ids
 556     )
 557   end
 558
 559   def get_users_from_set_query(ap_ids, true) do
 560     query = get_users_from_set_query(ap_ids, false)
 561
 562     from(
 563       u in query,
 564       where: u.local == true
 565     )
 566   end
 567
 568   def get_users_from_set(ap_ids, local_only \\ true) do
 569     get_users_from_set_query(ap_ids, local_only)
 570     |> Repo.all()
 571   end
 572
 573   def get_recipients_from_activity(%Activity{recipients: to}) do
 574     query =
 575       from(
 576         u in User,
 577         where: u.ap_id in ^to,
 578         or_where: fragment("? && ?", u.following, ^to)
 579       )
 580
 581     query = from(u in query, where: u.local == true)
 582
 583     Repo.all(query)
 584   end
 585
 586   def search(query, resolve \\ false) do
 587     # strip the beginning @ off if there is a query
 588     query = String.trim_leading(query, "@")
 589
 590     if resolve do
 591       User.get_or_fetch_by_nickname(query)
 592     end
 593
 594     inner =
 595       from(
 596         u in User,
 597         select_merge: %{
 598           search_distance:
 599             fragment(
 600               "? <-> (? || ?)",
 601               ^query,
 602               u.nickname,
 603               u.name
 604             )
 605         },
 606         where: not is_nil(u.nickname)
 607       )
 608
 609     q =
 610       from(
 611         s in subquery(inner),
 612         order_by: s.search_distance,
 613         limit: 20
 614       )
 615
 616     Repo.all(q)
 617   end
 618
 619   def blocks_import(%User{} = blocker, blocked_identifiers) when is_list(blocked_identifiers) do
 620     Enum.map(
 621       blocked_identifiers,
 622       fn blocked_identifier ->
 623         with %User{} = blocked <- get_or_fetch(blocked_identifier),
 624              {:ok, blocker} <- block(blocker, blocked),
 625              {:ok, _} <- ActivityPub.block(blocker, blocked) do
 626           blocked
 627         else
 628           err ->
 629             Logger.debug("blocks_import failed for #{blocked_identifier} with: #{inspect(err)}")
 630             err
 631         end
 632       end
 633     )
 634   end
 635
 636   def block(blocker, %User{ap_id: ap_id} = blocked) do
 637     # sever any follow relationships to prevent leaks per activitypub (Pleroma issue #213)
 638     blocker =
 639       if following?(blocker, blocked) do
 640         {:ok, blocker, _} = unfollow(blocker, blocked)
 641         blocker
 642       else
 643         blocker
 644       end
 645
 646     if following?(blocked, blocker) do
 647       unfollow(blocked, blocker)
 648     end
 649
 650     info_cng =
 651       blocker.info
 652       |> User.Info.add_to_block(ap_id)
 653
 654     cng =
 655       change(blocker)
 656       |> put_embed(:info, info_cng)
 657
 658     update_and_set_cache(cng)
 659   end
 660
 661   # helper to handle the block given only an actor's AP id
 662   def block(blocker, %{ap_id: ap_id}) do
 663     block(blocker, User.get_by_ap_id(ap_id))
 664   end
 665
 666   def unblock(blocker, %{ap_id: ap_id}) do
 667     info_cng =
 668       blocker.info
 669       |> User.Info.remove_from_block(ap_id)
 670
 671     cng =
 672       change(blocker)
 673       |> put_embed(:info, info_cng)
 674
 675     update_and_set_cache(cng)
 676   end
 677
 678   def blocks?(user, %{ap_id: ap_id}) do
 679     blocks = user.info.blocks
 680     domain_blocks = user.info.domain_blocks
 681     %{host: host} = URI.parse(ap_id)
 682
 683     Enum.member?(blocks, ap_id) ||
 684       Enum.any?(domain_blocks, fn domain ->
 685         host == domain
 686       end)
 687   end
 688
 689   def blocked_users(user),
 690     do: Repo.all(from(u in User, where: u.ap_id in ^user.info.blocks))
 691
 692   def block_domain(user, domain) do
 693     info_cng =
 694       user.info
 695       |> User.Info.add_to_domain_block(domain)
 696
 697     cng =
 698       change(user)
 699       |> put_embed(:info, info_cng)
 700
 701     update_and_set_cache(cng)
 702   end
 703
 704   def unblock_domain(user, domain) do
 705     info_cng =
 706       user.info
 707       |> User.Info.remove_from_domain_block(domain)
 708
 709     cng =
 710       change(user)
 711       |> put_embed(:info, info_cng)
 712
 713     update_and_set_cache(cng)
 714   end
 715
 716   def local_user_query() do
 717     from(
 718       u in User,
 719       where: u.local == true,
 720       where: not is_nil(u.nickname)
 721     )
 722   end
 723
 724   def moderator_user_query() do
 725     from(
 726       u in User,
 727       where: u.local == true,
 728       where: fragment("?->'is_moderator' @> 'true'", u.info)
 729     )
 730   end
 731
 732   def deactivate(%User{} = user, status \\ true) do
 733     info_cng = User.Info.set_activation_status(user.info, status)
 734
 735     cng =
 736       change(user)
 737       |> put_embed(:info, info_cng)
 738
 739     update_and_set_cache(cng)
 740   end
 741
 742   def delete(%User{} = user) do
 743     {:ok, user} = User.deactivate(user)
 744
 745     # Remove all relationships
 746     {:ok, followers} = User.get_followers(user)
 747
 748     followers
 749     |> Enum.each(fn follower -> User.unfollow(follower, user) end)
 750
 751     {:ok, friends} = User.get_friends(user)
 752
 753     friends
 754     |> Enum.each(fn followed -> User.unfollow(user, followed) end)
 755
 756     query = from(a in Activity, where: a.actor == ^user.ap_id)
 757
 758     Repo.all(query)
 759     |> Enum.each(fn activity ->
 760       case activity.data["type"] do
 761         "Create" ->
 762           ActivityPub.delete(Object.normalize(activity.data["object"]))
 763
 764         # TODO: Do something with likes, follows, repeats.
 765         _ ->
 766           "Doing nothing"
 767       end
 768     end)
 769
 770     {:ok, user}
 771   end
 772
 773   def html_filter_policy(%User{info: %{no_rich_text: true}}) do
 774     Pleroma.HTML.Scrubber.TwitterText
 775   end
 776
 777   def html_filter_policy(_), do: nil
 778
 779   def get_or_fetch_by_ap_id(ap_id) do
 780     user = get_by_ap_id(ap_id)
 781
 782     if !is_nil(user) and !User.needs_update?(user) do
 783       user
 784     else
 785       ap_try = ActivityPub.make_user_from_ap_id(ap_id)
 786
 787       case ap_try do
 788         {:ok, user} ->
 789           user
 790
 791         _ ->
 792           case OStatus.make_user(ap_id) do
 793             {:ok, user} -> user
 794             _ -> {:error, "Could not fetch by AP id"}
 795           end
 796       end
 797     end
 798   end
 799
 800   def get_or_create_instance_user do
 801     relay_uri = "#{Pleroma.Web.Endpoint.url()}/relay"
 802
 803     if user = get_by_ap_id(relay_uri) do
 804       user
 805     else
 806       changes =
 807         %User{info: %User.Info{}}
 808         |> cast(%{}, [:ap_id, :nickname, :local])
 809         |> put_change(:ap_id, relay_uri)
 810         |> put_change(:nickname, nil)
 811         |> put_change(:local, true)
 812         |> put_change(:follower_address, relay_uri <> "/followers")
 813
 814       {:ok, user} = Repo.insert(changes)
 815       user
 816     end
 817   end
 818
 819   # AP style
 820   def public_key_from_info(%{
 821         source_data: %{"publicKey" => %{"publicKeyPem" => public_key_pem}}
 822       }) do
 823     key =
 824       public_key_pem
 825       |> :public_key.pem_decode()
 826       |> hd()
 827       |> :public_key.pem_entry_decode()
 828
 829     {:ok, key}
 830   end
 831
 832   # OStatus Magic Key
 833   def public_key_from_info(%{magic_key: magic_key}) do
 834     {:ok, Pleroma.Web.Salmon.decode_key(magic_key)}
 835   end
 836
 837   def get_public_key_for_ap_id(ap_id) do
 838     with %User{} = user <- get_or_fetch_by_ap_id(ap_id),
 839          {:ok, public_key} <- public_key_from_info(user.info) do
 840       {:ok, public_key}
 841     else
 842       _ -> :error
 843     end
 844   end
 845
 846   defp blank?(""), do: nil
 847   defp blank?(n), do: n
 848
 849   def insert_or_update_user(data) do
 850     data =
 851       data
 852       |> Map.put(:name, blank?(data[:name]) || data[:nickname])
 853
 854     cs = User.remote_user_creation(data)
 855
 856     Repo.insert(cs, on_conflict: :replace_all, conflict_target: :nickname)
 857   end
 858
 859   def ap_enabled?(%User{local: true}), do: true
 860   def ap_enabled?(%User{info: info}), do: info.ap_enabled
 861   def ap_enabled?(_), do: false
 862
 863   @doc "Gets or fetch a user by uri or nickname."
 864   @spec get_or_fetch(String.t()) :: User.t()
 865   def get_or_fetch("http" <> _host = uri), do: get_or_fetch_by_ap_id(uri)
 866   def get_or_fetch(nickname), do: get_or_fetch_by_nickname(nickname)
 867
 868   # wait a period of time and return newest version of the User structs
 869   # this is because we have synchronous follow APIs and need to simulate them
 870   # with an async handshake
 871   def wait_and_refresh(_, %User{local: true} = a, %User{local: true} = b) do
 872     with %User{} = a <- Repo.get(User, a.id),
 873          %User{} = b <- Repo.get(User, b.id) do
 874       {:ok, a, b}
 875     else
 876       _e ->
 877         :error
 878     end
 879   end
 880
 881   def wait_and_refresh(timeout, %User{} = a, %User{} = b) do
 882     with :ok <- :timer.sleep(timeout),
 883          %User{} = a <- Repo.get(User, a.id),
 884          %User{} = b <- Repo.get(User, b.id) do
 885       {:ok, a, b}
 886     else
 887       _e ->
 888         :error
 889     end
 890   end
 891
 892   def parse_bio(bio, user \\ %User{info: %{source_data: %{}}})
 893   def parse_bio(nil, _user), do: ""
 894   def parse_bio(bio, _user) when bio == "", do: bio
 895
 896   def parse_bio(bio, user) do
 897     mentions = Formatter.parse_mentions(bio)
 898     tags = Formatter.parse_tags(bio)
 899
 900     emoji =
 901       (user.info.source_data["tag"] || [])
 902       |> Enum.filter(fn %{"type" => t} -> t == "Emoji" end)
 903       |> Enum.map(fn %{"icon" => %{"url" => url}, "name" => name} ->
 904         {String.trim(name, ":"), url}
 905       end)
 906
 907     bio
 908     |> CommonUtils.format_input(mentions, tags, "text/plain")
 909     |> Formatter.emojify(emoji)
 910   end
 911
 912   def tag(user_identifiers, tags) when is_list(user_identifiers) do
 913     Repo.transaction(fn ->
 914       for user_identifier <- user_identifiers, do: tag(user_identifier, tags)
 915     end)
 916   end
 917
 918   def tag(nickname, tags) when is_binary(nickname),
 919     do: tag(User.get_by_nickname(nickname), tags)
 920
 921   def tag(%User{} = user, tags),
 922     do: update_tags(user, Enum.uniq((user.tags || []) ++ normalize_tags(tags)))
 923
 924   def untag(user_identifiers, tags) when is_list(user_identifiers) do
 925     Repo.transaction(fn ->
 926       for user_identifier <- user_identifiers, do: untag(user_identifier, tags)
 927     end)
 928   end
 929
 930   def untag(nickname, tags) when is_binary(nickname),
 931     do: untag(User.get_by_nickname(nickname), tags)
 932
 933   def untag(%User{} = user, tags),
 934     do: update_tags(user, (user.tags || []) -- normalize_tags(tags))
 935
 936   defp update_tags(%User{} = user, new_tags) do
 937     {:ok, updated_user} =
 938       user
 939       |> change(%{tags: new_tags})
 940       |> Repo.update()
 941
 942     updated_user
 943   end
 944
 945   defp normalize_tags(tags) do
 946     [tags]
 947     |> List.flatten()
 948     |> Enum.map(&String.downcase(&1))
 949   end
 950
 951   defp local_nickname_regex() do
 952     if Pleroma.Config.get([:instance, :extended_nickname_format]) do
 953       @extended_local_nickname_regex
 954     else
 955       @strict_local_nickname_regex
 956     end
 957   end
 958 end