git.squeep.com Git - akkoma/blob - lib/pleroma/user.ex

   1 defmodule Pleroma.User do
   2   use Ecto.Schema
   3
   4   import Ecto.{Changeset, Query}
   5   alias Ecto.Multi
   6   alias Pleroma.{Repo, User, Object, Web, Activity, Notification}
   7   alias Comeonin.Pbkdf2
   8   alias Pleroma.Formatter
   9   alias Pleroma.Web.CommonAPI.Utils, as: CommonUtils
  10   alias Pleroma.Web.{OStatus, Websub, OAuth}
  11   alias Pleroma.Web.ActivityPub.{Utils, ActivityPub}
  12
  13   schema "users" do
  14     field(:bio, :string)
  15     field(:email, :string)
  16     field(:name, :string)
  17     field(:nickname, :string)
  18     field(:password_hash, :string)
  19     field(:password, :string, virtual: true)
  20     field(:password_confirmation, :string, virtual: true)
  21     field(:following, {:array, :string}, default: [])
  22     field(:ap_id, :string)
  23     field(:avatar, :map)
  24     field(:local, :boolean, default: true)
  25     field(:follower_address, :string)
  26     field(:search_distance, :float, virtual: true)
  27     field(:tags, {:array, :string}, default: [])
  28     field(:last_refreshed_at, :naive_datetime)
  29     has_many(:notifications, Notification)
  30     embeds_one(:info, Pleroma.User.Info)
  31
  32     timestamps()
  33   end
  34
  35   def avatar_url(user) do
  36     case user.avatar do
  37       %{"url" => [%{"href" => href} | _]} -> href
  38       _ -> "#{Web.base_url()}/images/avi.png"
  39     end
  40   end
  41
  42   def banner_url(user) do
  43     case user.info.banner do
  44       %{"url" => [%{"href" => href} | _]} -> href
  45       _ -> "#{Web.base_url()}/images/banner.png"
  46     end
  47   end
  48
  49   def profile_url(%User{info: %{source_data: %{"url" => url}}}), do: url
  50   def profile_url(%User{ap_id: ap_id}), do: ap_id
  51   def profile_url(_), do: nil
  52
  53   def ap_id(%User{nickname: nickname}) do
  54     "#{Web.base_url()}/users/#{nickname}"
  55   end
  56
  57   def ap_followers(%User{} = user) do
  58     "#{ap_id(user)}/followers"
  59   end
  60
  61   def follow_changeset(struct, params \\ %{}) do
  62     struct
  63     |> cast(params, [:following])
  64     |> validate_required([:following])
  65   end
  66
  67   def info_changeset(struct, params \\ %{}) do
  68     raise "NOT VALID ANYMORE"
  69   end
  70
  71   def user_info(%User{} = user) do
  72     oneself = if user.local, do: 1, else: 0
  73
  74     %{
  75       following_count: length(user.following) - oneself,
  76       note_count: user.info.note_count,
  77       follower_count: user.info.follower_count,
  78       locked: user.info.locked,
  79       default_scope: user.info.default_scope
  80     }
  81   end
  82
  83   @email_regex ~r/^[a-zA-Z0-9.!#$%&'*+\/=?^_`{|}~-]+@[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?(?:\.[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?)*$/
  84   def remote_user_creation(params) do
  85     params =
  86       params
  87       |> Map.put(:info, params[:info] || %{})
  88
  89     info_cng = User.Info.remote_user_creation(%User.Info{}, params[:info])
  90
  91     changes =
  92       %User{}
  93       |> cast(params, [:bio, :name, :ap_id, :nickname, :avatar])
  94       |> validate_required([:name, :ap_id])
  95       |> unique_constraint(:nickname)
  96       |> validate_format(:nickname, @email_regex)
  97       |> validate_length(:bio, max: 5000)
  98       |> validate_length(:name, max: 100)
  99       |> put_change(:local, false)
 100       |> put_embed(:info, info_cng)
 101
 102     if changes.valid? do
 103       case info_cng.changes[:source_data] do
 104         %{"followers" => followers} ->
 105           changes
 106           |> put_change(:follower_address, followers)
 107
 108         _ ->
 109           followers = User.ap_followers(%User{nickname: changes.changes[:nickname]})
 110
 111           changes
 112           |> put_change(:follower_address, followers)
 113       end
 114     else
 115       changes
 116     end
 117   end
 118
 119   def update_changeset(struct, params \\ %{}) do
 120     struct
 121     |> cast(params, [:bio, :name, :avatar])
 122     |> unique_constraint(:nickname)
 123     |> validate_format(:nickname, ~r/^[a-zA-Z\d]+$/)
 124     |> validate_length(:bio, max: 5000)
 125     |> validate_length(:name, min: 1, max: 100)
 126   end
 127
 128   def upgrade_changeset(struct, params \\ %{}) do
 129     params =
 130       params
 131       |> Map.put(:last_refreshed_at, NaiveDateTime.utc_now())
 132
 133     info_cng =
 134       struct.info
 135       |> User.Info.user_upgrade(params[:info])
 136
 137     struct
 138     |> cast(params, [:bio, :name, :follower_address, :avatar, :last_refreshed_at])
 139     |> unique_constraint(:nickname)
 140     |> validate_format(:nickname, ~r/^[a-zA-Z\d]+$/)
 141     |> validate_length(:bio, max: 5000)
 142     |> validate_length(:name, max: 100)
 143     |> put_embed(:info, info_cng)
 144   end
 145
 146   def password_update_changeset(struct, params) do
 147     changeset =
 148       struct
 149       |> cast(params, [:password, :password_confirmation])
 150       |> validate_required([:password, :password_confirmation])
 151       |> validate_confirmation(:password)
 152
 153     OAuth.Token.delete_user_tokens(struct)
 154     OAuth.Authorization.delete_user_authorizations(struct)
 155
 156     if changeset.valid? do
 157       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 158
 159       changeset
 160       |> put_change(:password_hash, hashed)
 161     else
 162       changeset
 163     end
 164   end
 165
 166   def reset_password(user, data) do
 167     update_and_set_cache(password_update_changeset(user, data))
 168   end
 169
 170   def register_changeset(struct, params \\ %{}) do
 171     changeset =
 172       struct
 173       |> cast(params, [:bio, :email, :name, :nickname, :password, :password_confirmation])
 174       |> validate_required([:email, :name, :nickname, :password, :password_confirmation])
 175       |> validate_confirmation(:password)
 176       |> unique_constraint(:email)
 177       |> unique_constraint(:nickname)
 178       |> validate_format(:nickname, ~r/^[a-zA-Z\d]+$/)
 179       |> validate_format(:email, @email_regex)
 180       |> validate_length(:bio, max: 1000)
 181       |> validate_length(:name, min: 1, max: 100)
 182       |> put_change(:info, %Pleroma.User.Info{})
 183
 184     if changeset.valid? do
 185       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 186       ap_id = User.ap_id(%User{nickname: changeset.changes[:nickname]})
 187       followers = User.ap_followers(%User{nickname: changeset.changes[:nickname]})
 188
 189       changeset
 190       |> put_change(:password_hash, hashed)
 191       |> put_change(:ap_id, ap_id)
 192       |> put_change(:following, [followers])
 193       |> put_change(:follower_address, followers)
 194     else
 195       changeset
 196     end
 197   end
 198
 199   def needs_update?(%User{local: true}), do: false
 200
 201   def needs_update?(%User{local: false, last_refreshed_at: nil}), do: true
 202
 203   def needs_update?(%User{local: false} = user) do
 204     NaiveDateTime.diff(NaiveDateTime.utc_now(), user.last_refreshed_at) >= 86400
 205   end
 206
 207   def needs_update?(_), do: true
 208
 209   def maybe_direct_follow(%User{} = follower, %User{local: true, info: %{locked: true}}) do
 210     {:ok, follower}
 211   end
 212
 213   def maybe_direct_follow(%User{} = follower, %User{local: true} = followed) do
 214     follow(follower, followed)
 215   end
 216
 217   def maybe_direct_follow(%User{} = follower, %User{} = followed) do
 218     if !User.ap_enabled?(followed) do
 219       follow(follower, followed)
 220     else
 221       {:ok, follower}
 222     end
 223   end
 224
 225   def maybe_follow(%User{} = follower, %User{info: info} = followed) do
 226     if not following?(follower, followed) do
 227       follow(follower, followed)
 228     else
 229       {:ok, follower}
 230     end
 231   end
 232
 233   def follow(%User{} = follower, %User{info: info} = followed) do
 234     user_config = Application.get_env(:pleroma, :user)
 235     deny_follow_blocked = Keyword.get(user_config, :deny_follow_blocked)
 236
 237     ap_followers = followed.follower_address
 238
 239     cond do
 240       following?(follower, followed) or info.deactivated ->
 241         {:error, "Could not follow user: #{followed.nickname} is already on your list."}
 242
 243       deny_follow_blocked and blocks?(followed, follower) ->
 244         {:error, "Could not follow user: #{followed.nickname} blocked you."}
 245
 246       true ->
 247         if !followed.local && follower.local && !ap_enabled?(followed) do
 248           Websub.subscribe(follower, followed)
 249         end
 250
 251         following =
 252           [ap_followers | follower.following]
 253           |> Enum.uniq()
 254
 255         follower =
 256           follower
 257           |> follow_changeset(%{following: following})
 258           |> update_and_set_cache
 259
 260         {:ok, _} = update_follower_count(followed)
 261
 262         follower
 263     end
 264   end
 265
 266   def unfollow(%User{} = follower, %User{} = followed) do
 267     ap_followers = followed.follower_address
 268
 269     if following?(follower, followed) and follower.ap_id != followed.ap_id do
 270       following =
 271         follower.following
 272         |> List.delete(ap_followers)
 273
 274       {:ok, follower} =
 275         follower
 276         |> follow_changeset(%{following: following})
 277         |> update_and_set_cache
 278
 279       {:ok, followed} = update_follower_count(followed)
 280
 281       {:ok, follower, Utils.fetch_latest_follow(follower, followed)}
 282     else
 283       {:error, "Not subscribed!"}
 284     end
 285   end
 286
 287   def following?(%User{} = follower, %User{} = followed) do
 288     Enum.member?(follower.following, followed.follower_address)
 289   end
 290
 291   def locked?(%User{} = user) do
 292     user.info.locked || false
 293   end
 294
 295   def get_by_ap_id(ap_id) do
 296     Repo.get_by(User, ap_id: ap_id)
 297   end
 298
 299   def update_and_set_cache(changeset) do
 300     with {:ok, user} <- Repo.update(changeset) do
 301       Cachex.put(:user_cache, "ap_id:#{user.ap_id}", user)
 302       Cachex.put(:user_cache, "nickname:#{user.nickname}", user)
 303       Cachex.put(:user_cache, "user_info:#{user.id}", user_info(user))
 304       {:ok, user}
 305     else
 306       e -> e
 307     end
 308   end
 309
 310   def invalidate_cache(user) do
 311     Cachex.del(:user_cache, "ap_id:#{user.ap_id}")
 312     Cachex.del(:user_cache, "nickname:#{user.nickname}")
 313     Cachex.del(:user_cache, "user_info:#{user.id}")
 314   end
 315
 316   def get_cached_by_ap_id(ap_id) do
 317     key = "ap_id:#{ap_id}"
 318     Cachex.fetch!(:user_cache, key, fn _ -> get_by_ap_id(ap_id) end)
 319   end
 320
 321   def get_cached_by_nickname(nickname) do
 322     key = "nickname:#{nickname}"
 323     Cachex.fetch!(:user_cache, key, fn _ -> get_or_fetch_by_nickname(nickname) end)
 324   end
 325
 326   def get_by_nickname(nickname) do
 327     Repo.get_by(User, nickname: nickname)
 328   end
 329
 330   def get_by_nickname_or_email(nickname_or_email) do
 331     case user = Repo.get_by(User, nickname: nickname_or_email) do
 332       %User{} -> user
 333       nil -> Repo.get_by(User, email: nickname_or_email)
 334     end
 335   end
 336
 337   def get_cached_user_info(user) do
 338     key = "user_info:#{user.id}"
 339     Cachex.fetch!(:user_cache, key, fn _ -> user_info(user) end)
 340   end
 341
 342   def fetch_by_nickname(nickname) do
 343     ap_try = ActivityPub.make_user_from_nickname(nickname)
 344
 345     case ap_try do
 346       {:ok, user} -> {:ok, user}
 347       _ -> OStatus.make_user(nickname)
 348     end
 349   end
 350
 351   def get_or_fetch_by_nickname(nickname) do
 352     with %User{} = user <- get_by_nickname(nickname) do
 353       user
 354     else
 355       _e ->
 356         with [_nick, _domain] <- String.split(nickname, "@"),
 357              {:ok, user} <- fetch_by_nickname(nickname) do
 358           user
 359         else
 360           _e -> nil
 361         end
 362     end
 363   end
 364
 365   def get_followers_query(%User{id: id, follower_address: follower_address}) do
 366     from(
 367       u in User,
 368       where: fragment("? <@ ?", ^[follower_address], u.following),
 369       where: u.id != ^id
 370     )
 371   end
 372
 373   def get_followers(user) do
 374     q = get_followers_query(user)
 375
 376     {:ok, Repo.all(q)}
 377   end
 378
 379   def get_friends_query(%User{id: id, following: following}) do
 380     from(
 381       u in User,
 382       where: u.follower_address in ^following,
 383       where: u.id != ^id
 384     )
 385   end
 386
 387   def get_friends(user) do
 388     q = get_friends_query(user)
 389
 390     {:ok, Repo.all(q)}
 391   end
 392
 393   def get_follow_requests_query(%User{} = user) do
 394     from(
 395       a in Activity,
 396       where:
 397         fragment(
 398           "? ->> 'type' = 'Follow'",
 399           a.data
 400         ),
 401       where:
 402         fragment(
 403           "? ->> 'state' = 'pending'",
 404           a.data
 405         ),
 406       where:
 407         fragment(
 408           "? @> ?",
 409           a.data,
 410           ^%{"object" => user.ap_id}
 411         )
 412     )
 413   end
 414
 415   def get_follow_requests(%User{} = user) do
 416     q = get_follow_requests_query(user)
 417     reqs = Repo.all(q)
 418
 419     users =
 420       Enum.map(reqs, fn req -> req.actor end)
 421       |> Enum.uniq()
 422       |> Enum.map(fn ap_id -> get_by_ap_id(ap_id) end)
 423       |> Enum.filter(fn u -> !following?(u, user) end)
 424
 425     {:ok, users}
 426   end
 427
 428   def increase_note_count(%User{} = user) do
 429     info_cng = User.Info.add_to_note_count(user.info, 1)
 430
 431     cng =
 432       change(user)
 433       |> put_embed(:info, info_cng)
 434
 435     update_and_set_cache(cng)
 436   end
 437
 438   def decrease_note_count(%User{} = user) do
 439     info_cng = User.Info.add_to_note_count(user.info, -1)
 440
 441     cng =
 442       change(user)
 443       |> put_embed(:info, info_cng)
 444
 445     update_and_set_cache(cng)
 446   end
 447
 448   def update_note_count(%User{} = user) do
 449     note_count_query =
 450       from(
 451         a in Object,
 452         where: fragment("?->>'actor' = ? and ?->>'type' = 'Note'", a.data, ^user.ap_id, a.data),
 453         select: count(a.id)
 454       )
 455
 456     note_count = Repo.one(note_count_query)
 457
 458     info_cng = User.Info.set_note_count(user.info, note_count)
 459
 460     cng =
 461       change(user)
 462       |> put_embed(:info, info_cng)
 463
 464     update_and_set_cache(cng)
 465   end
 466
 467   def update_follower_count(%User{} = user) do
 468     follower_count_query =
 469       from(
 470         u in User,
 471         where: ^user.follower_address in u.following,
 472         where: u.id != ^user.id,
 473         select: count(u.id)
 474       )
 475
 476     follower_count = Repo.one(follower_count_query)
 477
 478     info_cng =
 479       user.info
 480       |> User.Info.set_follower_count(follower_count)
 481
 482     cng =
 483       change(user)
 484       |> put_embed(:info, info_cng)
 485
 486     update_and_set_cache(cng)
 487   end
 488
 489   def get_users_from_set_query(ap_ids, false) do
 490     from(
 491       u in User,
 492       where: u.ap_id in ^ap_ids
 493     )
 494   end
 495
 496   def get_users_from_set_query(ap_ids, true) do
 497     query = get_users_from_set_query(ap_ids, false)
 498
 499     from(
 500       u in query,
 501       where: u.local == true
 502     )
 503   end
 504
 505   def get_users_from_set(ap_ids, local_only \\ true) do
 506     get_users_from_set_query(ap_ids, local_only)
 507     |> Repo.all()
 508   end
 509
 510   def get_recipients_from_activity(%Activity{recipients: to}) do
 511     query =
 512       from(
 513         u in User,
 514         where: u.ap_id in ^to,
 515         or_where: fragment("? && ?", u.following, ^to)
 516       )
 517
 518     query = from(u in query, where: u.local == true)
 519
 520     Repo.all(query)
 521   end
 522
 523   def search(query, resolve \\ false) do
 524     # strip the beginning @ off if there is a query
 525     query = String.trim_leading(query, "@")
 526
 527     if resolve do
 528       User.get_or_fetch_by_nickname(query)
 529     end
 530
 531     inner =
 532       from(
 533         u in User,
 534         select_merge: %{
 535           search_distance:
 536             fragment(
 537               "? <-> (? || ?)",
 538               ^query,
 539               u.nickname,
 540               u.name
 541             )
 542         },
 543         where: not is_nil(u.nickname)
 544       )
 545
 546     q =
 547       from(
 548         s in subquery(inner),
 549         order_by: s.search_distance,
 550         limit: 20
 551       )
 552
 553     Repo.all(q)
 554   end
 555
 556   def block(blocker, %User{ap_id: ap_id} = blocked) do
 557     # sever any follow relationships to prevent leaks per activitypub (Pleroma issue #213)
 558     blocker =
 559       if following?(blocker, blocked) do
 560         {:ok, blocker, _} = unfollow(blocker, blocked)
 561         blocker
 562       else
 563         blocker
 564       end
 565
 566     if following?(blocked, blocker) do
 567       unfollow(blocked, blocker)
 568     end
 569
 570     info_cng =
 571       blocker.info
 572       |> User.Info.add_to_block(ap_id)
 573
 574     cng =
 575       change(blocker)
 576       |> put_embed(:info, info_cng)
 577
 578     update_and_set_cache(cng)
 579   end
 580
 581   # helper to handle the block given only an actor's AP id
 582   def block(blocker, %{ap_id: ap_id}) do
 583     block(blocker, User.get_by_ap_id(ap_id))
 584   end
 585
 586   def unblock(blocker, %{ap_id: ap_id}) do
 587     info_cng =
 588       blocker.info
 589       |> User.Info.remove_from_block(ap_id)
 590
 591     cng =
 592       change(blocker)
 593       |> put_embed(:info, info_cng)
 594
 595     update_and_set_cache(cng)
 596   end
 597
 598   def blocks?(user, %{ap_id: ap_id}) do
 599     blocks = user.info.blocks
 600     domain_blocks = user.info.domain_blocks
 601     %{host: host} = URI.parse(ap_id)
 602
 603     Enum.member?(blocks, ap_id) ||
 604       Enum.any?(domain_blocks, fn domain ->
 605         host == domain
 606       end)
 607   end
 608
 609   def block_domain(user, domain) do
 610     info_cng =
 611       user.info
 612       |> User.Info.add_to_domain_block(domain)
 613
 614     cng =
 615       change(user)
 616       |> put_embed(:info, info_cng)
 617
 618     update_and_set_cache(cng)
 619   end
 620
 621   def unblock_domain(user, domain) do
 622     info_cng =
 623       user.info
 624       |> User.Info.remove_from_domain_block(domain)
 625
 626     cng =
 627       change(user)
 628       |> put_embed(:info, info_cng)
 629
 630     update_and_set_cache(cng)
 631   end
 632
 633   def local_user_query() do
 634     from(
 635       u in User,
 636       where: u.local == true,
 637       where: not is_nil(u.nickname)
 638     )
 639   end
 640
 641   def moderator_user_query() do
 642     from(
 643       u in User,
 644       where: u.local == true,
 645       where: fragment("?->'is_moderator' @> 'true'", u.info)
 646     )
 647   end
 648
 649   def deactivate(%User{} = user, status \\ true) do
 650     info_cng = User.Info.set_activation_status(user.info, status)
 651
 652     cng =
 653       change(user)
 654       |> put_embed(:info, info_cng)
 655
 656     update_and_set_cache(cng)
 657   end
 658
 659   def delete(%User{} = user) do
 660     {:ok, user} = User.deactivate(user)
 661
 662     # Remove all relationships
 663     {:ok, followers} = User.get_followers(user)
 664
 665     followers
 666     |> Enum.each(fn follower -> User.unfollow(follower, user) end)
 667
 668     {:ok, friends} = User.get_friends(user)
 669
 670     friends
 671     |> Enum.each(fn followed -> User.unfollow(user, followed) end)
 672
 673     query = from(a in Activity, where: a.actor == ^user.ap_id)
 674
 675     Repo.all(query)
 676     |> Enum.each(fn activity ->
 677       case activity.data["type"] do
 678         "Create" ->
 679           ActivityPub.delete(Object.normalize(activity.data["object"]))
 680
 681         # TODO: Do something with likes, follows, repeats.
 682         _ ->
 683           "Doing nothing"
 684       end
 685     end)
 686
 687     {:ok, user}
 688   end
 689
 690   def html_filter_policy(%User{info: %{no_rich_text: true}}) do
 691     Pleroma.HTML.Scrubber.TwitterText
 692   end
 693
 694   def html_filter_policy(_), do: nil
 695
 696   def get_or_fetch_by_ap_id(ap_id) do
 697     user = get_by_ap_id(ap_id)
 698
 699     if !is_nil(user) and !User.needs_update?(user) do
 700       user
 701     else
 702       ap_try = ActivityPub.make_user_from_ap_id(ap_id)
 703
 704       case ap_try do
 705         {:ok, user} ->
 706           user
 707
 708         _ ->
 709           case OStatus.make_user(ap_id) do
 710             {:ok, user} -> user
 711             _ -> {:error, "Could not fetch by AP id"}
 712           end
 713       end
 714     end
 715   end
 716
 717   def get_or_create_instance_user do
 718     relay_uri = "#{Pleroma.Web.Endpoint.url()}/relay"
 719
 720     if user = get_by_ap_id(relay_uri) do
 721       user
 722     else
 723       changes =
 724         %User{info: %User.Info{}}
 725         |> cast(%{}, [:ap_id, :nickname, :local])
 726         |> put_change(:ap_id, relay_uri)
 727         |> put_change(:nickname, nil)
 728         |> put_change(:local, true)
 729         |> put_change(:follower_address, relay_uri <> "/followers")
 730
 731       {:ok, user} = Repo.insert(changes)
 732       user
 733     end
 734   end
 735
 736   # AP style
 737   def public_key_from_info(%{
 738         source_data: %{"publicKey" => %{"publicKeyPem" => public_key_pem}}
 739       }) do
 740     key =
 741       :public_key.pem_decode(public_key_pem)
 742       |> hd()
 743       |> :public_key.pem_entry_decode()
 744
 745     {:ok, key}
 746   end
 747
 748   # OStatus Magic Key
 749   def public_key_from_info(%{magic_key: magic_key}) do
 750     {:ok, Pleroma.Web.Salmon.decode_key(magic_key)}
 751   end
 752
 753   def get_public_key_for_ap_id(ap_id) do
 754     with %User{} = user <- get_or_fetch_by_ap_id(ap_id),
 755          {:ok, public_key} <- public_key_from_info(user.info) do
 756       {:ok, public_key}
 757     else
 758       _ -> :error
 759     end
 760   end
 761
 762   defp blank?(""), do: nil
 763   defp blank?(n), do: n
 764
 765   def insert_or_update_user(data) do
 766     data =
 767       data
 768       |> Map.put(:name, blank?(data[:name]) || data[:nickname])
 769
 770     cs = User.remote_user_creation(data)
 771
 772     Repo.insert(cs, on_conflict: :replace_all, conflict_target: :nickname)
 773   end
 774
 775   def ap_enabled?(%User{local: true}), do: true
 776   def ap_enabled?(%User{info: info}), do: info.ap_enabled
 777   def ap_enabled?(_), do: false
 778
 779   def get_or_fetch(uri_or_nickname) do
 780     if String.starts_with?(uri_or_nickname, "http") do
 781       get_or_fetch_by_ap_id(uri_or_nickname)
 782     else
 783       get_or_fetch_by_nickname(uri_or_nickname)
 784     end
 785   end
 786
 787   # wait a period of time and return newest version of the User structs
 788   # this is because we have synchronous follow APIs and need to simulate them
 789   # with an async handshake
 790   def wait_and_refresh(_, %User{local: true} = a, %User{local: true} = b) do
 791     with %User{} = a <- Repo.get(User, a.id),
 792          %User{} = b <- Repo.get(User, b.id) do
 793       {:ok, a, b}
 794     else
 795       _e ->
 796         :error
 797     end
 798   end
 799
 800   def wait_and_refresh(timeout, %User{} = a, %User{} = b) do
 801     with :ok <- :timer.sleep(timeout),
 802          %User{} = a <- Repo.get(User, a.id),
 803          %User{} = b <- Repo.get(User, b.id) do
 804       {:ok, a, b}
 805     else
 806       _e ->
 807         :error
 808     end
 809   end
 810
 811   def parse_bio(bio, user \\ %User{info: %{source_data: %{}}}) do
 812     mentions = Formatter.parse_mentions(bio)
 813     tags = Formatter.parse_tags(bio)
 814
 815     emoji =
 816       (user.info.source_data["tag"] || [])
 817       |> Enum.filter(fn %{"type" => t} -> t == "Emoji" end)
 818       |> Enum.map(fn %{"icon" => %{"url" => url}, "name" => name} ->
 819         {String.trim(name, ":"), url}
 820       end)
 821
 822     CommonUtils.format_input(bio, mentions, tags, "text/plain") |> Formatter.emojify(emoji)
 823   end
 824
 825   def tag(user_identifiers, tags), do: tag_or_untag(user_identifiers, tags, :tag)
 826
 827   def untag(user_identifiers, tags), do: tag_or_untag(user_identifiers, tags, :untag)
 828
 829   defp tag_or_untag(user_identifier, tags, action) when not is_list(user_identifier),
 830     do: tag_or_untag([user_identifier], tags, action)
 831
 832   defp tag_or_untag([hd | _] = nicknames, tags, action) when is_binary(hd) do
 833     users = Repo.all(from(u in User, where: u.nickname in ^nicknames))
 834
 835     if length(users) == length(nicknames) do
 836       tag_or_untag(users, tags, action)
 837     else
 838       {:error, :not_found}
 839     end
 840   end
 841
 842   defp tag_or_untag([hd | _] = users, tags, action) when is_map(hd) do
 843     tags =
 844       [tags]
 845       |> List.flatten()
 846       |> Enum.map(&String.downcase(&1))
 847
 848     multi =
 849       Enum.reduce(users, Multi.new(), fn user, multi ->
 850         new_tags = mutate_tags(user, tags, action)
 851         Multi.update(multi, {:user, user.id}, change(user, %{tags: new_tags}))
 852       end)
 853
 854     Repo.transaction(multi)
 855   end
 856
 857   defp mutate_tags(user, tags, :tag), do: Enum.uniq(user.tags ++ tags)
 858
 859   defp mutate_tags(user, tags, :untag), do: user.tags -- tags
 860 end