git.squeep.com Git - akkoma/blob - lib/pleroma/user.ex

   1 defmodule Pleroma.User do
   2   use Ecto.Schema
   3
   4   import Ecto.{Changeset, Query}
   5   alias Pleroma.{Repo, User, Object, Web, Activity, Notification}
   6   alias Comeonin.Pbkdf2
   7   alias Pleroma.Formatter
   8   alias Pleroma.Web.CommonAPI.Utils, as: CommonUtils
   9   alias Pleroma.Web.{OStatus, Websub, OAuth}
  10   alias Pleroma.Web.ActivityPub.{Utils, ActivityPub}
  11
  12   schema "users" do
  13     field(:bio, :string)
  14     field(:email, :string)
  15     field(:name, :string)
  16     field(:nickname, :string)
  17     field(:password_hash, :string)
  18     field(:password, :string, virtual: true)
  19     field(:password_confirmation, :string, virtual: true)
  20     field(:following, {:array, :string}, default: [])
  21     field(:ap_id, :string)
  22     field(:avatar, :map)
  23     field(:local, :boolean, default: true)
  24     field(:follower_address, :string)
  25     field(:search_distance, :float, virtual: true)
  26     field(:tags, {:array, :string}, default: [])
  27     field(:last_refreshed_at, :naive_datetime)
  28     has_many(:notifications, Notification)
  29     embeds_one(:info, Pleroma.User.Info)
  30
  31     timestamps()
  32   end
  33
  34   def avatar_url(user) do
  35     case user.avatar do
  36       %{"url" => [%{"href" => href} | _]} -> href
  37       _ -> "#{Web.base_url()}/images/avi.png"
  38     end
  39   end
  40
  41   def banner_url(user) do
  42     case user.info.banner do
  43       %{"url" => [%{"href" => href} | _]} -> href
  44       _ -> "#{Web.base_url()}/images/banner.png"
  45     end
  46   end
  47
  48   def profile_url(%User{info: %{source_data: %{"url" => url}}}), do: url
  49   def profile_url(%User{ap_id: ap_id}), do: ap_id
  50   def profile_url(_), do: nil
  51
  52   def ap_id(%User{nickname: nickname}) do
  53     "#{Web.base_url()}/users/#{nickname}"
  54   end
  55
  56   def ap_followers(%User{} = user) do
  57     "#{ap_id(user)}/followers"
  58   end
  59
  60   def follow_changeset(struct, params \\ %{}) do
  61     struct
  62     |> cast(params, [:following])
  63     |> validate_required([:following])
  64   end
  65
  66   def info_changeset(struct, params \\ %{}) do
  67     raise "NOT VALID ANYMORE"
  68   end
  69
  70   def user_info(%User{} = user) do
  71     oneself = if user.local, do: 1, else: 0
  72
  73     %{
  74       following_count: length(user.following) - oneself,
  75       note_count: user.info.note_count,
  76       follower_count: user.info.follower_count,
  77       locked: user.info.locked,
  78       default_scope: user.info.default_scope
  79     }
  80   end
  81
  82   @email_regex ~r/^[a-zA-Z0-9.!#$%&'*+\/=?^_`{|}~-]+@[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?(?:\.[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?)*$/
  83   def remote_user_creation(params) do
  84     params =
  85       params
  86       |> Map.put(:info, params[:info] || %{})
  87
  88     info_cng = User.Info.remote_user_creation(%User.Info{}, params[:info])
  89
  90     changes =
  91       %User{}
  92       |> cast(params, [:bio, :name, :ap_id, :nickname, :avatar])
  93       |> validate_required([:name, :ap_id])
  94       |> unique_constraint(:nickname)
  95       |> validate_format(:nickname, @email_regex)
  96       |> validate_length(:bio, max: 5000)
  97       |> validate_length(:name, max: 100)
  98       |> put_change(:local, false)
  99       |> put_embed(:info, info_cng)
 100
 101     if changes.valid? do
 102       case info_cng.changes[:source_data] do
 103         %{"followers" => followers} ->
 104           changes
 105           |> put_change(:follower_address, followers)
 106
 107         _ ->
 108           followers = User.ap_followers(%User{nickname: changes.changes[:nickname]})
 109
 110           changes
 111           |> put_change(:follower_address, followers)
 112       end
 113     else
 114       changes
 115     end
 116   end
 117
 118   def update_changeset(struct, params \\ %{}) do
 119     struct
 120     |> cast(params, [:bio, :name, :avatar])
 121     |> unique_constraint(:nickname)
 122     |> validate_format(:nickname, ~r/^[a-zA-Z\d]+$/)
 123     |> validate_length(:bio, max: 5000)
 124     |> validate_length(:name, min: 1, max: 100)
 125   end
 126
 127   def upgrade_changeset(struct, params \\ %{}) do
 128     params =
 129       params
 130       |> Map.put(:last_refreshed_at, NaiveDateTime.utc_now())
 131
 132     info_cng =
 133       struct.info
 134       |> User.Info.user_upgrade(params[:info])
 135
 136     struct
 137     |> cast(params, [:bio, :name, :follower_address, :avatar, :last_refreshed_at])
 138     |> unique_constraint(:nickname)
 139     |> validate_format(:nickname, ~r/^[a-zA-Z\d]+$/)
 140     |> validate_length(:bio, max: 5000)
 141     |> validate_length(:name, max: 100)
 142     |> put_embed(:info, info_cng)
 143   end
 144
 145   def password_update_changeset(struct, params) do
 146     changeset =
 147       struct
 148       |> cast(params, [:password, :password_confirmation])
 149       |> validate_required([:password, :password_confirmation])
 150       |> validate_confirmation(:password)
 151
 152     OAuth.Token.delete_user_tokens(struct)
 153     OAuth.Authorization.delete_user_authorizations(struct)
 154
 155     if changeset.valid? do
 156       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 157
 158       changeset
 159       |> put_change(:password_hash, hashed)
 160     else
 161       changeset
 162     end
 163   end
 164
 165   def reset_password(user, data) do
 166     update_and_set_cache(password_update_changeset(user, data))
 167   end
 168
 169   def register_changeset(struct, params \\ %{}) do
 170     changeset =
 171       struct
 172       |> cast(params, [:bio, :email, :name, :nickname, :password, :password_confirmation])
 173       |> validate_required([:email, :name, :nickname, :password, :password_confirmation])
 174       |> validate_confirmation(:password)
 175       |> unique_constraint(:email)
 176       |> unique_constraint(:nickname)
 177       |> validate_format(:nickname, ~r/^[a-zA-Z\d]+$/)
 178       |> validate_format(:email, @email_regex)
 179       |> validate_length(:bio, max: 1000)
 180       |> validate_length(:name, min: 1, max: 100)
 181       |> put_change(:info, %Pleroma.User.Info{})
 182
 183     if changeset.valid? do
 184       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 185       ap_id = User.ap_id(%User{nickname: changeset.changes[:nickname]})
 186       followers = User.ap_followers(%User{nickname: changeset.changes[:nickname]})
 187
 188       changeset
 189       |> put_change(:password_hash, hashed)
 190       |> put_change(:ap_id, ap_id)
 191       |> put_change(:following, [followers])
 192       |> put_change(:follower_address, followers)
 193     else
 194       changeset
 195     end
 196   end
 197
 198   def needs_update?(%User{local: true}), do: false
 199
 200   def needs_update?(%User{local: false, last_refreshed_at: nil}), do: true
 201
 202   def needs_update?(%User{local: false} = user) do
 203     NaiveDateTime.diff(NaiveDateTime.utc_now(), user.last_refreshed_at) >= 86400
 204   end
 205
 206   def needs_update?(_), do: true
 207
 208   def maybe_direct_follow(%User{} = follower, %User{local: true, info: %{locked: true}}) do
 209     {:ok, follower}
 210   end
 211
 212   def maybe_direct_follow(%User{} = follower, %User{local: true} = followed) do
 213     follow(follower, followed)
 214   end
 215
 216   def maybe_direct_follow(%User{} = follower, %User{} = followed) do
 217     if !User.ap_enabled?(followed) do
 218       follow(follower, followed)
 219     else
 220       {:ok, follower}
 221     end
 222   end
 223
 224   def maybe_follow(%User{} = follower, %User{info: info} = followed) do
 225     if not following?(follower, followed) do
 226       follow(follower, followed)
 227     else
 228       {:ok, follower}
 229     end
 230   end
 231
 232   def follow(%User{} = follower, %User{info: info} = followed) do
 233     user_config = Application.get_env(:pleroma, :user)
 234     deny_follow_blocked = Keyword.get(user_config, :deny_follow_blocked)
 235
 236     ap_followers = followed.follower_address
 237
 238     cond do
 239       following?(follower, followed) or info.deactivated ->
 240         {:error, "Could not follow user: #{followed.nickname} is already on your list."}
 241
 242       deny_follow_blocked and blocks?(followed, follower) ->
 243         {:error, "Could not follow user: #{followed.nickname} blocked you."}
 244
 245       true ->
 246         if !followed.local && follower.local && !ap_enabled?(followed) do
 247           Websub.subscribe(follower, followed)
 248         end
 249
 250         following =
 251           [ap_followers | follower.following]
 252           |> Enum.uniq()
 253
 254         follower =
 255           follower
 256           |> follow_changeset(%{following: following})
 257           |> update_and_set_cache
 258
 259         {:ok, _} = update_follower_count(followed)
 260
 261         follower
 262     end
 263   end
 264
 265   def unfollow(%User{} = follower, %User{} = followed) do
 266     ap_followers = followed.follower_address
 267
 268     if following?(follower, followed) and follower.ap_id != followed.ap_id do
 269       following =
 270         follower.following
 271         |> List.delete(ap_followers)
 272
 273       {:ok, follower} =
 274         follower
 275         |> follow_changeset(%{following: following})
 276         |> update_and_set_cache
 277
 278       {:ok, followed} = update_follower_count(followed)
 279
 280       {:ok, follower, Utils.fetch_latest_follow(follower, followed)}
 281     else
 282       {:error, "Not subscribed!"}
 283     end
 284   end
 285
 286   def following?(%User{} = follower, %User{} = followed) do
 287     Enum.member?(follower.following, followed.follower_address)
 288   end
 289
 290   def locked?(%User{} = user) do
 291     user.info.locked || false
 292   end
 293
 294   def get_by_ap_id(ap_id) do
 295     Repo.get_by(User, ap_id: ap_id)
 296   end
 297
 298   def update_and_set_cache(changeset) do
 299     with {:ok, user} <- Repo.update(changeset) do
 300       Cachex.put(:user_cache, "ap_id:#{user.ap_id}", user)
 301       Cachex.put(:user_cache, "nickname:#{user.nickname}", user)
 302       Cachex.put(:user_cache, "user_info:#{user.id}", user_info(user))
 303       {:ok, user}
 304     else
 305       e -> e
 306     end
 307   end
 308
 309   def invalidate_cache(user) do
 310     Cachex.del(:user_cache, "ap_id:#{user.ap_id}")
 311     Cachex.del(:user_cache, "nickname:#{user.nickname}")
 312     Cachex.del(:user_cache, "user_info:#{user.id}")
 313   end
 314
 315   def get_cached_by_ap_id(ap_id) do
 316     key = "ap_id:#{ap_id}"
 317     Cachex.fetch!(:user_cache, key, fn _ -> get_by_ap_id(ap_id) end)
 318   end
 319
 320   def get_cached_by_nickname(nickname) do
 321     key = "nickname:#{nickname}"
 322     Cachex.fetch!(:user_cache, key, fn _ -> get_or_fetch_by_nickname(nickname) end)
 323   end
 324
 325   def get_by_nickname(nickname) do
 326     Repo.get_by(User, nickname: nickname)
 327   end
 328
 329   def get_by_nickname_or_email(nickname_or_email) do
 330     case user = Repo.get_by(User, nickname: nickname_or_email) do
 331       %User{} -> user
 332       nil -> Repo.get_by(User, email: nickname_or_email)
 333     end
 334   end
 335
 336   def get_cached_user_info(user) do
 337     key = "user_info:#{user.id}"
 338     Cachex.fetch!(:user_cache, key, fn _ -> user_info(user) end)
 339   end
 340
 341   def fetch_by_nickname(nickname) do
 342     ap_try = ActivityPub.make_user_from_nickname(nickname)
 343
 344     case ap_try do
 345       {:ok, user} -> {:ok, user}
 346       _ -> OStatus.make_user(nickname)
 347     end
 348   end
 349
 350   def get_or_fetch_by_nickname(nickname) do
 351     with %User{} = user <- get_by_nickname(nickname) do
 352       user
 353     else
 354       _e ->
 355         with [_nick, _domain] <- String.split(nickname, "@"),
 356              {:ok, user} <- fetch_by_nickname(nickname) do
 357           user
 358         else
 359           _e -> nil
 360         end
 361     end
 362   end
 363
 364   def get_followers_query(%User{id: id, follower_address: follower_address}) do
 365     from(
 366       u in User,
 367       where: fragment("? <@ ?", ^[follower_address], u.following),
 368       where: u.id != ^id
 369     )
 370   end
 371
 372   def get_followers(user) do
 373     q = get_followers_query(user)
 374
 375     {:ok, Repo.all(q)}
 376   end
 377
 378   def get_friends_query(%User{id: id, following: following}) do
 379     from(
 380       u in User,
 381       where: u.follower_address in ^following,
 382       where: u.id != ^id
 383     )
 384   end
 385
 386   def get_friends(user) do
 387     q = get_friends_query(user)
 388
 389     {:ok, Repo.all(q)}
 390   end
 391
 392   def get_follow_requests_query(%User{} = user) do
 393     from(
 394       a in Activity,
 395       where:
 396         fragment(
 397           "? ->> 'type' = 'Follow'",
 398           a.data
 399         ),
 400       where:
 401         fragment(
 402           "? ->> 'state' = 'pending'",
 403           a.data
 404         ),
 405       where:
 406         fragment(
 407           "? @> ?",
 408           a.data,
 409           ^%{"object" => user.ap_id}
 410         )
 411     )
 412   end
 413
 414   def get_follow_requests(%User{} = user) do
 415     q = get_follow_requests_query(user)
 416     reqs = Repo.all(q)
 417
 418     users =
 419       Enum.map(reqs, fn req -> req.actor end)
 420       |> Enum.uniq()
 421       |> Enum.map(fn ap_id -> get_by_ap_id(ap_id) end)
 422       |> Enum.filter(fn u -> !following?(u, user) end)
 423
 424     {:ok, users}
 425   end
 426
 427   def increase_note_count(%User{} = user) do
 428     info_cng = User.Info.add_to_note_count(user.info, 1)
 429
 430     cng =
 431       change(user)
 432       |> put_embed(:info, info_cng)
 433
 434     update_and_set_cache(cng)
 435   end
 436
 437   def decrease_note_count(%User{} = user) do
 438     info_cng = User.Info.add_to_note_count(user.info, -1)
 439
 440     cng =
 441       change(user)
 442       |> put_embed(:info, info_cng)
 443
 444     update_and_set_cache(cng)
 445   end
 446
 447   def update_note_count(%User{} = user) do
 448     note_count_query =
 449       from(
 450         a in Object,
 451         where: fragment("?->>'actor' = ? and ?->>'type' = 'Note'", a.data, ^user.ap_id, a.data),
 452         select: count(a.id)
 453       )
 454
 455     note_count = Repo.one(note_count_query)
 456
 457     info_cng = User.Info.set_note_count(user.info, note_count)
 458
 459     cng =
 460       change(user)
 461       |> put_embed(:info, info_cng)
 462
 463     update_and_set_cache(cng)
 464   end
 465
 466   def update_follower_count(%User{} = user) do
 467     follower_count_query =
 468       from(
 469         u in User,
 470         where: ^user.follower_address in u.following,
 471         where: u.id != ^user.id,
 472         select: count(u.id)
 473       )
 474
 475     follower_count = Repo.one(follower_count_query)
 476
 477     info_cng =
 478       user.info
 479       |> User.Info.set_follower_count(follower_count)
 480
 481     cng =
 482       change(user)
 483       |> put_embed(:info, info_cng)
 484
 485     update_and_set_cache(cng)
 486   end
 487
 488   def get_users_from_set_query(ap_ids, false) do
 489     from(
 490       u in User,
 491       where: u.ap_id in ^ap_ids
 492     )
 493   end
 494
 495   def get_users_from_set_query(ap_ids, true) do
 496     query = get_users_from_set_query(ap_ids, false)
 497
 498     from(
 499       u in query,
 500       where: u.local == true
 501     )
 502   end
 503
 504   def get_users_from_set(ap_ids, local_only \\ true) do
 505     get_users_from_set_query(ap_ids, local_only)
 506     |> Repo.all()
 507   end
 508
 509   def get_recipients_from_activity(%Activity{recipients: to}) do
 510     query =
 511       from(
 512         u in User,
 513         where: u.ap_id in ^to,
 514         or_where: fragment("? && ?", u.following, ^to)
 515       )
 516
 517     query = from(u in query, where: u.local == true)
 518
 519     Repo.all(query)
 520   end
 521
 522   def search(query, resolve \\ false) do
 523     # strip the beginning @ off if there is a query
 524     query = String.trim_leading(query, "@")
 525
 526     if resolve do
 527       User.get_or_fetch_by_nickname(query)
 528     end
 529
 530     inner =
 531       from(
 532         u in User,
 533         select_merge: %{
 534           search_distance:
 535             fragment(
 536               "? <-> (? || ?)",
 537               ^query,
 538               u.nickname,
 539               u.name
 540             )
 541         },
 542         where: not is_nil(u.nickname)
 543       )
 544
 545     q =
 546       from(
 547         s in subquery(inner),
 548         order_by: s.search_distance,
 549         limit: 20
 550       )
 551
 552     Repo.all(q)
 553   end
 554
 555   def block(blocker, %User{ap_id: ap_id} = blocked) do
 556     # sever any follow relationships to prevent leaks per activitypub (Pleroma issue #213)
 557     blocker =
 558       if following?(blocker, blocked) do
 559         {:ok, blocker, _} = unfollow(blocker, blocked)
 560         blocker
 561       else
 562         blocker
 563       end
 564
 565     if following?(blocked, blocker) do
 566       unfollow(blocked, blocker)
 567     end
 568
 569     info_cng =
 570       blocker.info
 571       |> User.Info.add_to_block(ap_id)
 572
 573     cng =
 574       change(blocker)
 575       |> put_embed(:info, info_cng)
 576
 577     update_and_set_cache(cng)
 578   end
 579
 580   # helper to handle the block given only an actor's AP id
 581   def block(blocker, %{ap_id: ap_id}) do
 582     block(blocker, User.get_by_ap_id(ap_id))
 583   end
 584
 585   def unblock(blocker, %{ap_id: ap_id}) do
 586     info_cng =
 587       blocker.info
 588       |> User.Info.remove_from_block(ap_id)
 589
 590     cng =
 591       change(blocker)
 592       |> put_embed(:info, info_cng)
 593
 594     update_and_set_cache(cng)
 595   end
 596
 597   def blocks?(user, %{ap_id: ap_id}) do
 598     blocks = user.info.blocks
 599     domain_blocks = user.info.domain_blocks
 600     %{host: host} = URI.parse(ap_id)
 601
 602     Enum.member?(blocks, ap_id) ||
 603       Enum.any?(domain_blocks, fn domain ->
 604         host == domain
 605       end)
 606   end
 607
 608   def block_domain(user, domain) do
 609     info_cng =
 610       user.info
 611       |> User.Info.add_to_domain_block(domain)
 612
 613     cng =
 614       change(user)
 615       |> put_embed(:info, info_cng)
 616
 617     update_and_set_cache(cng)
 618   end
 619
 620   def unblock_domain(user, domain) do
 621     info_cng =
 622       user.info
 623       |> User.Info.remove_from_domain_block(domain)
 624
 625     cng =
 626       change(user)
 627       |> put_embed(:info, info_cng)
 628
 629     update_and_set_cache(cng)
 630   end
 631
 632   def local_user_query() do
 633     from(
 634       u in User,
 635       where: u.local == true,
 636       where: not is_nil(u.nickname)
 637     )
 638   end
 639
 640   def moderator_user_query() do
 641     from(
 642       u in User,
 643       where: u.local == true,
 644       where: fragment("?->'is_moderator' @> 'true'", u.info)
 645     )
 646   end
 647
 648   def deactivate(%User{} = user, status \\ true) do
 649     info_cng = User.Info.set_activation_status(user.info, status)
 650
 651     cng =
 652       change(user)
 653       |> put_embed(:info, info_cng)
 654
 655     update_and_set_cache(cng)
 656   end
 657
 658   def delete(%User{} = user) do
 659     {:ok, user} = User.deactivate(user)
 660
 661     # Remove all relationships
 662     {:ok, followers} = User.get_followers(user)
 663
 664     followers
 665     |> Enum.each(fn follower -> User.unfollow(follower, user) end)
 666
 667     {:ok, friends} = User.get_friends(user)
 668
 669     friends
 670     |> Enum.each(fn followed -> User.unfollow(user, followed) end)
 671
 672     query = from(a in Activity, where: a.actor == ^user.ap_id)
 673
 674     Repo.all(query)
 675     |> Enum.each(fn activity ->
 676       case activity.data["type"] do
 677         "Create" ->
 678           ActivityPub.delete(Object.normalize(activity.data["object"]))
 679
 680         # TODO: Do something with likes, follows, repeats.
 681         _ ->
 682           "Doing nothing"
 683       end
 684     end)
 685
 686     {:ok, user}
 687   end
 688
 689   def html_filter_policy(%User{info: %{no_rich_text: true}}) do
 690     Pleroma.HTML.Scrubber.TwitterText
 691   end
 692
 693   def html_filter_policy(_), do: nil
 694
 695   def get_or_fetch_by_ap_id(ap_id) do
 696     user = get_by_ap_id(ap_id)
 697
 698     if !is_nil(user) and !User.needs_update?(user) do
 699       user
 700     else
 701       ap_try = ActivityPub.make_user_from_ap_id(ap_id)
 702
 703       case ap_try do
 704         {:ok, user} ->
 705           user
 706
 707         _ ->
 708           case OStatus.make_user(ap_id) do
 709             {:ok, user} -> user
 710             _ -> {:error, "Could not fetch by AP id"}
 711           end
 712       end
 713     end
 714   end
 715
 716   def get_or_create_instance_user do
 717     relay_uri = "#{Pleroma.Web.Endpoint.url()}/relay"
 718
 719     if user = get_by_ap_id(relay_uri) do
 720       user
 721     else
 722       changes =
 723         %User{info: %User.Info{}}
 724         |> cast(%{}, [:ap_id, :nickname, :local])
 725         |> put_change(:ap_id, relay_uri)
 726         |> put_change(:nickname, nil)
 727         |> put_change(:local, true)
 728         |> put_change(:follower_address, relay_uri <> "/followers")
 729
 730       {:ok, user} = Repo.insert(changes)
 731       user
 732     end
 733   end
 734
 735   # AP style
 736   def public_key_from_info(%{
 737         source_data: %{"publicKey" => %{"publicKeyPem" => public_key_pem}}
 738       }) do
 739     key =
 740       :public_key.pem_decode(public_key_pem)
 741       |> hd()
 742       |> :public_key.pem_entry_decode()
 743
 744     {:ok, key}
 745   end
 746
 747   # OStatus Magic Key
 748   def public_key_from_info(%{magic_key: magic_key}) do
 749     {:ok, Pleroma.Web.Salmon.decode_key(magic_key)}
 750   end
 751
 752   def get_public_key_for_ap_id(ap_id) do
 753     with %User{} = user <- get_or_fetch_by_ap_id(ap_id),
 754          {:ok, public_key} <- public_key_from_info(user.info) do
 755       {:ok, public_key}
 756     else
 757       _ -> :error
 758     end
 759   end
 760
 761   defp blank?(""), do: nil
 762   defp blank?(n), do: n
 763
 764   def insert_or_update_user(data) do
 765     data =
 766       data
 767       |> Map.put(:name, blank?(data[:name]) || data[:nickname])
 768
 769     cs = User.remote_user_creation(data)
 770
 771     Repo.insert(cs, on_conflict: :replace_all, conflict_target: :nickname)
 772   end
 773
 774   def ap_enabled?(%User{local: true}), do: true
 775   def ap_enabled?(%User{info: info}), do: info.ap_enabled
 776   def ap_enabled?(_), do: false
 777
 778   def get_or_fetch(uri_or_nickname) do
 779     if String.starts_with?(uri_or_nickname, "http") do
 780       get_or_fetch_by_ap_id(uri_or_nickname)
 781     else
 782       get_or_fetch_by_nickname(uri_or_nickname)
 783     end
 784   end
 785
 786   # wait a period of time and return newest version of the User structs
 787   # this is because we have synchronous follow APIs and need to simulate them
 788   # with an async handshake
 789   def wait_and_refresh(_, %User{local: true} = a, %User{local: true} = b) do
 790     with %User{} = a <- Repo.get(User, a.id),
 791          %User{} = b <- Repo.get(User, b.id) do
 792       {:ok, a, b}
 793     else
 794       _e ->
 795         :error
 796     end
 797   end
 798
 799   def wait_and_refresh(timeout, %User{} = a, %User{} = b) do
 800     with :ok <- :timer.sleep(timeout),
 801          %User{} = a <- Repo.get(User, a.id),
 802          %User{} = b <- Repo.get(User, b.id) do
 803       {:ok, a, b}
 804     else
 805       _e ->
 806         :error
 807     end
 808   end
 809
 810   def parse_bio(bio, user \\ %User{info: %{source_data: %{}}}) do
 811     mentions = Formatter.parse_mentions(bio)
 812     tags = Formatter.parse_tags(bio)
 813
 814     emoji =
 815       (user.info.source_data["tag"] || [])
 816       |> Enum.filter(fn %{"type" => t} -> t == "Emoji" end)
 817       |> Enum.map(fn %{"icon" => %{"url" => url}, "name" => name} ->
 818         {String.trim(name, ":"), url}
 819       end)
 820
 821     CommonUtils.format_input(bio, mentions, tags, "text/plain") |> Formatter.emojify(emoji)
 822   end
 823
 824   def tag(user_identifiers, tags), do: tag_or_untag(user_identifiers, tags, :tag)
 825
 826   def untag(user_identifiers, tags), do: tag_or_untag(user_identifiers, tags, :untag)
 827
 828   defp tag_or_untag(user_identifier, tags, action) when not is_list(user_identifier),
 829     do: tag_or_untag([user_identifier], tags, action)
 830
 831   defp tag_or_untag([hd | _] = nicknames, tags, action) when is_binary(hd) do
 832     users = Repo.all(from(u in User, where: u.nickname in ^nicknames))
 833
 834     if length(users) == length(nicknames) do
 835       tag_or_untag(users, tags, action)
 836     else
 837       {:error, :not_found}
 838     end
 839   end
 840
 841   defp tag_or_untag([hd | _] = users, tags, action) when is_map(hd) do
 842     tags =
 843       [tags]
 844       |> List.flatten()
 845       |> Enum.map(&String.downcase(&1))
 846
 847     Repo.transaction(fn ->
 848       for user <- users do
 849         new_tags =
 850           if action == :tag do
 851             Enum.uniq(user.tags ++ tags)
 852           else
 853             user.tags -- tags
 854           end
 855
 856         {:ok, updated_user} =
 857           user
 858           |> change(%{tags: new_tags})
 859           |> Repo.update()
 860
 861         updated_user
 862       end
 863     end)
 864   end
 865 end