git.squeep.com Git - akkoma/blob - lib/pleroma/user.ex

   1 defmodule Pleroma.User do
   2   use Ecto.Schema
   3
   4   import Ecto.{Changeset, Query}
   5   alias Pleroma.{Repo, User, Object, Web, Activity, Notification}
   6   alias Comeonin.Pbkdf2
   7   alias Pleroma.Web.{OStatus, Websub}
   8   alias Pleroma.Web.ActivityPub.{Utils, ActivityPub}
   9
  10   schema "users" do
  11     field(:bio, :string)
  12     field(:email, :string)
  13     field(:name, :string)
  14     field(:nickname, :string)
  15     field(:password_hash, :string)
  16     field(:password, :string, virtual: true)
  17     field(:password_confirmation, :string, virtual: true)
  18     field(:following, {:array, :string}, default: [])
  19     field(:ap_id, :string)
  20     field(:avatar, :map)
  21     field(:local, :boolean, default: true)
  22     field(:info, :map, default: %{})
  23     field(:follower_address, :string)
  24     field(:search_distance, :float, virtual: true)
  25     has_many(:notifications, Notification)
  26
  27     timestamps()
  28   end
  29
  30   def avatar_url(user) do
  31     case user.avatar do
  32       %{"url" => [%{"href" => href} | _]} -> href
  33       _ -> "#{Web.base_url()}/images/avi.png"
  34     end
  35   end
  36
  37   def banner_url(user) do
  38     case user.info["banner"] do
  39       %{"url" => [%{"href" => href} | _]} -> href
  40       _ -> "#{Web.base_url()}/images/banner.png"
  41     end
  42   end
  43
  44   def ap_id(%User{nickname: nickname}) do
  45     "#{Web.base_url()}/users/#{nickname}"
  46   end
  47
  48   def ap_followers(%User{} = user) do
  49     "#{ap_id(user)}/followers"
  50   end
  51
  52   def follow_changeset(struct, params \\ %{}) do
  53     struct
  54     |> cast(params, [:following])
  55     |> validate_required([:following])
  56   end
  57
  58   def info_changeset(struct, params \\ %{}) do
  59     struct
  60     |> cast(params, [:info])
  61     |> validate_required([:info])
  62   end
  63
  64   def user_info(%User{} = user) do
  65     oneself = if user.local, do: 1, else: 0
  66
  67     %{
  68       following_count: length(user.following) - oneself,
  69       note_count: user.info["note_count"] || 0,
  70       follower_count: user.info["follower_count"] || 0
  71     }
  72   end
  73
  74   @email_regex ~r/^[a-zA-Z0-9.!#$%&'*+\/=?^_`{|}~-]+@[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?(?:\.[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?)*$/
  75   def remote_user_creation(params) do
  76     changes =
  77       %User{}
  78       |> cast(params, [:bio, :name, :ap_id, :nickname, :info, :avatar])
  79       |> validate_required([:name, :ap_id, :nickname])
  80       |> unique_constraint(:nickname)
  81       |> validate_format(:nickname, @email_regex)
  82       |> validate_length(:bio, max: 5000)
  83       |> validate_length(:name, max: 100)
  84       |> put_change(:local, false)
  85
  86     if changes.valid? do
  87       case changes.changes[:info]["source_data"] do
  88         %{"followers" => followers} ->
  89           changes
  90           |> put_change(:follower_address, followers)
  91
  92         _ ->
  93           followers = User.ap_followers(%User{nickname: changes.changes[:nickname]})
  94
  95           changes
  96           |> put_change(:follower_address, followers)
  97       end
  98     else
  99       changes
 100     end
 101   end
 102
 103   def update_changeset(struct, params \\ %{}) do
 104     struct
 105     |> cast(params, [:bio, :name])
 106     |> unique_constraint(:nickname)
 107     |> validate_format(:nickname, ~r/^[a-zA-Z\d]+$/)
 108     |> validate_length(:bio, max: 5000)
 109     |> validate_length(:name, min: 1, max: 100)
 110   end
 111
 112   def upgrade_changeset(struct, params \\ %{}) do
 113     struct
 114     |> cast(params, [:bio, :name, :info, :follower_address, :avatar])
 115     |> unique_constraint(:nickname)
 116     |> validate_format(:nickname, ~r/^[a-zA-Z\d]+$/)
 117     |> validate_length(:bio, max: 5000)
 118     |> validate_length(:name, max: 100)
 119   end
 120
 121   def password_update_changeset(struct, params) do
 122     changeset =
 123       struct
 124       |> cast(params, [:password, :password_confirmation])
 125       |> validate_required([:password, :password_confirmation])
 126       |> validate_confirmation(:password)
 127
 128     if changeset.valid? do
 129       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 130
 131       changeset
 132       |> put_change(:password_hash, hashed)
 133     else
 134       changeset
 135     end
 136   end
 137
 138   def reset_password(user, data) do
 139     update_and_set_cache(password_update_changeset(user, data))
 140   end
 141
 142   def register_changeset(struct, params \\ %{}) do
 143     changeset =
 144       struct
 145       |> cast(params, [:bio, :email, :name, :nickname, :password, :password_confirmation])
 146       |> validate_required([:email, :name, :nickname, :password, :password_confirmation])
 147       |> validate_confirmation(:password)
 148       |> unique_constraint(:email)
 149       |> unique_constraint(:nickname)
 150       |> validate_format(:nickname, ~r/^[a-zA-Z\d]+$/)
 151       |> validate_format(:email, @email_regex)
 152       |> validate_length(:bio, max: 1000)
 153       |> validate_length(:name, min: 1, max: 100)
 154
 155     if changeset.valid? do
 156       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 157       ap_id = User.ap_id(%User{nickname: changeset.changes[:nickname]})
 158       followers = User.ap_followers(%User{nickname: changeset.changes[:nickname]})
 159
 160       changeset
 161       |> put_change(:password_hash, hashed)
 162       |> put_change(:ap_id, ap_id)
 163       |> put_change(:following, [followers])
 164       |> put_change(:follower_address, followers)
 165     else
 166       changeset
 167     end
 168   end
 169
 170   def follow(%User{} = follower, %User{info: info} = followed) do
 171     ap_followers = followed.follower_address
 172
 173     cond do
 174       following?(follower, followed) or info["deactivated"] ->
 175         {:error, "Could not follow user: #{followed.nickname} is already on your list."}
 176
 177       blocks?(followed, follower) ->
 178         {:error, "Could not follow user: #{followed.nickname} blocked you."}
 179
 180       true ->
 181         if !followed.local && follower.local && !ap_enabled?(followed) do
 182           Websub.subscribe(follower, followed)
 183         end
 184
 185         following =
 186           [ap_followers | follower.following]
 187           |> Enum.uniq()
 188
 189         follower =
 190           follower
 191           |> follow_changeset(%{following: following})
 192           |> update_and_set_cache
 193
 194         {:ok, _} = update_follower_count(followed)
 195
 196         follower
 197     end
 198   end
 199
 200   def unfollow(%User{} = follower, %User{} = followed) do
 201     ap_followers = followed.follower_address
 202
 203     if following?(follower, followed) and follower.ap_id != followed.ap_id do
 204       following =
 205         follower.following
 206         |> List.delete(ap_followers)
 207
 208       {:ok, follower} =
 209         follower
 210         |> follow_changeset(%{following: following})
 211         |> update_and_set_cache
 212
 213       {:ok, followed} = update_follower_count(followed)
 214
 215       {:ok, follower, Utils.fetch_latest_follow(follower, followed)}
 216     else
 217       {:error, "Not subscribed!"}
 218     end
 219   end
 220
 221   def following?(%User{} = follower, %User{} = followed) do
 222     Enum.member?(follower.following, followed.follower_address)
 223   end
 224
 225   def get_by_ap_id(ap_id) do
 226     Repo.get_by(User, ap_id: ap_id)
 227   end
 228
 229   def update_and_set_cache(changeset) do
 230     with {:ok, user} <- Repo.update(changeset) do
 231       Cachex.put(:user_cache, "ap_id:#{user.ap_id}", user)
 232       Cachex.put(:user_cache, "nickname:#{user.nickname}", user)
 233       Cachex.put(:user_cache, "user_info:#{user.id}", user_info(user))
 234       {:ok, user}
 235     else
 236       e -> e
 237     end
 238   end
 239
 240   def invalidate_cache(user) do
 241     Cachex.del(:user_cache, "ap_id:#{user.ap_id}")
 242     Cachex.del(:user_cache, "nickname:#{user.nickname}")
 243   end
 244
 245   def get_cached_by_ap_id(ap_id) do
 246     key = "ap_id:#{ap_id}"
 247     Cachex.fetch!(:user_cache, key, fn _ -> get_by_ap_id(ap_id) end)
 248   end
 249
 250   def get_cached_by_nickname(nickname) do
 251     key = "nickname:#{nickname}"
 252     Cachex.fetch!(:user_cache, key, fn _ -> get_or_fetch_by_nickname(nickname) end)
 253   end
 254
 255   def get_by_nickname(nickname) do
 256     Repo.get_by(User, nickname: nickname)
 257   end
 258
 259   def get_by_nickname_or_email(nickname_or_email) do
 260     case user = Repo.get_by(User, nickname: nickname_or_email) do
 261       %User{} -> user
 262       nil -> Repo.get_by(User, email: nickname_or_email)
 263     end
 264   end
 265
 266   def get_cached_user_info(user) do
 267     key = "user_info:#{user.id}"
 268     Cachex.fetch!(:user_cache, key, fn _ -> user_info(user) end)
 269   end
 270
 271   def fetch_by_nickname(nickname) do
 272     ap_try = ActivityPub.make_user_from_nickname(nickname)
 273
 274     case ap_try do
 275       {:ok, user} -> {:ok, user}
 276       _ -> OStatus.make_user(nickname)
 277     end
 278   end
 279
 280   def get_or_fetch_by_nickname(nickname) do
 281     with %User{} = user <- get_by_nickname(nickname) do
 282       user
 283     else
 284       _e ->
 285         with [_nick, _domain] <- String.split(nickname, "@"),
 286              {:ok, user} <- fetch_by_nickname(nickname) do
 287           user
 288         else
 289           _e -> nil
 290         end
 291     end
 292   end
 293
 294   def get_followers_query(%User{id: id, follower_address: follower_address}) do
 295     from(
 296       u in User,
 297       where: fragment("? <@ ?", ^[follower_address], u.following),
 298       where: u.id != ^id
 299     )
 300   end
 301
 302   def get_followers(user) do
 303     q = get_followers_query(user)
 304
 305     {:ok, Repo.all(q)}
 306   end
 307
 308   def get_friends_query(%User{id: id, following: following}) do
 309     from(
 310       u in User,
 311       where: u.follower_address in ^following,
 312       where: u.id != ^id
 313     )
 314   end
 315
 316   def get_friends(user) do
 317     q = get_friends_query(user)
 318
 319     {:ok, Repo.all(q)}
 320   end
 321
 322   def increase_note_count(%User{} = user) do
 323     note_count = (user.info["note_count"] || 0) + 1
 324     new_info = Map.put(user.info, "note_count", note_count)
 325
 326     cs = info_changeset(user, %{info: new_info})
 327
 328     update_and_set_cache(cs)
 329   end
 330
 331   def decrease_note_count(%User{} = user) do
 332     note_count = user.info["note_count"] || 0
 333     note_count = if note_count <= 0, do: 0, else: note_count - 1
 334     new_info = Map.put(user.info, "note_count", note_count)
 335
 336     cs = info_changeset(user, %{info: new_info})
 337
 338     update_and_set_cache(cs)
 339   end
 340
 341   def update_note_count(%User{} = user) do
 342     note_count_query =
 343       from(
 344         a in Object,
 345         where: fragment("?->>'actor' = ? and ?->>'type' = 'Note'", a.data, ^user.ap_id, a.data),
 346         select: count(a.id)
 347       )
 348
 349     note_count = Repo.one(note_count_query)
 350
 351     new_info = Map.put(user.info, "note_count", note_count)
 352
 353     cs = info_changeset(user, %{info: new_info})
 354
 355     update_and_set_cache(cs)
 356   end
 357
 358   def update_follower_count(%User{} = user) do
 359     follower_count_query =
 360       from(
 361         u in User,
 362         where: ^user.follower_address in u.following,
 363         where: u.id != ^user.id,
 364         select: count(u.id)
 365       )
 366
 367     follower_count = Repo.one(follower_count_query)
 368
 369     new_info = Map.put(user.info, "follower_count", follower_count)
 370
 371     cs = info_changeset(user, %{info: new_info})
 372
 373     update_and_set_cache(cs)
 374   end
 375
 376   def get_notified_from_activity(%Activity{recipients: to}) do
 377     query =
 378       from(
 379         u in User,
 380         where: u.ap_id in ^to,
 381         where: u.local == true
 382       )
 383
 384     Repo.all(query)
 385   end
 386
 387   def get_recipients_from_activity(%Activity{recipients: to}) do
 388     query =
 389       from(
 390         u in User,
 391         where: u.ap_id in ^to,
 392         or_where: fragment("? && ?", u.following, ^to)
 393       )
 394
 395     query = from(u in query, where: u.local == true)
 396
 397     Repo.all(query)
 398   end
 399
 400   def search(query, resolve) do
 401     # strip the beginning @ off if there is a query
 402     query = String.trim_leading(query, "@")
 403
 404     if resolve do
 405       User.get_or_fetch_by_nickname(query)
 406     end
 407
 408     inner =
 409       from(
 410         u in User,
 411         select_merge: %{
 412           search_distance:
 413             fragment(
 414               "? <-> (? || ?)",
 415               ^query,
 416               u.nickname,
 417               u.name
 418             )
 419         }
 420       )
 421
 422     q =
 423       from(
 424         s in subquery(inner),
 425         order_by: s.search_distance,
 426         limit: 20
 427       )
 428
 429     Repo.all(q)
 430   end
 431
 432   def block(user, %{ap_id: ap_id}) do
 433     blocks = user.info["blocks"] || []
 434     new_blocks = Enum.uniq([ap_id | blocks])
 435     new_info = Map.put(user.info, "blocks", new_blocks)
 436
 437     cs = User.info_changeset(user, %{info: new_info})
 438     update_and_set_cache(cs)
 439   end
 440
 441   def unblock(user, %{ap_id: ap_id}) do
 442     blocks = user.info["blocks"] || []
 443     new_blocks = List.delete(blocks, ap_id)
 444     new_info = Map.put(user.info, "blocks", new_blocks)
 445
 446     cs = User.info_changeset(user, %{info: new_info})
 447     update_and_set_cache(cs)
 448   end
 449
 450   def blocks?(user, %{ap_id: ap_id}) do
 451     blocks = user.info["blocks"] || []
 452     Enum.member?(blocks, ap_id)
 453   end
 454
 455   def local_user_query() do
 456     from(u in User, where: u.local == true)
 457   end
 458
 459   def deactivate(%User{} = user) do
 460     new_info = Map.put(user.info, "deactivated", true)
 461     cs = User.info_changeset(user, %{info: new_info})
 462     update_and_set_cache(cs)
 463   end
 464
 465   def delete(%User{} = user) do
 466     {:ok, user} = User.deactivate(user)
 467
 468     # Remove all relationships
 469     {:ok, followers} = User.get_followers(user)
 470
 471     followers
 472     |> Enum.each(fn follower -> User.unfollow(follower, user) end)
 473
 474     {:ok, friends} = User.get_friends(user)
 475
 476     friends
 477     |> Enum.each(fn followed -> User.unfollow(user, followed) end)
 478
 479     query = from(a in Activity, where: a.actor == ^user.ap_id)
 480
 481     Repo.all(query)
 482     |> Enum.each(fn activity ->
 483       case activity.data["type"] do
 484         "Create" ->
 485           ActivityPub.delete(Object.get_by_ap_id(activity.data["object"]["id"]))
 486
 487         # TODO: Do something with likes, follows, repeats.
 488         _ ->
 489           "Doing nothing"
 490       end
 491     end)
 492
 493     :ok
 494   end
 495
 496   def get_or_fetch_by_ap_id(ap_id) do
 497     if user = get_by_ap_id(ap_id) do
 498       user
 499     else
 500       ap_try = ActivityPub.make_user_from_ap_id(ap_id)
 501
 502       case ap_try do
 503         {:ok, user} ->
 504           user
 505
 506         _ ->
 507           case OStatus.make_user(ap_id) do
 508             {:ok, user} -> user
 509             _ -> {:error, "Could not fetch by AP id"}
 510           end
 511       end
 512     end
 513   end
 514
 515   # AP style
 516   def public_key_from_info(%{
 517         "source_data" => %{"publicKey" => %{"publicKeyPem" => public_key_pem}}
 518       }) do
 519     key =
 520       :public_key.pem_decode(public_key_pem)
 521       |> hd()
 522       |> :public_key.pem_entry_decode()
 523
 524     {:ok, key}
 525   end
 526
 527   # OStatus Magic Key
 528   def public_key_from_info(%{"magic_key" => magic_key}) do
 529     {:ok, Pleroma.Web.Salmon.decode_key(magic_key)}
 530   end
 531
 532   def get_public_key_for_ap_id(ap_id) do
 533     with %User{} = user <- get_or_fetch_by_ap_id(ap_id),
 534          {:ok, public_key} <- public_key_from_info(user.info) do
 535       {:ok, public_key}
 536     else
 537       _ -> :error
 538     end
 539   end
 540
 541   defp blank?(""), do: nil
 542   defp blank?(n), do: n
 543
 544   def insert_or_update_user(data) do
 545     data =
 546       data
 547       |> Map.put(:name, blank?(data[:name]) || data[:nickname])
 548
 549     cs = User.remote_user_creation(data)
 550     Repo.insert(cs, on_conflict: :replace_all, conflict_target: :nickname)
 551   end
 552
 553   def ap_enabled?(%User{info: info}), do: info["ap_enabled"]
 554   def ap_enabled?(_), do: false
 555
 556   def get_or_fetch(uri_or_nickname) do
 557     if String.starts_with?(uri_or_nickname, "http") do
 558       get_or_fetch_by_ap_id(uri_or_nickname)
 559     else
 560       get_or_fetch_by_nickname(uri_or_nickname)
 561     end
 562   end
 563 end