git.squeep.com Git - akkoma/blob - lib/pleroma/user/search.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.User.Search do
   6   alias Pleroma.Repo
   7   alias Pleroma.User
   8   import Ecto.Query
   9
  10   @similarity_threshold 0.25
  11   @limit 20
  12
  13   def search(query_string, opts \\ []) do
  14     resolve = Keyword.get(opts, :resolve, false)
  15     following = Keyword.get(opts, :following, false)
  16     result_limit = Keyword.get(opts, :limit, @limit)
  17     offset = Keyword.get(opts, :offset, 0)
  18
  19     for_user = Keyword.get(opts, :for_user)
  20
  21     # Strip the beginning @ off if there is a query
  22     query_string = String.trim_leading(query_string, "@")
  23
  24     maybe_resolve(resolve, for_user, query_string)
  25
  26     {:ok, results} =
  27       Repo.transaction(fn ->
  28         Ecto.Adapters.SQL.query(
  29           Repo,
  30           "select set_limit(#{@similarity_threshold})",
  31           []
  32         )
  33
  34         query_string
  35         |> search_query(for_user, following)
  36         |> paginate(result_limit, offset)
  37         |> Repo.all()
  38       end)
  39
  40     results
  41   end
  42
  43   defp search_query(query_string, for_user, following) do
  44     for_user
  45     |> base_query(following)
  46     |> search_subqueries(query_string)
  47     |> union_subqueries
  48     |> distinct_query()
  49     |> boost_search_rank_query(for_user)
  50     |> subquery()
  51     |> order_by(desc: :search_rank)
  52     |> maybe_restrict_local(for_user)
  53   end
  54
  55   defp base_query(_user, false), do: User
  56   defp base_query(user, true), do: User.get_followers_query(user)
  57
  58   defp paginate(query, limit, offset) do
  59     from(q in query, limit: ^limit, offset: ^offset)
  60   end
  61
  62   defp union_subqueries({fts_subquery, trigram_subquery}) do
  63     from(s in trigram_subquery, union_all: ^fts_subquery)
  64   end
  65
  66   defp search_subqueries(base_query, query_string) do
  67     {
  68       fts_search_subquery(base_query, query_string),
  69       trigram_search_subquery(base_query, query_string)
  70     }
  71   end
  72
  73   defp distinct_query(q) do
  74     from(s in subquery(q), order_by: s.search_type, distinct: s.id)
  75   end
  76
  77   defp maybe_resolve(true, user, query) do
  78     case {limit(), user} do
  79       {:all, _} -> :noop
  80       {:unauthenticated, %User{}} -> User.get_or_fetch(query)
  81       {:unauthenticated, _} -> :noop
  82       {false, _} -> User.get_or_fetch(query)
  83     end
  84   end
  85
  86   defp maybe_resolve(_, _, _), do: :noop
  87
  88   defp maybe_restrict_local(q, user) do
  89     case {limit(), user} do
  90       {:all, _} -> restrict_local(q)
  91       {:unauthenticated, %User{}} -> q
  92       {:unauthenticated, _} -> restrict_local(q)
  93       {false, _} -> q
  94     end
  95   end
  96
  97   defp limit, do: Pleroma.Config.get([:instance, :limit_to_local_content], :unauthenticated)
  98
  99   defp restrict_local(q), do: where(q, [u], u.local == true)
 100
 101   defp boost_search_rank_query(query, nil), do: query
 102
 103   defp boost_search_rank_query(query, for_user) do
 104     friends_ids = User.get_friends_ids(for_user)
 105     followers_ids = User.get_followers_ids(for_user)
 106
 107     from(u in subquery(query),
 108       select_merge: %{
 109         search_rank:
 110           fragment(
 111             """
 112              CASE WHEN (?) THEN 0.5 + (?) * 1.3
 113              WHEN (?) THEN 0.5 + (?) * 1.2
 114              WHEN (?) THEN (?) * 1.1
 115              ELSE (?) END
 116             """,
 117             u.id in ^friends_ids and u.id in ^followers_ids,
 118             u.search_rank,
 119             u.id in ^friends_ids,
 120             u.search_rank,
 121             u.id in ^followers_ids,
 122             u.search_rank,
 123             u.search_rank
 124           )
 125       }
 126     )
 127   end
 128
 129   @spec fts_search_subquery(User.t() | Ecto.Query.t(), String.t()) :: Ecto.Query.t()
 130   defp fts_search_subquery(query, term) do
 131     processed_query =
 132       term
 133       |> String.replace(~r/\W+/, " ")
 134       |> String.trim()
 135       |> String.split()
 136       |> Enum.map(&(&1 <> ":*"))
 137       |> Enum.join(" | ")
 138
 139     from(
 140       u in query,
 141       select_merge: %{
 142         search_type: ^0,
 143         search_rank:
 144           fragment(
 145             """
 146             ts_rank_cd(
 147               setweight(to_tsvector('simple', regexp_replace(?, '\\W', ' ', 'g')), 'A') ||
 148               setweight(to_tsvector('simple', regexp_replace(coalesce(?, ''), '\\W', ' ', 'g')), 'B'),
 149               to_tsquery('simple', ?),
 150               32
 151             )
 152             """,
 153             u.nickname,
 154             u.name,
 155             ^processed_query
 156           )
 157       },
 158       where:
 159         fragment(
 160           """
 161             (setweight(to_tsvector('simple', regexp_replace(?, '\\W', ' ', 'g')), 'A') ||
 162             setweight(to_tsvector('simple', regexp_replace(coalesce(?, ''), '\\W', ' ', 'g')), 'B')) @@ to_tsquery('simple', ?)
 163           """,
 164           u.nickname,
 165           u.name,
 166           ^processed_query
 167         )
 168     )
 169     |> User.restrict_deactivated()
 170   end
 171
 172   @spec trigram_search_subquery(User.t() | Ecto.Query.t(), String.t()) :: Ecto.Query.t()
 173   defp trigram_search_subquery(query, term) do
 174     from(
 175       u in query,
 176       select_merge: %{
 177         # ^1 gives 'Postgrex expected a binary, got 1' for some weird reason
 178         search_type: fragment("?", 1),
 179         search_rank:
 180           fragment(
 181             "similarity(?, trim(? || ' ' || coalesce(?, '')))",
 182             ^term,
 183             u.nickname,
 184             u.name
 185           )
 186       },
 187       where: fragment("trim(? || ' ' || coalesce(?, '')) % ?", u.nickname, u.name, ^term)
 188     )
 189     |> User.restrict_deactivated()
 190   end
 191 end