git.squeep.com Git - akkoma/blob - lib/pleroma/user.ex

   1 defmodule Pleroma.User do
   2   use Ecto.Schema
   3
   4   import Ecto.{Changeset, Query}
   5   alias Pleroma.{Repo, User, Object, Web, Activity, Notification}
   6   alias Comeonin.Pbkdf2
   7   alias Pleroma.Formatter
   8   alias Pleroma.Web.CommonAPI.Utils, as: CommonUtils
   9   alias Pleroma.Web.{OStatus, Websub, OAuth}
  10   alias Pleroma.Web.ActivityPub.{Utils, ActivityPub}
  11
  12   @type t :: %__MODULE__{}
  13
  14   @email_regex ~r/^[a-zA-Z0-9.!#$%&'*+\/=?^_`{|}~-]+@[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?(?:\.[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?)*$/
  15
  16   @strict_local_nickname_regex ~r/^[a-zA-Z\d]+$/
  17   @extended_local_nickname_regex ~r/^[a-zA-Z\d_-]+$/
  18
  19   schema "users" do
  20     field(:bio, :string)
  21     field(:email, :string)
  22     field(:name, :string)
  23     field(:nickname, :string)
  24     field(:password_hash, :string)
  25     field(:password, :string, virtual: true)
  26     field(:password_confirmation, :string, virtual: true)
  27     field(:following, {:array, :string}, default: [])
  28     field(:ap_id, :string)
  29     field(:avatar, :map)
  30     field(:local, :boolean, default: true)
  31     field(:follower_address, :string)
  32     field(:search_distance, :float, virtual: true)
  33     field(:tags, {:array, :string}, default: [])
  34     field(:last_refreshed_at, :naive_datetime)
  35     has_many(:notifications, Notification)
  36     embeds_one(:info, Pleroma.User.Info)
  37
  38     timestamps()
  39   end
  40
  41   def auth_active?(user), do: user.info && !user.info.confirmation_pending
  42
  43   def avatar_url(user) do
  44     case user.avatar do
  45       %{"url" => [%{"href" => href} | _]} -> href
  46       _ -> "#{Web.base_url()}/images/avi.png"
  47     end
  48   end
  49
  50   def banner_url(user) do
  51     case user.info.banner do
  52       %{"url" => [%{"href" => href} | _]} -> href
  53       _ -> "#{Web.base_url()}/images/banner.png"
  54     end
  55   end
  56
  57   def profile_url(%User{info: %{source_data: %{"url" => url}}}), do: url
  58   def profile_url(%User{ap_id: ap_id}), do: ap_id
  59   def profile_url(_), do: nil
  60
  61   def ap_id(%User{nickname: nickname}) do
  62     "#{Web.base_url()}/users/#{nickname}"
  63   end
  64
  65   def ap_followers(%User{} = user) do
  66     "#{ap_id(user)}/followers"
  67   end
  68
  69   def follow_changeset(struct, params \\ %{}) do
  70     struct
  71     |> cast(params, [:following])
  72     |> validate_required([:following])
  73   end
  74
  75   def user_info(%User{} = user) do
  76     oneself = if user.local, do: 1, else: 0
  77     user_info = user.info
  78
  79     %{
  80       following_count: length(user.following) - oneself,
  81       note_count: user_info.note_count,
  82       follower_count: user_info.follower_count,
  83       locked: user_info.locked,
  84       confirmation_pending: user_info.confirmation_pending,
  85       default_scope: user_info.default_scope
  86     }
  87   end
  88
  89   def remote_user_creation(params) do
  90     params =
  91       params
  92       |> Map.put(:info, params[:info] || %{})
  93
  94     info_cng = User.Info.remote_user_creation(%User.Info{}, params[:info])
  95
  96     changes =
  97       %User{}
  98       |> cast(params, [:bio, :name, :ap_id, :nickname, :avatar])
  99       |> validate_required([:name, :ap_id])
 100       |> unique_constraint(:nickname)
 101       |> validate_format(:nickname, @email_regex)
 102       |> validate_length(:bio, max: 5000)
 103       |> validate_length(:name, max: 100)
 104       |> put_change(:local, false)
 105       |> put_embed(:info, info_cng)
 106
 107     if changes.valid? do
 108       case info_cng.changes[:source_data] do
 109         %{"followers" => followers} ->
 110           changes
 111           |> put_change(:follower_address, followers)
 112
 113         _ ->
 114           followers = User.ap_followers(%User{nickname: changes.changes[:nickname]})
 115
 116           changes
 117           |> put_change(:follower_address, followers)
 118       end
 119     else
 120       changes
 121     end
 122   end
 123
 124   def update_changeset(struct, params \\ %{}) do
 125     struct
 126     |> cast(params, [:bio, :name, :avatar])
 127     |> unique_constraint(:nickname)
 128     |> validate_format(:nickname, local_nickname_regex())
 129     |> validate_length(:bio, max: 5000)
 130     |> validate_length(:name, min: 1, max: 100)
 131   end
 132
 133   def upgrade_changeset(struct, params \\ %{}) do
 134     params =
 135       params
 136       |> Map.put(:last_refreshed_at, NaiveDateTime.utc_now())
 137
 138     info_cng =
 139       struct.info
 140       |> User.Info.user_upgrade(params[:info])
 141
 142     struct
 143     |> cast(params, [:bio, :name, :follower_address, :avatar, :last_refreshed_at])
 144     |> unique_constraint(:nickname)
 145     |> validate_format(:nickname, local_nickname_regex())
 146     |> validate_length(:bio, max: 5000)
 147     |> validate_length(:name, max: 100)
 148     |> put_embed(:info, info_cng)
 149   end
 150
 151   def password_update_changeset(struct, params) do
 152     changeset =
 153       struct
 154       |> cast(params, [:password, :password_confirmation])
 155       |> validate_required([:password, :password_confirmation])
 156       |> validate_confirmation(:password)
 157
 158     OAuth.Token.delete_user_tokens(struct)
 159     OAuth.Authorization.delete_user_authorizations(struct)
 160
 161     if changeset.valid? do
 162       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 163
 164       changeset
 165       |> put_change(:password_hash, hashed)
 166     else
 167       changeset
 168     end
 169   end
 170
 171   def reset_password(user, data) do
 172     update_and_set_cache(password_update_changeset(user, data))
 173   end
 174
 175   def register_changeset(struct, params \\ %{}, opts \\ []) do
 176     confirmation_status =
 177       if opts[:confirmed] || !Pleroma.Config.get([:instance, :account_activation_required]) do
 178         :confirmed
 179       else
 180         :unconfirmed
 181       end
 182
 183     changeset =
 184       struct
 185       |> cast(params, [:bio, :email, :name, :nickname, :password, :password_confirmation])
 186       |> validate_required([:email, :name, :nickname, :password, :password_confirmation])
 187       |> validate_confirmation(:password)
 188       |> unique_constraint(:email)
 189       |> unique_constraint(:nickname)
 190       |> validate_format(:nickname, local_nickname_regex())
 191       |> validate_format(:email, @email_regex)
 192       |> validate_length(:bio, max: 1000)
 193       |> validate_length(:name, min: 1, max: 100)
 194       |> put_change(:info, User.Info.confirmation_changeset(%User.Info{}, confirmation_status))
 195
 196     if changeset.valid? do
 197       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 198       ap_id = User.ap_id(%User{nickname: changeset.changes[:nickname]})
 199       followers = User.ap_followers(%User{nickname: changeset.changes[:nickname]})
 200
 201       changeset
 202       |> put_change(:password_hash, hashed)
 203       |> put_change(:ap_id, ap_id)
 204       |> put_change(:following, [followers])
 205       |> put_change(:follower_address, followers)
 206     else
 207       changeset
 208     end
 209   end
 210
 211   @doc "Inserts provided changeset, performs post-registration actions (confirmation email sending etc.)"
 212   def register(%Ecto.Changeset{} = changeset) do
 213     with {:ok, user} <- Repo.insert(changeset),
 214          {:ok, _} = try_send_confirmation_email(user) do
 215       {:ok, user}
 216     end
 217   end
 218
 219   def try_send_confirmation_email(%User{} = user) do
 220     if user.info.confirmation_pending do
 221       user
 222       |> Pleroma.UserEmail.account_confirmation_email()
 223       |> Pleroma.Mailer.deliver()
 224     else
 225       {:ok, :noop}
 226     end
 227   end
 228
 229   def needs_update?(%User{local: true}), do: false
 230
 231   def needs_update?(%User{local: false, last_refreshed_at: nil}), do: true
 232
 233   def needs_update?(%User{local: false} = user) do
 234     NaiveDateTime.diff(NaiveDateTime.utc_now(), user.last_refreshed_at) >= 86400
 235   end
 236
 237   def needs_update?(_), do: true
 238
 239   def maybe_direct_follow(%User{} = follower, %User{local: true, info: %{locked: true}}) do
 240     {:ok, follower}
 241   end
 242
 243   def maybe_direct_follow(%User{} = follower, %User{local: true} = followed) do
 244     follow(follower, followed)
 245   end
 246
 247   def maybe_direct_follow(%User{} = follower, %User{} = followed) do
 248     if not User.ap_enabled?(followed) do
 249       follow(follower, followed)
 250     else
 251       {:ok, follower}
 252     end
 253   end
 254
 255   def maybe_follow(%User{} = follower, %User{info: _info} = followed) do
 256     if not following?(follower, followed) do
 257       follow(follower, followed)
 258     else
 259       {:ok, follower}
 260     end
 261   end
 262
 263   def follow(%User{} = follower, %User{info: info} = followed) do
 264     user_config = Application.get_env(:pleroma, :user)
 265     deny_follow_blocked = Keyword.get(user_config, :deny_follow_blocked)
 266
 267     ap_followers = followed.follower_address
 268
 269     cond do
 270       following?(follower, followed) or info.deactivated ->
 271         {:error, "Could not follow user: #{followed.nickname} is already on your list."}
 272
 273       deny_follow_blocked and blocks?(followed, follower) ->
 274         {:error, "Could not follow user: #{followed.nickname} blocked you."}
 275
 276       true ->
 277         if !followed.local && follower.local && !ap_enabled?(followed) do
 278           Websub.subscribe(follower, followed)
 279         end
 280
 281         following =
 282           [ap_followers | follower.following]
 283           |> Enum.uniq()
 284
 285         follower =
 286           follower
 287           |> follow_changeset(%{following: following})
 288           |> update_and_set_cache
 289
 290         {:ok, _} = update_follower_count(followed)
 291
 292         follower
 293     end
 294   end
 295
 296   def unfollow(%User{} = follower, %User{} = followed) do
 297     ap_followers = followed.follower_address
 298
 299     if following?(follower, followed) and follower.ap_id != followed.ap_id do
 300       following =
 301         follower.following
 302         |> List.delete(ap_followers)
 303
 304       {:ok, follower} =
 305         follower
 306         |> follow_changeset(%{following: following})
 307         |> update_and_set_cache
 308
 309       {:ok, followed} = update_follower_count(followed)
 310
 311       {:ok, follower, Utils.fetch_latest_follow(follower, followed)}
 312     else
 313       {:error, "Not subscribed!"}
 314     end
 315   end
 316
 317   @spec following?(User.t(), User.t()) :: boolean
 318   def following?(%User{} = follower, %User{} = followed) do
 319     Enum.member?(follower.following, followed.follower_address)
 320   end
 321
 322   def locked?(%User{} = user) do
 323     user.info.locked || false
 324   end
 325
 326   def get_by_ap_id(ap_id) do
 327     Repo.get_by(User, ap_id: ap_id)
 328   end
 329
 330   def update_and_set_cache(changeset) do
 331     with {:ok, user} <- Repo.update(changeset) do
 332       Cachex.put(:user_cache, "ap_id:#{user.ap_id}", user)
 333       Cachex.put(:user_cache, "nickname:#{user.nickname}", user)
 334       Cachex.put(:user_cache, "user_info:#{user.id}", user_info(user))
 335       {:ok, user}
 336     else
 337       e -> e
 338     end
 339   end
 340
 341   def invalidate_cache(user) do
 342     Cachex.del(:user_cache, "ap_id:#{user.ap_id}")
 343     Cachex.del(:user_cache, "nickname:#{user.nickname}")
 344     Cachex.del(:user_cache, "user_info:#{user.id}")
 345   end
 346
 347   def get_cached_by_ap_id(ap_id) do
 348     key = "ap_id:#{ap_id}"
 349     Cachex.fetch!(:user_cache, key, fn _ -> get_by_ap_id(ap_id) end)
 350   end
 351
 352   def get_cached_by_nickname(nickname) do
 353     key = "nickname:#{nickname}"
 354     Cachex.fetch!(:user_cache, key, fn _ -> get_or_fetch_by_nickname(nickname) end)
 355   end
 356
 357   def get_by_nickname(nickname) do
 358     Repo.get_by(User, nickname: nickname)
 359   end
 360
 361   def get_by_nickname_or_email(nickname_or_email) do
 362     case user = Repo.get_by(User, nickname: nickname_or_email) do
 363       %User{} -> user
 364       nil -> Repo.get_by(User, email: nickname_or_email)
 365     end
 366   end
 367
 368   def get_cached_user_info(user) do
 369     key = "user_info:#{user.id}"
 370     Cachex.fetch!(:user_cache, key, fn _ -> user_info(user) end)
 371   end
 372
 373   def fetch_by_nickname(nickname) do
 374     ap_try = ActivityPub.make_user_from_nickname(nickname)
 375
 376     case ap_try do
 377       {:ok, user} -> {:ok, user}
 378       _ -> OStatus.make_user(nickname)
 379     end
 380   end
 381
 382   def get_or_fetch_by_nickname(nickname) do
 383     with %User{} = user <- get_by_nickname(nickname) do
 384       user
 385     else
 386       _e ->
 387         with [_nick, _domain] <- String.split(nickname, "@"),
 388              {:ok, user} <- fetch_by_nickname(nickname) do
 389           user
 390         else
 391           _e -> nil
 392         end
 393     end
 394   end
 395
 396   def get_by_confirmation_token(token) do
 397     Repo.one(from(u in User, where: fragment("? ->> 'confirmation_token' = ?", u.info, ^token)))
 398   end
 399
 400   def get_followers_query(%User{id: id, follower_address: follower_address}) do
 401     from(
 402       u in User,
 403       where: fragment("? <@ ?", ^[follower_address], u.following),
 404       where: u.id != ^id
 405     )
 406   end
 407
 408   def get_followers(user) do
 409     q = get_followers_query(user)
 410
 411     {:ok, Repo.all(q)}
 412   end
 413
 414   def get_friends_query(%User{id: id, following: following}) do
 415     from(
 416       u in User,
 417       where: u.follower_address in ^following,
 418       where: u.id != ^id
 419     )
 420   end
 421
 422   def get_friends(user) do
 423     q = get_friends_query(user)
 424
 425     {:ok, Repo.all(q)}
 426   end
 427
 428   def get_follow_requests_query(%User{} = user) do
 429     from(
 430       a in Activity,
 431       where:
 432         fragment(
 433           "? ->> 'type' = 'Follow'",
 434           a.data
 435         ),
 436       where:
 437         fragment(
 438           "? ->> 'state' = 'pending'",
 439           a.data
 440         ),
 441       where:
 442         fragment(
 443           "? @> ?",
 444           a.data,
 445           ^%{"object" => user.ap_id}
 446         )
 447     )
 448   end
 449
 450   def get_follow_requests(%User{} = user) do
 451     q = get_follow_requests_query(user)
 452     reqs = Repo.all(q)
 453
 454     users =
 455       Enum.map(reqs, fn req -> req.actor end)
 456       |> Enum.uniq()
 457       |> Enum.map(fn ap_id -> get_by_ap_id(ap_id) end)
 458       |> Enum.filter(fn u -> !following?(u, user) end)
 459
 460     {:ok, users}
 461   end
 462
 463   def increase_note_count(%User{} = user) do
 464     info_cng = User.Info.add_to_note_count(user.info, 1)
 465
 466     cng =
 467       change(user)
 468       |> put_embed(:info, info_cng)
 469
 470     update_and_set_cache(cng)
 471   end
 472
 473   def decrease_note_count(%User{} = user) do
 474     info_cng = User.Info.add_to_note_count(user.info, -1)
 475
 476     cng =
 477       change(user)
 478       |> put_embed(:info, info_cng)
 479
 480     update_and_set_cache(cng)
 481   end
 482
 483   def update_note_count(%User{} = user) do
 484     note_count_query =
 485       from(
 486         a in Object,
 487         where: fragment("?->>'actor' = ? and ?->>'type' = 'Note'", a.data, ^user.ap_id, a.data),
 488         select: count(a.id)
 489       )
 490
 491     note_count = Repo.one(note_count_query)
 492
 493     info_cng = User.Info.set_note_count(user.info, note_count)
 494
 495     cng =
 496       change(user)
 497       |> put_embed(:info, info_cng)
 498
 499     update_and_set_cache(cng)
 500   end
 501
 502   def update_follower_count(%User{} = user) do
 503     follower_count_query =
 504       from(
 505         u in User,
 506         where: ^user.follower_address in u.following,
 507         where: u.id != ^user.id,
 508         select: count(u.id)
 509       )
 510
 511     follower_count = Repo.one(follower_count_query)
 512
 513     info_cng =
 514       user.info
 515       |> User.Info.set_follower_count(follower_count)
 516
 517     cng =
 518       change(user)
 519       |> put_embed(:info, info_cng)
 520
 521     update_and_set_cache(cng)
 522   end
 523
 524   def get_users_from_set_query(ap_ids, false) do
 525     from(
 526       u in User,
 527       where: u.ap_id in ^ap_ids
 528     )
 529   end
 530
 531   def get_users_from_set_query(ap_ids, true) do
 532     query = get_users_from_set_query(ap_ids, false)
 533
 534     from(
 535       u in query,
 536       where: u.local == true
 537     )
 538   end
 539
 540   def get_users_from_set(ap_ids, local_only \\ true) do
 541     get_users_from_set_query(ap_ids, local_only)
 542     |> Repo.all()
 543   end
 544
 545   def get_recipients_from_activity(%Activity{recipients: to}) do
 546     query =
 547       from(
 548         u in User,
 549         where: u.ap_id in ^to,
 550         or_where: fragment("? && ?", u.following, ^to)
 551       )
 552
 553     query = from(u in query, where: u.local == true)
 554
 555     Repo.all(query)
 556   end
 557
 558   def search(query, resolve \\ false) do
 559     # strip the beginning @ off if there is a query
 560     query = String.trim_leading(query, "@")
 561
 562     if resolve do
 563       User.get_or_fetch_by_nickname(query)
 564     end
 565
 566     inner =
 567       from(
 568         u in User,
 569         select_merge: %{
 570           search_distance:
 571             fragment(
 572               "? <-> (? || ?)",
 573               ^query,
 574               u.nickname,
 575               u.name
 576             )
 577         },
 578         where: not is_nil(u.nickname)
 579       )
 580
 581     q =
 582       from(
 583         s in subquery(inner),
 584         order_by: s.search_distance,
 585         limit: 20
 586       )
 587
 588     Repo.all(q)
 589   end
 590
 591   def block(blocker, %User{ap_id: ap_id} = blocked) do
 592     # sever any follow relationships to prevent leaks per activitypub (Pleroma issue #213)
 593     blocker =
 594       if following?(blocker, blocked) do
 595         {:ok, blocker, _} = unfollow(blocker, blocked)
 596         blocker
 597       else
 598         blocker
 599       end
 600
 601     if following?(blocked, blocker) do
 602       unfollow(blocked, blocker)
 603     end
 604
 605     info_cng =
 606       blocker.info
 607       |> User.Info.add_to_block(ap_id)
 608
 609     cng =
 610       change(blocker)
 611       |> put_embed(:info, info_cng)
 612
 613     update_and_set_cache(cng)
 614   end
 615
 616   # helper to handle the block given only an actor's AP id
 617   def block(blocker, %{ap_id: ap_id}) do
 618     block(blocker, User.get_by_ap_id(ap_id))
 619   end
 620
 621   def unblock(blocker, %{ap_id: ap_id}) do
 622     info_cng =
 623       blocker.info
 624       |> User.Info.remove_from_block(ap_id)
 625
 626     cng =
 627       change(blocker)
 628       |> put_embed(:info, info_cng)
 629
 630     update_and_set_cache(cng)
 631   end
 632
 633   def blocks?(user, %{ap_id: ap_id}) do
 634     blocks = user.info.blocks
 635     domain_blocks = user.info.domain_blocks
 636     %{host: host} = URI.parse(ap_id)
 637
 638     Enum.member?(blocks, ap_id) ||
 639       Enum.any?(domain_blocks, fn domain ->
 640         host == domain
 641       end)
 642   end
 643
 644   def block_domain(user, domain) do
 645     info_cng =
 646       user.info
 647       |> User.Info.add_to_domain_block(domain)
 648
 649     cng =
 650       change(user)
 651       |> put_embed(:info, info_cng)
 652
 653     update_and_set_cache(cng)
 654   end
 655
 656   def unblock_domain(user, domain) do
 657     info_cng =
 658       user.info
 659       |> User.Info.remove_from_domain_block(domain)
 660
 661     cng =
 662       change(user)
 663       |> put_embed(:info, info_cng)
 664
 665     update_and_set_cache(cng)
 666   end
 667
 668   def local_user_query() do
 669     from(
 670       u in User,
 671       where: u.local == true,
 672       where: not is_nil(u.nickname)
 673     )
 674   end
 675
 676   def moderator_user_query() do
 677     from(
 678       u in User,
 679       where: u.local == true,
 680       where: fragment("?->'is_moderator' @> 'true'", u.info)
 681     )
 682   end
 683
 684   def deactivate(%User{} = user, status \\ true) do
 685     info_cng = User.Info.set_activation_status(user.info, status)
 686
 687     cng =
 688       change(user)
 689       |> put_embed(:info, info_cng)
 690
 691     update_and_set_cache(cng)
 692   end
 693
 694   def delete(%User{} = user) do
 695     {:ok, user} = User.deactivate(user)
 696
 697     # Remove all relationships
 698     {:ok, followers} = User.get_followers(user)
 699
 700     followers
 701     |> Enum.each(fn follower -> User.unfollow(follower, user) end)
 702
 703     {:ok, friends} = User.get_friends(user)
 704
 705     friends
 706     |> Enum.each(fn followed -> User.unfollow(user, followed) end)
 707
 708     query = from(a in Activity, where: a.actor == ^user.ap_id)
 709
 710     Repo.all(query)
 711     |> Enum.each(fn activity ->
 712       case activity.data["type"] do
 713         "Create" ->
 714           ActivityPub.delete(Object.normalize(activity.data["object"]))
 715
 716         # TODO: Do something with likes, follows, repeats.
 717         _ ->
 718           "Doing nothing"
 719       end
 720     end)
 721
 722     {:ok, user}
 723   end
 724
 725   def html_filter_policy(%User{info: %{no_rich_text: true}}) do
 726     Pleroma.HTML.Scrubber.TwitterText
 727   end
 728
 729   def html_filter_policy(_), do: nil
 730
 731   def get_or_fetch_by_ap_id(ap_id) do
 732     user = get_by_ap_id(ap_id)
 733
 734     if !is_nil(user) and !User.needs_update?(user) do
 735       user
 736     else
 737       ap_try = ActivityPub.make_user_from_ap_id(ap_id)
 738
 739       case ap_try do
 740         {:ok, user} ->
 741           user
 742
 743         _ ->
 744           case OStatus.make_user(ap_id) do
 745             {:ok, user} -> user
 746             _ -> {:error, "Could not fetch by AP id"}
 747           end
 748       end
 749     end
 750   end
 751
 752   def get_or_create_instance_user do
 753     relay_uri = "#{Pleroma.Web.Endpoint.url()}/relay"
 754
 755     if user = get_by_ap_id(relay_uri) do
 756       user
 757     else
 758       changes =
 759         %User{info: %User.Info{}}
 760         |> cast(%{}, [:ap_id, :nickname, :local])
 761         |> put_change(:ap_id, relay_uri)
 762         |> put_change(:nickname, nil)
 763         |> put_change(:local, true)
 764         |> put_change(:follower_address, relay_uri <> "/followers")
 765
 766       {:ok, user} = Repo.insert(changes)
 767       user
 768     end
 769   end
 770
 771   # AP style
 772   def public_key_from_info(%{
 773         source_data: %{"publicKey" => %{"publicKeyPem" => public_key_pem}}
 774       }) do
 775     key =
 776       public_key_pem
 777       |> :public_key.pem_decode()
 778       |> hd()
 779       |> :public_key.pem_entry_decode()
 780
 781     {:ok, key}
 782   end
 783
 784   # OStatus Magic Key
 785   def public_key_from_info(%{magic_key: magic_key}) do
 786     {:ok, Pleroma.Web.Salmon.decode_key(magic_key)}
 787   end
 788
 789   def get_public_key_for_ap_id(ap_id) do
 790     with %User{} = user <- get_or_fetch_by_ap_id(ap_id),
 791          {:ok, public_key} <- public_key_from_info(user.info) do
 792       {:ok, public_key}
 793     else
 794       _ -> :error
 795     end
 796   end
 797
 798   defp blank?(""), do: nil
 799   defp blank?(n), do: n
 800
 801   def insert_or_update_user(data) do
 802     data =
 803       data
 804       |> Map.put(:name, blank?(data[:name]) || data[:nickname])
 805
 806     cs = User.remote_user_creation(data)
 807
 808     Repo.insert(cs, on_conflict: :replace_all, conflict_target: :nickname)
 809   end
 810
 811   def ap_enabled?(%User{local: true}), do: true
 812   def ap_enabled?(%User{info: info}), do: info.ap_enabled
 813   def ap_enabled?(_), do: false
 814
 815   @doc "Gets or fetch a user by uri or nickname."
 816   @spec get_or_fetch(String.t()) :: User.t()
 817   def get_or_fetch("http" <> _host = uri), do: get_or_fetch_by_ap_id(uri)
 818   def get_or_fetch(nickname), do: get_or_fetch_by_nickname(nickname)
 819
 820   # wait a period of time and return newest version of the User structs
 821   # this is because we have synchronous follow APIs and need to simulate them
 822   # with an async handshake
 823   def wait_and_refresh(_, %User{local: true} = a, %User{local: true} = b) do
 824     with %User{} = a <- Repo.get(User, a.id),
 825          %User{} = b <- Repo.get(User, b.id) do
 826       {:ok, a, b}
 827     else
 828       _e ->
 829         :error
 830     end
 831   end
 832
 833   def wait_and_refresh(timeout, %User{} = a, %User{} = b) do
 834     with :ok <- :timer.sleep(timeout),
 835          %User{} = a <- Repo.get(User, a.id),
 836          %User{} = b <- Repo.get(User, b.id) do
 837       {:ok, a, b}
 838     else
 839       _e ->
 840         :error
 841     end
 842   end
 843
 844   def parse_bio(bio, user \\ %User{info: %{source_data: %{}}})
 845   def parse_bio(nil, _user), do: ""
 846   def parse_bio(bio, _user) when bio == "", do: bio
 847
 848   def parse_bio(bio, user) do
 849     mentions = Formatter.parse_mentions(bio)
 850     tags = Formatter.parse_tags(bio)
 851
 852     emoji =
 853       (user.info.source_data["tag"] || [])
 854       |> Enum.filter(fn %{"type" => t} -> t == "Emoji" end)
 855       |> Enum.map(fn %{"icon" => %{"url" => url}, "name" => name} ->
 856         {String.trim(name, ":"), url}
 857       end)
 858
 859     bio
 860     |> CommonUtils.format_input(mentions, tags, "text/plain")
 861     |> Formatter.emojify(emoji)
 862   end
 863
 864   def tag(user_identifiers, tags) when is_list(user_identifiers) do
 865     Repo.transaction(fn ->
 866       for user_identifier <- user_identifiers, do: tag(user_identifier, tags)
 867     end)
 868   end
 869
 870   def tag(nickname, tags) when is_binary(nickname),
 871     do: tag(User.get_by_nickname(nickname), tags)
 872
 873   def tag(%User{} = user, tags),
 874     do: update_tags(user, Enum.uniq((user.tags || []) ++ normalize_tags(tags)))
 875
 876   def untag(user_identifiers, tags) when is_list(user_identifiers) do
 877     Repo.transaction(fn ->
 878       for user_identifier <- user_identifiers, do: untag(user_identifier, tags)
 879     end)
 880   end
 881
 882   def untag(nickname, tags) when is_binary(nickname),
 883     do: untag(User.get_by_nickname(nickname), tags)
 884
 885   def untag(%User{} = user, tags),
 886     do: update_tags(user, (user.tags || []) -- normalize_tags(tags))
 887
 888   defp update_tags(%User{} = user, new_tags) do
 889     {:ok, updated_user} =
 890       user
 891       |> change(%{tags: new_tags})
 892       |> Repo.update()
 893
 894     updated_user
 895   end
 896
 897   defp normalize_tags(tags) do
 898     [tags]
 899     |> List.flatten()
 900     |> Enum.map(&String.downcase(&1))
 901   end
 902
 903   defp local_nickname_regex() do
 904     if Pleroma.Config.get([:instance, :extended_nickname_format]) do
 905       @extended_local_nickname_regex
 906     else
 907       @strict_local_nickname_regex
 908     end
 909   end
 910 end