git.squeep.com Git - akkoma/blob - lib/pleroma/user.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2018 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.User do
   6   use Ecto.Schema
   7
   8   import Ecto.{Changeset, Query}
   9   alias Pleroma.{Repo, User, Object, Web, Activity, Notification}
  10   alias Comeonin.Pbkdf2
  11   alias Pleroma.Formatter
  12   alias Pleroma.Web.CommonAPI.Utils, as: CommonUtils
  13   alias Pleroma.Web.{OStatus, Websub, OAuth}
  14   alias Pleroma.Web.ActivityPub.{Utils, ActivityPub}
  15
  16   @type t :: %__MODULE__{}
  17
  18   @email_regex ~r/^[a-zA-Z0-9.!#$%&'*+\/=?^_`{|}~-]+@[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?(?:\.[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?)*$/
  19
  20   @strict_local_nickname_regex ~r/^[a-zA-Z\d]+$/
  21   @extended_local_nickname_regex ~r/^[a-zA-Z\d_-]+$/
  22
  23   schema "users" do
  24     field(:bio, :string)
  25     field(:email, :string)
  26     field(:name, :string)
  27     field(:nickname, :string)
  28     field(:password_hash, :string)
  29     field(:password, :string, virtual: true)
  30     field(:password_confirmation, :string, virtual: true)
  31     field(:following, {:array, :string}, default: [])
  32     field(:ap_id, :string)
  33     field(:avatar, :map)
  34     field(:local, :boolean, default: true)
  35     field(:follower_address, :string)
  36     field(:search_distance, :float, virtual: true)
  37     field(:tags, {:array, :string}, default: [])
  38     field(:last_refreshed_at, :naive_datetime)
  39     has_many(:notifications, Notification)
  40     embeds_one(:info, Pleroma.User.Info)
  41
  42     timestamps()
  43   end
  44
  45   def auth_active?(%User{} = user) do
  46     (user.info && !user.info.confirmation_pending) ||
  47       !Pleroma.Config.get([:instance, :account_activation_required])
  48   end
  49
  50   def superuser?(%User{} = user), do: user.info && User.Info.superuser?(user.info)
  51
  52   def avatar_url(user) do
  53     case user.avatar do
  54       %{"url" => [%{"href" => href} | _]} -> href
  55       _ -> "#{Web.base_url()}/images/avi.png"
  56     end
  57   end
  58
  59   def banner_url(user) do
  60     case user.info.banner do
  61       %{"url" => [%{"href" => href} | _]} -> href
  62       _ -> "#{Web.base_url()}/images/banner.png"
  63     end
  64   end
  65
  66   def profile_url(%User{info: %{source_data: %{"url" => url}}}), do: url
  67   def profile_url(%User{ap_id: ap_id}), do: ap_id
  68   def profile_url(_), do: nil
  69
  70   def ap_id(%User{nickname: nickname}) do
  71     "#{Web.base_url()}/users/#{nickname}"
  72   end
  73
  74   def ap_followers(%User{} = user) do
  75     "#{ap_id(user)}/followers"
  76   end
  77
  78   def follow_changeset(struct, params \\ %{}) do
  79     struct
  80     |> cast(params, [:following])
  81     |> validate_required([:following])
  82   end
  83
  84   def user_info(%User{} = user) do
  85     oneself = if user.local, do: 1, else: 0
  86
  87     %{
  88       following_count: length(user.following) - oneself,
  89       note_count: user.info.note_count,
  90       follower_count: user.info.follower_count,
  91       locked: user.info.locked,
  92       confirmation_pending: user.info.confirmation_pending,
  93       default_scope: user.info.default_scope
  94     }
  95   end
  96
  97   def remote_user_creation(params) do
  98     params =
  99       params
 100       |> Map.put(:info, params[:info] || %{})
 101
 102     info_cng = User.Info.remote_user_creation(%User.Info{}, params[:info])
 103
 104     changes =
 105       %User{}
 106       |> cast(params, [:bio, :name, :ap_id, :nickname, :avatar])
 107       |> validate_required([:name, :ap_id])
 108       |> unique_constraint(:nickname)
 109       |> validate_format(:nickname, @email_regex)
 110       |> validate_length(:bio, max: 5000)
 111       |> validate_length(:name, max: 100)
 112       |> put_change(:local, false)
 113       |> put_embed(:info, info_cng)
 114
 115     if changes.valid? do
 116       case info_cng.changes[:source_data] do
 117         %{"followers" => followers} ->
 118           changes
 119           |> put_change(:follower_address, followers)
 120
 121         _ ->
 122           followers = User.ap_followers(%User{nickname: changes.changes[:nickname]})
 123
 124           changes
 125           |> put_change(:follower_address, followers)
 126       end
 127     else
 128       changes
 129     end
 130   end
 131
 132   def update_changeset(struct, params \\ %{}) do
 133     struct
 134     |> cast(params, [:bio, :name, :avatar])
 135     |> unique_constraint(:nickname)
 136     |> validate_format(:nickname, local_nickname_regex())
 137     |> validate_length(:bio, max: 5000)
 138     |> validate_length(:name, min: 1, max: 100)
 139   end
 140
 141   def upgrade_changeset(struct, params \\ %{}) do
 142     params =
 143       params
 144       |> Map.put(:last_refreshed_at, NaiveDateTime.utc_now())
 145
 146     info_cng =
 147       struct.info
 148       |> User.Info.user_upgrade(params[:info])
 149
 150     struct
 151     |> cast(params, [:bio, :name, :follower_address, :avatar, :last_refreshed_at])
 152     |> unique_constraint(:nickname)
 153     |> validate_format(:nickname, local_nickname_regex())
 154     |> validate_length(:bio, max: 5000)
 155     |> validate_length(:name, max: 100)
 156     |> put_embed(:info, info_cng)
 157   end
 158
 159   def password_update_changeset(struct, params) do
 160     changeset =
 161       struct
 162       |> cast(params, [:password, :password_confirmation])
 163       |> validate_required([:password, :password_confirmation])
 164       |> validate_confirmation(:password)
 165
 166     OAuth.Token.delete_user_tokens(struct)
 167     OAuth.Authorization.delete_user_authorizations(struct)
 168
 169     if changeset.valid? do
 170       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 171
 172       changeset
 173       |> put_change(:password_hash, hashed)
 174     else
 175       changeset
 176     end
 177   end
 178
 179   def reset_password(user, data) do
 180     update_and_set_cache(password_update_changeset(user, data))
 181   end
 182
 183   def register_changeset(struct, params \\ %{}, opts \\ []) do
 184     confirmation_status =
 185       if opts[:confirmed] || !Pleroma.Config.get([:instance, :account_activation_required]) do
 186         :confirmed
 187       else
 188         :unconfirmed
 189       end
 190
 191     info_change = User.Info.confirmation_changeset(%User.Info{}, confirmation_status)
 192
 193     changeset =
 194       struct
 195       |> cast(params, [:bio, :email, :name, :nickname, :password, :password_confirmation])
 196       |> validate_required([:email, :name, :nickname, :password, :password_confirmation])
 197       |> validate_confirmation(:password)
 198       |> unique_constraint(:email)
 199       |> unique_constraint(:nickname)
 200       |> validate_format(:nickname, local_nickname_regex())
 201       |> validate_format(:email, @email_regex)
 202       |> validate_length(:bio, max: 1000)
 203       |> validate_length(:name, min: 1, max: 100)
 204       |> put_change(:info, info_change)
 205
 206     if changeset.valid? do
 207       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 208       ap_id = User.ap_id(%User{nickname: changeset.changes[:nickname]})
 209       followers = User.ap_followers(%User{nickname: changeset.changes[:nickname]})
 210
 211       changeset
 212       |> put_change(:password_hash, hashed)
 213       |> put_change(:ap_id, ap_id)
 214       |> put_change(:following, [followers])
 215       |> put_change(:follower_address, followers)
 216     else
 217       changeset
 218     end
 219   end
 220
 221   @doc "Inserts provided changeset, performs post-registration actions (confirmation email sending etc.)"
 222   def register(%Ecto.Changeset{} = changeset) do
 223     with {:ok, user} <- Repo.insert(changeset),
 224          {:ok, _} = try_send_confirmation_email(user) do
 225       {:ok, user}
 226     end
 227   end
 228
 229   def try_send_confirmation_email(%User{} = user) do
 230     if user.info.confirmation_pending &&
 231          Pleroma.Config.get([:instance, :account_activation_required]) do
 232       user
 233       |> Pleroma.UserEmail.account_confirmation_email()
 234       |> Pleroma.Mailer.deliver()
 235     else
 236       {:ok, :noop}
 237     end
 238   end
 239
 240   def needs_update?(%User{local: true}), do: false
 241
 242   def needs_update?(%User{local: false, last_refreshed_at: nil}), do: true
 243
 244   def needs_update?(%User{local: false} = user) do
 245     NaiveDateTime.diff(NaiveDateTime.utc_now(), user.last_refreshed_at) >= 86400
 246   end
 247
 248   def needs_update?(_), do: true
 249
 250   def maybe_direct_follow(%User{} = follower, %User{local: true, info: %{locked: true}}) do
 251     {:ok, follower}
 252   end
 253
 254   def maybe_direct_follow(%User{} = follower, %User{local: true} = followed) do
 255     follow(follower, followed)
 256   end
 257
 258   def maybe_direct_follow(%User{} = follower, %User{} = followed) do
 259     if not User.ap_enabled?(followed) do
 260       follow(follower, followed)
 261     else
 262       {:ok, follower}
 263     end
 264   end
 265
 266   def maybe_follow(%User{} = follower, %User{info: _info} = followed) do
 267     if not following?(follower, followed) do
 268       follow(follower, followed)
 269     else
 270       {:ok, follower}
 271     end
 272   end
 273
 274   def follow(%User{} = follower, %User{info: info} = followed) do
 275     user_config = Application.get_env(:pleroma, :user)
 276     deny_follow_blocked = Keyword.get(user_config, :deny_follow_blocked)
 277
 278     ap_followers = followed.follower_address
 279
 280     cond do
 281       following?(follower, followed) or info.deactivated ->
 282         {:error, "Could not follow user: #{followed.nickname} is already on your list."}
 283
 284       deny_follow_blocked and blocks?(followed, follower) ->
 285         {:error, "Could not follow user: #{followed.nickname} blocked you."}
 286
 287       true ->
 288         if !followed.local && follower.local && !ap_enabled?(followed) do
 289           Websub.subscribe(follower, followed)
 290         end
 291
 292         following =
 293           [ap_followers | follower.following]
 294           |> Enum.uniq()
 295
 296         follower =
 297           follower
 298           |> follow_changeset(%{following: following})
 299           |> update_and_set_cache
 300
 301         {:ok, _} = update_follower_count(followed)
 302
 303         follower
 304     end
 305   end
 306
 307   def unfollow(%User{} = follower, %User{} = followed) do
 308     ap_followers = followed.follower_address
 309
 310     if following?(follower, followed) and follower.ap_id != followed.ap_id do
 311       following =
 312         follower.following
 313         |> List.delete(ap_followers)
 314
 315       {:ok, follower} =
 316         follower
 317         |> follow_changeset(%{following: following})
 318         |> update_and_set_cache
 319
 320       {:ok, followed} = update_follower_count(followed)
 321
 322       {:ok, follower, Utils.fetch_latest_follow(follower, followed)}
 323     else
 324       {:error, "Not subscribed!"}
 325     end
 326   end
 327
 328   @spec following?(User.t(), User.t()) :: boolean
 329   def following?(%User{} = follower, %User{} = followed) do
 330     Enum.member?(follower.following, followed.follower_address)
 331   end
 332
 333   def locked?(%User{} = user) do
 334     user.info.locked || false
 335   end
 336
 337   def get_by_ap_id(ap_id) do
 338     Repo.get_by(User, ap_id: ap_id)
 339   end
 340
 341   def update_and_set_cache(changeset) do
 342     with {:ok, user} <- Repo.update(changeset) do
 343       Cachex.put(:user_cache, "ap_id:#{user.ap_id}", user)
 344       Cachex.put(:user_cache, "nickname:#{user.nickname}", user)
 345       Cachex.put(:user_cache, "user_info:#{user.id}", user_info(user))
 346       {:ok, user}
 347     else
 348       e -> e
 349     end
 350   end
 351
 352   def invalidate_cache(user) do
 353     Cachex.del(:user_cache, "ap_id:#{user.ap_id}")
 354     Cachex.del(:user_cache, "nickname:#{user.nickname}")
 355     Cachex.del(:user_cache, "user_info:#{user.id}")
 356   end
 357
 358   def get_cached_by_ap_id(ap_id) do
 359     key = "ap_id:#{ap_id}"
 360     Cachex.fetch!(:user_cache, key, fn _ -> get_by_ap_id(ap_id) end)
 361   end
 362
 363   def get_cached_by_nickname(nickname) do
 364     key = "nickname:#{nickname}"
 365     Cachex.fetch!(:user_cache, key, fn _ -> get_or_fetch_by_nickname(nickname) end)
 366   end
 367
 368   def get_by_nickname(nickname) do
 369     Repo.get_by(User, nickname: nickname)
 370   end
 371
 372   def get_by_nickname_or_email(nickname_or_email) do
 373     case user = Repo.get_by(User, nickname: nickname_or_email) do
 374       %User{} -> user
 375       nil -> Repo.get_by(User, email: nickname_or_email)
 376     end
 377   end
 378
 379   def get_cached_user_info(user) do
 380     key = "user_info:#{user.id}"
 381     Cachex.fetch!(:user_cache, key, fn _ -> user_info(user) end)
 382   end
 383
 384   def fetch_by_nickname(nickname) do
 385     ap_try = ActivityPub.make_user_from_nickname(nickname)
 386
 387     case ap_try do
 388       {:ok, user} -> {:ok, user}
 389       _ -> OStatus.make_user(nickname)
 390     end
 391   end
 392
 393   def get_or_fetch_by_nickname(nickname) do
 394     with %User{} = user <- get_by_nickname(nickname) do
 395       user
 396     else
 397       _e ->
 398         with [_nick, _domain] <- String.split(nickname, "@"),
 399              {:ok, user} <- fetch_by_nickname(nickname) do
 400           user
 401         else
 402           _e -> nil
 403         end
 404     end
 405   end
 406
 407   def get_followers_query(%User{id: id, follower_address: follower_address}) do
 408     from(
 409       u in User,
 410       where: fragment("? <@ ?", ^[follower_address], u.following),
 411       where: u.id != ^id
 412     )
 413   end
 414
 415   def get_followers(user) do
 416     q = get_followers_query(user)
 417
 418     {:ok, Repo.all(q)}
 419   end
 420
 421   def get_friends_query(%User{id: id, following: following}) do
 422     from(
 423       u in User,
 424       where: u.follower_address in ^following,
 425       where: u.id != ^id
 426     )
 427   end
 428
 429   def get_friends(user) do
 430     q = get_friends_query(user)
 431
 432     {:ok, Repo.all(q)}
 433   end
 434
 435   def get_follow_requests_query(%User{} = user) do
 436     from(
 437       a in Activity,
 438       where:
 439         fragment(
 440           "? ->> 'type' = 'Follow'",
 441           a.data
 442         ),
 443       where:
 444         fragment(
 445           "? ->> 'state' = 'pending'",
 446           a.data
 447         ),
 448       where:
 449         fragment(
 450           "? @> ?",
 451           a.data,
 452           ^%{"object" => user.ap_id}
 453         )
 454     )
 455   end
 456
 457   def get_follow_requests(%User{} = user) do
 458     q = get_follow_requests_query(user)
 459     reqs = Repo.all(q)
 460
 461     users =
 462       Enum.map(reqs, fn req -> req.actor end)
 463       |> Enum.uniq()
 464       |> Enum.map(fn ap_id -> get_by_ap_id(ap_id) end)
 465       |> Enum.filter(fn u -> !following?(u, user) end)
 466
 467     {:ok, users}
 468   end
 469
 470   def increase_note_count(%User{} = user) do
 471     info_cng = User.Info.add_to_note_count(user.info, 1)
 472
 473     cng =
 474       change(user)
 475       |> put_embed(:info, info_cng)
 476
 477     update_and_set_cache(cng)
 478   end
 479
 480   def decrease_note_count(%User{} = user) do
 481     info_cng = User.Info.add_to_note_count(user.info, -1)
 482
 483     cng =
 484       change(user)
 485       |> put_embed(:info, info_cng)
 486
 487     update_and_set_cache(cng)
 488   end
 489
 490   def update_note_count(%User{} = user) do
 491     note_count_query =
 492       from(
 493         a in Object,
 494         where: fragment("?->>'actor' = ? and ?->>'type' = 'Note'", a.data, ^user.ap_id, a.data),
 495         select: count(a.id)
 496       )
 497
 498     note_count = Repo.one(note_count_query)
 499
 500     info_cng = User.Info.set_note_count(user.info, note_count)
 501
 502     cng =
 503       change(user)
 504       |> put_embed(:info, info_cng)
 505
 506     update_and_set_cache(cng)
 507   end
 508
 509   def update_follower_count(%User{} = user) do
 510     follower_count_query =
 511       from(
 512         u in User,
 513         where: ^user.follower_address in u.following,
 514         where: u.id != ^user.id,
 515         select: count(u.id)
 516       )
 517
 518     follower_count = Repo.one(follower_count_query)
 519
 520     info_cng =
 521       user.info
 522       |> User.Info.set_follower_count(follower_count)
 523
 524     cng =
 525       change(user)
 526       |> put_embed(:info, info_cng)
 527
 528     update_and_set_cache(cng)
 529   end
 530
 531   def get_users_from_set_query(ap_ids, false) do
 532     from(
 533       u in User,
 534       where: u.ap_id in ^ap_ids
 535     )
 536   end
 537
 538   def get_users_from_set_query(ap_ids, true) do
 539     query = get_users_from_set_query(ap_ids, false)
 540
 541     from(
 542       u in query,
 543       where: u.local == true
 544     )
 545   end
 546
 547   def get_users_from_set(ap_ids, local_only \\ true) do
 548     get_users_from_set_query(ap_ids, local_only)
 549     |> Repo.all()
 550   end
 551
 552   def get_recipients_from_activity(%Activity{recipients: to}) do
 553     query =
 554       from(
 555         u in User,
 556         where: u.ap_id in ^to,
 557         or_where: fragment("? && ?", u.following, ^to)
 558       )
 559
 560     query = from(u in query, where: u.local == true)
 561
 562     Repo.all(query)
 563   end
 564
 565   def search(query, resolve \\ false) do
 566     # strip the beginning @ off if there is a query
 567     query = String.trim_leading(query, "@")
 568
 569     if resolve do
 570       User.get_or_fetch_by_nickname(query)
 571     end
 572
 573     inner =
 574       from(
 575         u in User,
 576         select_merge: %{
 577           search_distance:
 578             fragment(
 579               "? <-> (? || ?)",
 580               ^query,
 581               u.nickname,
 582               u.name
 583             )
 584         },
 585         where: not is_nil(u.nickname)
 586       )
 587
 588     q =
 589       from(
 590         s in subquery(inner),
 591         order_by: s.search_distance,
 592         limit: 20
 593       )
 594
 595     Repo.all(q)
 596   end
 597
 598   def block(blocker, %User{ap_id: ap_id} = blocked) do
 599     # sever any follow relationships to prevent leaks per activitypub (Pleroma issue #213)
 600     blocker =
 601       if following?(blocker, blocked) do
 602         {:ok, blocker, _} = unfollow(blocker, blocked)
 603         blocker
 604       else
 605         blocker
 606       end
 607
 608     if following?(blocked, blocker) do
 609       unfollow(blocked, blocker)
 610     end
 611
 612     info_cng =
 613       blocker.info
 614       |> User.Info.add_to_block(ap_id)
 615
 616     cng =
 617       change(blocker)
 618       |> put_embed(:info, info_cng)
 619
 620     update_and_set_cache(cng)
 621   end
 622
 623   # helper to handle the block given only an actor's AP id
 624   def block(blocker, %{ap_id: ap_id}) do
 625     block(blocker, User.get_by_ap_id(ap_id))
 626   end
 627
 628   def unblock(blocker, %{ap_id: ap_id}) do
 629     info_cng =
 630       blocker.info
 631       |> User.Info.remove_from_block(ap_id)
 632
 633     cng =
 634       change(blocker)
 635       |> put_embed(:info, info_cng)
 636
 637     update_and_set_cache(cng)
 638   end
 639
 640   def blocks?(user, %{ap_id: ap_id}) do
 641     blocks = user.info.blocks
 642     domain_blocks = user.info.domain_blocks
 643     %{host: host} = URI.parse(ap_id)
 644
 645     Enum.member?(blocks, ap_id) ||
 646       Enum.any?(domain_blocks, fn domain ->
 647         host == domain
 648       end)
 649   end
 650
 651   def block_domain(user, domain) do
 652     info_cng =
 653       user.info
 654       |> User.Info.add_to_domain_block(domain)
 655
 656     cng =
 657       change(user)
 658       |> put_embed(:info, info_cng)
 659
 660     update_and_set_cache(cng)
 661   end
 662
 663   def unblock_domain(user, domain) do
 664     info_cng =
 665       user.info
 666       |> User.Info.remove_from_domain_block(domain)
 667
 668     cng =
 669       change(user)
 670       |> put_embed(:info, info_cng)
 671
 672     update_and_set_cache(cng)
 673   end
 674
 675   def local_user_query() do
 676     from(
 677       u in User,
 678       where: u.local == true,
 679       where: not is_nil(u.nickname)
 680     )
 681   end
 682
 683   def moderator_user_query() do
 684     from(
 685       u in User,
 686       where: u.local == true,
 687       where: fragment("?->'is_moderator' @> 'true'", u.info)
 688     )
 689   end
 690
 691   def deactivate(%User{} = user, status \\ true) do
 692     info_cng = User.Info.set_activation_status(user.info, status)
 693
 694     cng =
 695       change(user)
 696       |> put_embed(:info, info_cng)
 697
 698     update_and_set_cache(cng)
 699   end
 700
 701   def delete(%User{} = user) do
 702     {:ok, user} = User.deactivate(user)
 703
 704     # Remove all relationships
 705     {:ok, followers} = User.get_followers(user)
 706
 707     followers
 708     |> Enum.each(fn follower -> User.unfollow(follower, user) end)
 709
 710     {:ok, friends} = User.get_friends(user)
 711
 712     friends
 713     |> Enum.each(fn followed -> User.unfollow(user, followed) end)
 714
 715     query = from(a in Activity, where: a.actor == ^user.ap_id)
 716
 717     Repo.all(query)
 718     |> Enum.each(fn activity ->
 719       case activity.data["type"] do
 720         "Create" ->
 721           ActivityPub.delete(Object.normalize(activity.data["object"]))
 722
 723         # TODO: Do something with likes, follows, repeats.
 724         _ ->
 725           "Doing nothing"
 726       end
 727     end)
 728
 729     {:ok, user}
 730   end
 731
 732   def html_filter_policy(%User{info: %{no_rich_text: true}}) do
 733     Pleroma.HTML.Scrubber.TwitterText
 734   end
 735
 736   def html_filter_policy(_), do: nil
 737
 738   def get_or_fetch_by_ap_id(ap_id) do
 739     user = get_by_ap_id(ap_id)
 740
 741     if !is_nil(user) and !User.needs_update?(user) do
 742       user
 743     else
 744       ap_try = ActivityPub.make_user_from_ap_id(ap_id)
 745
 746       case ap_try do
 747         {:ok, user} ->
 748           user
 749
 750         _ ->
 751           case OStatus.make_user(ap_id) do
 752             {:ok, user} -> user
 753             _ -> {:error, "Could not fetch by AP id"}
 754           end
 755       end
 756     end
 757   end
 758
 759   def get_or_create_instance_user do
 760     relay_uri = "#{Pleroma.Web.Endpoint.url()}/relay"
 761
 762     if user = get_by_ap_id(relay_uri) do
 763       user
 764     else
 765       changes =
 766         %User{info: %User.Info{}}
 767         |> cast(%{}, [:ap_id, :nickname, :local])
 768         |> put_change(:ap_id, relay_uri)
 769         |> put_change(:nickname, nil)
 770         |> put_change(:local, true)
 771         |> put_change(:follower_address, relay_uri <> "/followers")
 772
 773       {:ok, user} = Repo.insert(changes)
 774       user
 775     end
 776   end
 777
 778   # AP style
 779   def public_key_from_info(%{
 780         source_data: %{"publicKey" => %{"publicKeyPem" => public_key_pem}}
 781       }) do
 782     key =
 783       public_key_pem
 784       |> :public_key.pem_decode()
 785       |> hd()
 786       |> :public_key.pem_entry_decode()
 787
 788     {:ok, key}
 789   end
 790
 791   # OStatus Magic Key
 792   def public_key_from_info(%{magic_key: magic_key}) do
 793     {:ok, Pleroma.Web.Salmon.decode_key(magic_key)}
 794   end
 795
 796   def get_public_key_for_ap_id(ap_id) do
 797     with %User{} = user <- get_or_fetch_by_ap_id(ap_id),
 798          {:ok, public_key} <- public_key_from_info(user.info) do
 799       {:ok, public_key}
 800     else
 801       _ -> :error
 802     end
 803   end
 804
 805   defp blank?(""), do: nil
 806   defp blank?(n), do: n
 807
 808   def insert_or_update_user(data) do
 809     data =
 810       data
 811       |> Map.put(:name, blank?(data[:name]) || data[:nickname])
 812
 813     cs = User.remote_user_creation(data)
 814
 815     Repo.insert(cs, on_conflict: :replace_all, conflict_target: :nickname)
 816   end
 817
 818   def ap_enabled?(%User{local: true}), do: true
 819   def ap_enabled?(%User{info: info}), do: info.ap_enabled
 820   def ap_enabled?(_), do: false
 821
 822   @doc "Gets or fetch a user by uri or nickname."
 823   @spec get_or_fetch(String.t()) :: User.t()
 824   def get_or_fetch("http" <> _host = uri), do: get_or_fetch_by_ap_id(uri)
 825   def get_or_fetch(nickname), do: get_or_fetch_by_nickname(nickname)
 826
 827   # wait a period of time and return newest version of the User structs
 828   # this is because we have synchronous follow APIs and need to simulate them
 829   # with an async handshake
 830   def wait_and_refresh(_, %User{local: true} = a, %User{local: true} = b) do
 831     with %User{} = a <- Repo.get(User, a.id),
 832          %User{} = b <- Repo.get(User, b.id) do
 833       {:ok, a, b}
 834     else
 835       _e ->
 836         :error
 837     end
 838   end
 839
 840   def wait_and_refresh(timeout, %User{} = a, %User{} = b) do
 841     with :ok <- :timer.sleep(timeout),
 842          %User{} = a <- Repo.get(User, a.id),
 843          %User{} = b <- Repo.get(User, b.id) do
 844       {:ok, a, b}
 845     else
 846       _e ->
 847         :error
 848     end
 849   end
 850
 851   def parse_bio(bio, user \\ %User{info: %{source_data: %{}}})
 852   def parse_bio(nil, _user), do: ""
 853   def parse_bio(bio, _user) when bio == "", do: bio
 854
 855   def parse_bio(bio, user) do
 856     mentions = Formatter.parse_mentions(bio)
 857     tags = Formatter.parse_tags(bio)
 858
 859     emoji =
 860       (user.info.source_data["tag"] || [])
 861       |> Enum.filter(fn %{"type" => t} -> t == "Emoji" end)
 862       |> Enum.map(fn %{"icon" => %{"url" => url}, "name" => name} ->
 863         {String.trim(name, ":"), url}
 864       end)
 865
 866     bio
 867     |> CommonUtils.format_input(mentions, tags, "text/plain")
 868     |> Formatter.emojify(emoji)
 869   end
 870
 871   def tag(user_identifiers, tags) when is_list(user_identifiers) do
 872     Repo.transaction(fn ->
 873       for user_identifier <- user_identifiers, do: tag(user_identifier, tags)
 874     end)
 875   end
 876
 877   def tag(nickname, tags) when is_binary(nickname),
 878     do: tag(User.get_by_nickname(nickname), tags)
 879
 880   def tag(%User{} = user, tags),
 881     do: update_tags(user, Enum.uniq((user.tags || []) ++ normalize_tags(tags)))
 882
 883   def untag(user_identifiers, tags) when is_list(user_identifiers) do
 884     Repo.transaction(fn ->
 885       for user_identifier <- user_identifiers, do: untag(user_identifier, tags)
 886     end)
 887   end
 888
 889   def untag(nickname, tags) when is_binary(nickname),
 890     do: untag(User.get_by_nickname(nickname), tags)
 891
 892   def untag(%User{} = user, tags),
 893     do: update_tags(user, (user.tags || []) -- normalize_tags(tags))
 894
 895   defp update_tags(%User{} = user, new_tags) do
 896     {:ok, updated_user} =
 897       user
 898       |> change(%{tags: new_tags})
 899       |> Repo.update()
 900
 901     updated_user
 902   end
 903
 904   defp normalize_tags(tags) do
 905     [tags]
 906     |> List.flatten()
 907     |> Enum.map(&String.downcase(&1))
 908   end
 909
 910   defp local_nickname_regex() do
 911     if Pleroma.Config.get([:instance, :extended_nickname_format]) do
 912       @extended_local_nickname_regex
 913     else
 914       @strict_local_nickname_regex
 915     end
 916   end
 917 end