git.squeep.com Git - akkoma/blob - lib/pleroma/user.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2018 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.User do
   6   use Ecto.Schema
   7
   8   import Ecto.{Changeset, Query}
   9   alias Pleroma.{Repo, User, Object, Web, Activity, Notification}
  10   alias Comeonin.Pbkdf2
  11   alias Pleroma.Formatter
  12   alias Pleroma.Web.CommonAPI.Utils, as: CommonUtils
  13   alias Pleroma.Web.{OStatus, Websub, OAuth}
  14   alias Pleroma.Web.ActivityPub.{Utils, ActivityPub}
  15
  16   @type t :: %__MODULE__{}
  17
  18   @email_regex ~r/^[a-zA-Z0-9.!#$%&'*+\/=?^_`{|}~-]+@[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?(?:\.[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?)*$/
  19
  20   @strict_local_nickname_regex ~r/^[a-zA-Z\d]+$/
  21   @extended_local_nickname_regex ~r/^[a-zA-Z\d_-]+$/
  22
  23   schema "users" do
  24     field(:bio, :string)
  25     field(:email, :string)
  26     field(:name, :string)
  27     field(:nickname, :string)
  28     field(:password_hash, :string)
  29     field(:password, :string, virtual: true)
  30     field(:password_confirmation, :string, virtual: true)
  31     field(:following, {:array, :string}, default: [])
  32     field(:ap_id, :string)
  33     field(:avatar, :map)
  34     field(:local, :boolean, default: true)
  35     field(:follower_address, :string)
  36     field(:search_distance, :float, virtual: true)
  37     field(:tags, {:array, :string}, default: [])
  38     field(:last_refreshed_at, :naive_datetime)
  39     has_many(:notifications, Notification)
  40     embeds_one(:info, Pleroma.User.Info)
  41
  42     timestamps()
  43   end
  44
  45   def auth_active?(%User{} = user) do
  46     (user.info && !user.info.confirmation_pending) ||
  47       !Pleroma.Config.get([:instance, :account_activation_required])
  48   end
  49
  50   def remote_or_auth_active?(%User{} = user), do: !user.local || auth_active?(user)
  51
  52   def visible_for?(%User{} = user, for_user \\ nil) do
  53     User.remote_or_auth_active?(user) || (for_user && for_user.id == user.id) ||
  54       User.superuser?(for_user)
  55   end
  56
  57   def superuser?(nil), do: false
  58   def superuser?(%User{} = user), do: user.info && User.Info.superuser?(user.info)
  59
  60   def avatar_url(user) do
  61     case user.avatar do
  62       %{"url" => [%{"href" => href} | _]} -> href
  63       _ -> "#{Web.base_url()}/images/avi.png"
  64     end
  65   end
  66
  67   def banner_url(user) do
  68     case user.info.banner do
  69       %{"url" => [%{"href" => href} | _]} -> href
  70       _ -> "#{Web.base_url()}/images/banner.png"
  71     end
  72   end
  73
  74   def profile_url(%User{info: %{source_data: %{"url" => url}}}), do: url
  75   def profile_url(%User{ap_id: ap_id}), do: ap_id
  76   def profile_url(_), do: nil
  77
  78   def ap_id(%User{nickname: nickname}) do
  79     "#{Web.base_url()}/users/#{nickname}"
  80   end
  81
  82   def ap_followers(%User{} = user) do
  83     "#{ap_id(user)}/followers"
  84   end
  85
  86   def follow_changeset(struct, params \\ %{}) do
  87     struct
  88     |> cast(params, [:following])
  89     |> validate_required([:following])
  90   end
  91
  92   def user_info(%User{} = user) do
  93     oneself = if user.local, do: 1, else: 0
  94
  95     %{
  96       following_count: length(user.following) - oneself,
  97       note_count: user.info.note_count,
  98       follower_count: user.info.follower_count,
  99       locked: user.info.locked,
 100       confirmation_pending: user.info.confirmation_pending,
 101       default_scope: user.info.default_scope
 102     }
 103   end
 104
 105   def remote_user_creation(params) do
 106     params =
 107       params
 108       |> Map.put(:info, params[:info] || %{})
 109
 110     info_cng = User.Info.remote_user_creation(%User.Info{}, params[:info])
 111
 112     changes =
 113       %User{}
 114       |> cast(params, [:bio, :name, :ap_id, :nickname, :avatar])
 115       |> validate_required([:name, :ap_id])
 116       |> unique_constraint(:nickname)
 117       |> validate_format(:nickname, @email_regex)
 118       |> validate_length(:bio, max: 5000)
 119       |> validate_length(:name, max: 100)
 120       |> put_change(:local, false)
 121       |> put_embed(:info, info_cng)
 122
 123     if changes.valid? do
 124       case info_cng.changes[:source_data] do
 125         %{"followers" => followers} ->
 126           changes
 127           |> put_change(:follower_address, followers)
 128
 129         _ ->
 130           followers = User.ap_followers(%User{nickname: changes.changes[:nickname]})
 131
 132           changes
 133           |> put_change(:follower_address, followers)
 134       end
 135     else
 136       changes
 137     end
 138   end
 139
 140   def update_changeset(struct, params \\ %{}) do
 141     struct
 142     |> cast(params, [:bio, :name, :avatar])
 143     |> unique_constraint(:nickname)
 144     |> validate_format(:nickname, local_nickname_regex())
 145     |> validate_length(:bio, max: 5000)
 146     |> validate_length(:name, min: 1, max: 100)
 147   end
 148
 149   def upgrade_changeset(struct, params \\ %{}) do
 150     params =
 151       params
 152       |> Map.put(:last_refreshed_at, NaiveDateTime.utc_now())
 153
 154     info_cng =
 155       struct.info
 156       |> User.Info.user_upgrade(params[:info])
 157
 158     struct
 159     |> cast(params, [:bio, :name, :follower_address, :avatar, :last_refreshed_at])
 160     |> unique_constraint(:nickname)
 161     |> validate_format(:nickname, local_nickname_regex())
 162     |> validate_length(:bio, max: 5000)
 163     |> validate_length(:name, max: 100)
 164     |> put_embed(:info, info_cng)
 165   end
 166
 167   def password_update_changeset(struct, params) do
 168     changeset =
 169       struct
 170       |> cast(params, [:password, :password_confirmation])
 171       |> validate_required([:password, :password_confirmation])
 172       |> validate_confirmation(:password)
 173
 174     OAuth.Token.delete_user_tokens(struct)
 175     OAuth.Authorization.delete_user_authorizations(struct)
 176
 177     if changeset.valid? do
 178       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 179
 180       changeset
 181       |> put_change(:password_hash, hashed)
 182     else
 183       changeset
 184     end
 185   end
 186
 187   def reset_password(user, data) do
 188     update_and_set_cache(password_update_changeset(user, data))
 189   end
 190
 191   def register_changeset(struct, params \\ %{}, opts \\ []) do
 192     confirmation_status =
 193       if opts[:confirmed] || !Pleroma.Config.get([:instance, :account_activation_required]) do
 194         :confirmed
 195       else
 196         :unconfirmed
 197       end
 198
 199     info_change = User.Info.confirmation_changeset(%User.Info{}, confirmation_status)
 200
 201     changeset =
 202       struct
 203       |> cast(params, [:bio, :email, :name, :nickname, :password, :password_confirmation])
 204       |> validate_required([:email, :name, :nickname, :password, :password_confirmation])
 205       |> validate_confirmation(:password)
 206       |> unique_constraint(:email)
 207       |> unique_constraint(:nickname)
 208       |> validate_exclusion(:nickname, Pleroma.Config.get([Pleroma.User, :restricted_nicknames]))
 209       |> validate_format(:nickname, local_nickname_regex())
 210       |> validate_format(:email, @email_regex)
 211       |> validate_length(:bio, max: 1000)
 212       |> validate_length(:name, min: 1, max: 100)
 213       |> put_change(:info, info_change)
 214
 215     if changeset.valid? do
 216       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 217       ap_id = User.ap_id(%User{nickname: changeset.changes[:nickname]})
 218       followers = User.ap_followers(%User{nickname: changeset.changes[:nickname]})
 219
 220       changeset
 221       |> put_change(:password_hash, hashed)
 222       |> put_change(:ap_id, ap_id)
 223       |> put_change(:following, [followers])
 224       |> put_change(:follower_address, followers)
 225     else
 226       changeset
 227     end
 228   end
 229
 230   @doc "Inserts provided changeset, performs post-registration actions (confirmation email sending etc.)"
 231   def register(%Ecto.Changeset{} = changeset) do
 232     with {:ok, user} <- Repo.insert(changeset),
 233          {:ok, _} = try_send_confirmation_email(user) do
 234       {:ok, user}
 235     end
 236   end
 237
 238   def try_send_confirmation_email(%User{} = user) do
 239     if user.info.confirmation_pending &&
 240          Pleroma.Config.get([:instance, :account_activation_required]) do
 241       user
 242       |> Pleroma.UserEmail.account_confirmation_email()
 243       |> Pleroma.Mailer.deliver()
 244     else
 245       {:ok, :noop}
 246     end
 247   end
 248
 249   def needs_update?(%User{local: true}), do: false
 250
 251   def needs_update?(%User{local: false, last_refreshed_at: nil}), do: true
 252
 253   def needs_update?(%User{local: false} = user) do
 254     NaiveDateTime.diff(NaiveDateTime.utc_now(), user.last_refreshed_at) >= 86400
 255   end
 256
 257   def needs_update?(_), do: true
 258
 259   def maybe_direct_follow(%User{} = follower, %User{local: true, info: %{locked: true}}) do
 260     {:ok, follower}
 261   end
 262
 263   def maybe_direct_follow(%User{} = follower, %User{local: true} = followed) do
 264     follow(follower, followed)
 265   end
 266
 267   def maybe_direct_follow(%User{} = follower, %User{} = followed) do
 268     if not User.ap_enabled?(followed) do
 269       follow(follower, followed)
 270     else
 271       {:ok, follower}
 272     end
 273   end
 274
 275   def maybe_follow(%User{} = follower, %User{info: _info} = followed) do
 276     if not following?(follower, followed) do
 277       follow(follower, followed)
 278     else
 279       {:ok, follower}
 280     end
 281   end
 282
 283   def follow(%User{} = follower, %User{info: info} = followed) do
 284     user_config = Application.get_env(:pleroma, :user)
 285     deny_follow_blocked = Keyword.get(user_config, :deny_follow_blocked)
 286
 287     ap_followers = followed.follower_address
 288
 289     cond do
 290       following?(follower, followed) or info.deactivated ->
 291         {:error, "Could not follow user: #{followed.nickname} is already on your list."}
 292
 293       deny_follow_blocked and blocks?(followed, follower) ->
 294         {:error, "Could not follow user: #{followed.nickname} blocked you."}
 295
 296       true ->
 297         if !followed.local && follower.local && !ap_enabled?(followed) do
 298           Websub.subscribe(follower, followed)
 299         end
 300
 301         following =
 302           [ap_followers | follower.following]
 303           |> Enum.uniq()
 304
 305         follower =
 306           follower
 307           |> follow_changeset(%{following: following})
 308           |> update_and_set_cache
 309
 310         {:ok, _} = update_follower_count(followed)
 311
 312         follower
 313     end
 314   end
 315
 316   def unfollow(%User{} = follower, %User{} = followed) do
 317     ap_followers = followed.follower_address
 318
 319     if following?(follower, followed) and follower.ap_id != followed.ap_id do
 320       following =
 321         follower.following
 322         |> List.delete(ap_followers)
 323
 324       {:ok, follower} =
 325         follower
 326         |> follow_changeset(%{following: following})
 327         |> update_and_set_cache
 328
 329       {:ok, followed} = update_follower_count(followed)
 330
 331       {:ok, follower, Utils.fetch_latest_follow(follower, followed)}
 332     else
 333       {:error, "Not subscribed!"}
 334     end
 335   end
 336
 337   @spec following?(User.t(), User.t()) :: boolean
 338   def following?(%User{} = follower, %User{} = followed) do
 339     Enum.member?(follower.following, followed.follower_address)
 340   end
 341
 342   def locked?(%User{} = user) do
 343     user.info.locked || false
 344   end
 345
 346   def get_by_ap_id(ap_id) do
 347     Repo.get_by(User, ap_id: ap_id)
 348   end
 349
 350   def update_and_set_cache(changeset) do
 351     with {:ok, user} <- Repo.update(changeset) do
 352       Cachex.put(:user_cache, "ap_id:#{user.ap_id}", user)
 353       Cachex.put(:user_cache, "nickname:#{user.nickname}", user)
 354       Cachex.put(:user_cache, "user_info:#{user.id}", user_info(user))
 355       {:ok, user}
 356     else
 357       e -> e
 358     end
 359   end
 360
 361   def invalidate_cache(user) do
 362     Cachex.del(:user_cache, "ap_id:#{user.ap_id}")
 363     Cachex.del(:user_cache, "nickname:#{user.nickname}")
 364     Cachex.del(:user_cache, "user_info:#{user.id}")
 365   end
 366
 367   def get_cached_by_ap_id(ap_id) do
 368     key = "ap_id:#{ap_id}"
 369     Cachex.fetch!(:user_cache, key, fn _ -> get_by_ap_id(ap_id) end)
 370   end
 371
 372   def get_cached_by_nickname(nickname) do
 373     key = "nickname:#{nickname}"
 374     Cachex.fetch!(:user_cache, key, fn _ -> get_or_fetch_by_nickname(nickname) end)
 375   end
 376
 377   def get_by_nickname(nickname) do
 378     Repo.get_by(User, nickname: nickname)
 379   end
 380
 381   def get_by_nickname_or_email(nickname_or_email) do
 382     case user = Repo.get_by(User, nickname: nickname_or_email) do
 383       %User{} -> user
 384       nil -> Repo.get_by(User, email: nickname_or_email)
 385     end
 386   end
 387
 388   def get_cached_user_info(user) do
 389     key = "user_info:#{user.id}"
 390     Cachex.fetch!(:user_cache, key, fn _ -> user_info(user) end)
 391   end
 392
 393   def fetch_by_nickname(nickname) do
 394     ap_try = ActivityPub.make_user_from_nickname(nickname)
 395
 396     case ap_try do
 397       {:ok, user} -> {:ok, user}
 398       _ -> OStatus.make_user(nickname)
 399     end
 400   end
 401
 402   def get_or_fetch_by_nickname(nickname) do
 403     with %User{} = user <- get_by_nickname(nickname) do
 404       user
 405     else
 406       _e ->
 407         with [_nick, _domain] <- String.split(nickname, "@"),
 408              {:ok, user} <- fetch_by_nickname(nickname) do
 409           user
 410         else
 411           _e -> nil
 412         end
 413     end
 414   end
 415
 416   def get_followers_query(%User{id: id, follower_address: follower_address}) do
 417     from(
 418       u in User,
 419       where: fragment("? <@ ?", ^[follower_address], u.following),
 420       where: u.id != ^id
 421     )
 422   end
 423
 424   def get_followers(user) do
 425     q = get_followers_query(user)
 426
 427     {:ok, Repo.all(q)}
 428   end
 429
 430   def get_friends_query(%User{id: id, following: following}) do
 431     from(
 432       u in User,
 433       where: u.follower_address in ^following,
 434       where: u.id != ^id
 435     )
 436   end
 437
 438   def get_friends(user) do
 439     q = get_friends_query(user)
 440
 441     {:ok, Repo.all(q)}
 442   end
 443
 444   def get_follow_requests_query(%User{} = user) do
 445     from(
 446       a in Activity,
 447       where:
 448         fragment(
 449           "? ->> 'type' = 'Follow'",
 450           a.data
 451         ),
 452       where:
 453         fragment(
 454           "? ->> 'state' = 'pending'",
 455           a.data
 456         ),
 457       where:
 458         fragment(
 459           "? @> ?",
 460           a.data,
 461           ^%{"object" => user.ap_id}
 462         )
 463     )
 464   end
 465
 466   def get_follow_requests(%User{} = user) do
 467     q = get_follow_requests_query(user)
 468     reqs = Repo.all(q)
 469
 470     users =
 471       Enum.map(reqs, fn req -> req.actor end)
 472       |> Enum.uniq()
 473       |> Enum.map(fn ap_id -> get_by_ap_id(ap_id) end)
 474       |> Enum.filter(fn u -> !following?(u, user) end)
 475
 476     {:ok, users}
 477   end
 478
 479   def increase_note_count(%User{} = user) do
 480     info_cng = User.Info.add_to_note_count(user.info, 1)
 481
 482     cng =
 483       change(user)
 484       |> put_embed(:info, info_cng)
 485
 486     update_and_set_cache(cng)
 487   end
 488
 489   def decrease_note_count(%User{} = user) do
 490     info_cng = User.Info.add_to_note_count(user.info, -1)
 491
 492     cng =
 493       change(user)
 494       |> put_embed(:info, info_cng)
 495
 496     update_and_set_cache(cng)
 497   end
 498
 499   def update_note_count(%User{} = user) do
 500     note_count_query =
 501       from(
 502         a in Object,
 503         where: fragment("?->>'actor' = ? and ?->>'type' = 'Note'", a.data, ^user.ap_id, a.data),
 504         select: count(a.id)
 505       )
 506
 507     note_count = Repo.one(note_count_query)
 508
 509     info_cng = User.Info.set_note_count(user.info, note_count)
 510
 511     cng =
 512       change(user)
 513       |> put_embed(:info, info_cng)
 514
 515     update_and_set_cache(cng)
 516   end
 517
 518   def update_follower_count(%User{} = user) do
 519     follower_count_query =
 520       from(
 521         u in User,
 522         where: ^user.follower_address in u.following,
 523         where: u.id != ^user.id,
 524         select: count(u.id)
 525       )
 526
 527     follower_count = Repo.one(follower_count_query)
 528
 529     info_cng =
 530       user.info
 531       |> User.Info.set_follower_count(follower_count)
 532
 533     cng =
 534       change(user)
 535       |> put_embed(:info, info_cng)
 536
 537     update_and_set_cache(cng)
 538   end
 539
 540   def get_users_from_set_query(ap_ids, false) do
 541     from(
 542       u in User,
 543       where: u.ap_id in ^ap_ids
 544     )
 545   end
 546
 547   def get_users_from_set_query(ap_ids, true) do
 548     query = get_users_from_set_query(ap_ids, false)
 549
 550     from(
 551       u in query,
 552       where: u.local == true
 553     )
 554   end
 555
 556   def get_users_from_set(ap_ids, local_only \\ true) do
 557     get_users_from_set_query(ap_ids, local_only)
 558     |> Repo.all()
 559   end
 560
 561   def get_recipients_from_activity(%Activity{recipients: to}) do
 562     query =
 563       from(
 564         u in User,
 565         where: u.ap_id in ^to,
 566         or_where: fragment("? && ?", u.following, ^to)
 567       )
 568
 569     query = from(u in query, where: u.local == true)
 570
 571     Repo.all(query)
 572   end
 573
 574   def search(query, resolve \\ false) do
 575     # strip the beginning @ off if there is a query
 576     query = String.trim_leading(query, "@")
 577
 578     if resolve do
 579       User.get_or_fetch_by_nickname(query)
 580     end
 581
 582     inner =
 583       from(
 584         u in User,
 585         select_merge: %{
 586           search_distance:
 587             fragment(
 588               "? <-> (? || ?)",
 589               ^query,
 590               u.nickname,
 591               u.name
 592             )
 593         },
 594         where: not is_nil(u.nickname)
 595       )
 596
 597     q =
 598       from(
 599         s in subquery(inner),
 600         order_by: s.search_distance,
 601         limit: 20
 602       )
 603
 604     Repo.all(q)
 605   end
 606
 607   def block(blocker, %User{ap_id: ap_id} = blocked) do
 608     # sever any follow relationships to prevent leaks per activitypub (Pleroma issue #213)
 609     blocker =
 610       if following?(blocker, blocked) do
 611         {:ok, blocker, _} = unfollow(blocker, blocked)
 612         blocker
 613       else
 614         blocker
 615       end
 616
 617     if following?(blocked, blocker) do
 618       unfollow(blocked, blocker)
 619     end
 620
 621     info_cng =
 622       blocker.info
 623       |> User.Info.add_to_block(ap_id)
 624
 625     cng =
 626       change(blocker)
 627       |> put_embed(:info, info_cng)
 628
 629     update_and_set_cache(cng)
 630   end
 631
 632   # helper to handle the block given only an actor's AP id
 633   def block(blocker, %{ap_id: ap_id}) do
 634     block(blocker, User.get_by_ap_id(ap_id))
 635   end
 636
 637   def unblock(blocker, %{ap_id: ap_id}) do
 638     info_cng =
 639       blocker.info
 640       |> User.Info.remove_from_block(ap_id)
 641
 642     cng =
 643       change(blocker)
 644       |> put_embed(:info, info_cng)
 645
 646     update_and_set_cache(cng)
 647   end
 648
 649   def blocks?(user, %{ap_id: ap_id}) do
 650     blocks = user.info.blocks
 651     domain_blocks = user.info.domain_blocks
 652     %{host: host} = URI.parse(ap_id)
 653
 654     Enum.member?(blocks, ap_id) ||
 655       Enum.any?(domain_blocks, fn domain ->
 656         host == domain
 657       end)
 658   end
 659
 660   def block_domain(user, domain) do
 661     info_cng =
 662       user.info
 663       |> User.Info.add_to_domain_block(domain)
 664
 665     cng =
 666       change(user)
 667       |> put_embed(:info, info_cng)
 668
 669     update_and_set_cache(cng)
 670   end
 671
 672   def unblock_domain(user, domain) do
 673     info_cng =
 674       user.info
 675       |> User.Info.remove_from_domain_block(domain)
 676
 677     cng =
 678       change(user)
 679       |> put_embed(:info, info_cng)
 680
 681     update_and_set_cache(cng)
 682   end
 683
 684   def local_user_query() do
 685     from(
 686       u in User,
 687       where: u.local == true,
 688       where: not is_nil(u.nickname)
 689     )
 690   end
 691
 692   def moderator_user_query() do
 693     from(
 694       u in User,
 695       where: u.local == true,
 696       where: fragment("?->'is_moderator' @> 'true'", u.info)
 697     )
 698   end
 699
 700   def deactivate(%User{} = user, status \\ true) do
 701     info_cng = User.Info.set_activation_status(user.info, status)
 702
 703     cng =
 704       change(user)
 705       |> put_embed(:info, info_cng)
 706
 707     update_and_set_cache(cng)
 708   end
 709
 710   def delete(%User{} = user) do
 711     {:ok, user} = User.deactivate(user)
 712
 713     # Remove all relationships
 714     {:ok, followers} = User.get_followers(user)
 715
 716     followers
 717     |> Enum.each(fn follower -> User.unfollow(follower, user) end)
 718
 719     {:ok, friends} = User.get_friends(user)
 720
 721     friends
 722     |> Enum.each(fn followed -> User.unfollow(user, followed) end)
 723
 724     query = from(a in Activity, where: a.actor == ^user.ap_id)
 725
 726     Repo.all(query)
 727     |> Enum.each(fn activity ->
 728       case activity.data["type"] do
 729         "Create" ->
 730           ActivityPub.delete(Object.normalize(activity.data["object"]))
 731
 732         # TODO: Do something with likes, follows, repeats.
 733         _ ->
 734           "Doing nothing"
 735       end
 736     end)
 737
 738     {:ok, user}
 739   end
 740
 741   def html_filter_policy(%User{info: %{no_rich_text: true}}) do
 742     Pleroma.HTML.Scrubber.TwitterText
 743   end
 744
 745   def html_filter_policy(_), do: nil
 746
 747   def get_or_fetch_by_ap_id(ap_id) do
 748     user = get_by_ap_id(ap_id)
 749
 750     if !is_nil(user) and !User.needs_update?(user) do
 751       user
 752     else
 753       ap_try = ActivityPub.make_user_from_ap_id(ap_id)
 754
 755       case ap_try do
 756         {:ok, user} ->
 757           user
 758
 759         _ ->
 760           case OStatus.make_user(ap_id) do
 761             {:ok, user} -> user
 762             _ -> {:error, "Could not fetch by AP id"}
 763           end
 764       end
 765     end
 766   end
 767
 768   def get_or_create_instance_user do
 769     relay_uri = "#{Pleroma.Web.Endpoint.url()}/relay"
 770
 771     if user = get_by_ap_id(relay_uri) do
 772       user
 773     else
 774       changes =
 775         %User{info: %User.Info{}}
 776         |> cast(%{}, [:ap_id, :nickname, :local])
 777         |> put_change(:ap_id, relay_uri)
 778         |> put_change(:nickname, nil)
 779         |> put_change(:local, true)
 780         |> put_change(:follower_address, relay_uri <> "/followers")
 781
 782       {:ok, user} = Repo.insert(changes)
 783       user
 784     end
 785   end
 786
 787   # AP style
 788   def public_key_from_info(%{
 789         source_data: %{"publicKey" => %{"publicKeyPem" => public_key_pem}}
 790       }) do
 791     key =
 792       public_key_pem
 793       |> :public_key.pem_decode()
 794       |> hd()
 795       |> :public_key.pem_entry_decode()
 796
 797     {:ok, key}
 798   end
 799
 800   # OStatus Magic Key
 801   def public_key_from_info(%{magic_key: magic_key}) do
 802     {:ok, Pleroma.Web.Salmon.decode_key(magic_key)}
 803   end
 804
 805   def get_public_key_for_ap_id(ap_id) do
 806     with %User{} = user <- get_or_fetch_by_ap_id(ap_id),
 807          {:ok, public_key} <- public_key_from_info(user.info) do
 808       {:ok, public_key}
 809     else
 810       _ -> :error
 811     end
 812   end
 813
 814   defp blank?(""), do: nil
 815   defp blank?(n), do: n
 816
 817   def insert_or_update_user(data) do
 818     data =
 819       data
 820       |> Map.put(:name, blank?(data[:name]) || data[:nickname])
 821
 822     cs = User.remote_user_creation(data)
 823
 824     Repo.insert(cs, on_conflict: :replace_all, conflict_target: :nickname)
 825   end
 826
 827   def ap_enabled?(%User{local: true}), do: true
 828   def ap_enabled?(%User{info: info}), do: info.ap_enabled
 829   def ap_enabled?(_), do: false
 830
 831   @doc "Gets or fetch a user by uri or nickname."
 832   @spec get_or_fetch(String.t()) :: User.t()
 833   def get_or_fetch("http" <> _host = uri), do: get_or_fetch_by_ap_id(uri)
 834   def get_or_fetch(nickname), do: get_or_fetch_by_nickname(nickname)
 835
 836   # wait a period of time and return newest version of the User structs
 837   # this is because we have synchronous follow APIs and need to simulate them
 838   # with an async handshake
 839   def wait_and_refresh(_, %User{local: true} = a, %User{local: true} = b) do
 840     with %User{} = a <- Repo.get(User, a.id),
 841          %User{} = b <- Repo.get(User, b.id) do
 842       {:ok, a, b}
 843     else
 844       _e ->
 845         :error
 846     end
 847   end
 848
 849   def wait_and_refresh(timeout, %User{} = a, %User{} = b) do
 850     with :ok <- :timer.sleep(timeout),
 851          %User{} = a <- Repo.get(User, a.id),
 852          %User{} = b <- Repo.get(User, b.id) do
 853       {:ok, a, b}
 854     else
 855       _e ->
 856         :error
 857     end
 858   end
 859
 860   def parse_bio(bio, user \\ %User{info: %{source_data: %{}}})
 861   def parse_bio(nil, _user), do: ""
 862   def parse_bio(bio, _user) when bio == "", do: bio
 863
 864   def parse_bio(bio, user) do
 865     mentions = Formatter.parse_mentions(bio)
 866     tags = Formatter.parse_tags(bio)
 867
 868     emoji =
 869       (user.info.source_data["tag"] || [])
 870       |> Enum.filter(fn %{"type" => t} -> t == "Emoji" end)
 871       |> Enum.map(fn %{"icon" => %{"url" => url}, "name" => name} ->
 872         {String.trim(name, ":"), url}
 873       end)
 874
 875     bio
 876     |> CommonUtils.format_input(mentions, tags, "text/plain")
 877     |> Formatter.emojify(emoji)
 878   end
 879
 880   def tag(user_identifiers, tags) when is_list(user_identifiers) do
 881     Repo.transaction(fn ->
 882       for user_identifier <- user_identifiers, do: tag(user_identifier, tags)
 883     end)
 884   end
 885
 886   def tag(nickname, tags) when is_binary(nickname),
 887     do: tag(User.get_by_nickname(nickname), tags)
 888
 889   def tag(%User{} = user, tags),
 890     do: update_tags(user, Enum.uniq((user.tags || []) ++ normalize_tags(tags)))
 891
 892   def untag(user_identifiers, tags) when is_list(user_identifiers) do
 893     Repo.transaction(fn ->
 894       for user_identifier <- user_identifiers, do: untag(user_identifier, tags)
 895     end)
 896   end
 897
 898   def untag(nickname, tags) when is_binary(nickname),
 899     do: untag(User.get_by_nickname(nickname), tags)
 900
 901   def untag(%User{} = user, tags),
 902     do: update_tags(user, (user.tags || []) -- normalize_tags(tags))
 903
 904   defp update_tags(%User{} = user, new_tags) do
 905     {:ok, updated_user} =
 906       user
 907       |> change(%{tags: new_tags})
 908       |> Repo.update()
 909
 910     updated_user
 911   end
 912
 913   defp normalize_tags(tags) do
 914     [tags]
 915     |> List.flatten()
 916     |> Enum.map(&String.downcase(&1))
 917   end
 918
 919   defp local_nickname_regex() do
 920     if Pleroma.Config.get([:instance, :extended_nickname_format]) do
 921       @extended_local_nickname_regex
 922     else
 923       @strict_local_nickname_regex
 924     end
 925   end
 926 end